cgit.sxemacs.org Git - gnus/blob - lisp/nnrss.el

   1 ;;; nnrss.el --- interfacing with RSS
   2 ;; Copyright (C) 2001, 2002, 2003  Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5 ;; Keywords: RSS
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'nnoo)
  32 (require 'nnmail)
  33 (require 'message)
  34 (require 'mm-util)
  35 (require 'gnus-util)
  36 (require 'time-date)
  37 (require 'rfc2231)
  38 (require 'mm-url)
  39 (eval-when-compile
  40   (ignore-errors
  41     (require 'xml)))
  42 (eval '(require 'xml))
  43
  44 (nnoo-declare nnrss)
  45
  46 (defvoo nnrss-directory (nnheader-concat gnus-directory "rss/")
  47   "Where nnrss will save its files.")
  48
  49 ;; (group max rss-url)
  50 (defvoo nnrss-server-data nil)
  51
  52 ;; (num timestamp url subject author date extra)
  53 (defvoo nnrss-group-data nil)
  54 (defvoo nnrss-group-max 0)
  55 (defvoo nnrss-group-min 1)
  56 (defvoo nnrss-group nil)
  57 (defvoo nnrss-group-hashtb nil)
  58 (defvoo nnrss-status-string "")
  59
  60 (defconst nnrss-version "nnrss 1.0")
  61
  62 (defvar nnrss-group-alist '()
  63   "List of RSS addresses.")
  64
  65 (defvar nnrss-use-local nil)
  66
  67 (defvar nnrss-description-field 'X-Gnus-Description
  68   "Field name used for DESCRIPTION.
  69 To use the description in headers, put this name into `nnmail-extra-headers'.")
  70
  71 (defvar nnrss-url-field 'X-Gnus-Url
  72   "Field name used for URL.
  73 To use the description in headers, put this name into `nnmail-extra-headers'.")
  74
  75 (defvar nnrss-content-function nil
  76   "A function which is called in `nnrss-request-article'.
  77 The arguments are (ENTRY GROUP ARTICLE).
  78 ENTRY is the record of the current headline. GROUP is the group name.
  79 ARTICLE is the article number of the current headline.")
  80
  81 (nnoo-define-basics nnrss)
  82
  83 ;;; Interface functions
  84
  85 (deffoo nnrss-retrieve-headers (articles &optional group server fetch-old)
  86   (nnrss-possibly-change-group group server)
  87   (let (e)
  88     (save-excursion
  89       (set-buffer nntp-server-buffer)
  90       (erase-buffer)
  91       (dolist (article articles)
  92         (if (setq e (assq article nnrss-group-data))
  93             (insert (number-to-string (car e)) "\t" ;; number
  94                     (if (nth 3 e)
  95                         (nnrss-format-string (nth 3 e)) "")
  96                     "\t" ;; subject
  97                     (if (nth 4 e)
  98                         (nnrss-format-string (nth 4 e))
  99                       "(nobody)")
 100                     "\t" ;;from
 101                     (or (nth 5 e) "")
 102                     "\t" ;; date
 103                     (format "<%d@%s.nnrss>" (car e) group)
 104                     "\t" ;; id
 105                     "\t" ;; refs
 106                     "-1" "\t" ;; chars
 107                     "-1" "\t" ;; lines
 108                     "" "\t" ;; Xref
 109                     (if (and (nth 6 e)
 110                              (memq nnrss-description-field
 111                                    nnmail-extra-headers))
 112                         (concat (symbol-name nnrss-description-field)
 113                                 ": "
 114                                 (nnrss-format-string (nth 6 e))
 115                                 "\t")
 116                       "")
 117                     (if (and (nth 2 e)
 118                              (memq nnrss-url-field
 119                                    nnmail-extra-headers))
 120                         (concat (symbol-name nnrss-url-field)
 121                                 ": "
 122                                 (nnrss-format-string (nth 2 e))
 123                                 "\t")
 124                       "")
 125                     "\n")))))
 126   'nov)
 127
 128 (deffoo nnrss-request-group (group &optional server dont-check)
 129   (nnrss-possibly-change-group group server)
 130   (if dont-check
 131       t
 132     (nnrss-check-group group server)
 133     (nnheader-report 'nnrss "Opened group %s" group)
 134     (nnheader-insert
 135      "211 %d %d %d %s\n" nnrss-group-max nnrss-group-min nnrss-group-max
 136      (prin1-to-string group)
 137      t)))
 138
 139 (deffoo nnrss-close-group (group &optional server)
 140   t)
 141
 142 (deffoo nnrss-request-article (article &optional group server buffer)
 143   (nnrss-possibly-change-group group server)
 144   (let ((e (assq article nnrss-group-data))
 145         (nntp-server-buffer (or buffer nntp-server-buffer))
 146         post err)
 147     (when e
 148       (catch 'error
 149         (with-current-buffer nntp-server-buffer
 150           (erase-buffer)
 151           (goto-char (point-min))
 152           (insert "Mime-Version: 1.0\nContent-Type: text/html\n")
 153           (if group
 154               (insert "Newsgroups: " group "\n"))
 155           (if (nth 3 e)
 156               (insert "Subject: " (nnrss-format-string (nth 3 e)) "\n"))
 157           (if (nth 4 e)
 158               (insert "From: " (nnrss-format-string (nth 4 e)) "\n"))
 159           (if (nth 5 e)
 160               (insert "Date: " (nnrss-format-string (nth 5 e)) "\n"))
 161           (insert "Message-ID: " (format "<%d@%s.nnrss>" (car e) group) "\n")
 162           (insert "\n")
 163           (if (nth 6 e)
 164               (let ((point (point)))
 165                 (insert (nnrss-string-as-multibyte (nth 6 e)))
 166                 (goto-char point)
 167                 (while (re-search-forward "\n" nil t)
 168                   (replace-match " "))
 169                 (goto-char (point-max))
 170                 (insert "\n\n")
 171                 (fill-region point (point))))
 172           (if (nth 2 e)
 173               (insert "<p><a href='" (nth 2 e) "'>link</a></p>\n"))
 174           (if nnrss-content-function
 175               (funcall nnrss-content-function e group article)))))
 176     (cond
 177      (err
 178       (nnheader-report 'nnrss err))
 179      ((not e)
 180       (nnheader-report 'nnrss "no such id: %d" article))
 181      (t
 182       (nnheader-report 'nnrss "article %s retrieved" (car e))
 183       ;; we return the article number.
 184       (cons nnrss-group (car e))))))
 185
 186 (deffoo nnrss-request-list (&optional server)
 187   (nnrss-possibly-change-group nil server)
 188   (nnrss-generate-active)
 189   t)
 190
 191 (deffoo nnrss-open-server (server &optional defs connectionless)
 192   (nnrss-read-server-data server)
 193   (nnoo-change-server 'nnrss server defs)
 194   t)
 195
 196 (deffoo nnrss-request-expire-articles
 197     (articles group &optional server force)
 198   (nnrss-possibly-change-group group server)
 199   (let (e days not-expirable changed)
 200     (dolist (art articles)
 201       (if (and (setq e (assq art nnrss-group-data))
 202                (nnmail-expired-article-p
 203                 group
 204                 (if (listp (setq days (nth 1 e))) days
 205                   (days-to-time (- days (time-to-days '(0 0)))))
 206                 force))
 207           (setq nnrss-group-data (delq e nnrss-group-data)
 208                 changed t)
 209         (push art not-expirable)))
 210     (if changed
 211         (nnrss-save-group-data group server))
 212     not-expirable))
 213
 214 (deffoo nnrss-request-delete-group (group &optional force server)
 215   (nnrss-possibly-change-group group server)
 216   (setq nnrss-server-data
 217         (delq (assoc group nnrss-server-data) nnrss-server-data))
 218   (nnrss-save-server-data server)
 219   (let ((file (expand-file-name
 220                (nnrss-translate-file-chars
 221                 (concat group (and server
 222                                    (not (equal server ""))
 223                                    "-")
 224                         server ".el")) nnrss-directory)))
 225     (ignore-errors
 226       (delete-file file)))
 227   t)
 228
 229 (deffoo nnrss-request-list-newsgroups (&optional server)
 230   (nnrss-possibly-change-group nil server)
 231   (save-excursion
 232     (set-buffer nntp-server-buffer)
 233     (erase-buffer)
 234     (dolist (elem nnrss-group-alist)
 235       (if (third elem)
 236           (insert (car elem) "\t" (third elem) "\n"))))
 237   t)
 238
 239 (nnoo-define-skeleton nnrss)
 240
 241 ;;; Internal functions
 242 (eval-when-compile (defun xml-rpc-method-call (&rest args)))
 243 (defun nnrss-fetch (url &optional local)
 244   "Fetch the url and put it in a the expected lisp structure."
 245   (with-temp-buffer
 246   ;some CVS versions of url.el need this to close the connection quickly
 247     (let* (xmlform htmlform)
 248       ;; bit o' work necessary for w3 pre-cvs and post-cvs
 249       (if local
 250           (let ((coding-system-for-read 'binary))
 251             (insert-file-contents url))
 252         (mm-url-insert url))
 253
 254 ;; Because xml-parse-region can't deal with anything that isn't
 255 ;; xml and w3-parse-buffer can't deal with some xml, we have to
 256 ;; parse with xml-parse-region first and, if that fails, parse
 257 ;; with w3-parse-buffer.  Yuck.  Eventually, someone should find out
 258 ;; why w3-parse-buffer fails to parse some well-formed xml and
 259 ;; fix it.
 260
 261     (condition-case err
 262         (setq xmlform (xml-parse-region (point-min) (point-max)))
 263       (error (if (fboundp 'w3-parse-buffer)
 264                  (setq htmlform (caddar (w3-parse-buffer
 265                                          (current-buffer))))
 266                (message "nnrss: Not valid XML and w3 parse not available (%s)"
 267                         url))))
 268     (if htmlform
 269         htmlform
 270       xmlform))))
 271
 272 (defun nnrss-possibly-change-group (&optional group server)
 273   (when (and server
 274              (not (nnrss-server-opened server)))
 275     (nnrss-open-server server))
 276   (when (and group (not (equal group nnrss-group)))
 277     (nnrss-read-group-data group server)
 278     (setq nnrss-group group)))
 279
 280 (defvar nnrss-extra-categories '(nnrss-snarf-moreover-categories))
 281
 282 (defun nnrss-generate-active ()
 283   (if (y-or-n-p "fetch extra categories? ")
 284       (dolist (func nnrss-extra-categories)
 285         (funcall func)))
 286   (save-excursion
 287     (set-buffer nntp-server-buffer)
 288     (erase-buffer)
 289     (dolist (elem nnrss-group-alist)
 290       (insert (prin1-to-string (car elem)) " 0 1 y\n"))
 291     (dolist (elem nnrss-server-data)
 292       (unless (assoc (car elem) nnrss-group-alist)
 293         (insert (prin1-to-string (car elem)) " 0 1 y\n")))))
 294
 295 ;;; data functions
 296
 297 (defun nnrss-read-server-data (server)
 298   (setq nnrss-server-data nil)
 299   (let ((file (expand-file-name
 300                (nnrss-translate-file-chars
 301                 (concat "nnrss" (and server
 302                                      (not (equal server ""))
 303                                      "-")
 304                         server
 305                         ".el"))
 306                nnrss-directory)))
 307     (when (file-exists-p file)
 308       (with-temp-buffer
 309         (let ((coding-system-for-read 'binary)
 310               emacs-lisp-mode-hook)
 311           (insert-file-contents file)
 312           (emacs-lisp-mode)
 313           (goto-char (point-min))
 314           (eval-buffer))))))
 315
 316 (defun nnrss-save-server-data (server)
 317   (gnus-make-directory nnrss-directory)
 318   (let ((file (expand-file-name
 319                (nnrss-translate-file-chars
 320                 (concat "nnrss" (and server
 321                                      (not (equal server ""))
 322                                      "-")
 323                         server ".el"))
 324                nnrss-directory)))
 325     (let ((coding-system-for-write 'binary)
 326           print-level print-length)
 327       (with-temp-file file
 328         (insert "(setq nnrss-group-alist '"
 329                 (prin1-to-string nnrss-group-alist)
 330                 ")\n")
 331         (insert "(setq nnrss-server-data '"
 332                 (prin1-to-string nnrss-server-data)
 333                 ")\n")))))
 334
 335 (defun nnrss-read-group-data (group server)
 336   (setq nnrss-group-data nil)
 337   (setq nnrss-group-hashtb (gnus-make-hashtable))
 338   (let ((pair (assoc group nnrss-server-data)))
 339     (setq nnrss-group-max (or (cadr pair) 0))
 340     (setq nnrss-group-min (+ nnrss-group-max 1)))
 341   (let ((file (expand-file-name
 342                (nnrss-translate-file-chars
 343                 (concat group (and server
 344                                    (not (equal server ""))
 345                                    "-")
 346                         server ".el"))
 347                nnrss-directory)))
 348     (when (file-exists-p file)
 349       (with-temp-buffer
 350         (let ((coding-system-for-read 'binary)
 351               emacs-lisp-mode-hook)
 352           (insert-file-contents file)
 353           (emacs-lisp-mode)
 354           (goto-char (point-min))
 355           (eval-buffer)))
 356       (dolist (e nnrss-group-data)
 357         (gnus-sethash (nth 2 e) e nnrss-group-hashtb)
 358         (if (and (car e) (> nnrss-group-min (car e)))
 359             (setq nnrss-group-min (car e)))
 360         (if (and (car e) (< nnrss-group-max (car e)))
 361             (setq nnrss-group-max (car e)))))))
 362
 363 (defun nnrss-save-group-data (group server)
 364   (gnus-make-directory nnrss-directory)
 365   (let ((file (expand-file-name
 366                (nnrss-translate-file-chars
 367                 (concat group (and server
 368                                    (not (equal server ""))
 369                                    "-")
 370                         server ".el"))
 371                nnrss-directory)))
 372     (let ((coding-system-for-write 'binary)
 373           print-level print-length)
 374       (with-temp-file file
 375         (insert "(setq nnrss-group-data '"
 376                 (prin1-to-string nnrss-group-data)
 377                 ")\n")))))
 378
 379 ;;; URL interface
 380
 381 (defun nnrss-no-cache (url)
 382   "")
 383
 384 (defun nnrss-insert-w3 (url)
 385   (mm-with-unibyte-current-buffer
 386     (mm-url-insert url)))
 387
 388 (defun nnrss-decode-entities-unibyte-string (string)
 389   (if string
 390       (mm-with-unibyte-buffer
 391         (insert string)
 392         (mm-url-decode-entities-nbsp)
 393         (buffer-string))))
 394
 395 (defalias 'nnrss-insert 'nnrss-insert-w3)
 396
 397 (if (featurep 'xemacs)
 398     (defalias 'nnrss-string-as-multibyte 'identity)
 399   (defalias 'nnrss-string-as-multibyte 'string-as-multibyte))
 400
 401 ;;; Snarf functions
 402
 403 (defun nnrss-check-group (group server)
 404   (let (file xml subject url extra changed author
 405              date rss-ns rdf-ns content-ns dc-ns)
 406     (if (and nnrss-use-local
 407              (file-exists-p (setq file (expand-file-name
 408                                         (nnrss-translate-file-chars
 409                                          (concat group ".xml"))
 410                                         nnrss-directory))))
 411         (nnrss-fetch file t)
 412       (setq url (or (nth 2 (assoc group nnrss-server-data))
 413                     (second (assoc group nnrss-group-alist))))
 414       (unless url
 415         (setq url
 416              (cdr
 417               (assoc 'href
 418                      (nnrss-discover-feed
 419                       (read-string
 420                        (format "URL to search for %s: " group) "http://")))))
 421         (let ((pair (assoc group nnrss-server-data)))
 422           (if pair
 423               (setcdr (cdr pair) (list url))
 424             (push (list group nnrss-group-max url) nnrss-server-data)))
 425         (setq changed t))
 426       (setq xml (nnrss-fetch url)))
 427     ;; See
 428     ;; http://feeds.archive.org/validator/docs/howto/declare_namespaces.html
 429     ;; for more RSS namespaces.
 430     (setq dc-ns (nnrss-get-namespace-prefix xml "http://purl.org/dc/elements/1.1/")
 431           rdf-ns (nnrss-get-namespace-prefix xml "http://www.w3.org/1999/02/22-rdf-syntax-ns#")
 432           rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")
 433           content-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/modules/content/"))
 434     (dolist (item (nreverse (nnrss-find-el (intern (concat rss-ns "item")) xml)))
 435       (when (and (listp item)
 436                  (eq (intern (concat rss-ns "item")) (car item))
 437                  (setq url (nnrss-decode-entities-unibyte-string
 438                             (nnrss-node-text rss-ns 'link (cddr item))))
 439                  (not (gnus-gethash url nnrss-group-hashtb)))
 440         (setq subject (nnrss-node-text rss-ns 'title item))
 441         (setq extra (or (nnrss-node-text content-ns 'encoded item)
 442                         (nnrss-node-text rss-ns 'description item)))
 443         (setq author (or (nnrss-node-text rss-ns 'author item)
 444                          (nnrss-node-text dc-ns 'creator item)))
 445         (setq date (or (nnrss-node-text dc-ns 'date item)
 446                        (nnrss-node-text rss-ns 'pubDate item)
 447                        (message-make-date)))
 448         (push
 449          (list
 450           (incf nnrss-group-max)
 451           (current-time)
 452           url
 453           (and subject (nnrss-decode-entities-unibyte-string subject))
 454           (and author (nnrss-decode-entities-unibyte-string author))
 455           date
 456           (and extra (nnrss-decode-entities-unibyte-string extra)))
 457          nnrss-group-data)
 458         (gnus-sethash url (car nnrss-group-data) nnrss-group-hashtb)
 459         (setq changed t)))
 460     (when changed
 461       (nnrss-save-group-data group server)
 462       (let ((pair (assoc group nnrss-server-data)))
 463         (if pair
 464             (setcar (cdr pair) nnrss-group-max)
 465           (push (list group nnrss-group-max) nnrss-server-data)))
 466       (nnrss-save-server-data server))))
 467
 468 (defun nnrss-generate-download-script ()
 469   "Generate a download script in the current buffer.
 470 It is useful when `(setq nnrss-use-local t)'."
 471   (interactive)
 472   (insert "#!/bin/sh\n")
 473   (insert "WGET=wget\n")
 474   (insert "RSSDIR='" (expand-file-name nnrss-directory) "'\n")
 475   (dolist (elem nnrss-server-data)
 476     (let ((url (or (nth 2 elem)
 477                    (second (assoc (car elem) nnrss-group-alist)))))
 478       (insert "$WGET -q -O \"$RSSDIR\"/'"
 479               (nnrss-translate-file-chars (concat (car elem) ".xml"))
 480               "' '" url "'\n"))))
 481
 482 (defun nnrss-translate-file-chars (name)
 483   (let ((nnheader-file-name-translation-alist
 484          (append nnheader-file-name-translation-alist '((?' . ?_)))))
 485     (nnheader-translate-file-chars name)))
 486
 487 (defvar nnrss-moreover-url
 488   "http://w.moreover.com/categories/category_list_rss.html"
 489   "The url of moreover.com categories.")
 490
 491 (defun nnrss-snarf-moreover-categories ()
 492   "Snarf RSS links from moreover.com."
 493   (interactive)
 494   (let (category name url changed)
 495     (with-temp-buffer
 496       (nnrss-insert nnrss-moreover-url)
 497       (goto-char (point-min))
 498       (while (re-search-forward
 499               "<a name=\"\\([^\"]+\\)\">\\|<a href=\"\\(http://[^\"]*moreover\\.com[^\"]+page\\?c=\\([^\"&]+\\)&o=rss\\)" nil t)
 500         (if (match-string 1)
 501             (setq category (match-string 1))
 502           (setq url (match-string 2)
 503                 name (mm-url-decode-entities-string
 504                       (rfc2231-decode-encoded-string
 505                        (match-string 3))))
 506           (if category
 507               (setq name (concat category "." name)))
 508           (unless (assoc name nnrss-server-data)
 509             (setq changed t)
 510             (push (list name 0 url) nnrss-server-data)))))
 511     (if changed
 512         (nnrss-save-server-data ""))))
 513
 514 (defun nnrss-format-string (string)
 515   (gnus-replace-in-string (nnrss-string-as-multibyte string) " *\n *" " "))
 516
 517 (defun nnrss-node-text (namespace local-name element)
 518   (let* ((node (assq (intern (concat namespace (symbol-name local-name)))
 519                      element))
 520          (text (if (and node (listp node))
 521                    (nnrss-node-just-text node)
 522                  node))
 523          (cleaned-text (if text (gnus-replace-in-string
 524                                  text "^[[:cntrl:]]+\\|^ +\\| +$" ""))))
 525     (if (string-equal "" cleaned-text)
 526         nil
 527       cleaned-text)))
 528
 529 (defun nnrss-node-just-text (node)
 530   (if (and node (listp node))
 531       (mapconcat 'nnrss-node-just-text (cddr node) " ")
 532     node))
 533
 534 (defun nnrss-find-el (tag data &optional found-list)
 535   "Find the all matching elements in the data.  Careful with this on
 536 large documents!"
 537   (if (listp data)
 538       (mapcar (lambda (bit)
 539                 (if (car-safe bit)
 540                     (progn (if (equal tag (car bit))
 541                                (setq found-list
 542                                      (append found-list
 543                                              (list bit))))
 544                            (if (and (listp (car-safe (caddr bit)))
 545                                     (not (stringp (caddr bit))))
 546                                (setq found-list
 547                                      (append found-list
 548                                              (nnrss-find-el
 549                                               tag (caddr bit))))
 550                              (setq found-list
 551                                    (append found-list
 552                                            (nnrss-find-el
 553                                             tag (cddr bit))))))))
 554                 data))
 555   found-list)
 556
 557 (defun nnrss-rsslink-p (el)
 558   "Test if the element we are handed is an RSS autodiscovery link."
 559   (and (eq (car-safe el) 'link)
 560        (string-equal (cdr (assoc 'rel (cadr el))) "alternate")
 561        (or (string-equal (cdr (assoc 'type (cadr el)))
 562                          "application/rss+xml")
 563            (string-equal (cdr (assoc 'type (cadr el))) "text/xml"))))
 564
 565 (defun nnrss-get-rsslinks (data)
 566   "Extract the <link> elements that are links to RSS from the parsed data."
 567   (delq nil (mapcar
 568              (lambda (el)
 569                (if (nnrss-rsslink-p el) el))
 570              (nnrss-find-el 'link data))))
 571
 572 (defun nnrss-extract-hrefs (data)
 573   "Recursively extract hrefs from a page's source.  DATA should be
 574 the output of xml-parse-region or w3-parse-buffer."
 575   (mapcar (lambda (ahref)
 576             (cdr (assoc 'href (cadr ahref))))
 577           (nnrss-find-el 'a data)))
 578
 579 (defmacro nnrss-match-macro (base-uri item
 580                                            onsite-list offsite-list)
 581   `(cond ((or (string-match (concat "^" ,base-uri) ,item)
 582                (not (string-match "://" ,item)))
 583            (setq ,onsite-list (append ,onsite-list (list ,item))))
 584           (t (setq ,offsite-list (append ,offsite-list (list ,item))))))
 585
 586 (defun nnrss-order-hrefs (base-uri hrefs)
 587   "Given a list of hrefs, sort them using the following priorities:
 588   1. links ending in .rss
 589   2. links ending in .rdf
 590   3. links ending in .xml
 591   4. links containing the above
 592   5. offsite links
 593
 594 BASE-URI is used to determine the location of the links and
 595 whether they are `offsite' or `onsite'."
 596   (let (rss-onsite-end  rdf-onsite-end  xml-onsite-end
 597         rss-onsite-in   rdf-onsite-in   xml-onsite-in
 598         rss-offsite-end rdf-offsite-end xml-offsite-end
 599         rss-offsite-in rdf-offsite-in xml-offsite-in)
 600     (mapcar (lambda (href)
 601               (if (not (null href))
 602               (cond ((string-match "\\.rss$" href)
 603                      (nnrss-match-macro
 604                       base-uri href rss-onsite-end rss-offsite-end))
 605                     ((string-match "\\.rdf$" href)
 606                      (nnrss-match-macro
 607                       base-uri href rdf-onsite-end rdf-offsite-end))
 608                     ((string-match "\\.xml$" href)
 609                      (nnrss-match-macro
 610                       base-uri href xml-onsite-end xml-offsite-end))
 611                     ((string-match "rss" href)
 612                      (nnrss-match-macro
 613                       base-uri href rss-onsite-in rss-offsite-in))
 614                     ((string-match "rdf" href)
 615                      (nnrss-match-macro
 616                       base-uri href rdf-onsite-in rdf-offsite-in))
 617                     ((string-match "xml" href)
 618                      (nnrss-match-macro
 619                       base-uri href xml-onsite-in xml-offsite-in)))))
 620             hrefs)
 621     (append
 622      rss-onsite-end  rdf-onsite-end  xml-onsite-end
 623      rss-onsite-in   rdf-onsite-in   xml-onsite-in
 624      rss-offsite-end rdf-offsite-end xml-offsite-end
 625      rss-offsite-in rdf-offsite-in xml-offsite-in)))
 626
 627 (defun nnrss-discover-feed (url)
 628   "Given a page, find an RSS feed using Mark Pilgrim's
 629 `ultra-liberal rss locator' (http://diveintomark.org/2002/08/15.html)."
 630
 631   (let ((parsed-page (nnrss-fetch url)))
 632
 633 ;;    1. if this url is the rss, use it.
 634     (if (nnrss-rss-p parsed-page)
 635         (let ((rss-ns (nnrss-get-namespace-prefix parsed-page "http://purl.org/rss/1.0/")))
 636           (nnrss-rss-title-description rss-ns parsed-page url))
 637
 638 ;;    2. look for the <link rel="alternate"
 639 ;;    type="application/rss+xml" and use that if it is there.
 640       (let ((links (nnrss-get-rsslinks parsed-page)))
 641         (if links
 642             (let* ((xml (nnrss-fetch
 643                          (cdr (assoc 'href (cadar links)))))
 644                    (rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")))
 645               (nnrss-rss-title-description rss-ns xml (cdr (assoc 'href (cadar links)))))
 646
 647 ;;    3. look for links on the site in the following order:
 648 ;;       - onsite links ending in .rss, .rdf, or .xml
 649 ;;       - onsite links containing any of the above
 650 ;;       - offsite links ending in .rss, .rdf, or .xml
 651 ;;       - offsite links containing any of the above
 652           (let* ((base-uri (progn (string-match ".*://[^/]+/?" url)
 653                                   (match-string 0 url)))
 654                  (hrefs (nnrss-order-hrefs
 655                          base-uri (nnrss-extract-hrefs parsed-page)))
 656                  (rss-link nil))
 657           (while (and (eq rss-link nil) (not (eq hrefs nil)))
 658             (let ((href-data (nnrss-fetch (car hrefs))))
 659               (if (nnrss-rss-p href-data)
 660                   (let* ((rss-ns (nnrss-get-namespace-prefix href-data "http://purl.org/rss/1.0/")))
 661                     (setq rss-link (nnrss-rss-title-description
 662                                     rss-ns href-data (car hrefs))))
 663                 (setq hrefs (cdr hrefs)))))
 664           (if rss-link rss-link
 665
 666 ;;    4. check syndic8
 667             (nnrss-find-rss-via-syndic8 url))))))))
 668
 669 (defun nnrss-find-rss-via-syndic8 (url)
 670   "query syndic8 for the rss feeds it has for the url."
 671   (condition-case nil
 672       (progn (require 'xml-rpc)
 673              (let ((feedid (xml-rpc-method-call
 674                             "http://www.syndic8.com/xmlrpc.php"
 675                             'syndic8.FindSites
 676                             url)))
 677                (if feedid
 678                    (let* ((feedinfo (xml-rpc-method-call
 679                                      "http://www.syndic8.com/xmlrpc.php"
 680                                      'syndic8.GetFeedInfo
 681                                      feedid))
 682                           (urllist
 683                            (delq nil
 684                                  (mapcar
 685                                   (lambda (listinfo)
 686                                     (if (string-equal
 687                                          (cdr (assoc "status" listinfo))
 688                                          "Syndicated")
 689                                         (cons
 690                                          (cdr (assoc "sitename" listinfo))
 691                                          (list
 692                                           (cons 'title
 693                                                 (cdr (assoc
 694                                                       "sitename" listinfo)))
 695                                           (cons 'href
 696                                                 (cdr (assoc
 697                                                       "dataurl" listinfo)))))))
 698                                   feedinfo))))
 699                      (if (> (length urllist) 1)
 700                          (let ((completion-ignore-case t)
 701                                (selection
 702                                 (mapcar (lambda (listinfo)
 703                                           (cons (cdr (assoc "sitename" listinfo))
 704                                                 (string-to-int
 705                                                  (cdr (assoc "feedid" listinfo)))))
 706                                         feedinfo)))
 707                            (cdr (assoc
 708                                  (completing-read
 709                                   "Multiple feeds found.  Select one: "
 710                                   selection nil t) urllist)))
 711                        (cdar urllist))))))
 712     (error (message "XML-RPC is not available... not checking Syndic8."))))
 713
 714 (defun nnrss-rss-p (data)
 715   "Test if data is an RSS feed.  Simply ensures that the first
 716 element is rss or rdf."
 717   (or (eq (caar data) 'rss)
 718       (eq (caar data) 'rdf:RDF)))
 719
 720 (defun nnrss-rss-title-description (rss-namespace data url)
 721   "Return the title of an RSS feed."
 722   (if (nnrss-rss-p data)
 723       (let ((description (intern (concat rss-namespace "description")))
 724             (title (intern (concat rss-namespace "title")))
 725             (channel (nnrss-find-el (intern (concat rss-namespace "channel"))
 726                                     data)))
 727         (list
 728          (cons 'description (caddr (nth 0 (nnrss-find-el description channel))))
 729          (cons 'title (caddr (nth 0 (nnrss-find-el title channel))))
 730          (cons 'href url)))))
 731
 732 (defun nnrss-get-namespace-prefix (el uri)
 733   "Given EL (containing a parsed element) and URI (containing a string
 734 that gives the URI for which you want to retrieve the namespace
 735 prefix), return the prefix."
 736   (let* ((prefix (car (rassoc uri (cadar el))))
 737          (nslist (if prefix
 738                      (split-string (symbol-name prefix) ":")))
 739          (ns (cond ((eq (length nslist) 1) ; no prefix given
 740                     "")
 741                    ((eq (length nslist) 2) ; extract prefix
 742                     (cadr nslist)))))
 743     (if (and ns (not (eq ns "")))
 744         (concat ns ":")
 745       ns)))
 746
 747 (provide 'nnrss)
 748
 749
 750 ;;; nnrss.el ends here
 751