cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2
   3 ;; Copyright (C) 2010-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library is meant to provide the glue between modules that want
  26 ;; to establish a network connection to a server for protocols such as
  27 ;; IMAP, NNTP, SMTP and POP3.
  28
  29 ;; The main problem is that there's more than a couple of interfaces
  30 ;; towards doing this.  You have normal, plain connections, which are
  31 ;; no trouble at all, but you also have TLS/SSL connections, and you
  32 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  33 ;; tedious, so this library provides a single entry point, and hides
  34 ;; much of the ugliness.
  35
  36 ;; Usage example:
  37
  38 ;; (open-protocol-stream
  39 ;;  "*nnimap*" buffer address port
  40 ;;  :type 'network
  41 ;;  :capability-command "1 CAPABILITY\r\n"
  42 ;;  :success " OK "
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (eval-when-compile
  52   (require 'cl))
  53 (require 'tls)
  54 (require 'starttls)
  55 (require 'format-spec)
  56
  57 (defcustom proto-stream-always-use-starttls (fboundp 'open-gnutls-stream)
  58   "If non-nil, always try to upgrade network connections with STARTTLS."
  59   :version "24.1"
  60   :type 'boolean
  61   :group 'comm)
  62
  63 (declare-function gnutls-negotiate "gnutls"
  64                   (proc type &optional priority-string trustfiles keyfiles))
  65
  66 ;;;###autoload
  67 (defun open-protocol-stream (name buffer host service &rest parameters)
  68   "Open a network stream to HOST, upgrading to STARTTLS if possible.
  69 The first four parameters have the same meaning as in
  70 `open-network-stream'.  The function returns a list where the
  71 first element is the stream, the second element is the greeting
  72 the server replied with after connecting, and the third element
  73 is a string representing the capabilities of the server (if any).
  74
  75 The PARAMETERS is a keyword list that can have the following
  76 values:
  77
  78 :type -- either `network', `network-only, `tls', `shell' or
  79 `starttls'.  If omitted, the default is `network'.  `network'
  80 will be opportunistically upgraded to STARTTLS if both the server
  81 and Emacs supports it.  If you don't want STARTTLS upgrades, use
  82 `network-only'.
  83
  84 :end-of-command -- a regexp saying what the end of a command is.
  85 This defaults to \"\\n\".
  86
  87 :success -- a regexp saying whether the STARTTLS command was
  88 successful or not.  For instance, for NNTP this is \"^3\".
  89
  90 :capability-command -- a string representing the command used to
  91 query server for capabilities.  For instance, for IMAP this is
  92 \"1 CAPABILITY\\r\\n\".
  93
  94 :starttls-function -- a function that takes one parameter, which
  95 is the response to the capaibility command.  It should return nil
  96 if it turns out that the server doesn't support STARTTLS, or the
  97 command to switch on STARTTLS otherwise."
  98   (let ((type (or (cadr (memq :type parameters)) 'network)))
  99     (cond
 100      ((eq type 'starttls)
 101       (setq type 'network))
 102      ((eq type 'ssl)
 103       (setq type 'tls)))
 104     (let ((open-result
 105            (funcall (intern (format "proto-stream-open-%s" type) obarray)
 106                     name buffer host service parameters)))
 107       (if (null open-result)
 108           (list nil nil nil)
 109         (destructuring-bind (stream greeting capabilities) open-result
 110           (list (and stream
 111                      (memq (process-status stream)
 112                            '(open run))
 113                      stream)
 114                 greeting capabilities))))))
 115
 116 (defun proto-stream-open-network-only (name buffer host service parameters)
 117   (let ((start (with-current-buffer buffer (point)))
 118         (stream (open-network-stream name buffer host service)))
 119     (list stream
 120           (proto-stream-get-response
 121            stream start (proto-stream-eoc parameters))
 122           nil)))
 123
 124 (defun proto-stream-open-network (name buffer host service parameters)
 125   (let* ((start (with-current-buffer buffer (point)))
 126          (stream (open-network-stream name buffer host service))
 127          (capability-command (cadr (memq :capability-command parameters)))
 128          (eoc (proto-stream-eoc parameters))
 129          (type (cadr (memq :type parameters)))
 130          (greeting (proto-stream-get-response stream start eoc))
 131          success)
 132     (if (not capability-command)
 133         (list stream greeting nil)
 134       (let* ((capabilities
 135               (proto-stream-command stream capability-command eoc))
 136              (starttls-command
 137               (funcall (cadr (memq :starttls-function parameters))
 138                        capabilities)))
 139         (cond
 140           ;; If this server doesn't support STARTTLS, but we have
 141           ;; requested it explicitly, then close the connection and
 142           ;; return nil.
 143          ((or (not starttls-command)
 144               (and (not (eq type 'starttls))
 145                    (not proto-stream-always-use-starttls)))
 146           (if (eq type 'starttls)
 147               (progn
 148                 (delete-process stream)
 149                 nil)
 150             ;; Otherwise, just return this plain network connection.
 151             (list stream greeting capabilities)))
 152          ;; We have some kind of STARTTLS support, so we try to
 153          ;; upgrade the connection opportunistically.
 154          ((or (fboundp 'open-gnutls-stream)
 155               (executable-find "gnutls-cli"))
 156           (unless (fboundp 'open-gnutls-stream)
 157             (delete-process stream)
 158             (setq start (with-current-buffer buffer (point-max)))
 159             (let* ((starttls-use-gnutls t)
 160                    (starttls-extra-arguments
 161                     (if (not (eq type 'starttls))
 162                         ;; When doing opportunistic TLS upgrades we
 163                         ;; don't really care about the identity of the
 164                         ;; peer.
 165                         (cons "--insecure" starttls-extra-arguments)
 166                       starttls-extra-arguments)))
 167               (setq stream (starttls-open-stream name buffer host service)))
 168             (proto-stream-get-response stream start eoc))
 169           (if (not
 170                (string-match
 171                 (cadr (memq :success parameters))
 172                 (proto-stream-command stream starttls-command eoc)))
 173               ;; We got an error back from the STARTTLS command.
 174               (progn
 175                 (if (eq type 'starttls)
 176                     (progn
 177                       (delete-process stream)
 178                       nil)
 179                   (list stream greeting capabilities)))
 180             ;; The server said it was OK to start doing STARTTLS negotiations.
 181             (if (fboundp 'open-gnutls-stream)
 182                 (gnutls-negotiate stream nil)
 183               (unless (starttls-negotiate stream)
 184                 (delete-process stream)
 185                 (setq stream nil)))
 186             (when (or (null stream)
 187                       (not (memq (process-status stream)
 188                                  '(open run))))
 189               ;; It didn't successfully negotiate STARTTLS, so we reopen
 190               ;; the connection.
 191               (setq stream (open-network-stream name buffer host service))
 192               (proto-stream-get-response stream start eoc))
 193             ;; Re-get the capabilities, since they may have changed
 194             ;; after switching to TLS.
 195             (list stream greeting
 196                   (proto-stream-command stream capability-command eoc))))
 197          ;; We don't have STARTTLS support available, but the caller
 198          ;; requested a STARTTLS connection, so we give up.
 199          ((eq (cadr (memq :type parameters)) 'starttls)
 200           (delete-process stream)
 201           nil)
 202          ;; Fall back on using a plain network stream.
 203          (t
 204           (list stream greeting capabilities)))))))
 205
 206 (defun proto-stream-command (stream command eoc)
 207   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 208     (process-send-string stream command)
 209     (proto-stream-get-response stream start eoc)))
 210
 211 (defun proto-stream-get-response (stream start end-of-command)
 212   (with-current-buffer (process-buffer stream)
 213     (save-excursion
 214       (goto-char start)
 215       (while (and (memq (process-status stream)
 216                         '(open run))
 217                   (not (re-search-forward end-of-command nil t)))
 218         (accept-process-output stream 0 50)
 219         (goto-char start))
 220       (if (= start (point))
 221           ;; The process died; return nil.
 222           nil
 223         ;; Return the data we got back.
 224         (buffer-substring start (point))))))
 225
 226 (defun proto-stream-open-tls (name buffer host service parameters)
 227   (with-current-buffer buffer
 228     (let ((start (point-max))
 229           (stream
 230            (funcall (if (fboundp 'open-gnutls-stream)
 231                         'open-gnutls-stream
 232                       'open-tls-stream)
 233                     name buffer host service)))
 234       (if (null stream)
 235           nil
 236         ;; If we're using tls.el, we have to delete the output from
 237         ;; openssl/gnutls-cli.
 238         (unless (fboundp 'open-gnutls-stream)
 239           (proto-stream-get-response
 240            stream start (proto-stream-eoc parameters))
 241           (goto-char (point-min))
 242           (when (re-search-forward (proto-stream-eoc parameters) nil t)
 243             (goto-char (match-beginning 0))
 244             (delete-region (point-min) (line-beginning-position))))
 245         (proto-stream-capability-open start stream parameters)))))
 246
 247 (defun proto-stream-open-shell (name buffer host service parameters)
 248   (proto-stream-capability-open
 249    (with-current-buffer buffer (point))
 250    (let ((process-connection-type nil))
 251      (start-process name buffer shell-file-name
 252                     shell-command-switch
 253                     (format-spec
 254                      (cadr (memq :shell-command parameters))
 255                      (format-spec-make
 256                       ?s host
 257                       ?p service))))
 258    parameters))
 259
 260 (defun proto-stream-capability-open (start stream parameters)
 261   (let ((capability-command (cadr (memq :capability-command parameters)))
 262         (greeting (proto-stream-get-response
 263                    stream start (proto-stream-eoc parameters))))
 264     (list stream greeting
 265           (and capability-command
 266                (proto-stream-command
 267                 stream capability-command (proto-stream-eoc parameters))))))
 268
 269 (defun proto-stream-eoc (parameters)
 270   (or (cadr (memq :end-of-command parameters))
 271       "\r\n"))
 272
 273 (provide 'proto-stream)
 274
 275 ;;; proto-stream.el ends here