cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (nnheader-message 5 "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (nnheader-init-server-buffer)
 149   (nnmh-possibly-change-directory group server)
 150   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 151         (pathname-coding-system 'binary)
 152         dir)
 153     (cond
 154      ((not (file-directory-p pathname))
 155       (nnheader-report
 156        'nnmh "Can't select group (no such directory): %s" group))
 157      (t
 158       (setq nnmh-current-directory pathname)
 159       (and nnmh-get-new-mail
 160            nnmh-be-safe
 161            (nnmh-update-gnus-unreads group))
 162       (cond
 163        (dont-check
 164         (nnheader-report 'nnmh "Selected group %s" group)
 165         t)
 166        (t
 167         ;; Re-scan the directory if it's on a foreign system.
 168         (nnheader-re-read-dir pathname)
 169         (setq dir
 170               (sort
 171                (mapcar (lambda (name) (string-to-int name))
 172                        (directory-files pathname nil "^[0-9]+$" t))
 173                '<))
 174           (cond
 175            (dir
 176             (nnheader-report 'nnmh "Selected group %s" group)
 177             (nnheader-insert
 178              "211 %d %d %d %s\n" (length dir) (car dir)
 179              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 180              group))
 181            (t
 182             (nnheader-report 'nnmh "Empty group %s" group)
 183             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 184
 185 (deffoo nnmh-request-scan (&optional group server)
 186   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 187
 188 (deffoo nnmh-request-list (&optional server dir)
 189   (nnheader-insert "")
 190   (nnmh-possibly-change-directory nil server)
 191   (let ((pathname-coding-system 'binary)
 192         (nnmh-toplev
 193          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 194     (nnmh-request-list-1 nnmh-toplev))
 195   (setq nnmh-group-alist (nnmail-get-active))
 196   t)
 197
 198 (defvar nnmh-toplev)
 199 (defun nnmh-request-list-1 (dir)
 200   (setq dir (expand-file-name dir))
 201   ;; Recurse down all directories.
 202   (let ((dirs (and (file-readable-p dir)
 203                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 204                    (nnheader-directory-files dir t nil t)))
 205         rdir)
 206     ;; Recurse down directories.
 207     (while (setq rdir (pop dirs))
 208       (when (and (file-directory-p rdir)
 209                  (file-readable-p rdir)
 210                  (not (equal (file-truename rdir)
 211                              (file-truename dir))))
 212         (nnmh-request-list-1 rdir))))
 213   ;; For each directory, generate an active file line.
 214   (unless (string= (expand-file-name nnmh-toplev) dir)
 215     (let ((files (mapcar
 216                   (lambda (name) (string-to-int name))
 217                   (directory-files dir nil "^[0-9]+$" t))))
 218       (when files
 219         (save-excursion
 220           (set-buffer nntp-server-buffer)
 221           (goto-char (point-max))
 222           (insert
 223            (format
 224             "%s %d %d y\n"
 225             (progn
 226               (string-match
 227                (regexp-quote
 228                 (file-truename (file-name-as-directory
 229                                 (expand-file-name nnmh-toplev))))
 230                dir)
 231               (nnheader-replace-chars-in-string
 232                (gnus-decode-coding-string (substring dir (match-end 0))
 233                                           nnmail-pathname-coding-system)
 234                ?/ ?.))
 235             (apply 'max files)
 236             (apply 'min files)))))))
 237   t)
 238
 239 (deffoo nnmh-request-newgroups (date &optional server)
 240   (nnmh-request-list server))
 241
 242 (deffoo nnmh-request-expire-articles (articles newsgroup
 243                                                &optional server force)
 244   (nnmh-possibly-change-directory newsgroup server)
 245   (let* ((active-articles
 246           (mapcar
 247            (function
 248             (lambda (name)
 249               (string-to-int name)))
 250            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 251          (is-old t)
 252          article rest mod-time)
 253     (nnheader-init-server-buffer)
 254
 255     (while (and articles is-old)
 256       (setq article (concat nnmh-current-directory
 257                             (int-to-string (car articles))))
 258       (when (setq mod-time (nth 5 (file-attributes article)))
 259         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 260                  (setq is-old
 261                        (nnmail-expired-article-p newsgroup mod-time force)))
 262             (progn
 263               (nnheader-message 5 "Deleting article %s in %s..."
 264                                 article newsgroup)
 265               (condition-case ()
 266                   (funcall nnmail-delete-file-function article)
 267                 (file-error
 268                  (nnheader-message 1 "Couldn't delete article %s in %s"
 269                                    article newsgroup)
 270                  (push (car articles) rest))))
 271           (push (car articles) rest)))
 272       (setq articles (cdr articles)))
 273     (nnheader-message 5 "")
 274     (nconc rest articles)))
 275
 276 (deffoo nnmh-close-group (group &optional server)
 277   t)
 278
 279 (deffoo nnmh-request-move-article
 280   (article group server accept-form &optional last)
 281   (let ((buf (get-buffer-create " *nnmh move*"))
 282         result)
 283     (and
 284      (nnmh-deletable-article-p group article)
 285      (nnmh-request-article article group server)
 286      (save-excursion
 287        (set-buffer buf)
 288        (erase-buffer)
 289        (insert-buffer-substring nntp-server-buffer)
 290        (setq result (eval accept-form))
 291        (kill-buffer (current-buffer))
 292        result)
 293      (progn
 294        (nnmh-possibly-change-directory group server)
 295        (condition-case ()
 296            (funcall nnmail-delete-file-function
 297                     (concat nnmh-current-directory (int-to-string article)))
 298          (file-error nil))))
 299     result))
 300
 301 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 302   (nnmh-possibly-change-directory group server)
 303   (nnmail-check-syntax)
 304   (when nnmail-cache-accepted-message-ids
 305     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 306   (nnheader-init-server-buffer)
 307   (prog1
 308       (if (stringp group)
 309           (if noinsert
 310               (nnmh-active-number group)
 311             (car (nnmh-save-mail
 312                   (list (cons group (nnmh-active-number group)))
 313                   noinsert)))
 314         (let ((res (nnmail-article-group 'nnmh-active-number)))
 315           (if (and (null res)
 316                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 317               'junk
 318             (car (nnmh-save-mail res noinsert)))))
 319     (when (and last nnmail-cache-accepted-message-ids)
 320       (nnmail-cache-close))))
 321
 322 (deffoo nnmh-request-replace-article (article group buffer)
 323   (nnmh-possibly-change-directory group)
 324   (save-excursion
 325     (set-buffer buffer)
 326     (nnmh-possibly-create-directory group)
 327     (ignore-errors
 328       (nnmail-write-region
 329        (point-min) (point-max)
 330        (concat nnmh-current-directory (int-to-string article))
 331        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 332       t)))
 333
 334 (deffoo nnmh-request-create-group (group &optional server args)
 335   (nnheader-init-server-buffer)
 336   (unless (assoc group nnmh-group-alist)
 337     (let (active)
 338       (push (list group (setq active (cons 1 0)))
 339             nnmh-group-alist)
 340       (nnmh-possibly-create-directory group)
 341       (nnmh-possibly-change-directory group server)
 342       (let ((articles (mapcar
 343                        (lambda (file)
 344                          (string-to-int file))
 345                        (directory-files
 346                         nnmh-current-directory nil "^[0-9]+$"))))
 347         (when articles
 348           (setcar active (apply 'min articles))
 349           (setcdr active (apply 'max articles))))))
 350   t)
 351
 352 (deffoo nnmh-request-delete-group (group &optional force server)
 353   (nnmh-possibly-change-directory group server)
 354   ;; Delete all articles in GROUP.
 355   (if (not force)
 356       ()                                ; Don't delete the articles.
 357     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 358       (while articles
 359         (when (file-writable-p (car articles))
 360           (nnheader-message 5 "Deleting article %s in %s..."
 361                             (car articles) group)
 362           (funcall nnmail-delete-file-function (car articles)))
 363         (setq articles (cdr articles))))
 364     ;; Try to delete the directory itself.
 365     (ignore-errors
 366       (delete-directory nnmh-current-directory)))
 367   ;; Remove the group from all structures.
 368   (setq nnmh-group-alist
 369         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 370         nnmh-current-directory nil)
 371   t)
 372
 373 (deffoo nnmh-request-rename-group (group new-name &optional server)
 374   (nnmh-possibly-change-directory group server)
 375   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 376         (old-dir (nnmail-group-pathname group nnmh-directory)))
 377     (when (ignore-errors
 378             (make-directory new-dir t)
 379             t)
 380       ;; We move the articles file by file instead of renaming
 381       ;; the directory -- there may be subgroups in this group.
 382       ;; One might be more clever, I guess.
 383       (let ((files (nnheader-article-to-file-alist old-dir)))
 384         (while files
 385           (rename-file
 386            (concat old-dir (cdar files))
 387            (concat new-dir (cdar files)))
 388           (pop files)))
 389       (when (<= (length (directory-files old-dir)) 2)
 390         (ignore-errors
 391           (delete-directory old-dir)))
 392       ;; That went ok, so we change the internal structures.
 393       (let ((entry (assoc group nnmh-group-alist)))
 394         (when entry
 395           (setcar entry new-name))
 396         (setq nnmh-current-directory nil)
 397         t))))
 398
 399 (nnoo-define-skeleton nnmh)
 400
 401 \f
 402 ;;; Internal functions.
 403
 404 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 405   (when (and server
 406              (not (nnmh-server-opened server)))
 407     (nnmh-open-server server))
 408   (when newsgroup
 409     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 410           (pathname-coding-system 'binary))
 411       (if (file-directory-p pathname)
 412           (setq nnmh-current-directory pathname)
 413         (error "No such newsgroup: %s" newsgroup)))))
 414
 415 (defun nnmh-possibly-create-directory (group)
 416   (let (dir dirs)
 417     (setq dir (nnmail-group-pathname group nnmh-directory))
 418     (while (not (file-directory-p dir))
 419       (push dir dirs)
 420       (setq dir (file-name-directory (directory-file-name dir))))
 421     (while dirs
 422       (when (make-directory (directory-file-name (car dirs)))
 423         (error "Could not create directory %s" (car dirs)))
 424       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 425       (setq dirs (cdr dirs)))))
 426
 427 (defun nnmh-save-mail (group-art &optional noinsert)
 428   "Called narrowed to an article."
 429   (unless noinsert
 430     (nnmail-insert-lines)
 431     (nnmail-insert-xref group-art))
 432   (run-hooks 'nnmail-prepare-save-mail-hook)
 433   (run-hooks 'nnmh-prepare-save-mail-hook)
 434   (goto-char (point-min))
 435   (while (looking-at "From ")
 436     (replace-match "X-From-Line: ")
 437     (forward-line 1))
 438   ;; We save the article in all the newsgroups it belongs in.
 439   (let ((ga group-art)
 440         first)
 441     (while ga
 442       (nnmh-possibly-create-directory (caar ga))
 443       (let ((file (concat (nnmail-group-pathname
 444                            (caar ga) nnmh-directory)
 445                           (int-to-string (cdar ga)))))
 446         (if first
 447             ;; It was already saved, so we just make a hard link.
 448             (funcall nnmail-crosspost-link-function first file t)
 449           ;; Save the article.
 450           (nnmail-write-region (point-min) (point-max) file nil nil)
 451           (setq first file)))
 452       (setq ga (cdr ga))))
 453   group-art)
 454
 455 (defun nnmh-active-number (group)
 456   "Compute the next article number in GROUP."
 457   (let ((active (cadr (assoc group nnmh-group-alist)))
 458         (dir (nnmail-group-pathname group nnmh-directory))
 459         (pathname-coding-system 'binary))
 460     (unless active
 461       ;; The group wasn't known to nnmh, so we just create an active
 462       ;; entry for it.
 463       (setq active (cons 1 0))
 464       (push (list group active) nnmh-group-alist)
 465       (unless (file-exists-p dir)
 466         (gnus-make-directory dir))
 467       ;; Find the highest number in the group.
 468       (let ((files (sort
 469                     (mapcar
 470                      (lambda (f)
 471                        (string-to-int f))
 472                      (directory-files dir nil "^[0-9]+$"))
 473                     '>)))
 474         (when files
 475           (setcdr active (car files)))))
 476     (setcdr active (1+ (cdr active)))
 477     (while (file-exists-p
 478             (concat (nnmail-group-pathname group nnmh-directory)
 479                     (int-to-string (cdr active))))
 480       (setcdr active (1+ (cdr active))))
 481     (cdr active)))
 482
 483 (defun nnmh-update-gnus-unreads (group)
 484   ;; Go through the .nnmh-articles file and compare with the actual
 485   ;; articles in this folder.  The articles that are "new" will be
 486   ;; marked as unread by Gnus.
 487   (let* ((dir nnmh-current-directory)
 488          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 489                               (directory-files nnmh-current-directory
 490                                                nil "^[0-9]+$" t))
 491                       '<))
 492          (nnmh-file (concat dir ".nnmh-articles"))
 493          new articles)
 494     ;; Load the .nnmh-articles file.
 495     (when (file-exists-p nnmh-file)
 496       (setq articles
 497             (let (nnmh-newsgroup-articles)
 498               (ignore-errors (load nnmh-file nil t t))
 499               nnmh-newsgroup-articles)))
 500     ;; Add all new articles to the `new' list.
 501     (let ((art files))
 502       (while art
 503         (unless (assq (car art) articles)
 504           (push (car art) new))
 505         (setq art (cdr art))))
 506     ;; Remove all deleted articles.
 507     (let ((art articles))
 508       (while art
 509         (unless (memq (caar art) files)
 510           (setq articles (delq (car art) articles)))
 511         (setq art (cdr art))))
 512     ;; Check whether the articles really are the ones that Gnus thinks
 513     ;; they are by looking at the time-stamps.
 514     (let ((arts articles)
 515           art)
 516       (while (setq art (pop arts))
 517         (when (not (equal
 518                     (nth 5 (file-attributes
 519                             (concat dir (int-to-string (car art)))))
 520                     (cdr art)))
 521           (setq articles (delq art articles))
 522           (push (car art) new))))
 523     ;; Go through all the new articles and add them, and their
 524     ;; time-stamps, to the list.
 525     (setq articles
 526           (nconc articles
 527                  (mapcar
 528                   (lambda (art)
 529                     (cons art
 530                           (nth 5 (file-attributes
 531                                   (concat dir (int-to-string art))))))
 532                   new)))
 533     ;; Make Gnus mark all new articles as unread.
 534     (when new
 535       (gnus-make-articles-unread
 536        (gnus-group-prefixed-name group (list 'nnmh ""))
 537        (setq new (sort new '<))))
 538     ;; Sort the article list with highest numbers first.
 539     (setq articles (sort articles (lambda (art1 art2)
 540                                     (> (car art1) (car art2)))))
 541     ;; Finally write this list back to the .nnmh-articles file.
 542     (nnheader-temp-write nnmh-file
 543       (insert ";; Gnus article active file for " group "\n\n")
 544       (insert "(setq nnmh-newsgroup-articles '")
 545       (gnus-prin1 articles)
 546       (insert ")\n"))))
 547
 548 (defun nnmh-deletable-article-p (group article)
 549   "Say whether ARTICLE in GROUP can be deleted."
 550   (let ((path (concat nnmh-current-directory (int-to-string article))))
 551     ;; Writable.
 552     (and (file-writable-p path)
 553          (or
 554           ;; We can never delete the last article in the group.
 555           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 556                    article))
 557           ;; Well, we can.
 558           nnmh-allow-delete-final))))
 559
 560 (provide 'nnmh)
 561
 562 ;;; nnmh.el ends here