cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; nntp.el --- nntp access for Gnus
   2 ;; Copyright (C) 1987, 1988, 1989, 1990, 1992, 1993, 1994, 1995, 1996,
   3 ;;        1997, 1998, 2000, 2001
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nnoo)
  31 (require 'gnus-util)
  32
  33 (nnoo-declare nntp)
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defvoo nntp-address nil
  38   "Address of the physical nntp server.")
  39
  40 (defvoo nntp-port-number "nntp"
  41   "Port number on the physical nntp server.")
  42
  43 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  44   "*Hook used for sending commands to the server at startup.
  45 The default value is `nntp-send-mode-reader', which makes an innd
  46 server spawn an nnrpd server.")
  47
  48 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  49   "Function used to send AUTHINFO to the server.
  50 It is called with no parameters.")
  51
  52 (defvoo nntp-server-action-alist
  53     '(("nntpd 1\\.5\\.11t"
  54        (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  55       ("NNRP server Netscape"
  56        (setq nntp-server-list-active-group nil)))
  57   "Alist of regexps to match on server types and actions to be taken.
  58 For instance, if you want Gnus to beep every time you connect
  59 to innd, you could say something like:
  60
  61 \(setq nntp-server-action-alist
  62        '((\"innd\" (ding))))
  63
  64 You probably don't want to do that, though.")
  65
  66 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  67   "*Function used for connecting to a remote system.
  68 It will be called with the buffer to output in.
  69
  70 Two pre-made functions are `nntp-open-network-stream', which is the
  71 default, and simply connects to some port or other on the remote
  72 system (see nntp-port-number).  The other are `nntp-open-rlogin',
  73 which does an rlogin on the remote system, and then does a telnet to
  74 the NNTP server available there (see nntp-rlogin-parameters) and
  75 `nntp-open-telnet' which telnets to a remote system, logs in and does
  76 the same.")
  77
  78 (defvoo nntp-rlogin-program "rsh"
  79   "*Program used to log in on remote machines.
  80 The default is \"rsh\", but \"ssh\" is a popular alternative.")
  81
  82 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  83   "*Parameters to `nntp-open-rlogin'.
  84 That function may be used as `nntp-open-connection-function'.  In that
  85 case, this list will be used as the parameter list given to rsh.")
  86
  87 (defvoo nntp-rlogin-user-name nil
  88   "*User name on remote system when using the rlogin connect method.")
  89
  90 (defvoo nntp-telnet-parameters
  91     '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  92   "*Parameters to `nntp-open-telnet'.
  93 That function may be used as `nntp-open-connection-function'.  In that
  94 case, this list will be executed as a command after logging in
  95 via telnet.")
  96
  97 (defvoo nntp-telnet-user-name nil
  98   "User name to log in via telnet with.")
  99
 100 (defvoo nntp-telnet-passwd nil
 101   "Password to use to log in via telnet with.")
 102
 103 (defvoo nntp-open-telnet-envuser nil
 104   "*If non-nil, telnet session (client and server both) will support the ENVIRON option and not prompt for login name.")
 105
 106 (defvoo nntp-telnet-shell-prompt "bash\\|\$ *\r?$\\|> *\r?"
 107   "*Regular expression to match the shell prompt on the remote machine.")
 108
 109 (defvoo nntp-telnet-command "telnet"
 110   "Command used to start telnet.")
 111
 112 (defvoo nntp-telnet-switches '("-8")
 113   "Switches given to the telnet command.")
 114
 115 (defvoo nntp-end-of-line "\r\n"
 116   "String to use on the end of lines when talking to the NNTP server.
 117 This is \"\\r\\n\" by default, but should be \"\\n\" when
 118 using rlogin or telnet to communicate with the server.")
 119
 120 (defvoo nntp-large-newsgroup 50
 121   "*The number of the articles which indicates a large newsgroup.
 122 If the number of the articles is greater than the value, verbose
 123 messages will be shown to indicate the current status.")
 124
 125 (defvoo nntp-maximum-request 400
 126   "*The maximum number of the requests sent to the NNTP server at one time.
 127 If Emacs hangs up while retrieving headers, set the variable to a
 128 lower value.")
 129
 130 (defvoo nntp-nov-is-evil nil
 131   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 132
 133 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 134   "*List of strings that are used as commands to fetch NOV lines from a server.
 135 The strings are tried in turn until a positive response is gotten.  If
 136 none of the commands are successful, nntp will just grab headers one
 137 by one.")
 138
 139 (defvoo nntp-nov-gap 5
 140   "*Maximum allowed gap between two articles.
 141 If the gap between two consecutive articles is bigger than this
 142 variable, split the XOVER request into two requests.")
 143
 144 (defvoo nntp-prepare-server-hook nil
 145   "*Hook run before a server is opened.
 146 If can be used to set up a server remotely, for instance.  Say you
 147 have an account at the machine \"other.machine\".  This machine has
 148 access to an NNTP server that you can't access locally.  You could
 149 then use this hook to rsh to the remote machine and start a proxy NNTP
 150 server there that you can connect to.  See also
 151 `nntp-open-connection-function'")
 152
 153 (defvoo nntp-warn-about-losing-connection t
 154   "*If non-nil, beep when a server closes connection.")
 155
 156 (defvoo nntp-coding-system-for-read 'binary
 157   "*Coding system to read from NNTP.")
 158
 159 (defvoo nntp-coding-system-for-write 'binary
 160   "*Coding system to write to NNTP.")
 161
 162 (defcustom nntp-authinfo-file "~/.authinfo"
 163   ".netrc-like file that holds nntp authinfo passwords."
 164   :type
 165   '(choice file
 166            (repeat :tag "Entries"
 167                    :menu-tag "Inline"
 168                    (list :format "%v"
 169                          :value ("" ("login" . "") ("password" . ""))
 170                          (string :tag "Host")
 171                          (checklist :inline t
 172                                     (cons :format "%v"
 173                                           (const :format "" "login")
 174                                           (string :format "Login: %v"))
 175                                     (cons :format "%v"
 176                                           (const :format "" "password")
 177                                           (string :format "Password: %v")))))))
 178
 179 \f
 180
 181 (defvoo nntp-connection-timeout nil
 182   "*Number of seconds to wait before an nntp connection times out.
 183 If this variable is nil, which is the default, no timers are set.
 184 NOTE: This variable is never seen to work in Emacs 20 and XEmacs 21.")
 185
 186 ;;; Internal variables.
 187
 188 (defvar nntp-record-commands nil
 189   "*If non-nil, nntp will record all commands in the \"*nntp-log*\" buffer.")
 190
 191 (defvar nntp-have-messaged nil)
 192
 193 (defvar nntp-process-wait-for nil)
 194 (defvar nntp-process-to-buffer nil)
 195 (defvar nntp-process-callback nil)
 196 (defvar nntp-process-decode nil)
 197 (defvar nntp-process-start-point nil)
 198 (defvar nntp-inside-change-function nil)
 199 (defvoo nntp-last-command-time nil)
 200 (defvoo nntp-last-command nil)
 201 (defvoo nntp-authinfo-password nil)
 202 (defvoo nntp-authinfo-user nil)
 203
 204 (defvar nntp-connection-list nil)
 205
 206 (defvoo nntp-server-type nil)
 207 (defvoo nntp-connection-alist nil)
 208 (defvoo nntp-status-string "")
 209 (defconst nntp-version "nntp 5.0")
 210 (defvoo nntp-inhibit-erase nil)
 211 (defvoo nntp-inhibit-output nil)
 212
 213 (defvoo nntp-server-xover 'try)
 214 (defvoo nntp-server-list-active-group 'try)
 215
 216 (defvar nntp-async-needs-kluge
 217   (string-match "^GNU Emacs 20\\.3\\." (emacs-version))
 218   "*When non-nil, nntp will poll asynchronous connections
 219 once a second.  By default, this is turned on only for Emacs
 220 20.3, which has a bug that breaks nntp's normal method of
 221 noticing asynchronous data.")
 222
 223 (defvar nntp-async-timer nil)
 224 (defvar nntp-async-process-list nil)
 225
 226 (eval-and-compile
 227   (autoload 'mail-source-read-passwd "mail-source")
 228   (autoload 'open-ssl-stream "ssl"))
 229
 230 \f
 231
 232 ;;; Internal functions.
 233
 234 (defsubst nntp-send-string (process string)
 235   "Send STRING to PROCESS."
 236   ;; We need to store the time to provide timeouts, and
 237   ;; to store the command so the we can replay the command
 238   ;; if the server gives us an AUTHINFO challenge.
 239   (setq nntp-last-command-time (current-time)
 240         nntp-last-command string)
 241   (when nntp-record-commands
 242     (nntp-record-command string))
 243   (process-send-string process (concat string nntp-end-of-line)))
 244
 245 (defun nntp-record-command (string)
 246   "Record the command STRING."
 247   (save-excursion
 248     (set-buffer (get-buffer-create "*nntp-log*"))
 249     (goto-char (point-max))
 250     (let ((time (current-time)))
 251       (insert (format-time-string "%Y%m%dT%H%M%S" time)
 252               "." (format "%03d" (/ (nth 2 time) 1000))
 253               " " nntp-address " " string "\n"))))
 254
 255 (defsubst nntp-wait-for (process wait-for buffer &optional decode discard)
 256   "Wait for WAIT-FOR to arrive from PROCESS."
 257   (save-excursion
 258     (set-buffer (process-buffer process))
 259     (goto-char (point-min))
 260     (while (and (or (not (memq (char-after (point)) '(?2 ?3 ?4 ?5)))
 261                     (looking-at "480"))
 262                 (memq (process-status process) '(open run)))
 263       (when (looking-at "480")
 264         (nntp-handle-authinfo process))
 265       (nntp-accept-process-output process)
 266       (goto-char (point-min)))
 267     (prog1
 268         (cond
 269          ((looking-at "[45]")
 270           (progn
 271             (nntp-snarf-error-message)
 272             nil))
 273          ((not (memq (process-status process) '(open run)))
 274           (nnheader-report 'nntp "Server closed connection"))
 275          (t
 276           (goto-char (point-max))
 277           (let ((limit (point-min)))
 278             (while (not (re-search-backward wait-for limit t))
 279               (nntp-accept-process-output process)
 280               ;; We assume that whatever we wait for is less than 1000
 281               ;; characters long.
 282               (setq limit (max (- (point-max) 1000) (point-min)))
 283               (goto-char (point-max))))
 284           (nntp-decode-text (not decode))
 285           (unless discard
 286             (save-excursion
 287               (set-buffer buffer)
 288               (goto-char (point-max))
 289               (insert-buffer-substring (process-buffer process))
 290               ;; Nix out "nntp reading...." message.
 291               (when nntp-have-messaged
 292                 (setq nntp-have-messaged nil)
 293                 (nnheader-message 5 ""))))
 294           t))
 295       (unless discard
 296         (erase-buffer)))))
 297
 298 (defun nntp-kill-buffer (buffer)
 299   (when (buffer-name buffer)
 300     (kill-buffer buffer)
 301     (nnheader-init-server-buffer)))
 302
 303 (defsubst nntp-find-connection (buffer)
 304   "Find the connection delivering to BUFFER."
 305   (let ((alist nntp-connection-alist)
 306         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 307         process entry)
 308     (while (and alist (setq entry (pop alist)))
 309       (when (eq buffer (cadr entry))
 310         (setq process (car entry)
 311               alist nil)))
 312     (when process
 313       (if (memq (process-status process) '(open run))
 314           process
 315         (nntp-kill-buffer (process-buffer process))
 316         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 317         nil))))
 318
 319 (defsubst nntp-find-connection-entry (buffer)
 320   "Return the entry for the connection to BUFFER."
 321   (assq (nntp-find-connection buffer) nntp-connection-alist))
 322
 323 (defun nntp-find-connection-buffer (buffer)
 324   "Return the process connection buffer tied to BUFFER."
 325   (let ((process (nntp-find-connection buffer)))
 326     (when process
 327       (process-buffer process))))
 328
 329 (defsubst nntp-retrieve-data (command address port buffer
 330                                       &optional wait-for callback decode)
 331   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 332   (let ((process (or (nntp-find-connection buffer)
 333                      (nntp-open-connection buffer))))
 334     (if (not process)
 335         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 336       (unless (or nntp-inhibit-erase nnheader-callback-function)
 337         (save-excursion
 338           (set-buffer (process-buffer process))
 339           (erase-buffer)))
 340       (condition-case err
 341           (progn
 342             (when command
 343               (nntp-send-string process command))
 344             (cond
 345              ((eq callback 'ignore)
 346               t)
 347              ((and callback wait-for)
 348               (nntp-async-wait process wait-for buffer decode callback)
 349               t)
 350              (wait-for
 351               (nntp-wait-for process wait-for buffer decode))
 352              (t t)))
 353         (error
 354          (nnheader-report 'nntp "Couldn't open connection to %s: %s"
 355                           address err))
 356         (quit
 357          (message "Quit retrieving data from nntp")
 358          (signal 'quit nil)
 359          nil)))))
 360
 361 (defsubst nntp-send-command (wait-for &rest strings)
 362   "Send STRINGS to server and wait until WAIT-FOR returns."
 363   (when (and (not nnheader-callback-function)
 364              (not nntp-inhibit-output))
 365     (save-excursion
 366       (set-buffer nntp-server-buffer)
 367       (erase-buffer)))
 368   (nntp-retrieve-data
 369    (mapconcat 'identity strings " ")
 370    nntp-address nntp-port-number nntp-server-buffer
 371    wait-for nnheader-callback-function))
 372
 373 (defun nntp-send-command-nodelete (wait-for &rest strings)
 374   "Send STRINGS to server and wait until WAIT-FOR returns."
 375   (nntp-retrieve-data
 376    (mapconcat 'identity strings " ")
 377    nntp-address nntp-port-number nntp-server-buffer
 378    wait-for nnheader-callback-function))
 379
 380 (defun nntp-send-command-and-decode (wait-for &rest strings)
 381   "Send STRINGS to server and wait until WAIT-FOR returns."
 382   (when (and (not nnheader-callback-function)
 383              (not nntp-inhibit-output))
 384     (save-excursion
 385       (set-buffer nntp-server-buffer)
 386       (erase-buffer)))
 387   (nntp-retrieve-data
 388    (mapconcat 'identity strings " ")
 389    nntp-address nntp-port-number nntp-server-buffer
 390    wait-for nnheader-callback-function t))
 391
 392 (defun nntp-send-buffer (wait-for)
 393   "Send the current buffer to server and wait until WAIT-FOR returns."
 394   (when (and (not nnheader-callback-function)
 395              (not nntp-inhibit-output))
 396     (save-excursion
 397       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 398       (erase-buffer)))
 399   (nntp-encode-text)
 400   (process-send-region (nntp-find-connection nntp-server-buffer)
 401                        (point-min) (point-max))
 402   (nntp-retrieve-data
 403    nil nntp-address nntp-port-number nntp-server-buffer
 404    wait-for nnheader-callback-function))
 405
 406 \f
 407
 408 ;;; Interface functions.
 409
 410 (nnoo-define-basics nntp)
 411
 412 (defsubst nntp-next-result-arrived-p ()
 413   (cond
 414    ;; A result that starts with a 2xx code is terminated by
 415    ;; a line with only a "." on it.
 416    ((eq (char-after) ?2)
 417     (if (re-search-forward "\n\\.\r?\n" nil t)
 418         t
 419       nil))
 420    ;; A result that starts with a 3xx or 4xx code is terminated
 421    ;; by a newline.
 422    ((looking-at "[34]")
 423     (if (search-forward "\n" nil t)
 424         t
 425       nil))
 426    ;; No result here.
 427    (t
 428     nil)))
 429
 430 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 431   "Retrieve the headers of ARTICLES."
 432   (nntp-possibly-change-group group server)
 433   (save-excursion
 434     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 435     (erase-buffer)
 436     (if (and (not gnus-nov-is-evil)
 437              (not nntp-nov-is-evil)
 438              (nntp-retrieve-headers-with-xover articles fetch-old))
 439         ;; We successfully retrieved the headers via XOVER.
 440         'nov
 441       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 442       ;; way.
 443       (let ((number (length articles))
 444             (count 0)
 445             (received 0)
 446             (last-point (point-min))
 447             (buf (nntp-find-connection-buffer nntp-server-buffer))
 448             (nntp-inhibit-erase t)
 449             article)
 450         ;; Send HEAD commands.
 451         (while (setq article (pop articles))
 452           (nntp-send-command
 453            nil
 454            "HEAD" (if (numberp article)
 455                       (int-to-string article)
 456                     ;; `articles' is either a list of article numbers
 457                     ;; or a list of article IDs.
 458                     article))
 459           (incf count)
 460           ;; Every 400 requests we have to read the stream in
 461           ;; order to avoid deadlocks.
 462           (when (or (null articles)     ;All requests have been sent.
 463                     (zerop (% count nntp-maximum-request)))
 464             (nntp-accept-response)
 465             (while (progn
 466                      (set-buffer buf)
 467                      (goto-char last-point)
 468                      ;; Count replies.
 469                      (while (nntp-next-result-arrived-p)
 470                        (setq last-point (point))
 471                        (incf received))
 472                      (< received count))
 473               ;; If number of headers is greater than 100, give
 474               ;;  informative messages.
 475               (and (numberp nntp-large-newsgroup)
 476                    (> number nntp-large-newsgroup)
 477                    (zerop (% received 20))
 478                    (nnheader-message 6 "NNTP: Receiving headers... %d%%"
 479                                      (/ (* received 100) number)))
 480               (nntp-accept-response))))
 481         (and (numberp nntp-large-newsgroup)
 482              (> number nntp-large-newsgroup)
 483              (nnheader-message 6 "NNTP: Receiving headers...done"))
 484
 485         ;; Now all of replies are received.  Fold continuation lines.
 486         (nnheader-fold-continuation-lines)
 487         ;; Remove all "\r"'s.
 488         (nnheader-strip-cr)
 489         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 490         'headers))))
 491
 492 (deffoo nntp-retrieve-groups (groups &optional server)
 493   "Retrieve group info on GROUPS."
 494   (nntp-possibly-change-group nil server)
 495   (when (nntp-find-connection-buffer nntp-server-buffer)
 496     (catch 'done
 497       (save-excursion
 498         ;; Erase nntp-server-buffer before nntp-inhibit-erase.
 499         (set-buffer nntp-server-buffer)
 500         (erase-buffer)
 501         (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 502         ;; The first time this is run, this variable is `try'.  So we
 503         ;; try.
 504         (when (eq nntp-server-list-active-group 'try)
 505           (nntp-try-list-active (car groups)))
 506         (erase-buffer)
 507         (let ((count 0)
 508               (received 0)
 509               (last-point (point-min))
 510               (nntp-inhibit-erase t)
 511               (buf (nntp-find-connection-buffer nntp-server-buffer))
 512               (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 513           (while groups
 514             ;; Send the command to the server.
 515             (nntp-send-command nil command (pop groups))
 516             (incf count)
 517             ;; Every 400 requests we have to read the stream in
 518             ;; order to avoid deadlocks.
 519             (when (or (null groups)     ;All requests have been sent.
 520                       (zerop (% count nntp-maximum-request)))
 521               (nntp-accept-response)
 522               (while (and (gnus-buffer-live-p buf)
 523                           (progn
 524                             ;; Search `blue moon' in this file for the
 525                             ;; reason why set-buffer here.
 526                             (set-buffer buf)
 527                             (goto-char last-point)
 528                             ;; Count replies.
 529                             (while (re-search-forward "^[0-9]" nil t)
 530                               (incf received))
 531                             (setq last-point (point))
 532                             (< received count)))
 533                 (nntp-accept-response))))
 534
 535           ;; Wait for the reply from the final command.
 536           (unless (gnus-buffer-live-p buf)
 537             (nnheader-report 'nntp "Connection to %s is closed." server)
 538             (throw 'done nil))
 539           (set-buffer buf)
 540           (goto-char (point-max))
 541           (re-search-backward "^[0-9]" nil t)
 542           (when (looking-at "^[23]")
 543             (while (and (gnus-buffer-live-p buf)
 544                         (progn
 545                           (set-buffer buf)
 546                           (goto-char (point-max))
 547                           (if (not nntp-server-list-active-group)
 548                               (not (re-search-backward "\r?\n" (- (point) 3) t))
 549                             (not (re-search-backward "^\\.\r?\n"
 550                                                      (- (point) 4) t)))))
 551               (nntp-accept-response)))
 552
 553           ;; Now all replies are received.  We remove CRs.
 554           (unless (gnus-buffer-live-p buf)
 555             (nnheader-report 'nntp "Connection to %s is closed." server)
 556             (throw 'done nil))
 557           (set-buffer buf)
 558           (goto-char (point-min))
 559           (while (search-forward "\r" nil t)
 560             (replace-match "" t t))
 561
 562           (if (not nntp-server-list-active-group)
 563               (progn
 564                 (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 565                 'group)
 566             ;; We have read active entries, so we just delete the
 567             ;; superfluous gunk.
 568             (goto-char (point-min))
 569             (while (re-search-forward "^[.2-5]" nil t)
 570               (delete-region (match-beginning 0)
 571                              (progn (forward-line 1) (point))))
 572             (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 573             'active))))))
 574
 575 (deffoo nntp-retrieve-articles (articles &optional group server)
 576   (nntp-possibly-change-group group server)
 577   (save-excursion
 578     (let ((number (length articles))
 579           (count 0)
 580           (received 0)
 581           (last-point (point-min))
 582           (buf (nntp-find-connection-buffer nntp-server-buffer))
 583           (nntp-inhibit-erase t)
 584           (map (apply 'vector articles))
 585           (point 1)
 586           article)
 587       (set-buffer buf)
 588       (erase-buffer)
 589       ;; Send ARTICLE command.
 590       (while (setq article (pop articles))
 591         (nntp-send-command
 592          nil
 593          "ARTICLE" (if (numberp article)
 594                        (int-to-string article)
 595                      ;; `articles' is either a list of article numbers
 596                      ;; or a list of article IDs.
 597                      article))
 598         (incf count)
 599         ;; Every 400 requests we have to read the stream in
 600         ;; order to avoid deadlocks.
 601         (when (or (null articles)       ;All requests have been sent.
 602                   (zerop (% count nntp-maximum-request)))
 603           (nntp-accept-response)
 604           (while (progn
 605                    (set-buffer buf)
 606                    (goto-char last-point)
 607                    ;; Count replies.
 608                    (while (nntp-next-result-arrived-p)
 609                      (aset map received (cons (aref map received) (point)))
 610                      (setq last-point (point))
 611                      (incf received))
 612                    (< received count))
 613             ;; If number of headers is greater than 100, give
 614             ;;  informative messages.
 615             (and (numberp nntp-large-newsgroup)
 616                  (> number nntp-large-newsgroup)
 617                  (zerop (% received 20))
 618                  (nnheader-message 6 "NNTP: Receiving articles... %d%%"
 619                                    (/ (* received 100) number)))
 620             (nntp-accept-response))))
 621       (and (numberp nntp-large-newsgroup)
 622            (> number nntp-large-newsgroup)
 623            (nnheader-message 6 "NNTP: Receiving articles...done"))
 624
 625       ;; Now we have all the responses.  We go through the results,
 626       ;; wash it and copy it over to the server buffer.
 627       (set-buffer nntp-server-buffer)
 628       (erase-buffer)
 629       (setq last-point (point-min))
 630       (mapcar
 631        (lambda (entry)
 632          (narrow-to-region
 633           (setq point (goto-char (point-max)))
 634           (progn
 635             (insert-buffer-substring buf last-point (cdr entry))
 636             (point-max)))
 637          (setq last-point (cdr entry))
 638          (nntp-decode-text)
 639          (widen)
 640          (cons (car entry) point))
 641        map))))
 642
 643 (defun nntp-try-list-active (group)
 644   (nntp-list-active-group group)
 645   (save-excursion
 646     (set-buffer nntp-server-buffer)
 647     (goto-char (point-min))
 648     (cond ((or (eobp)
 649                (looking-at "5[0-9]+"))
 650            (setq nntp-server-list-active-group nil))
 651           (t
 652            (setq nntp-server-list-active-group t)))))
 653
 654 (deffoo nntp-list-active-group (group &optional server)
 655   "Return the active info on GROUP (which can be a regexp)."
 656   (nntp-possibly-change-group nil server)
 657   (nntp-send-command "^\\.*\r?\n" "LIST ACTIVE" group))
 658
 659 (deffoo nntp-request-group-articles (group &optional server)
 660   "Return the list of existing articles in GROUP."
 661   (nntp-possibly-change-group nil server)
 662   (nntp-send-command "^\\.*\r?\n" "LISTGROUP" group))
 663
 664 (deffoo nntp-request-article (article &optional group server buffer command)
 665   (nntp-possibly-change-group group server)
 666   (when (nntp-send-command-and-decode
 667          "\r?\n\\.\r?\n" "ARTICLE"
 668          (if (numberp article) (int-to-string article) article))
 669     (if (and buffer
 670              (not (equal buffer nntp-server-buffer)))
 671         (save-excursion
 672           (set-buffer nntp-server-buffer)
 673           (copy-to-buffer buffer (point-min) (point-max))
 674           (nntp-find-group-and-number))
 675       (nntp-find-group-and-number))))
 676
 677 (deffoo nntp-request-head (article &optional group server)
 678   (nntp-possibly-change-group group server)
 679   (when (nntp-send-command
 680          "\r?\n\\.\r?\n" "HEAD"
 681          (if (numberp article) (int-to-string article) article))
 682     (prog1
 683         (nntp-find-group-and-number)
 684       (nntp-decode-text))))
 685
 686 (deffoo nntp-request-body (article &optional group server)
 687   (nntp-possibly-change-group group server)
 688   (nntp-send-command-and-decode
 689    "\r?\n\\.\r?\n" "BODY"
 690    (if (numberp article) (int-to-string article) article)))
 691
 692 (deffoo nntp-request-group (group &optional server dont-check)
 693   (nntp-possibly-change-group nil server)
 694   (when (nntp-send-command "^[245].*\n" "GROUP" group)
 695     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 696       (setcar (cddr entry) group))))
 697
 698 (deffoo nntp-close-group (group &optional server)
 699   t)
 700
 701 (deffoo nntp-server-opened (&optional server)
 702   "Say whether a connection to SERVER has been opened."
 703   (and (nnoo-current-server-p 'nntp server)
 704        nntp-server-buffer
 705        (gnus-buffer-live-p nntp-server-buffer)
 706        (nntp-find-connection nntp-server-buffer)))
 707
 708 (deffoo nntp-open-server (server &optional defs connectionless)
 709   (nnheader-init-server-buffer)
 710   (if (nntp-server-opened server)
 711       t
 712     (when (or (stringp (car defs))
 713               (numberp (car defs)))
 714       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 715     (unless (assq 'nntp-address defs)
 716       (setq defs (append defs (list (list 'nntp-address server)))))
 717     (nnoo-change-server 'nntp server defs)
 718     (unless connectionless
 719       (or (nntp-find-connection nntp-server-buffer)
 720           (nntp-open-connection nntp-server-buffer)))))
 721
 722 (deffoo nntp-close-server (&optional server)
 723   (nntp-possibly-change-group nil server t)
 724   (let ((process (nntp-find-connection nntp-server-buffer)))
 725     (while process
 726       (when (memq (process-status process) '(open run))
 727         (ignore-errors
 728           (nntp-send-string process "QUIT")
 729           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 730             ;; Ok, this is evil, but when using telnet and stuff
 731             ;; as the connection method, it's important that the
 732             ;; QUIT command actually is sent out before we kill
 733             ;; the process.
 734             (sleep-for 1))))
 735       (nntp-kill-buffer (process-buffer process))
 736       (setq process (car (pop nntp-connection-alist))))
 737     (nnoo-close-server 'nntp)))
 738
 739 (deffoo nntp-request-close ()
 740   (let (process)
 741     (while (setq process (pop nntp-connection-list))
 742       (when (memq (process-status process) '(open run))
 743         (ignore-errors
 744           (nntp-send-string process "QUIT")
 745           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 746             ;; Ok, this is evil, but when using telnet and stuff
 747             ;; as the connection method, it's important that the
 748             ;; QUIT command actually is sent out before we kill
 749             ;; the process.
 750             (sleep-for 1))))
 751       (nntp-kill-buffer (process-buffer process)))))
 752
 753 (deffoo nntp-request-list (&optional server)
 754   (nntp-possibly-change-group nil server)
 755   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 756
 757 (deffoo nntp-request-list-newsgroups (&optional server)
 758   (nntp-possibly-change-group nil server)
 759   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 760
 761 (deffoo nntp-request-newgroups (date &optional server)
 762   (nntp-possibly-change-group nil server)
 763   (save-excursion
 764     (set-buffer nntp-server-buffer)
 765     (prog1
 766         (nntp-send-command
 767          "^\\.\r?\n" "NEWGROUPS"
 768          (format-time-string "%y%m%d %H%M%S" (date-to-time date)))
 769       (nntp-decode-text))))
 770
 771 (deffoo nntp-request-post (&optional server)
 772   (nntp-possibly-change-group nil server)
 773   (when (nntp-send-command "^[23].*\r?\n" "POST")
 774     (nntp-send-buffer "^[23].*\n")))
 775
 776 (deffoo nntp-request-type (group article)
 777   'news)
 778
 779 (deffoo nntp-asynchronous-p ()
 780   t)
 781
 782 ;;; Hooky functions.
 783
 784 (defun nntp-send-mode-reader ()
 785   "Send the MODE READER command to the nntp server.
 786 This function is supposed to be called from `nntp-server-opened-hook'.
 787 It will make innd servers spawn an nnrpd process to allow actual article
 788 reading."
 789   (nntp-send-command "^.*\n" "MODE READER"))
 790
 791 (defun nntp-send-authinfo (&optional send-if-force)
 792   "Send the AUTHINFO to the nntp server.
 793 It will look in the \"~/.authinfo\" file for matching entries.  If
 794 nothing suitable is found there, it will prompt for a user name
 795 and a password.
 796
 797 If SEND-IF-FORCE, only send authinfo to the server if the
 798 .authinfo file has the FORCE token."
 799   (let* ((list (gnus-parse-netrc nntp-authinfo-file))
 800          (alist (gnus-netrc-machine list nntp-address "nntp"))
 801          (force (gnus-netrc-get alist "force"))
 802          (user (or (gnus-netrc-get alist "login") nntp-authinfo-user))
 803          (passwd (gnus-netrc-get alist "password")))
 804     (when (or (not send-if-force)
 805               force)
 806       (unless user
 807         (setq user (read-string (format "NNTP (%s) user name: " nntp-address))
 808               nntp-authinfo-user user))
 809       (unless (member user '(nil ""))
 810         (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 811         (when t                         ;???Should check if AUTHINFO succeeded
 812           (nntp-send-command
 813            "^2.*\r?\n" "AUTHINFO PASS"
 814            (or passwd
 815                nntp-authinfo-password
 816                (setq nntp-authinfo-password
 817                      (mail-source-read-passwd
 818                       (format "NNTP (%s@%s) password: "
 819                               user nntp-address))))))))))
 820
 821 (defun nntp-send-nosy-authinfo ()
 822   "Send the AUTHINFO to the nntp server."
 823   (let ((user (read-string (format "NNTP (%s) user name: " nntp-address))))
 824     (unless (member user '(nil ""))
 825       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 826       (when t                           ;???Should check if AUTHINFO succeeded
 827         (nntp-send-command "^2.*\r?\n" "AUTHINFO PASS"
 828                            (mail-source-read-passwd "NNTP (%s@%s) password: "
 829                                                     user nntp-address))))))
 830
 831 (defun nntp-send-authinfo-from-file ()
 832   "Send the AUTHINFO to the nntp server.
 833
 834 The authinfo login name is taken from the user's login name and the
 835 password contained in '~/.nntp-authinfo'."
 836   (when (file-exists-p "~/.nntp-authinfo")
 837     (with-temp-buffer
 838       (insert-file-contents "~/.nntp-authinfo")
 839       (goto-char (point-min))
 840       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" (user-login-name))
 841       (nntp-send-command
 842        "^2.*\r?\n" "AUTHINFO PASS"
 843        (buffer-substring (point) (progn (end-of-line) (point)))))))
 844
 845 ;;; Internal functions.
 846
 847 (defun nntp-handle-authinfo (process)
 848   "Take care of an authinfo response from the server."
 849   (let ((last nntp-last-command))
 850     (funcall nntp-authinfo-function)
 851     ;; We have to re-send the function that was interrupted by
 852     ;; the authinfo request.
 853     (save-excursion
 854       (set-buffer nntp-server-buffer)
 855       (erase-buffer))
 856     (nntp-send-string process last)))
 857
 858 (defun nntp-make-process-buffer (buffer)
 859   "Create a new, fresh buffer usable for nntp process connections."
 860   (save-excursion
 861     (set-buffer
 862      (generate-new-buffer
 863       (format " *server %s %s %s*"
 864               nntp-address nntp-port-number
 865               (gnus-buffer-exists-p buffer))))
 866     (mm-enable-multibyte)
 867     (set (make-local-variable 'after-change-functions) nil)
 868     (set (make-local-variable 'nntp-process-wait-for) nil)
 869     (set (make-local-variable 'nntp-process-callback) nil)
 870     (set (make-local-variable 'nntp-process-to-buffer) nil)
 871     (set (make-local-variable 'nntp-process-start-point) nil)
 872     (set (make-local-variable 'nntp-process-decode) nil)
 873     (current-buffer)))
 874
 875 (defun nntp-open-connection (buffer)
 876   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 877   (run-hooks 'nntp-prepare-server-hook)
 878   (let* ((pbuffer (nntp-make-process-buffer buffer))
 879          (timer
 880           (and nntp-connection-timeout
 881                (nnheader-run-at-time
 882                 nntp-connection-timeout nil
 883                 `(lambda ()
 884                    (nntp-kill-buffer ,pbuffer)))))
 885          (process
 886           (condition-case ()
 887               (let ((coding-system-for-read nntp-coding-system-for-read)
 888                     (coding-system-for-write nntp-coding-system-for-write))
 889                 (funcall nntp-open-connection-function pbuffer))
 890             (error nil)
 891             (quit
 892              (message "Quit opening connection")
 893              (nntp-kill-buffer pbuffer)
 894              (signal 'quit nil)
 895              nil))))
 896     (when timer
 897       (nnheader-cancel-timer timer))
 898     (unless process
 899       (nntp-kill-buffer pbuffer))
 900     (when (and (buffer-name pbuffer)
 901                process)
 902       (process-kill-without-query process)
 903       (if (and (nntp-wait-for process "^2.*\n" buffer nil t)
 904                (memq (process-status process) '(open run)))
 905           (prog1
 906               (caar (push (list process buffer nil) nntp-connection-alist))
 907             (push process nntp-connection-list)
 908             (save-excursion
 909               (set-buffer pbuffer)
 910               (nntp-read-server-type)
 911               (erase-buffer)
 912               (set-buffer nntp-server-buffer)
 913               (let ((nnheader-callback-function nil))
 914                 (run-hooks 'nntp-server-opened-hook)
 915                 (nntp-send-authinfo t))))
 916         (nntp-kill-buffer (process-buffer process))
 917         nil))))
 918
 919 (defun nntp-open-network-stream (buffer)
 920   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 921
 922 (defun nntp-open-ssl-stream (buffer)
 923   (let* ((ssl-program-arguments '("-connect" (concat host ":" service)))
 924          (proc (open-ssl-stream "nntpd" buffer nntp-address nntp-port-number)))
 925     (save-excursion
 926       (set-buffer buffer)
 927       (nntp-wait-for-string "^\r*20[01]")
 928       (beginning-of-line)
 929       (delete-region (point-min) (point))
 930       proc)))
 931
 932 (defun nntp-read-server-type ()
 933   "Find out what the name of the server we have connected to is."
 934   ;; Wait for the status string to arrive.
 935   (setq nntp-server-type (buffer-string))
 936   (let ((alist nntp-server-action-alist)
 937         (case-fold-search t)
 938         entry)
 939     ;; Run server-specific commands.
 940     (while alist
 941       (setq entry (pop alist))
 942       (when (string-match (car entry) nntp-server-type)
 943         (if (and (listp (cadr entry))
 944                  (not (eq 'lambda (caadr entry))))
 945             (eval (cadr entry))
 946           (funcall (cadr entry)))))))
 947
 948 (defun nntp-async-wait (process wait-for buffer decode callback)
 949   (save-excursion
 950     (set-buffer (process-buffer process))
 951     (unless nntp-inside-change-function
 952       (erase-buffer))
 953     (setq nntp-process-wait-for wait-for
 954           nntp-process-to-buffer buffer
 955           nntp-process-decode decode
 956           nntp-process-callback callback
 957           nntp-process-start-point (point-max))
 958     (setq after-change-functions '(nntp-after-change-function))
 959     (if nntp-async-needs-kluge
 960         (nntp-async-kluge process))))
 961
 962 (defun nntp-async-kluge (process)
 963   ;; emacs 20.3 bug: process output with encoding 'binary
 964   ;; doesn't trigger after-change-functions.
 965   (unless nntp-async-timer
 966     (setq nntp-async-timer
 967           (nnheader-run-at-time 1 1 'nntp-async-timer-handler)))
 968   (add-to-list 'nntp-async-process-list process))
 969
 970 (defun nntp-async-timer-handler ()
 971   (mapcar
 972    (lambda (proc)
 973      (if (memq (process-status proc) '(open run))
 974          (nntp-async-trigger proc)
 975        (nntp-async-stop proc)))
 976    nntp-async-process-list))
 977
 978 (defun nntp-async-stop (proc)
 979   (setq nntp-async-process-list (delq proc nntp-async-process-list))
 980   (when (and nntp-async-timer (not nntp-async-process-list))
 981     (nnheader-cancel-timer nntp-async-timer)
 982     (setq nntp-async-timer nil)))
 983
 984 (defun nntp-after-change-function (beg end len)
 985   (unwind-protect
 986       ;; we only care about insertions at eob
 987       (when (and (eq 0 len) (eq (point-max) end))
 988         (save-match-data
 989           (let ((proc (get-buffer-process (current-buffer))))
 990             (when proc
 991               (nntp-async-trigger proc)))))
 992     ;; any throw from after-change-functions will leave it
 993     ;; set to nil.  so we reset it here, if necessary.
 994     (when quit-flag
 995       (setq after-change-functions '(nntp-after-change-function)))))
 996
 997 (defun nntp-async-trigger (process)
 998   (save-excursion
 999     (set-buffer (process-buffer process))
1000     (when nntp-process-callback
1001       ;; do we have an error message?
1002       (goto-char nntp-process-start-point)
1003       (if (memq (following-char) '(?4 ?5))
1004           ;; wants credentials?
1005           (if (looking-at "480")
1006               (nntp-handle-authinfo process)
1007             ;; report error message.
1008             (nntp-snarf-error-message)
1009             (nntp-do-callback nil))
1010
1011         ;; got what we expect?
1012         (goto-char (point-max))
1013         (when (re-search-backward
1014                nntp-process-wait-for nntp-process-start-point t)
1015           (nntp-async-stop process)
1016           ;; convert it.
1017           (when (gnus-buffer-exists-p nntp-process-to-buffer)
1018             (let ((buf (current-buffer))
1019                   (start nntp-process-start-point)
1020                   (decode nntp-process-decode))
1021               (save-excursion
1022                 (set-buffer nntp-process-to-buffer)
1023                 (goto-char (point-max))
1024                 (save-restriction
1025                   (narrow-to-region (point) (point))
1026                   (insert-buffer-substring buf start)
1027                   (when decode
1028                     (nntp-decode-text))))))
1029           ;; report it.
1030           (goto-char (point-max))
1031           (nntp-do-callback
1032            (buffer-name (get-buffer nntp-process-to-buffer))))))))
1033
1034 (defun nntp-do-callback (arg)
1035   (let ((callback nntp-process-callback)
1036         (nntp-inside-change-function t))
1037     (setq nntp-process-callback nil)
1038     (funcall callback arg)))
1039
1040 (defun nntp-snarf-error-message ()
1041   "Save the error message in the current buffer."
1042   (let ((message (buffer-string)))
1043     (while (string-match "[\r\n]+" message)
1044       (setq message (replace-match " " t t message)))
1045     (nnheader-report 'nntp message)
1046     message))
1047
1048 (defun nntp-accept-process-output (process &optional timeout)
1049   "Wait for output from PROCESS and message some dots."
1050   (save-excursion
1051     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
1052                     nntp-server-buffer))
1053     (let ((len (/ (point-max) 1024))
1054           message-log-max)
1055       (unless (< len 10)
1056         (setq nntp-have-messaged t)
1057         (nnheader-message 7 "nntp read: %dk" len)))
1058     (accept-process-output process (or timeout 1))))
1059
1060 (defun nntp-accept-response ()
1061   "Wait for output from the process that outputs to BUFFER."
1062   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
1063
1064 (defun nntp-possibly-change-group (group server &optional connectionless)
1065   (let ((nnheader-callback-function nil))
1066     (when server
1067       (or (nntp-server-opened server)
1068           (nntp-open-server server nil connectionless)))
1069
1070     (unless connectionless
1071       (or (nntp-find-connection nntp-server-buffer)
1072           (nntp-open-connection nntp-server-buffer))))
1073
1074   (when group
1075     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
1076       (when (not (equal group (caddr entry)))
1077         (save-excursion
1078           (set-buffer (process-buffer (car entry)))
1079           (erase-buffer)
1080           (nntp-send-command "^[245].*\n" "GROUP" group)
1081           (setcar (cddr entry) group)
1082           (erase-buffer))))))
1083
1084 (defun nntp-decode-text (&optional cr-only)
1085   "Decode the text in the current buffer."
1086   (goto-char (point-min))
1087   (while (search-forward "\r" nil t)
1088     (delete-char -1))
1089   (unless cr-only
1090     ;; Remove trailing ".\n" end-of-transfer marker.
1091     (goto-char (point-max))
1092     (forward-line -1)
1093     (when (looking-at ".\n")
1094       (delete-char 2))
1095     ;; Delete status line.
1096     (goto-char (point-min))
1097     (while (looking-at "[1-5][0-9][0-9] .*\n")
1098       ;; For some unknown reason, there is more than one status line.
1099       (delete-region (point) (progn (forward-line 1) (point))))
1100     ;; Remove "." -> ".." encoding.
1101     (while (search-forward "\n.." nil t)
1102       (delete-char -1))))
1103
1104 (defun nntp-encode-text ()
1105   "Encode the text in the current buffer."
1106   (save-excursion
1107     ;; Replace "." at beginning of line with "..".
1108     (goto-char (point-min))
1109     (while (re-search-forward "^\\." nil t)
1110       (insert "."))
1111     (goto-char (point-max))
1112     ;; Insert newline at the end of the buffer.
1113     (unless (bolp)
1114       (insert "\n"))
1115     ;; Insert `.' at end of buffer (end of text mark).
1116     (goto-char (point-max))
1117     (insert ".\n")
1118     (goto-char (point-min))
1119     (while (not (eobp))
1120       (end-of-line)
1121       (delete-char 1)
1122       (insert nntp-end-of-line))))
1123
1124 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
1125   (set-buffer nntp-server-buffer)
1126   (erase-buffer)
1127   (cond
1128
1129    ;; This server does not talk NOV.
1130    ((not nntp-server-xover)
1131     nil)
1132
1133    ;; We don't care about gaps.
1134    ((or (not nntp-nov-gap)
1135         fetch-old)
1136     (nntp-send-xover-command
1137      (if fetch-old
1138          (if (numberp fetch-old)
1139              (max 1 (- (car articles) fetch-old))
1140            1)
1141        (car articles))
1142      (car (last articles)) 'wait)
1143
1144     (goto-char (point-min))
1145     (when (looking-at "[1-5][0-9][0-9] .*\n")
1146       (delete-region (point) (progn (forward-line 1) (point))))
1147     (while (search-forward "\r" nil t)
1148       (replace-match "" t t))
1149     (goto-char (point-max))
1150     (forward-line -1)
1151     (when (looking-at "\\.")
1152       (delete-region (point) (progn (forward-line 1) (point)))))
1153
1154    ;; We do it the hard way.  For each gap, an XOVER command is sent
1155    ;; to the server.  We do not wait for a reply from the server, we
1156    ;; just send them off as fast as we can.  That means that we have
1157    ;; to count the number of responses we get back to find out when we
1158    ;; have gotten all we asked for.
1159    ((numberp nntp-nov-gap)
1160     (let ((count 0)
1161           (received 0)
1162           last-point
1163           in-process-buffer-p
1164           (buf nntp-server-buffer)
1165           (process-buffer (nntp-find-connection-buffer nntp-server-buffer))
1166           first)
1167       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
1168       ;; that means that the server does not understand XOVER, but we
1169       ;; won't know that until we try.
1170       (while (and nntp-server-xover articles)
1171         (setq first (car articles))
1172         ;; Search forward until we find a gap, or until we run out of
1173         ;; articles.
1174         (while (and (cdr articles)
1175                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
1176           (setq articles (cdr articles)))
1177
1178         (setq in-process-buffer-p (stringp nntp-server-xover))
1179         (nntp-send-xover-command first (car articles))
1180         (setq articles (cdr articles))
1181
1182         (when (and nntp-server-xover in-process-buffer-p)
1183           ;; Don't count tried request.
1184           (setq count (1+ count))
1185
1186           ;; Every 400 requests we have to read the stream in
1187           ;; order to avoid deadlocks.
1188           (when (or (null articles)     ;All requests have been sent.
1189                     (zerop (% count nntp-maximum-request)))
1190
1191             (nntp-accept-response)
1192             ;; On some Emacs versions the preceding function has a
1193             ;; tendency to change the buffer.  Perhaps.  It's quite
1194             ;; difficult to reproduce, because it only seems to happen
1195             ;; once in a blue moon.
1196             (set-buffer process-buffer)
1197             (while (progn
1198                      (goto-char (or last-point (point-min)))
1199                      ;; Count replies.
1200                      (while (re-search-forward "^[0-9][0-9][0-9] .*\n" nil t)
1201                        (incf received))
1202                      (setq last-point (point))
1203                      (< received count))
1204               (nntp-accept-response)
1205               (set-buffer process-buffer))
1206             (set-buffer buf))))
1207
1208       (when nntp-server-xover
1209         (when in-process-buffer-p
1210           (set-buffer process-buffer)
1211           ;; Wait for the reply from the final command.
1212           (goto-char (point-max))
1213           (while (not (re-search-backward "^[0-9][0-9][0-9] " nil t))
1214             (nntp-accept-response)
1215             (set-buffer process-buffer)
1216             (goto-char (point-max)))
1217           (when (looking-at "^[23]")
1218             (while (progn
1219                      (goto-char (point-max))
1220                      (forward-line -1)
1221                      (not (looking-at "^\\.\r?\n")))
1222               (nntp-accept-response)
1223               (set-buffer process-buffer)))
1224           (set-buffer buf)
1225           (goto-char (point-max))
1226           (insert-buffer-substring process-buffer)
1227           (set-buffer process-buffer)
1228           (erase-buffer)
1229           (set-buffer buf))
1230
1231         ;; We remove any "." lines and status lines.
1232         (goto-char (point-min))
1233         (while (search-forward "\r" nil t)
1234           (delete-char -1))
1235         (goto-char (point-min))
1236         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
1237         t))))
1238
1239   nntp-server-xover)
1240
1241 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
1242   "Send the XOVER command to the server."
1243   (let ((range (format "%d-%d" beg end))
1244         (nntp-inhibit-erase t))
1245     (if (stringp nntp-server-xover)
1246         ;; If `nntp-server-xover' is a string, then we just send this
1247         ;; command.
1248         (if wait-for-reply
1249             (nntp-send-command-nodelete
1250              "\r?\n\\.\r?\n" nntp-server-xover range)
1251           ;; We do not wait for the reply.
1252           (nntp-send-command-nodelete nil nntp-server-xover range))
1253       (let ((commands nntp-xover-commands))
1254         ;; `nntp-xover-commands' is a list of possible XOVER commands.
1255         ;; We try them all until we get at positive response.
1256         (while (and commands (eq nntp-server-xover 'try))
1257           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
1258           (save-excursion
1259             (set-buffer nntp-server-buffer)
1260             (goto-char (point-min))
1261             (and (looking-at "[23]")    ; No error message.
1262                  ;; We also have to look at the lines.  Some buggy
1263                  ;; servers give back simple lines with just the
1264                  ;; article number.  How... helpful.
1265                  (progn
1266                    (forward-line 1)
1267                    (looking-at "[0-9]+\t...")) ; More text after number.
1268                  (setq nntp-server-xover (car commands))))
1269           (setq commands (cdr commands)))
1270         ;; If none of the commands worked, we disable XOVER.
1271         (when (eq nntp-server-xover 'try)
1272           (save-excursion
1273             (set-buffer nntp-server-buffer)
1274             (erase-buffer)
1275             (setq nntp-server-xover nil)))
1276         nntp-server-xover))))
1277
1278 ;;; Alternative connection methods.
1279
1280 (defun nntp-wait-for-string (regexp)
1281   "Wait until string arrives in the buffer."
1282   (let ((buf (current-buffer)))
1283     (goto-char (point-min))
1284     (while (not (re-search-forward regexp nil t))
1285       (accept-process-output (nntp-find-connection nntp-server-buffer))
1286       (set-buffer buf)
1287       (goto-char (point-min)))))
1288
1289 (defun nntp-open-telnet (buffer)
1290   (save-excursion
1291     (set-buffer buffer)
1292     (erase-buffer)
1293     (let ((proc (apply
1294                  'start-process
1295                  "nntpd" buffer nntp-telnet-command nntp-telnet-switches))
1296           (case-fold-search t))
1297       (when (memq (process-status proc) '(open run))
1298         (nntp-wait-for-string "^r?telnet")
1299         (process-send-string proc "set escape \^X\n")
1300         (cond
1301          ((and nntp-open-telnet-envuser nntp-telnet-user-name)
1302           (process-send-string proc (concat "open " "-l" nntp-telnet-user-name
1303                                             nntp-address "\n")))
1304          (t
1305           (process-send-string proc (concat "open " nntp-address "\n"))))
1306         (cond
1307          ((not nntp-open-telnet-envuser)
1308           (nntp-wait-for-string "^\r*.?login:")
1309           (process-send-string
1310            proc (concat
1311                  (or nntp-telnet-user-name
1312                      (setq nntp-telnet-user-name (read-string "login: ")))
1313                  "\n"))))
1314         (nntp-wait-for-string "^\r*.?password:")
1315         (process-send-string
1316          proc (concat
1317                (or nntp-telnet-passwd
1318                    (setq nntp-telnet-passwd
1319                          (mail-source-read-passwd "Password: ")))
1320                "\n"))
1321         (nntp-wait-for-string nntp-telnet-shell-prompt)
1322         (process-send-string
1323          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
1324         (nntp-wait-for-string "^\r*20[01]")
1325         (beginning-of-line)
1326         (delete-region (point-min) (point))
1327         (process-send-string proc "\^]")
1328         (nntp-wait-for-string "^r?telnet")
1329         (process-send-string proc "mode character\n")
1330         (accept-process-output proc 1)
1331         (sit-for 1)
1332         (goto-char (point-min))
1333         (forward-line 1)
1334         (delete-region (point) (point-max)))
1335       proc)))
1336
1337 (defun nntp-open-rlogin (buffer)
1338   "Open a connection to SERVER using rsh."
1339   (let ((proc (if nntp-rlogin-user-name
1340                   (apply 'start-process
1341                          "nntpd" buffer nntp-rlogin-program
1342                          nntp-address "-l" nntp-rlogin-user-name
1343                          nntp-rlogin-parameters)
1344                 (apply 'start-process
1345                        "nntpd" buffer nntp-rlogin-program nntp-address
1346                        nntp-rlogin-parameters))))
1347     (save-excursion
1348       (set-buffer buffer)
1349       (nntp-wait-for-string "^\r*20[01]")
1350       (beginning-of-line)
1351       (delete-region (point-min) (point))
1352       proc)))
1353
1354 (defun nntp-find-group-and-number ()
1355   (save-excursion
1356     (save-restriction
1357       (set-buffer nntp-server-buffer)
1358       (narrow-to-region (goto-char (point-min))
1359                         (or (search-forward "\n\n" nil t) (point-max)))
1360       (goto-char (point-min))
1361       ;; We first find the number by looking at the status line.
1362       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
1363                          (string-to-int
1364                           (buffer-substring (match-beginning 1)
1365                                             (match-end 1)))))
1366             group newsgroups xref)
1367         (and number (zerop number) (setq number nil))
1368         ;; Then we find the group name.
1369         (setq group
1370               (cond
1371                ;; If there is only one group in the Newsgroups header,
1372                ;; then it seems quite likely that this article comes
1373                ;; from that group, I'd say.
1374                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1375                      (not (string-match "," newsgroups)))
1376                 newsgroups)
1377                ;; If there is more than one group in the Newsgroups
1378                ;; header, then the Xref header should be filled out.
1379                ;; We hazard a guess that the group that has this
1380                ;; article number in the Xref header is the one we are
1381                ;; looking for.  This might very well be wrong if this
1382                ;; article happens to have the same number in several
1383                ;; groups, but that's life.
1384                ((and (setq xref (mail-fetch-field "xref"))
1385                      number
1386                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1387                 (substring xref (match-beginning 1) (match-end 1)))
1388                (t "")))
1389         (when (string-match "\r" group)
1390           (setq group (substring group 0 (match-beginning 0))))
1391         (cons group number)))))
1392
1393 (provide 'nntp)
1394
1395 ;;; nntp.el ends here