cgit.sxemacs.org Git - gnus/blob - lisp/nnir.el

   1 ;;; nnir.el --- search mail with various search engines -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1998-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Kai Großjohann <grossjohann@ls6.cs.uni-dortmund.de>
   6 ;; Swish-e and Swish++ backends by:
   7 ;;   Christoph Conrad <christoph.conrad@gmx.de>.
   8 ;; IMAP backend by: Simon Josefsson <jas@pdc.kth.se>.
   9 ;; IMAP search by: Torsten Hilbrich <torsten.hilbrich <at> gmx.net>
  10 ;; IMAP search improved by Daniel Pittman  <daniel@rimspace.net>.
  11 ;; nnmaildir support for Swish++ and Namazu backends by:
  12 ;;   Justus Piater <Justus <at> Piater.name>
  13 ;; Keywords: news mail searching ir
  14
  15 ;; This file is part of GNU Emacs.
  16
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;; What does it do?  Well, it allows you to search your mail using
  33 ;; some search engine (imap, namazu, swish-e, gmane and others -- see
  34 ;; later) by typing `G G' in the Group buffer.  You will then get a
  35 ;; buffer which shows all articles matching the query, sorted by
  36 ;; Retrieval Status Value (score).
  37
  38 ;; When looking at the retrieval result (in the Summary buffer) you
  39 ;; can type `A W' (aka M-x gnus-warp-to-article RET) on an article.  You
  40 ;; will be warped into the group this article came from. Typing `A T'
  41 ;; (aka M-x gnus-summary-refer-thread RET) will warp to the group and
  42 ;; also show the thread this article is part of.
  43
  44 ;; The Lisp setup may involve setting a few variables and setting up the
  45 ;; search engine. You can define the variables in the server definition
  46 ;; like this :
  47 ;;   (setq gnus-secondary-select-methods '(
  48 ;;       (nnimap "" (nnimap-address "localhost")
  49 ;;                  (nnir-search-engine namazu)
  50 ;;       )))
  51 ;; The main variable to set is `nnir-search-engine'.  Choose one of
  52 ;; the engines listed in `nnir-engines'.  (Actually `nnir-engines' is
  53 ;; an alist, type `C-h v nnir-engines RET' for more information; this
  54 ;; includes examples for setting `nnir-search-engine', too.)
  55
  56 ;; If you use one of the local indices (namazu, find-grep, swish) you
  57 ;; must also set up a search engine backend.
  58
  59 ;; 1. Namazu
  60 ;;
  61 ;; The Namazu backend requires you to have one directory containing all
  62 ;; index files, this is controlled by the `nnir-namazu-index-directory'
  63 ;; variable.  To function the `nnir-namazu-remove-prefix' variable must
  64 ;; also be correct, see the documentation for `nnir-namazu-remove-prefix'
  65 ;; above.
  66 ;;
  67 ;; It is particularly important not to pass any any switches to namazu
  68 ;; that will change the output format.  Good switches to use include
  69 ;; `--sort', `--ascending', `--early' and `--late'.  Refer to the Namazu
  70 ;; documentation for further information on valid switches.
  71 ;;
  72 ;; To index my mail with the `mknmz' program I use the following
  73 ;; configuration file:
  74 ;;
  75 ;; ,----
  76 ;; | package conf;  # Don't remove this line!
  77 ;; |
  78 ;; | # Paths which will not be indexed. Don't use `^' or `$' anchors.
  79 ;; | $EXCLUDE_PATH = "spam|sent";
  80 ;; |
  81 ;; | # Header fields which should be searchable. case-insensitive
  82 ;; | $REMAIN_HEADER = "from|date|message-id|subject";
  83 ;; |
  84 ;; | # Searchable fields. case-insensitive
  85 ;; | $SEARCH_FIELD = "from|date|message-id|subject";
  86 ;; |
  87 ;; | # The max length of a word.
  88 ;; | $WORD_LENG_MAX = 128;
  89 ;; |
  90 ;; | # The max length of a field.
  91 ;; | $MAX_FIELD_LENGTH = 256;
  92 ;; `----
  93 ;;
  94 ;; My mail is stored in the directories ~/Mail/mail/, ~/Mail/lists/ and
  95 ;; ~/Mail/archive/, so to index them I go to the directory set in
  96 ;; `nnir-namazu-index-directory' and issue the following command.
  97 ;;
  98 ;;      mknmz --mailnews ~/Mail/archive/ ~/Mail/mail/ ~/Mail/lists/
  99 ;;
 100 ;; For maximum searching efficiency I have a cron job set to run this
 101 ;; command every four hours.
 102
 103 ;; 2. find-grep
 104 ;;
 105 ;; The find-grep engine simply runs find(1) to locate eligible
 106 ;; articles and searches them with grep(1).  This, of course, is much
 107 ;; slower than using a proper search engine but OTOH doesn't require
 108 ;; maintenance of an index and is still faster than using any built-in
 109 ;; means for searching.  The method specification of the server to
 110 ;; search must include a directory for this engine to work (E.g.,
 111 ;; `nnml-directory').  The tools must be POSIX compliant.  GNU Find
 112 ;; prior to version 4.2.12 (4.2.26 on Linux due to incorrect ARG_MAX
 113 ;; handling) does not work.
 114 ;; ,----
 115 ;; |    ;; find-grep configuration for searching the Gnus Cache
 116 ;; |
 117 ;; |    (nnml "cache"
 118 ;; |          (nnml-get-new-mail nil)
 119 ;; |          (nnir-search-engine find-grep)
 120 ;; |          (nnml-directory "~/News/cache/")
 121 ;; |          (nnml-active-file "~/News/cache/active"))
 122 ;; `----
 123
 124 ;; Developer information:
 125
 126 ;; I have tried to make the code expandable.  Basically, it is divided
 127 ;; into two layers.  The upper layer is somewhat like the `nnvirtual'
 128 ;; backend: given a specification of what articles to show from
 129 ;; another backend, it creates a group containing exactly those
 130 ;; articles.  The lower layer issues a query to a search engine and
 131 ;; produces such a specification of what articles to show from the
 132 ;; other backend.
 133
 134 ;; The interface between the two layers consists of the single
 135 ;; function `nnir-run-query', which dispatches the search to the
 136 ;; proper search function.  The argument of `nnir-run-query' is an
 137 ;; alist with two keys: 'nnir-query-spec and 'nnir-group-spec. The
 138 ;; value for 'nnir-query-spec is an alist. The only required key/value
 139 ;; pair is (query . "query") specifying the search string to pass to
 140 ;; the query engine. Individual engines may have other elements. The
 141 ;; value of 'nnir-group-spec is a list with the specification of the
 142 ;; groups/servers to search.  The format of the 'nnir-group-spec is
 143 ;; (("server1" ("group11" "group12")) ("server2" ("group21"
 144 ;; "group22"))). If any of the group lists is absent then all groups
 145 ;; on that server are searched.
 146
 147 ;; The output of `nnir-run-query' is supposed to be a vector, each
 148 ;; element of which should in turn be a three-element vector.  The
 149 ;; first element should be full group name of the article, the second
 150 ;; element should be the article number, and the third element should
 151 ;; be the Retrieval Status Value (RSV) as returned from the search
 152 ;; engine.  An RSV is the score assigned to the document by the search
 153 ;; engine.  For Boolean search engines, the RSV is always 1000 (or 1
 154 ;; or 100, or whatever you like).
 155
 156 ;; The sorting order of the articles in the summary buffer created by
 157 ;; nnir is based on the order of the articles in the above mentioned
 158 ;; vector, so that's where you can do the sorting you'd like.  Maybe
 159 ;; it would be nice to have a way of displaying the search result
 160 ;; sorted differently?
 161
 162 ;; So what do you need to do when you want to add another search
 163 ;; engine?  You write a function that executes the query.  Temporary
 164 ;; data from the search engine can be put in `nnir-tmp-buffer'.  This
 165 ;; function should return the list of articles as a vector, as
 166 ;; described above.  Then, you need to register this backend in
 167 ;; `nnir-engines'.  Then, users can choose the backend by setting
 168 ;; `nnir-search-engine' as a server variable.
 169
 170 ;;; Code:
 171
 172 ;;; Setup:
 173
 174 ;; For Emacs <22.2 and XEmacs.
 175 (eval-and-compile
 176   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
 177
 178 (require 'nnoo)
 179 (require 'gnus-group)
 180 (require 'message)
 181 (require 'gnus-util)
 182 (eval-when-compile
 183   (require 'cl))
 184
 185 ;;; Internal Variables:
 186
 187 (defvar nnir-memo-query nil
 188   "Internal: stores current query.")
 189
 190 (defvar nnir-memo-server nil
 191   "Internal: stores current server.")
 192
 193 (defvar nnir-artlist nil
 194   "Internal: stores search result.")
 195
 196 (defvar nnir-search-history ()
 197   "Internal: the history for querying search options in nnir")
 198
 199 (defconst nnir-tmp-buffer " *nnir*"
 200   "Internal: temporary buffer.")
 201
 202
 203 ;; Imap variables
 204
 205 (defvar nnir-imap-search-arguments
 206   '(("whole message" . "TEXT")
 207     ("subject" . "SUBJECT")
 208     ("to" . "TO")
 209     ("from" . "FROM")
 210     ("body" . "BODY")
 211     ("imap" . ""))
 212   "Mapping from user readable keys to IMAP search items for use in nnir")
 213
 214 (defvar nnir-imap-search-other "HEADER %S"
 215   "The IMAP search item to use for anything other than
 216   `nnir-imap-search-arguments'. By default this is the name of an
 217   email header field")
 218
 219 (defvar nnir-imap-search-argument-history ()
 220   "The history for querying search options in nnir")
 221
 222 ;;; Helper macros
 223
 224 ;; Data type article list.
 225
 226 (defmacro nnir-artlist-length (artlist)
 227   "Returns number of articles in artlist."
 228   `(length ,artlist))
 229
 230 (defmacro nnir-artlist-article (artlist n)
 231   "Returns from ARTLIST the Nth artitem (counting starting at 1)."
 232   `(when (> ,n 0)
 233      (elt ,artlist (1- ,n))))
 234
 235 (defmacro nnir-artitem-group (artitem)
 236   "Returns the group from the ARTITEM."
 237   `(elt ,artitem 0))
 238
 239 (defmacro nnir-artitem-number (artitem)
 240   "Returns the number from the ARTITEM."
 241   `(elt ,artitem 1))
 242
 243 (defmacro nnir-artitem-rsv (artitem)
 244   "Returns the Retrieval Status Value (RSV, score) from the ARTITEM."
 245   `(elt ,artitem 2))
 246
 247 (defmacro nnir-article-group (article)
 248   "Returns the group for ARTICLE"
 249   `(nnir-artitem-group (nnir-artlist-article nnir-artlist ,article)))
 250
 251 (defmacro nnir-article-number (article)
 252   "Returns the number for ARTICLE"
 253   `(nnir-artitem-number (nnir-artlist-article nnir-artlist ,article)))
 254
 255 (defmacro nnir-article-rsv (article)
 256   "Returns the rsv for ARTICLE"
 257   `(nnir-artitem-rsv (nnir-artlist-article nnir-artlist ,article)))
 258
 259 (defsubst nnir-article-ids (article)
 260   "Returns the pair `(nnir id . real id)' of ARTICLE"
 261   (cons article (nnir-article-number article)))
 262
 263 (defmacro nnir-categorize (sequence keyfunc &optional valuefunc)
 264   "Sorts a sequence into categories and returns a list of the form
 265 `((key1 (element11 element12)) (key2 (element21 element22))'.
 266 The category key for a member of the sequence is obtained
 267 as `(keyfunc member)' and the corresponding element is just
 268 `member'. If `valuefunc' is non-nil, the element of the list
 269 is `(valuefunc member)'."
 270   `(unless (null ,sequence)
 271      (let (value)
 272        (mapc
 273         (lambda (member)
 274           (let ((y (,keyfunc member))
 275                 (x ,(if valuefunc
 276                         `(,valuefunc member)
 277                       'member)))
 278             (if (assoc y value)
 279                 (push x (cadr (assoc y value)))
 280               (push (list y (list x)) value))))
 281         ,sequence)
 282        value)))
 283
 284 ;;; Finish setup:
 285
 286 (require 'gnus-sum)
 287
 288 (eval-when-compile
 289   (autoload 'nnimap-buffer "nnimap")
 290   (autoload 'nnimap-command "nnimap")
 291   (autoload 'nnimap-change-group "nnimap")
 292   (autoload 'nnimap-make-thread-query "nnimap")
 293   (autoload 'gnus-registry-action "gnus-registry")
 294   (autoload 'gnus-registry-get-id-key "gnus-registry")
 295   (autoload 'gnus-group-topic-name "gnus-topic"))
 296
 297
 298 (nnoo-declare nnir)
 299 (nnoo-define-basics nnir)
 300
 301 (gnus-declare-backend "nnir" 'mail 'virtual)
 302
 303
 304 ;;; User Customizable Variables:
 305
 306 (defgroup nnir nil
 307   "Search groups in Gnus with assorted search engines."
 308   :group 'gnus)
 309
 310 (defcustom nnir-ignored-newsgroups ""
 311   "*A regexp to match newsgroups in the active file that should
 312   be skipped when searching."
 313   :version "24.1"
 314   :type '(regexp)
 315   :group 'nnir)
 316
 317 (defcustom nnir-summary-line-format nil
 318   "*The format specification of the lines in an nnir summary buffer.
 319
 320 All the items from `gnus-summary-line-format' are available, along
 321 with three items unique to nnir summary buffers:
 322
 323 %Z    Search retrieval score value (integer)
 324 %G    Article original full group name (string)
 325 %g    Article original short group name (string)
 326
 327 If nil this will use `gnus-summary-line-format'."
 328   :version "24.1"
 329   :type '(choice (const :tag "gnus-summary-line-format" nil) string)
 330   :group 'nnir)
 331
 332 (defcustom nnir-retrieve-headers-override-function nil
 333   "*If non-nil, a function that accepts an article list and group
 334 and populates the `nntp-server-buffer' with the retrieved
 335 headers. Must return either 'nov or 'headers indicating the
 336 retrieved header format.
 337
 338 If this variable is nil, or if the provided function returns nil for a search
 339 result, `gnus-retrieve-headers' will be called instead."
 340   :version "24.1"
 341   :type '(choice (const :tag "gnus-retrieve-headers" nil) function)
 342   :group 'nnir)
 343
 344 (defcustom nnir-imap-default-search-key "whole message"
 345   "*The default IMAP search key for an nnir search. Must be one of
 346   the keys in `nnir-imap-search-arguments'. To use raw imap queries
 347   by default set this to \"imap\"."
 348   :version "24.1"
 349   :type `(choice ,@(mapcar (lambda (elem) (list 'const (car elem)))
 350                            nnir-imap-search-arguments))
 351   :group 'nnir)
 352
 353 (defcustom nnir-swish++-configuration-file
 354   (expand-file-name "~/Mail/swish++.conf")
 355   "*Configuration file for swish++."
 356   :type '(file)
 357   :group 'nnir)
 358
 359 (defcustom nnir-swish++-program "search"
 360   "*Name of swish++ search executable."
 361   :type '(string)
 362   :group 'nnir)
 363
 364 (defcustom nnir-swish++-additional-switches '()
 365   "*A list of strings, to be given as additional arguments to swish++.
 366
 367 Note that this should be a list.  Ie, do NOT use the following:
 368     (setq nnir-swish++-additional-switches \"-i -w\") ; wrong
 369 Instead, use this:
 370     (setq nnir-swish++-additional-switches '(\"-i\" \"-w\"))"
 371   :type '(repeat (string))
 372   :group 'nnir)
 373
 374 (defcustom nnir-swish++-remove-prefix (concat (getenv "HOME") "/Mail/")
 375   "*The prefix to remove from each file name returned by swish++
 376 in order to get a group name (albeit with / instead of .).  This is a
 377 regular expression.
 378
 379 This variable is very similar to `nnir-namazu-remove-prefix', except
 380 that it is for swish++, not Namazu."
 381   :type '(regexp)
 382   :group 'nnir)
 383
 384 ;; Swish-E.
 385 ;; URL: http://swish-e.org/
 386 ;; Variables `nnir-swish-e-index-file', `nnir-swish-e-program' and
 387 ;; `nnir-swish-e-additional-switches'
 388
 389 (make-obsolete-variable 'nnir-swish-e-index-file
 390                         'nnir-swish-e-index-files "Emacs 23.1")
 391 (defcustom nnir-swish-e-index-file
 392   (expand-file-name "~/Mail/index.swish-e")
 393   "*Index file for swish-e.
 394 This could be a server parameter.
 395 It is never consulted once `nnir-swish-e-index-files', which should be
 396 used instead, has been customized."
 397   :type '(file)
 398   :group 'nnir)
 399
 400 (defcustom nnir-swish-e-index-files
 401   (list nnir-swish-e-index-file)
 402   "*List of index files for swish-e.
 403 This could be a server parameter."
 404   :type '(repeat (file))
 405   :group 'nnir)
 406
 407 (defcustom nnir-swish-e-program "swish-e"
 408   "*Name of swish-e search executable.
 409 This cannot be a server parameter."
 410   :type '(string)
 411   :group 'nnir)
 412
 413 (defcustom nnir-swish-e-additional-switches '()
 414   "*A list of strings, to be given as additional arguments to swish-e.
 415
 416 Note that this should be a list.  Ie, do NOT use the following:
 417     (setq nnir-swish-e-additional-switches \"-i -w\") ; wrong
 418 Instead, use this:
 419     (setq nnir-swish-e-additional-switches '(\"-i\" \"-w\"))
 420
 421 This could be a server parameter."
 422   :type '(repeat (string))
 423   :group 'nnir)
 424
 425 (defcustom nnir-swish-e-remove-prefix (concat (getenv "HOME") "/Mail/")
 426   "*The prefix to remove from each file name returned by swish-e
 427 in order to get a group name (albeit with / instead of .).  This is a
 428 regular expression.
 429
 430 This variable is very similar to `nnir-namazu-remove-prefix', except
 431 that it is for swish-e, not Namazu.
 432
 433 This could be a server parameter."
 434   :type '(regexp)
 435   :group 'nnir)
 436
 437 ;; HyREX engine, see <URL:http://ls6-www.cs.uni-dortmund.de/>
 438
 439 (defcustom nnir-hyrex-program "nnir-search"
 440   "*Name of the nnir-search executable."
 441   :type '(string)
 442   :group 'nnir)
 443
 444 (defcustom nnir-hyrex-additional-switches '()
 445   "*A list of strings, to be given as additional arguments for nnir-search.
 446 Note that this should be a list. Ie, do NOT use the following:
 447     (setq nnir-hyrex-additional-switches \"-ddl ddl.xml -c nnir\") ; wrong !
 448 Instead, use this:
 449     (setq nnir-hyrex-additional-switches '(\"-ddl\" \"ddl.xml\" \"-c\" \"nnir\"))"
 450   :type '(repeat (string))
 451   :group 'nnir)
 452
 453 (defcustom nnir-hyrex-index-directory (getenv "HOME")
 454   "*Index directory for HyREX."
 455   :type '(directory)
 456   :group 'nnir)
 457
 458 (defcustom nnir-hyrex-remove-prefix (concat (getenv "HOME") "/Mail/")
 459   "*The prefix to remove from each file name returned by HyREX
 460 in order to get a group name (albeit with / instead of .).
 461
 462 For example, suppose that HyREX returns file names such as
 463 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 464 setting:  (setq nnir-hyrex-remove-prefix \"/home/john/Mail/\")
 465 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 466 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 467 arrive at the correct group name, \"mail.misc\"."
 468   :type '(directory)
 469   :group 'nnir)
 470
 471 ;; Namazu engine, see <URL:http://www.namazu.org/>
 472
 473 (defcustom nnir-namazu-program "namazu"
 474   "*Name of Namazu search executable."
 475   :type '(string)
 476   :group 'nnir)
 477
 478 (defcustom nnir-namazu-index-directory (expand-file-name "~/Mail/namazu/")
 479   "*Index directory for Namazu."
 480   :type '(directory)
 481   :group 'nnir)
 482
 483 (defcustom nnir-namazu-additional-switches '()
 484   "*A list of strings, to be given as additional arguments to namazu.
 485 The switches `-q', `-a', and `-s' are always used, very few other switches
 486 make any sense in this context.
 487
 488 Note that this should be a list.  Ie, do NOT use the following:
 489     (setq nnir-namazu-additional-switches \"-i -w\") ; wrong
 490 Instead, use this:
 491     (setq nnir-namazu-additional-switches '(\"-i\" \"-w\"))"
 492   :type '(repeat (string))
 493   :group 'nnir)
 494
 495 (defcustom nnir-namazu-remove-prefix (concat (getenv "HOME") "/Mail/")
 496   "*The prefix to remove from each file name returned by Namazu
 497 in order to get a group name (albeit with / instead of .).
 498
 499 For example, suppose that Namazu returns file names such as
 500 \"/home/john/Mail/mail/misc/42\".  For this example, use the following
 501 setting:  (setq nnir-namazu-remove-prefix \"/home/john/Mail/\")
 502 Note the trailing slash.  Removing this prefix gives \"mail/misc/42\".
 503 `nnir' knows to remove the \"/42\" and to replace \"/\" with \".\" to
 504 arrive at the correct group name, \"mail.misc\"."
 505   :type '(directory)
 506   :group 'nnir)
 507
 508 (defcustom nnir-notmuch-program "notmuch"
 509   "*Name of notmuch search executable."
 510   :version "24.1"
 511   :type '(string)
 512   :group 'nnir)
 513
 514 (defcustom nnir-notmuch-additional-switches '()
 515   "*A list of strings, to be given as additional arguments to notmuch.
 516
 517 Note that this should be a list.  Ie, do NOT use the following:
 518     (setq nnir-notmuch-additional-switches \"-i -w\") ; wrong
 519 Instead, use this:
 520     (setq nnir-notmuch-additional-switches '(\"-i\" \"-w\"))"
 521   :version "24.1"
 522   :type '(repeat (string))
 523   :group 'nnir)
 524
 525 (defcustom nnir-notmuch-remove-prefix (concat (getenv "HOME") "/Mail/")
 526   "*The prefix to remove from each file name returned by notmuch
 527 in order to get a group name (albeit with / instead of .).  This is a
 528 regular expression.
 529
 530 This variable is very similar to `nnir-namazu-remove-prefix', except
 531 that it is for notmuch, not Namazu."
 532   :version "24.1"
 533   :type '(regexp)
 534   :group 'nnir)
 535
 536 ;;; Developer Extension Variable:
 537
 538 (defvar nnir-engines
 539   `((imap    nnir-run-imap
 540              ((criteria
 541                "Imap Search in"                   ; Prompt
 542                ,(mapcar 'car nnir-imap-search-arguments) ; alist for completing
 543                nil                                ; allow any user input
 544                nil                                ; initial value
 545                nnir-imap-search-argument-history  ; the history to use
 546                ,nnir-imap-default-search-key      ; default
 547                )))
 548     (gmane   nnir-run-gmane
 549              ((gmane-author . "Gmane Author: ")))
 550     (swish++ nnir-run-swish++
 551              ((swish++-group . "Swish++ Group spec (regexp): ")))
 552     (swish-e nnir-run-swish-e
 553              ((swish-e-group . "Swish-e Group spec (regexp): ")))
 554     (namazu  nnir-run-namazu
 555              ())
 556     (notmuch nnir-run-notmuch
 557              ())
 558     (hyrex   nnir-run-hyrex
 559              ((hyrex-group . "Hyrex Group spec (regexp): ")))
 560     (find-grep nnir-run-find-grep
 561                ((grep-options . "Grep options: "))))
 562   "Alist of supported search engines.
 563 Each element in the alist is a three-element list (ENGINE FUNCTION ARGS).
 564 ENGINE is a symbol designating the searching engine.  FUNCTION is also
 565 a symbol, giving the function that does the search.  The third element
 566 ARGS is a list of cons pairs (PARAM . PROMPT).  When issuing a query,
 567 the FUNCTION will issue a query for each of the PARAMs, using PROMPT.
 568
 569 The value of `nnir-search-engine' must be one of the ENGINE symbols.
 570 For example, for searching a server using namazu include
 571     (nnir-search-engine namazu)
 572 in the server definition.  Note that you have to set additional
 573 variables for most backends.  For example, the `namazu' backend
 574 needs the variables `nnir-namazu-program',
 575 `nnir-namazu-index-directory' and `nnir-namazu-remove-prefix'.
 576
 577 Add an entry here when adding a new search engine.")
 578
 579 (defcustom nnir-method-default-engines  '((nnimap . imap) (nntp . gmane))
 580   "*Alist of default search engines keyed by server method."
 581   :version "24.1"
 582   :group 'nnir
 583   :type `(repeat (cons (choice (const nnimap) (const nntp) (const nnspool)
 584                                (const nneething) (const nndir) (const nnmbox)
 585                                (const nnml) (const nnmh) (const nndraft)
 586                                (const nnfolder) (const nnmaildir))
 587                        (choice
 588                         ,@(mapcar (lambda (elem) (list 'const (car elem)))
 589                                   nnir-engines)))))
 590
 591 ;; Gnus glue.
 592
 593 (defun gnus-group-make-nnir-group (nnir-extra-parms &optional specs)
 594   "Create an nnir group.  Prompt for a search query and determine
 595 the groups to search as follows: if called from the *Server*
 596 buffer search all groups belonging to the server on the current
 597 line; if called from the *Group* buffer search any marked groups,
 598 or the group on the current line, or all the groups under the
 599 current topic. Calling with a prefix-arg prompts for additional
 600 search-engine specific constraints. A non-nil `specs' arg must be
 601 an alist with `nnir-query-spec' and `nnir-group-spec' keys, and
 602 skips all prompting."
 603   (interactive "P")
 604   (let* ((group-spec
 605           (or (cdr (assq 'nnir-group-spec specs))
 606             (if (gnus-server-server-name)
 607                 (list (list (gnus-server-server-name)))
 608               (nnir-categorize
 609                (or gnus-group-marked
 610                    (if (gnus-group-group-name)
 611                        (list (gnus-group-group-name))
 612                      (cdr (assoc (gnus-group-topic-name) gnus-topic-alist))))
 613                gnus-group-server))))
 614          (query-spec
 615           (or (cdr (assq 'nnir-query-spec specs))
 616             (apply
 617              'append
 618              (list (cons 'query
 619                          (read-string "Query: " nil 'nnir-search-history)))
 620              (when nnir-extra-parms
 621                (mapcar
 622                 (lambda (x)
 623                   (nnir-read-parms (nnir-server-to-search-engine (car x))))
 624                 group-spec))))))
 625     (gnus-group-read-ephemeral-group
 626      (concat "nnir-" (message-unique-id))
 627      (list 'nnir "nnir")
 628      nil
 629 ;     (cons (current-buffer) gnus-current-window-configuration)
 630      nil
 631      nil nil
 632      (list
 633       (cons 'nnir-specs (list (cons 'nnir-query-spec query-spec)
 634                               (cons 'nnir-group-spec group-spec)))
 635       (cons 'nnir-artlist nil)))))
 636
 637 (defun gnus-summary-make-nnir-group (nnir-extra-parms)
 638   "Search a group from the summary buffer."
 639   (interactive "P")
 640   (gnus-warp-to-article)
 641   (let ((spec
 642          (list
 643           (cons 'nnir-group-spec
 644                 (list (list
 645                        (gnus-group-server gnus-newsgroup-name)
 646                        (list gnus-newsgroup-name)))))))
 647     (gnus-group-make-nnir-group nnir-extra-parms spec)))
 648
 649
 650 ;; Gnus backend interface functions.
 651
 652 (deffoo nnir-open-server (server &optional definitions)
 653   ;; Just set the server variables appropriately.
 654   (let ((backend (car (gnus-server-to-method server))))
 655     (if backend
 656         (nnoo-change-server backend server definitions)
 657       (add-hook 'gnus-summary-mode-hook 'nnir-mode)
 658       (nnoo-change-server 'nnir server definitions))))
 659
 660 (deffoo nnir-request-group (group &optional server dont-check info)
 661   (nnir-possibly-change-group group server)
 662   (let ((pgroup (gnus-group-guess-full-name-from-command-method group))
 663         length)
 664     ;; Check for cached search result or run the query and cache the
 665     ;; result.
 666     (unless (and nnir-artlist dont-check)
 667       (gnus-group-set-parameter
 668        pgroup 'nnir-artlist
 669        (setq nnir-artlist
 670              (nnir-run-query
 671               (gnus-group-get-parameter pgroup 'nnir-specs t))))
 672       (nnir-request-update-info pgroup (gnus-get-info pgroup)))
 673     (with-current-buffer nntp-server-buffer
 674       (if (zerop (setq length (nnir-artlist-length nnir-artlist)))
 675           (progn
 676             (nnir-close-group group)
 677             (nnheader-report 'nnir "Search produced empty results."))
 678         (nnheader-insert "211 %d %d %d %s\n"
 679                          length    ; total #
 680                          1         ; first #
 681                          length    ; last #
 682                          group)))) ; group name
 683   nnir-artlist)
 684
 685 (deffoo nnir-retrieve-headers (articles &optional group server fetch-old)
 686   (with-current-buffer nntp-server-buffer
 687     (let ((gnus-inhibit-demon t)
 688           (articles-by-group (nnir-categorize
 689                               articles nnir-article-group nnir-article-ids))
 690           headers)
 691       (while (not (null articles-by-group))
 692         (let* ((group-articles (pop articles-by-group))
 693                (artgroup (car group-articles))
 694                (articleids (cadr group-articles))
 695                (artlist (sort (mapcar 'cdr articleids) '<))
 696                (server (gnus-group-server artgroup))
 697                (gnus-override-method (gnus-server-to-method server))
 698                parsefunc)
 699           ;; (nnir-possibly-change-group nil server)
 700           (erase-buffer)
 701           (case (setq gnus-headers-retrieved-by
 702                       (or
 703                        (and
 704                         nnir-retrieve-headers-override-function
 705                         (funcall nnir-retrieve-headers-override-function
 706                                  artlist artgroup))
 707                        (gnus-retrieve-headers artlist artgroup nil)))
 708             (nov
 709              (setq parsefunc 'nnheader-parse-nov))
 710             (headers
 711              (setq parsefunc 'nnheader-parse-head))
 712             (t (error "Unknown header type %s while requesting articles \
 713                     of group %s" gnus-headers-retrieved-by artgroup)))
 714           (goto-char (point-min))
 715           (while (not (eobp))
 716             (let* ((novitem (funcall parsefunc))
 717                    (artno (and novitem
 718                                (mail-header-number novitem)))
 719                    (art (car (rassq artno articleids))))
 720               (when art
 721                 (mail-header-set-number novitem art)
 722                 (push novitem headers))
 723               (forward-line 1)))))
 724       (setq headers
 725             (sort headers
 726                   (lambda (x y)
 727                     (< (mail-header-number x) (mail-header-number y)))))
 728       (erase-buffer)
 729       (mapc 'nnheader-insert-nov headers)
 730       'nov)))
 731
 732 (deffoo nnir-request-article (article &optional group server to-buffer)
 733   (nnir-possibly-change-group group server)
 734   (if (and (stringp article)
 735            (not (eq 'nnimap (car (gnus-server-to-method server)))))
 736       (nnheader-report
 737        'nnir
 738        "nnir-request-article only groks message ids for nnimap servers: %s"
 739        server)
 740     (save-excursion
 741       (let ((article article)
 742             query)
 743         (when (stringp article)
 744           (setq gnus-override-method (gnus-server-to-method server))
 745           (setq query
 746                 (list
 747                  (cons 'query (format "HEADER Message-ID %s" article))
 748                  (cons 'criteria "")
 749                  (cons 'shortcut t)))
 750           (unless (and nnir-artlist (equal query nnir-memo-query)
 751                        (equal server nnir-memo-server))
 752             (setq nnir-artlist (nnir-run-imap query server)
 753                   nnir-memo-query query
 754                   nnir-memo-server server))
 755           (setq article 1))
 756         (unless (zerop (nnir-artlist-length nnir-artlist))
 757           (let ((artfullgroup (nnir-article-group article))
 758                 (artno (nnir-article-number article)))
 759             (message "Requesting article %d from group %s"
 760                      artno artfullgroup)
 761             (if to-buffer
 762                 (with-current-buffer to-buffer
 763                   (let ((gnus-article-decode-hook nil))
 764                     (gnus-request-article-this-buffer artno artfullgroup)))
 765               (gnus-request-article artno artfullgroup))
 766             (cons artfullgroup artno)))))))
 767
 768 (deffoo nnir-request-move-article (article group server accept-form
 769                                            &optional last internal-move-group)
 770   (nnir-possibly-change-group group server)
 771   (let* ((artfullgroup (nnir-article-group article))
 772          (artno (nnir-article-number article))
 773          (to-newsgroup (nth 1 accept-form))
 774          (to-method (gnus-find-method-for-group to-newsgroup))
 775          (from-method (gnus-find-method-for-group artfullgroup))
 776          (move-is-internal (gnus-server-equal from-method to-method)))
 777     (unless (gnus-check-backend-function
 778              'request-move-article artfullgroup)
 779       (error "The group %s does not support article moving" artfullgroup))
 780     (gnus-request-move-article
 781      artno
 782      artfullgroup
 783      (nth 1 from-method)
 784      accept-form
 785      last
 786      (and move-is-internal
 787           to-newsgroup          ; Not respooling
 788           (gnus-group-real-name to-newsgroup)))))
 789
 790 (deffoo nnir-request-expire-articles (articles group &optional server force)
 791   (nnir-possibly-change-group group server)
 792   (if force
 793     (let ((articles-by-group (nnir-categorize
 794                               articles nnir-article-group nnir-article-ids))
 795           not-deleted)
 796       (while (not (null articles-by-group))
 797         (let* ((group-articles (pop articles-by-group))
 798                (artgroup (car group-articles))
 799                (articleids (cadr group-articles))
 800                (artlist (sort (mapcar 'cdr articleids) '<)))
 801           (unless (gnus-check-backend-function 'request-expire-articles
 802                                                artgroup)
 803             (error "The group %s does not support article deletion" artgroup))
 804           (unless (gnus-check-server (gnus-find-method-for-group artgroup))
 805             (error "Couldn't open server for group %s" artgroup))
 806           (push (gnus-request-expire-articles
 807                  artlist artgroup force)
 808                 not-deleted)))
 809       (sort (delq nil not-deleted) '<))
 810     articles))
 811
 812 (deffoo nnir-warp-to-article ()
 813   (nnir-possibly-change-group gnus-newsgroup-name)
 814   (let* ((cur (if (> (gnus-summary-article-number) 0)
 815                   (gnus-summary-article-number)
 816                 (error "Can't warp to a pseudo-article")))
 817          (backend-article-group (nnir-article-group cur))
 818          (backend-article-number (nnir-article-number cur))
 819          (quit-config (gnus-ephemeral-group-p gnus-newsgroup-name)))
 820
 821     ;; what should we do here? we could leave all the buffers around
 822     ;; and assume that we have to exit from them one by one. or we can
 823     ;; try to clean up directly
 824
 825     ;;first exit from the nnir summary buffer.
 826 ;    (gnus-summary-exit)
 827     ;; and if the nnir summary buffer in turn came from another
 828     ;; summary buffer we have to clean that summary up too.
 829  ;   (when (not (eq (cdr quit-config) 'group))
 830 ;      (gnus-summary-exit))
 831     (gnus-summary-read-group-1 backend-article-group t t  nil
 832                                nil (list backend-article-number))))
 833
 834 (deffoo nnir-request-update-mark (group article mark)
 835   (let ((artgroup (nnir-article-group article))
 836         (artnumber (nnir-article-number article)))
 837     (gnus-request-update-mark artgroup artnumber mark)))
 838
 839 (deffoo nnir-request-set-mark (group actions &optional server)
 840   (nnir-possibly-change-group group server)
 841   (let (mlist)
 842     (dolist (action actions)
 843       (destructuring-bind (range action marks) action
 844         (let ((articles-by-group (nnir-categorize
 845                                   (gnus-uncompress-range range)
 846                                   nnir-article-group nnir-article-number)))
 847           (dolist (artgroup articles-by-group)
 848             (push (list
 849                    (car artgroup)
 850                    (list (gnus-compress-sequence
 851                           (sort (cadr artgroup) '<)) action marks)) mlist)))))
 852     (dolist (request (nnir-categorize  mlist car cadr))
 853       (gnus-request-set-mark (car request) (cadr request)))))
 854
 855
 856 (deffoo nnir-request-update-info (group info &optional server)
 857   (nnir-possibly-change-group group server)
 858   ;; clear out all existing marks.
 859   (gnus-info-set-marks info nil)
 860   (gnus-info-set-read info nil)
 861   (let ((group (gnus-group-guess-full-name-from-command-method group))
 862         (articles-by-group
 863          (nnir-categorize
 864           (gnus-uncompress-range (cons 1 (nnir-artlist-length nnir-artlist)))
 865           nnir-article-group nnir-article-ids)))
 866     (gnus-set-active group
 867                      (cons 1 (nnir-artlist-length nnir-artlist)))
 868     (while (not (null articles-by-group))
 869       (let* ((group-articles (pop articles-by-group))
 870              (articleids (reverse (cadr group-articles)))
 871              (group-info (gnus-get-info (car group-articles)))
 872              (marks (gnus-info-marks group-info))
 873              (read (gnus-info-read group-info)))
 874         (gnus-info-set-read
 875          info
 876          (gnus-add-to-range
 877           (gnus-info-read info)
 878           (delq nil
 879                   (mapcar
 880                    #'(lambda (art)
 881                      (when (gnus-member-of-range (cdr art) read) (car art)))
 882                    articleids))))
 883         (dolist (mark marks)
 884           (destructuring-bind (type . range) mark
 885             (gnus-add-marked-articles
 886              group type
 887              (delq nil
 888                      (mapcar
 889                       #'(lambda (art)
 890                         (when (gnus-member-of-range (cdr art) range) (car art)))
 891                       articleids)))))))))
 892
 893
 894 (deffoo nnir-close-group (group &optional server)
 895   (nnir-possibly-change-group group server)
 896   (let ((pgroup (gnus-group-guess-full-name-from-command-method group)))
 897     (when (and nnir-artlist (not (gnus-ephemeral-group-p pgroup)))
 898       (gnus-group-set-parameter  pgroup 'nnir-artlist nnir-artlist))
 899     (setq nnir-artlist nil)
 900     (when (gnus-ephemeral-group-p pgroup)
 901       (gnus-kill-ephemeral-group pgroup)
 902       (setq gnus-ephemeral-servers
 903             (delq (assq 'nnir gnus-ephemeral-servers)
 904                   gnus-ephemeral-servers)))))
 905 ;; (gnus-opened-servers-remove
 906 ;;  (car (assoc  '(nnir "nnir-ephemeral" (nnir-address "nnir"))
 907 ;;              gnus-opened-servers))))
 908
 909
 910
 911
 912 (defmacro nnir-add-result (dirnam artno score prefix server artlist)
 913   "Ask `nnir-compose-result' to construct a result vector,
 914 and if it is non-nil, add it to artlist."
 915   `(let ((result (nnir-compose-result ,dirnam ,artno ,score ,prefix ,server)))
 916      (when (not (null result))
 917        (push result ,artlist))))
 918
 919 (autoload 'nnmaildir-base-name-to-article-number "nnmaildir")
 920
 921 ;; Helper function currently used by the Swish++ and Namazu backends;
 922 ;; perhaps useful for other backends as well
 923 (defun nnir-compose-result (dirnam article score prefix server)
 924   "Extract the group from dirnam, and create a result vector
 925 ready to be added to the list of search results."
 926
 927   ;; remove nnir-*-remove-prefix from beginning of dirnam filename
 928   (when (string-match (concat "^" prefix) dirnam)
 929     (setq dirnam (replace-match "" t t dirnam)))
 930
 931   (when (file-readable-p (concat prefix dirnam article))
 932     ;; remove trailing slash and, for nnmaildir, cur/new/tmp
 933     (setq dirnam
 934           (substring dirnam 0
 935                      (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 936                          -5 -1)))
 937
 938     ;; Set group to dirnam without any leading dots or slashes,
 939     ;; and with all subsequent slashes replaced by dots
 940     (let ((group (gnus-replace-in-string
 941                  (gnus-replace-in-string dirnam "^[./\\]" "" t)
 942                  "[/\\]" "." t)))
 943
 944     (vector (gnus-group-full-name group server)
 945             (if (string-match "\\`nnmaildir:" (gnus-group-server server))
 946                 (nnmaildir-base-name-to-article-number
 947                  (substring article 0 (string-match ":" article))
 948                  group nil)
 949               (string-to-number article))
 950             (string-to-number score)))))
 951
 952 ;;; Search Engine Interfaces:
 953
 954 ;; imap interface
 955 (defun nnir-run-imap (query srv &optional groups)
 956   "Run a search against an IMAP back-end server.
 957 This uses a custom query language parser; see `nnir-imap-make-query' for
 958 details on the language and supported extensions."
 959   (save-excursion
 960     (let ((qstring (cdr (assq 'query query)))
 961           (server (cadr (gnus-server-to-method srv)))
 962           (defs (caddr (gnus-server-to-method srv)))
 963           (criteria (or (cdr (assq 'criteria query))
 964                         (cdr (assoc nnir-imap-default-search-key
 965                                     nnir-imap-search-arguments))))
 966           (gnus-inhibit-demon t)
 967           (groups (or groups (nnir-get-active srv))))
 968       (message "Opening server %s" server)
 969       (apply
 970        'vconcat
 971        (catch 'found
 972          (mapcar
 973           #'(lambda (group)
 974             (let (artlist)
 975               (condition-case ()
 976                   (when (nnimap-change-group
 977                          (gnus-group-short-name group) server)
 978                     (with-current-buffer (nnimap-buffer)
 979                       (message "Searching %s..." group)
 980                       (let ((arts 0)
 981                             (result (nnimap-command "UID SEARCH %s"
 982                                                     (if (string= criteria "")
 983                                                         qstring
 984                                                       (nnir-imap-make-query
 985                                                        criteria qstring)))))
 986                         (mapc
 987                          (lambda (artnum)
 988                            (let ((artn (string-to-number artnum)))
 989                              (when (> artn 0)
 990                                (push (vector group artn 100)
 991                                      artlist)
 992                                (when (assq 'shortcut query)
 993                                  (throw 'found (list artlist)))
 994                                (setq arts (1+ arts)))))
 995                          (and (car result)
 996                               (cdr (assoc "SEARCH" (cdr result)))))
 997                         (message "Searching %s... %d matches" group arts)))
 998                     (message "Searching %s...done" group))
 999                 (quit nil))
1000               (nreverse artlist)))
1001           groups))))))
1002
1003 (defun nnir-imap-make-query (criteria qstring)
1004   "Parse the query string and criteria into an appropriate IMAP search
1005 expression, returning the string query to make.
1006
1007 This implements a little language designed to return the expected results
1008 to an arbitrary query string to the end user.
1009
1010 The search is always case-insensitive, as defined by RFC2060, and supports
1011 the following features (inspired by the Google search input language):
1012
1013 Automatic \"and\" queries
1014     If you specify multiple words then they will be treated as an \"and\"
1015     expression intended to match all components.
1016
1017 Phrase searches
1018     If you wrap your query in double-quotes then it will be treated as a
1019     literal string.
1020
1021 Negative terms
1022     If you precede a term with \"-\" then it will negate that.
1023
1024 \"OR\" queries
1025     If you include an upper-case \"OR\" in your search it will cause the
1026     term before it and the term after it to be treated as alternatives.
1027
1028 In future the following will be added to the language:
1029  * support for date matches
1030  * support for location of text matching within the query
1031  * from/to/etc headers
1032  * additional search terms
1033  * flag based searching
1034  * anything else that the RFC supports, basically."
1035   ;; Walk through the query and turn it into an IMAP query string.
1036   (nnir-imap-query-to-imap criteria (nnir-imap-parse-query qstring)))
1037
1038
1039 (defun nnir-imap-query-to-imap (criteria query)
1040   "Turn a s-expression format query into IMAP."
1041   (mapconcat
1042    ;; Turn the expressions into IMAP text
1043    (lambda (item)
1044      (nnir-imap-expr-to-imap criteria item))
1045    ;; The query, already in s-expr format.
1046    query
1047    ;; Append a space between each expression
1048    " "))
1049
1050
1051 (defun nnir-imap-expr-to-imap (criteria expr)
1052   "Convert EXPR into an IMAP search expression on CRITERIA"
1053   ;; What sort of expression is this, eh?
1054   (cond
1055    ;; Simple string term
1056    ((stringp expr)
1057     (format "%s %S" criteria expr))
1058    ;; Trivial term: and
1059    ((eq expr 'and) nil)
1060    ;; Composite term: or expression
1061    ((eq (car-safe expr) 'or)
1062     (format "OR %s %s"
1063             (nnir-imap-expr-to-imap criteria (second expr))
1064             (nnir-imap-expr-to-imap criteria (third expr))))
1065    ;; Composite term: just the fax, mam
1066    ((eq (car-safe expr) 'not)
1067     (format "NOT (%s)" (nnir-imap-query-to-imap criteria (rest expr))))
1068    ;; Composite term: just expand it all.
1069    ((and (not (null expr)) (listp expr))
1070     (format "(%s)" (nnir-imap-query-to-imap criteria expr)))
1071    ;; Complex value, give up for now.
1072    (t (error "Unhandled input: %S" expr))))
1073
1074
1075 (defun nnir-imap-parse-query (string)
1076   "Turn STRING into an s-expression based query based on the IMAP
1077 query language as defined in `nnir-imap-make-query'.
1078
1079 This involves turning individual tokens into higher level terms
1080 that the search language can then understand and use."
1081   (with-temp-buffer
1082     ;; Set up the parsing environment.
1083     (insert string)
1084     (goto-char (point-min))
1085     ;; Now, collect the output terms and return them.
1086     (let (out)
1087       (while (not (nnir-imap-end-of-input))
1088         (push (nnir-imap-next-expr) out))
1089       (reverse out))))
1090
1091
1092 (defun nnir-imap-next-expr (&optional count)
1093   "Return the next expression from the current buffer."
1094   (let ((term (nnir-imap-next-term count))
1095         (next (nnir-imap-peek-symbol)))
1096     ;; Are we looking at an 'or' expression?
1097     (cond
1098      ;; Handle 'expr or expr'
1099      ((eq next 'or)
1100       (list 'or term (nnir-imap-next-expr 2)))
1101      ;; Anything else
1102      (t term))))
1103
1104
1105 (defun nnir-imap-next-term (&optional count)
1106   "Return the next TERM from the current buffer."
1107   (let ((term (nnir-imap-next-symbol count)))
1108     ;; What sort of term is this?
1109     (cond
1110      ;; and -- just ignore it
1111      ((eq term 'and) 'and)
1112      ;; negated term
1113      ((eq term 'not) (list 'not (nnir-imap-next-expr)))
1114      ;; generic term
1115      (t term))))
1116
1117
1118 (defun nnir-imap-peek-symbol ()
1119   "Return the next symbol from the current buffer, but don't consume it."
1120   (save-excursion
1121     (nnir-imap-next-symbol)))
1122
1123 (defun nnir-imap-next-symbol (&optional count)
1124   "Return the next symbol from the current buffer, or nil if we are
1125 at the end of the buffer.  If supplied COUNT skips some symbols before
1126 returning the one at the supplied position."
1127   (when (and (numberp count) (> count 1))
1128     (nnir-imap-next-symbol (1- count)))
1129   (let ((case-fold-search t))
1130     ;; end of input stream?
1131     (unless (nnir-imap-end-of-input)
1132       ;; No, return the next symbol from the stream.
1133       (cond
1134        ;; negated expression -- return it and advance one char.
1135        ((looking-at "-") (forward-char 1) 'not)
1136        ;; quoted string
1137        ((looking-at "\"") (nnir-imap-delimited-string "\""))
1138        ;; list expression -- we parse the content and return this as a list.
1139        ((looking-at "(")
1140         (nnir-imap-parse-query (nnir-imap-delimited-string ")")))
1141        ;; keyword input -- return a symbol version
1142        ((looking-at "\\band\\b") (forward-char 3) 'and)
1143        ((looking-at "\\bor\\b")  (forward-char 2) 'or)
1144        ((looking-at "\\bnot\\b") (forward-char 3) 'not)
1145        ;; Simple, boring keyword
1146        (t (let ((start (point))
1147                 (end (if (search-forward-regexp "[[:blank:]]" nil t)
1148                          (prog1
1149                              (match-beginning 0)
1150                            ;; unskip if we hit a non-blank terminal character.
1151                            (when (string-match "[^[:blank:]]" (match-string 0))
1152                              (backward-char 1)))
1153                        (goto-char (point-max)))))
1154             (buffer-substring start end)))))))
1155
1156 (defun nnir-imap-delimited-string (delimiter)
1157   "Return a delimited string from the current buffer."
1158   (let ((start (point)) end)
1159     (forward-char 1)                    ; skip the first delimiter.
1160     (while (not end)
1161       (unless (search-forward delimiter nil t)
1162         (error "Unmatched delimited input with %s in query" delimiter))
1163       (let ((here (point)))
1164         (unless (equal (buffer-substring (- here 2) (- here 1)) "\\")
1165           (setq end (point)))))
1166     (buffer-substring (1+ start) (1- end))))
1167
1168 (defun nnir-imap-end-of-input ()
1169   "Are we at the end of input?"
1170   (skip-chars-forward "[[:blank:]]")
1171   (looking-at "$"))
1172
1173
1174 ;; Swish++ interface.
1175 ;; -cc- Todo
1176 ;; Search by
1177 ;; - group
1178 ;; Sort by
1179 ;; - rank (default)
1180 ;; - article number
1181 ;; - file size
1182 ;; - group
1183 (defun nnir-run-swish++ (query server &optional group)
1184   "Run QUERY against swish++.
1185 Returns a vector of (group name, file name) pairs (also vectors,
1186 actually).
1187
1188 Tested with swish++ 4.7 on GNU/Linux and with swish++ 5.0b2 on
1189 Windows NT 4.0."
1190
1191   ;; (when group
1192   ;;   (error "The swish++ backend cannot search specific groups"))
1193
1194   (save-excursion
1195     (let ( (qstring (cdr (assq 'query query)))
1196            (groupspec (cdr (assq 'swish++-group query)))
1197            (prefix (nnir-read-server-parm 'nnir-swish++-remove-prefix server))
1198            artlist
1199            ;; nnml-use-compressed-files might be any string, but probably this
1200            ;; is sufficient.  Note that we can't only use the value of
1201            ;; nnml-use-compressed-files because old articles might have been
1202            ;; saved with a different value.
1203            (article-pattern (if (string-match "\\`nnmaildir:"
1204                                               (gnus-group-server server))
1205                                 ":[0-9]+"
1206                               "^[0-9]+\\(\\.[a-z0-9]+\\)?$"))
1207            score artno dirnam filenam)
1208
1209       (when (equal "" qstring)
1210         (error "swish++: You didn't enter anything"))
1211
1212       (set-buffer (get-buffer-create nnir-tmp-buffer))
1213       (erase-buffer)
1214
1215       (if groupspec
1216           (message "Doing swish++ query %s on %s..." qstring groupspec)
1217         (message "Doing swish++ query %s..." qstring))
1218
1219       (let* ((cp-list `( ,nnir-swish++-program
1220                          nil            ; input from /dev/null
1221                          t              ; output
1222                          nil            ; don't redisplay
1223                          "--config-file" ,(nnir-read-server-parm 'nnir-swish++-configuration-file server)
1224                          ,@(nnir-read-server-parm 'nnir-swish++-additional-switches server)
1225                          ,qstring       ; the query, in swish++ format
1226                          ))
1227              (exitstatus
1228               (progn
1229                 (message "%s args: %s" nnir-swish++-program
1230                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1231                 (apply 'call-process cp-list))))
1232         (unless (or (null exitstatus)
1233                     (zerop exitstatus))
1234           (nnheader-report 'nnir "Couldn't run swish++: %s" exitstatus)
1235           ;; swish++ failure reason is in this buffer, show it if
1236           ;; the user wants it.
1237           (when (> gnus-verbose 6)
1238             (display-buffer nnir-tmp-buffer))))
1239
1240       ;; The results are output in the format of:
1241       ;; V 4.7 Linux
1242       ;; rank relative-path-name file-size file-title
1243       ;; V 5.0b2:
1244       ;; rank relative-path-name file-size topic??
1245       ;; where rank is an integer from 1 to 100.
1246       (goto-char (point-min))
1247       (while (re-search-forward
1248               "\\(^[0-9]+\\) \\([^ ]+\\) [0-9]+ \\(.*\\)$" nil t)
1249         (setq score (match-string 1)
1250               filenam (match-string 2)
1251               artno (file-name-nondirectory filenam)
1252               dirnam (file-name-directory filenam))
1253
1254         ;; don't match directories
1255         (when (string-match article-pattern artno)
1256           (when (not (null dirnam))
1257
1258             ;; maybe limit results to matching groups.
1259             (when (or (not groupspec)
1260                       (string-match groupspec dirnam))
1261               (nnir-add-result dirnam artno score prefix server artlist)))))
1262
1263       (message "Massaging swish++ output...done")
1264
1265       ;; Sort by score
1266       (apply 'vector
1267              (sort artlist
1268                    (function (lambda (x y)
1269                                (> (nnir-artitem-rsv x)
1270                                   (nnir-artitem-rsv y)))))))))
1271
1272 ;; Swish-E interface.
1273 (defun nnir-run-swish-e (query server &optional group)
1274   "Run given query against swish-e.
1275 Returns a vector of (group name, file name) pairs (also vectors,
1276 actually).
1277
1278 Tested with swish-e-2.0.1 on Windows NT 4.0."
1279
1280   ;; swish-e crashes with empty parameter to "-w" on commandline...
1281   ;; (when group
1282   ;;   (error "The swish-e backend cannot search specific groups"))
1283
1284   (save-excursion
1285     (let ((qstring (cdr (assq 'query query)))
1286           (prefix
1287            (or (nnir-read-server-parm 'nnir-swish-e-remove-prefix server)
1288                (error "Missing parameter `nnir-swish-e-remove-prefix'")))
1289           artlist score artno dirnam group )
1290
1291       (when (equal "" qstring)
1292         (error "swish-e: You didn't enter anything"))
1293
1294       (set-buffer (get-buffer-create nnir-tmp-buffer))
1295       (erase-buffer)
1296
1297       (message "Doing swish-e query %s..." query)
1298       (let* ((index-files
1299               (or (nnir-read-server-parm
1300                    'nnir-swish-e-index-files server)
1301                   (error "Missing parameter `nnir-swish-e-index-files'")))
1302              (additional-switches
1303               (nnir-read-server-parm
1304                'nnir-swish-e-additional-switches server))
1305              (cp-list `(,nnir-swish-e-program
1306                         nil             ; input from /dev/null
1307                         t               ; output
1308                         nil             ; don't redisplay
1309                         "-f" ,@index-files
1310                         ,@additional-switches
1311                         "-w"
1312                         ,qstring        ; the query, in swish-e format
1313                         ))
1314              (exitstatus
1315               (progn
1316                 (message "%s args: %s" nnir-swish-e-program
1317                          (mapconcat 'identity (cddddr cp-list) " "))
1318                 (apply 'call-process cp-list))))
1319         (unless (or (null exitstatus)
1320                     (zerop exitstatus))
1321           (nnheader-report 'nnir "Couldn't run swish-e: %s" exitstatus)
1322           ;; swish-e failure reason is in this buffer, show it if
1323           ;; the user wants it.
1324           (when (> gnus-verbose 6)
1325             (display-buffer nnir-tmp-buffer))))
1326
1327       ;; The results are output in the format of:
1328       ;; rank path-name file-title file-size
1329       (goto-char (point-min))
1330       (while (re-search-forward
1331               "\\(^[0-9]+\\) \\([^ ]+\\) \"\\([^\"]+\\)\" [0-9]+$" nil t)
1332         (setq score (match-string 1)
1333               artno (match-string 3)
1334               dirnam (file-name-directory (match-string 2)))
1335
1336         ;; don't match directories
1337         (when (string-match "^[0-9]+$" artno)
1338           (when (not (null dirnam))
1339
1340             ;; remove nnir-swish-e-remove-prefix from beginning of dirname
1341             (when (string-match (concat "^" prefix) dirnam)
1342               (setq dirnam (replace-match "" t t dirnam)))
1343
1344             (setq dirnam (substring dirnam 0 -1))
1345             ;; eliminate all ".", "/", "\" from beginning. Always matches.
1346             (string-match "^[./\\]*\\(.*\\)$" dirnam)
1347             ;; "/" -> "."
1348             (setq group (gnus-replace-in-string (match-string 1 dirnam) "/" "."))
1349             ;; Windows "\\" -> "."
1350             (setq group (gnus-replace-in-string group "\\\\" "."))
1351
1352             (push (vector (gnus-group-full-name group server)
1353                           (string-to-number artno)
1354                           (string-to-number score))
1355                   artlist))))
1356
1357       (message "Massaging swish-e output...done")
1358
1359       ;; Sort by score
1360       (apply 'vector
1361              (sort artlist
1362                    (function (lambda (x y)
1363                                (> (nnir-artitem-rsv x)
1364                                   (nnir-artitem-rsv y)))))))))
1365
1366 ;; HyREX interface
1367 (defun nnir-run-hyrex (query server &optional group)
1368   (save-excursion
1369     (let ((artlist nil)
1370           (groupspec (cdr (assq 'hyrex-group query)))
1371           (qstring (cdr (assq 'query query)))
1372           (prefix (nnir-read-server-parm 'nnir-hyrex-remove-prefix server))
1373           score artno dirnam)
1374       (when (and (not groupspec) group)
1375         (setq groupspec
1376               (regexp-opt
1377                (mapcar (lambda (x) (gnus-group-real-name x)) group))))
1378       (set-buffer (get-buffer-create nnir-tmp-buffer))
1379       (erase-buffer)
1380       (message "Doing hyrex-search query %s..." query)
1381       (let* ((cp-list
1382               `( ,nnir-hyrex-program
1383                  nil                    ; input from /dev/null
1384                  t                      ; output
1385                  nil                    ; don't redisplay
1386                  "-i",(nnir-read-server-parm 'nnir-hyrex-index-directory server) ; index directory
1387                  ,@(nnir-read-server-parm 'nnir-hyrex-additional-switches server)
1388                  ,qstring          ; the query, in hyrex-search format
1389                  ))
1390              (exitstatus
1391               (progn
1392                 (message "%s args: %s" nnir-hyrex-program
1393                          (mapconcat 'identity (cddddr cp-list) " "))
1394                 (apply 'call-process cp-list))))
1395         (unless (or (null exitstatus)
1396                     (zerop exitstatus))
1397           (nnheader-report 'nnir "Couldn't run hyrex-search: %s" exitstatus)
1398           ;; nnir-search failure reason is in this buffer, show it if
1399           ;; the user wants it.
1400           (when (> gnus-verbose 6)
1401             (display-buffer nnir-tmp-buffer)))) ;; FIXME: Don't clear buffer !
1402       (message "Doing hyrex-search query \"%s\"...done" qstring)
1403       (sit-for 0)
1404       ;; nnir-search returns:
1405       ;;   for nnml/nnfolder: "filename mailid weight"
1406       ;;   for nnimap:        "group mailid weight"
1407       (goto-char (point-min))
1408       (delete-non-matching-lines "^\\S + [0-9]+ [0-9]+$")
1409       ;; HyREX doesn't search directly in groups -- so filter out here.
1410       (when groupspec
1411         (keep-lines groupspec))
1412       ;; extract data from result lines
1413       (goto-char (point-min))
1414       (while (re-search-forward
1415               "\\(\\S +\\) \\([0-9]+\\) \\([0-9]+\\)" nil t)
1416         (setq dirnam (match-string 1)
1417               artno (match-string 2)
1418               score (match-string 3))
1419         (when (string-match prefix dirnam)
1420           (setq dirnam (replace-match "" t t dirnam)))
1421         (push (vector (gnus-group-full-name
1422                        (gnus-replace-in-string dirnam "/" ".") server)
1423                       (string-to-number artno)
1424                       (string-to-number score))
1425               artlist))
1426       (message "Massaging hyrex-search output...done.")
1427       (apply 'vector
1428              (sort artlist
1429                    (function (lambda (x y)
1430                                (if (string-lessp (nnir-artitem-group x)
1431                                                  (nnir-artitem-group y))
1432                                    t
1433                                  (< (nnir-artitem-number x)
1434                                     (nnir-artitem-number y)))))))
1435       )))
1436
1437 ;; Namazu interface
1438 (defun nnir-run-namazu (query server &optional group)
1439   "Run given query against Namazu.  Returns a vector of (group name, file name)
1440 pairs (also vectors, actually).
1441
1442 Tested with Namazu 2.0.6 on a GNU/Linux system."
1443   ;; (when group
1444   ;;   (error "The Namazu backend cannot search specific groups"))
1445   (save-excursion
1446     (let ((article-pattern (if (string-match "\\`nnmaildir:"
1447                                              (gnus-group-server server))
1448                                ":[0-9]+"
1449                              "^[0-9]+$"))
1450           artlist
1451           (qstring (cdr (assq 'query query)))
1452           (prefix (nnir-read-server-parm 'nnir-namazu-remove-prefix server))
1453           score group article
1454           (process-environment (copy-sequence process-environment)))
1455       (setenv "LC_MESSAGES" "C")
1456       (set-buffer (get-buffer-create nnir-tmp-buffer))
1457       (erase-buffer)
1458       (let* ((cp-list
1459               `( ,nnir-namazu-program
1460                  nil                    ; input from /dev/null
1461                  t                      ; output
1462                  nil                    ; don't redisplay
1463                  "-q"                   ; don't be verbose
1464                  "-a"                   ; show all matches
1465                  "-s"                   ; use short format
1466                  ,@(nnir-read-server-parm 'nnir-namazu-additional-switches server)
1467                  ,qstring               ; the query, in namazu format
1468                  ,(nnir-read-server-parm 'nnir-namazu-index-directory server) ; index directory
1469                  ))
1470              (exitstatus
1471               (progn
1472                 (message "%s args: %s" nnir-namazu-program
1473                          (mapconcat 'identity (cddddr cp-list) " "))
1474                 (apply 'call-process cp-list))))
1475         (unless (or (null exitstatus)
1476                     (zerop exitstatus))
1477           (nnheader-report 'nnir "Couldn't run namazu: %s" exitstatus)
1478           ;; Namazu failure reason is in this buffer, show it if
1479           ;; the user wants it.
1480           (when (> gnus-verbose 6)
1481             (display-buffer nnir-tmp-buffer))))
1482
1483       ;; Namazu output looks something like this:
1484       ;; 2. Re: Gnus agent expire broken (score: 55)
1485       ;; /home/henrik/Mail/mail/sent/1310 (4,138 bytes)
1486
1487       (goto-char (point-min))
1488       (while (re-search-forward
1489               "^\\([0-9]+\\.\\).*\\((score: \\([0-9]+\\)\\))\n\\([^ ]+\\)"
1490               nil t)
1491         (setq score (match-string 3)
1492               group (file-name-directory (match-string 4))
1493               article (file-name-nondirectory (match-string 4)))
1494
1495         ;; make sure article and group is sane
1496         (when (and (string-match article-pattern article)
1497                    (not (null group)))
1498           (nnir-add-result group article score prefix server artlist)))
1499
1500       ;; sort artlist by score
1501       (apply 'vector
1502              (sort artlist
1503                    (function (lambda (x y)
1504                                (> (nnir-artitem-rsv x)
1505                                   (nnir-artitem-rsv y)))))))))
1506
1507 (defun nnir-run-notmuch (query server &optional group)
1508   "Run QUERY against notmuch.
1509 Returns a vector of (group name, file name) pairs (also vectors,
1510 actually)."
1511
1512   ;; (when group
1513   ;;   (error "The notmuch backend cannot search specific groups"))
1514
1515   (save-excursion
1516     (let ( (qstring (cdr (assq 'query query)))
1517            (groupspec (cdr (assq 'notmuch-group query)))
1518            (prefix (nnir-read-server-parm 'nnir-notmuch-remove-prefix server))
1519            artlist
1520            (article-pattern (if (string-match "\\`nnmaildir:"
1521                                               (gnus-group-server server))
1522                                ":[0-9]+"
1523                              "^[0-9]+$"))
1524            artno dirnam filenam)
1525
1526       (when (equal "" qstring)
1527         (error "notmuch: You didn't enter anything"))
1528
1529       (set-buffer (get-buffer-create nnir-tmp-buffer))
1530       (erase-buffer)
1531
1532       (if groupspec
1533           (message "Doing notmuch query %s on %s..." qstring groupspec)
1534         (message "Doing notmuch query %s..." qstring))
1535
1536       (let* ((cp-list `( ,nnir-notmuch-program
1537                          nil            ; input from /dev/null
1538                          t              ; output
1539                          nil            ; don't redisplay
1540                          "search"
1541                          "--format=text"
1542                          "--output=files"
1543                          ,@(nnir-read-server-parm 'nnir-notmuch-additional-switches server)
1544                          ,qstring       ; the query, in notmuch format
1545                          ))
1546              (exitstatus
1547               (progn
1548                 (message "%s args: %s" nnir-notmuch-program
1549                          (mapconcat 'identity (cddddr cp-list) " ")) ;; ???
1550                 (apply 'call-process cp-list))))
1551         (unless (or (null exitstatus)
1552                     (zerop exitstatus))
1553           (nnheader-report 'nnir "Couldn't run notmuch: %s" exitstatus)
1554           ;; notmuch failure reason is in this buffer, show it if
1555           ;; the user wants it.
1556           (when (> gnus-verbose 6)
1557             (display-buffer nnir-tmp-buffer))))
1558
1559       ;; The results are output in the format of:
1560       ;; absolute-path-name
1561       (goto-char (point-min))
1562       (while (not (eobp))
1563         (setq filenam (buffer-substring-no-properties (line-beginning-position)
1564                                                       (line-end-position))
1565               artno (file-name-nondirectory filenam)
1566               dirnam (file-name-directory filenam))
1567         (forward-line 1)
1568
1569         ;; don't match directories
1570         (when (string-match article-pattern artno)
1571           (when (not (null dirnam))
1572
1573             ;; maybe limit results to matching groups.
1574             (when (or (not groupspec)
1575                       (string-match groupspec dirnam))
1576               (nnir-add-result dirnam artno "" prefix server artlist)))))
1577
1578       (message "Massaging notmuch output...done")
1579
1580       artlist)))
1581
1582 (defun nnir-run-find-grep (query server &optional grouplist)
1583   "Run find and grep to obtain matching articles."
1584   (let* ((method (gnus-server-to-method server))
1585          (sym (intern
1586                (concat (symbol-name (car method)) "-directory")))
1587          (directory (cadr (assoc sym (cddr method))))
1588          (regexp (cdr (assoc 'query query)))
1589          (grep-options (cdr (assoc 'grep-options query)))
1590          (grouplist (or grouplist (nnir-get-active server))))
1591     (unless directory
1592       (error "No directory found in method specification of server %s"
1593              server))
1594     (apply
1595      'vconcat
1596      (mapcar (lambda (x)
1597                (let ((group x)
1598                      artlist)
1599                  (message "Searching %s using find-grep..."
1600                           (or group server))
1601                  (save-window-excursion
1602                    (set-buffer (get-buffer-create nnir-tmp-buffer))
1603                    (if (> gnus-verbose 6)
1604                        (pop-to-buffer (current-buffer)))
1605                    (cd directory) ; Using relative paths simplifies
1606                                         ; postprocessing.
1607                    (let ((group
1608                           (if (not group)
1609                               "."
1610                             ;; Try accessing the group literally as
1611                             ;; well as interpreting dots as directory
1612                             ;; separators so the engine works with
1613                             ;; plain nnml as well as the Gnus Cache.
1614                             (let ((group (gnus-group-real-name group)))
1615                               ;; Replace cl-func find-if.
1616                               (if (file-directory-p group)
1617                                   group
1618                                 (if (file-directory-p
1619                                      (setq group
1620                                            (gnus-replace-in-string
1621                                             group
1622                                             "\\." "/" t)))
1623                                     group))))))
1624                      (unless group
1625                        (error "Cannot locate directory for group"))
1626                      (save-excursion
1627                        (apply
1628                         'call-process "find" nil t
1629                         "find" group "-maxdepth" "1" "-type" "f"
1630                         "-name" "[0-9]*" "-exec"
1631                         "grep"
1632                         `("-l" ,@(and grep-options
1633                                       (split-string grep-options "\\s-" t))
1634                           "-e" ,regexp "{}" "+"))))
1635
1636                    ;; Translate relative paths to group names.
1637                    (while (not (eobp))
1638                      (let* ((path (split-string
1639                                    (buffer-substring
1640                                     (point)
1641                                     (line-end-position)) "/" t))
1642                             (art (string-to-number (car (last path)))))
1643                        (while (string= "." (car path))
1644                          (setq path (cdr path)))
1645                        (let ((group (mapconcat 'identity
1646                                                ;; Replace cl-func:
1647                                                ;; (subseq path 0 -1)
1648                                                (let ((end (1- (length path)))
1649                                                      res)
1650                                                  (while
1651                                                      (>= (setq end (1- end)) 0)
1652                                                    (push (pop path) res))
1653                                                  (nreverse res))
1654                                                ".")))
1655                          (push
1656                           (vector (gnus-group-full-name group server) art 0)
1657                           artlist))
1658                        (forward-line 1)))
1659                    (message "Searching %s using find-grep...done"
1660                             (or group server))
1661                    artlist)))
1662      grouplist))))
1663
1664 (declare-function mm-url-insert "mm-url" (url &optional follow-refresh))
1665 (declare-function mm-url-encode-www-form-urlencoded "mm-url" (pairs))
1666
1667 ;; gmane interface
1668 (defun nnir-run-gmane (query srv &optional groups)
1669   "Run a search against a gmane back-end server."
1670       (let* ((case-fold-search t)
1671              (qstring (cdr (assq 'query query)))
1672              (server (cadr (gnus-server-to-method srv)))
1673              (groupspec (mapconcat
1674                          (lambda (x)
1675                            (if (gnus-string-match-p "gmane" x)
1676                                (format "group:%s" (gnus-group-short-name x))
1677                              (error "Can't search non-gmane groups: %s" x)))
1678                            groups " "))
1679              (authorspec
1680               (if (assq 'gmane-author query)
1681                   (format "author:%s" (cdr (assq 'gmane-author query))) ""))
1682              (search (format "%s %s %s"
1683                              qstring groupspec authorspec))
1684              (gnus-inhibit-demon t)
1685              artlist)
1686         (require 'mm-url)
1687         (with-current-buffer (get-buffer-create nnir-tmp-buffer)
1688           (erase-buffer)
1689           (mm-url-insert
1690            (concat
1691             "http://search.gmane.org/nov.php"
1692             "?"
1693             (mm-url-encode-www-form-urlencoded
1694              `(("query" . ,search)
1695                ("HITSPERPAGE" . "999")))))
1696           (unless (featurep 'xemacs) (set-buffer-multibyte t))
1697           (mm-decode-coding-region (point-min) (point-max) 'utf-8)
1698           (goto-char (point-min))
1699           (forward-line 1)
1700           (while (not (eobp))
1701             (unless (or (eolp) (looking-at "\x0d"))
1702               (let ((header (nnheader-parse-nov)))
1703                 (let ((xref (mail-header-xref header))
1704                       (xscore (string-to-number (cdr (assoc 'X-Score
1705                                (mail-header-extra header))))))
1706                   (when (string-match " \\([^:]+\\)[:/]\\([0-9]+\\)" xref)
1707                     (push
1708                      (vector
1709                       (gnus-group-prefixed-name (match-string 1 xref) srv)
1710                       (string-to-number (match-string 2 xref)) xscore)
1711                      artlist)))))
1712             (forward-line 1)))
1713         (apply 'vector (nreverse (mm-delete-duplicates artlist)))))
1714
1715 ;;; Util Code:
1716
1717 (defun gnus-nnir-group-p (group)
1718   "Say whether GROUP is nnir or not."
1719   (if (gnus-group-prefixed-p group)
1720       (eq 'nnir (car (gnus-find-method-for-group group)))
1721     (and group (string-match "^nnir" group))))
1722
1723 (defun nnir-read-parms (nnir-search-engine)
1724   "Reads additional search parameters according to `nnir-engines'."
1725   (let ((parmspec (caddr (assoc nnir-search-engine nnir-engines))))
1726     (mapcar 'nnir-read-parm parmspec)))
1727
1728 (defun nnir-read-parm (parmspec)
1729   "Reads a single search parameter.
1730 `parmspec' is a cons cell, the car is a symbol, the cdr is a prompt."
1731   (let ((sym (car parmspec))
1732         (prompt (cdr parmspec)))
1733     (if (listp prompt)
1734         (let* ((result (apply 'gnus-completing-read prompt))
1735                (mapping (or (assoc result nnir-imap-search-arguments)
1736                             (cons nil nnir-imap-search-other))))
1737           (cons sym (format (cdr mapping) result)))
1738       (cons sym (read-string prompt)))))
1739
1740 (defun nnir-run-query (specs)
1741   "Invoke appropriate search engine function (see `nnir-engines')."
1742   (apply 'vconcat
1743          (mapcar
1744           (lambda (x)
1745             (let* ((server (car x))
1746                    (search-engine (nnir-server-to-search-engine server))
1747                    (search-func (cadr (assoc search-engine nnir-engines))))
1748               (and search-func
1749                    (funcall search-func (cdr (assq 'nnir-query-spec specs))
1750                             server (cadr x)))))
1751           (cdr (assq 'nnir-group-spec specs)))))
1752
1753 (defun nnir-server-to-search-engine (server)
1754   (or (nnir-read-server-parm 'nnir-search-engine server t)
1755       (cdr (assoc (car (gnus-server-to-method server))
1756                   nnir-method-default-engines))))
1757
1758 (defun nnir-read-server-parm (key server &optional not-global)
1759   "Returns the parameter value corresponding to `key' for
1760 `server'. If no server-specific value is found consult the global
1761 environment unless `not-global' is non-nil."
1762   (let ((method (gnus-server-to-method server)))
1763     (cond ((and method (assq key (cddr method)))
1764            (nth 1 (assq key (cddr method))))
1765           ((and (not not-global) (boundp key)) (symbol-value key))
1766           (t nil))))
1767
1768 (defun nnir-possibly-change-group (group &optional server)
1769   (or (not server) (nnir-server-opened server) (nnir-open-server server))
1770   (when (gnus-nnir-group-p group)
1771     (setq nnir-artlist (gnus-group-get-parameter
1772                         (gnus-group-prefixed-name
1773                          (gnus-group-short-name group) '(nnir "nnir"))
1774                         'nnir-artlist t))))
1775
1776 (defun nnir-server-opened (&optional server)
1777   (let ((backend (car (gnus-server-to-method server))))
1778     (nnoo-current-server-p (or backend 'nnir) server)))
1779
1780 (defun nnir-search-thread (header)
1781   "Make an nnir group based on the thread containing the article
1782 header. The current server will be searched. If the registry is
1783 installed, the server that the registry reports the current
1784 article came from is also searched."
1785   (let* ((query
1786           (list (cons 'query (nnimap-make-thread-query header))
1787                 (cons 'criteria "")))
1788          (server
1789           (list (list (gnus-method-to-server
1790            (gnus-find-method-for-group gnus-newsgroup-name)))))
1791          (registry-group (and
1792                           (gnus-bound-and-true-p 'gnus-registry-enabled)
1793                           (car (gnus-registry-get-id-key
1794                                 (mail-header-id header) 'group))))
1795          (registry-server
1796           (and registry-group
1797                (gnus-method-to-server
1798                 (gnus-find-method-for-group registry-group)))))
1799     (when registry-server (add-to-list 'server (list registry-server)))
1800     (gnus-group-make-nnir-group nil (list
1801                                      (cons 'nnir-query-spec query)
1802                                      (cons 'nnir-group-spec server)))
1803     (gnus-summary-goto-subject (gnus-id-to-article (mail-header-id header)))))
1804
1805 (defun nnir-get-active (srv)
1806   (let ((method (gnus-server-to-method srv))
1807         groups)
1808     (gnus-request-list method)
1809     (with-current-buffer nntp-server-buffer
1810       (let ((cur (current-buffer))
1811             name)
1812         (goto-char (point-min))
1813         (unless (or (null nnir-ignored-newsgroups)
1814                     (string= nnir-ignored-newsgroups ""))
1815           (delete-matching-lines nnir-ignored-newsgroups))
1816         (if (eq (car method) 'nntp)
1817             (while (not (eobp))
1818               (ignore-errors
1819                 (push (mm-string-as-unibyte
1820                        (gnus-group-full-name
1821                         (buffer-substring
1822                          (point)
1823                          (progn
1824                            (skip-chars-forward "^ \t")
1825                            (point))) method))
1826                       groups))
1827               (forward-line))
1828           (while (not (eobp))
1829             (ignore-errors
1830               (push (mm-string-as-unibyte
1831                      (if (eq (char-after) ?\")
1832                          (gnus-group-full-name (read cur) method)
1833                        (let ((p (point)) (name ""))
1834                          (skip-chars-forward "^ \t\\\\")
1835                          (setq name (buffer-substring p (point)))
1836                          (while (eq (char-after) ?\\)
1837                            (setq p (1+ (point)))
1838                            (forward-char 2)
1839                            (skip-chars-forward "^ \t\\\\")
1840                            (setq name (concat name (buffer-substring
1841                                                     p (point)))))
1842                          (gnus-group-full-name name method))))
1843                     groups))
1844             (forward-line)))))
1845     groups))
1846
1847 (defun nnir-registry-action (action data-header from &optional to method)
1848   "Call `gnus-registry-action' with the original article group."
1849   (gnus-registry-action
1850    action
1851    data-header
1852    (nnir-article-group (mail-header-number data-header))
1853    to
1854    method))
1855
1856 (defun nnir-mode ()
1857   (when (eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnir)
1858     (setq gnus-summary-line-format
1859           (or nnir-summary-line-format gnus-summary-line-format))
1860     (when (gnus-bound-and-true-p 'gnus-registry-enabled)
1861       (remove-hook 'gnus-summary-article-delete-hook 'gnus-registry-action t)
1862       (remove-hook 'gnus-summary-article-move-hook 'gnus-registry-action t)
1863       (remove-hook 'gnus-summary-article-expire-hook 'gnus-registry-action t)
1864       (add-hook 'gnus-summary-article-delete-hook 'nnir-registry-action t t)
1865       (add-hook 'gnus-summary-article-move-hook 'nnir-registry-action t t)
1866       (add-hook 'gnus-summary-article-expire-hook 'nnir-registry-action t t))))
1867
1868
1869 (defun gnus-summary-create-nnir-group ()
1870   (interactive)
1871   (or (nnir-server-opened "") (nnir-open-server "nnir"))
1872   (let ((name (gnus-read-group "Group name: "))
1873         (method '(nnir ""))
1874         (pgroup
1875          (gnus-group-guess-full-name-from-command-method gnus-newsgroup-name)))
1876     (with-current-buffer gnus-group-buffer
1877       (gnus-group-make-group
1878        name method nil
1879        (gnus-group-find-parameter pgroup)))))
1880
1881
1882 (deffoo nnir-request-create-group (group &optional server args)
1883   (message "Creating nnir group %s" group)
1884   (let* ((group (gnus-group-prefixed-name  group '(nnir "nnir")))
1885          (specs (assq 'nnir-specs args))
1886          (query-spec
1887           (or (cdr (assq 'nnir-query-spec specs))
1888               (list (cons 'query
1889                           (read-string "Query: " nil 'nnir-search-history)))))
1890          (group-spec
1891           (or (cdr (assq 'nnir-group-spec specs))
1892               (list (list (read-string "Server: " nil nil)))))
1893          (nnir-specs (list (cons 'nnir-query-spec query-spec)
1894                            (cons 'nnir-group-spec group-spec))))
1895     (gnus-group-set-parameter group 'nnir-specs nnir-specs)
1896     (gnus-group-set-parameter
1897      group 'nnir-artlist
1898      (or (cdr (assq 'nnir-artlist args))
1899          (nnir-run-query nnir-specs)))
1900     (nnir-request-update-info group (gnus-get-info group)))
1901   t)
1902
1903 (deffoo nnir-request-delete-group (group &optional force server)
1904   t)
1905
1906 (deffoo nnir-request-list (&optional server)
1907   t)
1908
1909 (deffoo nnir-request-scan (group method)
1910   t)
1911
1912 (deffoo nnir-request-close ()
1913   t)
1914
1915 (nnoo-define-skeleton nnir)
1916
1917 ;; The end.
1918 (provide 'nnir)
1919
1920 ;;; nnir.el ends here