392aff2406fbaa46c28f693203136393d7c92a1e
[gnus] / lisp / parse-time.el
1 ;;; parse-time.el --- parsing time strings
2
3 ;; Copyright (C) 1996, 2000-2014 Free Software Foundation, Inc.
4
5 ;; Author: Erik Naggum <erik@naggum.no>
6 ;; Keywords: util
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22
23 ;;; Commentary:
24
25 ;; With the introduction of the `encode-time', `decode-time', and
26 ;; `format-time-string' functions, dealing with time became simpler in
27 ;; Emacs.  However, parsing time strings is still largely a matter of
28 ;; heuristics and no common interface has been designed.
29
30 ;; `parse-time-string' parses a time in a string and returns a list of 9
31 ;; values, just like `decode-time', where unspecified elements in the
32 ;; string are returned as nil.  `encode-time' may be applied on these
33 ;; values to obtain an internal time value.
34
35 ;;; Code:
36
37 (eval-and-compile
38   (ignore-errors (require 'cl-lib))
39   (if (featurep 'cl-lib)
40       ;; Emacs >=24
41       (defalias 'parse-time-incf 'cl-incf)
42     (require 'cl)
43     (defalias 'parse-time-incf 'incf)))
44
45 ;; Byte-compiler warnings
46 (defvar parse-time-elt)
47 (defvar parse-time-val)
48
49 (eval-and-compile
50   (if (featurep 'xemacs)
51       (progn
52         (defvar parse-time-syntax (make-vector 256 nil))
53         (loop for i from ?0 to ?9
54               do (aset parse-time-syntax i ?0))
55         (loop for i from ?A to ?Z
56               do (aset parse-time-syntax i ?A))
57         (loop for i from ?a to ?z
58               do (aset parse-time-syntax i ?a))
59         (aset parse-time-syntax ?+ 1)
60         (aset parse-time-syntax ?- -1)
61         (aset parse-time-syntax ?: ?d)
62         (defsubst parse-time-string-chars (char)
63           (and (< char (length parse-time-syntax))
64                (aref parse-time-syntax char))))
65     (defsubst parse-time-string-chars (char)
66       (save-match-data
67         (let (case-fold-search str)
68           (cond ((eq char ?+) 1)
69                 ((eq char ?-) -1)
70                 ((eq char ?:) ?d)
71                 ((string-match "[[:upper:]]" (setq str (string char))) ?A)
72                 ((string-match "[[:lower:]]" str) ?a)
73                 ((string-match "[[:digit:]]" str) ?0)))))))
74
75 (eval-and-compile
76   (if (fboundp 'cl-parse-integer)
77       (defalias 'parse-time-integer 'cl-parse-integer)
78     (defvar parse-time-digits (make-vector 256 nil))
79     (loop for i from ?0 to ?9
80           do (aset parse-time-digits i (- i ?0)))
81     (defun parse-time-integer (string &rest keys)
82       "[CL] Parse and return the integer in STRING, or nil if none."
83       (let* ((start (plist-get keys :start))
84              (end (or (plist-get keys :end) (length string)))
85              (integer 0)
86              (digit 0)
87              (index (or start 0)))
88         (when (< index end)
89           (let ((sign (aref string index)))
90             (if (or (eq sign ?+) (eq sign ?-))
91                 (setq sign (parse-time-string-chars sign)
92                       index (1+ index))
93               (setq sign 1))
94             (while (and (< index end)
95                         (setq digit (aref parse-time-digits
96                                           (aref string index))))
97               (setq integer (+ (* integer 10) digit)
98                     index (1+ index)))
99             (if (/= index end)
100                 (error "Not an integer string: `%s'" string)
101               (* sign integer))))))))
102
103 (defun parse-time-tokenize (string)
104   "Tokenize STRING into substrings."
105   (let ((start nil)
106         (end (length string))
107         (all-digits nil)
108         (list ())
109         (index 0)
110         (c nil))
111     (while (< index end)
112       (while (and (< index end)         ;Skip invalid characters.
113                   (not (setq c (parse-time-string-chars (aref string index)))))
114         (parse-time-incf index))
115       (setq start index all-digits (eq c ?0))
116       (while (and (< (parse-time-incf index) end) ;Scan valid characters.
117                   (setq c (parse-time-string-chars (aref string index))))
118         (setq all-digits (and all-digits (eq c ?0))))
119       (if (<= index end)
120           (push (if all-digits (parse-time-integer string
121                                                    :start start :end index)
122                   (substring string start index))
123                 list)))
124     (nreverse list)))
125
126 (defvar parse-time-months '(("jan" . 1) ("feb" . 2) ("mar" . 3)
127                             ("apr" . 4) ("may" . 5) ("jun" . 6)
128                             ("jul" . 7) ("aug" . 8) ("sep" . 9)
129                             ("oct" . 10) ("nov" . 11) ("dec" . 12)
130                             ("january" . 1) ("february" . 2)
131                             ("march" . 3) ("april" . 4) ("june" . 6)
132                             ("july" . 7) ("august" . 8)
133                             ("september" . 9) ("october" . 10)
134                             ("november" . 11) ("december" . 12)))
135 (defvar parse-time-weekdays '(("sun" . 0) ("mon" . 1) ("tue" . 2)
136                               ("wed" . 3) ("thu" . 4) ("fri" . 5)
137                               ("sat" . 6) ("sunday" . 0) ("monday" . 1)
138                               ("tuesday" . 2) ("wednesday" . 3)
139                               ("thursday" . 4) ("friday" . 5)
140                               ("saturday" . 6)))
141 (defvar parse-time-zoneinfo `(("z" 0) ("ut" 0) ("gmt" 0)
142                               ("pst" ,(* -8 3600)) ("pdt" ,(* -7 3600) t)
143                               ("mst" ,(* -7 3600)) ("mdt" ,(* -6 3600) t)
144                               ("cst" ,(* -6 3600)) ("cdt" ,(* -5 3600) t)
145                               ("est" ,(* -5 3600)) ("edt" ,(* -4 3600) t))
146   "(zoneinfo seconds-off daylight-savings-time-p)")
147
148 (defvar parse-time-rules
149   `(((6) parse-time-weekdays)
150     ((3) (1 31))
151     ((4) parse-time-months)
152     ((5) (100 ,most-positive-fixnum))
153     ((2 1 0)
154      ,#'(lambda () (and (stringp parse-time-elt)
155                         (= (length parse-time-elt) 8)
156                         (= (aref parse-time-elt 2) ?:)
157                         (= (aref parse-time-elt 5) ?:)))
158      [0 2] [3 5] [6 8])
159     ((8 7) parse-time-zoneinfo
160      ,#'(lambda () (car parse-time-val))
161      ,#'(lambda () (cadr parse-time-val)))
162     ((8)
163      ,#'(lambda ()
164           (and (stringp parse-time-elt)
165                (= 5 (length parse-time-elt))
166                (or (= (aref parse-time-elt 0) ?+)
167                    (= (aref parse-time-elt 0) ?-))))
168      ,#'(lambda () (* 60 (+ (parse-time-integer parse-time-elt :start 3 :end 5)
169                             (* 60 (parse-time-integer parse-time-elt
170                                                       :start 1 :end 3)))
171                       (if (= (aref parse-time-elt 0) ?-) -1 1))))
172     ((5 4 3)
173      ,#'(lambda () (and (stringp parse-time-elt)
174                         (= (length parse-time-elt) 10)
175                         (= (aref parse-time-elt 4) ?-)
176                         (= (aref parse-time-elt 7) ?-)))
177      [0 4] [5 7] [8 10])
178     ((2 1 0)
179      ,#'(lambda () (and (stringp parse-time-elt)
180                         (= (length parse-time-elt) 5)
181                         (= (aref parse-time-elt 2) ?:)))
182      [0 2] [3 5] ,#'(lambda () 0))
183     ((2 1 0)
184      ,#'(lambda () (and (stringp parse-time-elt)
185                         (= (length parse-time-elt) 4)
186                         (= (aref parse-time-elt 1) ?:)))
187      [0 1] [2 4] ,#'(lambda () 0))
188     ((2 1 0)
189      ,#'(lambda () (and (stringp parse-time-elt)
190                         (= (length parse-time-elt) 7)
191                         (= (aref parse-time-elt 1) ?:)))
192      [0 1] [2 4] [5 7])
193     ((5) (50 110) ,#'(lambda () (+ 1900 parse-time-elt)))
194     ((5) (0 49) ,#'(lambda () (+ 2000 parse-time-elt))))
195   "(slots predicate extractor...)")
196 ;;;###autoload(put 'parse-time-rules 'risky-local-variable t)
197
198 ;;;###autoload
199 (defun parse-time-string (string)
200   "Parse the time-string STRING into (SEC MIN HOUR DAY MON YEAR DOW DST TZ).
201 The values are identical to those of `decode-time', but any values that are
202 unknown are returned as nil."
203   (let ((time (list nil nil nil nil nil nil nil nil nil))
204         (temp (parse-time-tokenize (downcase string))))
205     (while temp
206       (let ((parse-time-elt (pop temp))
207             (rules parse-time-rules)
208             (exit nil))
209         (while (and rules (not exit))
210           (let* ((rule (pop rules))
211                  (slots (pop rule))
212                  (predicate (pop rule))
213                  (parse-time-val))
214             (when (and (not (nth (car slots) time)) ;not already set
215                        (setq parse-time-val
216                              (cond ((and (consp predicate)
217                                          (not (eq (car predicate)
218                                                   'lambda)))
219                                     (and (numberp parse-time-elt)
220                                          (<= (car predicate) parse-time-elt)
221                                          (<= parse-time-elt (cadr predicate))
222                                          parse-time-elt))
223                                    ((symbolp predicate)
224                                     (cdr (assoc parse-time-elt
225                                                 (symbol-value predicate))))
226                                    ((funcall predicate)))))
227               (setq exit t)
228               (while slots
229                 (let ((new-val (if rule
230                                    (let ((this (pop rule)))
231                                      (if (vectorp this)
232                                          (parse-time-integer
233                                           parse-time-elt
234                                           :start (aref this 0)
235                                           :end (aref this 1))
236                                        (funcall this)))
237                                  parse-time-val)))
238                   (rplaca (nthcdr (pop slots) time) new-val))))))))
239     time))
240
241 (defconst parse-time-iso8601-regexp
242   (let* ((dash "-?")
243          (colon ":?")
244          (4digit "\\([0-9][0-9][0-9][0-9]\\)")
245          (2digit "\\([0-9][0-9]\\)")
246          (date-fullyear 4digit)
247          (date-month 2digit)
248          (date-mday 2digit)
249          (time-hour 2digit)
250          (time-minute 2digit)
251          (time-second 2digit)
252          (time-secfrac "\\(\\.[0-9]+\\)?")
253          (time-numoffset (concat "[-+]\\(" time-hour "\\):" time-minute))
254          (time-offset (concat "Z" time-numoffset))
255          (partial-time (concat time-hour colon time-minute colon time-second
256                                time-secfrac))
257          (full-date (concat date-fullyear dash date-month dash date-mday))
258          (full-time (concat partial-time time-offset))
259          (date-time (concat full-date "T" full-time)))
260     (list (concat "^" full-date)
261           (concat "T" partial-time)
262           (concat "Z" time-numoffset)))
263   "List of regular expressions matching ISO 8601 dates.
264 1st regular expression matches the date.
265 2nd regular expression matches the time.
266 3rd regular expression matches the (optional) timezone specification.")
267
268 (defun parse-iso8601-time-string (date-string)
269   (let* ((date-re (nth 0 parse-time-iso8601-regexp))
270          (time-re (nth 1 parse-time-iso8601-regexp))
271          (tz-re (nth 2 parse-time-iso8601-regexp))
272          re-start
273          time seconds minute hour fractional-seconds
274          day month year day-of-week dst tz)
275     ;; We need to populate 'time' with
276     ;; (SEC MIN HOUR DAY MON YEAR DOW DST TZ)
277
278     ;; Nobody else handles iso8601 correctly, let's do it ourselves.
279     (when (string-match date-re date-string re-start)
280       (setq year (string-to-number (match-string 1 date-string))
281             month (string-to-number (match-string 2 date-string))
282             day (string-to-number (match-string 3 date-string))
283             re-start (match-end 0))
284       (when (string-match time-re date-string re-start)
285         (setq hour (string-to-number (match-string 1 date-string))
286               minute (string-to-number (match-string 2 date-string))
287               seconds (string-to-number (match-string 3 date-string))
288               fractional-seconds (string-to-number (or
289                                                     (match-string 4 date-string)
290                                                     "0"))
291               re-start (match-end 0))
292         (when (string-match tz-re date-string re-start)
293           (setq tz (match-string 1 date-string)))
294         (setq time (list seconds minute hour day month year day-of-week dst tz))))
295
296     ;; Fall back to having Gnus do fancy things for us.
297     (when (not time)
298       (setq time (parse-time-string date-string)))
299
300     (and time
301          (apply 'encode-time time))))
302
303 (provide 'parse-time)
304
305 ;;; parse-time.el ends here