cgit.sxemacs.org Git - gnus/blob - lisp/parse-time.el

   1 ;;; parse-time.el --- parsing time strings
   2
   3 ;; Copyright (C) 1996, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008  Free Software Foundation, Inc.
   5
   6 ;; Author: Erik Naggum <erik@naggum.no>
   7 ;; Keywords: util
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; With the introduction of the `encode-time', `decode-time', and
  27 ;; `format-time-string' functions, dealing with time became simpler in
  28 ;; Emacs.  However, parsing time strings is still largely a matter of
  29 ;; heuristics and no common interface has been designed.
  30
  31 ;; `parse-time-string' parses a time in a string and returns a list of 9
  32 ;; values, just like `decode-time', where unspecified elements in the
  33 ;; string are returned as nil.  `encode-time' may be applied on these
  34 ;; values to obtain an internal time value.
  35
  36 ;;; Code:
  37
  38 (eval-when-compile (require 'cl))       ;and ah ain't kiddin' 'bout it
  39
  40 (defvar parse-time-syntax (make-vector 256 nil))
  41 (defvar parse-time-digits (make-vector 256 nil))
  42
  43 ;; Byte-compiler warnings
  44 (defvar parse-time-elt)
  45 (defvar parse-time-val)
  46
  47 (unless (aref parse-time-digits ?0)
  48   (loop for i from ?0 to ?9
  49     do (aset parse-time-digits i (- i ?0))))
  50
  51 (unless (aref parse-time-syntax ?0)
  52   (loop for i from ?0 to ?9
  53     do (aset parse-time-syntax i ?0))
  54   (loop for i from ?A to ?Z
  55     do (aset parse-time-syntax i ?A))
  56   (loop for i from ?a to ?z
  57     do (aset parse-time-syntax i ?a))
  58   (aset parse-time-syntax ?+ 1)
  59   (aset parse-time-syntax ?- -1)
  60   (aset parse-time-syntax ?: ?d)
  61   )
  62
  63 (defsubst digit-char-p (char)
  64   (aref parse-time-digits char))
  65
  66 (defsubst parse-time-string-chars (char)
  67   (and (< char (length parse-time-syntax))
  68        (aref parse-time-syntax char)))
  69
  70 (put 'parse-error 'error-conditions '(parse-error error))
  71 (put 'parse-error 'error-message "Parsing error")
  72
  73 (defsubst parse-integer (string &optional start end)
  74   "[CL] Parse and return the integer in STRING, or nil if none."
  75   (let ((integer 0)
  76         (digit 0)
  77         (index (or start 0))
  78         (end (or end (length string))))
  79     (when (< index end)
  80       (let ((sign (aref string index)))
  81         (if (or (eq sign ?+) (eq sign ?-))
  82             (setq sign (parse-time-string-chars sign)
  83                   index (1+ index))
  84           (setq sign 1))
  85         (while (and (< index end)
  86                     (setq digit (digit-char-p (aref string index))))
  87           (setq integer (+ (* integer 10) digit)
  88                 index (1+ index)))
  89         (if (/= index end)
  90             (signal 'parse-error `("not an integer"
  91                                    ,(substring string (or start 0) end)))
  92           (* sign integer))))))
  93
  94 (defun parse-time-tokenize (string)
  95   "Tokenize STRING into substrings."
  96   (let ((start nil)
  97         (end (length string))
  98         (all-digits nil)
  99         (list ())
 100         (index 0)
 101         (c nil))
 102     (while (< index end)
 103       (while (and (< index end)         ;skip invalid characters
 104                   (not (setq c (parse-time-string-chars (aref string index)))))
 105         (incf index))
 106       (setq start index all-digits (eq c ?0))
 107       (while (and (< (incf index) end)  ;scan valid characters
 108                   (setq c (parse-time-string-chars (aref string index))))
 109         (setq all-digits (and all-digits (eq c ?0))))
 110       (if (<= index end)
 111           (push (if all-digits (parse-integer string start index)
 112                   (substring string start index))
 113                 list)))
 114     (nreverse list)))
 115
 116 (defvar parse-time-months '(("jan" . 1) ("feb" . 2) ("mar" . 3)
 117                             ("apr" . 4) ("may" . 5) ("jun" . 6)
 118                             ("jul" . 7) ("aug" . 8) ("sep" . 9)
 119                             ("oct" . 10) ("nov" . 11) ("dec" . 12)))
 120 (defvar parse-time-weekdays '(("sun" . 0) ("mon" . 1) ("tue" . 2)
 121                               ("wed" . 3) ("thu" . 4) ("fri" . 5) ("sat" . 6)))
 122 (defvar parse-time-zoneinfo `(("z" 0) ("ut" 0) ("gmt" 0)
 123                               ("pst" ,(* -8 3600)) ("pdt" ,(* -7 3600) t)
 124                               ("mst" ,(* -7 3600)) ("mdt" ,(* -6 3600) t)
 125                               ("cst" ,(* -6 3600)) ("cdt" ,(* -5 3600) t)
 126                               ("est" ,(* -5 3600)) ("edt" ,(* -4 3600) t))
 127   "(zoneinfo seconds-off daylight-savings-time-p)")
 128
 129 (defvar parse-time-rules
 130   `(((6) parse-time-weekdays)
 131     ((3) (1 31))
 132     ((4) parse-time-months)
 133     ((5) (100 4038))
 134     ((2 1 0)
 135      ,#'(lambda () (and (stringp parse-time-elt)
 136                         (= (length parse-time-elt) 8)
 137                         (= (aref parse-time-elt 2) ?:)
 138                         (= (aref parse-time-elt 5) ?:)))
 139      [0 2] [3 5] [6 8])
 140     ((8 7) parse-time-zoneinfo
 141      ,#'(lambda () (car parse-time-val))
 142      ,#'(lambda () (cadr parse-time-val)))
 143     ((8)
 144      ,#'(lambda ()
 145           (and (stringp parse-time-elt)
 146                (= 5 (length parse-time-elt))
 147                (or (= (aref parse-time-elt 0) ?+)
 148                    (= (aref parse-time-elt 0) ?-))))
 149      ,#'(lambda () (* 60 (+ (parse-integer parse-time-elt 3 5)
 150                             (* 60 (parse-integer parse-time-elt 1 3)))
 151                       (if (= (aref parse-time-elt 0) ?-) -1 1))))
 152     ((5 4 3)
 153      ,#'(lambda () (and (stringp parse-time-elt)
 154                         (= (length parse-time-elt) 10)
 155                         (= (aref parse-time-elt 4) ?-)
 156                         (= (aref parse-time-elt 7) ?-)))
 157      [0 4] [5 7] [8 10])
 158     ((2 1 0)
 159      ,#'(lambda () (and (stringp parse-time-elt)
 160                         (= (length parse-time-elt) 5)
 161                         (= (aref parse-time-elt 2) ?:)))
 162      [0 2] [3 5] ,#'(lambda () 0))
 163     ((2 1 0)
 164      ,#'(lambda () (and (stringp parse-time-elt)
 165                         (= (length parse-time-elt) 4)
 166                         (= (aref parse-time-elt 1) ?:)))
 167      [0 1] [2 4] ,#'(lambda () 0))
 168     ((2 1 0)
 169      ,#'(lambda () (and (stringp parse-time-elt)
 170                         (= (length parse-time-elt) 7)
 171                         (= (aref parse-time-elt 1) ?:)))
 172      [0 1] [2 4] [5 7])
 173     ((5) (50 110) ,#'(lambda () (+ 1900 parse-time-elt)))
 174     ((5) (0 49) ,#'(lambda () (+ 2000 parse-time-elt))))
 175   "(slots predicate extractor...)")
 176
 177 ;;;###autoload
 178 (defun parse-time-string (string)
 179   "Parse the time-string STRING into (SEC MIN HOUR DAY MON YEAR DOW DST TZ).
 180 The values are identical to those of `decode-time', but any values that are
 181 unknown are returned as nil."
 182   (let ((time (list nil nil nil nil nil nil nil nil nil))
 183         (temp (parse-time-tokenize (downcase string))))
 184     (while temp
 185       (let ((parse-time-elt (pop temp))
 186             (rules parse-time-rules)
 187             (exit nil))
 188         (while (and rules (not exit))
 189           (let* ((rule (pop rules))
 190                  (slots (pop rule))
 191                  (predicate (pop rule))
 192                  (parse-time-val))
 193             (when (and (not (nth (car slots) time)) ;not already set
 194                        (setq parse-time-val (cond ((and (consp predicate)
 195                                              (not (eq (car predicate)
 196                                                       'lambda)))
 197                                         (and (numberp parse-time-elt)
 198                                              (<= (car predicate) parse-time-elt)
 199                                              (<= parse-time-elt (cadr predicate))
 200                                              parse-time-elt))
 201                                        ((symbolp predicate)
 202                                         (cdr (assoc parse-time-elt
 203                                                     (symbol-value predicate))))
 204                                        ((funcall predicate)))))
 205               (setq exit t)
 206               (while slots
 207                 (let ((new-val (and rule
 208                                     (let ((this (pop rule)))
 209                                       (if (vectorp this)
 210                                           (parse-integer
 211                                            parse-time-elt
 212                                            (aref this 0) (aref this 1))
 213                                         (funcall this))))))
 214                   (rplaca (nthcdr (pop slots) time)
 215                           (or new-val parse-time-val)))))))))
 216     time))
 217
 218 (provide 'parse-time)
 219
 220 ;; arch-tag: 07066094-45a8-4c68-b307-86195e2c1103
 221 ;;; parse-time.el ends here