cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (nnheader-message 5 "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (nnheader-init-server-buffer)
 149   (nnmh-possibly-change-directory group server)
 150   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 151         (pathname-coding-system 'binary)
 152         dir)
 153     (cond
 154      ((not (file-directory-p pathname))
 155       (nnheader-report
 156        'nnmh "Can't select group (no such directory): %s" group))
 157      (t
 158       (setq nnmh-current-directory pathname)
 159       (and nnmh-get-new-mail
 160            nnmh-be-safe
 161            (nnmh-update-gnus-unreads group))
 162       (cond
 163        (dont-check
 164         (nnheader-report 'nnmh "Selected group %s" group)
 165         t)
 166        (t
 167         ;; Re-scan the directory if it's on a foreign system.
 168         (nnheader-re-read-dir pathname)
 169         (setq dir
 170               (sort
 171                (mapcar (lambda (name) (string-to-int name))
 172                        (directory-files pathname nil "^[0-9]+$" t))
 173                '<))
 174           (cond
 175            (dir
 176             (setq nnmh-group-alist
 177                   (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 178             (push (list group (cons (car dir) (car (last dir))))
 179                   nnmh-group-alist)
 180             (nnheader-report 'nnmh "Selected group %s" group)
 181             (nnheader-insert
 182              "211 %d %d %d %s\n" (length dir) (car dir)
 183              (car (last dir)) group))
 184            (t
 185             (nnheader-report 'nnmh "Empty group %s" group)
 186             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 187
 188 (deffoo nnmh-request-scan (&optional group server)
 189   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 190
 191 (deffoo nnmh-request-list (&optional server dir)
 192   (nnheader-insert "")
 193   (nnmh-possibly-change-directory nil server)
 194   (let ((pathname-coding-system 'binary)
 195         (nnmh-toplev
 196          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 197     (nnmh-request-list-1 nnmh-toplev))
 198   (setq nnmh-group-alist (nnmail-get-active))
 199   t)
 200
 201 (defvar nnmh-toplev)
 202 (defun nnmh-request-list-1 (dir)
 203   (setq dir (expand-file-name dir))
 204   ;; Recurse down all directories.
 205   (let ((dirs (and (file-readable-p dir)
 206                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 207                    (nnheader-directory-files dir t nil t)))
 208         rdir)
 209     ;; Recurse down directories.
 210     (while (setq rdir (pop dirs))
 211       (when (and (file-directory-p rdir)
 212                  (file-readable-p rdir)
 213                  (not (equal (file-truename rdir)
 214                              (file-truename dir))))
 215         (nnmh-request-list-1 rdir))))
 216   ;; For each directory, generate an active file line.
 217   (unless (string= (expand-file-name nnmh-toplev) dir)
 218     (let ((files (mapcar
 219                   (lambda (name) (string-to-int name))
 220                   (directory-files dir nil "^[0-9]+$" t))))
 221       (when files
 222         (save-excursion
 223           (set-buffer nntp-server-buffer)
 224           (goto-char (point-max))
 225           (insert
 226            (format
 227             "%s %d %d y\n"
 228             (progn
 229               (string-match
 230                (regexp-quote
 231                 (file-truename (file-name-as-directory
 232                                 (expand-file-name nnmh-toplev))))
 233                dir)
 234               (nnheader-replace-chars-in-string
 235                (mm-decode-coding-string (substring dir (match-end 0))
 236                                         nnmail-pathname-coding-system)
 237                ?/ ?.))
 238             (apply 'max files)
 239             (apply 'min files)))))))
 240   t)
 241
 242 (deffoo nnmh-request-newgroups (date &optional server)
 243   (nnmh-request-list server))
 244
 245 (deffoo nnmh-request-expire-articles (articles newsgroup
 246                                                &optional server force)
 247   (nnmh-possibly-change-directory newsgroup server)
 248   (let* ((is-old t)
 249          article rest mod-time)
 250     (nnheader-init-server-buffer)
 251
 252     (while (and articles is-old)
 253       (setq article (concat nnmh-current-directory
 254                             (int-to-string (car articles))))
 255       (when (setq mod-time (nth 5 (file-attributes article)))
 256         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 257                  (setq is-old
 258                        (nnmail-expired-article-p newsgroup mod-time force)))
 259             (progn
 260               (nnheader-message 5 "Deleting article %s in %s..."
 261                                 article newsgroup)
 262               (condition-case ()
 263                   (funcall nnmail-delete-file-function article)
 264                 (file-error
 265                  (nnheader-message 1 "Couldn't delete article %s in %s"
 266                                    article newsgroup)
 267                  (push (car articles) rest))))
 268           (push (car articles) rest)))
 269       (setq articles (cdr articles)))
 270     (nnheader-message 5 "")
 271     (nconc rest articles)))
 272
 273 (deffoo nnmh-close-group (group &optional server)
 274   t)
 275
 276 (deffoo nnmh-request-move-article
 277   (article group server accept-form &optional last)
 278   (let ((buf (get-buffer-create " *nnmh move*"))
 279         result)
 280     (and
 281      (nnmh-deletable-article-p group article)
 282      (nnmh-request-article article group server)
 283      (save-excursion
 284        (set-buffer buf)
 285        (erase-buffer)
 286        (insert-buffer-substring nntp-server-buffer)
 287        (setq result (eval accept-form))
 288        (kill-buffer (current-buffer))
 289        result)
 290      (progn
 291        (nnmh-possibly-change-directory group server)
 292        (condition-case ()
 293            (funcall nnmail-delete-file-function
 294                     (concat nnmh-current-directory (int-to-string article)))
 295          (file-error nil))))
 296     result))
 297
 298 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 299   (nnmh-possibly-change-directory group server)
 300   (nnmail-check-syntax)
 301   (when nnmail-cache-accepted-message-ids
 302     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 303   (nnheader-init-server-buffer)
 304   (prog1
 305       (if (stringp group)
 306           (if noinsert
 307               (nnmh-active-number group)
 308             (car (nnmh-save-mail
 309                   (list (cons group (nnmh-active-number group)))
 310                   noinsert)))
 311         (let ((res (nnmail-article-group 'nnmh-active-number)))
 312           (if (and (null res)
 313                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 314               'junk
 315             (car (nnmh-save-mail res noinsert)))))
 316     (when (and last nnmail-cache-accepted-message-ids)
 317       (nnmail-cache-close))))
 318
 319 (deffoo nnmh-request-replace-article (article group buffer)
 320   (nnmh-possibly-change-directory group)
 321   (save-excursion
 322     (set-buffer buffer)
 323     (nnmh-possibly-create-directory group)
 324     (ignore-errors
 325       (nnmail-write-region
 326        (point-min) (point-max)
 327        (concat nnmh-current-directory (int-to-string article))
 328        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 329       t)))
 330
 331 (deffoo nnmh-request-create-group (group &optional server args)
 332   (nnheader-init-server-buffer)
 333   (unless (assoc group nnmh-group-alist)
 334     (let (active)
 335       (push (list group (setq active (cons 1 0)))
 336             nnmh-group-alist)
 337       (nnmh-possibly-create-directory group)
 338       (nnmh-possibly-change-directory group server)
 339       (let ((articles (mapcar
 340                        (lambda (file)
 341                          (string-to-int file))
 342                        (directory-files
 343                         nnmh-current-directory nil "^[0-9]+$"))))
 344         (when articles
 345           (setcar active (apply 'min articles))
 346           (setcdr active (apply 'max articles))))))
 347   t)
 348
 349 (deffoo nnmh-request-delete-group (group &optional force server)
 350   (nnmh-possibly-change-directory group server)
 351   ;; Delete all articles in GROUP.
 352   (if (not force)
 353       ()                                ; Don't delete the articles.
 354     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 355       (while articles
 356         (when (file-writable-p (car articles))
 357           (nnheader-message 5 "Deleting article %s in %s..."
 358                             (car articles) group)
 359           (funcall nnmail-delete-file-function (car articles)))
 360         (setq articles (cdr articles))))
 361     ;; Try to delete the directory itself.
 362     (ignore-errors
 363       (delete-directory nnmh-current-directory)))
 364   ;; Remove the group from all structures.
 365   (setq nnmh-group-alist
 366         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 367         nnmh-current-directory nil)
 368   t)
 369
 370 (deffoo nnmh-request-rename-group (group new-name &optional server)
 371   (nnmh-possibly-change-directory group server)
 372   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 373         (old-dir (nnmail-group-pathname group nnmh-directory)))
 374     (when (ignore-errors
 375             (make-directory new-dir t)
 376             t)
 377       ;; We move the articles file by file instead of renaming
 378       ;; the directory -- there may be subgroups in this group.
 379       ;; One might be more clever, I guess.
 380       (let ((files (nnheader-article-to-file-alist old-dir)))
 381         (while files
 382           (rename-file
 383            (concat old-dir (cdar files))
 384            (concat new-dir (cdar files)))
 385           (pop files)))
 386       (when (<= (length (directory-files old-dir)) 2)
 387         (ignore-errors
 388           (delete-directory old-dir)))
 389       ;; That went ok, so we change the internal structures.
 390       (let ((entry (assoc group nnmh-group-alist)))
 391         (when entry
 392           (setcar entry new-name))
 393         (setq nnmh-current-directory nil)
 394         t))))
 395
 396 (nnoo-define-skeleton nnmh)
 397
 398 \f
 399 ;;; Internal functions.
 400
 401 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 402   (when (and server
 403              (not (nnmh-server-opened server)))
 404     (nnmh-open-server server))
 405   (when newsgroup
 406     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 407           (pathname-coding-system 'binary))
 408       (if (file-directory-p pathname)
 409           (setq nnmh-current-directory pathname)
 410         (error "No such newsgroup: %s" newsgroup)))))
 411
 412 (defun nnmh-possibly-create-directory (group)
 413   (let (dir dirs)
 414     (setq dir (nnmail-group-pathname group nnmh-directory))
 415     (while (not (file-directory-p dir))
 416       (push dir dirs)
 417       (setq dir (file-name-directory (directory-file-name dir))))
 418     (while dirs
 419       (when (make-directory (directory-file-name (car dirs)))
 420         (error "Could not create directory %s" (car dirs)))
 421       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 422       (setq dirs (cdr dirs)))))
 423
 424 (defun nnmh-save-mail (group-art &optional noinsert)
 425   "Called narrowed to an article."
 426   (unless noinsert
 427     (nnmail-insert-lines)
 428     (nnmail-insert-xref group-art))
 429   (run-hooks 'nnmail-prepare-save-mail-hook)
 430   (run-hooks 'nnmh-prepare-save-mail-hook)
 431   (goto-char (point-min))
 432   (while (looking-at "From ")
 433     (replace-match "X-From-Line: ")
 434     (forward-line 1))
 435   ;; We save the article in all the newsgroups it belongs in.
 436   (let ((ga group-art)
 437         first)
 438     (while ga
 439       (nnmh-possibly-create-directory (caar ga))
 440       (let ((file (concat (nnmail-group-pathname
 441                            (caar ga) nnmh-directory)
 442                           (int-to-string (cdar ga)))))
 443         (if first
 444             ;; It was already saved, so we just make a hard link.
 445             (funcall nnmail-crosspost-link-function first file t)
 446           ;; Save the article.
 447           (nnmail-write-region (point-min) (point-max) file nil nil)
 448           (setq first file)))
 449       (setq ga (cdr ga))))
 450   group-art)
 451
 452 (defun nnmh-active-number (group)
 453   "Compute the next article number in GROUP."
 454   (let ((active (cadr (assoc group nnmh-group-alist)))
 455         (dir (nnmail-group-pathname group nnmh-directory))
 456         (pathname-coding-system 'binary)
 457         file)
 458     (unless active
 459       ;; The group wasn't known to nnmh, so we just create an active
 460       ;; entry for it.
 461       (setq active (cons 1 0))
 462       (push (list group active) nnmh-group-alist)
 463       (unless (file-exists-p dir)
 464         (gnus-make-directory dir))
 465       ;; Find the highest number in the group.
 466       (let ((files (sort
 467                     (mapcar
 468                      (lambda (f)
 469                        (string-to-int f))
 470                      (directory-files dir nil "^[0-9]+$"))
 471                     '>)))
 472         (when files
 473           (setcdr active (car files)))))
 474     (setcdr active (1+ (cdr active)))
 475     (while (or
 476             ;; See whether the file exists...
 477             (file-exists-p
 478              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 479                                 (int-to-string (cdr active)))))
 480             ;; ... or there is a buffer that will make that file exist
 481             ;; in the future.
 482             (get-file-buffer file))
 483       ;; Skip past that file.
 484       (setcdr active (1+ (cdr active))))
 485     (cdr active)))
 486
 487 (defun nnmh-update-gnus-unreads (group)
 488   ;; Go through the .nnmh-articles file and compare with the actual
 489   ;; articles in this folder.  The articles that are "new" will be
 490   ;; marked as unread by Gnus.
 491   (let* ((dir nnmh-current-directory)
 492          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 493                               (directory-files nnmh-current-directory
 494                                                nil "^[0-9]+$" t))
 495                       '<))
 496          (nnmh-file (concat dir ".nnmh-articles"))
 497          new articles)
 498     ;; Load the .nnmh-articles file.
 499     (when (file-exists-p nnmh-file)
 500       (setq articles
 501             (let (nnmh-newsgroup-articles)
 502               (ignore-errors (load nnmh-file nil t t))
 503               nnmh-newsgroup-articles)))
 504     ;; Add all new articles to the `new' list.
 505     (let ((art files))
 506       (while art
 507         (unless (assq (car art) articles)
 508           (push (car art) new))
 509         (setq art (cdr art))))
 510     ;; Remove all deleted articles.
 511     (let ((art articles))
 512       (while art
 513         (unless (memq (caar art) files)
 514           (setq articles (delq (car art) articles)))
 515         (setq art (cdr art))))
 516     ;; Check whether the articles really are the ones that Gnus thinks
 517     ;; they are by looking at the time-stamps.
 518     (let ((arts articles)
 519           art)
 520       (while (setq art (pop arts))
 521         (when (not (equal
 522                     (nth 5 (file-attributes
 523                             (concat dir (int-to-string (car art)))))
 524                     (cdr art)))
 525           (setq articles (delq art articles))
 526           (push (car art) new))))
 527     ;; Go through all the new articles and add them, and their
 528     ;; time-stamps, to the list.
 529     (setq articles
 530           (nconc articles
 531                  (mapcar
 532                   (lambda (art)
 533                     (cons art
 534                           (nth 5 (file-attributes
 535                                   (concat dir (int-to-string art))))))
 536                   new)))
 537     ;; Make Gnus mark all new articles as unread.
 538     (when new
 539       (gnus-make-articles-unread
 540        (gnus-group-prefixed-name group (list 'nnmh ""))
 541        (setq new (sort new '<))))
 542     ;; Sort the article list with highest numbers first.
 543     (setq articles (sort articles (lambda (art1 art2)
 544                                     (> (car art1) (car art2)))))
 545     ;; Finally write this list back to the .nnmh-articles file.
 546     (with-temp-file nnmh-file
 547       (insert ";; Gnus article active file for " group "\n\n")
 548       (insert "(setq nnmh-newsgroup-articles '")
 549       (gnus-prin1 articles)
 550       (insert ")\n"))))
 551
 552 (defun nnmh-deletable-article-p (group article)
 553   "Say whether ARTICLE in GROUP can be deleted."
 554   (let ((path (concat nnmh-current-directory (int-to-string article))))
 555     ;; Writable.
 556     (and (file-writable-p path)
 557          (or
 558           ;; We can never delete the last article in the group.
 559           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 560                    article))
 561           ;; Well, we can.
 562           nnmh-allow-delete-final))))
 563
 564 (provide 'nnmh)
 565
 566 ;;; nnmh.el ends here