cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (save-excursion
  79     (set-buffer nntp-server-buffer)
  80     (erase-buffer)
  81     (let* ((file nil)
  82            (number (length articles))
  83            (large (and (numberp nnmail-large-newsgroup)
  84                        (> number nnmail-large-newsgroup)))
  85            (count 0)
  86            (file-name-coding-system nnmail-pathname-coding-system)
  87            beg article)
  88       (nnmh-possibly-change-directory newsgroup server)
  89       ;; We don't support fetching by Message-ID.
  90       (if (stringp (car articles))
  91           'headers
  92         (while articles
  93           (when (and (file-exists-p
  94                       (setq file (concat (file-name-as-directory
  95                                           nnmh-current-directory)
  96                                          (int-to-string
  97                                           (setq article (pop articles))))))
  98                      (not (file-directory-p file)))
  99             (insert (format "221 %d Article retrieved.\n" article))
 100             (setq beg (point))
 101             (nnheader-insert-head file)
 102             (goto-char beg)
 103             (if (search-forward "\n\n" nil t)
 104                 (forward-char -1)
 105               (goto-char (point-max))
 106               (insert "\n\n"))
 107             (insert ".\n")
 108             (delete-region (point) (point-max)))
 109           (setq count (1+ count))
 110
 111           (and large
 112                (zerop (% count 20))
 113                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 114                                  (/ (* count 100) number))))
 115
 116         (when large
 117           (nnheader-message 5 "nnmh: Receiving headers...done"))
 118
 119         (nnheader-fold-continuation-lines)
 120         'headers))))
 121
 122 (deffoo nnmh-open-server (server &optional defs)
 123   (nnoo-change-server 'nnmh server defs)
 124   (when (not (file-exists-p nnmh-directory))
 125     (condition-case ()
 126         (make-directory nnmh-directory t)
 127       (error t)))
 128   (cond
 129    ((not (file-exists-p nnmh-directory))
 130     (nnmh-close-server)
 131     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 132    ((not (file-directory-p (file-truename nnmh-directory)))
 133     (nnmh-close-server)
 134     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 135    (t
 136     (nnheader-report 'nnmh "Opened server %s using directory %s"
 137                      server nnmh-directory)
 138     t)))
 139
 140 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 141   (nnmh-possibly-change-directory newsgroup server)
 142   (let ((file (if (stringp id)
 143                   nil
 144                 (concat nnmh-current-directory (int-to-string id))))
 145         (file-name-coding-system nnmail-pathname-coding-system)
 146         (nntp-server-buffer (or buffer nntp-server-buffer)))
 147     (and (stringp file)
 148          (file-exists-p file)
 149          (not (file-directory-p file))
 150          (save-excursion (nnmail-find-file file))
 151          (string-to-int (file-name-nondirectory file)))))
 152
 153 (deffoo nnmh-request-group (group &optional server dont-check)
 154   (nnheader-init-server-buffer)
 155   (nnmh-possibly-change-directory group server)
 156   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 157         (file-name-coding-system nnmail-pathname-coding-system)
 158         dir)
 159     (cond
 160      ((not (file-directory-p pathname))
 161       (nnheader-report
 162        'nnmh "Can't select group (no such directory): %s" group))
 163      (t
 164       (setq nnmh-current-directory pathname)
 165       (and nnmh-get-new-mail
 166            nnmh-be-safe
 167            (nnmh-update-gnus-unreads group))
 168       (cond
 169        (dont-check
 170         (nnheader-report 'nnmh "Selected group %s" group)
 171         t)
 172        (t
 173         ;; Re-scan the directory if it's on a foreign system.
 174         (nnheader-re-read-dir pathname)
 175         (setq dir
 176               (sort
 177                (mapcar (lambda (name) (string-to-int name))
 178                        (directory-files pathname nil "^[0-9]+$" t))
 179                '<))
 180         (cond
 181          (dir
 182           (setq nnmh-group-alist
 183                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 184           (push (list group (cons (car dir) (car (last dir))))
 185                 nnmh-group-alist)
 186           (nnheader-report 'nnmh "Selected group %s" group)
 187           (nnheader-insert
 188            "211 %d %d %d %s\n" (length dir) (car dir)
 189            (car (last dir)) group))
 190          (t
 191           (nnheader-report 'nnmh "Empty group %s" group)
 192           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 193
 194 (deffoo nnmh-request-scan (&optional group server)
 195   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 196
 197 (deffoo nnmh-request-list (&optional server dir)
 198   (nnheader-insert "")
 199   (nnmh-possibly-change-directory nil server)
 200   (let ((file-name-coding-system nnmail-pathname-coding-system)
 201         (nnmh-toplev
 202          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 203     (nnmh-request-list-1 nnmh-toplev))
 204   (setq nnmh-group-alist (nnmail-get-active))
 205   t)
 206
 207 (defvar nnmh-toplev)
 208 (defun nnmh-request-list-1 (dir)
 209   (setq dir (expand-file-name dir))
 210   ;; Recurse down all directories.
 211   (let ((dirs (and (file-readable-p dir)
 212                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 213                    (nnheader-directory-files dir t nil t)))
 214         rdir)
 215     ;; Recurse down directories.
 216     (while (setq rdir (pop dirs))
 217       (when (and (file-directory-p rdir)
 218                  (file-readable-p rdir)
 219                  (not (equal (file-truename rdir)
 220                              (file-truename dir))))
 221         (nnmh-request-list-1 rdir))))
 222   ;; For each directory, generate an active file line.
 223   (unless (string= (expand-file-name nnmh-toplev) dir)
 224     (let ((files (mapcar
 225                   (lambda (name) (string-to-int name))
 226                   (directory-files dir nil "^[0-9]+$" t))))
 227       (when files
 228         (save-excursion
 229           (set-buffer nntp-server-buffer)
 230           (goto-char (point-max))
 231           (insert
 232            (format
 233             "%s %d %d y\n"
 234             (progn
 235               (string-match
 236                (regexp-quote
 237                 (file-truename (file-name-as-directory
 238                                 (expand-file-name nnmh-toplev))))
 239                dir)
 240               (nnheader-replace-chars-in-string
 241                (mm-decode-coding-string (substring dir (match-end 0))
 242                                         nnmail-pathname-coding-system)
 243                ?/ ?.))
 244             (apply 'max files)
 245             (apply 'min files)))))))
 246   t)
 247
 248 (deffoo nnmh-request-newgroups (date &optional server)
 249   (nnmh-request-list server))
 250
 251 (deffoo nnmh-request-expire-articles (articles newsgroup
 252                                                &optional server force)
 253   (nnmh-possibly-change-directory newsgroup server)
 254   (let* ((is-old t)
 255          article rest mod-time)
 256     (nnheader-init-server-buffer)
 257
 258     (while (and articles is-old)
 259       (setq article (concat nnmh-current-directory
 260                             (int-to-string (car articles))))
 261       (when (setq mod-time (nth 5 (file-attributes article)))
 262         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 263                  (setq is-old
 264                        (nnmail-expired-article-p newsgroup mod-time force)))
 265             (progn
 266               (nnheader-message 5 "Deleting article %s in %s..."
 267                                 article newsgroup)
 268               (condition-case ()
 269                   (funcall nnmail-delete-file-function article)
 270                 (file-error
 271                  (nnheader-message 1 "Couldn't delete article %s in %s"
 272                                    article newsgroup)
 273                  (push (car articles) rest))))
 274           (push (car articles) rest)))
 275       (setq articles (cdr articles)))
 276     (nnheader-message 5 "")
 277     (nconc rest articles)))
 278
 279 (deffoo nnmh-close-group (group &optional server)
 280   t)
 281
 282 (deffoo nnmh-request-move-article
 283     (article group server accept-form &optional last)
 284   (let ((buf (get-buffer-create " *nnmh move*"))
 285         result)
 286     (and
 287      (nnmh-deletable-article-p group article)
 288      (nnmh-request-article article group server)
 289      (save-excursion
 290        (set-buffer buf)
 291        (erase-buffer)
 292        (insert-buffer-substring nntp-server-buffer)
 293        (setq result (eval accept-form))
 294        (kill-buffer (current-buffer))
 295        result)
 296      (progn
 297        (nnmh-possibly-change-directory group server)
 298        (condition-case ()
 299            (funcall nnmail-delete-file-function
 300                     (concat nnmh-current-directory (int-to-string article)))
 301          (file-error nil))))
 302     result))
 303
 304 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 305   (nnmh-possibly-change-directory group server)
 306   (nnmail-check-syntax)
 307   (when nnmail-cache-accepted-message-ids
 308     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 309   (nnheader-init-server-buffer)
 310   (prog1
 311       (if (stringp group)
 312           (if noinsert
 313               (nnmh-active-number group)
 314             (car (nnmh-save-mail
 315                   (list (cons group (nnmh-active-number group)))
 316                   noinsert)))
 317         (let ((res (nnmail-article-group 'nnmh-active-number)))
 318           (if (and (null res)
 319                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 320               'junk
 321             (car (nnmh-save-mail res noinsert)))))
 322     (when (and last nnmail-cache-accepted-message-ids)
 323       (nnmail-cache-close))))
 324
 325 (deffoo nnmh-request-replace-article (article group buffer)
 326   (nnmh-possibly-change-directory group)
 327   (save-excursion
 328     (set-buffer buffer)
 329     (nnmh-possibly-create-directory group)
 330     (ignore-errors
 331       (nnmail-write-region
 332        (point-min) (point-max)
 333        (concat nnmh-current-directory (int-to-string article))
 334        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 335       t)))
 336
 337 (deffoo nnmh-request-create-group (group &optional server args)
 338   (nnheader-init-server-buffer)
 339   (unless (assoc group nnmh-group-alist)
 340     (let (active)
 341       (push (list group (setq active (cons 1 0)))
 342             nnmh-group-alist)
 343       (nnmh-possibly-create-directory group)
 344       (nnmh-possibly-change-directory group server)
 345       (let ((articles (mapcar
 346                        (lambda (file)
 347                          (string-to-int file))
 348                        (directory-files
 349                         nnmh-current-directory nil "^[0-9]+$"))))
 350         (when articles
 351           (setcar active (apply 'min articles))
 352           (setcdr active (apply 'max articles))))))
 353   t)
 354
 355 (deffoo nnmh-request-delete-group (group &optional force server)
 356   (nnmh-possibly-change-directory group server)
 357   ;; Delete all articles in GROUP.
 358   (if (not force)
 359       ()                                ; Don't delete the articles.
 360     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 361       (while articles
 362         (when (file-writable-p (car articles))
 363           (nnheader-message 5 "Deleting article %s in %s..."
 364                             (car articles) group)
 365           (funcall nnmail-delete-file-function (car articles)))
 366         (setq articles (cdr articles))))
 367     ;; Try to delete the directory itself.
 368     (ignore-errors
 369       (delete-directory nnmh-current-directory)))
 370   ;; Remove the group from all structures.
 371   (setq nnmh-group-alist
 372         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 373         nnmh-current-directory nil)
 374   t)
 375
 376 (deffoo nnmh-request-rename-group (group new-name &optional server)
 377   (nnmh-possibly-change-directory group server)
 378   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 379         (old-dir (nnmail-group-pathname group nnmh-directory)))
 380     (when (ignore-errors
 381             (make-directory new-dir t)
 382             t)
 383       ;; We move the articles file by file instead of renaming
 384       ;; the directory -- there may be subgroups in this group.
 385       ;; One might be more clever, I guess.
 386       (let ((files (nnheader-article-to-file-alist old-dir)))
 387         (while files
 388           (rename-file
 389            (concat old-dir (cdar files))
 390            (concat new-dir (cdar files)))
 391           (pop files)))
 392       (when (<= (length (directory-files old-dir)) 2)
 393         (ignore-errors
 394           (delete-directory old-dir)))
 395       ;; That went ok, so we change the internal structures.
 396       (let ((entry (assoc group nnmh-group-alist)))
 397         (when entry
 398           (setcar entry new-name))
 399         (setq nnmh-current-directory nil)
 400         t))))
 401
 402 (nnoo-define-skeleton nnmh)
 403
 404 \f
 405 ;;; Internal functions.
 406
 407 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 408   (when (and server
 409              (not (nnmh-server-opened server)))
 410     (nnmh-open-server server))
 411   (when newsgroup
 412     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 413           (file-name-coding-system nnmail-pathname-coding-system))
 414       (if (file-directory-p pathname)
 415           (setq nnmh-current-directory pathname)
 416         (error "No such newsgroup: %s" newsgroup)))))
 417
 418 (defun nnmh-possibly-create-directory (group)
 419   (let (dir dirs)
 420     (setq dir (nnmail-group-pathname group nnmh-directory))
 421     (while (not (file-directory-p dir))
 422       (push dir dirs)
 423       (setq dir (file-name-directory (directory-file-name dir))))
 424     (while dirs
 425       (when (make-directory (directory-file-name (car dirs)))
 426         (error "Could not create directory %s" (car dirs)))
 427       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 428       (setq dirs (cdr dirs)))))
 429
 430 (defun nnmh-save-mail (group-art &optional noinsert)
 431   "Called narrowed to an article."
 432   (unless noinsert
 433     (nnmail-insert-lines)
 434     (nnmail-insert-xref group-art))
 435   (run-hooks 'nnmail-prepare-save-mail-hook)
 436   (run-hooks 'nnmh-prepare-save-mail-hook)
 437   (goto-char (point-min))
 438   (while (looking-at "From ")
 439     (replace-match "X-From-Line: ")
 440     (forward-line 1))
 441   ;; We save the article in all the newsgroups it belongs in.
 442   (let ((ga group-art)
 443         first)
 444     (while ga
 445       (nnmh-possibly-create-directory (caar ga))
 446       (let ((file (concat (nnmail-group-pathname
 447                            (caar ga) nnmh-directory)
 448                           (int-to-string (cdar ga)))))
 449         (if first
 450             ;; It was already saved, so we just make a hard link.
 451             (funcall nnmail-crosspost-link-function first file t)
 452           ;; Save the article.
 453           (nnmail-write-region (point-min) (point-max) file nil nil)
 454           (setq first file)))
 455       (setq ga (cdr ga))))
 456   group-art)
 457
 458 (defun nnmh-active-number (group)
 459   "Compute the next article number in GROUP."
 460   (let ((active (cadr (assoc group nnmh-group-alist)))
 461         (dir (nnmail-group-pathname group nnmh-directory))
 462         (file-name-coding-system nnmail-pathname-coding-system)
 463         file)
 464     (unless active
 465       ;; The group wasn't known to nnmh, so we just create an active
 466       ;; entry for it.
 467       (setq active (cons 1 0))
 468       (push (list group active) nnmh-group-alist)
 469       (unless (file-exists-p dir)
 470         (gnus-make-directory dir))
 471       ;; Find the highest number in the group.
 472       (let ((files (sort
 473                     (mapcar
 474                      (lambda (f)
 475                        (string-to-int f))
 476                      (directory-files dir nil "^[0-9]+$"))
 477                     '>)))
 478         (when files
 479           (setcdr active (car files)))))
 480     (setcdr active (1+ (cdr active)))
 481     (while (or
 482             ;; See whether the file exists...
 483             (file-exists-p
 484              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 485                                 (int-to-string (cdr active)))))
 486             ;; ... or there is a buffer that will make that file exist
 487             ;; in the future.
 488             (get-file-buffer file))
 489       ;; Skip past that file.
 490       (setcdr active (1+ (cdr active))))
 491     (cdr active)))
 492
 493 (defun nnmh-update-gnus-unreads (group)
 494   ;; Go through the .nnmh-articles file and compare with the actual
 495   ;; articles in this folder.  The articles that are "new" will be
 496   ;; marked as unread by Gnus.
 497   (let* ((dir nnmh-current-directory)
 498          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 499                               (directory-files nnmh-current-directory
 500                                                nil "^[0-9]+$" t))
 501                       '<))
 502          (nnmh-file (concat dir ".nnmh-articles"))
 503          new articles)
 504     ;; Load the .nnmh-articles file.
 505     (when (file-exists-p nnmh-file)
 506       (setq articles
 507             (let (nnmh-newsgroup-articles)
 508               (ignore-errors (load nnmh-file nil t t))
 509               nnmh-newsgroup-articles)))
 510     ;; Add all new articles to the `new' list.
 511     (let ((art files))
 512       (while art
 513         (unless (assq (car art) articles)
 514           (push (car art) new))
 515         (setq art (cdr art))))
 516     ;; Remove all deleted articles.
 517     (let ((art articles))
 518       (while art
 519         (unless (memq (caar art) files)
 520           (setq articles (delq (car art) articles)))
 521         (setq art (cdr art))))
 522     ;; Check whether the articles really are the ones that Gnus thinks
 523     ;; they are by looking at the time-stamps.
 524     (let ((arts articles)
 525           art)
 526       (while (setq art (pop arts))
 527         (when (not (equal
 528                     (nth 5 (file-attributes
 529                             (concat dir (int-to-string (car art)))))
 530                     (cdr art)))
 531           (setq articles (delq art articles))
 532           (push (car art) new))))
 533     ;; Go through all the new articles and add them, and their
 534     ;; time-stamps, to the list.
 535     (setq articles
 536           (nconc articles
 537                  (mapcar
 538                   (lambda (art)
 539                     (cons art
 540                           (nth 5 (file-attributes
 541                                   (concat dir (int-to-string art))))))
 542                   new)))
 543     ;; Make Gnus mark all new articles as unread.
 544     (when new
 545       (gnus-make-articles-unread
 546        (gnus-group-prefixed-name group (list 'nnmh ""))
 547        (setq new (sort new '<))))
 548     ;; Sort the article list with highest numbers first.
 549     (setq articles (sort articles (lambda (art1 art2)
 550                                     (> (car art1) (car art2)))))
 551     ;; Finally write this list back to the .nnmh-articles file.
 552     (with-temp-file nnmh-file
 553       (insert ";; Gnus article active file for " group "\n\n")
 554       (insert "(setq nnmh-newsgroup-articles '")
 555       (gnus-prin1 articles)
 556       (insert ")\n"))))
 557
 558 (defun nnmh-deletable-article-p (group article)
 559   "Say whether ARTICLE in GROUP can be deleted."
 560   (let ((path (concat nnmh-current-directory (int-to-string article))))
 561     ;; Writable.
 562     (and (file-writable-p path)
 563          (or
 564           ;; We can never delete the last article in the group.
 565           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 566                    article))
 567           ;; Well, we can.
 568           nnmh-allow-delete-final))))
 569
 570 (provide 'nnmh)
 571
 572 ;;; nnmh.el ends here