cgit.sxemacs.org Git - gnus/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 198,998,89,90,93,94,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'nnoo)
  32 (eval-when-compile (require 'cl))
  33
  34 (nnoo-declare nnspool)
  35
  36 (defvoo nnspool-inews-program news-inews-program
  37   "Program to post news.
  38 This is most commonly `inews' or `injnews'.")
  39
  40 (defvoo nnspool-inews-switches '("-h" "-S")
  41   "Switches for nnspool-request-post to pass to `inews' for posting news.
  42 If you are using Cnews, you probably should set this variable to nil.")
  43
  44 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  45   "Local news spool directory.")
  46
  47 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  48   "Local news nov directory.")
  49
  50 (defvoo nnspool-lib-dir "/usr/lib/news/"
  51   "Where the local news library files are stored.")
  52
  53 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  54   "Local news active file.")
  55
  56 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  57   "Local news newsgroups file.")
  58
  59 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  60   "Local news distributions file.")
  61
  62 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  63   "Local news history file.")
  64
  65 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  66   "Local news active date file.")
  67
  68 (defvoo nnspool-large-newsgroup 50
  69   "The number of the articles which indicates a large newsgroup.
  70 If the number of the articles is greater than the value, verbose
  71 messages will be shown to indicate the current status.")
  72
  73 (defvoo nnspool-nov-is-evil nil
  74   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  75
  76 (defconst nnspool-sift-nov-with-sed nil
  77   "If non-nil, use sed to get the relevant portion from the overview file.
  78 If nil, nnspool will load the entire file into a buffer and process it
  79 there.")
  80
  81 (defvoo nnspool-rejected-article-hook nil
  82   "*A hook that will be run when an article has been rejected by the server.")
  83
  84 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  85   "Coding system for nnspool.")
  86
  87 \f
  88
  89 (defconst nnspool-version "nnspool 2.0"
  90   "Version numbers of this version of NNSPOOL.")
  91
  92 (defvoo nnspool-current-directory nil
  93   "Current news group directory.")
  94
  95 (defvoo nnspool-current-group nil)
  96 (defvoo nnspool-status-string "")
  97
  98 \f
  99 ;;; Interface functions.
 100
 101 (nnoo-define-basics nnspool)
 102
 103 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 104   "Retrieve the headers of ARTICLES."
 105   (save-excursion
 106     (set-buffer nntp-server-buffer)
 107     (erase-buffer)
 108     (when (nnspool-possibly-change-directory group)
 109       (let* ((number (length articles))
 110              (count 0)
 111              (default-directory nnspool-current-directory)
 112              (do-message (and (numberp nnspool-large-newsgroup)
 113                               (> number nnspool-large-newsgroup)))
 114              (nnheader-file-coding-system nnspool-file-coding-system)
 115              file beg article ag)
 116         (if (and (numberp (car articles))
 117                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 118             ;; We successfully retrieved the NOV headers.
 119             'nov
 120           ;; No NOV headers here, so we do it the hard way.
 121           (while (setq article (pop articles))
 122             (if (stringp article)
 123                 ;; This is a Message-ID.
 124                 (setq ag (nnspool-find-id article)
 125                       file (and ag (nnspool-article-pathname
 126                                     (car ag) (cdr ag)))
 127                       article (cdr ag))
 128               ;; This is an article in the current group.
 129               (setq file (int-to-string article)))
 130             ;; Insert the head of the article.
 131             (when (and file
 132                        (file-exists-p file))
 133               (insert "221 ")
 134               (princ article (current-buffer))
 135               (insert " Article retrieved.\n")
 136               (setq beg (point))
 137               (inline (nnheader-insert-head file))
 138               (goto-char beg)
 139               (if (search-forward "\n\n" nil t)
 140                   (progn
 141                     (forward-char -1)
 142                     (insert ".\n"))
 143                 (goto-char (point-max))
 144                 (if (bolp)
 145                     (insert ".\n")
 146                   (insert "\n.\n")))
 147               (delete-region (point) (point-max)))
 148
 149             (and do-message
 150                  (zerop (% (incf count) 20))
 151                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 152                           (/ (* count 100) number))))
 153
 154           (when do-message
 155             (nnheader-message 5 "nnspool: Receiving headers...done"))
 156
 157           ;; Fold continuation lines.
 158           (nnheader-fold-continuation-lines)
 159           'headers)))))
 160
 161 (deffoo nnspool-open-server (server &optional defs)
 162   (nnoo-change-server 'nnspool server defs)
 163   (cond
 164    ((not (file-exists-p nnspool-spool-directory))
 165     (nnspool-close-server)
 166     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 167                      nnspool-spool-directory))
 168    ((not (file-directory-p
 169           (directory-file-name
 170            (file-truename nnspool-spool-directory))))
 171     (nnspool-close-server)
 172     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 173    ((not (file-exists-p nnspool-active-file))
 174     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 175                      nnspool-active-file))
 176    (t
 177     (nnheader-report 'nnspool "Opened server %s using directory %s"
 178                      server nnspool-spool-directory)
 179     t)))
 180
 181 (deffoo nnspool-request-article (id &optional group server buffer)
 182   "Select article by message ID (or number)."
 183   (nnspool-possibly-change-directory group)
 184   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 185         file ag)
 186     (if (stringp id)
 187         ;; This is a Message-ID.
 188         (when (setq ag (nnspool-find-id id))
 189           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 190       (setq file (nnspool-article-pathname nnspool-current-group id)))
 191     (and file
 192          (file-exists-p file)
 193          (not (file-directory-p file))
 194          (save-excursion (nnspool-find-file file))
 195          ;; We return the article number and group name.
 196          (if (numberp id)
 197              (cons nnspool-current-group id)
 198            ag))))
 199
 200 (deffoo nnspool-request-body (id &optional group server)
 201   "Select article body by message ID (or number)."
 202   (nnspool-possibly-change-directory group)
 203   (let ((res (nnspool-request-article id)))
 204     (when res
 205       (save-excursion
 206         (set-buffer nntp-server-buffer)
 207         (goto-char (point-min))
 208         (when (search-forward "\n\n" nil t)
 209           (delete-region (point-min) (point)))
 210         res))))
 211
 212 (deffoo nnspool-request-head (id &optional group server)
 213   "Select article head by message ID (or number)."
 214   (nnspool-possibly-change-directory group)
 215   (let ((res (nnspool-request-article id)))
 216     (when res
 217       (save-excursion
 218         (set-buffer nntp-server-buffer)
 219         (goto-char (point-min))
 220         (when (search-forward "\n\n" nil t)
 221           (delete-region (1- (point)) (point-max)))
 222         (nnheader-fold-continuation-lines)))
 223     res))
 224
 225 (deffoo nnspool-request-group (group &optional server dont-check)
 226   "Select news GROUP."
 227   (let ((pathname (nnspool-article-pathname group))
 228         dir)
 229     (if (not (file-directory-p pathname))
 230         (nnheader-report
 231          'nnspool "Invalid group name (no such directory): %s" group)
 232       (setq nnspool-current-directory pathname)
 233       (nnheader-report 'nnspool "Selected group %s" group)
 234       (if dont-check
 235           (progn
 236             (nnheader-report 'nnspool "Selected group %s" group)
 237             t)
 238         ;; Yes, completely empty spool directories *are* possible.
 239         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 240         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 241           (setq dir
 242                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 243         (if dir
 244             (nnheader-insert
 245              "211 %d %d %d %s\n" (length dir) (car dir)
 246              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 247              group)
 248           (nnheader-report 'nnspool "Empty group %s" group)
 249           (nnheader-insert "211 0 0 0 %s\n" group))))))
 250
 251 (deffoo nnspool-request-type (group &optional article)
 252   'news)
 253
 254 (deffoo nnspool-close-group (group &optional server)
 255   t)
 256
 257 (deffoo nnspool-request-list (&optional server)
 258   "List active newsgroups."
 259   (save-excursion
 260     (or (nnspool-find-file nnspool-active-file)
 261         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 262
 263 (deffoo nnspool-request-list-newsgroups (&optional server)
 264   "List newsgroups (defined in NNTP2)."
 265   (save-excursion
 266     (or (nnspool-find-file nnspool-newsgroups-file)
 267         (nnheader-report 'nnspool (nnheader-file-error
 268                                    nnspool-newsgroups-file)))))
 269
 270 (deffoo nnspool-request-list-distributions (&optional server)
 271   "List distributions (defined in NNTP2)."
 272   (save-excursion
 273     (or (nnspool-find-file nnspool-distributions-file)
 274         (nnheader-report 'nnspool (nnheader-file-error
 275                                    nnspool-distributions-file)))))
 276
 277 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 278 (deffoo nnspool-request-newgroups (date &optional server)
 279   "List groups created after DATE."
 280   (if (nnspool-find-file nnspool-active-times-file)
 281       (save-excursion
 282         ;; Find the last valid line.
 283         (goto-char (point-max))
 284         (while (and (not (looking-at
 285                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 286                     (zerop (forward-line -1))))
 287         (let ((seconds (time-to-seconds (date-to-time date)))
 288               groups)
 289           ;; Go through lines and add the latest groups to a list.
 290           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 291                       (progn
 292                         ;; We insert a .0 to make the list reader
 293                         ;; interpret the number as a float.  It is far
 294                         ;; too big to be stored in a lisp integer.
 295                         (goto-char (1- (match-end 0)))
 296                         (insert ".0")
 297                         (> (progn
 298                              (goto-char (match-end 1))
 299                              (read (current-buffer)))
 300                            seconds))
 301                       (push (buffer-substring
 302                                           (match-beginning 1) (match-end 1))
 303                                          groups)
 304                       (zerop (forward-line -1))))
 305           (erase-buffer)
 306           (while groups
 307             (insert (car groups) " 0 0 y\n")
 308             (setq groups (cdr groups))))
 309         t)
 310     nil))
 311
 312 (deffoo nnspool-request-post (&optional server)
 313   "Post a new news in current buffer."
 314   (save-excursion
 315     (let* ((process-connection-type nil) ; t bugs out on Solaris
 316            (inews-buffer (generate-new-buffer " *nnspool post*"))
 317            (proc
 318             (condition-case err
 319                 (apply 'start-process "*nnspool inews*" inews-buffer
 320                        nnspool-inews-program nnspool-inews-switches)
 321               (error
 322                (nnheader-report 'nnspool "inews error: %S" err)))))
 323       (if (not proc)
 324           ;; The inews program failed.
 325           ()
 326         (nnheader-report 'nnspool "")
 327         (set-process-sentinel proc 'nnspool-inews-sentinel)
 328         (process-send-region proc (point-min) (point-max))
 329         ;; We slap a condition-case around this, because the process may
 330         ;; have exited already...
 331         (ignore-errors
 332           (process-send-eof proc))
 333         t))))
 334
 335
 336 \f
 337 ;;; Internal functions.
 338
 339 (defun nnspool-inews-sentinel (proc status)
 340   (save-excursion
 341     (set-buffer (process-buffer proc))
 342     (goto-char (point-min))
 343     (if (or (zerop (buffer-size))
 344             (search-forward "spooled" nil t))
 345         (kill-buffer (current-buffer))
 346       ;; Make status message by folding lines.
 347       (while (re-search-forward "[ \t\n]+" nil t)
 348         (replace-match " " t t))
 349       (nnheader-report 'nnspool "%s" (buffer-string))
 350       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 351       (ding)
 352       (run-hooks 'nnspool-rejected-article-hook))))
 353
 354 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 355   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 356       nil
 357     (let ((nov (nnheader-group-pathname
 358                 nnspool-current-group nnspool-nov-directory ".overview"))
 359           (arts articles)
 360           (nnheader-file-coding-system nnspool-file-coding-system)
 361           last)
 362       (if (not (file-exists-p nov))
 363           ()
 364         (save-excursion
 365           (set-buffer nntp-server-buffer)
 366           (erase-buffer)
 367           (if nnspool-sift-nov-with-sed
 368               (nnspool-sift-nov-with-sed articles nov)
 369             (mm-insert-file-contents nov)
 370             (if (and fetch-old
 371                      (not (numberp fetch-old)))
 372                 t                       ; We want all the headers.
 373               (ignore-errors
 374                 ;; Delete unwanted NOV lines.
 375                 (nnheader-nov-delete-outside-range
 376                  (if fetch-old (max 1 (- (car articles) fetch-old))
 377                    (car articles))
 378                  (car (last articles)))
 379                 ;; If the buffer is empty, this wasn't very successful.
 380                 (unless (zerop (buffer-size))
 381                   ;; We check what the last article number was.
 382                   ;; The NOV file may be out of sync with the articles
 383                   ;; in the group.
 384                   (forward-line -1)
 385                   (setq last (read (current-buffer)))
 386                   (if (= last (car articles))
 387                       ;; Yup, it's all there.
 388                       t
 389                     ;; Perhaps not.  We try to find the missing articles.
 390                     (while (and arts
 391                                 (<= last (car arts)))
 392                       (pop arts))
 393                     ;; The articles in `arts' are missing from the buffer.
 394                     (while arts
 395                       (nnspool-insert-nov-head (pop arts)))
 396                     t))))))))))
 397
 398 (defun nnspool-insert-nov-head (article)
 399   "Read the head of ARTICLE, convert to NOV headers, and insert."
 400   (save-excursion
 401     (let ((cur (current-buffer))
 402           buf)
 403       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 404       (when (nnheader-insert-head
 405              (nnspool-article-pathname nnspool-current-group article))
 406         (nnheader-insert-article-line article)
 407         (let ((headers (nnheader-parse-head)))
 408           (set-buffer cur)
 409           (goto-char (point-max))
 410           (nnheader-insert-nov headers)))
 411       (kill-buffer buf))))
 412
 413 (defun nnspool-sift-nov-with-sed (articles file)
 414   (let ((first (car articles))
 415         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 416                      (car articles))))
 417     (call-process "awk" nil t nil
 418                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 419                           (1- first) (1+ last))
 420                   file)))
 421
 422 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 423 ;; Find out what group an article identified by a Message-ID is in.
 424 (defun nnspool-find-id (id)
 425   (save-excursion
 426     (set-buffer (get-buffer-create " *nnspool work*"))
 427     (erase-buffer)
 428     (ignore-errors
 429       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 430     (goto-char (point-min))
 431     (prog1
 432         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 433           (cons (match-string 1) (string-to-int (match-string 2))))
 434       (kill-buffer (current-buffer)))))
 435
 436 (defun nnspool-find-file (file)
 437   "Insert FILE in server buffer safely."
 438   (set-buffer nntp-server-buffer)
 439   (erase-buffer)
 440   (condition-case ()
 441       (let ((nnheader-file-coding-system nnspool-file-coding-system))
 442         (mm-insert-file-contents file)
 443         t)
 444     (file-error nil)))
 445
 446 (defun nnspool-possibly-change-directory (group)
 447   (if (not group)
 448       t
 449     (let ((pathname (nnspool-article-pathname group)))
 450       (if (file-directory-p pathname)
 451           (setq nnspool-current-directory pathname
 452                 nnspool-current-group group)
 453         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 454
 455 (defun nnspool-article-pathname (group &optional article)
 456   "Find the path for GROUP."
 457   (nnheader-group-pathname group nnspool-spool-directory article))
 458
 459 (provide 'nnspool)
 460
 461 ;;; nnspool.el ends here