cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 1988,89,90,93,94,95,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'nnheader)
  29 (require 'nntp)
  30 (require 'timezone)
  31
  32 (defvar nnspool-inews-program news-inews-program
  33   "Program to post news.
  34 This is most commonly `inews' or `injnews'.")
  35
  36 (defvar nnspool-inews-switches '("-h")
  37   "Switches for nnspool-request-post to pass to `inews' for posting news.
  38 If you are using Cnews, you probably should set this variable to nil.")
  39
  40 (defvar nnspool-spool-directory (file-name-as-directory news-path)
  41   "Local news spool directory.")
  42
  43 (defvar nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  44   "Local news nov directory.")
  45
  46 (defvar nnspool-lib-dir "/usr/lib/news/"
  47   "Where the local news library files are stored.")
  48
  49 (defvar nnspool-active-file (concat nnspool-lib-dir "active")
  50   "Local news active file.")
  51
  52 (defvar nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  53   "Local news newsgroups file.")
  54
  55 (defvar nnspool-distributions-file (concat nnspool-lib-dir "distributions")
  56   "Local news distributions file.")
  57
  58 (defvar nnspool-history-file (concat nnspool-lib-dir "history")
  59   "Local news history file.")
  60
  61 (defvar nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  62   "Local news active date file.")
  63
  64 (defvar nnspool-large-newsgroup 50
  65   "The number of the articles which indicates a large newsgroup.
  66 If the number of the articles is greater than the value, verbose
  67 messages will be shown to indicate the current status.")
  68
  69 (defvar nnspool-nov-is-evil nil
  70   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  71
  72 (defconst nnspool-sift-nov-with-sed nil
  73   "If non-nil, use sed to get the relevant portion from the overview file.
  74 If nil, nnspool will load the entire file into a buffer and process it
  75 there.")
  76
  77 (defvar nnspool-rejected-article-hook nil
  78   "*A hook that will be run when an article has been rejected by the server.")
  79
  80 \f
  81
  82 (defconst nnspool-version "nnspool 2.0"
  83   "Version numbers of this version of NNSPOOL.")
  84
  85 (defvar nnspool-current-directory nil
  86   "Current news group directory.")
  87
  88 (defvar nnspool-current-group nil)
  89 (defvar nnspool-status-string "")
  90
  91 \f
  92
  93 (defvar nnspool-current-server nil)
  94 (defvar nnspool-server-alist nil)
  95 (defvar nnspool-server-variables
  96   (list
  97    (list 'nnspool-inews-program nnspool-inews-program)
  98    (list 'nnspool-inews-switches nnspool-inews-switches)
  99    (list 'nnspool-spool-directory nnspool-spool-directory)
 100    (list 'nnspool-nov-directory nnspool-nov-directory)
 101    (list 'nnspool-lib-dir nnspool-lib-dir)
 102    (list 'nnspool-active-file nnspool-active-file)
 103    (list 'nnspool-newsgroups-file nnspool-newsgroups-file)
 104    (list 'nnspool-distributions-file nnspool-distributions-file)
 105    (list 'nnspool-history-file nnspool-history-file)
 106    (list 'nnspool-active-times-file nnspool-active-times-file)
 107    (list 'nnspool-large-newsgroup nnspool-large-newsgroup)
 108    (list 'nnspool-nov-is-evil nnspool-nov-is-evil)
 109    (list 'nnspool-sift-nov-with-sed nnspool-sift-nov-with-sed)
 110    '(nnspool-current-directory nil)
 111    '(nnspool-current-group nil)
 112    '(nnspool-status-string "")))
 113
 114 \f
 115 ;;; Interface functions.
 116
 117 (defun nnspool-retrieve-headers (articles &optional group server fetch-old)
 118   "Retrieve the headers of ARTICLES."
 119   (save-excursion
 120     (set-buffer nntp-server-buffer)
 121     (erase-buffer)
 122     (when (nnspool-possibly-change-directory group)
 123       (let* ((number (length articles))
 124              (count 0)
 125              (do-message (and (numberp nnspool-large-newsgroup)
 126                               (> number nnspool-large-newsgroup)))
 127              file beg article ag)
 128         (if (and (numberp (car articles))
 129                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 130             ;; We successfully retrieved the NOV headers.
 131             'nov
 132           ;; No NOV headers here, so we do it the hard way.
 133           (while articles
 134             (setq article (pop articles))
 135             (if (stringp article)
 136                 ;; This is a Message-ID.
 137                 (setq ag (nnspool-find-id article)
 138                       file (and ag (nnspool-article-pathname
 139                                     (car ag) (cdr ag)))
 140                       article (cdr ag))
 141               ;; This is an article in the current group.
 142               (setq file (nnspool-article-pathname
 143                           nnspool-current-group article)))
 144             ;; Insert the head of the article.
 145             (when (and file
 146                        (file-exists-p file))
 147               (insert (format "221 %d Article retrieved.\n" article))
 148               (setq beg (point))
 149               (nnheader-insert-head file)
 150               (goto-char beg)
 151               (search-forward "\n\n" nil t)
 152               (forward-char -1)
 153               (insert ".\n")
 154               (delete-region (point) (point-max)))
 155
 156             (and do-message
 157                  (zerop (% (incf count) 20))
 158                  (message "nnspool: Receiving headers... %d%%"
 159                           (/ (* count 100) number))))
 160
 161           (and do-message
 162                (message "nnspool: Receiving headers...done"))
 163
 164           ;; Fold continuation lines.
 165           (nnheader-fold-continuation-lines)
 166           'headers)))))
 167
 168 (defun nnspool-open-server (server &optional defs)
 169   (nnheader-init-server-buffer)
 170   (if (equal server nnspool-current-server)
 171       t
 172     (if nnspool-current-server
 173         (setq nnspool-server-alist
 174               (cons (list nnspool-current-server
 175                           (nnheader-save-variables nnspool-server-variables))
 176                     nnspool-server-alist)))
 177     (let ((state (assoc server nnspool-server-alist)))
 178       (if state
 179           (progn
 180             (nnheader-restore-variables (nth 1 state))
 181             (setq nnspool-server-alist (delq state nnspool-server-alist)))
 182         (nnheader-set-init-variables nnspool-server-variables defs)))
 183     (setq nnspool-current-server server)))
 184
 185 (defun nnspool-close-server (&optional server)
 186   (setq nnspool-current-server nil)
 187   t)
 188
 189 (defun nnspool-server-opened (&optional server)
 190   (and (equal server nnspool-current-server)
 191        nntp-server-buffer
 192        (buffer-name nntp-server-buffer)))
 193
 194 (defun nnspool-status-message (&optional server)
 195   "Return server status response as string."
 196   nnspool-status-string)
 197
 198 (defun nnspool-request-article (id &optional group server buffer)
 199   "Select article by message ID (or number)."
 200   (nnspool-possibly-change-directory group)
 201   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 202         file ag)
 203     (if (stringp id)
 204         ;; This is a Message-ID.
 205         (when (setq ag (nnspool-find-id id))
 206           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 207       (setq file (nnspool-article-pathname nnspool-current-group id)))
 208     (and file
 209          (file-exists-p file)
 210          (not (file-directory-p file))
 211          (save-excursion (nnspool-find-file file))
 212          ;; We return the article number and group name.
 213          (if (numberp id)
 214              (cons nnspool-current-group id)
 215            ag))))
 216
 217 (defun nnspool-request-body (id &optional group server)
 218   "Select article body by message ID (or number)."
 219   (nnspool-possibly-change-directory group)
 220   (if (nnspool-request-article id)
 221       (save-excursion
 222         (set-buffer nntp-server-buffer)
 223         (goto-char (point-min))
 224         (if (search-forward "\n\n" nil t)
 225             (delete-region (point-min) (point)))
 226         t)))
 227
 228 (defun nnspool-request-head (id &optional group server)
 229   "Select article head by message ID (or number)."
 230   (nnspool-possibly-change-directory group)
 231   (let ((res (nnspool-request-article id)))
 232     (when res
 233       (save-excursion
 234         (set-buffer nntp-server-buffer)
 235         (goto-char (point-min))
 236         (when (search-forward "\n\n" nil t)
 237           (delete-region (1- (point)) (point-max)))))
 238     res))
 239
 240 (defun nnspool-request-group (group &optional server dont-check)
 241   "Select news GROUP."
 242   (let ((pathname (nnspool-article-pathname group))
 243         dir)
 244     (if (not (file-directory-p pathname))
 245         (nnheader-report
 246          'nnspool "Invalid group name (no such directory): %s" group)
 247       (setq nnspool-current-directory pathname)
 248       (nnheader-report 'nnspool "Selected group %s" group)
 249       (if dont-check
 250           (progn
 251             (nnheader-report 'nnspool "Selected group %s" group)
 252             t)
 253         ;; Yes, completely empty spool directories *are* possible
 254         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 255         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 256           (setq dir
 257                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 258         (save-excursion
 259           (set-buffer nntp-server-buffer)
 260           (erase-buffer)
 261           (if dir
 262               (progn
 263                 (insert
 264                  (format "211 %d %d %d %s\n" (length dir) (car dir)
 265                          (progn (while (cdr dir) (setq dir (cdr dir)))
 266                                 (car dir))
 267                          group))
 268                 t)
 269             (insert (format "211 0 0 0 %s\n" group))
 270             (nnheader-report 'nnspool "Empty group %s" group)
 271             t))))))
 272
 273 (defun nnspool-request-type (group &optional article)
 274   'news)
 275
 276 (defun nnspool-close-group (group &optional server)
 277   t)
 278
 279 (defun nnspool-request-list (&optional server)
 280   "List active newsgroups."
 281   (save-excursion
 282     (nnspool-find-file nnspool-active-file)))
 283
 284 (defun nnspool-request-list-newsgroups (&optional server)
 285   "List newsgroups (defined in NNTP2)."
 286   (save-excursion
 287     (nnspool-find-file nnspool-newsgroups-file)))
 288
 289 (defun nnspool-request-list-distributions (&optional server)
 290   "List distributions (defined in NNTP2)."
 291   (save-excursion
 292     (nnspool-find-file nnspool-distributions-file)))
 293
 294 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 295 (defun nnspool-request-newgroups (date &optional server)
 296   "List groups created after DATE."
 297   (if (nnspool-find-file nnspool-active-times-file)
 298       (save-excursion
 299         ;; Find the last valid line.
 300         (goto-char (point-max))
 301         (while (and (not (looking-at
 302                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 303                     (zerop (forward-line -1))))
 304         (let ((seconds (nnspool-seconds-since-epoch date))
 305               groups)
 306           ;; Go through lines and add the latest groups to a list.
 307           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 308                       (progn
 309                         ;; We insert a .0 to make the list reader
 310                         ;; interpret the number as a float. It is far
 311                         ;; too big to be stored in a lisp integer.
 312                         (goto-char (1- (match-end 0)))
 313                         (insert ".0")
 314                         (> (progn
 315                              (goto-char (match-end 1))
 316                              (read (current-buffer)))
 317                            seconds))
 318                       (setq groups (cons (buffer-substring
 319                                           (match-beginning 1) (match-end 1))
 320                                          groups))
 321                       (zerop (forward-line -1))))
 322           (erase-buffer)
 323           (while groups
 324             (insert (car groups) " 0 0 y\n")
 325             (setq groups (cdr groups))))
 326         t)
 327     nil))
 328
 329 (defun nnspool-request-post (&optional server)
 330   "Post a new news in current buffer."
 331   (save-excursion
 332     (let* ((process-connection-type nil) ; t bugs out on Solaris
 333            (inews-buffer (generate-new-buffer " *nnspool post*"))
 334            (proc
 335             (condition-case err
 336                 (apply 'start-process "*nnspool inews*" inews-buffer
 337                        nnspool-inews-program nnspool-inews-switches)
 338               (error
 339                (setq nnspool-status-string (format "inews error: %S" err))
 340                nil))))
 341       (if (not proc)
 342           ;; The inews program failed.
 343           ()
 344         (setq nnspool-status-string "")
 345         (set-process-sentinel proc 'nnspool-inews-sentinel)
 346         (process-send-region proc (point-min) (point-max))
 347         ;; We slap a condition-case around this, because the process may
 348         ;; have exited already...
 349         (condition-case nil
 350             (process-send-eof proc)
 351           (error nil))
 352         t))))
 353
 354 (defun nnspool-inews-sentinel (proc status)
 355   (save-excursion
 356     (set-buffer (process-buffer proc))
 357     (goto-char (point-min))
 358     (if (or (zerop (buffer-size))
 359             (search-forward "spooled" nil t))
 360         (kill-buffer (current-buffer))
 361       ;; Make status message by folding lines.
 362       (while (re-search-forward "[ \t\n]+" nil t)
 363         (replace-match " " t t))
 364       (setq nnspool-status-string (buffer-string))
 365       (message "nnspool: %s" nnspool-status-string)
 366       (ding)
 367       (run-hooks 'nnspool-rejected-article-hook))))
 368
 369 \f
 370 ;;; Internal functions.
 371
 372 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 373   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 374       nil
 375     (let ((nov (nnheader-group-pathname
 376                 nnspool-current-group nnspool-nov-directory ".overview")))
 377       (if (not (file-exists-p nov))
 378           ()
 379         (save-excursion
 380           (set-buffer nntp-server-buffer)
 381           (erase-buffer)
 382           (if nnspool-sift-nov-with-sed
 383               (nnspool-sift-nov-with-sed articles nov)
 384             (insert-file-contents nov)
 385             (if (and fetch-old
 386                      (not (numberp fetch-old)))
 387                 t                       ; We want all the headers.
 388               ;; First we find the first wanted line.
 389               (nnspool-find-nov-line
 390                (if fetch-old (max 1 (- (car articles) fetch-old))
 391                  (car articles)))
 392               (delete-region (point-min) (point))
 393               ;; Then we find the last wanted line.
 394               (if (nnspool-find-nov-line
 395                    (progn (while (cdr articles) (setq articles (cdr articles)))
 396                           (car articles)))
 397                   (forward-line 1))
 398               (delete-region (point) (point-max))
 399               ;; If the buffer is empty, this wasn't very successful.
 400               (not (zerop (buffer-size))))))))))
 401
 402 (defun nnspool-find-nov-line (article)
 403   (let ((max (point-max))
 404         (min (goto-char (point-min)))
 405         (cur (current-buffer))
 406         (prev (point-min))
 407         num found)
 408     (while (not found)
 409       (goto-char (/ (+ max min) 2))
 410       (beginning-of-line)
 411       (if (or (= (point) prev)
 412               (eobp))
 413           (setq found t)
 414         (setq prev (point))
 415         (cond ((> (setq num (read cur)) article)
 416                (setq max (point)))
 417               ((< num article)
 418                (setq min (point)))
 419               (t
 420                (setq found t)))))
 421     (when (not (eq num article))
 422       (setq found (point))
 423       (forward-line 1)
 424       (or (eobp)
 425           (= (setq num (read cur)) article)
 426           (goto-char found)))
 427     (beginning-of-line)
 428     (eq num article)))
 429
 430
 431 (defun nnspool-sift-nov-with-sed (articles file)
 432   (let ((first (car articles))
 433         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 434                      (car articles))))
 435     (call-process "awk" nil t nil
 436                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 437                           (1- first) (1+ last))
 438                   file)))
 439
 440 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 441 ;; Find out what group an article identified by a Message-ID is in.
 442 (defun nnspool-find-id (id)
 443   (save-excursion
 444     (set-buffer (get-buffer-create " *nnspool work*"))
 445     (buffer-disable-undo (current-buffer))
 446     (erase-buffer)
 447     (condition-case ()
 448         (call-process "grep" nil t nil id nnspool-history-file)
 449       (error nil))
 450     (goto-char (point-min))
 451     (prog1
 452         (if (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 453             (cons (match-string 1) (string-to-int (match-string 2))))
 454       (kill-buffer (current-buffer)))))
 455
 456 (defun nnspool-find-file (file)
 457   "Insert FILE in server buffer safely."
 458   (set-buffer nntp-server-buffer)
 459   (erase-buffer)
 460   (condition-case ()
 461       (progn (insert-file-contents file) t)
 462     (file-error nil)))
 463
 464 (defun nnspool-possibly-change-directory (group)
 465   (if group
 466       (let ((pathname (nnspool-article-pathname group)))
 467         (if (file-directory-p pathname)
 468             (progn
 469               (setq nnspool-current-directory pathname)
 470               (setq nnspool-current-group group))
 471           (setq nnspool-status-string
 472                 (format "No such newsgroup: %s" group))
 473           nil))
 474     t))
 475
 476 (defun nnspool-article-pathname (group &optional article)
 477   "Find the path for GROUP."
 478   (nnheader-group-pathname group nnspool-spool-directory article))
 479
 480 (defun nnspool-seconds-since-epoch (date)
 481   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 482                         (timezone-parse-date date)))
 483          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 484                         (timezone-parse-time
 485                          (aref (timezone-parse-date date) 3))))
 486          (unix (encode-time (nth 2 ttime) (nth 1 ttime) (nth 0 ttime)
 487                             (nth 2 tdate) (nth 1 tdate) (nth 0 tdate)
 488                             (nth 4 tdate))))
 489     (+ (* (car unix) 65536.0)
 490        (car (cdr unix)))))
 491
 492 (provide 'nnspool)
 493
 494 ;;; nnspool.el ends here