cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org> (adding MARKS)
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  30 ;; For an overview of what the interface functions do, please see the
  31 ;; Gnus sources.
  32
  33 ;;; Code:
  34
  35 (require 'gnus)
  36 (require 'nnheader)
  37 (require 'nnmail)
  38 (require 'nnoo)
  39 (eval-when-compile (require 'cl))
  40
  41 (eval-and-compile
  42   (autoload 'gnus-article-unpropagatable-p "gnus-sum"))
  43
  44 (nnoo-declare nnml)
  45
  46 (defvoo nnml-directory message-directory
  47   "Spool directory for the nnml mail backend.")
  48
  49 (defvoo nnml-active-file
  50     (expand-file-name "active" nnml-directory)
  51   "Mail active file.")
  52
  53 (defvoo nnml-newsgroups-file
  54     (expand-file-name "newsgroups" nnml-directory)
  55   "Mail newsgroups description file.")
  56
  57 (defvoo nnml-get-new-mail t
  58   "If non-nil, nnml will check the incoming mail file and split the mail.")
  59
  60 (defvoo nnml-nov-is-evil nil
  61   "If non-nil, Gnus will never generate and use nov databases for mail spools.
  62 Using nov databases will speed up header fetching considerably.
  63 This variable shouldn't be flipped much.  If you have, for some reason,
  64 set this to t, and want to set it to nil again, you should always run
  65 the `nnml-generate-nov-databases' command.  The function will go
  66 through all nnml directories and generate nov databases for them
  67 all.  This may very well take some time.")
  68
  69 (defvoo nnml-marks-is-evil nil
  70   "If non-nil, Gnus will never generate and use marks file for mail spools.
  71 Using marks files makes it possible to backup and restore mail groups
  72 separately from `.newsrc.eld'.  If you have, for some reason, set this
  73 to t, and want to set it to nil again, you should always remove the
  74 corresponding marks file (usually named `.marks' in the nnml group
  75 directory, but see `nnml-marks-file-name') for the group.  Then the
  76 marks file will be regenerated properly by Gnus.")
  77
  78 (defvoo nnml-prepare-save-mail-hook nil
  79   "Hook run narrowed to an article before saving.")
  80
  81 (defvoo nnml-inhibit-expiry nil
  82   "If non-nil, inhibit expiry.")
  83
  84 (defvoo nnml-use-compressed-files nil
  85   "If non-nil, allow using compressed message files.")
  86
  87 \f
  88
  89 (defconst nnml-version "nnml 1.0"
  90   "nnml version.")
  91
  92 (defvoo nnml-nov-file-name ".overview")
  93 (defvoo nnml-marks-file-name ".marks")
  94
  95 (defvoo nnml-current-directory nil)
  96 (defvoo nnml-current-group nil)
  97 (defvoo nnml-status-string "")
  98 (defvoo nnml-nov-buffer-alist nil)
  99 (defvoo nnml-group-alist nil)
 100 (defvoo nnml-active-timestamp nil)
 101 (defvoo nnml-article-file-alist nil)
 102
 103 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
 104
 105 (defvar nnml-nov-buffer-file-name nil)
 106
 107 (defvoo nnml-file-coding-system nnmail-file-coding-system)
 108
 109 (defvoo nnml-marks nil)
 110
 111 (defvar nnml-marks-modtime (gnus-make-hashtable))
 112
 113 \f
 114 ;;; Interface functions.
 115
 116 (nnoo-define-basics nnml)
 117
 118 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
 119   (when (nnml-possibly-change-directory group server)
 120     (save-excursion
 121       (set-buffer nntp-server-buffer)
 122       (erase-buffer)
 123       (let* ((file nil)
 124              (number (length sequence))
 125              (count 0)
 126              (file-name-coding-system nnmail-pathname-coding-system)
 127              beg article)
 128         (if (stringp (car sequence))
 129             'headers
 130           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 131               'nov
 132             (while sequence
 133               (setq article (car sequence))
 134               (setq file (nnml-article-to-file article))
 135               (when (and file
 136                          (file-exists-p file)
 137                          (not (file-directory-p file)))
 138                 (insert (format "221 %d Article retrieved.\n" article))
 139                 (setq beg (point))
 140                 (nnheader-insert-head file)
 141                 (goto-char beg)
 142                 (if (re-search-forward "\n\r?\n" nil t)
 143                     (forward-char -1)
 144                   (goto-char (point-max))
 145                   (insert "\n\n"))
 146                 (insert ".\n")
 147                 (delete-region (point) (point-max)))
 148               (setq sequence (cdr sequence))
 149               (setq count (1+ count))
 150               (and (numberp nnmail-large-newsgroup)
 151                    (> number nnmail-large-newsgroup)
 152                    (zerop (% count 20))
 153                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 154                                      (/ (* count 100) number))))
 155
 156             (and (numberp nnmail-large-newsgroup)
 157                  (> number nnmail-large-newsgroup)
 158                  (nnheader-message 6 "nnml: Receiving headers...done"))
 159
 160             (nnheader-fold-continuation-lines)
 161             'headers))))))
 162
 163 (deffoo nnml-open-server (server &optional defs)
 164   (nnoo-change-server 'nnml server defs)
 165   (when (not (file-exists-p nnml-directory))
 166     (ignore-errors (make-directory nnml-directory t)))
 167   (cond
 168    ((not (file-exists-p nnml-directory))
 169     (nnml-close-server)
 170     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 171    ((not (file-directory-p (file-truename nnml-directory)))
 172     (nnml-close-server)
 173     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 174    (t
 175     (nnheader-report 'nnml "Opened server %s using directory %s"
 176                      server nnml-directory)
 177     t)))
 178
 179 (deffoo nnml-request-regenerate (server)
 180   (nnml-possibly-change-directory nil server)
 181   (nnml-generate-nov-databases server)
 182   t)
 183
 184 (deffoo nnml-request-article (id &optional group server buffer)
 185   (nnml-possibly-change-directory group server)
 186   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 187          (file-name-coding-system nnmail-pathname-coding-system)
 188          path gpath group-num)
 189     (if (stringp id)
 190         (when (and (setq group-num (nnml-find-group-number id))
 191                    (cdr
 192                     (assq (cdr group-num)
 193                           (nnheader-article-to-file-alist
 194                            (setq gpath
 195                                  (nnmail-group-pathname
 196                                   (car group-num)
 197                                   nnml-directory))))))
 198           (setq path (concat gpath (int-to-string (cdr group-num)))))
 199       (setq path (nnml-article-to-file id)))
 200     (cond
 201      ((not path)
 202       (nnheader-report 'nnml "No such article: %s" id))
 203      ((not (file-exists-p path))
 204       (nnheader-report 'nnml "No such file: %s" path))
 205      ((file-directory-p path)
 206       (nnheader-report 'nnml "File is a directory: %s" path))
 207      ((not (save-excursion (let ((nnmail-file-coding-system
 208                                   nnml-file-coding-system))
 209                              (nnmail-find-file path))))
 210       (nnheader-report 'nnml "Couldn't read file: %s" path))
 211      (t
 212       (nnheader-report 'nnml "Article %s retrieved" id)
 213       ;; We return the article number.
 214       (cons (if group-num (car group-num) group)
 215             (string-to-int (file-name-nondirectory path)))))))
 216
 217 (deffoo nnml-request-group (group &optional server dont-check)
 218   (let ((file-name-coding-system nnmail-pathname-coding-system))
 219     (cond
 220      ((not (nnml-possibly-change-directory group server))
 221       (nnheader-report 'nnml "Invalid group (no such directory)"))
 222      ((not (file-exists-p nnml-current-directory))
 223       (nnheader-report 'nnml "Directory %s does not exist"
 224                        nnml-current-directory))
 225      ((not (file-directory-p nnml-current-directory))
 226       (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 227      (dont-check
 228       (nnheader-report 'nnml "Group %s selected" group)
 229       t)
 230      (t
 231       (nnheader-re-read-dir nnml-current-directory)
 232       (nnmail-activate 'nnml)
 233       (let ((active (nth 1 (assoc group nnml-group-alist))))
 234         (if (not active)
 235             (nnheader-report 'nnml "No such group: %s" group)
 236           (nnheader-report 'nnml "Selected group %s" group)
 237           (nnheader-insert "211 %d %d %d %s\n"
 238                            (max (1+ (- (cdr active) (car active))) 0)
 239                            (car active) (cdr active) group)))))))
 240
 241 (deffoo nnml-request-scan (&optional group server)
 242   (setq nnml-article-file-alist nil)
 243   (nnml-possibly-change-directory group server)
 244   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 245
 246 (deffoo nnml-close-group (group &optional server)
 247   (setq nnml-article-file-alist nil)
 248   t)
 249
 250 (deffoo nnml-request-create-group (group &optional server args)
 251   (nnml-possibly-change-directory nil server)
 252   (nnmail-activate 'nnml)
 253   (cond
 254    ((assoc group nnml-group-alist)
 255     t)
 256    ((and (file-exists-p (nnmail-group-pathname group nnml-directory))
 257          (not (file-directory-p (nnmail-group-pathname group nnml-directory))))
 258     (nnheader-report 'nnml "%s is a file"
 259                      (nnmail-group-pathname group nnml-directory)))
 260    (t
 261     (let (active)
 262       (push (list group (setq active (cons 1 0)))
 263             nnml-group-alist)
 264       (nnml-possibly-create-directory group)
 265       (nnml-possibly-change-directory group server)
 266       (let ((articles (nnml-directory-articles nnml-current-directory)))
 267         (when articles
 268           (setcar active (apply 'min articles))
 269           (setcdr active (apply 'max articles))))
 270       (nnmail-save-active nnml-group-alist nnml-active-file)
 271       t))))
 272
 273 (deffoo nnml-request-list (&optional server)
 274   (save-excursion
 275     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 276           (file-name-coding-system nnmail-pathname-coding-system))
 277       (nnmail-find-file nnml-active-file))
 278     (setq nnml-group-alist (nnmail-get-active))
 279     t))
 280
 281 (deffoo nnml-request-newgroups (date &optional server)
 282   (nnml-request-list server))
 283
 284 (deffoo nnml-request-list-newsgroups (&optional server)
 285   (save-excursion
 286     (nnmail-find-file nnml-newsgroups-file)))
 287
 288 (deffoo nnml-request-expire-articles (articles group &optional server force)
 289   (nnml-possibly-change-directory group server)
 290   (let ((active-articles
 291          (nnml-directory-articles nnml-current-directory))
 292         (is-old t)
 293         article rest mod-time number)
 294     (nnmail-activate 'nnml)
 295
 296     (setq active-articles (sort active-articles '<))
 297     ;; Articles not listed in active-articles are already gone,
 298     ;; so don't try to expire them.
 299     (setq articles (gnus-sorted-intersection articles active-articles))
 300
 301     (while (and articles is-old)
 302       (if (and (setq article (nnml-article-to-file
 303                               (setq number (pop articles))))
 304                (setq mod-time (nth 5 (file-attributes article)))
 305                (nnml-deletable-article-p group number)
 306                (setq is-old (nnmail-expired-article-p group mod-time force
 307                                                       nnml-inhibit-expiry)))
 308           (progn
 309             ;; Allow a special target group.
 310             (unless (eq nnmail-expiry-target 'delete)
 311               (with-temp-buffer
 312                 (nnml-request-article number group server (current-buffer))
 313                 (let (nnml-current-directory
 314                       nnml-current-group
 315                       nnml-article-file-alist)
 316                   (nnmail-expiry-target-group nnmail-expiry-target group)))
 317               ;; Maybe directory is changed during nnmail-expiry-target-group.
 318               (nnml-possibly-change-directory group server))
 319             (nnheader-message 5 "Deleting article %s in %s"
 320                               number group)
 321             (condition-case ()
 322                 (funcall nnmail-delete-file-function article)
 323               (file-error
 324                (push number rest)))
 325             (setq active-articles (delq number active-articles))
 326             (nnml-nov-delete-article group number))
 327         (push number rest)))
 328     (let ((active (nth 1 (assoc group nnml-group-alist))))
 329       (when active
 330         (setcar active (or (and active-articles
 331                                 (apply 'min active-articles))
 332                            (1+ (cdr active)))))
 333       (nnmail-save-active nnml-group-alist nnml-active-file))
 334     (nnml-save-nov)
 335     (nconc rest articles)))
 336
 337 (deffoo nnml-request-move-article
 338     (article group server accept-form &optional last)
 339   (let ((buf (get-buffer-create " *nnml move*"))
 340         result)
 341     (nnml-possibly-change-directory group server)
 342     (nnml-update-file-alist)
 343     (and
 344      (nnml-deletable-article-p group article)
 345      (nnml-request-article article group server)
 346      (let (nnml-current-directory
 347            nnml-current-group
 348            nnml-article-file-alist)
 349        (save-excursion
 350          (set-buffer buf)
 351          (insert-buffer-substring nntp-server-buffer)
 352          (setq result (eval accept-form))
 353          (kill-buffer (current-buffer))
 354          result))
 355      (progn
 356        (nnml-possibly-change-directory group server)
 357        (condition-case ()
 358            (funcall nnmail-delete-file-function
 359                     (nnml-article-to-file  article))
 360          (file-error nil))
 361        (nnml-nov-delete-article group article)
 362        (when last
 363          (nnml-save-nov)
 364          (nnmail-save-active nnml-group-alist nnml-active-file))))
 365     result))
 366
 367 (deffoo nnml-request-accept-article (group &optional server last)
 368   (nnml-possibly-change-directory group server)
 369   (nnmail-check-syntax)
 370   (let (result)
 371     (when nnmail-cache-accepted-message-ids
 372       (nnmail-cache-insert (nnmail-fetch-field "message-id") group))
 373     (if (stringp group)
 374         (and
 375          (nnmail-activate 'nnml)
 376          (setq result (car (nnml-save-mail
 377                             (list (cons group (nnml-active-number group))))))
 378          (progn
 379            (nnmail-save-active nnml-group-alist nnml-active-file)
 380            (and last (nnml-save-nov))))
 381       (and
 382        (nnmail-activate 'nnml)
 383        (if (and (not (setq result (nnmail-article-group 'nnml-active-number)))
 384                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 385            (setq result 'junk)
 386          (setq result (car (nnml-save-mail result))))
 387        (when last
 388          (nnmail-save-active nnml-group-alist nnml-active-file)
 389          (when nnmail-cache-accepted-message-ids
 390            (nnmail-cache-close))
 391          (nnml-save-nov))))
 392     result))
 393
 394 (deffoo nnml-request-post (&optional server)
 395   (nnmail-do-request-post 'nnml-request-accept-article server))
 396
 397 (deffoo nnml-request-replace-article (article group buffer)
 398   (nnml-possibly-change-directory group)
 399   (save-excursion
 400     (set-buffer buffer)
 401     (nnml-possibly-create-directory group)
 402     (let ((chars (nnmail-insert-lines))
 403           (art (concat (int-to-string article) "\t"))
 404           headers)
 405       (when (ignore-errors
 406               (nnmail-write-region
 407                (point-min) (point-max)
 408                (or (nnml-article-to-file article)
 409                    (expand-file-name (int-to-string article)
 410                                      nnml-current-directory))
 411                nil (if (nnheader-be-verbose 5) nil 'nomesg))
 412               t)
 413         (setq headers (nnml-parse-head chars article))
 414         ;; Replace the NOV line in the NOV file.
 415         (save-excursion
 416           (set-buffer (nnml-open-nov group))
 417           (goto-char (point-min))
 418           (if (or (looking-at art)
 419                   (search-forward (concat "\n" art) nil t))
 420               ;; Delete the old NOV line.
 421               (gnus-delete-line)
 422             ;; The line isn't here, so we have to find out where
 423             ;; we should insert it.  (This situation should never
 424             ;; occur, but one likes to make sure...)
 425             (while (and (looking-at "[0-9]+\t")
 426                         (< (string-to-int
 427                             (buffer-substring
 428                              (match-beginning 0) (match-end 0)))
 429                            article)
 430                         (zerop (forward-line 1)))))
 431           (beginning-of-line)
 432           (nnheader-insert-nov headers)
 433           (nnml-save-nov)
 434           t)))))
 435
 436 (deffoo nnml-request-delete-group (group &optional force server)
 437   (nnml-possibly-change-directory group server)
 438   (when force
 439     ;; Delete all articles in GROUP.
 440     (let ((articles
 441            (directory-files
 442             nnml-current-directory t
 443             (concat nnheader-numerical-short-files
 444                     "\\|" (regexp-quote nnml-nov-file-name) "$"
 445                     "\\|" (regexp-quote nnml-marks-file-name) "$")))
 446           article)
 447       (while articles
 448         (setq article (pop articles))
 449         (when (file-writable-p article)
 450           (nnheader-message 5 "Deleting article %s in %s..." article group)
 451           (funcall nnmail-delete-file-function article))))
 452     ;; Try to delete the directory itself.
 453     (ignore-errors (delete-directory nnml-current-directory)))
 454   ;; Remove the group from all structures.
 455   (setq nnml-group-alist
 456         (delq (assoc group nnml-group-alist) nnml-group-alist)
 457         nnml-current-group nil
 458         nnml-current-directory nil)
 459   ;; Save the active file.
 460   (nnmail-save-active nnml-group-alist nnml-active-file)
 461   t)
 462
 463 (deffoo nnml-request-rename-group (group new-name &optional server)
 464   (nnml-possibly-change-directory group server)
 465   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 466         (old-dir (nnmail-group-pathname group nnml-directory)))
 467     (when (ignore-errors
 468             (make-directory new-dir t)
 469             t)
 470       ;; We move the articles file by file instead of renaming
 471       ;; the directory -- there may be subgroups in this group.
 472       ;; One might be more clever, I guess.
 473       (let ((files (nnheader-article-to-file-alist old-dir)))
 474         (while files
 475           (rename-file
 476            (concat old-dir (cdar files))
 477            (concat new-dir (cdar files)))
 478           (pop files)))
 479       ;; Move .overview file.
 480       (let ((overview (concat old-dir nnml-nov-file-name)))
 481         (when (file-exists-p overview)
 482           (rename-file overview (concat new-dir nnml-nov-file-name))))
 483       ;; Move .marks file.
 484       (let ((marks (concat old-dir nnml-marks-file-name)))
 485         (when (file-exists-p marks)
 486           (rename-file marks (concat new-dir nnml-marks-file-name))))
 487       (when (<= (length (directory-files old-dir)) 2)
 488         (ignore-errors (delete-directory old-dir)))
 489       ;; That went ok, so we change the internal structures.
 490       (let ((entry (assoc group nnml-group-alist)))
 491         (when entry
 492           (setcar entry new-name))
 493         (setq nnml-current-directory nil
 494               nnml-current-group nil)
 495         ;; Save the new group alist.
 496         (nnmail-save-active nnml-group-alist nnml-active-file)
 497         t))))
 498
 499 (deffoo nnml-set-status (article name value &optional group server)
 500   (nnml-possibly-change-directory group server)
 501   (let ((file (nnml-article-to-file article)))
 502     (cond
 503      ((not (file-exists-p file))
 504       (nnheader-report 'nnml "File %s does not exist" file))
 505      (t
 506       (with-temp-file file
 507         (nnheader-insert-file-contents file)
 508         (nnmail-replace-status name value))
 509       t))))
 510
 511 \f
 512 ;;; Internal functions.
 513
 514 (defun nnml-article-to-file (article)
 515   (nnml-update-file-alist)
 516   (let (file)
 517     (if (setq file
 518               (if nnml-use-compressed-files
 519                   (cdr (assq article nnml-article-file-alist))
 520                 (number-to-string article)))
 521         (expand-file-name file nnml-current-directory)
 522       (when (not nnheader-directory-files-is-safe)
 523         ;; Just to make sure nothing went wrong when reading over NFS --
 524         ;; check once more.
 525         (when (file-exists-p
 526                (setq file (expand-file-name (number-to-string article)
 527                                             nnml-current-directory)))
 528           (nnml-update-file-alist t)
 529           file)))))
 530
 531 (defun nnml-deletable-article-p (group article)
 532   "Say whether ARTICLE in GROUP can be deleted."
 533   (let (path)
 534     (when (setq path (nnml-article-to-file article))
 535       (when (file-writable-p path)
 536         (or (not nnmail-keep-last-article)
 537             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 538                      article)))))))
 539
 540 ;; Find an article number in the current group given the Message-ID.
 541 (defun nnml-find-group-number (id)
 542   (save-excursion
 543     (set-buffer (get-buffer-create " *nnml id*"))
 544     (let ((alist nnml-group-alist)
 545           number)
 546       ;; We want to look through all .overview files, but we want to
 547       ;; start with the one in the current directory.  It seems most
 548       ;; likely that the article we are looking for is in that group.
 549       (if (setq number (nnml-find-id nnml-current-group id))
 550           (cons nnml-current-group number)
 551       ;; It wasn't there, so we look through the other groups as well.
 552         (while (and (not number)
 553                     alist)
 554           (or (string= (caar alist) nnml-current-group)
 555               (setq number (nnml-find-id (caar alist) id)))
 556           (or number
 557               (setq alist (cdr alist))))
 558         (and number
 559              (cons (caar alist) number))))))
 560
 561 (defun nnml-find-id (group id)
 562   (erase-buffer)
 563   (let ((nov (expand-file-name nnml-nov-file-name
 564                                (nnmail-group-pathname group nnml-directory)))
 565         number found)
 566     (when (file-exists-p nov)
 567       (nnheader-insert-file-contents nov)
 568       (while (and (not found)
 569                   (search-forward id nil t)) ; We find the ID.
 570         ;; And the id is in the fourth field.
 571         (if (not (and (search-backward "\t" nil t 4)
 572                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 573             (forward-line 1)
 574           (beginning-of-line)
 575           (setq found t)
 576           ;; We return the article number.
 577           (setq number
 578                 (ignore-errors (read (current-buffer))))))
 579       number)))
 580
 581 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 582   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 583       nil
 584     (let ((nov (expand-file-name nnml-nov-file-name nnml-current-directory)))
 585       (when (file-exists-p nov)
 586         (save-excursion
 587           (set-buffer nntp-server-buffer)
 588           (erase-buffer)
 589           (nnheader-insert-file-contents nov)
 590           (if (and fetch-old
 591                    (not (numberp fetch-old)))
 592               t                         ; Don't remove anything.
 593             (nnheader-nov-delete-outside-range
 594              (if fetch-old (max 1 (- (car articles) fetch-old))
 595                (car articles))
 596              (car (last articles)))
 597             t))))))
 598
 599 (defun nnml-possibly-change-directory (group &optional server)
 600   (when (and server
 601              (not (nnml-server-opened server)))
 602     (nnml-open-server server))
 603   (if (not group)
 604       t
 605     (let ((pathname (nnmail-group-pathname group nnml-directory))
 606           (file-name-coding-system nnmail-pathname-coding-system))
 607       (when (not (equal pathname nnml-current-directory))
 608         (setq nnml-current-directory pathname
 609               nnml-current-group group
 610               nnml-article-file-alist nil))
 611       (file-exists-p nnml-current-directory))))
 612
 613 (defun nnml-possibly-create-directory (group)
 614   (let ((dir (nnmail-group-pathname group nnml-directory)))
 615     (unless (file-exists-p dir)
 616       (make-directory (directory-file-name dir) t)
 617       (nnheader-message 5 "Creating mail directory %s" dir))))
 618
 619 (defun nnml-save-mail (group-art)
 620   "Called narrowed to an article."
 621   (let (chars headers)
 622     (setq chars (nnmail-insert-lines))
 623     (nnmail-insert-xref group-art)
 624     (run-hooks 'nnmail-prepare-save-mail-hook)
 625     (run-hooks 'nnml-prepare-save-mail-hook)
 626     (goto-char (point-min))
 627     (while (looking-at "From ")
 628       (replace-match "X-From-Line: ")
 629       (forward-line 1))
 630     ;; We save the article in all the groups it belongs in.
 631     (let ((ga group-art)
 632           first)
 633       (while ga
 634         (nnml-possibly-create-directory (caar ga))
 635         (let ((file (concat (nnmail-group-pathname
 636                              (caar ga) nnml-directory)
 637                             (int-to-string (cdar ga)))))
 638           (if first
 639               ;; It was already saved, so we just make a hard link.
 640               (funcall nnmail-crosspost-link-function first file t)
 641             ;; Save the article.
 642             (nnmail-write-region (point-min) (point-max) file nil
 643                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 644             (setq first file)))
 645         (setq ga (cdr ga))))
 646     ;; Generate a nov line for this article.  We generate the nov
 647     ;; line after saving, because nov generation destroys the
 648     ;; header.
 649     (setq headers (nnml-parse-head chars))
 650     ;; Output the nov line to all nov databases that should have it.
 651     (let ((ga group-art))
 652       (while ga
 653         (nnml-add-nov (caar ga) (cdar ga) headers)
 654         (setq ga (cdr ga))))
 655     group-art))
 656
 657 (defun nnml-active-number (group)
 658   "Compute the next article number in GROUP."
 659   (let ((active (cadr (assoc group nnml-group-alist))))
 660     ;; The group wasn't known to nnml, so we just create an active
 661     ;; entry for it.
 662     (unless active
 663       ;; Perhaps the active file was corrupt?  See whether
 664       ;; there are any articles in this group.
 665       (nnml-possibly-create-directory group)
 666       (nnml-possibly-change-directory group)
 667       (unless nnml-article-file-alist
 668         (setq nnml-article-file-alist
 669               (sort
 670                (nnml-current-group-article-to-file-alist)
 671                'car-less-than-car)))
 672       (setq active
 673             (if nnml-article-file-alist
 674                 (cons (caar nnml-article-file-alist)
 675                       (caar (last nnml-article-file-alist)))
 676               (cons 1 0)))
 677       (push (list group active) nnml-group-alist))
 678     (setcdr active (1+ (cdr active)))
 679     (while (file-exists-p
 680             (expand-file-name (int-to-string (cdr active))
 681                               (nnmail-group-pathname group nnml-directory)))
 682       (setcdr active (1+ (cdr active))))
 683     (cdr active)))
 684
 685 (defun nnml-add-nov (group article headers)
 686   "Add a nov line for the GROUP base."
 687   (save-excursion
 688     (set-buffer (nnml-open-nov group))
 689     (goto-char (point-max))
 690     (mail-header-set-number headers article)
 691     (nnheader-insert-nov headers)))
 692
 693 (defsubst nnml-header-value ()
 694   (buffer-substring (match-end 0) (gnus-point-at-eol)))
 695
 696 (defun nnml-parse-head (chars &optional number)
 697   "Parse the head of the current buffer."
 698   (save-excursion
 699     (save-restriction
 700       (unless (zerop (buffer-size))
 701         (narrow-to-region
 702          (goto-char (point-min))
 703          (if (re-search-forward "\n\r?\n" nil t)
 704              (1- (point))
 705            (point-max))))
 706       (let ((headers (nnheader-parse-naked-head)))
 707         (mail-header-set-chars headers chars)
 708         (mail-header-set-number headers number)
 709         headers))))
 710
 711 (defun nnml-get-nov-buffer (group)
 712   (let ((buffer (get-buffer-create (format " *nnml overview %s*" group))))
 713     (save-excursion
 714       (set-buffer buffer)
 715       (set (make-local-variable 'nnml-nov-buffer-file-name)
 716            (expand-file-name
 717             nnml-nov-file-name
 718             (nnmail-group-pathname group nnml-directory)))
 719       (erase-buffer)
 720       (when (file-exists-p nnml-nov-buffer-file-name)
 721         (nnheader-insert-file-contents nnml-nov-buffer-file-name)))
 722     buffer))
 723
 724 (defun nnml-open-nov (group)
 725   (or (cdr (assoc group nnml-nov-buffer-alist))
 726       (let ((buffer (nnml-get-nov-buffer group)))
 727         (push (cons group buffer) nnml-nov-buffer-alist)
 728         buffer)))
 729
 730 (defun nnml-save-nov ()
 731   (save-excursion
 732     (while nnml-nov-buffer-alist
 733       (when (buffer-name (cdar nnml-nov-buffer-alist))
 734         (set-buffer (cdar nnml-nov-buffer-alist))
 735         (when (buffer-modified-p)
 736           (nnmail-write-region (point-min) (point-max)
 737                                nnml-nov-buffer-file-name nil 'nomesg))
 738         (set-buffer-modified-p nil)
 739         (kill-buffer (current-buffer)))
 740       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 741
 742 ;;;###autoload
 743 (defun nnml-generate-nov-databases (&optional server)
 744   "Generate NOV databases in all nnml directories."
 745   (interactive (list (or (nnoo-current-server 'nnml) "")))
 746   ;; Read the active file to make sure we don't re-use articles
 747   ;; numbers in empty groups.
 748   (nnmail-activate 'nnml)
 749   (unless (nnml-server-opened server)
 750     (nnml-open-server server))
 751   (setq nnml-directory (expand-file-name nnml-directory))
 752   ;; Recurse down the directories.
 753   (nnml-generate-nov-databases-1 nnml-directory nil t)
 754   ;; Save the active file.
 755   (nnmail-save-active nnml-group-alist nnml-active-file))
 756
 757 (defun nnml-generate-nov-databases-1 (dir &optional seen no-active)
 758   "Regenerate the NOV database in DIR."
 759   (interactive "DRegenerate NOV in: ")
 760   (setq dir (file-name-as-directory dir))
 761   ;; Only scan this sub-tree if we haven't been here yet.
 762   (unless (member (file-truename dir) seen)
 763     (push (file-truename dir) seen)
 764     ;; We descend recursively
 765     (let ((dirs (directory-files dir t nil t))
 766           dir)
 767       (while (setq dir (pop dirs))
 768         (when (and (not (string-match "^\\." (file-name-nondirectory dir)))
 769                    (file-directory-p dir))
 770           (nnml-generate-nov-databases-1 dir seen))))
 771     ;; Do this directory.
 772     (let ((files (sort (nnheader-article-to-file-alist dir)
 773                        'car-less-than-car)))
 774       (if (not files)
 775           (let* ((group (nnheader-file-to-group
 776                          (directory-file-name dir) nnml-directory))
 777                  (info (cadr (assoc group nnml-group-alist))))
 778             (when info
 779               (setcar info (1+ (cdr info)))))
 780         (funcall nnml-generate-active-function dir)
 781         ;; Generate the nov file.
 782         (nnml-generate-nov-file dir files)
 783         (unless no-active
 784           (nnmail-save-active nnml-group-alist nnml-active-file))))))
 785
 786 (eval-when-compile (defvar files))
 787 (defun nnml-generate-active-info (dir)
 788   ;; Update the active info for this group.
 789   (let* ((group (nnheader-file-to-group
 790                  (directory-file-name dir) nnml-directory))
 791          (entry (assoc group nnml-group-alist))
 792          (last (or (caadr entry) 0)))
 793     (setq nnml-group-alist (delq entry nnml-group-alist))
 794     (push (list group
 795                 (cons (or (caar files) (1+ last))
 796                       (max last
 797                            (or (let ((f files))
 798                                  (while (cdr f) (setq f (cdr f)))
 799                                  (caar f))
 800                                0))))
 801           nnml-group-alist)))
 802
 803 (defun nnml-generate-nov-file (dir files)
 804   (let* ((dir (file-name-as-directory dir))
 805          (nov (concat dir nnml-nov-file-name))
 806          (nov-buffer (get-buffer-create " *nov*"))
 807          chars file headers)
 808     (save-excursion
 809       ;; Init the nov buffer.
 810       (set-buffer nov-buffer)
 811       (buffer-disable-undo)
 812       (erase-buffer)
 813       (set-buffer nntp-server-buffer)
 814       ;; Delete the old NOV file.
 815       (when (file-exists-p nov)
 816         (funcall nnmail-delete-file-function nov))
 817       (while files
 818         (unless (file-directory-p (setq file (concat dir (cdar files))))
 819           (erase-buffer)
 820           (nnheader-insert-file-contents file)
 821           (narrow-to-region
 822            (goto-char (point-min))
 823            (progn
 824              (re-search-forward "\n\r?\n" nil t)
 825              (setq chars (- (point-max) (point)))
 826              (max (point-min) (1- (point)))))
 827           (unless (zerop (buffer-size))
 828             (goto-char (point-min))
 829             (setq headers (nnml-parse-head chars (caar files)))
 830             (save-excursion
 831               (set-buffer nov-buffer)
 832               (goto-char (point-max))
 833               (nnheader-insert-nov headers)))
 834           (widen))
 835         (setq files (cdr files)))
 836       (save-excursion
 837         (set-buffer nov-buffer)
 838         (nnmail-write-region (point-min) (point-max) nov nil 'nomesg)
 839         (kill-buffer (current-buffer))))))
 840
 841 (defun nnml-nov-delete-article (group article)
 842   (save-excursion
 843     (set-buffer (nnml-open-nov group))
 844     (when (nnheader-find-nov-line article)
 845       (delete-region (point) (progn (forward-line 1) (point)))
 846       (when (bobp)
 847         (let ((active (cadr (assoc group nnml-group-alist)))
 848               num)
 849           (when active
 850             (if (eobp)
 851                 (setf (car active) (1+ (cdr active)))
 852               (when (and (setq num (ignore-errors (read (current-buffer))))
 853                          (numberp num))
 854                 (setf (car active) num)))))))
 855     t))
 856
 857 (defun nnml-update-file-alist (&optional force)
 858   (when nnml-use-compressed-files
 859     (when (or (not nnml-article-file-alist)
 860               force)
 861       (setq nnml-article-file-alist
 862             (nnml-current-group-article-to-file-alist)))))
 863
 864 (defun nnml-directory-articles (dir)
 865   "Return a list of all article files in a directory.
 866 Use the nov database for that directory if available."
 867   (if (or gnus-nov-is-evil nnml-nov-is-evil
 868           (not (file-exists-p
 869                 (expand-file-name nnml-nov-file-name dir))))
 870       (nnheader-directory-articles dir)
 871     ;; build list from .overview if available
 872     ;; We would use nnml-open-nov, except that nnml-nov-buffer-alist is
 873     ;; defvoo'd, and we might get called when it hasn't been swapped in.
 874     (save-excursion
 875       (let ((list nil)
 876             art
 877             (buffer (nnml-get-nov-buffer nnml-current-group)))
 878         (set-buffer buffer)
 879         (goto-char (point-min))
 880         (while (not (eobp))
 881           (setq art (read (current-buffer)))
 882           (push art list)
 883           (forward-line 1))
 884         list))))
 885
 886 (defun nnml-current-group-article-to-file-alist ()
 887   "Return an alist of article/file pairs in the current group.
 888 Use the nov database for the current group if available."
 889   (if (or gnus-nov-is-evil
 890           nnml-nov-is-evil
 891           (not (file-exists-p
 892                 (expand-file-name nnml-nov-file-name
 893                                   nnml-current-directory))))
 894       (nnheader-article-to-file-alist nnml-current-directory)
 895     ;; build list from .overview if available
 896     (save-excursion
 897       (let ((alist nil)
 898             (buffer (nnml-get-nov-buffer nnml-current-group))
 899             art)
 900         (set-buffer buffer)
 901         (goto-char (point-min))
 902         (while (not (eobp))
 903           (setq art (read (current-buffer)))
 904           ;; assume file name is unadorned (ie. not compressed etc)
 905           (push (cons art (int-to-string art)) alist)
 906           (forward-line 1))
 907         alist))))
 908
 909 (deffoo nnml-request-set-mark (group actions &optional server)
 910   (nnml-possibly-change-directory group server)
 911   (unless nnml-marks-is-evil
 912     (nnml-open-marks group server)
 913     (dolist (action actions)
 914       (let ((range (nth 0 action))
 915             (what  (nth 1 action))
 916             (marks (nth 2 action)))
 917         (assert (or (eq what 'add) (eq what 'del)) t
 918                 "Unknown request-set-mark action: %s" what)
 919         (dolist (mark marks)
 920           (setq nnml-marks (gnus-update-alist-soft
 921                             mark
 922                             (funcall (if (eq what 'add) 'gnus-range-add
 923                                        'gnus-remove-from-range)
 924                                      (cdr (assoc mark nnml-marks)) range)
 925                             nnml-marks)))))
 926     (nnml-save-marks group server))
 927   nil)
 928
 929 (deffoo nnml-request-update-info (group info &optional server)
 930   (nnml-possibly-change-directory group server)
 931   (when (and (not nnml-marks-is-evil) (nnml-marks-changed-p group))
 932     (nnheader-message 8 "Updating marks for %s..." group)
 933     (nnml-open-marks group server)
 934     ;; Update info using `nnml-marks'.
 935     (mapcar (lambda (pred)
 936               (unless (memq (cdr pred) gnus-article-unpropagated-mark-lists)
 937                 (gnus-info-set-marks
 938                  info
 939                  (gnus-update-alist-soft
 940                   (cdr pred)
 941                   (cdr (assq (cdr pred) nnml-marks))
 942                   (gnus-info-marks info))
 943                  t)))
 944             gnus-article-mark-lists)
 945     (let ((seen (cdr (assq 'read nnml-marks))))
 946       (gnus-info-set-read info
 947                           (if (and (integerp (car seen))
 948                                    (null (cdr seen)))
 949                               (list (cons (car seen) (car seen)))
 950                             seen)))
 951     (nnheader-message 8 "Updating marks for %s...done" group))
 952   info)
 953
 954 (defun nnml-marks-changed-p (group)
 955   (let ((file (expand-file-name nnml-marks-file-name
 956                                 (nnmail-group-pathname group nnml-directory))))
 957     (if (null (gnus-gethash file nnml-marks-modtime))
 958         t ;; never looked at marks file, assume it has changed
 959       (not (equal (gnus-gethash file nnml-marks-modtime)
 960                   (nth 5 (file-attributes file)))))))
 961
 962 (defun nnml-save-marks (group server)
 963   (let ((file-name-coding-system nnmail-pathname-coding-system)
 964         (file (expand-file-name nnml-marks-file-name
 965                                 (nnmail-group-pathname group nnml-directory))))
 966     (condition-case err
 967         (progn
 968           (nnml-possibly-create-directory group)
 969           (with-temp-file file
 970             (erase-buffer)
 971             (gnus-prin1 nnml-marks)
 972             (insert "\n"))
 973           (gnus-sethash file
 974                         (nth 5 (file-attributes file))
 975                         nnml-marks-modtime))
 976       (error (or (gnus-yes-or-no-p
 977                   (format "Could not write to %s (%s).  Continue? " file err))
 978                  (error "Cannot write to %s (%s)" err))))))
 979
 980 (defun nnml-open-marks (group server)
 981   (let ((file (expand-file-name
 982                nnml-marks-file-name
 983                (nnmail-group-pathname group nnml-directory))))
 984     (if (file-exists-p file)
 985         (condition-case err
 986             (with-temp-buffer
 987               (gnus-sethash file (nth 5 (file-attributes file))
 988                             nnml-marks-modtime)
 989               (nnheader-insert-file-contents file)
 990               (setq nnml-marks (read (current-buffer)))
 991               (dolist (el gnus-article-unpropagated-mark-lists)
 992                 (setq nnml-marks (gnus-remassoc el nnml-marks))))
 993           (error (or (gnus-yes-or-no-p
 994                       (format "Error reading nnml marks file %s (%s).  Continuing will use marks from .newsrc.eld.  Continue? " file err))
 995                      (error "Cannot read nnml marks file %s (%s)" file err))))
 996       ;; User didn't have a .marks file.  Probably first time
 997       ;; user of the .marks stuff.  Bootstrap it from .newsrc.eld.
 998       (let ((info (gnus-get-info
 999                    (gnus-group-prefixed-name
1000                     group
1001                     (gnus-server-to-method (format "nnml:%s" server))))))
1002         (nnheader-message 7 "Bootstrapping marks for %s..." group)
1003         (setq nnml-marks (gnus-info-marks info))
1004         (push (cons 'read (gnus-info-read info)) nnml-marks)
1005         (dolist (el gnus-article-unpropagated-mark-lists)
1006           (setq nnml-marks (gnus-remassoc el nnml-marks)))
1007         (nnml-save-marks group server)
1008         (nnheader-message 7 "Bootstrapping marks for %s...done" group)))))
1009
1010 (provide 'nnml)
1011
1012 ;;; nnml.el ends here