cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (with-current-buffer nntp-server-buffer
  79     (erase-buffer)
  80     (let* ((file nil)
  81            (number (length articles))
  82            (large (and (numberp nnmail-large-newsgroup)
  83                        (> number nnmail-large-newsgroup)))
  84            (count 0)
  85            (file-name-coding-system nnmail-pathname-coding-system)
  86            beg article)
  87       (nnmh-possibly-change-directory newsgroup server)
  88       ;; We don't support fetching by Message-ID.
  89       (if (stringp (car articles))
  90           'headers
  91         (while articles
  92           (when (and (file-exists-p
  93                       (setq file (concat (file-name-as-directory
  94                                           nnmh-current-directory)
  95                                          (int-to-string
  96                                           (setq article (pop articles))))))
  97                      (not (file-directory-p file)))
  98             (insert (format "221 %d Article retrieved.\n" article))
  99             (setq beg (point))
 100             (nnheader-insert-head file)
 101             (goto-char beg)
 102             (if (search-forward "\n\n" nil t)
 103                 (forward-char -1)
 104               (goto-char (point-max))
 105               (insert "\n\n"))
 106             (insert ".\n")
 107             (delete-region (point) (point-max)))
 108           (setq count (1+ count))
 109
 110           (and large
 111                (zerop (% count 20))
 112                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 113                                  (/ (* count 100) number))))
 114
 115         (when large
 116           (nnheader-message 5 "nnmh: Receiving headers...done"))
 117
 118         (nnheader-fold-continuation-lines)
 119         'headers))))
 120
 121 (deffoo nnmh-open-server (server &optional defs)
 122   (nnoo-change-server 'nnmh server defs)
 123   (when (not (file-exists-p nnmh-directory))
 124     (condition-case ()
 125         (make-directory nnmh-directory t)
 126       (error t)))
 127   (cond
 128    ((not (file-exists-p nnmh-directory))
 129     (nnmh-close-server)
 130     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 131    ((not (file-directory-p (file-truename nnmh-directory)))
 132     (nnmh-close-server)
 133     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 134    (t
 135     (nnheader-report 'nnmh "Opened server %s using directory %s"
 136                      server nnmh-directory)
 137     t)))
 138
 139 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 140   (nnmh-possibly-change-directory newsgroup server)
 141   (let ((file (if (stringp id)
 142                   nil
 143                 (concat nnmh-current-directory (int-to-string id))))
 144         (file-name-coding-system nnmail-pathname-coding-system)
 145         (nntp-server-buffer (or buffer nntp-server-buffer)))
 146     (and (stringp file)
 147          (file-exists-p file)
 148          (not (file-directory-p file))
 149          (save-excursion (nnmail-find-file file))
 150          (string-to-number (file-name-nondirectory file)))))
 151
 152 (deffoo nnmh-request-group (group &optional server dont-check info)
 153   (nnheader-init-server-buffer)
 154   (nnmh-possibly-change-directory group server)
 155   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 156         (file-name-coding-system nnmail-pathname-coding-system)
 157         dir)
 158     (cond
 159      ((not (file-directory-p pathname))
 160       (nnheader-report
 161        'nnmh "Can't select group (no such directory): %s" group))
 162      (t
 163       (setq nnmh-current-directory pathname)
 164       (and nnmh-get-new-mail
 165            nnmh-be-safe
 166            (nnmh-update-gnus-unreads group))
 167       (cond
 168        (dont-check
 169         (nnheader-report 'nnmh "Selected group %s" group)
 170         t)
 171        (t
 172         ;; Re-scan the directory if it's on a foreign system.
 173         (nnheader-re-read-dir pathname)
 174         (setq dir
 175               (sort
 176                (mapcar 'string-to-number
 177                        (directory-files pathname nil "^[0-9]+$" t))
 178                '<))
 179         (cond
 180          (dir
 181           (setq nnmh-group-alist
 182                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 183           (push (list group (cons (car dir) (car (last dir))))
 184                 nnmh-group-alist)
 185           (nnheader-report 'nnmh "Selected group %s" group)
 186           (nnheader-insert
 187            "211 %d %d %d %s\n" (length dir) (car dir)
 188            (car (last dir)) group))
 189          (t
 190           (nnheader-report 'nnmh "Empty group %s" group)
 191           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 192
 193 (deffoo nnmh-request-scan (&optional group server)
 194   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 195
 196 (deffoo nnmh-request-list (&optional server dir)
 197   (nnheader-insert "")
 198   (nnmh-possibly-change-directory nil server)
 199   (let ((file-name-coding-system nnmail-pathname-coding-system)
 200         (nnmh-toplev
 201          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 202     (nnmh-request-list-1 nnmh-toplev))
 203   (setq nnmh-group-alist (nnmail-get-active))
 204   t)
 205
 206 (defvar nnmh-toplev)
 207 (defun nnmh-request-list-1 (dir)
 208   (setq dir (expand-file-name dir))
 209   ;; Recurse down all directories.
 210   (let ((files (nnheader-directory-files dir t nil t))
 211         (max 0)
 212         min rdir num subdirectoriesp file)
 213     ;; Recurse down directories.
 214     (setq subdirectoriesp (> (nth 1 (file-attributes dir)) 2))
 215     (dolist (rdir files)
 216       (if (or (not subdirectoriesp)
 217               (file-regular-p rdir))
 218           (progn
 219             (setq file (file-name-nondirectory rdir))
 220             (when (string-match "^[0-9]+$" file)
 221               (setq num (string-to-number file))
 222               (setq max (max max num))
 223               (when (or (null min)
 224                         (< num min))
 225                 (setq min num))))
 226         ;; This is a directory.
 227         (when (and (file-readable-p rdir)
 228                    (not (equal (file-truename rdir)
 229                                (file-truename dir))))
 230           (nnmh-request-list-1 rdir))))
 231     ;; For each directory, generate an active file line.
 232     (unless (string= (expand-file-name nnmh-toplev) dir)
 233       (with-current-buffer nntp-server-buffer
 234         (goto-char (point-max))
 235         (insert
 236          (format
 237           "%s %.0f %.0f y\n"
 238           (progn
 239             (string-match
 240              (regexp-quote
 241               (file-truename (file-name-as-directory
 242                               (expand-file-name nnmh-toplev))))
 243              dir)
 244             (mm-string-to-multibyte ;Why?  Isn't it multibyte already?
 245              (mm-encode-coding-string
 246               (nnheader-replace-chars-in-string
 247                (substring dir (match-end 0))
 248                ?/ ?.)
 249               nnmail-pathname-coding-system)))
 250           (or max 0)
 251           (or min 1))))))
 252   t)
 253
 254 (deffoo nnmh-request-newgroups (date &optional server)
 255   (nnmh-request-list server))
 256
 257 (deffoo nnmh-request-expire-articles (articles newsgroup
 258                                                &optional server force)
 259   (nnmh-possibly-change-directory newsgroup server)
 260   (let ((is-old t)
 261         article rest mod-time)
 262     (nnheader-init-server-buffer)
 263
 264     (while (and articles is-old)
 265       (setq article (concat nnmh-current-directory
 266                             (int-to-string (car articles))))
 267       (when (setq mod-time (nth 5 (file-attributes article)))
 268         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 269                  (setq is-old
 270                        (nnmail-expired-article-p newsgroup mod-time force)))
 271             (progn
 272               ;; Allow a special target group. -- jcn
 273               (unless (eq nnmail-expiry-target 'delete)
 274                 (with-temp-buffer
 275                   (nnmh-request-article (car articles)
 276                                         newsgroup server (current-buffer))
 277                   (nnmail-expiry-target-group
 278                    nnmail-expiry-target newsgroup)))
 279               (nnheader-message 5 "Deleting article %s in %s..."
 280                                 article newsgroup)
 281               (condition-case ()
 282                   (funcall nnmail-delete-file-function article)
 283                 (file-error
 284                  (nnheader-message 1 "Couldn't delete article %s in %s"
 285                                    article newsgroup)
 286                  (push (car articles) rest))))
 287           (push (car articles) rest)))
 288       (setq articles (cdr articles)))
 289     (nnheader-message 5 "")
 290     (nconc rest articles)))
 291
 292 (deffoo nnmh-close-group (group &optional server)
 293   t)
 294
 295 (deffoo nnmh-request-move-article (article group server accept-form
 296                                            &optional last move-is-internal)
 297   (let ((buf (get-buffer-create " *nnmh move*"))
 298         result)
 299     (and
 300      (nnmh-deletable-article-p group article)
 301      (nnmh-request-article article group server)
 302      (with-current-buffer buf
 303        (erase-buffer)
 304        (insert-buffer-substring nntp-server-buffer)
 305        (setq result (eval accept-form))
 306        (kill-buffer (current-buffer))
 307        result)
 308      (progn
 309        (nnmh-possibly-change-directory group server)
 310        (condition-case ()
 311            (funcall nnmail-delete-file-function
 312                     (concat nnmh-current-directory (int-to-string article)))
 313          (file-error nil))))
 314     result))
 315
 316 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 317   (nnmh-possibly-change-directory group server)
 318   (nnmail-check-syntax)
 319   (when nnmail-cache-accepted-message-ids
 320     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 321                          group
 322                          (nnmail-fetch-field "subject")
 323                          (nnmail-fetch-field "from")))
 324   (nnheader-init-server-buffer)
 325   (prog1
 326       (if (stringp group)
 327           (if noinsert
 328               (nnmh-active-number group)
 329             (car (nnmh-save-mail
 330                   (list (cons group (nnmh-active-number group)))
 331                   noinsert)))
 332         (let ((res (nnmail-article-group 'nnmh-active-number)))
 333           (if (and (null res)
 334                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 335               'junk
 336             (car (nnmh-save-mail res noinsert)))))
 337     (when (and last nnmail-cache-accepted-message-ids)
 338       (nnmail-cache-close))))
 339
 340 (deffoo nnmh-request-replace-article (article group buffer)
 341   (nnmh-possibly-change-directory group)
 342   (with-current-buffer buffer
 343     (nnmh-possibly-create-directory group)
 344     (ignore-errors
 345       (nnmail-write-region
 346        (point-min) (point-max)
 347        (concat nnmh-current-directory (int-to-string article))
 348        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 349       t)))
 350
 351 (deffoo nnmh-request-create-group (group &optional server args)
 352   (nnheader-init-server-buffer)
 353   (unless (assoc group nnmh-group-alist)
 354     (let (active)
 355       (push (list group (setq active (cons 1 0)))
 356             nnmh-group-alist)
 357       (nnmh-possibly-create-directory group)
 358       (nnmh-possibly-change-directory group server)
 359       (let ((articles (mapcar 'string-to-number
 360                               (directory-files
 361                                nnmh-current-directory nil "^[0-9]+$"))))
 362         (when articles
 363           (setcar active (apply 'min articles))
 364           (setcdr active (apply 'max articles))))))
 365   t)
 366
 367 (deffoo nnmh-request-delete-group (group &optional force server)
 368   (nnmh-possibly-change-directory group server)
 369   ;; Delete all articles in GROUP.
 370   (if (not force)
 371       ()                                ; Don't delete the articles.
 372     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 373       (while articles
 374         (when (file-writable-p (car articles))
 375           (nnheader-message 5 "Deleting article %s in %s..."
 376                             (car articles) group)
 377           (funcall nnmail-delete-file-function (car articles)))
 378         (setq articles (cdr articles))))
 379     ;; Try to delete the directory itself.
 380     (ignore-errors
 381       (delete-directory nnmh-current-directory)))
 382   ;; Remove the group from all structures.
 383   (setq nnmh-group-alist
 384         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 385         nnmh-current-directory nil)
 386   t)
 387
 388 (deffoo nnmh-request-rename-group (group new-name &optional server)
 389   (nnmh-possibly-change-directory group server)
 390   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 391         (old-dir (nnmail-group-pathname group nnmh-directory)))
 392     (when (ignore-errors
 393             (make-directory new-dir t)
 394             t)
 395       ;; We move the articles file by file instead of renaming
 396       ;; the directory -- there may be subgroups in this group.
 397       ;; One might be more clever, I guess.
 398       (let ((files (nnheader-article-to-file-alist old-dir)))
 399         (while files
 400           (rename-file
 401            (concat old-dir (cdar files))
 402            (concat new-dir (cdar files)))
 403           (pop files)))
 404       (when (<= (length (directory-files old-dir)) 2)
 405         (ignore-errors
 406           (delete-directory old-dir)))
 407       ;; That went ok, so we change the internal structures.
 408       (let ((entry (assoc group nnmh-group-alist)))
 409         (when entry
 410           (setcar entry new-name))
 411         (setq nnmh-current-directory nil)
 412         t))))
 413
 414 (nnoo-define-skeleton nnmh)
 415
 416 \f
 417 ;;; Internal functions.
 418
 419 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 420   (when (and server
 421              (not (nnmh-server-opened server)))
 422     (nnmh-open-server server))
 423   (when newsgroup
 424     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 425           (file-name-coding-system nnmail-pathname-coding-system))
 426       (if (file-directory-p pathname)
 427           (setq nnmh-current-directory pathname)
 428         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 429
 430 (defun nnmh-possibly-create-directory (group)
 431   (let (dir dirs)
 432     (setq dir (nnmail-group-pathname group nnmh-directory))
 433     (while (not (file-directory-p dir))
 434       (push dir dirs)
 435       (setq dir (file-name-directory (directory-file-name dir))))
 436     (while dirs
 437       (when (make-directory (directory-file-name (car dirs)))
 438         (error "Could not create directory %s" (car dirs)))
 439       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 440       (setq dirs (cdr dirs)))))
 441
 442 (defun nnmh-save-mail (group-art &optional noinsert)
 443   "Called narrowed to an article."
 444   (unless noinsert
 445     (nnmail-insert-lines)
 446     (nnmail-insert-xref group-art))
 447   (run-hooks 'nnmail-prepare-save-mail-hook)
 448   (run-hooks 'nnmh-prepare-save-mail-hook)
 449   (goto-char (point-min))
 450   (while (looking-at "From ")
 451     (replace-match "X-From-Line: ")
 452     (forward-line 1))
 453   ;; We save the article in all the newsgroups it belongs in.
 454   (let ((ga group-art)
 455         first)
 456     (while ga
 457       (nnmh-possibly-create-directory (caar ga))
 458       (let ((file (concat (nnmail-group-pathname
 459                            (caar ga) nnmh-directory)
 460                           (int-to-string (cdar ga)))))
 461         (if first
 462             ;; It was already saved, so we just make a hard link.
 463             (funcall nnmail-crosspost-link-function first file t)
 464           ;; Save the article.
 465           (nnmail-write-region (point-min) (point-max) file nil nil)
 466           (setq first file)))
 467       (setq ga (cdr ga))))
 468   group-art)
 469
 470 (defun nnmh-active-number (group)
 471   "Compute the next article number in GROUP."
 472   (let ((active (cadr (assoc group nnmh-group-alist)))
 473         (dir (nnmail-group-pathname group nnmh-directory))
 474         (file-name-coding-system nnmail-pathname-coding-system)
 475         file)
 476     (unless active
 477       ;; The group wasn't known to nnmh, so we just create an active
 478       ;; entry for it.
 479       (setq active (cons 1 0))
 480       (push (list group active) nnmh-group-alist)
 481       (unless (file-exists-p dir)
 482         (gnus-make-directory dir))
 483       ;; Find the highest number in the group.
 484       (let ((files (sort
 485                     (mapcar 'string-to-number
 486                             (directory-files dir nil "^[0-9]+$"))
 487                     '>)))
 488         (when files
 489           (setcdr active (car files)))))
 490     (setcdr active (1+ (cdr active)))
 491     (while (or
 492             ;; See whether the file exists...
 493             (file-exists-p
 494              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 495                                 (int-to-string (cdr active)))))
 496             ;; ... or there is a buffer that will make that file exist
 497             ;; in the future.
 498             (get-file-buffer file))
 499       ;; Skip past that file.
 500       (setcdr active (1+ (cdr active))))
 501     (cdr active)))
 502
 503 (defun nnmh-update-gnus-unreads (group)
 504   ;; Go through the .nnmh-articles file and compare with the actual
 505   ;; articles in this folder.  The articles that are "new" will be
 506   ;; marked as unread by Gnus.
 507   (let* ((dir nnmh-current-directory)
 508          (files (sort (mapcar 'string-to-number
 509                               (directory-files nnmh-current-directory
 510                                                nil "^[0-9]+$" t))
 511                       '<))
 512          (nnmh-file (concat dir ".nnmh-articles"))
 513          new articles)
 514     ;; Load the .nnmh-articles file.
 515     (when (file-exists-p nnmh-file)
 516       (setq articles
 517             (let (nnmh-newsgroup-articles)
 518               (ignore-errors (load nnmh-file nil t t))
 519               nnmh-newsgroup-articles)))
 520     ;; Add all new articles to the `new' list.
 521     (let ((art files))
 522       (while art
 523         (unless (assq (car art) articles)
 524           (push (car art) new))
 525         (setq art (cdr art))))
 526     ;; Remove all deleted articles.
 527     (let ((art articles))
 528       (while art
 529         (unless (memq (caar art) files)
 530           (setq articles (delq (car art) articles)))
 531         (setq art (cdr art))))
 532     ;; Check whether the articles really are the ones that Gnus thinks
 533     ;; they are by looking at the time-stamps.
 534     (let ((arts articles)
 535           art)
 536       (while (setq art (pop arts))
 537         (when (not (equal
 538                     (nth 5 (file-attributes
 539                             (concat dir (int-to-string (car art)))))
 540                     (cdr art)))
 541           (setq articles (delq art articles))
 542           (push (car art) new))))
 543     ;; Go through all the new articles and add them, and their
 544     ;; time-stamps, to the list.
 545     (setq articles
 546           (nconc articles
 547                  (mapcar
 548                   (lambda (art)
 549                     (cons art
 550                           (nth 5 (file-attributes
 551                                   (concat dir (int-to-string art))))))
 552                   new)))
 553     ;; Make Gnus mark all new articles as unread.
 554     (when new
 555       (gnus-make-articles-unread
 556        (gnus-group-prefixed-name group (list 'nnmh ""))
 557        (setq new (sort new '<))))
 558     ;; Sort the article list with highest numbers first.
 559     (setq articles (sort articles (lambda (art1 art2)
 560                                     (> (car art1) (car art2)))))
 561     ;; Finally write this list back to the .nnmh-articles file.
 562     (with-temp-file nnmh-file
 563       (insert ";; Gnus article active file for " group "\n\n")
 564       (insert "(setq nnmh-newsgroup-articles '")
 565       (gnus-prin1 articles)
 566       (insert ")\n"))))
 567
 568 (defun nnmh-deletable-article-p (group article)
 569   "Say whether ARTICLE in GROUP can be deleted."
 570   (let ((path (concat nnmh-current-directory (int-to-string article))))
 571     ;; Writable.
 572     (and (file-writable-p path)
 573          (or
 574           ;; We can never delete the last article in the group.
 575           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 576                    article))
 577           ;; Well, we can.
 578           nnmh-allow-delete-final))))
 579
 580 (provide 'nnmh)
 581
 582 ;;; nnmh.el ends here