cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (message "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (message "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (nnmh-possibly-change-directory group server)
 149   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 150         (pathname-coding-system 'binary)
 151         dir)
 152     (cond
 153      ((not (file-directory-p pathname))
 154       (nnheader-report
 155        'nnmh "Can't select group (no such directory): %s" group))
 156      (t
 157       (setq nnmh-current-directory pathname)
 158       (and nnmh-get-new-mail
 159            nnmh-be-safe
 160            (nnmh-update-gnus-unreads group))
 161       (cond
 162        (dont-check
 163         (nnheader-report 'nnmh "Selected group %s" group)
 164         t)
 165        (t
 166         ;; Re-scan the directory if it's on a foreign system.
 167         (nnheader-re-read-dir pathname)
 168         (setq dir
 169               (sort
 170                (mapcar (lambda (name) (string-to-int name))
 171                        (directory-files pathname nil "^[0-9]+$" t))
 172                '<))
 173           (cond
 174            (dir
 175             (nnheader-report 'nnmh "Selected group %s" group)
 176             (nnheader-insert
 177              "211 %d %d %d %s\n" (length dir) (car dir)
 178              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 179              group))
 180            (t
 181             (nnheader-report 'nnmh "Empty group %s" group)
 182             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 183
 184 (deffoo nnmh-request-scan (&optional group server)
 185   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 186
 187 (deffoo nnmh-request-list (&optional server dir)
 188   (nnheader-insert "")
 189   (nnmh-possibly-change-directory nil server)
 190   (let ((pathname-coding-system 'binary)
 191         (nnmh-toplev
 192          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 193     (nnmh-request-list-1 nnmh-toplev))
 194   (setq nnmh-group-alist (nnmail-get-active))
 195   t)
 196
 197 (defvar nnmh-toplev)
 198 (defun nnmh-request-list-1 (dir)
 199   (setq dir (expand-file-name dir))
 200   ;; Recurse down all directories.
 201   (let ((dirs (and (file-readable-p dir)
 202                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 203                    (nnheader-directory-files dir t nil t)))
 204         rdir)
 205     ;; Recurse down directories.
 206     (while (setq rdir (pop dirs))
 207       (when (and (file-directory-p rdir)
 208                  (file-readable-p rdir)
 209                  (not (equal (file-truename rdir)
 210                              (file-truename dir))))
 211         (nnmh-request-list-1 rdir))))
 212   ;; For each directory, generate an active file line.
 213   (unless (string= (expand-file-name nnmh-toplev) dir)
 214     (let ((files (mapcar
 215                   (lambda (name) (string-to-int name))
 216                   (directory-files dir nil "^[0-9]+$" t))))
 217       (when files
 218         (save-excursion
 219           (set-buffer nntp-server-buffer)
 220           (goto-char (point-max))
 221           (insert
 222            (format
 223             "%s %d %d y\n"
 224             (progn
 225               (string-match
 226                (regexp-quote
 227                 (file-truename (file-name-as-directory
 228                                 (expand-file-name nnmh-toplev))))
 229                dir)
 230               (nnheader-replace-chars-in-string
 231                (gnus-decode-coding-string (substring dir (match-end 0))
 232                                           nnmail-pathname-coding-system)
 233                ?/ ?.))
 234             (apply 'max files)
 235             (apply 'min files)))))))
 236   t)
 237
 238 (deffoo nnmh-request-newgroups (date &optional server)
 239   (nnmh-request-list server))
 240
 241 (deffoo nnmh-request-expire-articles (articles newsgroup
 242                                                &optional server force)
 243   (nnmh-possibly-change-directory newsgroup server)
 244   (let* ((active-articles
 245           (mapcar
 246            (function
 247             (lambda (name)
 248               (string-to-int name)))
 249            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 250          (is-old t)
 251          article rest mod-time)
 252     (nnmail-activate 'nnmh)
 253
 254     (while (and articles is-old)
 255       (setq article (concat nnmh-current-directory
 256                             (int-to-string (car articles))))
 257       (when (setq mod-time (nth 5 (file-attributes article)))
 258         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 259                  (setq is-old
 260                        (nnmail-expired-article-p newsgroup mod-time force)))
 261             (progn
 262               (nnheader-message 5 "Deleting article %s in %s..."
 263                                 article newsgroup)
 264               (condition-case ()
 265                   (funcall nnmail-delete-file-function article)
 266                 (file-error
 267                  (nnheader-message 1 "Couldn't delete article %s in %s"
 268                                    article newsgroup)
 269                  (push (car articles) rest))))
 270           (push (car articles) rest)))
 271       (setq articles (cdr articles)))
 272     (message "")
 273     (nconc rest articles)))
 274
 275 (deffoo nnmh-close-group (group &optional server)
 276   t)
 277
 278 (deffoo nnmh-request-move-article
 279   (article group server accept-form &optional last)
 280   (let ((buf (get-buffer-create " *nnmh move*"))
 281         result)
 282     (and
 283      (nnmh-deletable-article-p group article)
 284      (nnmh-request-article article group server)
 285      (save-excursion
 286        (set-buffer buf)
 287        (erase-buffer)
 288        (insert-buffer-substring nntp-server-buffer)
 289        (setq result (eval accept-form))
 290        (kill-buffer (current-buffer))
 291        result)
 292      (progn
 293        (nnmh-possibly-change-directory group server)
 294        (condition-case ()
 295            (funcall nnmail-delete-file-function
 296                     (concat nnmh-current-directory (int-to-string article)))
 297          (file-error nil))))
 298     result))
 299
 300 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 301   (nnmh-possibly-change-directory group server)
 302   (nnmail-check-syntax)
 303   (when nnmail-cache-accepted-message-ids
 304     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 305   (prog1
 306       (if (stringp group)
 307           (and
 308            (nnmail-activate 'nnmh)
 309            (if noinsert
 310                (nnmh-active-number group)
 311              (car (nnmh-save-mail
 312                    (list (cons group (nnmh-active-number group)))
 313                    noinsert))))
 314         (and
 315          (nnmail-activate 'nnmh)
 316          (let ((res (nnmail-article-group 'nnmh-active-number)))
 317            (if (and (null res)
 318                     (yes-or-no-p "Moved to `junk' group; delete article? "))
 319                'junk
 320              (car (nnmh-save-mail res noinsert))))))
 321     (when (and last nnmail-cache-accepted-message-ids)
 322       (nnmail-cache-close))))
 323
 324 (deffoo nnmh-request-replace-article (article group buffer)
 325   (nnmh-possibly-change-directory group)
 326   (save-excursion
 327     (set-buffer buffer)
 328     (nnmh-possibly-create-directory group)
 329     (ignore-errors
 330       (nnmail-write-region
 331        (point-min) (point-max)
 332        (concat nnmh-current-directory (int-to-string article))
 333        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 334       t)))
 335
 336 (deffoo nnmh-request-create-group (group &optional server args)
 337   (nnmail-activate 'nnmh)
 338   (unless (assoc group nnmh-group-alist)
 339     (let (active)
 340       (push (list group (setq active (cons 1 0)))
 341             nnmh-group-alist)
 342       (nnmh-possibly-create-directory group)
 343       (nnmh-possibly-change-directory group server)
 344       (let ((articles (mapcar
 345                        (lambda (file)
 346                          (string-to-int file))
 347                        (directory-files
 348                         nnmh-current-directory nil "^[0-9]+$"))))
 349         (when articles
 350           (setcar active (apply 'min articles))
 351           (setcdr active (apply 'max articles))))))
 352   t)
 353
 354 (deffoo nnmh-request-delete-group (group &optional force server)
 355   (nnmh-possibly-change-directory group server)
 356   ;; Delete all articles in GROUP.
 357   (if (not force)
 358       ()                                ; Don't delete the articles.
 359     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 360       (while articles
 361         (when (file-writable-p (car articles))
 362           (nnheader-message 5 "Deleting article %s in %s..."
 363                             (car articles) group)
 364           (funcall nnmail-delete-file-function (car articles)))
 365         (setq articles (cdr articles))))
 366     ;; Try to delete the directory itself.
 367     (ignore-errors
 368       (delete-directory nnmh-current-directory)))
 369   ;; Remove the group from all structures.
 370   (setq nnmh-group-alist
 371         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 372         nnmh-current-directory nil)
 373   t)
 374
 375 (deffoo nnmh-request-rename-group (group new-name &optional server)
 376   (nnmh-possibly-change-directory group server)
 377   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 378         (old-dir (nnmail-group-pathname group nnmh-directory)))
 379     (when (ignore-errors
 380             (make-directory new-dir t)
 381             t)
 382       ;; We move the articles file by file instead of renaming
 383       ;; the directory -- there may be subgroups in this group.
 384       ;; One might be more clever, I guess.
 385       (let ((files (nnheader-article-to-file-alist old-dir)))
 386         (while files
 387           (rename-file
 388            (concat old-dir (cdar files))
 389            (concat new-dir (cdar files)))
 390           (pop files)))
 391       (when (<= (length (directory-files old-dir)) 2)
 392         (ignore-errors
 393           (delete-directory old-dir)))
 394       ;; That went ok, so we change the internal structures.
 395       (let ((entry (assoc group nnmh-group-alist)))
 396         (when entry
 397           (setcar entry new-name))
 398         (setq nnmh-current-directory nil)
 399         t))))
 400
 401 (nnoo-define-skeleton nnmh)
 402
 403 \f
 404 ;;; Internal functions.
 405
 406 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 407   (when (and server
 408              (not (nnmh-server-opened server)))
 409     (nnmh-open-server server))
 410   (when newsgroup
 411     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 412           (pathname-coding-system 'binary))
 413       (if (file-directory-p pathname)
 414           (setq nnmh-current-directory pathname)
 415         (error "No such newsgroup: %s" newsgroup)))))
 416
 417 (defun nnmh-possibly-create-directory (group)
 418   (let (dir dirs)
 419     (setq dir (nnmail-group-pathname group nnmh-directory))
 420     (while (not (file-directory-p dir))
 421       (push dir dirs)
 422       (setq dir (file-name-directory (directory-file-name dir))))
 423     (while dirs
 424       (when (make-directory (directory-file-name (car dirs)))
 425         (error "Could not create directory %s" (car dirs)))
 426       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 427       (setq dirs (cdr dirs)))))
 428
 429 (defun nnmh-save-mail (group-art &optional noinsert)
 430   "Called narrowed to an article."
 431   (unless noinsert
 432     (nnmail-insert-lines)
 433     (nnmail-insert-xref group-art))
 434   (run-hooks 'nnmail-prepare-save-mail-hook)
 435   (run-hooks 'nnmh-prepare-save-mail-hook)
 436   (goto-char (point-min))
 437   (while (looking-at "From ")
 438     (replace-match "X-From-Line: ")
 439     (forward-line 1))
 440   ;; We save the article in all the newsgroups it belongs in.
 441   (let ((ga group-art)
 442         first)
 443     (while ga
 444       (nnmh-possibly-create-directory (caar ga))
 445       (let ((file (concat (nnmail-group-pathname
 446                            (caar ga) nnmh-directory)
 447                           (int-to-string (cdar ga)))))
 448         (if first
 449             ;; It was already saved, so we just make a hard link.
 450             (funcall nnmail-crosspost-link-function first file t)
 451           ;; Save the article.
 452           (nnmail-write-region (point-min) (point-max) file nil nil)
 453           (setq first file)))
 454       (setq ga (cdr ga))))
 455   group-art)
 456
 457 (defun nnmh-active-number (group)
 458   "Compute the next article number in GROUP."
 459   (let ((active (cadr (assoc group nnmh-group-alist)))
 460         (dir (nnmail-group-pathname group nnmh-directory))
 461         (pathname-coding-system 'binary))
 462     (unless active
 463       ;; The group wasn't known to nnmh, so we just create an active
 464       ;; entry for it.
 465       (setq active (cons 1 0))
 466       (push (list group active) nnmh-group-alist)
 467       (unless (file-exists-p dir)
 468         (make-directory dir))
 469       ;; Find the highest number in the group.
 470       (let ((files (sort
 471                     (mapcar
 472                      (lambda (f)
 473                        (string-to-int f))
 474                      (directory-files dir nil "^[0-9]+$"))
 475                     '>)))
 476         (when files
 477           (setcdr active (car files)))))
 478     (setcdr active (1+ (cdr active)))
 479     (while (file-exists-p
 480             (concat (nnmail-group-pathname group nnmh-directory)
 481                     (int-to-string (cdr active))))
 482       (setcdr active (1+ (cdr active))))
 483     (cdr active)))
 484
 485 (defun nnmh-update-gnus-unreads (group)
 486   ;; Go through the .nnmh-articles file and compare with the actual
 487   ;; articles in this folder.  The articles that are "new" will be
 488   ;; marked as unread by Gnus.
 489   (let* ((dir nnmh-current-directory)
 490          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 491                               (directory-files nnmh-current-directory
 492                                                nil "^[0-9]+$" t))
 493                       '<))
 494          (nnmh-file (concat dir ".nnmh-articles"))
 495          new articles)
 496     ;; Load the .nnmh-articles file.
 497     (when (file-exists-p nnmh-file)
 498       (setq articles
 499             (let (nnmh-newsgroup-articles)
 500               (ignore-errors (load nnmh-file nil t t))
 501               nnmh-newsgroup-articles)))
 502     ;; Add all new articles to the `new' list.
 503     (let ((art files))
 504       (while art
 505         (unless (assq (car art) articles)
 506           (push (car art) new))
 507         (setq art (cdr art))))
 508     ;; Remove all deleted articles.
 509     (let ((art articles))
 510       (while art
 511         (unless (memq (caar art) files)
 512           (setq articles (delq (car art) articles)))
 513         (setq art (cdr art))))
 514     ;; Check whether the articles really are the ones that Gnus thinks
 515     ;; they are by looking at the time-stamps.
 516     (let ((arts articles)
 517           art)
 518       (while (setq art (pop arts))
 519         (when (not (equal
 520                     (nth 5 (file-attributes
 521                             (concat dir (int-to-string (car art)))))
 522                     (cdr art)))
 523           (setq articles (delq art articles))
 524           (push (car art) new))))
 525     ;; Go through all the new articles and add them, and their
 526     ;; time-stamps, to the list.
 527     (setq articles
 528           (nconc articles
 529                  (mapcar
 530                   (lambda (art)
 531                     (cons art
 532                           (nth 5 (file-attributes
 533                                   (concat dir (int-to-string art))))))
 534                   new)))
 535     ;; Make Gnus mark all new articles as unread.
 536     (when new
 537       (gnus-make-articles-unread
 538        (gnus-group-prefixed-name group (list 'nnmh ""))
 539        (setq new (sort new '<))))
 540     ;; Sort the article list with highest numbers first.
 541     (setq articles (sort articles (lambda (art1 art2)
 542                                     (> (car art1) (car art2)))))
 543     ;; Finally write this list back to the .nnmh-articles file.
 544     (nnheader-temp-write nnmh-file
 545       (insert ";; Gnus article active file for " group "\n\n")
 546       (insert "(setq nnmh-newsgroup-articles '")
 547       (gnus-prin1 articles)
 548       (insert ")\n"))))
 549
 550 (defun nnmh-deletable-article-p (group article)
 551   "Say whether ARTICLE in GROUP can be deleted."
 552   (let ((path (concat nnmh-current-directory (int-to-string article))))
 553     ;; Writable.
 554     (and (file-writable-p path)
 555          (or
 556           ;; We can never delete the last article in the group.
 557           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 558                    article))
 559           ;; Well, we can.
 560           nnmh-allow-delete-final))))
 561
 562 (provide 'nnmh)
 563
 564 ;;; nnmh.el ends here