cgit.sxemacs.org Git - gnus/blob - lisp/nnrss.el

   1 ;;; nnrss.el --- interfacing with RSS
   2
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   6 ;; Keywords: RSS
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published
  12 ;; by the Free Software Foundation; either version 2, or (at your
  13 ;; option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'nnoo)
  33 (require 'nnmail)
  34 (require 'message)
  35 (require 'mm-util)
  36 (require 'gnus-util)
  37 (require 'time-date)
  38 (require 'rfc2231)
  39 (require 'mm-url)
  40 (require 'rfc2047)
  41 (require 'mml)
  42 (eval-when-compile
  43   (ignore-errors
  44    (require 'xml)))
  45 (eval '(require 'xml))
  46
  47 (nnoo-declare nnrss)
  48
  49 (defvoo nnrss-directory (nnheader-concat gnus-directory "rss/")
  50   "Where nnrss will save its files.")
  51
  52 ;; (group max rss-url)
  53 (defvoo nnrss-server-data nil)
  54
  55 ;; (num timestamp url subject author date extra)
  56 (defvoo nnrss-group-data nil)
  57 (defvoo nnrss-group-max 0)
  58 (defvoo nnrss-group-min 1)
  59 (defvoo nnrss-group nil)
  60 (defvoo nnrss-group-hashtb (make-hash-table :test 'equal))
  61 (defvoo nnrss-status-string "")
  62
  63 (defconst nnrss-version "nnrss 1.0")
  64
  65 (defvar nnrss-group-alist '()
  66   "List of RSS addresses.")
  67
  68 (defvar nnrss-use-local nil)
  69
  70 (defvar nnrss-description-field 'X-Gnus-Description
  71   "Field name used for DESCRIPTION.
  72 To use the description in headers, put this name into `nnmail-extra-headers'.")
  73
  74 (defvar nnrss-url-field 'X-Gnus-Url
  75   "Field name used for URL.
  76 To use the description in headers, put this name into `nnmail-extra-headers'.")
  77
  78 (defvar nnrss-content-function nil
  79   "A function which is called in `nnrss-request-article'.
  80 The arguments are (ENTRY GROUP ARTICLE).
  81 ENTRY is the record of the current headline.  GROUP is the group name.
  82 ARTICLE is the article number of the current headline.")
  83
  84 (defvar nnrss-file-coding-system mm-universal-coding-system
  85   "Coding system used when reading and writing files.")
  86
  87 (defvar nnrss-compatible-encoding-alist '((iso-8859-1 . windows-1252))
  88   "Alist of encodings and those supersets.
  89 The cdr of each element is used to decode data if it is available when
  90 the car is what the data specify as the encoding.  Or, the car is used
  91 for decoding when the cdr that the data specify is not available.")
  92
  93 (defvar nnrss-wash-html-in-text-plain-parts nil
  94   "*Non-nil means render text in text/plain parts as HTML.
  95 The function specified by the `mm-text-html-renderer' variable will be
  96 used to render text.  If it is nil, text will simply be folded.")
  97
  98 (nnoo-define-basics nnrss)
  99
 100 ;;; Interface functions
 101
 102 (defsubst nnrss-format-string (string)
 103   (gnus-replace-in-string string " *\n *" " "))
 104
 105 (defun nnrss-decode-group-name (group)
 106   (if (and group (mm-coding-system-p 'utf-8))
 107       (setq group (mm-decode-coding-string group 'utf-8))
 108     group))
 109
 110 (deffoo nnrss-retrieve-headers (articles &optional group server fetch-old)
 111   (setq group (nnrss-decode-group-name group))
 112   (nnrss-possibly-change-group group server)
 113   (let (e)
 114     (save-excursion
 115       (set-buffer nntp-server-buffer)
 116       (erase-buffer)
 117       (dolist (article articles)
 118         (if (setq e (assq article nnrss-group-data))
 119             (insert (number-to-string (car e)) "\t" ;; number
 120                     ;; subject
 121                     (or (nth 3 e) "")
 122                     "\t"
 123                     ;; from
 124                     (or (nth 4 e) "(nobody)")
 125                     "\t"
 126                     ;; date
 127                     (or (nth 5 e) "")
 128                     "\t"
 129                     ;; id
 130                     (format "<%d@%s.nnrss>" (car e) group)
 131                     "\t"
 132                     ;; refs
 133                     "\t"
 134                     ;; chars
 135                     "-1" "\t"
 136                     ;; lines
 137                     "-1" "\t"
 138                     ;; Xref
 139                     "" "\t"
 140                     (if (and (nth 6 e)
 141                              (memq nnrss-description-field
 142                                    nnmail-extra-headers))
 143                         (concat (symbol-name nnrss-description-field)
 144                                 ": "
 145                                 (nnrss-format-string (nth 6 e))
 146                                 "\t")
 147                       "")
 148                     (if (and (nth 2 e)
 149                              (memq nnrss-url-field
 150                                    nnmail-extra-headers))
 151                         (concat (symbol-name nnrss-url-field)
 152                                 ": "
 153                                 (nnrss-format-string (nth 2 e))
 154                                 "\t")
 155                       "")
 156                     "\n")))))
 157   'nov)
 158
 159 (deffoo nnrss-request-group (group &optional server dont-check)
 160   (setq group (nnrss-decode-group-name group))
 161   (nnheader-message 6 "nnrss: Requesting %s..." group)
 162   (nnrss-possibly-change-group group server)
 163   (prog1
 164       (if dont-check
 165           t
 166         (nnrss-check-group group server)
 167         (nnheader-report 'nnrss "Opened group %s" group)
 168         (nnheader-insert
 169          "211 %d %d %d %s\n" nnrss-group-max nnrss-group-min nnrss-group-max
 170          (prin1-to-string group)
 171          t))
 172     (nnheader-message 6 "nnrss: Requesting %s...done" group)))
 173
 174 (deffoo nnrss-close-group (group &optional server)
 175   t)
 176
 177 (eval-when-compile
 178   (defvar mm-text-html-renderer)
 179   (defvar mm-text-html-washer-alist))
 180
 181 (deffoo nnrss-request-article (article &optional group server buffer)
 182   (setq group (nnrss-decode-group-name group))
 183   (when (stringp article)
 184     (setq article (if (string-match "\\`<\\([0-9]+\\)@" article)
 185                       (string-to-number (match-string 1 article))
 186                     0)))
 187   (nnrss-possibly-change-group group server)
 188   (let ((e (assq article nnrss-group-data))
 189         (nntp-server-buffer (or buffer nntp-server-buffer))
 190         post err)
 191     (when e
 192       (with-current-buffer nntp-server-buffer
 193         (erase-buffer)
 194         (if group
 195             (insert "Newsgroups: " group "\n"))
 196         (if (nth 3 e)
 197             (insert "Subject: " (nth 3 e) "\n"))
 198         (if (nth 4 e)
 199             (insert "From: " (nth 4 e) "\n"))
 200         (if (nth 5 e)
 201             (insert "Date: " (nnrss-format-string (nth 5 e)) "\n"))
 202         (let ((header (buffer-string))
 203               (text (nth 6 e))
 204               (link (nth 2 e))
 205               (enclosure (nth 7 e))
 206               (comments (nth 8 e))
 207               ;; Enable encoding of Newsgroups header in XEmacs.
 208               (default-enable-multibyte-characters t)
 209               (rfc2047-header-encoding-alist
 210                (if (mm-coding-system-p 'utf-8)
 211                    (cons '("Newsgroups" . utf-8)
 212                          rfc2047-header-encoding-alist)
 213                  rfc2047-header-encoding-alist))
 214               rfc2047-encode-encoded-words body fn)
 215           (when (or text link enclosure comments)
 216             (insert "\n")
 217             (insert "<#multipart type=alternative>\n"
 218                     "<#part type=\"text/plain\">\n")
 219             (setq body (point))
 220             (when text
 221               (insert text)
 222               (goto-char body)
 223               (if (and nnrss-wash-html-in-text-plain-parts
 224                        (progn
 225                          (require 'mm-view)
 226                          (setq fn (or (cdr (assq mm-text-html-renderer
 227                                                  mm-text-html-washer-alist))
 228                                       mm-text-html-renderer))))
 229                   (progn
 230                     (narrow-to-region body (point-max))
 231                     (if (functionp fn)
 232                         (funcall fn)
 233                       (apply (car fn) (cdr fn)))
 234                     (widen)
 235                     (goto-char body)
 236                     (re-search-forward "[^\t\n ]" nil t)
 237                     (beginning-of-line)
 238                     (delete-region body (point))
 239                     (goto-char (point-max))
 240                     (skip-chars-backward "\t\n ")
 241                     (end-of-line)
 242                     (delete-region (point) (point-max))
 243                     (insert "\n"))
 244                 (while (re-search-forward "\n+" nil t)
 245                   (replace-match " "))
 246                 (goto-char body)
 247                 ;; See `nnrss-check-group', which inserts "<br /><br />".
 248                 (when (search-forward "<br /><br />" nil t)
 249                   (if (eobp)
 250                       (replace-match "\n")
 251                     (replace-match "\n\n")))
 252                 (unless (eobp)
 253                   (let ((fill-column default-fill-column)
 254                         (window (get-buffer-window nntp-server-buffer)))
 255                     (when window
 256                       (setq fill-column
 257                             (max 1 (/ (* (window-width window) 7) 8))))
 258                     (fill-region (point) (point-max))
 259                     (goto-char (point-max))
 260                     ;; XEmacs version of `fill-region' inserts newline.
 261                     (unless (bolp)
 262                       (insert "\n")))))
 263               (when (or link enclosure)
 264                 (insert "\n")))
 265             (when link
 266               (insert link "\n"))
 267             (when enclosure
 268               (insert (car enclosure) " "
 269                       (nth 2 enclosure) " "
 270                       (nth 3 enclosure) "\n"))
 271             (when comments
 272               (insert comments "\n"))
 273             (setq body (buffer-substring body (point)))
 274             (insert "<#/part>\n"
 275                     "<#part type=\"text/html\">\n"
 276                     "<html><head></head><body>\n")
 277             (when text
 278               (insert text "\n"))
 279             (when link
 280               (insert "<p><a href=\"" link "\">link</a></p>\n"))
 281             (when enclosure
 282               (insert "<p><a href=\"" (car enclosure) "\">"
 283                       (cadr enclosure) "</a> " (nth 2 enclosure)
 284                       " " (nth 3 enclosure) "</p>\n"))
 285             (when comments
 286               (insert "<p><a href=\"" comments "\">comments</a></p>\n"))
 287             (insert "</body></html>\n"
 288                     "<#/part>\n"
 289                     "<#/multipart>\n"))
 290           (condition-case nil
 291               (mml-to-mime)
 292             (error
 293              (erase-buffer)
 294              (insert header
 295                      "Content-Type: text/plain; charset=gnus-decoded\n"
 296                      "Content-Transfer-Encoding: 8bit\n\n"
 297                      body)
 298              (nnheader-message
 299               3 "Warning - there might be invalid characters"))))
 300         (goto-char (point-min))
 301         (search-forward "\n\n")
 302         (forward-line -1)
 303         (insert (format "Message-ID: <%d@%s.nnrss>\n"
 304                         (car e)
 305                         (let ((rfc2047-encoding-type 'mime)
 306                               rfc2047-encode-max-chars)
 307                           (rfc2047-encode-string
 308                            (gnus-replace-in-string group "[\t\n ]+" "_")))))
 309         (when nnrss-content-function
 310           (funcall nnrss-content-function e group article))))
 311     (cond
 312      (err
 313       (nnheader-report 'nnrss err))
 314      ((not e)
 315       (nnheader-report 'nnrss "no such id: %d" article))
 316      (t
 317       (nnheader-report 'nnrss "article %s retrieved" (car e))
 318       ;; we return the article number.
 319       (cons nnrss-group (car e))))))
 320
 321 (deffoo nnrss-request-list (&optional server)
 322   (nnrss-possibly-change-group nil server)
 323   (nnrss-generate-active)
 324   t)
 325
 326 (deffoo nnrss-open-server (server &optional defs connectionless)
 327   (nnrss-read-server-data server)
 328   (nnoo-change-server 'nnrss server defs)
 329   t)
 330
 331 (deffoo nnrss-request-expire-articles
 332     (articles group &optional server force)
 333   (setq group (nnrss-decode-group-name group))
 334   (nnrss-possibly-change-group group server)
 335   (let (e days not-expirable changed)
 336     (dolist (art articles)
 337       (if (and (setq e (assq art nnrss-group-data))
 338                (nnmail-expired-article-p
 339                 group
 340                 (if (listp (setq days (nth 1 e))) days
 341                   (days-to-time (- days (time-to-days '(0 0)))))
 342                 force))
 343           (setq nnrss-group-data (delq e nnrss-group-data)
 344                 changed t)
 345         (push art not-expirable)))
 346     (if changed
 347         (nnrss-save-group-data group server))
 348     not-expirable))
 349
 350 (deffoo nnrss-request-delete-group (group &optional force server)
 351   (setq group (nnrss-decode-group-name group))
 352   (nnrss-possibly-change-group group server)
 353   (let (elem)
 354     ;; There may be two or more entries in `nnrss-group-alist' since
 355     ;; this function didn't delete them formerly.
 356     (while (setq elem (assoc group nnrss-group-alist))
 357       (setq nnrss-group-alist (delq elem nnrss-group-alist))))
 358   (setq nnrss-server-data
 359         (delq (assoc group nnrss-server-data) nnrss-server-data))
 360   (nnrss-save-server-data server)
 361   (ignore-errors
 362    (delete-file (nnrss-make-filename group server)))
 363   t)
 364
 365 (deffoo nnrss-request-list-newsgroups (&optional server)
 366   (nnrss-possibly-change-group nil server)
 367   (save-excursion
 368     (set-buffer nntp-server-buffer)
 369     (erase-buffer)
 370     (dolist (elem nnrss-group-alist)
 371       (if (third elem)
 372           (insert (car elem) "\t" (third elem) "\n"))))
 373   t)
 374
 375 (nnoo-define-skeleton nnrss)
 376
 377 ;;; Internal functions
 378 (eval-when-compile (defun xml-rpc-method-call (&rest args)))
 379
 380 (defun nnrss-get-encoding ()
 381   "Return an encoding attribute specified in the current xml contents.
 382 If `nnrss-compatible-encoding-alist' specifies the compatible encoding,
 383 it is used instead.  If the xml contents doesn't specify the encoding,
 384 return `utf-8' which is the default encoding for xml if it is available,
 385 otherwise return nil."
 386   (goto-char (point-min))
 387   (if (re-search-forward
 388        "<\\?[^>]*encoding=\\(?:\"\\([^\">]+\\)\"\\|'\\([^'>]+\\)'\\)"
 389        nil t)
 390       (let ((encoding (intern (downcase (or (match-string 1)
 391                                             (match-string 2))))))
 392         (or
 393          (mm-coding-system-p (cdr (assq encoding
 394                                         nnrss-compatible-encoding-alist)))
 395          (mm-coding-system-p encoding)
 396          (mm-coding-system-p (car (rassq encoding
 397                                          nnrss-compatible-encoding-alist)))))
 398     (mm-coding-system-p 'utf-8)))
 399
 400 (defun nnrss-fetch (url &optional local)
 401   "Fetch URL and put it in a the expected Lisp structure."
 402   (mm-with-unibyte-buffer
 403     ;;some CVS versions of url.el need this to close the connection quickly
 404     (let (cs xmlform htmlform)
 405       ;; bit o' work necessary for w3 pre-cvs and post-cvs
 406       (if local
 407           (let ((coding-system-for-read 'binary))
 408             (insert-file-contents url))
 409         ;; FIXME: shouldn't binding `coding-system-for-read' be moved
 410         ;; to `mm-url-insert'?
 411         (let ((coding-system-for-read 'binary))
 412           (condition-case err
 413               (mm-url-insert url)
 414             (error (if (or debug-on-quit debug-on-error)
 415                        (signal (car err) (cdr err))
 416                      (message "nnrss: Failed to fetch %s" url))))))
 417       (nnheader-remove-cr-followed-by-lf)
 418       ;; Decode text according to the encoding attribute.
 419       (when (setq cs (nnrss-get-encoding))
 420         (mm-decode-coding-region (point-min) (point-max) cs)
 421         (mm-enable-multibyte))
 422       (goto-char (point-min))
 423
 424       ;; Because xml-parse-region can't deal with anything that isn't
 425       ;; xml and w3-parse-buffer can't deal with some xml, we have to
 426       ;; parse with xml-parse-region first and, if that fails, parse
 427       ;; with w3-parse-buffer.  Yuck.  Eventually, someone should find out
 428       ;; why w3-parse-buffer fails to parse some well-formed xml and
 429       ;; fix it.
 430
 431       (condition-case err1
 432           (setq xmlform (xml-parse-region (point-min) (point-max)))
 433         (error
 434          (condition-case err2
 435              (setq htmlform (caddar (w3-parse-buffer
 436                                      (current-buffer))))
 437            (error
 438             (message "\
 439 nnrss: %s: Not valid XML %s and w3-parse doesn't work %s"
 440                      url err1 err2)))))
 441       (if htmlform
 442           htmlform
 443         xmlform))))
 444
 445 (defun nnrss-possibly-change-group (&optional group server)
 446   (when (and server
 447              (not (nnrss-server-opened server)))
 448     (nnrss-open-server server))
 449   (when (and group (not (equal group nnrss-group)))
 450     (nnrss-read-group-data group server)
 451     (setq nnrss-group group)))
 452
 453 (defvar nnrss-extra-categories '(nnrss-snarf-moreover-categories))
 454
 455 (defun nnrss-generate-active ()
 456   (when (y-or-n-p "Fetch extra categories? ")
 457     (mapc 'funcall nnrss-extra-categories))
 458   (save-excursion
 459     (set-buffer nntp-server-buffer)
 460     (erase-buffer)
 461     (dolist (elem nnrss-group-alist)
 462       (insert (prin1-to-string (car elem)) " 0 1 y\n"))
 463     (dolist (elem nnrss-server-data)
 464       (unless (assoc (car elem) nnrss-group-alist)
 465         (insert (prin1-to-string (car elem)) " 0 1 y\n")))))
 466
 467 (eval-and-compile (autoload 'timezone-parse-date "timezone"))
 468
 469 (defun nnrss-normalize-date (date)
 470   "Return a date string of DATE in the RFC822 style.
 471 This function handles the ISO 8601 date format described in
 472 <URL:http://www.w3.org/TR/NOTE-datetime>, and also the RFC822 style
 473 which RSS 2.0 allows."
 474   (let (case-fold-search vector year month day time zone cts)
 475     (cond ((null date))
 476           ;; RFC822
 477           ((string-match " [0-9]+ " date)
 478            (setq vector (timezone-parse-date date)
 479                  year (string-to-number (aref vector 0)))
 480            (when (>= year 1969)
 481              (setq month (string-to-number (aref vector 1))
 482                    day (string-to-number (aref vector 2)))
 483              (unless (>= (length (setq time (aref vector 3))) 3)
 484                (setq time "00:00:00"))
 485              (when (and (setq zone (aref vector 4))
 486                         (not (string-match "\\`[A-Z+-]" zone)))
 487                (setq zone nil))))
 488           ;; ISO 8601
 489           ((string-match
 490             (eval-when-compile
 491               (concat
 492                ;; 1. year
 493                "\\(199[0-9]\\|20[0-9][0-9]\\)"
 494                "\\(?:-"
 495                ;; 2. month
 496                "\\([01][0-9]\\)"
 497                "\\(?:-"
 498                ;; 3. day
 499                "\\([0-3][0-9]\\)"
 500                "\\)?\\)?\\(?:T"
 501                ;; 4. hh:mm
 502                "\\([012][0-9]:[0-5][0-9]\\)"
 503                "\\(?:"
 504                ;; 5. :ss
 505                "\\(:[0-5][0-9]\\)"
 506                "\\(?:\\.[0-9]+\\)?\\)?\\)?"
 507                ;; 6+7,8,9. zone
 508                "\\(?:\\(?:\\([+-][012][0-9]\\):\\([0-5][0-9]\\)\\)"
 509                "\\|\\([+-][012][0-9][0-5][0-9]\\)"
 510                "\\|\\(Z\\)\\)?"))
 511             date)
 512            (setq year (string-to-number (match-string 1 date))
 513                  month (string-to-number (or (match-string 2 date) "1"))
 514                  day (string-to-number (or (match-string 3 date) "1"))
 515                  time (if (match-beginning 5)
 516                           (substring date (match-beginning 4) (match-end 5))
 517                         (concat (or (match-string 4 date) "00:00") ":00"))
 518                  zone (cond ((match-beginning 6)
 519                              (concat (match-string 6 date)
 520                                      (match-string 7 date)))
 521                             ((match-beginning 9) ;; Z
 522                              "+0000")
 523                             (t ;; nil if zone is not provided.
 524                              (match-string 8 date))))))
 525     (if month
 526         (progn
 527           (setq cts (current-time-string (encode-time 0 0 0 day month year)))
 528           (format "%s, %02d %s %04d %s%s"
 529                   (substring cts 0 3) day (substring cts 4 7) year time
 530                   (if zone
 531                       (concat " " zone)
 532                     "")))
 533       (message-make-date))))
 534
 535 ;;; data functions
 536
 537 (defun nnrss-read-server-data (server)
 538   (setq nnrss-server-data nil)
 539   (let ((file (nnrss-make-filename "nnrss" server)))
 540     (when (file-exists-p file)
 541       ;; In Emacs 21.3 and earlier, `load' doesn't support non-ASCII
 542       ;; file names.  So, we use `insert-file-contents' instead.
 543       (mm-with-multibyte-buffer
 544         (let ((coding-system-for-read nnrss-file-coding-system)
 545               (file-name-coding-system nnmail-pathname-coding-system))
 546           (insert-file-contents file)
 547           (eval-region (point-min) (point-max)))))))
 548
 549 (defun nnrss-save-server-data (server)
 550   (gnus-make-directory nnrss-directory)
 551   (let ((coding-system-for-write nnrss-file-coding-system)
 552         (file-name-coding-system nnmail-pathname-coding-system))
 553     (with-temp-file (nnrss-make-filename "nnrss" server)
 554       (insert (format ";; -*- coding: %s; -*-\n"
 555                       nnrss-file-coding-system))
 556       (gnus-prin1 `(setq nnrss-group-alist ',nnrss-group-alist))
 557       (insert "\n")
 558       (gnus-prin1 `(setq nnrss-server-data ',nnrss-server-data)))))
 559
 560 (defun nnrss-read-group-data (group server)
 561   (setq nnrss-group-data nil)
 562   (if (hash-table-p nnrss-group-hashtb)
 563       (clrhash nnrss-group-hashtb)
 564     (setq nnrss-group-hashtb (make-hash-table :test 'equal)))
 565   (let ((pair (assoc group nnrss-server-data)))
 566     (setq nnrss-group-max (or (cadr pair) 0))
 567     (setq nnrss-group-min (+ nnrss-group-max 1)))
 568   (let ((file (nnrss-make-filename group server)))
 569     (when (file-exists-p file)
 570       ;; In Emacs 21.3 and earlier, `load' doesn't support non-ASCII
 571       ;; file names.  So, we use `insert-file-contents' instead.
 572       (mm-with-multibyte-buffer
 573         (let ((coding-system-for-read nnrss-file-coding-system)
 574               (file-name-coding-system nnmail-pathname-coding-system))
 575           (insert-file-contents file)
 576           (eval-region (point-min) (point-max))))
 577       (dolist (e nnrss-group-data)
 578         (puthash (or (nth 2 e) (nth 6 e)) t nnrss-group-hashtb)
 579         (when (and (car e) (> nnrss-group-min (car e)))
 580           (setq nnrss-group-min (car e)))
 581         (when (and (car e) (< nnrss-group-max (car e)))
 582           (setq nnrss-group-max (car e)))))))
 583
 584 (defun nnrss-save-group-data (group server)
 585   (gnus-make-directory nnrss-directory)
 586   (let ((coding-system-for-write nnrss-file-coding-system)
 587         (file-name-coding-system nnmail-pathname-coding-system))
 588     (with-temp-file (nnrss-make-filename group server)
 589       (insert (format ";; -*- coding: %s; -*-\n"
 590                       nnrss-file-coding-system))
 591       (gnus-prin1 `(setq nnrss-group-data ',nnrss-group-data)))))
 592
 593 (defun nnrss-make-filename (name server)
 594   (expand-file-name
 595    (nnrss-translate-file-chars
 596     (concat name
 597             (and server
 598                  (not (equal server ""))
 599                  "-")
 600             server
 601             ".el"))
 602    nnrss-directory))
 603
 604 (gnus-add-shutdown 'nnrss-close 'gnus)
 605
 606 (defun nnrss-close ()
 607   "Clear internal nnrss variables."
 608   (setq nnrss-group-data nil
 609         nnrss-server-data nil
 610         nnrss-group-hashtb nil
 611         nnrss-group-alist nil))
 612
 613 ;;; URL interface
 614
 615 (defun nnrss-no-cache (url)
 616   "")
 617
 618 (defun nnrss-insert-w3 (url)
 619   (mm-with-unibyte-current-buffer
 620     (condition-case err
 621         (mm-url-insert url)
 622       (error (if (or debug-on-quit debug-on-error)
 623                  (signal (car err) (cdr err))
 624                (message "nnrss: Failed to fetch %s" url))))))
 625
 626 (defun nnrss-decode-entities-string (string)
 627   (if string
 628       (mm-with-multibyte-buffer
 629         (insert string)
 630         (mm-url-decode-entities-nbsp)
 631         (buffer-string))))
 632
 633 (defalias 'nnrss-insert 'nnrss-insert-w3)
 634
 635 (defun nnrss-mime-encode-string (string)
 636   (mm-with-multibyte-buffer
 637     (insert string)
 638     (mm-url-decode-entities-nbsp)
 639     (goto-char (point-min))
 640     (while (re-search-forward "[\t\n ]+" nil t)
 641       (replace-match " "))
 642     (goto-char (point-min))
 643     (skip-chars-forward " ")
 644     (delete-region (point-min) (point))
 645     (goto-char (point-max))
 646     (skip-chars-forward " ")
 647     (delete-region (point) (point-max))
 648     (let ((rfc2047-encoding-type 'mime)
 649           rfc2047-encode-max-chars)
 650       (rfc2047-encode-region (point-min) (point-max)))
 651     (goto-char (point-min))
 652     (while (search-forward "\n" nil t)
 653       (delete-backward-char 1))
 654     (buffer-string)))
 655
 656 ;;; Snarf functions
 657
 658 (defun nnrss-check-group (group server)
 659   (let (file xml subject url extra changed author date feed-subject
 660              enclosure comments rss-ns rdf-ns content-ns dc-ns)
 661     (if (and nnrss-use-local
 662              (file-exists-p (setq file (expand-file-name
 663                                         (nnrss-translate-file-chars
 664                                          (concat group ".xml"))
 665                                         nnrss-directory))))
 666         (setq xml (nnrss-fetch file t))
 667       (setq url (or (nth 2 (assoc group nnrss-server-data))
 668                     (second (assoc group nnrss-group-alist))))
 669       (unless url
 670         (setq url
 671               (cdr
 672                (assoc 'href
 673                       (nnrss-discover-feed
 674                        (read-string
 675                         (format "URL to search for %s: " group) "http://")))))
 676         (let ((pair (assoc group nnrss-server-data)))
 677           (if pair
 678               (setcdr (cdr pair) (list url))
 679             (push (list group nnrss-group-max url) nnrss-server-data)))
 680         (setq changed t))
 681       (setq xml (nnrss-fetch url)))
 682     ;; See
 683     ;; http://feeds.archive.org/validator/docs/howto/declare_namespaces.html
 684     ;; for more RSS namespaces.
 685     (setq dc-ns (nnrss-get-namespace-prefix xml "http://purl.org/dc/elements/1.1/")
 686           rdf-ns (nnrss-get-namespace-prefix xml "http://www.w3.org/1999/02/22-rdf-syntax-ns#")
 687           rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")
 688           content-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/modules/content/"))
 689     (dolist (item (nreverse (nnrss-find-el (intern (concat rss-ns "item")) xml)))
 690       (when (and (listp item)
 691                  (string= (concat rss-ns "item") (car item))
 692                  (if (setq url (nnrss-decode-entities-string
 693                                 (nnrss-node-text rss-ns 'link (cddr item))))
 694                      (not (gethash url nnrss-group-hashtb))
 695                    (setq extra (or (nnrss-node-text content-ns 'encoded item)
 696                                    (nnrss-node-text rss-ns 'description item)))
 697                    (not (gethash extra nnrss-group-hashtb))))
 698         (setq subject (nnrss-node-text rss-ns 'title item))
 699         (setq extra (or extra
 700                         (nnrss-node-text content-ns 'encoded item)
 701                         (nnrss-node-text rss-ns 'description item)))
 702         (if (setq feed-subject (nnrss-node-text dc-ns 'subject item))
 703             (setq extra (concat feed-subject "<br /><br />" extra)))
 704         (setq author (or (nnrss-node-text rss-ns 'author item)
 705                          (nnrss-node-text dc-ns 'creator item)
 706                          (nnrss-node-text dc-ns 'contributor item)))
 707         (setq date (nnrss-normalize-date
 708                     (or (nnrss-node-text dc-ns 'date item)
 709                         (nnrss-node-text rss-ns 'pubDate item))))
 710         (setq comments (nnrss-node-text rss-ns 'comments item))
 711         (when (setq enclosure (cadr (assq (intern (concat rss-ns "enclosure")) item)))
 712           (let ((url (cdr (assq 'url enclosure)))
 713                 (len (cdr (assq 'length enclosure)))
 714                 (type (cdr (assq 'type enclosure)))
 715                 (name))
 716             (setq len
 717                   (if (and len (integerp (setq len (string-to-number len))))
 718                       ;; actually already in `ls-lisp-format-file-size' but
 719                       ;; probably not worth to require it for one function
 720                       (do ((size (/ len 1.0) (/ size 1024.0))
 721                            (post-fixes (list "" "k" "M" "G" "T" "P" "E")
 722                                        (cdr post-fixes)))
 723                           ((< size 1024)
 724                            (format "%.1f%s" size (car post-fixes))))
 725                     "0"))
 726             (setq url (or url ""))
 727             (setq name (if (string-match "/\\([^/]*\\)$" url)
 728                            (match-string 1 url)
 729                          "file"))
 730             (setq type (or type ""))
 731             (setq enclosure (list url name len type))))
 732         (push
 733          (list
 734           (incf nnrss-group-max)
 735           (current-time)
 736           url
 737           (and subject (nnrss-mime-encode-string subject))
 738           (and author (nnrss-mime-encode-string author))
 739           date
 740           (and extra (nnrss-decode-entities-string extra))
 741           enclosure
 742           comments)
 743          nnrss-group-data)
 744         (puthash (or url extra) t nnrss-group-hashtb)
 745         (setq changed t))
 746       (setq extra nil))
 747     (when changed
 748       (nnrss-save-group-data group server)
 749       (let ((pair (assoc group nnrss-server-data)))
 750         (if pair
 751             (setcar (cdr pair) nnrss-group-max)
 752           (push (list group nnrss-group-max) nnrss-server-data)))
 753       (nnrss-save-server-data server))))
 754
 755 (defun nnrss-opml-import (opml-file)
 756   "OPML subscriptions import.
 757 Read the file and attempt to subscribe to each Feed in the file."
 758   (interactive "fImport file: ")
 759   (mapcar
 760    (lambda (node) (gnus-group-make-rss-group
 761                    (cdr (assq 'xmlUrl (cadr node)))))
 762    (nnrss-find-el 'outline
 763                   (progn
 764                     (find-file opml-file)
 765                     (xml-parse-region (point-min)
 766                                       (point-max))))))
 767
 768 (defun nnrss-opml-export ()
 769   "OPML subscription export.
 770 Export subscriptions to a buffer in OPML Format."
 771   (interactive)
 772   (with-current-buffer (get-buffer-create "*OPML Export*")
 773     (mm-set-buffer-file-coding-system 'utf-8)
 774     (insert "<?xml version=\"1.0\" encoding=\"utf-8\"?>\n"
 775             "<!-- OPML generated by Emacs Gnus' nnrss.el -->\n"
 776             "<opml version=\"1.1\">\n"
 777             "  <head>\n"
 778             "    <title>mySubscriptions</title>\n"
 779             "    <dateCreated>" (format-time-string "%a, %d %b %Y %T %z")
 780             "</dateCreated>\n"
 781             "    <ownerEmail>" user-mail-address "</ownerEmail>\n"
 782             "    <ownerName>" (user-full-name) "</ownerName>\n"
 783             "  </head>\n"
 784             "  <body>\n")
 785     (dolist (sub nnrss-group-alist)
 786       (insert "    <outline text=\"" (car sub)
 787               "\" xmlUrl=\"" (cadr sub) "\"/>\n"))
 788     (insert "  </body>\n"
 789             "</opml>\n"))
 790   (pop-to-buffer "*OPML Export*")
 791   (when (fboundp 'sgml-mode)
 792     (sgml-mode)))
 793
 794 (defun nnrss-generate-download-script ()
 795   "Generate a download script in the current buffer.
 796 It is useful when `(setq nnrss-use-local t)'."
 797   (interactive)
 798   (insert "#!/bin/sh\n")
 799   (insert "WGET=wget\n")
 800   (insert "RSSDIR='" (expand-file-name nnrss-directory) "'\n")
 801   (dolist (elem nnrss-server-data)
 802     (let ((url (or (nth 2 elem)
 803                    (second (assoc (car elem) nnrss-group-alist)))))
 804       (insert "$WGET -q -O \"$RSSDIR\"/'"
 805               (nnrss-translate-file-chars (concat (car elem) ".xml"))
 806               "' '" url "'\n"))))
 807
 808 (defun nnrss-translate-file-chars (name)
 809   (let ((nnheader-file-name-translation-alist
 810          (append nnheader-file-name-translation-alist '((?' . ?_)))))
 811     (nnheader-translate-file-chars name)))
 812
 813 (defvar nnrss-moreover-url
 814   "http://w.moreover.com/categories/category_list_rss.html"
 815   "The url of moreover.com categories.")
 816
 817 (defun nnrss-snarf-moreover-categories ()
 818   "Snarf RSS links from moreover.com."
 819   (interactive)
 820   (let (category name url changed)
 821     (with-temp-buffer
 822       (nnrss-insert nnrss-moreover-url)
 823       (goto-char (point-min))
 824       (while (re-search-forward
 825               "<a name=\"\\([^\"]+\\)\">\\|<a href=\"\\(http://[^\"]*moreover\\.com[^\"]+page\\?c=\\([^\"&]+\\)&o=rss\\)" nil t)
 826         (if (match-string 1)
 827             (setq category (match-string 1))
 828           (setq url (match-string 2)
 829                 name (mm-url-decode-entities-string
 830                       (rfc2231-decode-encoded-string
 831                        (match-string 3))))
 832           (if category
 833               (setq name (concat category "." name)))
 834           (unless (assoc name nnrss-server-data)
 835             (setq changed t)
 836             (push (list name 0 url) nnrss-server-data)))))
 837     (if changed
 838         (nnrss-save-server-data ""))))
 839
 840 (defun nnrss-node-text (namespace local-name element)
 841   (let* ((node (assq (intern (concat namespace (symbol-name local-name)))
 842                      element))
 843          (text (if (and node (listp node))
 844                    (nnrss-node-just-text node)
 845                  node))
 846          (cleaned-text (if text
 847                            (gnus-replace-in-string
 848                             (gnus-replace-in-string
 849                              text "^[\000-\037\177]+\\|^ +\\| +$" "")
 850                             "\r\n" "\n"))))
 851     (if (string-equal "" cleaned-text)
 852         nil
 853       cleaned-text)))
 854
 855 (defun nnrss-node-just-text (node)
 856   (if (and node (listp node))
 857       (mapconcat 'nnrss-node-just-text (cddr node) " ")
 858     node))
 859
 860 (defun nnrss-find-el (tag data &optional found-list)
 861   "Find the all matching elements in the data.
 862 Careful with this on large documents!"
 863   (when (consp data)
 864     (dolist (bit data)
 865       (when (car-safe bit)
 866         (when (equal tag (car bit))
 867           ;; Old xml.el may return a list of string.
 868           (when (and (consp (caddr bit))
 869                      (stringp (caaddr bit)))
 870             (setcar (cddr bit) (caaddr bit)))
 871           (setq found-list
 872                 (append found-list
 873                         (list bit))))
 874         (if (and (consp (car-safe (caddr bit)))
 875                  (not (stringp (caddr bit))))
 876             (setq found-list
 877                   (append found-list
 878                           (nnrss-find-el
 879                            tag (caddr bit))))
 880           (setq found-list
 881                 (append found-list
 882                         (nnrss-find-el
 883                          tag (cddr bit))))))))
 884   found-list)
 885
 886 (defun nnrss-rsslink-p (el)
 887   "Test if the element we are handed is an RSS autodiscovery link."
 888   (and (eq (car-safe el) 'link)
 889        (string-equal (cdr (assoc 'rel (cadr el))) "alternate")
 890        (or (string-equal (cdr (assoc 'type (cadr el)))
 891                          "application/rss+xml")
 892            (string-equal (cdr (assoc 'type (cadr el))) "text/xml"))))
 893
 894 (defun nnrss-get-rsslinks (data)
 895   "Extract the <link> elements that are links to RSS from the parsed data."
 896   (delq nil (mapcar
 897              (lambda (el)
 898                (if (nnrss-rsslink-p el) el))
 899              (nnrss-find-el 'link data))))
 900
 901 (defun nnrss-extract-hrefs (data)
 902   "Recursively extract hrefs from a page's source.
 903 DATA should be the output of `xml-parse-region' or
 904 `w3-parse-buffer'."
 905   (mapcar (lambda (ahref)
 906             (cdr (assoc 'href (cadr ahref))))
 907           (nnrss-find-el 'a data)))
 908
 909 (defmacro nnrss-match-macro (base-uri item onsite-list offsite-list)
 910   `(cond ((or (string-match (concat "^" ,base-uri) ,item)
 911               (not (string-match "://" ,item)))
 912           (setq ,onsite-list (append ,onsite-list (list ,item))))
 913          (t (setq ,offsite-list (append ,offsite-list (list ,item))))))
 914
 915 (defun nnrss-order-hrefs (base-uri hrefs)
 916   "Given a list of hrefs, sort them using the following priorities:
 917   1. links ending in .rss
 918   2. links ending in .rdf
 919   3. links ending in .xml
 920   4. links containing the above
 921   5. offsite links
 922
 923 BASE-URI is used to determine the location of the links and
 924 whether they are `offsite' or `onsite'."
 925   (let (rss-onsite-end  rdf-onsite-end  xml-onsite-end
 926         rss-onsite-in   rdf-onsite-in   xml-onsite-in
 927         rss-offsite-end rdf-offsite-end xml-offsite-end
 928         rss-offsite-in rdf-offsite-in xml-offsite-in)
 929     (dolist (href hrefs)
 930       (cond ((null href))
 931             ((string-match "\\.rss$" href)
 932              (nnrss-match-macro
 933               base-uri href rss-onsite-end rss-offsite-end))
 934             ((string-match "\\.rdf$" href)
 935              (nnrss-match-macro
 936               base-uri href rdf-onsite-end rdf-offsite-end))
 937             ((string-match "\\.xml$" href)
 938              (nnrss-match-macro
 939               base-uri href xml-onsite-end xml-offsite-end))
 940             ((string-match "rss" href)
 941              (nnrss-match-macro
 942               base-uri href rss-onsite-in rss-offsite-in))
 943             ((string-match "rdf" href)
 944              (nnrss-match-macro
 945               base-uri href rdf-onsite-in rdf-offsite-in))
 946             ((string-match "xml" href)
 947              (nnrss-match-macro
 948               base-uri href xml-onsite-in xml-offsite-in))))
 949     (append
 950      rss-onsite-end  rdf-onsite-end  xml-onsite-end
 951      rss-onsite-in   rdf-onsite-in   xml-onsite-in
 952      rss-offsite-end rdf-offsite-end xml-offsite-end
 953      rss-offsite-in rdf-offsite-in xml-offsite-in)))
 954
 955 (defun nnrss-discover-feed (url)
 956   "Given a page, find an RSS feed using Mark Pilgrim's
 957 `ultra-liberal rss locator' (http://diveintomark.org/2002/08/15.html)."
 958
 959   (let ((parsed-page (nnrss-fetch url)))
 960
 961 ;;    1. if this url is the rss, use it.
 962     (if (nnrss-rss-p parsed-page)
 963         (let ((rss-ns (nnrss-get-namespace-prefix parsed-page "http://purl.org/rss/1.0/")))
 964           (nnrss-rss-title-description rss-ns parsed-page url))
 965
 966 ;;    2. look for the <link rel="alternate"
 967 ;;    type="application/rss+xml" and use that if it is there.
 968       (let ((links (nnrss-get-rsslinks parsed-page)))
 969         (if links
 970             (let* ((xml (nnrss-fetch
 971                          (cdr (assoc 'href (cadar links)))))
 972                    (rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")))
 973               (nnrss-rss-title-description rss-ns xml (cdr (assoc 'href (cadar links)))))
 974
 975 ;;    3. look for links on the site in the following order:
 976 ;;       - onsite links ending in .rss, .rdf, or .xml
 977 ;;       - onsite links containing any of the above
 978 ;;       - offsite links ending in .rss, .rdf, or .xml
 979 ;;       - offsite links containing any of the above
 980           (let* ((base-uri (progn (string-match ".*://[^/]+/?" url)
 981                                   (match-string 0 url)))
 982                  (hrefs (nnrss-order-hrefs
 983                          base-uri (nnrss-extract-hrefs parsed-page)))
 984                  (rss-link nil))
 985             (while (and (eq rss-link nil) (not (eq hrefs nil)))
 986               (let ((href-data (nnrss-fetch (car hrefs))))
 987                 (if (nnrss-rss-p href-data)
 988                     (let* ((rss-ns (nnrss-get-namespace-prefix href-data "http://purl.org/rss/1.0/")))
 989                       (setq rss-link (nnrss-rss-title-description
 990                                       rss-ns href-data (car hrefs))))
 991                   (setq hrefs (cdr hrefs)))))
 992             (if rss-link rss-link
 993
 994 ;;    4. check syndic8
 995               (nnrss-find-rss-via-syndic8 url))))))))
 996
 997 (defun nnrss-find-rss-via-syndic8 (url)
 998   "Query syndic8 for the rss feeds it has for URL."
 999   (if (not (locate-library "xml-rpc"))
1000       (progn
1001         (message "XML-RPC is not available... not checking Syndic8.")
1002         nil)
1003     (require 'xml-rpc)
1004     (let ((feedid (xml-rpc-method-call
1005                    "http://www.syndic8.com/xmlrpc.php"
1006                    'syndic8.FindSites
1007                    url)))
1008       (when feedid
1009         (let* ((feedinfo (xml-rpc-method-call
1010                           "http://www.syndic8.com/xmlrpc.php"
1011                           'syndic8.GetFeedInfo
1012                           feedid))
1013                (urllist
1014                 (delq nil
1015                       (mapcar
1016                        (lambda (listinfo)
1017                          (if (string-equal
1018                               (cdr (assoc "status" listinfo))
1019                               "Syndicated")
1020                              (cons
1021                               (cdr (assoc "sitename" listinfo))
1022                               (list
1023                                (cons 'title
1024                                      (cdr (assoc
1025                                            "sitename" listinfo)))
1026                                (cons 'href
1027                                      (cdr (assoc
1028                                            "dataurl" listinfo)))))))
1029                        feedinfo))))
1030           (if (not (> (length urllist) 1))
1031               (cdar urllist)
1032             (let ((completion-ignore-case t)
1033                   (selection
1034                    (mapcar (lambda (listinfo)
1035                              (cons (cdr (assoc "sitename" listinfo))
1036                                    (string-to-number
1037                                     (cdr (assoc "feedid" listinfo)))))
1038                            feedinfo)))
1039               (cdr (assoc
1040                     (completing-read
1041                      "Multiple feeds found.  Select one: "
1042                      selection nil t) urllist)))))))))
1043
1044 (defun nnrss-rss-p (data)
1045   "Test if DATA is an RSS feed.
1046 Simply ensures that the first element is rss or rdf."
1047   (or (eq (caar data) 'rss)
1048       (eq (caar data) 'rdf:RDF)))
1049
1050 (defun nnrss-rss-title-description (rss-namespace data url)
1051   "Return the title of an RSS feed."
1052   (if (nnrss-rss-p data)
1053       (let ((description (intern (concat rss-namespace "description")))
1054             (title (intern (concat rss-namespace "title")))
1055             (channel (nnrss-find-el (intern (concat rss-namespace "channel"))
1056                                     data)))
1057         (list
1058          (cons 'description (caddr (nth 0 (nnrss-find-el description channel))))
1059          (cons 'title (caddr (nth 0 (nnrss-find-el title channel))))
1060          (cons 'href url)))))
1061
1062 (defun nnrss-get-namespace-prefix (el uri)
1063   "Given EL (containing a parsed element) and URI (containing a string
1064 that gives the URI for which you want to retrieve the namespace
1065 prefix), return the prefix."
1066   (let* ((prefix (car (rassoc uri (cadar el))))
1067          (nslist (if prefix
1068                      (split-string (symbol-name prefix) ":")))
1069          (ns (cond ((eq (length nslist) 1) ; no prefix given
1070                     "")
1071                    ((eq (length nslist) 2) ; extract prefix
1072                     (cadr nslist)))))
1073     (if (and ns (not (string= ns "")))
1074         (concat ns ":")
1075       ns)))
1076
1077 (provide 'nnrss)
1078
1079
1080 ;;; nnrss.el ends here
1081
1082 ;;; arch-tag: 12910c07-0cdf-44fb-8d2c-416ded64c267