cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'nnoo)
  32 (eval-when-compile (require 'cl))
  33
  34 (nnoo-declare nnspool)
  35
  36 (defvoo nnspool-inews-program news-inews-program
  37   "Program to post news.
  38 This is most commonly `inews' or `injnews'.")
  39
  40 (defvoo nnspool-inews-switches '("-h" "-S")
  41   "Switches for nnspool-request-post to pass to `inews' for posting news.
  42 If you are using Cnews, you probably should set this variable to nil.")
  43
  44 (defvoo nnspool-spool-directory
  45     (file-name-as-directory (if (boundp 'news-directory)
  46                                 (symbol-value 'news-directory)
  47                               news-path))
  48   "Local news spool directory.")
  49
  50 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  51   "Local news nov directory.")
  52
  53 (defvoo nnspool-lib-dir
  54     (if (file-exists-p "/usr/lib/news/active")
  55         "/usr/lib/news/"
  56       "/var/lib/news/")
  57   "Where the local news library files are stored.")
  58
  59 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  60   "Local news active file.")
  61
  62 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  63   "Local news newsgroups file.")
  64
  65 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  66   "Local news distributions file.")
  67
  68 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  69   "Local news history file.")
  70
  71 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  72   "Local news active date file.")
  73
  74 (defvoo nnspool-large-newsgroup 50
  75   "The number of articles which indicates a large newsgroup.
  76 If the number of articles is greater than the value, verbose
  77 messages will be shown to indicate the current status.")
  78
  79 (defvoo nnspool-nov-is-evil nil
  80   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  81
  82 (defconst nnspool-sift-nov-with-sed nil
  83   "If non-nil, use sed to get the relevant portion from the overview file.
  84 If nil, nnspool will load the entire file into a buffer and process it
  85 there.")
  86
  87 (defvoo nnspool-rejected-article-hook nil
  88   "*A hook that will be run when an article has been rejected by the server.")
  89
  90 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  91   "Coding system for nnspool.")
  92
  93 \f
  94
  95 (defconst nnspool-version "nnspool 2.0"
  96   "Version numbers of this version of NNSPOOL.")
  97
  98 (defvoo nnspool-current-directory nil
  99   "Current news group directory.")
 100
 101 (defvoo nnspool-current-group nil)
 102 (defvoo nnspool-status-string "")
 103
 104 \f
 105 ;;; Interface functions.
 106
 107 (nnoo-define-basics nnspool)
 108
 109 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 110   "Retrieve the headers of ARTICLES."
 111   (save-excursion
 112     (set-buffer nntp-server-buffer)
 113     (erase-buffer)
 114     (when (nnspool-possibly-change-directory group)
 115       (let* ((number (length articles))
 116              (count 0)
 117              (default-directory nnspool-current-directory)
 118              (do-message (and (numberp nnspool-large-newsgroup)
 119                               (> number nnspool-large-newsgroup)))
 120              (nnheader-file-coding-system nnspool-file-coding-system)
 121              file beg article ag)
 122         (if (and (numberp (car articles))
 123                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 124             ;; We successfully retrieved the NOV headers.
 125             'nov
 126           ;; No NOV headers here, so we do it the hard way.
 127           (while (setq article (pop articles))
 128             (if (stringp article)
 129                 ;; This is a Message-ID.
 130                 (setq ag (nnspool-find-id article)
 131                       file (and ag (nnspool-article-pathname
 132                                     (car ag) (cdr ag)))
 133                       article (cdr ag))
 134               ;; This is an article in the current group.
 135               (setq file (int-to-string article)))
 136             ;; Insert the head of the article.
 137             (when (and file
 138                        (file-exists-p file))
 139               (insert "221 ")
 140               (princ article (current-buffer))
 141               (insert " Article retrieved.\n")
 142               (setq beg (point))
 143               (inline (nnheader-insert-head file))
 144               (goto-char beg)
 145               (if (search-forward "\n\n" nil t)
 146                   (progn
 147                     (forward-char -1)
 148                     (insert ".\n"))
 149                 (goto-char (point-max))
 150                 (if (bolp)
 151                     (insert ".\n")
 152                   (insert "\n.\n")))
 153               (delete-region (point) (point-max)))
 154
 155             (and do-message
 156                  (zerop (% (incf count) 20))
 157                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 158                                    (/ (* count 100) number))))
 159
 160           (when do-message
 161             (nnheader-message 5 "nnspool: Receiving headers...done"))
 162
 163           ;; Fold continuation lines.
 164           (nnheader-fold-continuation-lines)
 165           'headers)))))
 166
 167 (deffoo nnspool-open-server (server &optional defs)
 168   (nnoo-change-server 'nnspool server defs)
 169   (cond
 170    ((not (file-exists-p nnspool-spool-directory))
 171     (nnspool-close-server)
 172     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 173                      nnspool-spool-directory))
 174    ((not (file-directory-p
 175           (directory-file-name
 176            (file-truename nnspool-spool-directory))))
 177     (nnspool-close-server)
 178     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 179    ((not (file-exists-p nnspool-active-file))
 180     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 181                      nnspool-active-file))
 182    (t
 183     (nnheader-report 'nnspool "Opened server %s using directory %s"
 184                      server nnspool-spool-directory)
 185     t)))
 186
 187 (deffoo nnspool-request-article (id &optional group server buffer)
 188   "Select article by message ID (or number)."
 189   (nnspool-possibly-change-directory group)
 190   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 191         file ag)
 192     (if (stringp id)
 193         ;; This is a Message-ID.
 194         (when (setq ag (nnspool-find-id id))
 195           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 196       (setq file (nnspool-article-pathname nnspool-current-group id)))
 197     (and file
 198          (file-exists-p file)
 199          (not (file-directory-p file))
 200          (save-excursion (nnspool-find-file file))
 201          ;; We return the article number and group name.
 202          (if (numberp id)
 203              (cons nnspool-current-group id)
 204            ag))))
 205
 206 (deffoo nnspool-request-body (id &optional group server)
 207   "Select article body by message ID (or number)."
 208   (nnspool-possibly-change-directory group)
 209   (let ((res (nnspool-request-article id)))
 210     (when res
 211       (save-excursion
 212         (set-buffer nntp-server-buffer)
 213         (goto-char (point-min))
 214         (when (search-forward "\n\n" nil t)
 215           (delete-region (point-min) (point)))
 216         res))))
 217
 218 (deffoo nnspool-request-head (id &optional group server)
 219   "Select article head by message ID (or number)."
 220   (nnspool-possibly-change-directory group)
 221   (let ((res (nnspool-request-article id)))
 222     (when res
 223       (save-excursion
 224         (set-buffer nntp-server-buffer)
 225         (goto-char (point-min))
 226         (when (search-forward "\n\n" nil t)
 227           (delete-region (1- (point)) (point-max)))
 228         (nnheader-fold-continuation-lines)))
 229     res))
 230
 231 (deffoo nnspool-request-group (group &optional server dont-check)
 232   "Select news GROUP."
 233   (let ((pathname (nnspool-article-pathname group))
 234         dir)
 235     (if (not (file-directory-p pathname))
 236         (nnheader-report
 237          'nnspool "Invalid group name (no such directory): %s" group)
 238       (setq nnspool-current-directory pathname)
 239       (nnheader-report 'nnspool "Selected group %s" group)
 240       (if dont-check
 241           (progn
 242             (nnheader-report 'nnspool "Selected group %s" group)
 243             t)
 244         ;; Yes, completely empty spool directories *are* possible.
 245         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 246         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 247           (setq dir (sort (mapcar 'string-to-number dir) '<)))
 248         (if dir
 249             (nnheader-insert
 250              "211 %d %d %d %s\n" (length dir) (car dir)
 251              (car (last dir)) group)
 252           (nnheader-report 'nnspool "Empty group %s" group)
 253           (nnheader-insert "211 0 0 0 %s\n" group))))))
 254
 255 (deffoo nnspool-request-type (group &optional article)
 256   'news)
 257
 258 (deffoo nnspool-close-group (group &optional server)
 259   t)
 260
 261 (deffoo nnspool-request-list (&optional server)
 262   "List active newsgroups."
 263   (save-excursion
 264     (or (nnspool-find-file nnspool-active-file)
 265         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 266
 267 (deffoo nnspool-request-list-newsgroups (&optional server)
 268   "List newsgroups (defined in NNTP2)."
 269   (save-excursion
 270     (or (nnspool-find-file nnspool-newsgroups-file)
 271         (nnheader-report 'nnspool (nnheader-file-error
 272                                    nnspool-newsgroups-file)))))
 273
 274 (deffoo nnspool-request-list-distributions (&optional server)
 275   "List distributions (defined in NNTP2)."
 276   (save-excursion
 277     (or (nnspool-find-file nnspool-distributions-file)
 278         (nnheader-report 'nnspool (nnheader-file-error
 279                                    nnspool-distributions-file)))))
 280
 281 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 282 (deffoo nnspool-request-newgroups (date &optional server)
 283   "List groups created after DATE."
 284   (if (nnspool-find-file nnspool-active-times-file)
 285       (save-excursion
 286         ;; Find the last valid line.
 287         (goto-char (point-max))
 288         (while (and (not (looking-at
 289                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 290                     (zerop (forward-line -1))))
 291         (let ((seconds (time-to-seconds (date-to-time date)))
 292               groups)
 293           ;; Go through lines and add the latest groups to a list.
 294           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 295                       (progn
 296                         ;; We insert a .0 to make the list reader
 297                         ;; interpret the number as a float.  It is far
 298                         ;; too big to be stored in a lisp integer.
 299                         (goto-char (1- (match-end 0)))
 300                         (insert ".0")
 301                         (> (progn
 302                              (goto-char (match-end 1))
 303                              (read (current-buffer)))
 304                            seconds))
 305                       (push (buffer-substring
 306                              (match-beginning 1) (match-end 1))
 307                             groups)
 308                       (zerop (forward-line -1))))
 309           (erase-buffer)
 310           (dolist (group groups)
 311             (insert group " 0 0 y\n")))
 312         t)
 313     nil))
 314
 315 (deffoo nnspool-request-post (&optional server)
 316   "Post a new news in current buffer."
 317   (save-excursion
 318     (let* ((process-connection-type nil) ; t bugs out on Solaris
 319            (inews-buffer (generate-new-buffer " *nnspool post*"))
 320            (proc
 321             (condition-case err
 322                 (apply 'start-process "*nnspool inews*" inews-buffer
 323                        nnspool-inews-program nnspool-inews-switches)
 324               (error
 325                (nnheader-report 'nnspool "inews error: %S" err)))))
 326       (if (not proc)
 327           ;; The inews program failed.
 328           ()
 329         (nnheader-report 'nnspool "")
 330         (set-process-sentinel proc 'nnspool-inews-sentinel)
 331         (mm-with-unibyte-current-buffer
 332           (process-send-region proc (point-min) (point-max)))
 333         ;; We slap a condition-case around this, because the process may
 334         ;; have exited already...
 335         (ignore-errors
 336           (process-send-eof proc))
 337         t))))
 338
 339
 340 \f
 341 ;;; Internal functions.
 342
 343 (defun nnspool-inews-sentinel (proc status)
 344   (save-excursion
 345     (set-buffer (process-buffer proc))
 346     (goto-char (point-min))
 347     (if (or (zerop (buffer-size))
 348             (search-forward "spooled" nil t))
 349         (kill-buffer (current-buffer))
 350       ;; Make status message by folding lines.
 351       (while (re-search-forward "[ \t\n]+" nil t)
 352         (replace-match " " t t))
 353       (nnheader-report 'nnspool "%s" (buffer-string))
 354       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 355       (ding)
 356       (run-hooks 'nnspool-rejected-article-hook))))
 357
 358 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 359   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 360       nil
 361     (let ((nov (nnheader-group-pathname
 362                 nnspool-current-group nnspool-nov-directory ".overview"))
 363           (arts articles)
 364           (nnheader-file-coding-system nnspool-file-coding-system)
 365           last)
 366       (if (not (file-exists-p nov))
 367           ()
 368         (save-excursion
 369           (set-buffer nntp-server-buffer)
 370           (erase-buffer)
 371           (if nnspool-sift-nov-with-sed
 372               (nnspool-sift-nov-with-sed articles nov)
 373             (nnheader-insert-file-contents nov)
 374             (if (and fetch-old
 375                      (not (numberp fetch-old)))
 376                 t                       ; We want all the headers.
 377               (ignore-errors
 378                 ;; Delete unwanted NOV lines.
 379                 (nnheader-nov-delete-outside-range
 380                  (if fetch-old (max 1 (- (car articles) fetch-old))
 381                    (car articles))
 382                  (car (last articles)))
 383                 ;; If the buffer is empty, this wasn't very successful.
 384                 (unless (zerop (buffer-size))
 385                   ;; We check what the last article number was.
 386                   ;; The NOV file may be out of sync with the articles
 387                   ;; in the group.
 388                   (forward-line -1)
 389                   (setq last (read (current-buffer)))
 390                   (if (= last (car articles))
 391                       ;; Yup, it's all there.
 392                       t
 393                     ;; Perhaps not.  We try to find the missing articles.
 394                     (while (and arts
 395                                 (<= last (car arts)))
 396                       (pop arts))
 397                     ;; The articles in `arts' are missing from the buffer.
 398                     (mapc 'nnspool-insert-nov-head arts)
 399                     t))))))))))
 400
 401 (defun nnspool-insert-nov-head (article)
 402   "Read the head of ARTICLE, convert to NOV headers, and insert."
 403   (save-excursion
 404     (let ((cur (current-buffer))
 405           buf)
 406       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 407       (when (nnheader-insert-head
 408              (nnspool-article-pathname nnspool-current-group article))
 409         (nnheader-insert-article-line article)
 410         (let ((headers (nnheader-parse-head)))
 411           (set-buffer cur)
 412           (goto-char (point-max))
 413           (nnheader-insert-nov headers)))
 414       (kill-buffer buf))))
 415
 416 (defun nnspool-sift-nov-with-sed (articles file)
 417   (let ((first (car articles))
 418         (last (car (last articles))))
 419     (call-process "awk" nil t nil
 420                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 421                           (1- first) (1+ last))
 422                   file)))
 423
 424 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 425 ;; Find out what group an article identified by a Message-ID is in.
 426 (defun nnspool-find-id (id)
 427   (with-temp-buffer
 428     (ignore-errors
 429       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 430     (goto-char (point-min))
 431     (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 432       (cons (match-string 1) (string-to-number (match-string 2))))))
 433
 434 (defun nnspool-find-file (file)
 435   "Insert FILE in server buffer safely."
 436   (set-buffer nntp-server-buffer)
 437   (erase-buffer)
 438   (condition-case ()
 439       (let ((coding-system-for-read nnspool-file-coding-system))
 440         (mm-insert-file-contents file)
 441         t)
 442     (file-error nil)))
 443
 444 (defun nnspool-possibly-change-directory (group)
 445   (if (not group)
 446       t
 447     (let ((pathname (nnspool-article-pathname group)))
 448       (if (file-directory-p pathname)
 449           (setq nnspool-current-directory pathname
 450                 nnspool-current-group group)
 451         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 452
 453 (defun nnspool-article-pathname (group &optional article)
 454   "Find the file name for GROUP."
 455   (nnheader-group-pathname group nnspool-spool-directory article))
 456
 457 (provide 'nnspool)
 458
 459 ;; arch-tag: bdac8d27-2934-4eee-bad0-49e6b90c0d05
 460 ;;; nnspool.el ends here