cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: David Moore <dmoore@ucsd.edu>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; The other access methods (nntp, nnspool, etc) are general news
  31 ;; access methods.  This module relies on Gnus and can not be used
  32 ;; separately.
  33
  34 ;;; Code:
  35
  36 (require 'nntp)
  37 (require 'nnheader)
  38 (require 'gnus)
  39 (require 'nnoo)
  40 (require 'gnus-util)
  41 (require 'gnus-start)
  42 (require 'gnus-sum)
  43 (require 'gnus-msg)
  44 (eval-when-compile (require 'cl))
  45
  46 (nnoo-declare nnvirtual)
  47
  48 (defvoo nnvirtual-always-rescan t
  49   "If non-nil, always scan groups for unread articles when entering a group.
  50 If this variable is nil and you read articles in a component group
  51 after the virtual group has been activated, the read articles from the
  52 component group will show up when you enter the virtual group.")
  53
  54 (defvoo nnvirtual-component-regexp nil
  55   "Regexp to match component groups.")
  56
  57 (defvoo nnvirtual-component-groups nil
  58   "Component group in this nnvirtual group.")
  59
  60 \f
  61
  62 (defconst nnvirtual-version "nnvirtual 1.1")
  63
  64 (defvoo nnvirtual-current-group nil)
  65
  66 (defvoo nnvirtual-mapping-table nil
  67   "Table of rules on how to map between component group and article number to virtual article number.")
  68
  69 (defvoo nnvirtual-mapping-offsets nil
  70   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  71
  72 (defvoo nnvirtual-mapping-len 0
  73   "Number of articles in this virtual group.")
  74
  75 (defvoo nnvirtual-mapping-reads nil
  76   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  77
  78 (defvoo nnvirtual-mapping-marks nil
  79   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  80
  81 (defvoo nnvirtual-info-installed nil
  82   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  83
  84 (defvoo nnvirtual-status-string "")
  85
  86 (eval-and-compile
  87   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  88
  89 \f
  90
  91 ;;; Interface functions.
  92
  93 (nnoo-define-basics nnvirtual)
  94
  95
  96 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  97                                              server fetch-old)
  98   (when (nnvirtual-possibly-change-server server)
  99     (save-excursion
 100       (set-buffer nntp-server-buffer)
 101       (erase-buffer)
 102       (if (stringp (car articles))
 103           'headers
 104         (let ((vbuf (nnheader-set-temp-buffer
 105                      (get-buffer-create " *virtual headers*")))
 106               (carticles (nnvirtual-partition-sequence articles))
 107               (system-name (system-name))
 108               cgroup carticle article result prefix)
 109           (while carticles
 110             (setq cgroup (caar carticles))
 111             (setq articles (cdar carticles))
 112             (pop carticles)
 113             (when (and articles
 114                        (gnus-check-server
 115                         (gnus-find-method-for-group cgroup) t)
 116                        (gnus-request-group cgroup t)
 117                        (setq prefix (gnus-group-real-prefix cgroup))
 118                        ;; FIX FIX FIX we want to check the cache!
 119                        ;; This is probably evil if people have set
 120                        ;; gnus-use-cache to nil themselves, but I
 121                        ;; have no way of finding the true value of it.
 122                        (let ((gnus-use-cache t))
 123                          (setq result (gnus-retrieve-headers
 124                                        articles cgroup nil))))
 125               (set-buffer nntp-server-buffer)
 126               ;; If we got HEAD headers, we convert them into NOV
 127               ;; headers.  This is slow, inefficient and, come to think
 128               ;; of it, downright evil.  So sue me.  I couldn't be
 129               ;; bothered to write a header parse routine that could
 130               ;; parse a mixed HEAD/NOV buffer.
 131               (when (eq result 'headers)
 132                 (nnvirtual-convert-headers))
 133               (goto-char (point-min))
 134               (while (not (eobp))
 135                 (delete-region (point)
 136                                (progn
 137                                  (setq carticle (read nntp-server-buffer))
 138                                  (point)))
 139
 140                 ;; We remove this article from the articles list, if
 141                 ;; anything is left in the articles list after going through
 142                 ;; the entire buffer, then those articles have been
 143                 ;; expired or canceled, so we appropriately update the
 144                 ;; component group below.  They should be coming up
 145                 ;; generally in order, so this shouldn't be slow.
 146                 (setq articles (delq carticle articles))
 147
 148                 (setq article (nnvirtual-reverse-map-article cgroup carticle))
 149                 (if (null article)
 150                     ;; This line has no reverse mapping, that means it
 151                     ;; was an extra article reference returned by nntp.
 152                     (progn
 153                       (beginning-of-line)
 154                       (delete-region (point) (progn (forward-line 1) (point))))
 155                   ;; Otherwise insert the virtual article number,
 156                   ;; and clean up the xrefs.
 157                   (princ article nntp-server-buffer)
 158                   (nnvirtual-update-xref-header cgroup carticle
 159                                                 prefix system-name)
 160                   (forward-line 1))
 161                 )
 162
 163               (set-buffer vbuf)
 164               (goto-char (point-max))
 165               (insert-buffer-substring nntp-server-buffer))
 166             ;; Anything left in articles is expired or canceled.
 167             ;; Could be smart and not tell it about articles already known?
 168             (when articles
 169               (gnus-group-make-articles-read cgroup articles))
 170             )
 171
 172           ;; The headers are ready for reading, so they are inserted into
 173           ;; the nntp-server-buffer, which is where Gnus expects to find
 174           ;; them.
 175           (prog1
 176               (save-excursion
 177                 (set-buffer nntp-server-buffer)
 178                 (erase-buffer)
 179                 (insert-buffer-substring vbuf)
 180                 ;; FIX FIX FIX, we should be able to sort faster than
 181                 ;; this if needed, since each cgroup is sorted, we just
 182                 ;; need to merge
 183                 (sort-numeric-fields 1 (point-min) (point-max))
 184                 'nov)
 185             (kill-buffer vbuf)))))))
 186
 187
 188 (defvoo nnvirtual-last-accessed-component-group nil)
 189
 190 (deffoo nnvirtual-request-article (article &optional group server buffer)
 191   (when (nnvirtual-possibly-change-server server)
 192     (if (stringp article)
 193         ;; This is a fetch by Message-ID.
 194         (cond
 195          ((not nnvirtual-last-accessed-component-group)
 196           (nnheader-report
 197            'nnvirtual "Don't know what server to request from"))
 198          (t
 199           (save-excursion
 200             (when buffer
 201               (set-buffer buffer))
 202             (let* ((gnus-override-method nil)
 203                    (method (gnus-find-method-for-group
 204                             nnvirtual-last-accessed-component-group)))
 205               (funcall (gnus-get-function method 'request-article)
 206                        article nil (nth 1 method) buffer)))))
 207       ;; This is a fetch by number.
 208       (let* ((amap (nnvirtual-map-article article))
 209              (cgroup (car amap)))
 210         (cond
 211          ((not amap)
 212           (nnheader-report 'nnvirtual "No such article: %s" article))
 213          ((not (gnus-check-group cgroup))
 214           (nnheader-report
 215            'nnvirtual "Can't open server where %s exists" cgroup))
 216          ((not (gnus-request-group cgroup t))
 217           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 218          (t
 219           (setq nnvirtual-last-accessed-component-group cgroup)
 220           (if buffer
 221               (save-excursion
 222                 (set-buffer buffer)
 223                 ;; We bind this here to avoid double decoding.
 224                 (let ((gnus-article-decode-hook nil))
 225                   (gnus-request-article-this-buffer (cdr amap) cgroup)))
 226             (gnus-request-article (cdr amap) cgroup))))))))
 227
 228
 229 (deffoo nnvirtual-open-server (server &optional defs)
 230   (unless (assq 'nnvirtual-component-regexp defs)
 231     (push `(nnvirtual-component-regexp ,server)
 232           defs))
 233   (nnoo-change-server 'nnvirtual server defs)
 234   (if nnvirtual-component-groups
 235       t
 236     (setq nnvirtual-mapping-table nil
 237           nnvirtual-mapping-offsets nil
 238           nnvirtual-mapping-len 0
 239           nnvirtual-mapping-reads nil
 240           nnvirtual-mapping-marks nil
 241           nnvirtual-info-installed nil)
 242     (when nnvirtual-component-regexp
 243       ;; Go through the newsrc alist and find all component groups.
 244       (let ((newsrc (cdr gnus-newsrc-alist))
 245             group)
 246         (while (setq group (car (pop newsrc)))
 247           (when (string-match nnvirtual-component-regexp group) ; Match
 248             ;; Add this group to the list of component groups.
 249             (setq nnvirtual-component-groups
 250                   (cons group (delete group nnvirtual-component-groups)))))))
 251     (if (not nnvirtual-component-groups)
 252         (nnheader-report 'nnvirtual "No component groups: %s" server)
 253       t)))
 254
 255
 256 (deffoo nnvirtual-request-group (group &optional server dont-check)
 257   (nnvirtual-possibly-change-server server)
 258   (setq nnvirtual-component-groups
 259         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 260   (cond
 261    ((null nnvirtual-component-groups)
 262     (setq nnvirtual-current-group nil)
 263     (nnheader-report 'nnvirtual "No component groups in %s" group))
 264    (t
 265     (setq nnvirtual-current-group group)
 266     (when (or (not dont-check)
 267               nnvirtual-always-rescan)
 268       (nnvirtual-create-mapping)
 269       (when nnvirtual-always-rescan
 270         (nnvirtual-request-update-info
 271          (nnvirtual-current-group)
 272          (gnus-get-info (nnvirtual-current-group)))))
 273     (nnheader-insert "211 %d 1 %d %s\n"
 274                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 275
 276
 277 (deffoo nnvirtual-request-type (group &optional article)
 278   (if (not article)
 279       'unknown
 280     (if (numberp article)
 281         (let ((mart (nnvirtual-map-article article)))
 282           (if mart
 283               (gnus-request-type (car mart) (cdr mart))))
 284       (gnus-request-type
 285        nnvirtual-last-accessed-component-group nil))))
 286
 287 (deffoo nnvirtual-request-update-mark (group article mark)
 288   (let* ((nart (nnvirtual-map-article article))
 289          (cgroup (car nart)))
 290     (when (and nart
 291                (memq mark gnus-auto-expirable-marks)
 292                ;; The component group might be a virtual group.
 293                (= mark (gnus-request-update-mark cgroup (cdr nart) mark))
 294                (gnus-group-auto-expirable-p cgroup))
 295       (setq mark gnus-expirable-mark)))
 296   mark)
 297
 298
 299 (deffoo nnvirtual-close-group (group &optional server)
 300   (when (and (nnvirtual-possibly-change-server server)
 301              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 302     (nnvirtual-update-read-and-marked t t))
 303   t)
 304
 305
 306 (deffoo nnvirtual-request-list (&optional server)
 307   (nnheader-report 'nnvirtual "LIST is not implemented."))
 308
 309
 310 (deffoo nnvirtual-request-newgroups (date &optional server)
 311   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 312
 313
 314 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 315   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 316
 317
 318 (deffoo nnvirtual-request-update-info (group info &optional server)
 319   (when (and (nnvirtual-possibly-change-server server)
 320              (not nnvirtual-info-installed))
 321     ;; Install the precomputed lists atomically, so the virtual group
 322     ;; is not left in a half-way state in case of C-g.
 323     (gnus-atomic-progn
 324       (setcar (cddr info) nnvirtual-mapping-reads)
 325       (if (nthcdr 3 info)
 326           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 327         (when nnvirtual-mapping-marks
 328           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 329       (setq nnvirtual-info-installed t))
 330     t))
 331
 332
 333 (deffoo nnvirtual-catchup-group (group &optional server all)
 334   (when (and (nnvirtual-possibly-change-server server)
 335              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 336     ;; copy over existing marks first, in case they set anything
 337     (nnvirtual-update-read-and-marked nil nil)
 338     ;; do a catchup on all component groups
 339     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 340           (gnus-expert-user t))
 341       ;; Make sure all groups are activated.
 342       (mapc
 343        (lambda (g)
 344          (when (not (numberp (gnus-group-unread g)))
 345            (gnus-activate-group g)))
 346        nnvirtual-component-groups)
 347       (save-excursion
 348         (set-buffer gnus-group-buffer)
 349         (gnus-group-catchup-current nil all)))))
 350
 351
 352 (deffoo nnvirtual-find-group-art (group article)
 353   "Return the real group and article for virtual GROUP and ARTICLE."
 354   (nnvirtual-map-article article))
 355
 356
 357 (deffoo nnvirtual-request-post (&optional server)
 358   (if (not gnus-message-group-art)
 359       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 360     (let ((group (car (nnvirtual-find-group-art
 361                        (car gnus-message-group-art)
 362                        (cdr gnus-message-group-art)))))
 363       (gnus-request-post (gnus-find-method-for-group group)))))
 364
 365
 366 (deffoo nnvirtual-request-expire-articles (articles group
 367                                                     &optional server force)
 368   (nnvirtual-possibly-change-server server)
 369   (setq nnvirtual-component-groups
 370         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 371   (let (unexpired)
 372     (dolist (group nnvirtual-component-groups)
 373       (setq unexpired (nconc unexpired
 374                              (mapcar
 375                               #'(lambda (article)
 376                                   (nnvirtual-reverse-map-article
 377                                    group article))
 378                               (gnus-uncompress-range
 379                                (gnus-group-expire-articles-1 group))))))
 380     (sort (delq nil unexpired) '<)))
 381
 382 \f
 383 ;;; Internal functions.
 384
 385 (defun nnvirtual-convert-headers ()
 386   "Convert HEAD headers into NOV headers."
 387   (with-current-buffer nntp-server-buffer
 388     (let* ((dependencies (make-vector 100 0))
 389            (headers (gnus-get-newsgroup-headers dependencies)))
 390       (erase-buffer)
 391       (mapc 'nnheader-insert-nov headers))))
 392
 393
 394 (defun nnvirtual-update-xref-header (group article prefix system-name)
 395   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 396   ;; Move to beginning of Xref field, creating a slot if needed.
 397   (beginning-of-line)
 398   (looking-at
 399    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 400   (goto-char (match-end 0))
 401   (unless (search-forward "\t" (point-at-eol) 'move)
 402     (insert "\t"))
 403
 404   ;; Remove any spaces at the beginning of the Xref field.
 405   (while (eq (char-after (1- (point))) ? )
 406     (forward-char -1)
 407     (delete-char 1))
 408
 409   (insert "Xref: " system-name " " group ":")
 410   (princ article (current-buffer))
 411   (insert " ")
 412
 413   ;; If there were existing xref lines, clean them up to have the correct
 414   ;; component server prefix.
 415   (save-restriction
 416     (narrow-to-region (point)
 417                       (or (search-forward "\t" (point-at-eol) t)
 418                           (point-at-eol)))
 419     (goto-char (point-min))
 420     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 421       (replace-match "" t t))
 422     (goto-char (point-min))
 423     (when (re-search-forward
 424            (concat (regexp-quote (gnus-group-real-name group)) ":[0-9]+")
 425            nil t)
 426       (replace-match "" t t))
 427     (unless (eobp)
 428       (insert " ")
 429       (when (not (string= "" prefix))
 430         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 431           (save-excursion
 432             (goto-char (match-beginning 0))
 433             (insert prefix))))))
 434
 435   ;; Ensure a trailing \t.
 436   (end-of-line)
 437   (or (eq (char-after (1- (point))) ?\t)
 438       (insert ?\t)))
 439
 440
 441 (defun nnvirtual-possibly-change-server (server)
 442   (or (not server)
 443       (nnoo-current-server-p 'nnvirtual server)
 444       (nnvirtual-open-server server)))
 445
 446
 447 (defun nnvirtual-update-read-and-marked (read-p update-p)
 448   "Copy marks from the virtual group to the component groups.
 449 If READ-P is not nil, update the (un)read status of the components.
 450 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 451   (when nnvirtual-current-group
 452     (let ((unreads (and read-p
 453                         (nnvirtual-partition-sequence
 454                          (gnus-list-of-unread-articles
 455                           (nnvirtual-current-group)))))
 456           (type-marks
 457            (delq nil
 458                  (mapcar (lambda (ml)
 459                            (if (eq (car ml) 'score)
 460                                nil
 461                              (cons (car ml)
 462                                    (nnvirtual-partition-sequence (cdr ml)))))
 463                          (gnus-info-marks (gnus-get-info
 464                                            (nnvirtual-current-group))))))
 465           type groups info)
 466
 467       ;; Ok, atomically move all of the (un)read info, clear any old
 468       ;; marks, and move all of the current marks.  This way if someone
 469       ;; hits C-g, you won't leave the component groups in a half-way state.
 470       (progn
 471         ;; move (un)read
 472         ;; bind for workaround guns-update-read-articles
 473         (let ((gnus-newsgroup-active nil))
 474           (dolist (entry unreads)
 475             (gnus-update-read-articles (car entry) (cdr entry))))
 476
 477         ;; clear all existing marks on the component groups
 478         (dolist (group nnvirtual-component-groups)
 479           (when (and (setq info (gnus-get-info group))
 480                      (gnus-info-marks info))
 481             (gnus-info-set-marks
 482              info
 483              (if (assq 'score (gnus-info-marks info))
 484                  (list (assq 'score (gnus-info-marks info)))
 485                nil))))
 486
 487         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 488         ;; with data of an assq list with keys of component group names
 489         ;; and the articles which correspond to that key/group pair.
 490         (dolist (mark type-marks)
 491           (setq type (car mark))
 492           (setq groups (cdr mark))
 493           (dolist (carticles groups)
 494             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 495                                       nil t))))
 496
 497       ;; possibly update the display, it is really slow
 498       (when update-p
 499         (dolist (group nnvirtual-component-groups)
 500           (gnus-group-update-group group t))))))
 501
 502
 503 (defun nnvirtual-current-group ()
 504   "Return the prefixed name of the current nnvirtual group."
 505   (concat "nnvirtual:" nnvirtual-current-group))
 506
 507
 508
 509 ;;; This is currently O(kn^2) to merge n lists of length k.
 510 ;;; You could do it in O(knlogn), but we have a small n, and the
 511 ;;; overhead of the other approach is probably greater.
 512 (defun nnvirtual-merge-sorted-lists (&rest lists)
 513   "Merge many sorted lists of numbers."
 514   (if (null (cdr lists))
 515       (car lists)
 516     (sort (apply 'nconc lists) '<)))
 517
 518
 519 ;;; We map between virtual articles and real articles in a manner
 520 ;;; which keeps the size of the virtual active list the same as the
 521 ;;; sum of the component active lists.
 522
 523 ;;; To achieve fair mixing of the groups, the last article in each of
 524 ;;; N component groups will be in the last N articles in the virtual
 525 ;;; group.
 526
 527 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and
 528 ;;; 6-7 respectively, then the virtual article numbers look like:
 529 ;;;
 530 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 531 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 532
 533 ;;; To compute these mappings we generate a couple tables and then
 534 ;;; do some fast operations on them.  Tables for the example above:
 535 ;;;
 536 ;;; Offsets - [(A 0) (B -3) (C -1)]
 537 ;;;
 538 ;;;               a  b  c  d  e
 539 ;;; Mapping - ([  3  0  1  3  0 ]
 540 ;;;            [  6  3  2  9  3 ]
 541 ;;;            [  8  6  3 15  9 ])
 542 ;;;
 543 ;;; (note column 'e' is different in real algorithm, which is slightly
 544 ;;;  different than described here, but this gives you the methodology.)
 545 ;;;
 546 ;;; The basic idea is this, when going from component->virtual, apply
 547 ;;; the appropriate offset to the article number.  Then search the first
 548 ;;; column of the table for a row where 'a' is less than or equal to the
 549 ;;; modified number.  You can see that only group A can therefore go to
 550 ;;; the first row, groups A and B to the second, and all to the last.
 551 ;;; The third column of the table is telling us the number of groups
 552 ;;; which might be able to reach that row (it might increase by more than
 553 ;;; 1 if several groups have the same size).
 554 ;;; Then column 'b' provides an additional offset you apply when you have
 555 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 556 ;;; _position_ in the offset table.  The basic idea here is that on
 557 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 558 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 559 ;;; you apply a final offset from column 'e' to give the virtual article.
 560 ;;;
 561 ;;; Going the other direction, you instead search on column 'd' instead
 562 ;;; of 'a', and apply everything in reverse order.
 563
 564 ;;; Convert component -> virtual:
 565 ;;; set num = num - Offset(group)
 566 ;;; find first row in Mapping where num <= 'a'
 567 ;;; num = (num-'b')*c + Position(group) + 'e'
 568
 569 ;;; Convert virtual -> component:
 570 ;;; find first row in Mapping where num <= 'd'
 571 ;;; num = num - 'e'
 572 ;;; group_pos = num mod 'c'
 573 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 574
 575 ;;; Easy no? :)
 576 ;;;
 577 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 578 ;;; column for that line, and always add 1 more when going from
 579 ;;; component -> virtual.  Otherwise you run into a problem with
 580 ;;; unique reverse mapping.
 581
 582 (defun nnvirtual-map-article (article)
 583   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 584   (let ((table nnvirtual-mapping-table)
 585         entry group-pos)
 586     (while (and table
 587                 (> article (aref (car table) 3)))
 588       (setq table (cdr table)))
 589     (when (and table
 590                (> article 0))
 591       (setq entry (car table))
 592       (setq article (- article (aref entry 4) 1))
 593       (setq group-pos (mod article (aref entry 2)))
 594       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 595             (+ (/ article (aref entry 2))
 596                (aref entry 1)
 597                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 598             ))
 599     ))
 600
 601
 602
 603 (defun nnvirtual-reverse-map-article (group article)
 604   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 605   (when (numberp article)
 606     (let ((table nnvirtual-mapping-table)
 607           (group-pos 0)
 608           entry)
 609       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 610                                             group-pos))))
 611         (setq group-pos (1+ group-pos)))
 612       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 613                                           group-pos))))
 614       (while (and table
 615                   (> article (aref (car table) 0)))
 616         (setq table (cdr table)))
 617       (setq entry (car table))
 618       (when (and entry
 619                  (> article 0)
 620                  (< group-pos (aref entry 2))) ; article not out of range below
 621         (+ (aref entry 4)
 622            group-pos
 623            (* (- article (aref entry 1))
 624               (aref entry 2))
 625            1))
 626       )))
 627
 628
 629 (defsubst nnvirtual-reverse-map-sequence (group articles)
 630   "Return list of virtual article numbers for all ARTICLES in GROUP.
 631 The ARTICLES should be sorted, and can be a compressed sequence.
 632 If any of the article numbers has no corresponding virtual article,
 633 then it is left out of the result."
 634   (when (numberp (cdr-safe articles))
 635     (setq articles (list articles)))
 636   (let (result a i j new-a)
 637     (while (setq a (pop articles))
 638       (if (atom a)
 639           (setq i a
 640                 j a)
 641         (setq i (car a)
 642               j (cdr a)))
 643       (while (<= i j)
 644         ;; If this is slow, you can optimize by moving article checking
 645         ;; into here.  You don't have to recompute the group-pos,
 646         ;; nor scan the table every time.
 647         (when (setq new-a (nnvirtual-reverse-map-article group i))
 648           (push new-a result))
 649         (setq i (1+ i))))
 650     (nreverse result)))
 651
 652
 653 (defun nnvirtual-partition-sequence (articles)
 654   "Return an association list of component article numbers.
 655 These are indexed by elements of nnvirtual-component-groups, based on
 656 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 657 sorted, and can be a compressed sequence.  If any of the article
 658 numbers has no corresponding component article, then it is left out of
 659 the result."
 660   (when (numberp (cdr-safe articles))
 661     (setq articles (list articles)))
 662   (let ((carticles (mapcar 'list nnvirtual-component-groups))
 663         a i j article entry)
 664     (while (setq a (pop articles))
 665       (if (atom a)
 666           (setq i a
 667                 j a)
 668         (setq i (car a)
 669               j (cdr a)))
 670       (while (<= i j)
 671         (when (setq article (nnvirtual-map-article i))
 672           (setq entry (assoc (car article) carticles))
 673           (setcdr entry (cons (cdr article) (cdr entry))))
 674         (setq i (1+ i))))
 675     (mapc (lambda (x) (setcdr x (nreverse (cdr x))))
 676           carticles)
 677     carticles))
 678
 679
 680 (defun nnvirtual-create-mapping ()
 681   "Build the tables necessary to map between component (group, article) to virtual article.
 682 Generate the set of read messages and marks for the virtual group
 683 based on the marks on the component groups."
 684   (let ((cnt 0)
 685         (tot 0)
 686         (M 0)
 687         (i 0)
 688         actives all-unreads all-marks
 689         active min max size unreads marks
 690         next-M next-tot
 691         reads beg)
 692     ;; Ok, we loop over all component groups and collect a lot of
 693     ;; information:
 694     ;; Into actives we place (g size max), where size is max-min+1.
 695     ;; Into all-unreads we put (g unreads).
 696     ;; Into all-marks we put (g marks).
 697     ;; We also increment cnt and tot here, and compute M (max of sizes).
 698     (mapc (lambda (g)
 699             (setq active (gnus-activate-group g)
 700                   min (car active)
 701                   max (cdr active))
 702             (when (and active (>= max min) (not (zerop max)))
 703               ;; store active information
 704               (push (list g (- max min -1) max) actives)
 705               ;; collect unread/mark info for later
 706               (setq unreads (gnus-list-of-unread-articles g))
 707               (setq marks (gnus-info-marks (gnus-get-info g)))
 708               (when gnus-use-cache
 709                 (push (cons 'cache
 710                             (gnus-cache-articles-in-group g))
 711                       marks))
 712               (push (cons g unreads) all-unreads)
 713               (push (cons g marks) all-marks)
 714               ;; count groups, total #articles, and max size
 715               (setq size (- max min -1))
 716               (setq cnt (1+ cnt)
 717                     tot (+ tot size)
 718                     M (max M size))))
 719           nnvirtual-component-groups)
 720
 721     ;; Number of articles in the virtual group.
 722     (setq nnvirtual-mapping-len tot)
 723
 724
 725     ;; We want the actives list sorted by size, to build the tables.
 726     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 727
 728     ;; Build the offset table.  Largest sized groups are at the front.
 729     (setq nnvirtual-mapping-offsets
 730           (vconcat
 731            (nreverse
 732             (mapcar (lambda (entry)
 733                       (cons (nth 0 entry)
 734                             (- (nth 2 entry) M)))
 735                     actives))))
 736
 737     ;; Build the mapping table.
 738     (setq nnvirtual-mapping-table nil)
 739     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 740     (while actives
 741       (setq size (car actives))
 742       (setq next-M (- M size))
 743       (setq next-tot (- tot (* cnt size)))
 744       ;; make current row in table
 745       (push (vector M next-M cnt tot (- next-tot cnt))
 746             nnvirtual-mapping-table)
 747       ;; update M and tot
 748       (setq M next-M)
 749       (setq tot next-tot)
 750       ;; subtract the current size from all entries.
 751       (setq actives (mapcar (lambda (x) (- x size)) actives))
 752       ;; remove anything that went to 0.
 753       (while (and actives
 754                   (= (car actives) 0))
 755         (pop actives)
 756         (setq cnt (- cnt 1))))
 757
 758
 759     ;; Now that the mapping tables are generated, we can convert
 760     ;; and combine the separate component unreads and marks lists
 761     ;; into single lists of virtual article numbers.
 762     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 763                          (mapcar (lambda (x)
 764                                    (nnvirtual-reverse-map-sequence
 765                                     (car x) (cdr x)))
 766                                  all-unreads)))
 767     (setq marks (mapcar
 768                  (lambda (type)
 769                    (cons (cdr type)
 770                          (gnus-compress-sequence
 771                           (apply
 772                            'nnvirtual-merge-sorted-lists
 773                            (mapcar (lambda (x)
 774                                      (nnvirtual-reverse-map-sequence
 775                                       (car x)
 776                                       (cdr (assq (cdr type) (cdr x)))))
 777                                    all-marks)))))
 778                  gnus-article-mark-lists))
 779
 780     ;; Remove any empty marks lists, and store.
 781     (setq nnvirtual-mapping-marks nil)
 782     (dolist (mark marks)
 783       (when (cdr mark)
 784         (push mark nnvirtual-mapping-marks)))
 785
 786     ;; We need to convert the unreads to reads.  We compress the
 787     ;; sequence as we go, otherwise it could be huge.
 788     (while (and (<= (incf i) nnvirtual-mapping-len)
 789                 unreads)
 790       (if (= i (car unreads))
 791           (setq unreads (cdr unreads))
 792         ;; try to get a range.
 793         (setq beg i)
 794         (while (and (<= (incf i) nnvirtual-mapping-len)
 795                     (not (= i (car unreads)))))
 796         (setq i (- i 1))
 797         (if (= i beg)
 798             (push i reads)
 799           (push (cons beg i) reads))
 800         ))
 801     (when (<= i nnvirtual-mapping-len)
 802       (if (= i nnvirtual-mapping-len)
 803           (push i reads)
 804         (push (cons i nnvirtual-mapping-len) reads)))
 805
 806     ;; Store the reads list for later use.
 807     (setq nnvirtual-mapping-reads (nreverse reads))
 808
 809     ;; Throw flag to show we changed the info.
 810     (setq nnvirtual-info-installed nil)
 811     ))
 812
 813 (provide 'nnvirtual)
 814
 815 ;;; arch-tag: ca8c8ad9-1bd8-4b0f-9722-90dc645a45f5
 816 ;;; nnvirtual.el ends here