cgit.sxemacs.org Git - gnus/blob - lisp/pgg-pgp5.el

   1 ;;; pgg-pgp5.el --- PGP 5.* support for PGG.
   2
   3 ;; Copyright (C) 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Daiki Ueno <ueno@unixuser.org>
   7 ;; Created: 1999/11/02
   8 ;; Keywords: PGP, OpenPGP
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)                         ; for pgg macros
  31   (require 'pgg))
  32
  33 (defgroup pgg-pgp5 ()
  34   "PGP 5.* interface."
  35   :group 'pgg)
  36
  37 (defcustom pgg-pgp5-pgpe-program "pgpe"
  38   "PGP 5.* 'pgpe' executable."
  39   :group 'pgg-pgp5
  40   :type 'string)
  41
  42 (defcustom pgg-pgp5-pgps-program "pgps"
  43   "PGP 5.* 'pgps' executable."
  44   :group 'pgg-pgp5
  45   :type 'string)
  46
  47 (defcustom pgg-pgp5-pgpk-program "pgpk"
  48   "PGP 5.* 'pgpk' executable."
  49   :group 'pgg-pgp5
  50   :type 'string)
  51
  52 (defcustom pgg-pgp5-pgpv-program "pgpv"
  53   "PGP 5.* 'pgpv' executable."
  54   :group 'pgg-pgp5
  55   :type 'string)
  56
  57 (defcustom pgg-pgp5-shell-file-name "/bin/sh"
  58   "File name to load inferior shells from.
  59 Bourne shell or its equivalent \(not tcsh) is needed for \"2>\"."
  60   :group 'pgg-pgp5
  61   :type 'string)
  62
  63 (defcustom pgg-pgp5-shell-command-switch "-c"
  64   "Switch used to have the shell execute its command line argument."
  65   :group 'pgg-pgp5
  66   :type 'string)
  67
  68 (defcustom pgg-pgp5-extra-args nil
  69   "Extra arguments for every PGP 5.* invocation."
  70   :group 'pgg-pgp5
  71   :type '(choice
  72           (const :tag "None" nil)
  73           (string :tag "Arguments")))
  74
  75 (defvar pgg-pgp5-user-id nil
  76   "PGP 5.* ID of your default identity.")
  77
  78 (defun pgg-pgp5-process-region (start end passphrase program args)
  79   (let* ((errors-file-name (pgg-make-temp-file "pgg-errors"))
  80          (args
  81           (append args
  82                   pgg-pgp5-extra-args
  83                   (list (concat "2>" errors-file-name))))
  84          (shell-file-name pgg-pgp5-shell-file-name)
  85          (shell-command-switch pgg-pgp5-shell-command-switch)
  86          (process-environment process-environment)
  87          (output-buffer pgg-output-buffer)
  88          (errors-buffer pgg-errors-buffer)
  89          (process-connection-type nil)
  90          process status exit-status)
  91     (with-current-buffer (get-buffer-create output-buffer)
  92       (buffer-disable-undo)
  93       (erase-buffer))
  94     (when passphrase
  95       (setenv "PGPPASSFD" "0"))
  96     (unwind-protect
  97         (progn
  98           (let ((coding-system-for-read 'binary)
  99                 (coding-system-for-write 'binary))
 100             (setq process
 101                   (apply #'funcall
 102                          #'start-process-shell-command "*PGP*" output-buffer
 103                          program args)))
 104           (set-process-sentinel process #'ignore)
 105           (when passphrase
 106             (process-send-string process (concat passphrase "\n")))
 107           (process-send-region process start end)
 108           (process-send-eof process)
 109           (while (eq 'run (process-status process))
 110             (accept-process-output process 5))
 111           (setq status (process-status process)
 112                 exit-status (process-exit-status process))
 113           (delete-process process)
 114           (with-current-buffer output-buffer
 115             (pgg-convert-lbt-region (point-min)(point-max) 'LF)
 116
 117             (if (memq status '(stop signal))
 118                 (error "%s exited abnormally: '%s'" program exit-status))
 119             (if (= 127 exit-status)
 120                 (error "%s could not be found" program))
 121
 122             (set-buffer (get-buffer-create errors-buffer))
 123             (buffer-disable-undo)
 124             (erase-buffer)
 125             (insert-file-contents errors-file-name)))
 126       (if (and process (eq 'run (process-status process)))
 127           (interrupt-process process))
 128       (condition-case nil
 129           (delete-file errors-file-name)
 130         (file-error nil)))))
 131
 132 (defun pgg-pgp5-lookup-key (string &optional type)
 133   "Search keys associated with STRING."
 134   (let ((args (list "+language=en" "-l" string)))
 135     (with-current-buffer (get-buffer-create pgg-output-buffer)
 136       (buffer-disable-undo)
 137       (erase-buffer)
 138       (apply #'call-process pgg-pgp5-pgpk-program nil t nil args)
 139       (goto-char (point-min))
 140       (when (re-search-forward "^sec" nil t)
 141         (substring
 142          (nth 2 (split-string
 143                  (buffer-substring (match-end 0)(progn (end-of-line)(point)))))
 144          2)))))
 145
 146 (defun pgg-pgp5-encrypt-region (start end recipients &optional sign)
 147   "Encrypt the current region between START and END."
 148   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 149          (args
 150           `("+NoBatchInvalidKeys=off" "-fat" "+batchmode=1"
 151             ,@(if recipients
 152                   (apply #'append
 153                          (mapcar (lambda (rcpt)
 154                                    (list "-r"
 155                                          (concat "\"" rcpt "\"")))
 156                                  (append recipients
 157                                          (if pgg-encrypt-for-me
 158                                              (list pgg-pgp5-user-id)))))))))
 159     (pgg-pgp5-process-region start end nil pgg-pgp5-pgpe-program args)
 160     (pgg-process-when-success nil)))
 161
 162 (defun pgg-pgp5-decrypt-region (start end)
 163   "Decrypt the current region between START and END."
 164   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 165          (passphrase
 166           (pgg-read-passphrase
 167            (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 168            (pgg-pgp5-lookup-key pgg-pgp5-user-id 'encrypt)))
 169          (args
 170           '("+verbose=1" "+batchmode=1" "+language=us" "-f")))
 171     (pgg-pgp5-process-region start end passphrase pgg-pgp5-pgpv-program args)
 172     (pgg-process-when-success nil)))
 173
 174 (defun pgg-pgp5-sign-region (start end &optional clearsign)
 175   "Make detached signature from text between START and END."
 176   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 177          (passphrase
 178           (pgg-read-passphrase
 179            (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 180            (pgg-pgp5-lookup-key pgg-pgp5-user-id 'sign)))
 181          (args
 182           (list (if clearsign "-fat" "-fbat")
 183                 "+verbose=1" "+language=us" "+batchmode=1"
 184                 "-u" pgg-pgp5-user-id)))
 185     (pgg-pgp5-process-region start end passphrase pgg-pgp5-pgps-program args)
 186     (pgg-process-when-success
 187       (when (re-search-forward "^-+BEGIN PGP SIGNATURE" nil t);XXX
 188         (let ((packet
 189                (cdr (assq 2 (pgg-parse-armor-region
 190                              (progn (beginning-of-line 2)
 191                                     (point))
 192                              (point-max))))))
 193           (if pgg-cache-passphrase
 194               (pgg-add-passphrase-cache
 195                (cdr (assq 'key-identifier packet))
 196                passphrase)))))))
 197
 198 (defun pgg-pgp5-verify-region (start end &optional signature)
 199   "Verify region between START and END as the detached signature SIGNATURE."
 200   (let ((orig-file (pgg-make-temp-file "pgg"))
 201         (args '("+verbose=1" "+batchmode=1" "+language=us"))
 202         (orig-mode (default-file-modes)))
 203     (unwind-protect
 204         (progn
 205           (set-default-file-modes 448)
 206           (let ((coding-system-for-write 'binary)
 207                 jka-compr-compression-info-list jam-zcat-filename-list)
 208             (write-region start end orig-file)))
 209       (set-default-file-modes orig-mode))
 210     (when (stringp signature)
 211       (copy-file signature (setq signature (concat orig-file ".asc")))
 212       (setq args (append args (list signature))))
 213     (pgg-pgp5-process-region (point)(point) nil pgg-pgp5-pgpv-program args)
 214     (delete-file orig-file)
 215     (if signature (delete-file signature))
 216     (with-current-buffer pgg-errors-buffer
 217       (goto-char (point-min))
 218       (if (re-search-forward "^Good signature" nil t)
 219           (progn
 220             (set-buffer pgg-output-buffer)
 221             (insert-buffer-substring pgg-errors-buffer)
 222             t)
 223         nil))))
 224
 225 (defun pgg-pgp5-insert-key ()
 226   "Insert public key at point."
 227   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 228          (args
 229           (list "+verbose=1" "+batchmode=1" "+language=us" "-x"
 230                 (concat "\"" pgg-pgp5-user-id "\""))))
 231     (pgg-pgp5-process-region (point)(point) nil pgg-pgp5-pgpk-program args)
 232     (insert-buffer-substring pgg-output-buffer)))
 233
 234 (defun pgg-pgp5-snarf-keys-region (start end)
 235   "Add all public keys in region between START and END to the keyring."
 236   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 237          (key-file (pgg-make-temp-file "pgg"))
 238          (args
 239           (list "+verbose=1" "+batchmode=1" "+language=us" "-a"
 240                 key-file)))
 241     (let ((coding-system-for-write 'raw-text-dos))
 242       (write-region start end key-file))
 243     (pgg-pgp5-process-region start end nil pgg-pgp5-pgpk-program args)
 244     (delete-file key-file)
 245     (pgg-process-when-success nil)))
 246
 247 (provide 'pgg-pgp5)
 248
 249 ;;; arch-tag: 3dbd1073-6b3a-466c-9f55-5c587ffa6d7b
 250 ;;; pgg-pgp5.el ends here