cgit.sxemacs.org Git - gnus/blob - lisp/nnoo.el

   1 ;;; nnoo.el --- OO Gnus Backends
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'nnheader)
  29 (require 'cl)
  30
  31 (defvar nnoo-definition-alist nil)
  32 (defvar nnoo-state-alist nil)
  33
  34 (defmacro defvoo (var init &optional doc &rest map)
  35   "The same as `defvar', only takes list of variables to MAP to."
  36   `(prog1
  37        ,(if doc
  38             `(defvar ,var ,init ,doc)
  39           `(defvar ,var ,init))
  40      (nnoo-define ',var ',map)))
  41 (put 'defvoo 'lisp-indent-function 2)
  42 (put 'defvoo 'edebug-form-spec '(var init &optional doc &rest map))
  43
  44 (defmacro deffoo (func args &rest forms)
  45   "The same as `defun', only register FUNC."
  46   `(prog1
  47        (defun ,func ,args ,@forms)
  48      (nnoo-register-function ',func)))
  49 (put 'deffoo 'lisp-indent-function 2)
  50 (put 'deffoo 'edebug-form-spec '(&define name lambda-list def-body))
  51
  52 (defun nnoo-register-function (func)
  53   (let ((funcs (nthcdr 3 (assoc (nnoo-backend func)
  54                                 nnoo-definition-alist))))
  55     (unless funcs
  56       (error "%s belongs to a backend that hasn't been declared" func))
  57     (setcar funcs (cons func (car funcs)))))
  58
  59 (defmacro nnoo-declare (backend &rest parents)
  60   `(eval-and-compile
  61      (push (list ',backend
  62                  (mapcar (lambda (p) (list p)) ',parents)
  63                  nil nil)
  64            nnoo-definition-alist)))
  65 (put 'nnoo-declare 'lisp-indent-function 1)
  66
  67 (defun nnoo-parents (backend)
  68   (nth 1 (assoc backend nnoo-definition-alist)))
  69
  70 (defun nnoo-variables (backend)
  71   (nth 2 (assoc backend nnoo-definition-alist)))
  72
  73 (defun nnoo-functions (backend)
  74   (nth 3 (assoc backend nnoo-definition-alist)))
  75
  76 (defmacro nnoo-import (backend &rest imports)
  77   `(nnoo-import-1 ',backend ',imports))
  78 (put 'nnoo-import 'lisp-indent-function 1)
  79
  80 (defun nnoo-import-1 (backend imports)
  81   (let ((call-function
  82          (if (symbolp (car imports)) (pop imports) 'nnoo-parent-function))
  83         imp functions function)
  84     (while (setq imp (pop imports))
  85       (setq functions
  86             (or (cdr imp)
  87                 (nnoo-functions (car imp))))
  88       (while functions
  89         (unless (fboundp (setq function
  90                                (nnoo-symbol backend (nnoo-rest-symbol
  91                                                      (car functions)))))
  92           (eval `(deffoo ,function (&rest args)
  93                    (,call-function ',backend ',(car functions) args))))
  94         (pop functions)))))
  95
  96 (defun nnoo-parent-function (backend function args)
  97   (let* ((pbackend (nnoo-backend function)))
  98     (nnoo-change-server pbackend (nnoo-current-server backend)
  99                         (cdr (assq pbackend (nnoo-parents backend))))
 100     (apply function args)))
 101
 102 (defun nnoo-execute (backend function &rest args)
 103   "Execute FUNCTION on behalf of BACKEND."
 104   (let* ((pbackend (nnoo-backend function)))
 105     (nnoo-change-server pbackend (nnoo-current-server backend)
 106                         (cdr (assq pbackend (nnoo-parents backend))))
 107     (apply function args)))
 108
 109 (defmacro nnoo-map-functions (backend &rest maps)
 110   `(nnoo-map-functions-1 ',backend ',maps))
 111 (put 'nnoo-map-functions 'lisp-indent-function 1)
 112
 113 (defun nnoo-map-functions-1 (backend maps)
 114   (let (m margs i)
 115     (while (setq m (pop maps))
 116       (setq i 0
 117             margs nil)
 118       (while (< i (length (cdr m)))
 119         (if (numberp (nth i (cdr m)))
 120             (push `(nth ,i args) margs)
 121           (push (nth i (cdr m)) margs))
 122         (incf i))
 123       (eval `(deffoo ,(nnoo-symbol backend (nnoo-rest-symbol (car m)))
 124                  (&rest args)
 125                (nnoo-parent-function ',backend ',(car m)
 126                                      ,(cons 'list (nreverse margs))))))))
 127
 128 (defun nnoo-backend (symbol)
 129   (string-match "^[^-]+-" (symbol-name symbol))
 130   (intern (substring (symbol-name symbol) 0 (1- (match-end 0)))))
 131
 132 (defun nnoo-rest-symbol (symbol)
 133   (string-match "^[^-]+-" (symbol-name symbol))
 134   (intern (substring (symbol-name symbol) (match-end 0))))
 135
 136 (defun nnoo-symbol (backend symbol)
 137   (intern (format "%s-%s" backend symbol)))
 138
 139 (defun nnoo-define (var map)
 140   (let* ((backend (nnoo-backend var))
 141          (def (assq backend nnoo-definition-alist))
 142          (parents (nth 1 def)))
 143     (unless def
 144       (error "%s belongs to a backend that hasn't been declared." var))
 145     (setcar (nthcdr 2 def)
 146             (delq (assq var (nth 2 def)) (nth 2 def)))
 147     (setcar (nthcdr 2 def)
 148             (cons (cons var (symbol-value var))
 149                   (nth 2 def)))
 150     (while map
 151       (nconc (assq (nnoo-backend (car map)) parents)
 152              (list (list (pop map) var))))))
 153
 154 (defun nnoo-change-server (backend server defs)
 155   (let* ((bstate (cdr (assq backend nnoo-state-alist)))
 156          (current (car bstate))
 157          (parents (nnoo-parents backend))
 158          state)
 159     (unless bstate
 160       (push (setq bstate (list backend nil))
 161             nnoo-state-alist)
 162       (pop bstate))
 163     (if (equal server current)
 164         t
 165       (nnoo-push-server backend current)
 166       (setq state (or (cdr (assoc server (cddr bstate)))
 167                       (nnoo-variables backend)))
 168       (while state
 169         (set (caar state) (cdar state))
 170         (pop state))
 171       (setcar bstate server)
 172       (unless (cdr (assoc server (cddr bstate)))
 173         (while defs
 174           (set (caar defs) (cadar defs))
 175           (pop defs)))
 176       (while parents
 177         (nnoo-change-server
 178          (caar parents) server
 179          (mapcar (lambda (def) (list (car def) (symbol-value (cadr def))))
 180                  (cdar parents)))
 181         (pop parents))))
 182   t)
 183
 184 (defun nnoo-push-server (backend current)
 185   (let ((bstate (assq backend nnoo-state-alist))
 186         (defs (nnoo-variables backend)))
 187     ;; Remove the old definition.
 188     (setcdr (cdr bstate) (delq (assoc current (cddr bstate)) (cddr bstate)))
 189     (let (state)
 190       (while defs
 191         (push (cons (caar defs) (symbol-value (caar defs)))
 192               state)
 193         (pop defs))
 194       (nconc bstate (list (cons current state))))))
 195
 196 (defun nnoo-current-server-p (backend server)
 197   (equal (nnoo-current-server backend) server))
 198
 199 (defun nnoo-current-server (backend)
 200   (nth 1 (assq backend nnoo-state-alist)))
 201
 202 (defun nnoo-close-server (backend &optional server)
 203   (unless server
 204     (setq server (nnoo-current-server backend)))
 205   (when server
 206     (let* ((bstate (cdr (assq backend nnoo-state-alist)))
 207            (defs (assoc server (cdr bstate))))
 208       (when bstate
 209         (setcar bstate nil)
 210         (setcdr bstate (delq defs (cdr bstate)))
 211         (pop defs)
 212         (while defs
 213           (set (car (pop defs)) nil)))))
 214   t)
 215
 216 (defun nnoo-close (backend)
 217   (setq nnoo-state-alist
 218         (delq (assq backend nnoo-state-alist)
 219               nnoo-state-alist))
 220   t)
 221
 222 (defun nnoo-status-message (backend server)
 223   (nnheader-get-report backend))
 224
 225 (defun nnoo-server-opened (backend server)
 226   (and (nnoo-current-server-p backend server)
 227        nntp-server-buffer
 228        (buffer-name nntp-server-buffer)))
 229
 230 (defmacro nnoo-define-basics (backend)
 231   "Define `close-server', `server-opened' and `status-message'."
 232   `(eval-and-compile
 233      (nnoo-define-basics-1 ',backend)))
 234
 235 (defun nnoo-define-basics-1 (backend)
 236   (let ((functions '(close-server server-opened status-message)))
 237     (while functions
 238       (eval `(deffoo ,(nnoo-symbol backend (car functions))
 239                  (&optional server)
 240                (,(nnoo-symbol 'nnoo (pop functions)) ',backend server)))))
 241   (eval `(deffoo ,(nnoo-symbol backend 'open-server)
 242              (server &optional defs)
 243            (nnoo-change-server ',backend server defs))))
 244
 245 (defmacro nnoo-define-skeleton (backend)
 246   "Define all required backend functions for BACKEND.
 247 All functions will return nil and report an error."
 248   `(eval-and-compile
 249      (nnoo-define-skeleton-1 ',backend)))
 250
 251 (defun nnoo-define-skeleton-1 (backend)
 252   (let ((functions '(retrieve-headers
 253                      request-close request-article
 254                      open-group request-group close-group
 255                      request-list request-post request-list-newsgroups))
 256         function fun)
 257     (while (setq function (pop functions))
 258       (when (not (fboundp (setq fun (nnoo-symbol backend function))))
 259         (eval `(deffoo ,fun
 260                    (&rest args)
 261                  (nnheader-report ',backend ,(format "%s-%s not implemented"
 262                                                      backend function))))))))
 263 (provide 'nnoo)
 264
 265 ;;; nnoo.el ends here.