cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
  94   (when (nnml-possibly-change-directory group server)
  95     (save-excursion
  96       (set-buffer nntp-server-buffer)
  97       (erase-buffer)
  98       (let ((file nil)
  99             (number (length sequence))
 100             (count 0)
 101             beg article)
 102         (if (stringp (car sequence))
 103             'headers
 104           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 105               'nov
 106             (while sequence
 107               (setq article (car sequence))
 108               (setq file (nnml-article-to-file article))
 109               (when (and file
 110                          (file-exists-p file)
 111                          (not (file-directory-p file)))
 112                 (insert (format "221 %d Article retrieved.\n" article))
 113                 (setq beg (point))
 114                 (nnheader-insert-head file)
 115                 (goto-char beg)
 116                 (if (search-forward "\n\n" nil t)
 117                     (forward-char -1)
 118                   (goto-char (point-max))
 119                   (insert "\n\n"))
 120                 (insert ".\n")
 121                 (delete-region (point) (point-max)))
 122               (setq sequence (cdr sequence))
 123               (setq count (1+ count))
 124               (and (numberp nnmail-large-newsgroup)
 125                    (> number nnmail-large-newsgroup)
 126                    (zerop (% count 20))
 127                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 128                                      (/ (* count 100) number))))
 129
 130             (and (numberp nnmail-large-newsgroup)
 131                  (> number nnmail-large-newsgroup)
 132                  (nnheader-message 6 "nnml: Receiving headers...done"))
 133
 134             (nnheader-fold-continuation-lines)
 135             'headers))))))
 136
 137 (deffoo nnml-open-server (server &optional defs)
 138   (nnoo-change-server 'nnml server defs)
 139   (when (not (file-exists-p nnml-directory))
 140     (condition-case ()
 141         (make-directory nnml-directory t)
 142       (error)))
 143   (cond
 144    ((not (file-exists-p nnml-directory))
 145     (nnml-close-server)
 146     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 147    ((not (file-directory-p (file-truename nnml-directory)))
 148     (nnml-close-server)
 149     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 150    (t
 151     (nnheader-report 'nnml "Opened server %s using directory %s"
 152                      server nnml-directory)
 153     t)))
 154
 155 (defun nnml-request-regenerate (server)
 156   (nnml-possibly-change-directory nil server)
 157   (nnml-generate-nov-databases)
 158   t)
 159
 160 (deffoo nnml-request-article (id &optional group server buffer)
 161   (nnml-possibly-change-directory group server)
 162   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 163          path gpath group-num)
 164     (if (stringp id)
 165         (when (and (setq group-num (nnml-find-group-number id))
 166                    (cdr
 167                     (assq (cdr group-num)
 168                           (nnheader-article-to-file-alist
 169                            (setq gpath
 170                                  (nnmail-group-pathname
 171                                   (car group-num)
 172                                   nnml-directory))))))
 173           (setq path (concat gpath (int-to-string (cdr group-num)))))
 174       (setq path (nnml-article-to-file id)))
 175     (cond
 176      ((not path)
 177       (nnheader-report 'nnml "No such article: %s" id))
 178      ((not (file-exists-p path))
 179       (nnheader-report 'nnml "No such file: %s" path))
 180      ((file-directory-p path)
 181       (nnheader-report 'nnml "File is a directory: %s" path))
 182      ((not (save-excursion (nnmail-find-file path)))
 183       (nnheader-report 'nnml "Couldn't read file: %s" path))
 184      (t
 185       (nnheader-report 'nnml "Article %s retrieved" id)
 186       ;; We return the article number.
 187       (cons (if group-num (car group-num) group)
 188             (string-to-int (file-name-nondirectory path)))))))
 189
 190 (deffoo nnml-request-group (group &optional server dont-check)
 191   (cond
 192    ((not (nnml-possibly-change-directory group server))
 193     (nnheader-report 'nnml "Invalid group (no such directory)"))
 194    ((not (file-exists-p nnml-current-directory))
 195     (nnheader-report 'nnml "Directory %s does not exist"
 196                      nnml-current-directory))
 197    ((not (file-directory-p nnml-current-directory))
 198     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 199    (dont-check
 200     (nnheader-report 'nnml "Group %s selected" group)
 201     t)
 202    (t
 203     (nnheader-re-read-dir nnml-current-directory)
 204     (nnmail-activate 'nnml)
 205     (let ((active (nth 1 (assoc group nnml-group-alist))))
 206       (if (not active)
 207           (nnheader-report 'nnml "No such group: %s" group)
 208         (nnheader-report 'nnml "Selected group %s" group)
 209         (nnheader-insert "211 %d %d %d %s\n"
 210                          (max (1+ (- (cdr active) (car active))) 0)
 211                          (car active) (cdr active) group))))))
 212
 213 (deffoo nnml-request-scan (&optional group server)
 214   (setq nnml-article-file-alist nil)
 215   (nnml-possibly-change-directory group server)
 216   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 217
 218 (deffoo nnml-close-group (group &optional server)
 219   (setq nnml-article-file-alist nil)
 220   t)
 221
 222 (deffoo nnml-request-create-group (group &optional server args)
 223   (nnmail-activate 'nnml)
 224   (unless (assoc group nnml-group-alist)
 225     (let (active)
 226       (push (list group (setq active (cons 1 0)))
 227             nnml-group-alist)
 228       (nnml-possibly-create-directory group)
 229       (nnml-possibly-change-directory group server)
 230       (let ((articles (nnheader-directory-articles nnml-current-directory)))
 231         (when articles
 232           (setcar active (apply 'min articles))
 233           (setcdr active (apply 'max articles))))
 234       (nnmail-save-active nnml-group-alist nnml-active-file)))
 235   t)
 236
 237 (deffoo nnml-request-list (&optional server)
 238   (save-excursion
 239     (nnmail-find-file nnml-active-file)
 240     (setq nnml-group-alist (nnmail-get-active))
 241     t))
 242
 243 (deffoo nnml-request-newgroups (date &optional server)
 244   (nnml-request-list server))
 245
 246 (deffoo nnml-request-list-newsgroups (&optional server)
 247   (save-excursion
 248     (nnmail-find-file nnml-newsgroups-file)))
 249
 250 (deffoo nnml-request-expire-articles (articles group
 251                                                &optional server force)
 252   (nnml-possibly-change-directory group server)
 253   (let* ((active-articles
 254           (nnheader-directory-articles nnml-current-directory))
 255          (is-old t)
 256          article rest mod-time number)
 257     (nnmail-activate 'nnml)
 258
 259     (while (and articles is-old)
 260       (when (setq article (nnml-article-to-file (setq number (pop articles))))
 261         (when (setq mod-time (nth 5 (file-attributes article)))
 262           (if (and (nnml-deletable-article-p group number)
 263                    (setq is-old
 264                          (nnmail-expired-article-p group mod-time force
 265                                                    nnml-inhibit-expiry)))
 266               (progn
 267                 (nnheader-message 5 "Deleting article %s in %s"
 268                                   article group)
 269                 (condition-case ()
 270                     (funcall nnmail-delete-file-function article)
 271                   (file-error
 272                    (push number rest)))
 273                 (setq active-articles (delq number active-articles))
 274                 (nnml-nov-delete-article group number))
 275             (push number rest)))))
 276     (let ((active (nth 1 (assoc group nnml-group-alist))))
 277       (when active
 278         (setcar active (or (and active-articles
 279                                 (apply 'min active-articles))
 280                            (1+ (cdr active)))))
 281       (nnmail-save-active nnml-group-alist nnml-active-file))
 282     (nnml-save-nov)
 283     (nconc rest articles)))
 284
 285 (deffoo nnml-request-move-article
 286   (article group server accept-form &optional last)
 287   (let ((buf (get-buffer-create " *nnml move*"))
 288         result)
 289     (nnml-possibly-change-directory group server)
 290     (nnml-update-file-alist)
 291     (and
 292      (nnml-deletable-article-p group article)
 293      (nnml-request-article article group server)
 294      (save-excursion
 295        (set-buffer buf)
 296        (insert-buffer-substring nntp-server-buffer)
 297        (setq result (eval accept-form))
 298        (kill-buffer (current-buffer))
 299        result)
 300      (progn
 301        (nnml-possibly-change-directory group server)
 302        (condition-case ()
 303            (funcall nnmail-delete-file-function
 304                     (nnml-article-to-file  article))
 305          (file-error nil))
 306        (nnml-nov-delete-article group article)
 307        (when last
 308          (nnml-save-nov)
 309          (nnmail-save-active nnml-group-alist nnml-active-file))))
 310     result))
 311
 312 (deffoo nnml-request-accept-article (group &optional server last)
 313   (nnml-possibly-change-directory group server)
 314   (nnmail-check-syntax)
 315   (let (result)
 316     (nnmail-cache-insert (nnmail-fetch-field "message-id"))
 317     (if (stringp group)
 318         (and
 319          (nnmail-activate 'nnml)
 320          (setq result (car (nnml-save-mail
 321                             (list (cons group (nnml-active-number group))))))
 322          (progn
 323            (nnmail-save-active nnml-group-alist nnml-active-file)
 324            (and last (nnml-save-nov))))
 325       (and
 326        (nnmail-activate 'nnml)
 327        (setq result (car (nnml-save-mail
 328                           (nnmail-article-group 'nnml-active-number))))
 329        (when last
 330          (nnmail-save-active nnml-group-alist nnml-active-file)
 331          (nnmail-cache-close)
 332          (nnml-save-nov))))
 333     result))
 334
 335 (deffoo nnml-request-replace-article (article group buffer)
 336   (nnml-possibly-change-directory group)
 337   (save-excursion
 338     (set-buffer buffer)
 339     (nnml-possibly-create-directory group)
 340     (let ((chars (nnmail-insert-lines))
 341           (art (concat (int-to-string article) "\t"))
 342           headers)
 343       (when (condition-case ()
 344                 (progn
 345                   (nnmail-write-region
 346                    (point-min) (point-max)
 347                    (or (nnml-article-to-file article)
 348                        (concat nnml-current-directory
 349                                (int-to-string article)))
 350                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 351                   t)
 352               (error nil))
 353         (setq headers (nnml-parse-head chars article))
 354         ;; Replace the NOV line in the NOV file.
 355         (save-excursion
 356           (set-buffer (nnml-open-nov group))
 357           (goto-char (point-min))
 358           (if (or (looking-at art)
 359                   (search-forward (concat "\n" art) nil t))
 360               ;; Delete the old NOV line.
 361               (delete-region (progn (beginning-of-line) (point))
 362                              (progn (forward-line 1) (point)))
 363             ;; The line isn't here, so we have to find out where
 364             ;; we should insert it.  (This situation should never
 365             ;; occur, but one likes to make sure...)
 366             (while (and (looking-at "[0-9]+\t")
 367                         (< (string-to-int
 368                             (buffer-substring
 369                              (match-beginning 0) (match-end 0)))
 370                            article)
 371                         (zerop (forward-line 1)))))
 372           (beginning-of-line)
 373           (nnheader-insert-nov headers)
 374           (nnml-save-nov)
 375           t)))))
 376
 377 (deffoo nnml-request-delete-group (group &optional force server)
 378   (nnml-possibly-change-directory group server)
 379   (when force
 380     ;; Delete all articles in GROUP.
 381     (let ((articles
 382            (directory-files
 383             nnml-current-directory t
 384             (concat nnheader-numerical-short-files
 385                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 386           article)
 387       (while articles
 388         (setq article (pop articles))
 389         (when (file-writable-p article)
 390           (nnheader-message 5 "Deleting article %s in %s..." article group)
 391           (funcall nnmail-delete-file-function article))))
 392     ;; Try to delete the directory itself.
 393     (condition-case ()
 394         (delete-directory nnml-current-directory)
 395       (error nil)))
 396   ;; Remove the group from all structures.
 397   (setq nnml-group-alist
 398         (delq (assoc group nnml-group-alist) nnml-group-alist)
 399         nnml-current-group nil
 400         nnml-current-directory nil)
 401   ;; Save the active file.
 402   (nnmail-save-active nnml-group-alist nnml-active-file)
 403   t)
 404
 405 (deffoo nnml-request-rename-group (group new-name &optional server)
 406   (nnml-possibly-change-directory group server)
 407   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 408         (old-dir (nnmail-group-pathname group nnml-directory)))
 409     (when (condition-case ()
 410               (progn
 411                 (make-directory new-dir t)
 412                 t)
 413             (error nil))
 414       ;; We move the articles file by file instead of renaming
 415       ;; the directory -- there may be subgroups in this group.
 416       ;; One might be more clever, I guess.
 417       (let ((files (nnheader-article-to-file-alist old-dir)))
 418         (while files
 419           (rename-file
 420            (concat old-dir (cdar files))
 421            (concat new-dir (cdar files)))
 422           (pop files)))
 423       ;; Move .overview file.
 424       (let ((overview (concat old-dir nnml-nov-file-name)))
 425         (when (file-exists-p overview)
 426           (rename-file overview (concat new-dir nnml-nov-file-name))))
 427       (when (<= (length (directory-files old-dir)) 2)
 428         (condition-case ()
 429             (delete-directory old-dir)
 430           (error nil)))
 431       ;; That went ok, so we change the internal structures.
 432       (let ((entry (assoc group nnml-group-alist)))
 433         (when entry
 434           (setcar entry new-name))
 435         (setq nnml-current-directory nil
 436               nnml-current-group nil)
 437         ;; Save the new group alist.
 438         (nnmail-save-active nnml-group-alist nnml-active-file)
 439         t))))
 440
 441 (deffoo nnml-set-status (article name value &optional group server)
 442   (nnml-possibly-change-directory group server)
 443   (let ((file (nnml-article-to-file article)))
 444     (cond
 445      ((not (file-exists-p file))
 446       (nnheader-report 'nnml "File %s does not exist" file))
 447      (t
 448       (nnheader-temp-write file
 449         (nnheader-insert-file-contents file)
 450         (nnmail-replace-status name value))
 451       t))))
 452
 453 \f
 454 ;;; Internal functions.
 455
 456 (defun nnml-article-to-file (article)
 457   (nnml-update-file-alist)
 458   (let (file)
 459     (when (setq file (cdr (assq article nnml-article-file-alist)))
 460       (concat nnml-current-directory file))))
 461
 462 (defun nnml-deletable-article-p (group article)
 463   "Say whether ARTICLE in GROUP can be deleted."
 464   (let (path)
 465     (when (setq path (nnml-article-to-file article))
 466       (when (file-writable-p path)
 467         (or (not nnmail-keep-last-article)
 468             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 469                      article)))))))
 470
 471 ;; Find an article number in the current group given the Message-ID.
 472 (defun nnml-find-group-number (id)
 473   (save-excursion
 474     (set-buffer (get-buffer-create " *nnml id*"))
 475     (buffer-disable-undo (current-buffer))
 476     (let ((alist nnml-group-alist)
 477           number)
 478       ;; We want to look through all .overview files, but we want to
 479       ;; start with the one in the current directory.  It seems most
 480       ;; likely that the article we are looking for is in that group.
 481       (if (setq number (nnml-find-id nnml-current-group id))
 482           (cons nnml-current-group number)
 483         ;; It wasn't there, so we look through the other groups as well.
 484         (while (and (not number)
 485                     alist)
 486           (or (string= (caar alist) nnml-current-group)
 487               (setq number (nnml-find-id (caar alist) id)))
 488           (or number
 489               (setq alist (cdr alist))))
 490         (and number
 491              (cons (caar alist) number))))))
 492
 493 (defun nnml-find-id (group id)
 494   (erase-buffer)
 495   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 496                      nnml-nov-file-name))
 497         number found)
 498     (when (file-exists-p nov)
 499       (nnheader-insert-file-contents nov)
 500       (while (and (not found)
 501                   (search-forward id nil t)) ; We find the ID.
 502         ;; And the id is in the fourth field.
 503         (if (not (and (search-backward "\t" nil t 4)
 504                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 505             (forward-line 1)
 506           (beginning-of-line)
 507           (setq found t)
 508           ;; We return the article number.
 509           (setq number
 510                 (condition-case ()
 511                     (read (current-buffer))
 512                   (error nil)))))
 513       number)))
 514
 515 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 516   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 517       nil
 518     (let ((nov (concat nnml-current-directory nnml-nov-file-name)))
 519       (when (file-exists-p nov)
 520         (save-excursion
 521           (set-buffer nntp-server-buffer)
 522           (erase-buffer)
 523           (nnheader-insert-file-contents nov)
 524           (if (and fetch-old
 525                    (not (numberp fetch-old)))
 526               t                         ; Don't remove anything.
 527             (nnheader-nov-delete-outside-range
 528              (if fetch-old (max 1 (- (car articles) fetch-old))
 529                (car articles))
 530              (car (last articles)))
 531             t))))))
 532
 533 (defun nnml-possibly-change-directory (group &optional server)
 534   (when (and server
 535              (not (nnml-server-opened server)))
 536     (nnml-open-server server))
 537   (if (not group)
 538       t
 539     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 540       (when (not (equal pathname nnml-current-directory))
 541         (setq nnml-current-directory pathname
 542               nnml-current-group group
 543               nnml-article-file-alist nil))
 544       (file-exists-p nnml-current-directory))))
 545
 546 (defun nnml-possibly-create-directory (group)
 547   (let (dir dirs)
 548     (setq dir (nnmail-group-pathname group nnml-directory))
 549     (while (not (file-directory-p dir))
 550       (push dir dirs)
 551       (setq dir (file-name-directory (directory-file-name dir))))
 552     (while dirs
 553       (make-directory (directory-file-name (car dirs)))
 554       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 555       (setq dirs (cdr dirs)))))
 556
 557 (defun nnml-save-mail (group-art)
 558   "Called narrowed to an article."
 559   (let (chars headers)
 560     (setq chars (nnmail-insert-lines))
 561     (nnmail-insert-xref group-art)
 562     (run-hooks 'nnmail-prepare-save-mail-hook)
 563     (run-hooks 'nnml-prepare-save-mail-hook)
 564     (goto-char (point-min))
 565     (while (looking-at "From ")
 566       (replace-match "X-From-Line: ")
 567       (forward-line 1))
 568     ;; We save the article in all the groups it belongs in.
 569     (let ((ga group-art)
 570           first)
 571       (while ga
 572         (nnml-possibly-create-directory (caar ga))
 573         (let ((file (concat (nnmail-group-pathname
 574                              (caar ga) nnml-directory)
 575                             (int-to-string (cdar ga)))))
 576           (if first
 577               ;; It was already saved, so we just make a hard link.
 578               (funcall nnmail-crosspost-link-function first file t)
 579             ;; Save the article.
 580             (nnmail-write-region (point-min) (point-max) file nil
 581                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 582             (setq first file)))
 583         (setq ga (cdr ga))))
 584     ;; Generate a nov line for this article.  We generate the nov
 585     ;; line after saving, because nov generation destroys the
 586     ;; header.
 587     (setq headers (nnml-parse-head chars))
 588     ;; Output the nov line to all nov databases that should have it.
 589     (let ((ga group-art))
 590       (while ga
 591         (nnml-add-nov (caar ga) (cdar ga) headers)
 592         (setq ga (cdr ga))))
 593     group-art))
 594
 595 (defun nnml-active-number (group)
 596   "Compute the next article number in GROUP."
 597   (let ((active (cadr (assoc group nnml-group-alist))))
 598     ;; The group wasn't known to nnml, so we just create an active
 599     ;; entry for it.
 600     (unless active
 601       ;; Perhaps the active file was corrupt?  See whether
 602       ;; there are any articles in this group.
 603       (nnml-possibly-create-directory group)
 604       (nnml-possibly-change-directory group)
 605       (unless nnml-article-file-alist
 606         (setq nnml-article-file-alist
 607               (sort
 608                (nnheader-article-to-file-alist nnml-current-directory)
 609                (lambda (a1 a2) (< (car a1) (car a2))))))
 610       (setq active
 611             (if nnml-article-file-alist
 612                 (cons (caar nnml-article-file-alist)
 613                       (caar (last nnml-article-file-alist)))
 614               (cons 1 0)))
 615       (push (list group active) nnml-group-alist))
 616     (setcdr active (1+ (cdr active)))
 617     (while (file-exists-p
 618             (concat (nnmail-group-pathname group nnml-directory)
 619                     (int-to-string (cdr active))))
 620       (setcdr active (1+ (cdr active))))
 621     (cdr active)))
 622
 623 (defun nnml-add-nov (group article headers)
 624   "Add a nov line for the GROUP base."
 625   (save-excursion
 626     (set-buffer (nnml-open-nov group))
 627     (goto-char (point-max))
 628     (mail-header-set-number headers article)
 629     (nnheader-insert-nov headers)))
 630
 631 (defsubst nnml-header-value ()
 632   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 633
 634 (defun nnml-parse-head (chars &optional number)
 635   "Parse the head of the current buffer."
 636   (save-excursion
 637     (save-restriction
 638       (goto-char (point-min))
 639       (narrow-to-region
 640        (point)
 641        (1- (or (search-forward "\n\n" nil t) (point-max))))
 642       ;; Fold continuation lines.
 643       (goto-char (point-min))
 644       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 645         (replace-match " " t t))
 646       ;; Remove any tabs; they are too confusing.
 647       (subst-char-in-region (point-min) (point-max) ?\t ? )
 648       (let ((headers (nnheader-parse-head t)))
 649         (mail-header-set-chars headers chars)
 650         (mail-header-set-number headers number)
 651         headers))))
 652
 653 (defun nnml-open-nov (group)
 654   (or (cdr (assoc group nnml-nov-buffer-alist))
 655       (let ((buffer (nnheader-find-file-noselect
 656                      (concat (nnmail-group-pathname group nnml-directory)
 657                              nnml-nov-file-name))))
 658         (save-excursion
 659           (set-buffer buffer)
 660           (buffer-disable-undo (current-buffer)))
 661         (push (cons group buffer) nnml-nov-buffer-alist)
 662         buffer)))
 663
 664 (defun nnml-save-nov ()
 665   (save-excursion
 666     (while nnml-nov-buffer-alist
 667       (when (buffer-name (cdar nnml-nov-buffer-alist))
 668         (set-buffer (cdar nnml-nov-buffer-alist))
 669         (when (buffer-modified-p)
 670           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 671         (set-buffer-modified-p nil)
 672         (kill-buffer (current-buffer)))
 673       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 674
 675 ;;;###autoload
 676 (defun nnml-generate-nov-databases ()
 677   "Generate nov databases in all nnml directories."
 678   (interactive)
 679   ;; Read the active file to make sure we don't re-use articles
 680   ;; numbers in empty groups.
 681   (nnmail-activate 'nnml)
 682   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 683   (setq nnml-directory (expand-file-name nnml-directory))
 684   ;; Recurse down the directories.
 685   (nnml-generate-nov-databases-1 nnml-directory)
 686   ;; Save the active file.
 687   (nnmail-save-active nnml-group-alist nnml-active-file))
 688
 689 (defun nnml-generate-nov-databases-1 (dir &optional seen)
 690   (setq dir (file-name-as-directory dir))
 691   ;; Only scan this sub-tree if we haven't been here yet.
 692   (unless (member (file-truename dir) seen)
 693     (push (file-truename dir) seen)
 694     ;; We descend recursively
 695     (let ((dirs (directory-files dir t nil t))
 696           dir)
 697       (while (setq dir (pop dirs))
 698         (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 699                    (file-directory-p dir))
 700           (nnml-generate-nov-databases-1 dir seen))))
 701     ;; Do this directory.
 702     (let ((files (sort (nnheader-article-to-file-alist dir)
 703                        (lambda (a b) (< (car a) (car b))))))
 704       (when files
 705         (funcall nnml-generate-active-function dir)
 706         ;; Generate the nov file.
 707         (nnml-generate-nov-file dir files)))))
 708
 709 (defvar files)
 710 (defun nnml-generate-active-info (dir)
 711   ;; Update the active info for this group.
 712   (let ((group (nnheader-file-to-group
 713                 (directory-file-name dir) nnml-directory)))
 714     (setq nnml-group-alist
 715           (delq (assoc group nnml-group-alist) nnml-group-alist))
 716     (push (list group
 717                 (cons (caar files)
 718                       (let ((f files))
 719                         (while (cdr f) (setq f (cdr f)))
 720                         (caar f))))
 721           nnml-group-alist)))
 722
 723 (defun nnml-generate-nov-file (dir files)
 724   (let* ((dir (file-name-as-directory dir))
 725          (nov (concat dir nnml-nov-file-name))
 726          (nov-buffer (get-buffer-create " *nov*"))
 727          chars file headers)
 728     (save-excursion
 729       ;; Init the nov buffer.
 730       (set-buffer nov-buffer)
 731       (buffer-disable-undo (current-buffer))
 732       (erase-buffer)
 733       (set-buffer nntp-server-buffer)
 734       ;; Delete the old NOV file.
 735       (when (file-exists-p nov)
 736         (funcall nnmail-delete-file-function nov))
 737       (while files
 738         (unless (file-directory-p (setq file (concat dir (cdar files))))
 739           (erase-buffer)
 740           (nnheader-insert-file-contents file)
 741           (narrow-to-region
 742            (goto-char (point-min))
 743            (progn
 744              (search-forward "\n\n" nil t)
 745              (setq chars (- (point-max) (point)))
 746              (max 1 (1- (point)))))
 747           (when (and (not (= 0 chars))  ; none of them empty files...
 748                      (not (= (point-min) (point-max))))
 749             (goto-char (point-min))
 750             (setq headers (nnml-parse-head chars (caar files)))
 751             (save-excursion
 752               (set-buffer nov-buffer)
 753               (goto-char (point-max))
 754               (nnheader-insert-nov headers)))
 755           (widen))
 756         (setq files (cdr files)))
 757       (save-excursion
 758         (set-buffer nov-buffer)
 759         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 760         (kill-buffer (current-buffer))))))
 761
 762 (defun nnml-nov-delete-article (group article)
 763   (save-excursion
 764     (set-buffer (nnml-open-nov group))
 765     (when (nnheader-find-nov-line article)
 766       (delete-region (point) (progn (forward-line 1) (point)))
 767       (when (bobp)
 768         (let ((active (cadr (assoc group nnml-group-alist)))
 769               num)
 770           (when active
 771             (if (eobp)
 772                 (setf (car active) (1+ (cdr active)))
 773               (when (and (setq num (ignore-errors (read (current-buffer))))
 774                          (numberp num))
 775                 (setf (car active) num)))))))
 776     t))
 777
 778 (defun nnml-update-file-alist ()
 779   (unless nnml-article-file-alist
 780     (setq nnml-article-file-alist
 781           (nnheader-article-to-file-alist nnml-current-directory))))
 782
 783 (provide 'nnml)
 784
 785 ;;; nnml.el ends here