cgit.sxemacs.org Git - gnus/blob - lisp/parse-time.el

   1 ;;; parse-time.el --- parsing time strings
   2
   3 ;; Copyright (C) 1996, 2000-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Erik Naggum <erik@naggum.no>
   6 ;; Keywords: util
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; With the introduction of the `encode-time', `decode-time', and
  26 ;; `format-time-string' functions, dealing with time became simpler in
  27 ;; Emacs.  However, parsing time strings is still largely a matter of
  28 ;; heuristics and no common interface has been designed.
  29
  30 ;; `parse-time-string' parses a time in a string and returns a list of 9
  31 ;; values, just like `decode-time', where unspecified elements in the
  32 ;; string are returned as nil.  `encode-time' may be applied on these
  33 ;; values to obtain an internal time value.
  34
  35 ;;; Code:
  36
  37 (eval-when-compile (require 'cl))       ;and ah ain't kiddin' 'bout it
  38
  39 (eval-and-compile
  40   (when (featurep 'xemacs)
  41     (defvar parse-time-syntax (make-vector 256 nil))))
  42 (defvar parse-time-digits (make-vector 256 nil))
  43
  44 ;; Byte-compiler warnings
  45 (defvar parse-time-elt)
  46 (defvar parse-time-val)
  47
  48 (unless (aref parse-time-digits ?0)
  49   (loop for i from ?0 to ?9
  50     do (aset parse-time-digits i (- i ?0))))
  51
  52 (when (featurep 'xemacs)
  53   (unless (aref parse-time-syntax ?0)
  54     (loop for i from ?0 to ?9
  55           do (aset parse-time-syntax i ?0))
  56     (loop for i from ?A to ?Z
  57           do (aset parse-time-syntax i ?A))
  58     (loop for i from ?a to ?z
  59           do (aset parse-time-syntax i ?a))
  60     (aset parse-time-syntax ?+ 1)
  61     (aset parse-time-syntax ?- -1)
  62     (aset parse-time-syntax ?: ?d)))
  63
  64 (defsubst digit-char-p (char)
  65   (aref parse-time-digits char))
  66
  67 (eval-and-compile
  68   (if (featurep 'xemacs)
  69       (defsubst parse-time-string-chars (char)
  70         (and (< char (length parse-time-syntax))
  71              (aref parse-time-syntax char)))
  72     (defsubst parse-time-string-chars (char)
  73       (save-match-data
  74         (let (case-fold-search str)
  75           (cond ((eq char ?+) 1)
  76                 ((eq char ?-) -1)
  77                 ((eq char ?:) ?d)
  78                 ((string-match "[[:upper:]]" (setq str (string char))) ?A)
  79                 ((string-match "[[:lower:]]" str) ?a)
  80                 ((string-match "[[:digit:]]" str) ?0)))))))
  81
  82 (put 'parse-error 'error-conditions '(parse-error error))
  83 (put 'parse-error 'error-message "Parsing error")
  84
  85 (defsubst parse-integer (string &optional start end)
  86   "[CL] Parse and return the integer in STRING, or nil if none."
  87   (let ((integer 0)
  88         (digit 0)
  89         (index (or start 0))
  90         (end (or end (length string))))
  91     (when (< index end)
  92       (let ((sign (aref string index)))
  93         (if (or (eq sign ?+) (eq sign ?-))
  94             (setq sign (parse-time-string-chars sign)
  95                   index (1+ index))
  96           (setq sign 1))
  97         (while (and (< index end)
  98                     (setq digit (digit-char-p (aref string index))))
  99           (setq integer (+ (* integer 10) digit)
 100                 index (1+ index)))
 101         (if (/= index end)
 102             (signal 'parse-error `("not an integer"
 103                                    ,(substring string (or start 0) end)))
 104           (* sign integer))))))
 105
 106 (defun parse-time-tokenize (string)
 107   "Tokenize STRING into substrings."
 108   (let ((start nil)
 109         (end (length string))
 110         (all-digits nil)
 111         (list ())
 112         (index 0)
 113         (c nil))
 114     (while (< index end)
 115       (while (and (< index end)         ;Skip invalid characters.
 116                   (not (setq c (parse-time-string-chars (aref string index)))))
 117         (incf index))
 118       (setq start index all-digits (eq c ?0))
 119       (while (and (< (incf index) end)  ;Scan valid characters.
 120                   (setq c (parse-time-string-chars (aref string index))))
 121         (setq all-digits (and all-digits (eq c ?0))))
 122       (if (<= index end)
 123           (push (if all-digits (parse-integer string start index)
 124                   (substring string start index))
 125                 list)))
 126     (nreverse list)))
 127
 128 (defvar parse-time-months '(("jan" . 1) ("feb" . 2) ("mar" . 3)
 129                             ("apr" . 4) ("may" . 5) ("jun" . 6)
 130                             ("jul" . 7) ("aug" . 8) ("sep" . 9)
 131                             ("oct" . 10) ("nov" . 11) ("dec" . 12)
 132                             ("january" . 1) ("february" . 2)
 133                             ("march" . 3) ("april" . 4) ("june" . 6)
 134                             ("july" . 7) ("august" . 8)
 135                             ("september" . 9) ("october" . 10)
 136                             ("november" . 11) ("december" . 12)))
 137 (defvar parse-time-weekdays '(("sun" . 0) ("mon" . 1) ("tue" . 2)
 138                               ("wed" . 3) ("thu" . 4) ("fri" . 5)
 139                               ("sat" . 6) ("sunday" . 0) ("monday" . 1)
 140                               ("tuesday" . 2) ("wednesday" . 3)
 141                               ("thursday" . 4) ("friday" . 5)
 142                               ("saturday" . 6)))
 143 (defvar parse-time-zoneinfo `(("z" 0) ("ut" 0) ("gmt" 0)
 144                               ("pst" ,(* -8 3600)) ("pdt" ,(* -7 3600) t)
 145                               ("mst" ,(* -7 3600)) ("mdt" ,(* -6 3600) t)
 146                               ("cst" ,(* -6 3600)) ("cdt" ,(* -5 3600) t)
 147                               ("est" ,(* -5 3600)) ("edt" ,(* -4 3600) t))
 148   "(zoneinfo seconds-off daylight-savings-time-p)")
 149
 150 (defvar parse-time-rules
 151   `(((6) parse-time-weekdays)
 152     ((3) (1 31))
 153     ((4) parse-time-months)
 154     ((5) (100 4038))
 155     ((2 1 0)
 156      ,#'(lambda () (and (stringp parse-time-elt)
 157                         (= (length parse-time-elt) 8)
 158                         (= (aref parse-time-elt 2) ?:)
 159                         (= (aref parse-time-elt 5) ?:)))
 160      [0 2] [3 5] [6 8])
 161     ((8 7) parse-time-zoneinfo
 162      ,#'(lambda () (car parse-time-val))
 163      ,#'(lambda () (cadr parse-time-val)))
 164     ((8)
 165      ,#'(lambda ()
 166           (and (stringp parse-time-elt)
 167                (= 5 (length parse-time-elt))
 168                (or (= (aref parse-time-elt 0) ?+)
 169                    (= (aref parse-time-elt 0) ?-))))
 170      ,#'(lambda () (* 60 (+ (parse-integer parse-time-elt 3 5)
 171                             (* 60 (parse-integer parse-time-elt 1 3)))
 172                       (if (= (aref parse-time-elt 0) ?-) -1 1))))
 173     ((5 4 3)
 174      ,#'(lambda () (and (stringp parse-time-elt)
 175                         (= (length parse-time-elt) 10)
 176                         (= (aref parse-time-elt 4) ?-)
 177                         (= (aref parse-time-elt 7) ?-)))
 178      [0 4] [5 7] [8 10])
 179     ((2 1 0)
 180      ,#'(lambda () (and (stringp parse-time-elt)
 181                         (= (length parse-time-elt) 5)
 182                         (= (aref parse-time-elt 2) ?:)))
 183      [0 2] [3 5] ,#'(lambda () 0))
 184     ((2 1 0)
 185      ,#'(lambda () (and (stringp parse-time-elt)
 186                         (= (length parse-time-elt) 4)
 187                         (= (aref parse-time-elt 1) ?:)))
 188      [0 1] [2 4] ,#'(lambda () 0))
 189     ((2 1 0)
 190      ,#'(lambda () (and (stringp parse-time-elt)
 191                         (= (length parse-time-elt) 7)
 192                         (= (aref parse-time-elt 1) ?:)))
 193      [0 1] [2 4] [5 7])
 194     ((5) (50 110) ,#'(lambda () (+ 1900 parse-time-elt)))
 195     ((5) (0 49) ,#'(lambda () (+ 2000 parse-time-elt))))
 196   "(slots predicate extractor...)")
 197 ;;;###autoload(put 'parse-time-rules 'risky-local-variable t)
 198
 199 ;;;###autoload
 200 (defun parse-time-string (string)
 201   "Parse the time-string STRING into (SEC MIN HOUR DAY MON YEAR DOW DST TZ).
 202 The values are identical to those of `decode-time', but any values that are
 203 unknown are returned as nil."
 204   (let ((time (list nil nil nil nil nil nil nil nil nil))
 205         (temp (parse-time-tokenize (downcase string))))
 206     (while temp
 207       (let ((parse-time-elt (pop temp))
 208             (rules parse-time-rules)
 209             (exit nil))
 210         (while (and rules (not exit))
 211           (let* ((rule (pop rules))
 212                  (slots (pop rule))
 213                  (predicate (pop rule))
 214                  (parse-time-val))
 215             (when (and (not (nth (car slots) time)) ;not already set
 216                        (setq parse-time-val
 217                              (cond ((and (consp predicate)
 218                                          (not (eq (car predicate)
 219                                                   'lambda)))
 220                                     (and (numberp parse-time-elt)
 221                                          (<= (car predicate) parse-time-elt)
 222                                          (<= parse-time-elt (cadr predicate))
 223                                          parse-time-elt))
 224                                    ((symbolp predicate)
 225                                     (cdr (assoc parse-time-elt
 226                                                 (symbol-value predicate))))
 227                                    ((funcall predicate)))))
 228               (setq exit t)
 229               (while slots
 230                 (let ((new-val (if rule
 231                                    (let ((this (pop rule)))
 232                                      (if (vectorp this)
 233                                          (parse-integer
 234                                           parse-time-elt
 235                                           (aref this 0) (aref this 1))
 236                                        (funcall this)))
 237                                  parse-time-val)))
 238                   (rplaca (nthcdr (pop slots) time) new-val))))))))
 239     time))
 240
 241 (defconst parse-time-iso8601-regexp
 242   (let* ((dash "-?")
 243          (colon ":?")
 244          (4digit "\\([0-9][0-9][0-9][0-9]\\)")
 245          (2digit "\\([0-9][0-9]\\)")
 246          (date-fullyear 4digit)
 247          (date-month 2digit)
 248          (date-mday 2digit)
 249          (time-hour 2digit)
 250          (time-minute 2digit)
 251          (time-second 2digit)
 252          (time-secfrac "\\(\\.[0-9]+\\)?")
 253          (time-numoffset (concat "[-+]\\(" time-hour "\\):" time-minute))
 254          (time-offset (concat "Z" time-numoffset))
 255          (partial-time (concat time-hour colon time-minute colon time-second
 256                                time-secfrac))
 257          (full-date (concat date-fullyear dash date-month dash date-mday))
 258          (full-time (concat partial-time time-offset))
 259          (date-time (concat full-date "T" full-time)))
 260     (list (concat "^" full-date)
 261           (concat "T" partial-time)
 262           (concat "Z" time-numoffset)))
 263   "List of regular expressions matching ISO 8601 dates.
 264 1st regular expression matches the date.
 265 2nd regular expression matches the time.
 266 3rd regular expression matches the (optional) timezone specification.")
 267
 268 (defun parse-iso8601-time-string (date-string)
 269   (let* ((date-re (nth 0 parse-time-iso8601-regexp))
 270          (time-re (nth 1 parse-time-iso8601-regexp))
 271          (tz-re (nth 2 parse-time-iso8601-regexp))
 272          re-start
 273          time seconds minute hour fractional-seconds
 274          day month year day-of-week dst tz)
 275     ;; We need to populate 'time' with
 276     ;; (SEC MIN HOUR DAY MON YEAR DOW DST TZ)
 277
 278     ;; Nobody else handles iso8601 correctly, let's do it ourselves.
 279     (when (string-match date-re date-string re-start)
 280       (setq year (string-to-number (match-string 1 date-string))
 281             month (string-to-number (match-string 2 date-string))
 282             day (string-to-number (match-string 3 date-string))
 283             re-start (match-end 0))
 284       (when (string-match time-re date-string re-start)
 285         (setq hour (string-to-number (match-string 1 date-string))
 286               minute (string-to-number (match-string 2 date-string))
 287               seconds (string-to-number (match-string 3 date-string))
 288               fractional-seconds (string-to-number (or
 289                                                     (match-string 4 date-string)
 290                                                     "0"))
 291               re-start (match-end 0))
 292         (when (string-match tz-re date-string re-start)
 293           (setq tz (match-string 1 date-string)))
 294         (setq time (list seconds minute hour day month year day-of-week dst tz))))
 295
 296     ;; Fall back to having Gnus do fancy things for us.
 297     (when (not time)
 298       (setq time (parse-time-string date-string)))
 299
 300     (and time
 301          (apply 'encode-time time))))
 302
 303 (provide 'parse-time)
 304
 305 ;;; parse-time.el ends here