cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 1988,89,90,93,94,95,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'timezone)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nnspool)
  36
  37 (defvoo nnspool-inews-program news-inews-program
  38   "Program to post news.
  39 This is most commonly `inews' or `injnews'.")
  40
  41 (defvoo nnspool-inews-switches '("-h" "-S")
  42   "Switches for nnspool-request-post to pass to `inews' for posting news.
  43 If you are using Cnews, you probably should set this variable to nil.")
  44
  45 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  46   "Local news spool directory.")
  47
  48 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  49   "Local news nov directory.")
  50
  51 (defvoo nnspool-lib-dir "/usr/lib/news/"
  52   "Where the local news library files are stored.")
  53
  54 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  55   "Local news active file.")
  56
  57 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  58   "Local news newsgroups file.")
  59
  60 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  61   "Local news distributions file.")
  62
  63 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  64   "Local news history file.")
  65
  66 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  67   "Local news active date file.")
  68
  69 (defvoo nnspool-large-newsgroup 50
  70   "The number of the articles which indicates a large newsgroup.
  71 If the number of the articles is greater than the value, verbose
  72 messages will be shown to indicate the current status.")
  73
  74 (defvoo nnspool-nov-is-evil nil
  75   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  76
  77 (defconst nnspool-sift-nov-with-sed nil
  78   "If non-nil, use sed to get the relevant portion from the overview file.
  79 If nil, nnspool will load the entire file into a buffer and process it
  80 there.")
  81
  82 (defvoo nnspool-rejected-article-hook nil
  83   "*A hook that will be run when an article has been rejected by the server.")
  84
  85 \f
  86
  87 (defconst nnspool-version "nnspool 2.0"
  88   "Version numbers of this version of NNSPOOL.")
  89
  90 (defvoo nnspool-current-directory nil
  91   "Current news group directory.")
  92
  93 (defvoo nnspool-current-group nil)
  94 (defvoo nnspool-status-string "")
  95
  96 \f
  97 ;;; Interface functions.
  98
  99 (nnoo-define-basics nnspool)
 100
 101 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 102   "Retrieve the headers of ARTICLES."
 103   (save-excursion
 104     (set-buffer nntp-server-buffer)
 105     (erase-buffer)
 106     (when (nnspool-possibly-change-directory group)
 107       (let* ((number (length articles))
 108              (count 0)
 109              (default-directory nnspool-current-directory)
 110              (do-message (and (numberp nnspool-large-newsgroup)
 111                               (> number nnspool-large-newsgroup)))
 112              file beg article ag)
 113         (if (and (numberp (car articles))
 114                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 115             ;; We successfully retrieved the NOV headers.
 116             'nov
 117           ;; No NOV headers here, so we do it the hard way.
 118           (while (setq article (pop articles))
 119             (if (stringp article)
 120                 ;; This is a Message-ID.
 121                 (setq ag (nnspool-find-id article)
 122                       file (and ag (nnspool-article-pathname
 123                                     (car ag) (cdr ag)))
 124                       article (cdr ag))
 125               ;; This is an article in the current group.
 126               (setq file (int-to-string article)))
 127             ;; Insert the head of the article.
 128             (when (and file
 129                        (file-exists-p file))
 130               (insert "221 ")
 131               (princ article (current-buffer))
 132               (insert " Article retrieved.\n")
 133               (setq beg (point))
 134               (inline (nnheader-insert-head file))
 135               (goto-char beg)
 136               (search-forward "\n\n" nil t)
 137               (forward-char -1)
 138               (insert ".\n")
 139               (delete-region (point) (point-max)))
 140
 141             (and do-message
 142                  (zerop (% (incf count) 20))
 143                  (message "nnspool: Receiving headers... %d%%"
 144                           (/ (* count 100) number))))
 145
 146           (when do-message
 147             (message "nnspool: Receiving headers...done"))
 148
 149           ;; Fold continuation lines.
 150           (nnheader-fold-continuation-lines)
 151           'headers)))))
 152
 153 (deffoo nnspool-open-server (server &optional defs)
 154   (nnoo-change-server 'nnspool server defs)
 155   (cond
 156    ((not (file-exists-p nnspool-spool-directory))
 157     (nnspool-close-server)
 158     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 159                      nnspool-spool-directory))
 160    ((not (file-directory-p
 161           (directory-file-name
 162            (file-truename nnspool-spool-directory))))
 163     (nnspool-close-server)
 164     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 165    ((not (file-exists-p nnspool-active-file))
 166     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 167                      nnspool-active-file))
 168    (t
 169     (nnheader-report 'nnspool "Opened server %s using directory %s"
 170                      server nnspool-spool-directory)
 171     t)))
 172
 173 (deffoo nnspool-request-article (id &optional group server buffer)
 174   "Select article by message ID (or number)."
 175   (nnspool-possibly-change-directory group)
 176   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 177         file ag)
 178     (if (stringp id)
 179         ;; This is a Message-ID.
 180         (when (setq ag (nnspool-find-id id))
 181           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 182       (setq file (nnspool-article-pathname nnspool-current-group id)))
 183     (and file
 184          (file-exists-p file)
 185          (not (file-directory-p file))
 186          (save-excursion (nnspool-find-file file))
 187          ;; We return the article number and group name.
 188          (if (numberp id)
 189              (cons nnspool-current-group id)
 190            ag))))
 191
 192 (deffoo nnspool-request-body (id &optional group server)
 193   "Select article body by message ID (or number)."
 194   (nnspool-possibly-change-directory group)
 195   (let ((res (nnspool-request-article id)))
 196     (when res
 197       (save-excursion
 198         (set-buffer nntp-server-buffer)
 199         (goto-char (point-min))
 200         (when (search-forward "\n\n" nil t)
 201           (delete-region (point-min) (point)))
 202         res))))
 203
 204 (deffoo nnspool-request-head (id &optional group server)
 205   "Select article head by message ID (or number)."
 206   (nnspool-possibly-change-directory group)
 207   (let ((res (nnspool-request-article id)))
 208     (when res
 209       (save-excursion
 210         (set-buffer nntp-server-buffer)
 211         (goto-char (point-min))
 212         (when (search-forward "\n\n" nil t)
 213           (delete-region (1- (point)) (point-max)))
 214         (nnheader-fold-continuation-lines)))
 215     res))
 216
 217 (deffoo nnspool-request-group (group &optional server dont-check)
 218   "Select news GROUP."
 219   (let ((pathname (nnspool-article-pathname group))
 220         dir)
 221     (if (not (file-directory-p pathname))
 222         (nnheader-report
 223          'nnspool "Invalid group name (no such directory): %s" group)
 224       (setq nnspool-current-directory pathname)
 225       (nnheader-report 'nnspool "Selected group %s" group)
 226       (if dont-check
 227           (progn
 228             (nnheader-report 'nnspool "Selected group %s" group)
 229             t)
 230         ;; Yes, completely empty spool directories *are* possible.
 231         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 232         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 233           (setq dir
 234                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 235         (if dir
 236             (nnheader-insert
 237              "211 %d %d %d %s\n" (length dir) (car dir)
 238              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 239              group)
 240           (nnheader-report 'nnspool "Empty group %s" group)
 241           (nnheader-insert "211 0 0 0 %s\n" group))))))
 242
 243 (deffoo nnspool-request-type (group &optional article)
 244   'news)
 245
 246 (deffoo nnspool-close-group (group &optional server)
 247   t)
 248
 249 (deffoo nnspool-request-list (&optional server)
 250   "List active newsgroups."
 251   (save-excursion
 252     (or (nnspool-find-file nnspool-active-file)
 253         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 254
 255 (deffoo nnspool-request-list-newsgroups (&optional server)
 256   "List newsgroups (defined in NNTP2)."
 257   (save-excursion
 258     (or (nnspool-find-file nnspool-newsgroups-file)
 259         (nnheader-report 'nnspool (nnheader-file-error
 260                                    nnspool-newsgroups-file)))))
 261
 262 (deffoo nnspool-request-list-distributions (&optional server)
 263   "List distributions (defined in NNTP2)."
 264   (save-excursion
 265     (or (nnspool-find-file nnspool-distributions-file)
 266         (nnheader-report 'nnspool (nnheader-file-error
 267                                    nnspool-distributions-file)))))
 268
 269 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 270 (deffoo nnspool-request-newgroups (date &optional server)
 271   "List groups created after DATE."
 272   (if (nnspool-find-file nnspool-active-times-file)
 273       (save-excursion
 274         ;; Find the last valid line.
 275         (goto-char (point-max))
 276         (while (and (not (looking-at
 277                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 278                     (zerop (forward-line -1))))
 279         (let ((seconds (nnspool-seconds-since-epoch date))
 280               groups)
 281           ;; Go through lines and add the latest groups to a list.
 282           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 283                       (progn
 284                         ;; We insert a .0 to make the list reader
 285                         ;; interpret the number as a float.  It is far
 286                         ;; too big to be stored in a lisp integer.
 287                         (goto-char (1- (match-end 0)))
 288                         (insert ".0")
 289                         (> (progn
 290                              (goto-char (match-end 1))
 291                              (read (current-buffer)))
 292                            seconds))
 293                       (push (buffer-substring
 294                                           (match-beginning 1) (match-end 1))
 295                                          groups)
 296                       (zerop (forward-line -1))))
 297           (erase-buffer)
 298           (while groups
 299             (insert (car groups) " 0 0 y\n")
 300             (setq groups (cdr groups))))
 301         t)
 302     nil))
 303
 304 (deffoo nnspool-request-post (&optional server)
 305   "Post a new news in current buffer."
 306   (save-excursion
 307     (let* ((process-connection-type nil) ; t bugs out on Solaris
 308            (inews-buffer (generate-new-buffer " *nnspool post*"))
 309            (proc
 310             (condition-case err
 311                 (apply 'start-process "*nnspool inews*" inews-buffer
 312                        nnspool-inews-program nnspool-inews-switches)
 313               (error
 314                (nnheader-report 'nnspool "inews error: %S" err)))))
 315       (if (not proc)
 316           ;; The inews program failed.
 317           ()
 318         (nnheader-report 'nnspool "")
 319         (set-process-sentinel proc 'nnspool-inews-sentinel)
 320         (process-send-region proc (point-min) (point-max))
 321         ;; We slap a condition-case around this, because the process may
 322         ;; have exited already...
 323         (condition-case nil
 324             (process-send-eof proc)
 325           (error nil))
 326         t))))
 327
 328
 329 \f
 330 ;;; Internal functions.
 331
 332 (defun nnspool-inews-sentinel (proc status)
 333   (save-excursion
 334     (set-buffer (process-buffer proc))
 335     (goto-char (point-min))
 336     (if (or (zerop (buffer-size))
 337             (search-forward "spooled" nil t))
 338         (kill-buffer (current-buffer))
 339       ;; Make status message by folding lines.
 340       (while (re-search-forward "[ \t\n]+" nil t)
 341         (replace-match " " t t))
 342       (nnheader-report 'nnspool "%s" (buffer-string))
 343       (message "nnspool: %s" nnspool-status-string)
 344       (ding)
 345       (run-hooks 'nnspool-rejected-article-hook))))
 346
 347 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 348   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 349       nil
 350     (let ((nov (nnheader-group-pathname
 351                 nnspool-current-group nnspool-nov-directory ".overview"))
 352           (arts articles)
 353           last)
 354       (if (not (file-exists-p nov))
 355           ()
 356         (save-excursion
 357           (set-buffer nntp-server-buffer)
 358           (erase-buffer)
 359           (if nnspool-sift-nov-with-sed
 360               (nnspool-sift-nov-with-sed articles nov)
 361             (insert-file-contents nov)
 362             (if (and fetch-old
 363                      (not (numberp fetch-old)))
 364                 t                       ; We want all the headers.
 365               (condition-case ()
 366                   (progn
 367                     ;; Delete unwanted NOV lines.
 368                     (nnheader-nov-delete-outside-range
 369                      (if fetch-old (max 1 (- (car articles) fetch-old))
 370                        (car articles))
 371                      (car (last articles)))
 372                     ;; If the buffer is empty, this wasn't very successful.
 373                     (unless (zerop (buffer-size))
 374                       ;; We check what the last article number was.
 375                       ;; The NOV file may be out of sync with the articles
 376                       ;; in the group.
 377                       (forward-line -1)
 378                       (setq last (read (current-buffer)))
 379                       (if (= last (car articles))
 380                           ;; Yup, it's all there.
 381                           t
 382                         ;; Perhaps not.  We try to find the missing articles.
 383                         (while (and arts
 384                                     (<= last (car arts)))
 385                           (pop arts))
 386                         ;; The articles in `arts' are missing from the buffer.
 387                         (while arts
 388                           (nnspool-insert-nov-head (pop arts)))
 389                         t)))
 390                 ;; The NOV file was corrupted.
 391                 (error nil)))))))))
 392
 393 (defun nnspool-insert-nov-head (article)
 394   "Read the head of ARTICLE, convert to NOV headers, and insert."
 395   (save-excursion
 396     (let ((cur (current-buffer))
 397           buf)
 398       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 399       (when (nnheader-insert-head
 400              (nnspool-article-pathname nnspool-current-group article))
 401         (nnheader-insert-article-line article)
 402         (let ((headers (nnheader-parse-head)))
 403           (set-buffer cur)
 404           (goto-char (point-max))
 405           (nnheader-insert-nov headers)))
 406       (kill-buffer buf))))
 407
 408 (defun nnspool-sift-nov-with-sed (articles file)
 409   (let ((first (car articles))
 410         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 411                      (car articles))))
 412     (call-process "awk" nil t nil
 413                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 414                           (1- first) (1+ last))
 415                   file)))
 416
 417 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 418 ;; Find out what group an article identified by a Message-ID is in.
 419 (defun nnspool-find-id (id)
 420   (save-excursion
 421     (set-buffer (get-buffer-create " *nnspool work*"))
 422     (buffer-disable-undo (current-buffer))
 423     (erase-buffer)
 424     (condition-case ()
 425         (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file)
 426       (error nil))
 427     (goto-char (point-min))
 428     (prog1
 429         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 430           (cons (match-string 1) (string-to-int (match-string 2))))
 431       (kill-buffer (current-buffer)))))
 432
 433 (defun nnspool-find-file (file)
 434   "Insert FILE in server buffer safely."
 435   (set-buffer nntp-server-buffer)
 436   (erase-buffer)
 437   (condition-case ()
 438       (progn (nnheader-insert-file-contents-literally file) t)
 439     (file-error nil)))
 440
 441 (defun nnspool-possibly-change-directory (group)
 442   (if (not group)
 443       t
 444     (let ((pathname (nnspool-article-pathname group)))
 445       (if (file-directory-p pathname)
 446           (setq nnspool-current-directory pathname
 447                 nnspool-current-group group)
 448         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 449
 450 (defun nnspool-article-pathname (group &optional article)
 451   "Find the path for GROUP."
 452   (nnheader-group-pathname group nnspool-spool-directory article))
 453
 454 (defun nnspool-seconds-since-epoch (date)
 455   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 456                         (timezone-parse-date date)))
 457          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 458                         (timezone-parse-time
 459                          (aref (timezone-parse-date date) 3))))
 460          (unix (encode-time (nth 2 ttime) (nth 1 ttime) (nth 0 ttime)
 461                             (nth 2 tdate) (nth 1 tdate) (nth 0 tdate)
 462                             (nth 4 tdate))))
 463     (+ (* (car unix) 65536.0)
 464        (cadr unix))))
 465
 466 (provide 'nnspool)
 467
 468 ;;; nnspool.el ends here