cgit.sxemacs.org Git - gnus/blob - lisp/password.el

   1 ;;; password.el --- Read passwords from user, possibly using a password cache.
   2
   3 ;; Copyright (C) 1999, 2000, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6 ;; Created: 2003-12-21
   7 ;; Keywords: password cache passphrase key
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Greatly influenced by pgg.el written by Daiki Ueno, with timer
  29 ;; fixes for XEmacs by Katsumi Yamaoka.  In fact, this is mostly just
  30 ;; a rip-off.
  31 ;;
  32 ;; (password-read "Password? " "test")
  33 ;; ;; Minibuffer prompt for password.
  34 ;;  => "foo"
  35 ;;
  36 ;; (password-cache-add "test" "foo")
  37 ;;  => nil
  38
  39 ;; Note the previous two can be replaced with:
  40 ;; (password-read-and-add "Password? " "test")
  41 ;; ;; Minibuffer prompt for password.
  42 ;; => "foo"
  43 ;; ;; "foo" is now cached with key "test"
  44
  45
  46 ;; (password-read "Password? " "test")
  47 ;; ;; No minibuffer prompt
  48 ;;  => "foo"
  49 ;;
  50 ;; (password-read "Password? " "test")
  51 ;; ;; No minibuffer prompt
  52 ;;  => "foo"
  53 ;;
  54 ;; ;; Wait `password-cache-expiry' seconds.
  55 ;;
  56 ;; (password-read "Password? " "test")
  57 ;; ;; Minibuffer prompt for password is back.
  58 ;;  => "foo"
  59
  60 ;;; Code:
  61
  62 (eval-when-compile
  63   (require 'cl))
  64
  65 (defcustom password-cache t
  66   "Whether to cache passwords."
  67   :group 'password
  68   :type 'boolean)
  69
  70 (defcustom password-cache-expiry 16
  71   "How many seconds passwords are cached, or nil to disable expiring.
  72 Whether passwords are cached at all is controlled by `password-cache'."
  73   :group 'password
  74   :type '(choice (const :tag "Never" nil)
  75                  (integer :tag "Seconds")))
  76
  77 (defvar password-data (make-vector 7 0))
  78
  79 (defun password-read-from-cache (key)
  80   "Obtain passphrase for KEY from time-limited passphrase cache.
  81 Custom variables `password-cache' and `password-cache-expiry'
  82 regulate cache behavior."
  83   (and password-cache
  84        key
  85        (symbol-value (intern-soft key password-data))))
  86
  87 (defun password-read (prompt &optional key)
  88   "Read password, for use with KEY, from user, or from cache if wanted.
  89 KEY indicate the purpose of the password, so the cache can
  90 separate passwords.  The cache is not used if KEY is nil.  It is
  91 typically a string.
  92 The variable `password-cache' control whether the cache is used."
  93   (or (password-read-from-cache key)
  94       (read-passwd prompt)))
  95
  96 (defun password-read-and-add (prompt &optional key)
  97   "Read password, for use with KEY, from user, or from cache if wanted.
  98 Then store the password in the cache.  Uses `password-read' and
  99 `password-cache-add'.
 100 Custom variables `password-cache' and `password-cache-expiry'
 101 regulate cache behavior."
 102   (let ((password (password-read prompt key)))
 103     (when (and password key)
 104       (password-cache-add key password))
 105     password))
 106
 107 (defun password-cache-remove (key)
 108   "Remove password indexed by KEY from password cache.
 109 This is typically run be a timer setup from `password-cache-add',
 110 but can be invoked at any time to forcefully remove passwords
 111 from the cache.  This may be useful when it has been detected
 112 that a password is invalid, so that `password-read' query the
 113 user again."
 114   (let ((password (symbol-value (intern-soft key password-data))))
 115     (when password
 116       (fillarray password ?_)
 117       (unintern key password-data))))
 118
 119 (defun password-cache-add (key password)
 120   "Add password to cache.
 121 The password is removed by a timer after `password-cache-expiry'
 122 seconds."
 123   (when (and password-cache-expiry (null (intern-soft key password-data)))
 124     (run-at-time password-cache-expiry nil
 125                  #'password-cache-remove
 126                  key))
 127   (set (intern key password-data) password)
 128   nil)
 129
 130 (defun password-reset ()
 131   "Clear the password cache."
 132   (interactive)
 133   (fillarray password-data 0))
 134
 135 (provide 'password)
 136
 137 ;;; arch-tag: ab160494-16c8-4c68-a4a1-73eebf6686e5
 138 ;;; password.el ends here