cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 1988,89,90,93,94,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'nnoo)
  32 (eval-when-compile (require 'cl))
  33
  34 (nnoo-declare nnspool)
  35
  36 (defvoo nnspool-inews-program news-inews-program
  37   "Program to post news.
  38 This is most commonly `inews' or `injnews'.")
  39
  40 (defvoo nnspool-inews-switches '("-h" "-S")
  41   "Switches for nnspool-request-post to pass to `inews' for posting news.
  42 If you are using Cnews, you probably should set this variable to nil.")
  43
  44 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  45   "Local news spool directory.")
  46
  47 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  48   "Local news nov directory.")
  49
  50 (defvoo nnspool-lib-dir "/usr/lib/news/"
  51   "Where the local news library files are stored.")
  52
  53 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  54   "Local news active file.")
  55
  56 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  57   "Local news newsgroups file.")
  58
  59 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  60   "Local news distributions file.")
  61
  62 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  63   "Local news history file.")
  64
  65 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  66   "Local news active date file.")
  67
  68 (defvoo nnspool-large-newsgroup 50
  69   "The number of the articles which indicates a large newsgroup.
  70 If the number of the articles is greater than the value, verbose
  71 messages will be shown to indicate the current status.")
  72
  73 (defvoo nnspool-nov-is-evil nil
  74   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  75
  76 (defconst nnspool-sift-nov-with-sed nil
  77   "If non-nil, use sed to get the relevant portion from the overview file.
  78 If nil, nnspool will load the entire file into a buffer and process it
  79 there.")
  80
  81 (defvoo nnspool-rejected-article-hook nil
  82   "*A hook that will be run when an article has been rejected by the server.")
  83
  84 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  85   "Coding system for nnspool.")
  86
  87 \f
  88
  89 (defconst nnspool-version "nnspool 2.0"
  90   "Version numbers of this version of NNSPOOL.")
  91
  92 (defvoo nnspool-current-directory nil
  93   "Current news group directory.")
  94
  95 (defvoo nnspool-current-group nil)
  96 (defvoo nnspool-status-string "")
  97
  98 \f
  99 ;;; Interface functions.
 100
 101 (nnoo-define-basics nnspool)
 102
 103 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 104   "Retrieve the headers of ARTICLES."
 105   (save-excursion
 106     (set-buffer nntp-server-buffer)
 107     (erase-buffer)
 108     (when (nnspool-possibly-change-directory group)
 109       (let* ((number (length articles))
 110              (count 0)
 111              (default-directory nnspool-current-directory)
 112              (do-message (and (numberp nnspool-large-newsgroup)
 113                               (> number nnspool-large-newsgroup)))
 114              (nnheader-file-coding-system nnspool-file-coding-system)
 115              file beg article ag)
 116         (if (and (numberp (car articles))
 117                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 118             ;; We successfully retrieved the NOV headers.
 119             'nov
 120           ;; No NOV headers here, so we do it the hard way.
 121           (while (setq article (pop articles))
 122             (if (stringp article)
 123                 ;; This is a Message-ID.
 124                 (setq ag (nnspool-find-id article)
 125                       file (and ag (nnspool-article-pathname
 126                                     (car ag) (cdr ag)))
 127                       article (cdr ag))
 128               ;; This is an article in the current group.
 129               (setq file (int-to-string article)))
 130             ;; Insert the head of the article.
 131             (when (and file
 132                        (file-exists-p file))
 133               (insert "221 ")
 134               (princ article (current-buffer))
 135               (insert " Article retrieved.\n")
 136               (setq beg (point))
 137               (inline (nnheader-insert-head file))
 138               (goto-char beg)
 139               (search-forward "\n\n" nil t)
 140               (forward-char -1)
 141               (insert ".\n")
 142               (delete-region (point) (point-max)))
 143
 144             (and do-message
 145                  (zerop (% (incf count) 20))
 146                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 147                           (/ (* count 100) number))))
 148
 149           (when do-message
 150             (nnheader-message 5 "nnspool: Receiving headers...done"))
 151
 152           ;; Fold continuation lines.
 153           (nnheader-fold-continuation-lines)
 154           'headers)))))
 155
 156 (deffoo nnspool-open-server (server &optional defs)
 157   (nnoo-change-server 'nnspool server defs)
 158   (cond
 159    ((not (file-exists-p nnspool-spool-directory))
 160     (nnspool-close-server)
 161     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 162                      nnspool-spool-directory))
 163    ((not (file-directory-p
 164           (directory-file-name
 165            (file-truename nnspool-spool-directory))))
 166     (nnspool-close-server)
 167     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 168    ((not (file-exists-p nnspool-active-file))
 169     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 170                      nnspool-active-file))
 171    (t
 172     (nnheader-report 'nnspool "Opened server %s using directory %s"
 173                      server nnspool-spool-directory)
 174     t)))
 175
 176 (deffoo nnspool-request-article (id &optional group server buffer)
 177   "Select article by message ID (or number)."
 178   (nnspool-possibly-change-directory group)
 179   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 180         file ag)
 181     (if (stringp id)
 182         ;; This is a Message-ID.
 183         (when (setq ag (nnspool-find-id id))
 184           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 185       (setq file (nnspool-article-pathname nnspool-current-group id)))
 186     (and file
 187          (file-exists-p file)
 188          (not (file-directory-p file))
 189          (save-excursion (nnspool-find-file file))
 190          ;; We return the article number and group name.
 191          (if (numberp id)
 192              (cons nnspool-current-group id)
 193            ag))))
 194
 195 (deffoo nnspool-request-body (id &optional group server)
 196   "Select article body by message ID (or number)."
 197   (nnspool-possibly-change-directory group)
 198   (let ((res (nnspool-request-article id)))
 199     (when res
 200       (save-excursion
 201         (set-buffer nntp-server-buffer)
 202         (goto-char (point-min))
 203         (when (search-forward "\n\n" nil t)
 204           (delete-region (point-min) (point)))
 205         res))))
 206
 207 (deffoo nnspool-request-head (id &optional group server)
 208   "Select article head by message ID (or number)."
 209   (nnspool-possibly-change-directory group)
 210   (let ((res (nnspool-request-article id)))
 211     (when res
 212       (save-excursion
 213         (set-buffer nntp-server-buffer)
 214         (goto-char (point-min))
 215         (when (search-forward "\n\n" nil t)
 216           (delete-region (1- (point)) (point-max)))
 217         (nnheader-fold-continuation-lines)))
 218     res))
 219
 220 (deffoo nnspool-request-group (group &optional server dont-check)
 221   "Select news GROUP."
 222   (let ((pathname (nnspool-article-pathname group))
 223         dir)
 224     (if (not (file-directory-p pathname))
 225         (nnheader-report
 226          'nnspool "Invalid group name (no such directory): %s" group)
 227       (setq nnspool-current-directory pathname)
 228       (nnheader-report 'nnspool "Selected group %s" group)
 229       (if dont-check
 230           (progn
 231             (nnheader-report 'nnspool "Selected group %s" group)
 232             t)
 233         ;; Yes, completely empty spool directories *are* possible.
 234         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 235         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 236           (setq dir
 237                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 238         (if dir
 239             (nnheader-insert
 240              "211 %d %d %d %s\n" (length dir) (car dir)
 241              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 242              group)
 243           (nnheader-report 'nnspool "Empty group %s" group)
 244           (nnheader-insert "211 0 0 0 %s\n" group))))))
 245
 246 (deffoo nnspool-request-type (group &optional article)
 247   'news)
 248
 249 (deffoo nnspool-close-group (group &optional server)
 250   t)
 251
 252 (deffoo nnspool-request-list (&optional server)
 253   "List active newsgroups."
 254   (save-excursion
 255     (or (nnspool-find-file nnspool-active-file)
 256         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 257
 258 (deffoo nnspool-request-list-newsgroups (&optional server)
 259   "List newsgroups (defined in NNTP2)."
 260   (save-excursion
 261     (or (nnspool-find-file nnspool-newsgroups-file)
 262         (nnheader-report 'nnspool (nnheader-file-error
 263                                    nnspool-newsgroups-file)))))
 264
 265 (deffoo nnspool-request-list-distributions (&optional server)
 266   "List distributions (defined in NNTP2)."
 267   (save-excursion
 268     (or (nnspool-find-file nnspool-distributions-file)
 269         (nnheader-report 'nnspool (nnheader-file-error
 270                                    nnspool-distributions-file)))))
 271
 272 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 273 (deffoo nnspool-request-newgroups (date &optional server)
 274   "List groups created after DATE."
 275   (if (nnspool-find-file nnspool-active-times-file)
 276       (save-excursion
 277         ;; Find the last valid line.
 278         (goto-char (point-max))
 279         (while (and (not (looking-at
 280                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 281                     (zerop (forward-line -1))))
 282         (let ((seconds (time-to-seconds (date-to-time date)))
 283               groups)
 284           ;; Go through lines and add the latest groups to a list.
 285           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 286                       (progn
 287                         ;; We insert a .0 to make the list reader
 288                         ;; interpret the number as a float.  It is far
 289                         ;; too big to be stored in a lisp integer.
 290                         (goto-char (1- (match-end 0)))
 291                         (insert ".0")
 292                         (> (progn
 293                              (goto-char (match-end 1))
 294                              (read (current-buffer)))
 295                            seconds))
 296                       (push (buffer-substring
 297                                           (match-beginning 1) (match-end 1))
 298                                          groups)
 299                       (zerop (forward-line -1))))
 300           (erase-buffer)
 301           (while groups
 302             (insert (car groups) " 0 0 y\n")
 303             (setq groups (cdr groups))))
 304         t)
 305     nil))
 306
 307 (deffoo nnspool-request-post (&optional server)
 308   "Post a new news in current buffer."
 309   (save-excursion
 310     (let* ((process-connection-type nil) ; t bugs out on Solaris
 311            (inews-buffer (generate-new-buffer " *nnspool post*"))
 312            (proc
 313             (condition-case err
 314                 (apply 'start-process "*nnspool inews*" inews-buffer
 315                        nnspool-inews-program nnspool-inews-switches)
 316               (error
 317                (nnheader-report 'nnspool "inews error: %S" err)))))
 318       (if (not proc)
 319           ;; The inews program failed.
 320           ()
 321         (nnheader-report 'nnspool "")
 322         (set-process-sentinel proc 'nnspool-inews-sentinel)
 323         (process-send-region proc (point-min) (point-max))
 324         ;; We slap a condition-case around this, because the process may
 325         ;; have exited already...
 326         (ignore-errors
 327           (process-send-eof proc))
 328         t))))
 329
 330
 331 \f
 332 ;;; Internal functions.
 333
 334 (defun nnspool-inews-sentinel (proc status)
 335   (save-excursion
 336     (set-buffer (process-buffer proc))
 337     (goto-char (point-min))
 338     (if (or (zerop (buffer-size))
 339             (search-forward "spooled" nil t))
 340         (kill-buffer (current-buffer))
 341       ;; Make status message by folding lines.
 342       (while (re-search-forward "[ \t\n]+" nil t)
 343         (replace-match " " t t))
 344       (nnheader-report 'nnspool "%s" (buffer-string))
 345       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 346       (ding)
 347       (run-hooks 'nnspool-rejected-article-hook))))
 348
 349 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 350   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 351       nil
 352     (let ((nov (nnheader-group-pathname
 353                 nnspool-current-group nnspool-nov-directory ".overview"))
 354           (arts articles)
 355           (nnheader-file-coding-system nnspool-file-coding-system)
 356           last)
 357       (if (not (file-exists-p nov))
 358           ()
 359         (save-excursion
 360           (set-buffer nntp-server-buffer)
 361           (erase-buffer)
 362           (if nnspool-sift-nov-with-sed
 363               (nnspool-sift-nov-with-sed articles nov)
 364             (nnheader-insert-file-contents nov)
 365             (if (and fetch-old
 366                      (not (numberp fetch-old)))
 367                 t                       ; We want all the headers.
 368               (ignore-errors
 369                 ;; Delete unwanted NOV lines.
 370                 (nnheader-nov-delete-outside-range
 371                  (if fetch-old (max 1 (- (car articles) fetch-old))
 372                    (car articles))
 373                  (car (last articles)))
 374                 ;; If the buffer is empty, this wasn't very successful.
 375                 (unless (zerop (buffer-size))
 376                   ;; We check what the last article number was.
 377                   ;; The NOV file may be out of sync with the articles
 378                   ;; in the group.
 379                   (forward-line -1)
 380                   (setq last (read (current-buffer)))
 381                   (if (= last (car articles))
 382                       ;; Yup, it's all there.
 383                       t
 384                     ;; Perhaps not.  We try to find the missing articles.
 385                     (while (and arts
 386                                 (<= last (car arts)))
 387                       (pop arts))
 388                     ;; The articles in `arts' are missing from the buffer.
 389                     (while arts
 390                       (nnspool-insert-nov-head (pop arts)))
 391                     t))))))))))
 392
 393 (defun nnspool-insert-nov-head (article)
 394   "Read the head of ARTICLE, convert to NOV headers, and insert."
 395   (save-excursion
 396     (let ((cur (current-buffer))
 397           buf)
 398       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 399       (when (nnheader-insert-head
 400              (nnspool-article-pathname nnspool-current-group article))
 401         (nnheader-insert-article-line article)
 402         (let ((headers (nnheader-parse-head)))
 403           (set-buffer cur)
 404           (goto-char (point-max))
 405           (nnheader-insert-nov headers)))
 406       (kill-buffer buf))))
 407
 408 (defun nnspool-sift-nov-with-sed (articles file)
 409   (let ((first (car articles))
 410         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 411                      (car articles))))
 412     (call-process "awk" nil t nil
 413                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 414                           (1- first) (1+ last))
 415                   file)))
 416
 417 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 418 ;; Find out what group an article identified by a Message-ID is in.
 419 (defun nnspool-find-id (id)
 420   (save-excursion
 421     (set-buffer (get-buffer-create " *nnspool work*"))
 422     (erase-buffer)
 423     (ignore-errors
 424       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 425     (goto-char (point-min))
 426     (prog1
 427         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 428           (cons (match-string 1) (string-to-int (match-string 2))))
 429       (kill-buffer (current-buffer)))))
 430
 431 (defun nnspool-find-file (file)
 432   "Insert FILE in server buffer safely."
 433   (set-buffer nntp-server-buffer)
 434   (erase-buffer)
 435   (condition-case ()
 436       (let ((nnheader-file-coding-system nnspool-file-coding-system))
 437         (nnheader-insert-file-contents file)
 438         t)
 439     (file-error nil)))
 440
 441 (defun nnspool-possibly-change-directory (group)
 442   (if (not group)
 443       t
 444     (let ((pathname (nnspool-article-pathname group)))
 445       (if (file-directory-p pathname)
 446           (setq nnspool-current-directory pathname
 447                 nnspool-current-group group)
 448         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 449
 450 (defun nnspool-article-pathname (group &optional article)
 451   "Find the path for GROUP."
 452   (nnheader-group-pathname group nnspool-spool-directory article))
 453
 454 (provide 'nnspool)
 455
 456 ;;; nnspool.el ends here