cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (message "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (message "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 149         (pathname-coding-system 'binary)
 150         dir)
 151     (cond
 152      ((not (file-directory-p pathname))
 153       (nnheader-report
 154        'nnmh "Can't select group (no such directory): %s" group))
 155      (t
 156       (setq nnmh-current-directory pathname)
 157       (and nnmh-get-new-mail
 158            nnmh-be-safe
 159            (nnmh-update-gnus-unreads group))
 160       (cond
 161        (dont-check
 162         (nnheader-report 'nnmh "Selected group %s" group)
 163         t)
 164        (t
 165         ;; Re-scan the directory if it's on a foreign system.
 166         (nnheader-re-read-dir pathname)
 167         (setq dir
 168               (sort
 169                (mapcar (lambda (name) (string-to-int name))
 170                        (directory-files pathname nil "^[0-9]+$" t))
 171                '<))
 172           (cond
 173            (dir
 174             (nnheader-report 'nnmh "Selected group %s" group)
 175             (nnheader-insert
 176              "211 %d %d %d %s\n" (length dir) (car dir)
 177              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 178              group))
 179            (t
 180             (nnheader-report 'nnmh "Empty group %s" group)
 181             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 182
 183 (deffoo nnmh-request-scan (&optional group server)
 184   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 185
 186 (deffoo nnmh-request-list (&optional server dir)
 187   (nnheader-insert "")
 188   (let ((pathname-coding-system 'binary)
 189         (nnmh-toplev
 190          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 191     (nnmh-request-list-1 nnmh-toplev))
 192   (setq nnmh-group-alist (nnmail-get-active))
 193   t)
 194
 195 (defvar nnmh-toplev)
 196 (defun nnmh-request-list-1 (dir)
 197   (setq dir (expand-file-name dir))
 198   ;; Recurse down all directories.
 199   (let ((dirs (and (file-readable-p dir)
 200                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 201                    (directory-files dir t nil t)))
 202         dir)
 203     ;; Recurse down directories.
 204     (while (setq dir (pop dirs))
 205       (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 206                  (file-directory-p dir)
 207                  (file-readable-p dir))
 208         (nnmh-request-list-1 dir))))
 209   ;; For each directory, generate an active file line.
 210   (unless (string= (expand-file-name nnmh-toplev) dir)
 211     (let ((files (mapcar
 212                   (lambda (name) (string-to-int name))
 213                   (directory-files dir nil "^[0-9]+$" t))))
 214       (when files
 215         (save-excursion
 216           (set-buffer nntp-server-buffer)
 217           (goto-char (point-max))
 218           (insert
 219            (format
 220             "%s %d %d y\n"
 221             (progn
 222               (string-match
 223                (regexp-quote
 224                 (file-truename (file-name-as-directory
 225                                 (expand-file-name nnmh-toplev))))
 226                dir)
 227               (nnheader-replace-chars-in-string
 228                (gnus-decode-coding-string (substring dir (match-end 0))
 229                                           nnmail-pathname-coding-system)
 230                ?/ ?.))
 231             (apply 'max files)
 232             (apply 'min files)))))))
 233   t)
 234
 235 (deffoo nnmh-request-newgroups (date &optional server)
 236   (nnmh-request-list server))
 237
 238 (deffoo nnmh-request-expire-articles (articles newsgroup
 239                                                &optional server force)
 240   (nnmh-possibly-change-directory newsgroup server)
 241   (let* ((active-articles
 242           (mapcar
 243            (function
 244             (lambda (name)
 245               (string-to-int name)))
 246            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 247          (is-old t)
 248          article rest mod-time)
 249     (nnmail-activate 'nnmh)
 250
 251     (while (and articles is-old)
 252       (setq article (concat nnmh-current-directory
 253                             (int-to-string (car articles))))
 254       (when (setq mod-time (nth 5 (file-attributes article)))
 255         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 256                  (setq is-old
 257                        (nnmail-expired-article-p newsgroup mod-time force)))
 258             (progn
 259               (nnheader-message 5 "Deleting article %s in %s..."
 260                                 article newsgroup)
 261               (condition-case ()
 262                   (funcall nnmail-delete-file-function article)
 263                 (file-error
 264                  (nnheader-message 1 "Couldn't delete article %s in %s"
 265                                    article newsgroup)
 266                  (push (car articles) rest))))
 267           (push (car articles) rest)))
 268       (setq articles (cdr articles)))
 269     (message "")
 270     (nconc rest articles)))
 271
 272 (deffoo nnmh-close-group (group &optional server)
 273   t)
 274
 275 (deffoo nnmh-request-move-article
 276   (article group server accept-form &optional last)
 277   (let ((buf (get-buffer-create " *nnmh move*"))
 278         result)
 279     (and
 280      (nnmh-deletable-article-p group article)
 281      (nnmh-request-article article group server)
 282      (save-excursion
 283        (set-buffer buf)
 284        (erase-buffer)
 285        (insert-buffer-substring nntp-server-buffer)
 286        (setq result (eval accept-form))
 287        (kill-buffer (current-buffer))
 288        result)
 289      (progn
 290        (nnmh-possibly-change-directory group server)
 291        (condition-case ()
 292            (funcall nnmail-delete-file-function
 293                     (concat nnmh-current-directory (int-to-string article)))
 294          (file-error nil))))
 295     result))
 296
 297 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 298   (nnmh-possibly-change-directory group server)
 299   (nnmail-check-syntax)
 300   (when nnmail-cache-accepted-message-ids
 301     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 302   (prog1
 303       (if (stringp group)
 304           (and
 305            (nnmail-activate 'nnmh)
 306            (if noinsert
 307                (nnmh-active-number group)
 308              (car (nnmh-save-mail
 309                    (list (cons group (nnmh-active-number group)))
 310                    noinsert))))
 311         (and
 312          (nnmail-activate 'nnmh)
 313          (let ((res (nnmail-article-group 'nnmh-active-number)))
 314            (if (and (null res)
 315                     (yes-or-no-p "Moved to `junk' group; delete article? "))
 316                'junk
 317              (car (nnmh-save-mail res noinsert))))))
 318     (when (and last nnmail-cache-accepted-message-ids)
 319       (nnmail-cache-close))))
 320
 321 (deffoo nnmh-request-replace-article (article group buffer)
 322   (nnmh-possibly-change-directory group)
 323   (save-excursion
 324     (set-buffer buffer)
 325     (nnmh-possibly-create-directory group)
 326     (ignore-errors
 327       (nnmail-write-region
 328        (point-min) (point-max)
 329        (concat nnmh-current-directory (int-to-string article))
 330        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 331       t)))
 332
 333 (deffoo nnmh-request-create-group (group &optional server args)
 334   (nnmail-activate 'nnmh)
 335   (unless (assoc group nnmh-group-alist)
 336     (let (active)
 337       (push (list group (setq active (cons 1 0)))
 338             nnmh-group-alist)
 339       (nnmh-possibly-create-directory group)
 340       (nnmh-possibly-change-directory group server)
 341       (let ((articles (mapcar
 342                        (lambda (file)
 343                          (string-to-int file))
 344                        (directory-files
 345                         nnmh-current-directory nil "^[0-9]+$"))))
 346         (when articles
 347           (setcar active (apply 'min articles))
 348           (setcdr active (apply 'max articles))))))
 349   t)
 350
 351 (deffoo nnmh-request-delete-group (group &optional force server)
 352   (nnmh-possibly-change-directory group server)
 353   ;; Delete all articles in GROUP.
 354   (if (not force)
 355       ()                                ; Don't delete the articles.
 356     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 357       (while articles
 358         (when (file-writable-p (car articles))
 359           (nnheader-message 5 "Deleting article %s in %s..."
 360                             (car articles) group)
 361           (funcall nnmail-delete-file-function (car articles)))
 362         (setq articles (cdr articles))))
 363     ;; Try to delete the directory itself.
 364     (ignore-errors
 365       (delete-directory nnmh-current-directory)))
 366   ;; Remove the group from all structures.
 367   (setq nnmh-group-alist
 368         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 369         nnmh-current-directory nil)
 370   t)
 371
 372 (deffoo nnmh-request-rename-group (group new-name &optional server)
 373   (nnmh-possibly-change-directory group server)
 374   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 375         (old-dir (nnmail-group-pathname group nnmh-directory)))
 376     (when (ignore-errors
 377             (make-directory new-dir t)
 378             t)
 379       ;; We move the articles file by file instead of renaming
 380       ;; the directory -- there may be subgroups in this group.
 381       ;; One might be more clever, I guess.
 382       (let ((files (nnheader-article-to-file-alist old-dir)))
 383         (while files
 384           (rename-file
 385            (concat old-dir (cdar files))
 386            (concat new-dir (cdar files)))
 387           (pop files)))
 388       (when (<= (length (directory-files old-dir)) 2)
 389         (ignore-errors
 390           (delete-directory old-dir)))
 391       ;; That went ok, so we change the internal structures.
 392       (let ((entry (assoc group nnmh-group-alist)))
 393         (when entry
 394           (setcar entry new-name))
 395         (setq nnmh-current-directory nil)
 396         t))))
 397
 398 (nnoo-define-skeleton nnmh)
 399
 400 \f
 401 ;;; Internal functions.
 402
 403 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 404   (when (and server
 405              (not (nnmh-server-opened server)))
 406     (nnmh-open-server server))
 407   (when newsgroup
 408     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 409           (pathname-coding-system 'binary))
 410       (if (file-directory-p pathname)
 411           (setq nnmh-current-directory pathname)
 412         (error "No such newsgroup: %s" newsgroup)))))
 413
 414 (defun nnmh-possibly-create-directory (group)
 415   (let (dir dirs)
 416     (setq dir (nnmail-group-pathname group nnmh-directory))
 417     (while (not (file-directory-p dir))
 418       (push dir dirs)
 419       (setq dir (file-name-directory (directory-file-name dir))))
 420     (while dirs
 421       (when (make-directory (directory-file-name (car dirs)))
 422         (error "Could not create directory %s" (car dirs)))
 423       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 424       (setq dirs (cdr dirs)))))
 425
 426 (defun nnmh-save-mail (group-art &optional noinsert)
 427   "Called narrowed to an article."
 428   (unless noinsert
 429     (nnmail-insert-lines)
 430     (nnmail-insert-xref group-art))
 431   (run-hooks 'nnmail-prepare-save-mail-hook)
 432   (run-hooks 'nnmh-prepare-save-mail-hook)
 433   (goto-char (point-min))
 434   (while (looking-at "From ")
 435     (replace-match "X-From-Line: ")
 436     (forward-line 1))
 437   ;; We save the article in all the newsgroups it belongs in.
 438   (let ((ga group-art)
 439         first)
 440     (while ga
 441       (nnmh-possibly-create-directory (caar ga))
 442       (let ((file (concat (nnmail-group-pathname
 443                            (caar ga) nnmh-directory)
 444                           (int-to-string (cdar ga)))))
 445         (if first
 446             ;; It was already saved, so we just make a hard link.
 447             (funcall nnmail-crosspost-link-function first file t)
 448           ;; Save the article.
 449           (nnmail-write-region (point-min) (point-max) file nil nil)
 450           (setq first file)))
 451       (setq ga (cdr ga))))
 452   group-art)
 453
 454 (defun nnmh-active-number (group)
 455   "Compute the next article number in GROUP."
 456   (let ((active (cadr (assoc group nnmh-group-alist)))
 457         (dir (nnmail-group-pathname group nnmh-directory))
 458         (pathname-coding-system 'binary))
 459     (unless active
 460       ;; The group wasn't known to nnmh, so we just create an active
 461       ;; entry for it.
 462       (setq active (cons 1 0))
 463       (push (list group active) nnmh-group-alist)
 464       (unless (file-exists-p dir)
 465         (make-directory dir))
 466       ;; Find the highest number in the group.
 467       (let ((files (sort
 468                     (mapcar
 469                      (lambda (f)
 470                        (string-to-int f))
 471                      (directory-files dir nil "^[0-9]+$"))
 472                     '>)))
 473         (when files
 474           (setcdr active (car files)))))
 475     (setcdr active (1+ (cdr active)))
 476     (while (file-exists-p
 477             (concat (nnmail-group-pathname group nnmh-directory)
 478                     (int-to-string (cdr active))))
 479       (setcdr active (1+ (cdr active))))
 480     (cdr active)))
 481
 482 (defun nnmh-update-gnus-unreads (group)
 483   ;; Go through the .nnmh-articles file and compare with the actual
 484   ;; articles in this folder.  The articles that are "new" will be
 485   ;; marked as unread by Gnus.
 486   (let* ((dir nnmh-current-directory)
 487          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 488                               (directory-files nnmh-current-directory
 489                                                nil "^[0-9]+$" t))
 490                       '<))
 491          (nnmh-file (concat dir ".nnmh-articles"))
 492          new articles)
 493     ;; Load the .nnmh-articles file.
 494     (when (file-exists-p nnmh-file)
 495       (setq articles
 496             (let (nnmh-newsgroup-articles)
 497               (ignore-errors (load nnmh-file nil t t))
 498               nnmh-newsgroup-articles)))
 499     ;; Add all new articles to the `new' list.
 500     (let ((art files))
 501       (while art
 502         (unless (assq (car art) articles)
 503           (push (car art) new))
 504         (setq art (cdr art))))
 505     ;; Remove all deleted articles.
 506     (let ((art articles))
 507       (while art
 508         (unless (memq (caar art) files)
 509           (setq articles (delq (car art) articles)))
 510         (setq art (cdr art))))
 511     ;; Check whether the articles really are the ones that Gnus thinks
 512     ;; they are by looking at the time-stamps.
 513     (let ((arts articles)
 514           art)
 515       (while (setq art (pop arts))
 516         (when (not (equal
 517                     (nth 5 (file-attributes
 518                             (concat dir (int-to-string (car art)))))
 519                     (cdr art)))
 520           (setq articles (delq art articles))
 521           (push (car art) new))))
 522     ;; Go through all the new articles and add them, and their
 523     ;; time-stamps, to the list.
 524     (setq articles
 525           (nconc articles
 526                  (mapcar
 527                   (lambda (art)
 528                     (cons art
 529                           (nth 5 (file-attributes
 530                                   (concat dir (int-to-string art))))))
 531                   new)))
 532     ;; Make Gnus mark all new articles as unread.
 533     (when new
 534       (gnus-make-articles-unread
 535        (gnus-group-prefixed-name group (list 'nnmh ""))
 536        (setq new (sort new '<))))
 537     ;; Sort the article list with highest numbers first.
 538     (setq articles (sort articles (lambda (art1 art2)
 539                                     (> (car art1) (car art2)))))
 540     ;; Finally write this list back to the .nnmh-articles file.
 541     (nnheader-temp-write nnmh-file
 542       (insert ";; Gnus article active file for " group "\n\n")
 543       (insert "(setq nnmh-newsgroup-articles '")
 544       (gnus-prin1 articles)
 545       (insert ")\n"))))
 546
 547 (defun nnmh-deletable-article-p (group article)
 548   "Say whether ARTICLE in GROUP can be deleted."
 549   (let ((path (concat nnmh-current-directory (int-to-string article))))
 550     ;; Writable.
 551     (and (file-writable-p path)
 552          (or
 553           ;; We can never delete the last article in the group.
 554           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 555                    article))
 556           ;; Well, we can.
 557           nnmh-allow-delete-final))))
 558
 559 (provide 'nnmh)
 560
 561 ;;; nnmh.el ends here