cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;               2000, 2002, 2003
   5 ;;               Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nntp)
  34 (require 'nnoo)
  35 (eval-when-compile (require 'cl))
  36
  37 (nnoo-declare nnspool)
  38
  39 (defvoo nnspool-inews-program news-inews-program
  40   "Program to post news.
  41 This is most commonly `inews' or `injnews'.")
  42
  43 (defvoo nnspool-inews-switches '("-h" "-S")
  44   "Switches for nnspool-request-post to pass to `inews' for posting news.
  45 If you are using Cnews, you probably should set this variable to nil.")
  46
  47 (defvoo nnspool-spool-directory
  48     (file-name-as-directory (if (boundp 'news-directory)
  49                                 (symbol-value 'news-directory)
  50                               news-path))
  51   "Local news spool directory.")
  52
  53 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  54   "Local news nov directory.")
  55
  56 (defvoo nnspool-lib-dir
  57     (if (file-exists-p "/usr/lib/news/active")
  58         "/usr/lib/news/"
  59       "/var/lib/news/")
  60   "Where the local news library files are stored.")
  61
  62 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  63   "Local news active file.")
  64
  65 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  66   "Local news newsgroups file.")
  67
  68 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  69   "Local news distributions file.")
  70
  71 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  72   "Local news history file.")
  73
  74 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  75   "Local news active date file.")
  76
  77 (defvoo nnspool-large-newsgroup 50
  78   "The number of articles which indicates a large newsgroup.
  79 If the number of articles is greater than the value, verbose
  80 messages will be shown to indicate the current status.")
  81
  82 (defvoo nnspool-nov-is-evil nil
  83   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  84
  85 (defconst nnspool-sift-nov-with-sed nil
  86   "If non-nil, use sed to get the relevant portion from the overview file.
  87 If nil, nnspool will load the entire file into a buffer and process it
  88 there.")
  89
  90 (defvoo nnspool-rejected-article-hook nil
  91   "*A hook that will be run when an article has been rejected by the server.")
  92
  93 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  94   "Coding system for nnspool.")
  95
  96 \f
  97
  98 (defconst nnspool-version "nnspool 2.0"
  99   "Version numbers of this version of NNSPOOL.")
 100
 101 (defvoo nnspool-current-directory nil
 102   "Current news group directory.")
 103
 104 (defvoo nnspool-current-group nil)
 105 (defvoo nnspool-status-string "")
 106
 107 \f
 108 ;;; Interface functions.
 109
 110 (nnoo-define-basics nnspool)
 111
 112 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 113   "Retrieve the headers of ARTICLES."
 114   (save-excursion
 115     (set-buffer nntp-server-buffer)
 116     (erase-buffer)
 117     (when (nnspool-possibly-change-directory group)
 118       (let* ((number (length articles))
 119              (count 0)
 120              (default-directory nnspool-current-directory)
 121              (do-message (and (numberp nnspool-large-newsgroup)
 122                               (> number nnspool-large-newsgroup)))
 123              (nnheader-file-coding-system nnspool-file-coding-system)
 124              file beg article ag)
 125         (if (and (numberp (car articles))
 126                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 127             ;; We successfully retrieved the NOV headers.
 128             'nov
 129           ;; No NOV headers here, so we do it the hard way.
 130           (while (setq article (pop articles))
 131             (if (stringp article)
 132                 ;; This is a Message-ID.
 133                 (setq ag (nnspool-find-id article)
 134                       file (and ag (nnspool-article-pathname
 135                                     (car ag) (cdr ag)))
 136                       article (cdr ag))
 137               ;; This is an article in the current group.
 138               (setq file (int-to-string article)))
 139             ;; Insert the head of the article.
 140             (when (and file
 141                        (file-exists-p file))
 142               (insert "221 ")
 143               (princ article (current-buffer))
 144               (insert " Article retrieved.\n")
 145               (setq beg (point))
 146               (inline (nnheader-insert-head file))
 147               (goto-char beg)
 148               (if (search-forward "\n\n" nil t)
 149                   (progn
 150                     (forward-char -1)
 151                     (insert ".\n"))
 152                 (goto-char (point-max))
 153                 (if (bolp)
 154                     (insert ".\n")
 155                   (insert "\n.\n")))
 156               (delete-region (point) (point-max)))
 157
 158             (and do-message
 159                  (zerop (% (incf count) 20))
 160                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 161                                    (/ (* count 100) number))))
 162
 163           (when do-message
 164             (nnheader-message 5 "nnspool: Receiving headers...done"))
 165
 166           ;; Fold continuation lines.
 167           (nnheader-fold-continuation-lines)
 168           'headers)))))
 169
 170 (deffoo nnspool-open-server (server &optional defs)
 171   (nnoo-change-server 'nnspool server defs)
 172   (cond
 173    ((not (file-exists-p nnspool-spool-directory))
 174     (nnspool-close-server)
 175     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 176                      nnspool-spool-directory))
 177    ((not (file-directory-p
 178           (directory-file-name
 179            (file-truename nnspool-spool-directory))))
 180     (nnspool-close-server)
 181     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 182    ((not (file-exists-p nnspool-active-file))
 183     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 184                      nnspool-active-file))
 185    (t
 186     (nnheader-report 'nnspool "Opened server %s using directory %s"
 187                      server nnspool-spool-directory)
 188     t)))
 189
 190 (deffoo nnspool-request-article (id &optional group server buffer)
 191   "Select article by message ID (or number)."
 192   (nnspool-possibly-change-directory group)
 193   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 194         file ag)
 195     (if (stringp id)
 196         ;; This is a Message-ID.
 197         (when (setq ag (nnspool-find-id id))
 198           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 199       (setq file (nnspool-article-pathname nnspool-current-group id)))
 200     (and file
 201          (file-exists-p file)
 202          (not (file-directory-p file))
 203          (save-excursion (nnspool-find-file file))
 204          ;; We return the article number and group name.
 205          (if (numberp id)
 206              (cons nnspool-current-group id)
 207            ag))))
 208
 209 (deffoo nnspool-request-body (id &optional group server)
 210   "Select article body by message ID (or number)."
 211   (nnspool-possibly-change-directory group)
 212   (let ((res (nnspool-request-article id)))
 213     (when res
 214       (save-excursion
 215         (set-buffer nntp-server-buffer)
 216         (goto-char (point-min))
 217         (when (search-forward "\n\n" nil t)
 218           (delete-region (point-min) (point)))
 219         res))))
 220
 221 (deffoo nnspool-request-head (id &optional group server)
 222   "Select article head by message ID (or number)."
 223   (nnspool-possibly-change-directory group)
 224   (let ((res (nnspool-request-article id)))
 225     (when res
 226       (save-excursion
 227         (set-buffer nntp-server-buffer)
 228         (goto-char (point-min))
 229         (when (search-forward "\n\n" nil t)
 230           (delete-region (1- (point)) (point-max)))
 231         (nnheader-fold-continuation-lines)))
 232     res))
 233
 234 (deffoo nnspool-request-group (group &optional server dont-check)
 235   "Select news GROUP."
 236   (let ((pathname (nnspool-article-pathname group))
 237         dir)
 238     (if (not (file-directory-p pathname))
 239         (nnheader-report
 240          'nnspool "Invalid group name (no such directory): %s" group)
 241       (setq nnspool-current-directory pathname)
 242       (nnheader-report 'nnspool "Selected group %s" group)
 243       (if dont-check
 244           (progn
 245             (nnheader-report 'nnspool "Selected group %s" group)
 246             t)
 247         ;; Yes, completely empty spool directories *are* possible.
 248         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 249         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 250           (setq dir (sort (mapcar 'string-to-number dir) '<)))
 251         (if dir
 252             (nnheader-insert
 253              "211 %d %d %d %s\n" (length dir) (car dir)
 254              (car (last dir)) group)
 255           (nnheader-report 'nnspool "Empty group %s" group)
 256           (nnheader-insert "211 0 0 0 %s\n" group))))))
 257
 258 (deffoo nnspool-request-type (group &optional article)
 259   'news)
 260
 261 (deffoo nnspool-close-group (group &optional server)
 262   t)
 263
 264 (deffoo nnspool-request-list (&optional server)
 265   "List active newsgroups."
 266   (save-excursion
 267     (or (nnspool-find-file nnspool-active-file)
 268         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 269
 270 (deffoo nnspool-request-list-newsgroups (&optional server)
 271   "List newsgroups (defined in NNTP2)."
 272   (save-excursion
 273     (or (nnspool-find-file nnspool-newsgroups-file)
 274         (nnheader-report 'nnspool (nnheader-file-error
 275                                    nnspool-newsgroups-file)))))
 276
 277 (deffoo nnspool-request-list-distributions (&optional server)
 278   "List distributions (defined in NNTP2)."
 279   (save-excursion
 280     (or (nnspool-find-file nnspool-distributions-file)
 281         (nnheader-report 'nnspool (nnheader-file-error
 282                                    nnspool-distributions-file)))))
 283
 284 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 285 (deffoo nnspool-request-newgroups (date &optional server)
 286   "List groups created after DATE."
 287   (if (nnspool-find-file nnspool-active-times-file)
 288       (save-excursion
 289         ;; Find the last valid line.
 290         (goto-char (point-max))
 291         (while (and (not (looking-at
 292                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 293                     (zerop (forward-line -1))))
 294         (let ((seconds (time-to-seconds (date-to-time date)))
 295               groups)
 296           ;; Go through lines and add the latest groups to a list.
 297           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 298                       (progn
 299                         ;; We insert a .0 to make the list reader
 300                         ;; interpret the number as a float.  It is far
 301                         ;; too big to be stored in a lisp integer.
 302                         (goto-char (1- (match-end 0)))
 303                         (insert ".0")
 304                         (> (progn
 305                              (goto-char (match-end 1))
 306                              (read (current-buffer)))
 307                            seconds))
 308                       (push (buffer-substring
 309                              (match-beginning 1) (match-end 1))
 310                             groups)
 311                       (zerop (forward-line -1))))
 312           (erase-buffer)
 313           (dolist (group groups)
 314             (insert group " 0 0 y\n")))
 315         t)
 316     nil))
 317
 318 (deffoo nnspool-request-post (&optional server)
 319   "Post a new news in current buffer."
 320   (save-excursion
 321     (let* ((process-connection-type nil) ; t bugs out on Solaris
 322            (inews-buffer (generate-new-buffer " *nnspool post*"))
 323            (proc
 324             (condition-case err
 325                 (apply 'start-process "*nnspool inews*" inews-buffer
 326                        nnspool-inews-program nnspool-inews-switches)
 327               (error
 328                (nnheader-report 'nnspool "inews error: %S" err)))))
 329       (if (not proc)
 330           ;; The inews program failed.
 331           ()
 332         (nnheader-report 'nnspool "")
 333         (set-process-sentinel proc 'nnspool-inews-sentinel)
 334         (mm-with-unibyte-current-buffer
 335           (process-send-region proc (point-min) (point-max)))
 336         ;; We slap a condition-case around this, because the process may
 337         ;; have exited already...
 338         (ignore-errors
 339           (process-send-eof proc))
 340         t))))
 341
 342
 343 \f
 344 ;;; Internal functions.
 345
 346 (defun nnspool-inews-sentinel (proc status)
 347   (save-excursion
 348     (set-buffer (process-buffer proc))
 349     (goto-char (point-min))
 350     (if (or (zerop (buffer-size))
 351             (search-forward "spooled" nil t))
 352         (kill-buffer (current-buffer))
 353       ;; Make status message by folding lines.
 354       (while (re-search-forward "[ \t\n]+" nil t)
 355         (replace-match " " t t))
 356       (nnheader-report 'nnspool "%s" (buffer-string))
 357       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 358       (ding)
 359       (run-hooks 'nnspool-rejected-article-hook))))
 360
 361 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 362   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 363       nil
 364     (let ((nov (nnheader-group-pathname
 365                 nnspool-current-group nnspool-nov-directory ".overview"))
 366           (arts articles)
 367           (nnheader-file-coding-system nnspool-file-coding-system)
 368           last)
 369       (if (not (file-exists-p nov))
 370           ()
 371         (save-excursion
 372           (set-buffer nntp-server-buffer)
 373           (erase-buffer)
 374           (if nnspool-sift-nov-with-sed
 375               (nnspool-sift-nov-with-sed articles nov)
 376             (nnheader-insert-file-contents nov)
 377             (if (and fetch-old
 378                      (not (numberp fetch-old)))
 379                 t                       ; We want all the headers.
 380               (ignore-errors
 381                 ;; Delete unwanted NOV lines.
 382                 (nnheader-nov-delete-outside-range
 383                  (if fetch-old (max 1 (- (car articles) fetch-old))
 384                    (car articles))
 385                  (car (last articles)))
 386                 ;; If the buffer is empty, this wasn't very successful.
 387                 (unless (zerop (buffer-size))
 388                   ;; We check what the last article number was.
 389                   ;; The NOV file may be out of sync with the articles
 390                   ;; in the group.
 391                   (forward-line -1)
 392                   (setq last (read (current-buffer)))
 393                   (if (= last (car articles))
 394                       ;; Yup, it's all there.
 395                       t
 396                     ;; Perhaps not.  We try to find the missing articles.
 397                     (while (and arts
 398                                 (<= last (car arts)))
 399                       (pop arts))
 400                     ;; The articles in `arts' are missing from the buffer.
 401                     (mapc 'nnspool-insert-nov-head arts)
 402                     t))))))))))
 403
 404 (defun nnspool-insert-nov-head (article)
 405   "Read the head of ARTICLE, convert to NOV headers, and insert."
 406   (save-excursion
 407     (let ((cur (current-buffer))
 408           buf)
 409       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 410       (when (nnheader-insert-head
 411              (nnspool-article-pathname nnspool-current-group article))
 412         (nnheader-insert-article-line article)
 413         (let ((headers (nnheader-parse-head)))
 414           (set-buffer cur)
 415           (goto-char (point-max))
 416           (nnheader-insert-nov headers)))
 417       (kill-buffer buf))))
 418
 419 (defun nnspool-sift-nov-with-sed (articles file)
 420   (let ((first (car articles))
 421         (last (car (last articles))))
 422     (call-process "awk" nil t nil
 423                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 424                           (1- first) (1+ last))
 425                   file)))
 426
 427 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 428 ;; Find out what group an article identified by a Message-ID is in.
 429 (defun nnspool-find-id (id)
 430   (with-temp-buffer
 431     (ignore-errors
 432       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 433     (goto-char (point-min))
 434     (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 435       (cons (match-string 1) (string-to-number (match-string 2))))))
 436
 437 (defun nnspool-find-file (file)
 438   "Insert FILE in server buffer safely."
 439   (set-buffer nntp-server-buffer)
 440   (erase-buffer)
 441   (condition-case ()
 442       (let ((coding-system-for-read nnspool-file-coding-system))
 443         (mm-insert-file-contents file)
 444         t)
 445     (file-error nil)))
 446
 447 (defun nnspool-possibly-change-directory (group)
 448   (if (not group)
 449       t
 450     (let ((pathname (nnspool-article-pathname group)))
 451       (if (file-directory-p pathname)
 452           (setq nnspool-current-directory pathname
 453                 nnspool-current-group group)
 454         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 455
 456 (defun nnspool-article-pathname (group &optional article)
 457   "Find the file name for GROUP."
 458   (nnheader-group-pathname group nnspool-spool-directory article))
 459
 460 (provide 'nnspool)
 461
 462 ;;; arch-tag: bdac8d27-2934-4eee-bad0-49e6b90c0d05
 463 ;;; nnspool.el ends here