cgit.sxemacs.org Git - gnus/blob - lisp/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996,1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   6 ;; Keywords: mail, pop3
   7 ;; Version: 1.3k
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  29 ;; are implemented.  The LIST command has not been implemented due to lack
  30 ;; of actual usefulness.
  31 ;; The optional POP3 command TOP has not been implemented.
  32
  33 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  34
  35 ;;; Code:
  36
  37 (require 'mail-utils)
  38 (provide 'pop3)
  39
  40 (defconst pop3-version "1.3k")
  41
  42 (defvar pop3-maildrop (or user-login-name (getenv "LOGNAME") (getenv "USER") nil)
  43   "*POP3 maildrop.")
  44 (defvar pop3-mailhost (or (getenv "MAILHOST") nil)
  45   "*POP3 mailhost.")
  46 (defvar pop3-port 110
  47   "*POP3 port.")
  48
  49 (defvar pop3-password-required t
  50   "*Non-nil if a password is required when connecting to POP server.")
  51 (defvar pop3-password nil
  52   "*Password to use when connecting to POP server.")
  53
  54 (defvar pop3-authentication-scheme 'pass
  55   "*POP3 authentication scheme.
  56 Defaults to 'pass, for the standard USER/PASS authentication.  Other valid
  57 values are 'apop.")
  58
  59 (defvar pop3-timestamp nil
  60   "Timestamp returned when initially connected to the POP server.
  61 Used for APOP authentication.")
  62
  63 (defvar pop3-read-point nil)
  64 (defvar pop3-debug nil)
  65
  66 (defun pop3-movemail (&optional crashbox)
  67   "Transfer contents of a maildrop to the specified CRASHBOX."
  68   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
  69   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
  70          (crashbuf (get-buffer-create " *pop3-retr*"))
  71          (n 1)
  72          message-count
  73          (pop3-password pop3-password)
  74          )
  75     ;; for debugging only
  76     (if pop3-debug (switch-to-buffer (process-buffer process)))
  77     ;; query for password
  78     (if (and pop3-password-required (not pop3-password))
  79         (setq pop3-password
  80               (pop3-read-passwd (format "Password for %s: " pop3-maildrop))))
  81     (cond ((equal 'apop pop3-authentication-scheme)
  82            (pop3-apop process pop3-maildrop))
  83           ((equal 'pass pop3-authentication-scheme)
  84            (pop3-user process pop3-maildrop)
  85            (pop3-pass process))
  86           (t (error "Invalid POP3 authentication scheme.")))
  87     (setq message-count (car (pop3-stat process)))
  88     (while (<= n message-count)
  89       (message (format "Retrieving message %d of %d from %s..."
  90                        n message-count pop3-mailhost))
  91       (pop3-retr process n crashbuf)
  92       (save-excursion
  93         (set-buffer crashbuf)
  94         (append-to-file (point-min) (point-max) crashbox)
  95         (set-buffer (process-buffer process))
  96         (while (> (buffer-size) 5000)
  97           (goto-char (point-min))
  98           (forward-line 50)
  99           (delete-region (point-min) (point))))
 100       (pop3-dele process n)
 101       (setq n (+ 1 n))
 102       (if pop3-debug (sit-for 1) (sit-for 0.1))
 103       )
 104     (pop3-quit process)
 105     (kill-buffer crashbuf)
 106     )
 107   )
 108
 109 (defun pop3-open-server (mailhost port)
 110   "Open TCP connection to MAILHOST.
 111 Returns the process associated with the connection."
 112   (let ((process-buffer
 113          (get-buffer-create (format "trace of POP session to %s" mailhost)))
 114         (process))
 115     (save-excursion
 116       (set-buffer process-buffer)
 117       (erase-buffer)
 118       (setq pop3-read-point (point-min))
 119       )
 120     (setq process
 121           (open-network-stream "POP" process-buffer mailhost port))
 122     (let ((response (pop3-read-response process t)))
 123       (setq pop3-timestamp
 124             (substring response (or (string-match "<" response) 0)
 125                        (+ 1 (or (string-match ">" response) -1)))))
 126     process
 127     ))
 128
 129 ;; Support functions
 130
 131 (defun pop3-process-filter (process output)
 132   (save-excursion
 133     (set-buffer (process-buffer process))
 134     (goto-char (point-max))
 135     (insert output)))
 136
 137 (defun pop3-send-command (process command)
 138     (set-buffer (process-buffer process))
 139     (goto-char (point-max))
 140 ;;    (if (= (aref command 0) ?P)
 141 ;;      (insert "PASS <omitted>\r\n")
 142 ;;      (insert command "\r\n"))
 143     (setq pop3-read-point (point))
 144     (goto-char (point-max))
 145     (process-send-string process command)
 146     (process-send-string process "\r\n")
 147     )
 148
 149 (defun pop3-read-response (process &optional return)
 150   "Read the response from the server.
 151 Return the response string if optional second argument is non-nil."
 152   (let ((case-fold-search nil)
 153         match-end)
 154     (save-excursion
 155       (set-buffer (process-buffer process))
 156       (goto-char pop3-read-point)
 157       (while (not (search-forward "\r\n" nil t))
 158         (accept-process-output process 3)
 159         (goto-char pop3-read-point))
 160       (setq match-end (point))
 161       (goto-char pop3-read-point)
 162       (if (looking-at "-ERR")
 163           (error (buffer-substring (point) (- match-end 2)))
 164         (if (not (looking-at "+OK"))
 165             (progn (setq pop3-read-point match-end) nil)
 166           (setq pop3-read-point match-end)
 167           (if return
 168               (buffer-substring (point) match-end)
 169             t)
 170           )))))
 171
 172 (defun pop3-string-to-list (string &optional regexp)
 173   "Chop up a string into a list."
 174   (let ((list)
 175         (regexp (or regexp " "))
 176         (string (if (string-match "\r" string)
 177                     (substring string 0 (match-beginning 0))
 178                   string)))
 179     (store-match-data nil)
 180     (while string
 181       (if (string-match regexp string)
 182           (setq list (cons (substring string 0 (- (match-end 0) 1)) list)
 183                 string (substring string (match-end 0)))
 184         (setq list (cons string list)
 185               string nil)))
 186     (nreverse list)))
 187
 188 (defvar pop3-read-passwd nil)
 189 (defun pop3-read-passwd (prompt)
 190   (if (not pop3-read-passwd)
 191       (if (load "passwd" t)
 192           (setq pop3-read-passwd 'read-passwd)
 193         (autoload 'ange-ftp-read-passwd "ange-ftp")
 194         (setq pop3-read-passwd 'ange-ftp-read-passwd)))
 195   (funcall pop3-read-passwd prompt))
 196
 197 (defun pop3-clean-region (start end)
 198   (setq end (set-marker (make-marker) end))
 199   (save-excursion
 200     (goto-char start)
 201     (while (and (< (point) end) (search-forward "\r\n" end t))
 202       (replace-match "\n" t t))
 203     (goto-char start)
 204     (while (and (< (point) end) (re-search-forward "^\\." end t))
 205       (replace-match "" t t)
 206       (forward-char)))
 207   (set-marker end nil))
 208
 209 (defun pop3-munge-message-separator (start end)
 210   "Check to see if a message separator exists.  If not, generate one."
 211   (if (not (fboundp 'message-make-date)) (autoload 'message-make-date "message"))
 212   (save-excursion
 213     (save-restriction
 214       (narrow-to-region start end)
 215       (goto-char (point-min))
 216       (if (not (or (looking-at "From .?") ; Unix mail
 217                    (looking-at "\001\001\001\001\n") ; MMDF
 218                    (looking-at "BABYL OPTIONS:") ; Babyl
 219                    ))
 220           (let ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 221                 (date (pop3-string-to-list (or (mail-fetch-field "Date")
 222                                                (message-make-date))))
 223                 (From_))
 224             ;; sample date formats I have seen
 225             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 226             ;; Date: 08 Jul 1996 23:22:24 -0400
 227             ;; should be
 228             ;; Tue Jul 9 09:04:21 1996
 229             (setq date
 230                   (cond ((string-match "[A-Z]" (nth 0 date))
 231                          (format "%s %s %s %s %s"
 232                                  (nth 0 date) (nth 2 date) (nth 1 date)
 233                                  (nth 4 date) (nth 3 date)))
 234                         (t
 235                          ;; this really needs to be better but I don't feel
 236                          ;; like writing a date to day converter.
 237                          (format "Sun %s %s %s %s"
 238                                  (nth 1 date) (nth 0 date)
 239                                  (nth 3 date) (nth 2 date)))
 240                         ))
 241             (setq From_ (format "\nFrom %s  %s\n" from date))
 242             (while (string-match "," From_)
 243               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 244                                   (substring From_ (match-end 0)))))
 245             (goto-char (point-min))
 246             (insert From_))))))
 247
 248 ;; The Command Set
 249
 250 ;; AUTHORIZATION STATE
 251
 252 (defun pop3-user (process user)
 253   "Send USER information to POP3 server."
 254   (pop3-send-command process (format "USER %s" user))
 255   (let ((response (pop3-read-response process t)))
 256     (if (not (and response (string-match "+OK" response)))
 257         (error (format "USER %s not valid." user)))))
 258
 259 (defun pop3-pass (process)
 260   "Send authentication information to the server."
 261   (pop3-send-command process (format "PASS %s" pop3-password))
 262   (let ((response (pop3-read-response process t)))
 263     (if (not (and response (string-match "+OK" response)))
 264         (pop3-quit process))))
 265
 266 (defun pop3-apop (process user)
 267   "Send alternate authentication information to the server."
 268   (if (not (fboundp 'md5)) (autoload 'md5 "md5"))
 269   (let ((hash (md5 (concat pop3-timestamp pop3-password))))
 270     (pop3-send-command process (format "APOP %s %s" user hash))
 271     (let ((response (pop3-read-response process t)))
 272       (if (not (and response (string-match "+OK" response)))
 273           (pop3-quit process)))))
 274
 275 ;; TRANSACTION STATE
 276
 277 (defun pop3-stat (process)
 278   "Return the number of messages in the maildrop and the maildrop's size."
 279   (pop3-send-command process "STAT")
 280   (let ((response (pop3-read-response process t)))
 281     (list (string-to-int (nth 1 (pop3-string-to-list response)))
 282           (string-to-int (nth 2 (pop3-string-to-list response))))
 283     ))
 284
 285 (defun pop3-list (process &optional msg)
 286   "Scan listing of available messages.
 287 This function currently does nothing.")
 288
 289 (defun pop3-retr (process msg crashbuf)
 290   "Retrieve message-id MSG to buffer CRASHBUF."
 291   (pop3-send-command process (format "RETR %s" msg))
 292   (pop3-read-response process)
 293   (let ((start pop3-read-point) end)
 294     (save-excursion
 295       (set-buffer (process-buffer process))
 296       (while (not (re-search-forward "^\\.\r\n" nil t))
 297         (accept-process-output process 3)
 298         ;; bill@att.com ... to save wear and tear on the heap
 299         ;; uncommented because the condensed version below is a problem for
 300         ;; some.
 301         (if (> (buffer-size)  20000) (sleep-for 1))
 302         (if (> (buffer-size)  50000) (sleep-for 1))
 303         (if (> (buffer-size) 100000) (sleep-for 1))
 304         (if (> (buffer-size) 200000) (sleep-for 1))
 305         (if (> (buffer-size) 500000) (sleep-for 1))
 306         ;; bill@att.com
 307         ;; condensed into:
 308         ;; (sometimes causes problems for really large messages.)
 309 ;       (if (> (buffer-size) 20000) (sleep-for (/ (buffer-size) 20000)))
 310         (goto-char start))
 311       (setq pop3-read-point (point-marker))
 312 ;; this code does not seem to work for some POP servers...
 313 ;; and I cannot figure out why not.
 314 ;      (goto-char (match-beginning 0))
 315 ;      (backward-char 2)
 316 ;      (if (not (looking-at "\r\n"))
 317 ;         (insert "\r\n"))
 318 ;      (re-search-forward "\\.\r\n")
 319       (goto-char (match-beginning 0))
 320       (setq end (point-marker))
 321       (pop3-clean-region start end)
 322       (pop3-munge-message-separator start end)
 323       (save-excursion
 324         (set-buffer crashbuf)
 325         (erase-buffer))
 326       (copy-to-buffer crashbuf start end)
 327       (delete-region start end)
 328       )))
 329
 330 (defun pop3-dele (process msg)
 331   "Mark message-id MSG as deleted."
 332   (pop3-send-command process (format "DELE %s" msg))
 333   (pop3-read-response process))
 334
 335 (defun pop3-noop (process msg)
 336   "No-operation."
 337   (pop3-send-command process "NOOP")
 338   (pop3-read-response process))
 339
 340 (defun pop3-last (process)
 341   "Return highest accessed message-id number for the session."
 342   (pop3-send-command process "LAST")
 343   (let ((response (pop3-read-response process t)))
 344     (string-to-int (nth 1 (pop3-string-to-list response)))
 345     ))
 346
 347 (defun pop3-rset (process)
 348   "Remove all delete marks from current maildrop."
 349   (pop3-send-command process "RSET")
 350   (pop3-read-response process))
 351
 352 ;; UPDATE
 353
 354 (defun pop3-quit (process)
 355   "Close connection to POP3 server.
 356 Tell server to remove all messages marked as deleted, unlock the maildrop,
 357 and close the connection."
 358   (pop3-send-command process "QUIT")
 359   (pop3-read-response process t)
 360   (if process
 361       (save-excursion
 362         (set-buffer (process-buffer process))
 363         (goto-char (point-max))
 364         (delete-process process))))
 365 \f
 366 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 367
 368 ;;; AUTHORIZATION STATE
 369
 370 ;; Initial TCP connection
 371 ;; Arguments: none
 372 ;; Restrictions: none
 373 ;; Possible responses:
 374 ;;  +OK [POP3 server ready]
 375
 376 ;; USER name
 377 ;; Arguments: a server specific user-id (required)
 378 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 379 ;; Possible responses:
 380 ;;  +OK [valid user-id]
 381 ;;  -ERR [invalid user-id]
 382
 383 ;; PASS string
 384 ;; Arguments: a server/user-id specific password (required)
 385 ;; Restrictions: authorization state, after successful USER
 386 ;; Possible responses:
 387 ;;  +OK [maildrop locked and ready]
 388 ;;  -ERR [invalid password]
 389 ;;  -ERR [unable to lock maildrop]
 390
 391 ;;; TRANSACTION STATE
 392
 393 ;; STAT
 394 ;; Arguments: none
 395 ;; Restrictions: transaction state
 396 ;; Possible responses:
 397 ;;  +OK nn mm [# of messages, size of maildrop]
 398
 399 ;; LIST [msg]
 400 ;; Arguments: a message-id (optional)
 401 ;; Restrictions: transaction state; msg must not be deleted
 402 ;; Possible responses:
 403 ;;  +OK [scan listing follows]
 404 ;;  -ERR [no such message]
 405
 406 ;; RETR msg
 407 ;; Arguments: a message-id (required)
 408 ;; Restrictions: transaction state; msg must not be deleted
 409 ;; Possible responses:
 410 ;;  +OK [message contents follow]
 411 ;;  -ERR [no such message]
 412
 413 ;; DELE msg
 414 ;; Arguments: a message-id (required)
 415 ;; Restrictions: transaction state; msg must not be deleted
 416 ;; Possible responses:
 417 ;;  +OK [message deleted]
 418 ;;  -ERR [no such message]
 419
 420 ;; NOOP
 421 ;; Arguments: none
 422 ;; Restrictions: transaction state
 423 ;; Possible responses:
 424 ;;  +OK
 425
 426 ;; LAST
 427 ;; Arguments: none
 428 ;; Restrictions: transaction state
 429 ;; Possible responses:
 430 ;;  +OK nn [highest numbered message accessed]
 431
 432 ;; RSET
 433 ;; Arguments: none
 434 ;; Restrictions: transaction state
 435 ;; Possible responses:
 436 ;;  +OK [all delete marks removed]
 437
 438 ;;; UPDATE STATE
 439
 440 ;; QUIT
 441 ;; Arguments: none
 442 ;; Restrictions: none
 443 ;; Possible responses:
 444 ;;  +OK [TCP connection closed]