cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: David Moore <dmoore@ucsd.edu>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can not be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'nnoo)
  38 (require 'gnus-util)
  39 (require 'gnus-start)
  40 (require 'gnus-sum)
  41 (require 'cl)
  42
  43 (nnoo-declare nnvirtual)
  44
  45 (defvoo nnvirtual-always-rescan nil
  46   "*If non-nil, always scan groups for unread articles when entering a group.
  47 If this variable is nil (which is the default) and you read articles
  48 in a component group after the virtual group has been activated, the
  49 read articles from the component group will show up when you enter the
  50 virtual group.")
  51
  52 (defvoo nnvirtual-component-regexp nil
  53   "*Regexp to match component groups.")
  54
  55 (defvoo nnvirtual-component-groups nil
  56   "Component group in this nnvirtual group.")
  57
  58 \f
  59
  60 (defconst nnvirtual-version "nnvirtual 1.1")
  61
  62 (defvoo nnvirtual-current-group nil)
  63
  64 (defvoo nnvirtual-mapping-table nil
  65   "Table of rules on how to map between component group and article number
  66 to virtual article number.")
  67
  68 (defvoo nnvirtual-mapping-offsets nil
  69   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  70
  71 (defvoo nnvirtual-mapping-len 0
  72   "Number of articles in this virtual group.")
  73
  74 (defvoo nnvirtual-mapping-reads nil
  75   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  76
  77 (defvoo nnvirtual-mapping-marks nil
  78   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  79
  80 (defvoo nnvirtual-info-installed nil
  81   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  82
  83 (defvoo nnvirtual-status-string "")
  84
  85 (eval-and-compile
  86   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  87
  88 \f
  89
  90 ;;; Interface functions.
  91
  92 (nnoo-define-basics nnvirtual)
  93
  94
  95 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  96                                              server fetch-old)
  97   (when (nnvirtual-possibly-change-server server)
  98     (save-excursion
  99       (set-buffer nntp-server-buffer)
 100       (erase-buffer)
 101       (if (stringp (car articles))
 102           'headers
 103         (let ((vbuf (nnheader-set-temp-buffer
 104                      (get-buffer-create " *virtual headers*")))
 105               (carticles (nnvirtual-partition-sequence articles))
 106               (system-name (system-name))
 107               cgroup carticle article result prefix)
 108           (while carticles
 109             (setq cgroup (caar carticles))
 110             (setq articles (cdar carticles))
 111             (pop carticles)
 112             (when (and articles
 113                        (gnus-check-server
 114                         (gnus-find-method-for-group cgroup) t)
 115                        (gnus-request-group cgroup t)
 116                        (setq prefix (gnus-group-real-prefix cgroup))
 117                        ;; FIX FIX FIX we want to check the cache!
 118                        ;; This is probably evil if people have set
 119                        ;; gnus-use-cache to nil themselves, but I
 120                        ;; have no way of finding the true value of it.
 121                        (let ((gnus-use-cache t))
 122                          (setq result (gnus-retrieve-headers
 123                                        articles cgroup nil))))
 124             (set-buffer nntp-server-buffer)
 125             ;; If we got HEAD headers, we convert them into NOV
 126             ;; headers.  This is slow, inefficient and, come to think
 127             ;; of it, downright evil.  So sue me.  I couldn't be
 128             ;; bothered to write a header parse routine that could
 129             ;; parse a mixed HEAD/NOV buffer.
 130             (when (eq result 'headers)
 131               (nnvirtual-convert-headers))
 132             (goto-char (point-min))
 133             (while (not (eobp))
 134               (delete-region (point)
 135                              (progn
 136                                (setq carticle (read nntp-server-buffer))
 137                                (point)))
 138
 139               ;; We remove this article from the articles list, if
 140               ;; anything is left in the articles list after going through
 141               ;; the entire buffer, then those articles have been
 142               ;; expired or canceled, so we appropriately update the
 143               ;; component group below.  They should be coming up
 144               ;; generally in order, so this shouldn't be slow.
 145               (setq articles (delq carticle articles))
 146
 147               (setq article (nnvirtual-reverse-map-article cgroup carticle))
 148               (if (null article)
 149                   ;; This line has no reverse mapping, that means it
 150                   ;; was an extra article reference returned by nntp.
 151                   (progn
 152                     (beginning-of-line)
 153                     (delete-region (point) (progn (forward-line 1) (point))))
 154                 ;; Otherwise insert the virtual article number,
 155                 ;; and clean up the xrefs.
 156                 (princ article nntp-server-buffer)
 157                 (nnvirtual-update-xref-header cgroup carticle
 158                                               prefix system-name)
 159                 (forward-line 1))
 160               )
 161
 162             (set-buffer vbuf)
 163             (goto-char (point-max))
 164             (insert-buffer-substring nntp-server-buffer))
 165             ;; Anything left in articles is expired or canceled.
 166             ;; Could be smart and not tell it about articles already known?
 167             (when articles
 168               (gnus-group-make-articles-read cgroup articles))
 169             )
 170
 171           ;; The headers are ready for reading, so they are inserted into
 172           ;; the nntp-server-buffer, which is where Gnus expects to find
 173           ;; them.
 174           (prog1
 175               (save-excursion
 176                 (set-buffer nntp-server-buffer)
 177                 (erase-buffer)
 178                 (insert-buffer-substring vbuf)
 179                 ;; FIX FIX FIX, we should be able to sort faster than
 180                 ;; this if needed, since each cgroup is sorted, we just
 181                 ;; need to merge
 182                 (sort-numeric-fields 1 (point-min) (point-max))
 183                 'nov)
 184             (kill-buffer vbuf)))))))
 185
 186
 187 (defvoo nnvirtual-last-accessed-component-group nil)
 188
 189 (deffoo nnvirtual-request-article (article &optional group server buffer)
 190   (when (nnvirtual-possibly-change-server server)
 191     (if (stringp article)
 192         ;; This is a fetch by Message-ID.
 193         (cond
 194          ((not nnvirtual-last-accessed-component-group)
 195           (nnheader-report
 196            'nnvirtual "Don't know what server to request from"))
 197          (t
 198           (save-excursion
 199             (when buffer
 200               (set-buffer buffer))
 201             (let ((method (gnus-find-method-for-group
 202                            nnvirtual-last-accessed-component-group)))
 203               (funcall (gnus-get-function method 'request-article)
 204                        article nil (nth 1 method) buffer)))))
 205       ;; This is a fetch by number.
 206       (let* ((amap (nnvirtual-map-article article))
 207              (cgroup (car amap)))
 208         (cond
 209          ((not amap)
 210           (nnheader-report 'nnvirtual "No such article: %s" article))
 211          ((not (gnus-check-group cgroup))
 212           (nnheader-report
 213            'nnvirtual "Can't open server where %s exists" cgroup))
 214          ((not (gnus-request-group cgroup t))
 215           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 216          (t
 217           (setq nnvirtual-last-accessed-component-group cgroup)
 218           (if buffer
 219               (save-excursion
 220                 (set-buffer buffer)
 221                 (gnus-request-article-this-buffer (cdr amap) cgroup))
 222             (gnus-request-article (cdr amap) cgroup))))))))
 223
 224
 225 (deffoo nnvirtual-open-server (server &optional defs)
 226   (unless (assq 'nnvirtual-component-regexp defs)
 227     (push `(nnvirtual-component-regexp ,server)
 228           defs))
 229   (nnoo-change-server 'nnvirtual server defs)
 230   (if nnvirtual-component-groups
 231       t
 232     (setq nnvirtual-mapping-table nil
 233           nnvirtual-mapping-offsets nil
 234           nnvirtual-mapping-len 0
 235           nnvirtual-mapping-reads nil
 236           nnvirtual-mapping-marks nil
 237           nnvirtual-info-installed nil)
 238     (when nnvirtual-component-regexp
 239       ;; Go through the newsrc alist and find all component groups.
 240       (let ((newsrc (cdr gnus-newsrc-alist))
 241             group)
 242         (while (setq group (car (pop newsrc)))
 243           (when (string-match nnvirtual-component-regexp group) ; Match
 244             ;; Add this group to the list of component groups.
 245             (setq nnvirtual-component-groups
 246                   (cons group (delete group nnvirtual-component-groups)))))))
 247     (if (not nnvirtual-component-groups)
 248         (nnheader-report 'nnvirtual "No component groups: %s" server)
 249       t)))
 250
 251
 252 (deffoo nnvirtual-request-group (group &optional server dont-check)
 253   (nnvirtual-possibly-change-server server)
 254   (setq nnvirtual-component-groups
 255         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 256   (cond
 257    ((null nnvirtual-component-groups)
 258     (setq nnvirtual-current-group nil)
 259     (nnheader-report 'nnvirtual "No component groups in %s" group))
 260    (t
 261     (when (or (not dont-check)
 262               nnvirtual-always-rescan)
 263       (nnvirtual-create-mapping))
 264     (setq nnvirtual-current-group group)
 265     (nnheader-insert "211 %d 1 %d %s\n"
 266                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 267
 268
 269 (deffoo nnvirtual-request-type (group &optional article)
 270   (if (not article)
 271       'unknown
 272     (let ((mart (nnvirtual-map-article article)))
 273       (when mart
 274         (gnus-request-type (car mart) (cdr mart))))))
 275
 276 (deffoo nnvirtual-request-update-mark (group article mark)
 277   (let* ((nart (nnvirtual-map-article article))
 278          (cgroup (car nart))
 279          ;; The component group might be a virtual group.
 280          (nmark (gnus-request-update-mark cgroup (cdr nart) mark)))
 281     (when (and nart
 282                (= mark nmark)
 283                (gnus-group-auto-expirable-p cgroup))
 284       (setq mark gnus-expirable-mark)))
 285   mark)
 286
 287
 288 (deffoo nnvirtual-close-group (group &optional server)
 289   (when (and (nnvirtual-possibly-change-server server)
 290              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 291     (nnvirtual-update-read-and-marked t t))
 292   t)
 293
 294
 295 (deffoo nnvirtual-request-list (&optional server)
 296   (nnheader-report 'nnvirtual "LIST is not implemented."))
 297
 298
 299 (deffoo nnvirtual-request-newgroups (date &optional server)
 300   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 301
 302
 303 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 304   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 305
 306
 307 (deffoo nnvirtual-request-update-info (group info &optional server)
 308   (when (and (nnvirtual-possibly-change-server server)
 309              (not nnvirtual-info-installed))
 310     ;; Install the precomputed lists atomically, so the virtual group
 311     ;; is not left in a half-way state in case of C-g.
 312     (gnus-atomic-progn
 313       (setcar (cddr info) nnvirtual-mapping-reads)
 314       (if (nthcdr 3 info)
 315           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 316         (when nnvirtual-mapping-marks
 317           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 318       (setq nnvirtual-info-installed t))
 319     t))
 320
 321
 322 (deffoo nnvirtual-catchup-group (group &optional server all)
 323   (when (and (nnvirtual-possibly-change-server server)
 324              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 325     ;; copy over existing marks first, in case they set anything
 326     (nnvirtual-update-read-and-marked nil nil)
 327     ;; do a catchup on all component groups
 328     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 329           (gnus-expert-user t))
 330       ;; Make sure all groups are activated.
 331       (mapcar
 332        (lambda (g)
 333          (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
 334            (gnus-activate-group g)))
 335        nnvirtual-component-groups)
 336       (save-excursion
 337         (set-buffer gnus-group-buffer)
 338         (gnus-group-catchup-current nil all)))))
 339
 340
 341 (deffoo nnvirtual-find-group-art (group article)
 342   "Return the real group and article for virtual GROUP and ARTICLE."
 343   (nnvirtual-map-article article))
 344
 345
 346 (deffoo nnvirtual-request-post (&optional server)
 347   (if (not gnus-message-group-art)
 348       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 349     (let ((group (car (nnvirtual-find-group-art
 350                        (car gnus-message-group-art)
 351                        (cdr gnus-message-group-art)))))
 352       (gnus-request-post (gnus-find-method-for-group group)))))
 353
 354 \f
 355 ;;; Internal functions.
 356
 357 (defun nnvirtual-convert-headers ()
 358   "Convert HEAD headers into NOV headers."
 359   (save-excursion
 360     (set-buffer nntp-server-buffer)
 361     (let* ((dependencies (make-vector 100 0))
 362            (headers (gnus-get-newsgroup-headers dependencies))
 363            header)
 364       (erase-buffer)
 365       (while (setq header (pop headers))
 366         (nnheader-insert-nov header)))))
 367
 368
 369 (defun nnvirtual-update-xref-header (group article prefix system-name)
 370   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 371   ;; Move to beginning of Xref field, creating a slot if needed.
 372   (beginning-of-line)
 373   (looking-at
 374    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 375   (goto-char (match-end 0))
 376   (unless (search-forward "\t" (gnus-point-at-eol) 'move)
 377     (insert "\t"))
 378
 379   ;; Remove any spaces at the beginning of the Xref field.
 380   (while (= (char-after (1- (point))) ? )
 381     (forward-char -1)
 382     (delete-char 1))
 383
 384   (insert "Xref: " system-name " " group ":")
 385   (princ article (current-buffer))
 386   (insert " ")
 387
 388   ;; If there were existing xref lines, clean them up to have the correct
 389   ;; component server prefix.
 390   (save-restriction
 391     (narrow-to-region (point)
 392                       (or (search-forward "\t" (gnus-point-at-eol) t)
 393                           (gnus-point-at-eol)))
 394     (goto-char (point-min))
 395     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 396       (replace-match "" t t))
 397     (goto-char (point-min))
 398     (when (re-search-forward
 399            (concat (gnus-group-real-name group) ":[0-9]+")
 400            nil t)
 401       (replace-match "" t t))
 402     (unless (= (point) (point-max))
 403       (insert " ")
 404       (when (not (string= "" prefix))
 405         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 406           (save-excursion
 407             (goto-char (match-beginning 0))
 408             (insert prefix))))))
 409
 410   ;; Ensure a trailing \t.
 411   (end-of-line)
 412   (or (= (char-after (1- (point))) ?\t)
 413       (insert ?\t)))
 414
 415
 416 (defun nnvirtual-possibly-change-server (server)
 417   (or (not server)
 418       (nnoo-current-server-p 'nnvirtual server)
 419       (nnvirtual-open-server server)))
 420
 421
 422 (defun nnvirtual-update-read-and-marked (read-p update-p)
 423   "Copy marks from the virtual group to the component groups.
 424 If READ-P is not nil, update the (un)read status of the components.
 425 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 426   (when nnvirtual-current-group
 427     (let ((unreads (and read-p
 428                         (nnvirtual-partition-sequence
 429                          (gnus-list-of-unread-articles
 430                           (nnvirtual-current-group)))))
 431           (type-marks (mapcar (lambda (ml)
 432                                 (cons (car ml)
 433                                       (nnvirtual-partition-sequence (cdr ml))))
 434                               (gnus-info-marks (gnus-get-info
 435                                                 (nnvirtual-current-group)))))
 436           mark type groups carticles info entry)
 437
 438       ;; Ok, atomically move all of the (un)read info, clear any old
 439       ;; marks, and move all of the current marks.  This way if someone
 440       ;; hits C-g, you won't leave the component groups in a half-way state.
 441       (gnus-atomic-progn
 442         ;; move (un)read
 443         (let ((gnus-newsgroup-active nil)) ;workaround guns-update-read-articles
 444           (while (setq entry (pop unreads))
 445             (gnus-update-read-articles (car entry) (cdr entry))))
 446
 447         ;; clear all existing marks on the component groups
 448         (setq groups nnvirtual-component-groups)
 449         (while groups
 450           (when (and (setq info (gnus-get-info (pop groups)))
 451                      (gnus-info-marks info))
 452             (gnus-info-set-marks info nil)))
 453
 454         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 455         ;; with data of an assq list with keys of component group names
 456         ;; and the articles which correspond to that key/group pair.
 457         (while (setq mark (pop type-marks))
 458           (setq type (car mark))
 459           (setq groups (cdr mark))
 460           (while (setq carticles (pop groups))
 461             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 462                                       nil t))))
 463
 464       ;; possibly update the display, it is really slow
 465       (when update-p
 466         (setq groups nnvirtual-component-groups)
 467         (while groups
 468           (gnus-group-update-group (pop groups) t))))))
 469
 470
 471 (defun nnvirtual-current-group ()
 472   "Return the prefixed name of the current nnvirtual group."
 473   (concat "nnvirtual:" nnvirtual-current-group))
 474
 475
 476
 477 ;;; This is currently O(kn^2) to merge n lists of length k.
 478 ;;; You could do it in O(knlogn), but we have a small n, and the
 479 ;;; overhead of the other approach is probably greater.
 480 (defun nnvirtual-merge-sorted-lists (&rest lists)
 481   "Merge many sorted lists of numbers."
 482   (if (null (cdr lists))
 483       (car lists)
 484     (sort (apply 'nconc lists) '<)))
 485
 486
 487 ;;; We map between virtual articles and real articles in a manner
 488 ;;; which keeps the size of the virtual active list the same as
 489 ;;; the sum of the component active lists.
 490 ;;; To achieve fair mixing of the groups, the last article in
 491 ;;; each of N component groups will be in the the last N articles
 492 ;;; in the virtual group.
 493
 494 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and 6-7
 495 ;;; resprectively, then the virtual article numbers look like:
 496 ;;;
 497 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 498 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 499
 500 ;;; To compute these mappings we generate a couple tables and then
 501 ;;; do some fast operations on them.  Tables for the example above:
 502 ;;;
 503 ;;; Offsets - [(A 0) (B -3) (C -1)]
 504 ;;;
 505 ;;;               a  b  c  d  e
 506 ;;; Mapping - ([  3  0  1  3  0 ]
 507 ;;;            [  6  3  2  9  3 ]
 508 ;;;            [  8  6  3 15  9 ])
 509 ;;;
 510 ;;; (note column 'e' is different in real algorithm, which is slightly
 511 ;;;  different than described here, but this gives you the methodology.)
 512 ;;;
 513 ;;; The basic idea is this, when going from component->virtual, apply
 514 ;;; the appropriate offset to the article number.  Then search the first
 515 ;;; column of the table for a row where 'a' is less than or equal to the
 516 ;;; modified number.  You can see that only group A can therefore go to
 517 ;;; the first row, groups A and B to the second, and all to the last.
 518 ;;; The third column of the table is telling us the number of groups
 519 ;;; which might be able to reach that row (it might increase by more than
 520 ;;; 1 if several groups have the same size).
 521 ;;; Then column 'b' provides an additional offset you apply when you have
 522 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 523 ;;; _position_ in the offset table.  The basic idea here is that on
 524 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 525 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 526 ;;; you apply a final offset from column 'e' to give the virtual article.
 527 ;;;
 528 ;;; Going the other direction, you instead search on column 'd' instead
 529 ;;; of 'a', and apply everything in reverse order.
 530
 531 ;;; Convert component -> virtual:
 532 ;;; set num = num - Offset(group)
 533 ;;; find first row in Mapping where num <= 'a'
 534 ;;; num = (num-'b')*c + Position(group) + 'e'
 535
 536 ;;; Convert virtual -> component:
 537 ;;; find first row in Mapping where num <= 'd'
 538 ;;; num = num - 'e'
 539 ;;; group_pos = num mod 'c'
 540 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 541
 542 ;;; Easy no? :)
 543 ;;;
 544 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 545 ;;; column for that line, and always add 1 more when going from
 546 ;;; component -> virtual.  Otherwise you run into a problem with
 547 ;;; unique reverse mapping.
 548
 549 (defun nnvirtual-map-article (article)
 550   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 551   (let ((table nnvirtual-mapping-table)
 552         entry group-pos)
 553     (while (and table
 554                 (> article (aref (car table) 3)))
 555       (setq table (cdr table)))
 556     (when (and table
 557                (> article 0))
 558       (setq entry (car table))
 559       (setq article (- article (aref entry 4) 1))
 560       (setq group-pos (mod article (aref entry 2)))
 561       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 562             (+ (/ article (aref entry 2))
 563                (aref entry 1)
 564                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 565             ))
 566       ))
 567
 568
 569
 570 (defun nnvirtual-reverse-map-article (group article)
 571   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 572   (when (numberp article)
 573     (let ((table nnvirtual-mapping-table)
 574           (group-pos 0)
 575           entry)
 576       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 577                                             group-pos))))
 578         (setq group-pos (1+ group-pos)))
 579       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 580                                           group-pos))))
 581       (while (and table
 582                   (> article (aref (car table) 0)))
 583         (setq table (cdr table)))
 584       (setq entry (car table))
 585       (when (and entry
 586                  (> article 0)
 587                  (< group-pos (aref entry 2))) ; article not out of range below
 588         (+ (aref entry 4)
 589            group-pos
 590            (* (- article (aref entry 1))
 591               (aref entry 2))
 592            1))
 593       )))
 594
 595
 596 (defsubst nnvirtual-reverse-map-sequence (group articles)
 597   "Return list of virtual article numbers for all ARTICLES in GROUP.
 598 The ARTICLES should be sorted, and can be a compressed sequence.
 599 If any of the article numbers has no corresponding virtual article,
 600 then it is left out of the result."
 601   (when (numberp (cdr-safe articles))
 602     (setq articles (list articles)))
 603   (let (result a i j new-a)
 604     (while (setq a (pop articles))
 605       (if (atom a)
 606           (setq i a
 607                 j a)
 608         (setq i (car a)
 609               j (cdr a)))
 610       (while (<= i j)
 611         ;; If this is slow, you can optimize by moving article checking
 612         ;; into here.  You don't have to recompute the group-pos,
 613         ;; nor scan the table every time.
 614         (when (setq new-a (nnvirtual-reverse-map-article group i))
 615           (push new-a result))
 616         (setq i (1+ i))))
 617     (nreverse result)))
 618
 619
 620 (defun nnvirtual-partition-sequence (articles)
 621   "Return an association list of component article numbers.
 622 These are indexed by elements of nnvirtual-component-groups, based on
 623 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 624 sorted, and can be a compressed sequence. If any of the article
 625 numbers has no corresponding component article, then it is left out of
 626 the result."
 627   (when (numberp (cdr-safe articles))
 628     (setq articles (list articles)))
 629   (let ((carticles (mapcar (lambda (g) (list g))
 630                            nnvirtual-component-groups))
 631         a i j article entry)
 632     (while (setq a (pop articles))
 633       (if (atom a)
 634           (setq i a
 635                 j a)
 636         (setq i (car a)
 637               j (cdr a)))
 638       (while (<= i j)
 639         (when (setq article (nnvirtual-map-article i))
 640           (setq entry (assoc (car article) carticles))
 641           (setcdr entry (cons (cdr article) (cdr entry))))
 642         (setq i (1+ i))))
 643     (mapcar (lambda (x) (setcdr x (nreverse (cdr x))))
 644             carticles)
 645     carticles))
 646
 647
 648 (defun nnvirtual-create-mapping ()
 649   "Build the tables necessary to map between component (group, article) to virtual article.
 650 Generate the set of read messages and marks for the virtual group
 651 based on the marks on the component groups."
 652   (let ((cnt 0)
 653         (tot 0)
 654         (M 0)
 655         (i 0)
 656         actives all-unreads all-marks
 657         active min max size unreads marks
 658         next-M next-tot
 659         reads beg)
 660     ;; Ok, we loop over all component groups and collect a lot of
 661     ;; information:
 662     ;; Into actives we place (g size max), where size is max-min+1.
 663     ;; Into all-unreads we put (g unreads).
 664     ;; Into all-marks we put (g marks).
 665     ;; We also increment cnt and tot here, and compute M (max of sizes).
 666     (mapc (lambda (g)
 667             (setq active (gnus-activate-group g)
 668                   min (car active)
 669                   max (cdr active))
 670             (when (and active (>= max min) (not (zerop max)))
 671               ;; store active information
 672               (push (list g (- max min -1) max) actives)
 673               ;; collect unread/mark info for later
 674               (setq unreads (gnus-list-of-unread-articles g))
 675               (setq marks (gnus-info-marks (gnus-get-info g)))
 676               (when gnus-use-cache
 677                 (push (cons 'cache
 678                             (gnus-cache-articles-in-group g))
 679                       marks))
 680               (push (cons g unreads) all-unreads)
 681               (push (cons g marks) all-marks)
 682               ;; count groups, total #articles, and max size
 683               (setq size (- max min -1))
 684               (setq cnt (1+ cnt)
 685                     tot (+ tot size)
 686                     M (max M size))))
 687           nnvirtual-component-groups)
 688
 689     ;; Number of articles in the virtual group.
 690     (setq nnvirtual-mapping-len tot)
 691
 692
 693     ;; We want the actives list sorted by size, to build the tables.
 694     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 695
 696     ;; Build the offset table.  Largest sized groups are at the front.
 697     (setq nnvirtual-mapping-offsets
 698           (vconcat
 699            (nreverse
 700             (mapcar (lambda (entry)
 701                       (cons (nth 0 entry)
 702                             (- (nth 2 entry) M)))
 703                     actives))))
 704
 705     ;; Build the mapping table.
 706     (setq nnvirtual-mapping-table nil)
 707     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 708     (while actives
 709       (setq size (car actives))
 710       (setq next-M (- M size))
 711       (setq next-tot (- tot (* cnt size)))
 712       ;; make current row in table
 713       (push (vector M next-M cnt tot (- next-tot cnt))
 714             nnvirtual-mapping-table)
 715       ;; update M and tot
 716       (setq M next-M)
 717       (setq tot next-tot)
 718       ;; subtract the current size from all entries.
 719       (setq actives (mapcar (lambda (x) (- x size)) actives))
 720       ;; remove anything that went to 0.
 721       (while (and actives
 722                   (= (car actives) 0))
 723         (pop actives)
 724         (setq cnt (- cnt 1))))
 725
 726
 727     ;; Now that the mapping tables are generated, we can convert
 728     ;; and combine the separate component unreads and marks lists
 729     ;; into single lists of virtual article numbers.
 730     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 731                          (mapcar (lambda (x)
 732                                    (nnvirtual-reverse-map-sequence
 733                                     (car x) (cdr x)))
 734                                  all-unreads)))
 735     (setq marks (mapcar
 736                  (lambda (type)
 737                    (cons (cdr type)
 738                          (gnus-compress-sequence
 739                           (apply
 740                            'nnvirtual-merge-sorted-lists
 741                            (mapcar (lambda (x)
 742                                      (nnvirtual-reverse-map-sequence
 743                                       (car x)
 744                                       (cdr (assq (cdr type) (cdr x)))))
 745                                    all-marks)))))
 746                  gnus-article-mark-lists))
 747
 748     ;; Remove any empty marks lists, and store.
 749     (setq nnvirtual-mapping-marks nil)
 750     (while marks
 751       (if (cdr (car marks))
 752           (push (car marks) nnvirtual-mapping-marks))
 753       (setq marks (cdr marks)))
 754
 755     ;; We need to convert the unreads to reads.  We compress the
 756     ;; sequence as we go, otherwise it could be huge.
 757     (while (and (<= (incf i) nnvirtual-mapping-len)
 758                 unreads)
 759       (if (= i (car unreads))
 760           (setq unreads (cdr unreads))
 761         ;; try to get a range.
 762         (setq beg i)
 763         (while (and (<= (incf i) nnvirtual-mapping-len)
 764                     (not (= i (car unreads)))))
 765         (setq i (- i 1))
 766         (if (= i beg)
 767             (push i reads)
 768           (push (cons beg i) reads))
 769         ))
 770     (when (<= i nnvirtual-mapping-len)
 771       (if (= i nnvirtual-mapping-len)
 772           (push i reads)
 773         (push (cons i nnvirtual-mapping-len) reads)))
 774
 775     ;; Store the reads list for later use.
 776     (setq nnvirtual-mapping-reads (nreverse reads))
 777
 778     ;; Throw flag to show we changed the info.
 779     (setq nnvirtual-info-installed nil)
 780     ))
 781
 782 (provide 'nnvirtual)
 783
 784 ;;; nnvirtual.el ends here