cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader)
  35   ;; In Emacs 24, `open-protocol-stream' is an autoloaded alias for
  36   ;; `make-network-stream'.
  37   (unless (fboundp 'open-protocol-stream)
  38     (require 'proto-stream)))
  39
  40 (eval-when-compile
  41   (require 'cl))
  42
  43 (require 'nnheader)
  44 (require 'gnus-util)
  45 (require 'gnus)
  46 (require 'nnoo)
  47 (require 'netrc)
  48 (require 'utf7)
  49 (require 'tls)
  50 (require 'parse-time)
  51 (require 'nnmail)
  52
  53 (autoload 'auth-source-forget+ "auth-source")
  54 (autoload 'auth-source-search "auth-source")
  55
  56 (nnoo-declare nnimap)
  57
  58 (defvoo nnimap-address nil
  59   "The address of the IMAP server.")
  60
  61 (defvoo nnimap-user nil
  62   "Username to use for authentication to the IMAP server.")
  63
  64 (defvoo nnimap-server-port nil
  65   "The IMAP port used.
  66 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  67 it will default to `imap'.")
  68
  69 (defvoo nnimap-stream 'undecided
  70   "How nnimap talks to the IMAP server.
  71 The value should be either `undecided', `ssl' or `tls',
  72 `network', `starttls', `plain', or `shell'.
  73
  74 If the value is `undecided', nnimap tries `ssl' first, then falls
  75 back on `network'.")
  76
  77 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  78                                  (if (listp imap-shell-program)
  79                                      (car imap-shell-program)
  80                                    imap-shell-program)
  81                                "ssh %s imapd"))
  82
  83 (defvoo nnimap-inbox nil
  84   "The mail box where incoming mail arrives and should be split out of.
  85 This can be a string or a list of strings
  86 For example, \"INBOX\" or (\"INBOX\" \"SENT\").")
  87
  88 (defvoo nnimap-split-methods nil
  89   "How mail is split.
  90 Uses the same syntax as `nnmail-split-methods'.")
  91
  92 (defvoo nnimap-split-fancy nil
  93   "Uses the same syntax as `nnmail-split-fancy'.")
  94
  95 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  96   "Articles with the flags in the list will not be considered when splitting.")
  97
  98 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  99                         "Emacs 24.1")
 100
 101 (defvoo nnimap-authenticator nil
 102   "How nnimap authenticate itself to the server.
 103 Possible choices are nil (use default methods) or `anonymous'.")
 104
 105 (defvoo nnimap-expunge t
 106   "If non-nil, expunge articles after deleting them.
 107 This is always done if the server supports UID EXPUNGE, but it's
 108 not done by default on servers that doesn't support that command.")
 109
 110 (defvoo nnimap-streaming t
 111   "If non-nil, try to use streaming commands with IMAP servers.
 112 Switching this off will make nnimap slower, but it helps with
 113 some servers.")
 114
 115 (defvoo nnimap-connection-alist nil)
 116
 117 (defvoo nnimap-current-infos nil)
 118
 119 (defvoo nnimap-fetch-partial-articles nil
 120   "If non-nil, Gnus will fetch partial articles.
 121 If t, Gnus will fetch only the first part.  If a string, it
 122 will fetch all parts that have types that match that string.  A
 123 likely value would be \"text/\" to automatically fetch all
 124 textual parts.")
 125
 126 (defgroup nnimap nil
 127   "IMAP for Gnus."
 128   :group 'gnus)
 129
 130 (defcustom nnimap-request-articles-find-limit nil
 131   "Limit the number of articles to look for after moving an article."
 132   :type 'integer
 133   :version "24.3"
 134   :group 'nnimap)
 135
 136 (defvar nnimap-process nil)
 137
 138 (defvar nnimap-status-string "")
 139
 140 (defvar nnimap-split-download-body-default nil
 141   "Internal variable with default value for `nnimap-split-download-body'.")
 142
 143 (defvar nnimap-keepalive-timer nil)
 144 (defvar nnimap-process-buffers nil)
 145
 146 (defstruct nnimap
 147   group process commands capabilities select-result newlinep server
 148   last-command-time greeting examined stream-type initial-resync)
 149
 150 (defvar nnimap-object nil)
 151
 152 (defvar nnimap-mark-alist
 153   '((read "\\Seen" %Seen)
 154     (tick "\\Flagged" %Flagged)
 155     (reply "\\Answered" %Answered)
 156     (expire "gnus-expire")
 157     (dormant "gnus-dormant")
 158     (score "gnus-score")
 159     (save "gnus-save")
 160     (download "gnus-download")
 161     (forward "gnus-forward")))
 162
 163 (defvar nnimap-quirks
 164   '(("QRESYNC" "Zimbra" "QRESYNC ")))
 165
 166 (defvar nnimap-inhibit-logging nil)
 167
 168 (defun nnimap-buffer ()
 169   (nnimap-find-process-buffer nntp-server-buffer))
 170
 171 (defun nnimap-header-parameters ()
 172   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 173           (format
 174            (if (nnimap-ver4-p)
 175                "BODY.PEEK[HEADER.FIELDS %s]"
 176              "RFC822.HEADER.LINES %s")
 177            (append '(Subject From Date Message-Id
 178                              References In-Reply-To Xref)
 179                    nnmail-extra-headers))))
 180
 181 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 182   (when group
 183     (setq group (nnimap-decode-gnus-group group)))
 184   (with-current-buffer nntp-server-buffer
 185     (erase-buffer)
 186     (when (nnimap-change-group group server)
 187       (with-current-buffer (nnimap-buffer)
 188         (erase-buffer)
 189         (nnimap-wait-for-response
 190          (nnimap-send-command
 191           "UID FETCH %s %s"
 192           (nnimap-article-ranges (gnus-compress-sequence articles))
 193           (nnimap-header-parameters))
 194          t)
 195         (nnimap-transform-headers)
 196         (nnheader-remove-cr-followed-by-lf))
 197       (insert-buffer-substring
 198        (nnimap-find-process-buffer (current-buffer))))
 199     'headers))
 200
 201 (defun nnimap-transform-headers ()
 202   (goto-char (point-min))
 203   (let (article lines size string)
 204     (block nil
 205       (while (not (eobp))
 206         (while (not (looking-at "\\* [0-9]+ FETCH"))
 207           (delete-region (point) (progn (forward-line 1) (point)))
 208           (when (eobp)
 209             (return)))
 210         (goto-char (match-end 0))
 211         ;; Unfold quoted {number} strings.
 212         (while (re-search-forward
 213                 "[^]][ (]{\\([0-9]+\\)}\r?\n"
 214                 (save-excursion
 215                   ;; Start of the header section.
 216                   (or (re-search-forward "] {[0-9]+}\r?\n" nil t)
 217                       ;; Start of the next FETCH.
 218                       (re-search-forward "\\* [0-9]+ FETCH" nil t)
 219                       (point-max)))
 220                 t)
 221           (setq size (string-to-number (match-string 1)))
 222           (delete-region (+ (match-beginning 0) 2) (point))
 223           (setq string (buffer-substring (point) (+ (point) size)))
 224           (delete-region (point) (+ (point) size))
 225           (insert (format "%S" (mm-subst-char-in-string ?\n ?\s string))))
 226         (beginning-of-line)
 227         (setq article
 228               (and (re-search-forward "UID \\([0-9]+\\)" (line-end-position)
 229                                       t)
 230                    (match-string 1)))
 231         (setq lines nil)
 232         (setq size
 233               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 234                                       (line-end-position)
 235                                       t)
 236                    (match-string 1)))
 237         (beginning-of-line)
 238         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 239           (let ((structure (ignore-errors
 240                              (read (current-buffer)))))
 241             (while (and (consp structure)
 242                         (not (atom (car structure))))
 243               (setq structure (car structure)))
 244             (setq lines (if (and
 245                              (stringp (car structure))
 246                              (equal (upcase (nth 0 structure)) "MESSAGE")
 247                              (equal (upcase (nth 1 structure)) "RFC822"))
 248                             (nth 9 structure)
 249                           (nth 7 structure)))))
 250         (delete-region (line-beginning-position) (line-end-position))
 251         (insert (format "211 %s Article retrieved." article))
 252         (forward-line 1)
 253         (when size
 254           (insert (format "Chars: %s\n" size)))
 255         (when lines
 256           (insert (format "Lines: %s\n" lines)))
 257         (unless (re-search-forward "^\r$" nil t)
 258           (goto-char (point-max)))
 259         (delete-region (line-beginning-position) (line-end-position))
 260         (insert ".")
 261         (forward-line 1)))))
 262
 263 (defun nnimap-unfold-quoted-lines ()
 264   ;; Unfold quoted {number} strings.
 265   (let (size string)
 266     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 267       (setq size (string-to-number (match-string 1)))
 268       (delete-region (1+ (match-beginning 0)) (point))
 269       (setq string (buffer-substring (point) (+ (point) size)))
 270       (delete-region (point) (+ (point) size))
 271       (insert (format "%S" string)))))
 272
 273 (defun nnimap-get-length ()
 274   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 275        (string-to-number (match-string 1))))
 276
 277 (defun nnimap-article-ranges (ranges)
 278   (let (result)
 279     (cond
 280      ((numberp ranges)
 281       (number-to-string ranges))
 282      ((numberp (cdr ranges))
 283       (format "%d:%d" (car ranges) (cdr ranges)))
 284      (t
 285       (dolist (elem ranges)
 286         (push
 287          (if (consp elem)
 288              (format "%d:%d" (car elem) (cdr elem))
 289            (number-to-string elem))
 290          result))
 291       (mapconcat #'identity (nreverse result) ",")))))
 292
 293 (deffoo nnimap-open-server (server &optional defs no-reconnect)
 294   (if (nnimap-server-opened server)
 295       t
 296     (unless (assq 'nnimap-address defs)
 297       (setq defs (append defs (list (list 'nnimap-address server)))))
 298     (nnoo-change-server 'nnimap server defs)
 299     (if no-reconnect
 300         (nnimap-find-connection nntp-server-buffer)
 301       (or (nnimap-find-connection nntp-server-buffer)
 302           (nnimap-open-connection nntp-server-buffer)))))
 303
 304 (defun nnimap-make-process-buffer (buffer)
 305   (with-current-buffer
 306       (generate-new-buffer (format " *nnimap %s %s %s*"
 307                                    nnimap-address nnimap-server-port
 308                                    (gnus-buffer-exists-p buffer)))
 309     (mm-disable-multibyte)
 310     (buffer-disable-undo)
 311     (gnus-add-buffer)
 312     (set (make-local-variable 'after-change-functions) nil)
 313     (set (make-local-variable 'nnimap-object)
 314          (make-nnimap :server (nnoo-current-server 'nnimap)
 315                       :initial-resync 0))
 316     (push (list buffer (current-buffer)) nnimap-connection-alist)
 317     (push (current-buffer) nnimap-process-buffers)
 318     (current-buffer)))
 319
 320 (defun nnimap-credentials (address ports user)
 321   (let* ((auth-source-creation-prompts
 322           '((user  . "IMAP user at %h: ")
 323             (secret . "IMAP password for %u@%h: ")))
 324          (found (nth 0 (auth-source-search :max 1
 325                                            :host address
 326                                            :port ports
 327                                            :user user
 328                                            :require '(:user :secret)
 329                                            :create t))))
 330     (if found
 331         (list (plist-get found :user)
 332               (let ((secret (plist-get found :secret)))
 333                 (if (functionp secret)
 334                     (funcall secret)
 335                   secret))
 336               (plist-get found :save-function))
 337       nil)))
 338
 339 (defun nnimap-keepalive ()
 340   (let ((now (current-time)))
 341     (dolist (buffer nnimap-process-buffers)
 342       (when (buffer-name buffer)
 343         (with-current-buffer buffer
 344           (when (and nnimap-object
 345                      (nnimap-last-command-time nnimap-object)
 346                      (> (gnus-float-time
 347                          (time-subtract
 348                           now
 349                           (nnimap-last-command-time nnimap-object)))
 350                         ;; More than five minutes since the last command.
 351                         (* 5 60)))
 352             (nnimap-send-command "NOOP")))))))
 353
 354 (defun nnimap-open-connection (buffer)
 355   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
 356   ;; `ssl' when nnimap-server-port was nil.  Sort of.
 357   (when (and nnimap-server-port
 358              (eq nnimap-stream 'undecided))
 359     (setq nnimap-stream 'ssl))
 360   (let ((stream
 361          (if (eq nnimap-stream 'undecided)
 362              (loop for type in '(ssl network)
 363                    for stream = (let ((nnimap-stream type))
 364                                   (nnimap-open-connection-1 buffer))
 365                    while (eq stream 'no-connect)
 366                    finally (return stream))
 367            (nnimap-open-connection-1 buffer))))
 368     (if (eq stream 'no-connect)
 369         nil
 370       stream)))
 371
 372 (defun nnimap-map-port (port)
 373   (if (equal port "imaps")
 374       "993"
 375     port))
 376
 377 (defun nnimap-open-connection-1 (buffer)
 378   (unless nnimap-keepalive-timer
 379     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 380                                               'nnimap-keepalive)))
 381   (with-current-buffer (nnimap-make-process-buffer buffer)
 382     (let* ((coding-system-for-read 'binary)
 383            (coding-system-for-write 'binary)
 384            (ports
 385             (cond
 386              ((memq nnimap-stream '(network plain starttls))
 387               (nnheader-message 7 "Opening connection to %s..."
 388                                 nnimap-address)
 389               '("imap" "143"))
 390              ((eq nnimap-stream 'shell)
 391               (nnheader-message 7 "Opening connection to %s via shell..."
 392                                 nnimap-address)
 393               '("imap"))
 394              ((memq nnimap-stream '(ssl tls))
 395               (nnheader-message 7 "Opening connection to %s via tls..."
 396                                 nnimap-address)
 397               '("imaps" "imap" "993" "143"))
 398              (t
 399               (error "Unknown stream type: %s" nnimap-stream))))
 400            login-result credentials)
 401       (when nnimap-server-port
 402         (push nnimap-server-port ports))
 403       (let* ((stream-list
 404               (open-protocol-stream
 405                "*nnimap*" (current-buffer) nnimap-address
 406                (nnimap-map-port (car ports))
 407                :type nnimap-stream
 408                :return-list t
 409                :shell-command nnimap-shell-program
 410                :capability-command "1 CAPABILITY\r\n"
 411                :end-of-command "\r\n"
 412                :success " OK "
 413                :starttls-function
 414                (lambda (capabilities)
 415                  (when (gnus-string-match-p "STARTTLS" capabilities)
 416                    "1 STARTTLS\r\n"))))
 417              (stream (car stream-list))
 418              (props (cdr stream-list))
 419              (greeting (plist-get props :greeting))
 420              (capabilities (plist-get props :capabilities))
 421              (stream-type (plist-get props :type)))
 422         (when (and stream (not (memq (process-status stream) '(open run))))
 423           (setq stream nil))
 424
 425         (when (and (fboundp 'set-network-process-option) ;; Not in XEmacs.
 426                    (fboundp 'process-type) ;; Emacs 22 doesn't provide it.
 427                    (eq (process-type stream) 'network))
 428           ;; Use TCP-keepalive so that connections that pass through a NAT
 429           ;; router don't hang when left idle.
 430           (set-network-process-option stream :keepalive t))
 431
 432         (setf (nnimap-process nnimap-object) stream)
 433         (setf (nnimap-stream-type nnimap-object) stream-type)
 434         (if (not stream)
 435             (progn
 436               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 437                                nnimap-address (car ports) nnimap-stream)
 438               'no-connect)
 439           (gnus-set-process-query-on-exit-flag stream nil)
 440           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
 441               (nnheader-report 'nnimap "%s" greeting)
 442             ;; Store the greeting (for debugging purposes).
 443             (setf (nnimap-greeting nnimap-object) greeting)
 444             (setf (nnimap-capabilities nnimap-object)
 445                   (mapcar #'upcase
 446                           (split-string capabilities)))
 447             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
 448               (if (not (setq credentials
 449                              (if (eq nnimap-authenticator 'anonymous)
 450                                  (list "anonymous"
 451                                        (message-make-address))
 452                                ;; Look for the credentials based on
 453                                ;; the virtual server name and the address
 454                                (nnimap-credentials
 455                                 (gnus-delete-duplicates
 456                                  (list
 457                                   nnimap-address
 458                                   (nnoo-current-server 'nnimap)))
 459                                 ports
 460                                 nnimap-user))))
 461                   (setq nnimap-object nil)
 462                 (let ((nnimap-inhibit-logging t))
 463                   (setq login-result
 464                         (nnimap-login (car credentials) (cadr credentials))))
 465                 (if (car login-result)
 466                     (progn
 467                       ;; Save the credentials if a save function exists
 468                       ;; (such a function will only be passed if a new
 469                       ;; token was created).
 470                       (when (functionp (nth 2 credentials))
 471                         (funcall (nth 2 credentials)))
 472                       ;; See if CAPABILITY is set as part of login
 473                       ;; response.
 474                       (dolist (response (cddr login-result))
 475                         (when (string= "CAPABILITY" (upcase (car response)))
 476                           (setf (nnimap-capabilities nnimap-object)
 477                                 (mapcar #'upcase (cdr response))))))
 478                   ;; If the login failed, then forget the credentials
 479                   ;; that are now possibly cached.
 480                   (dolist (host (list (nnoo-current-server 'nnimap)
 481                                       nnimap-address))
 482                     (dolist (port ports)
 483                       (auth-source-forget+ :host host :port port)))
 484                   (delete-process (nnimap-process nnimap-object))
 485                   (setq nnimap-object nil))))
 486             (when nnimap-object
 487               (when (nnimap-capability "QRESYNC")
 488                 (nnimap-command "ENABLE QRESYNC"))
 489               (nnheader-message 7 "Opening connection to %s...done"
 490                                 nnimap-address)
 491               (nnimap-process nnimap-object))))))))
 492
 493 (autoload 'rfc2104-hash "rfc2104")
 494
 495 (defun nnimap-login (user password)
 496   (cond
 497    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
 498    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
 499    ;; and we're using an encrypted connection.
 500    ((and (not (nnimap-capability "LOGINDISABLED"))
 501          (eq (nnimap-stream-type nnimap-object) 'tls))
 502     (nnimap-command "LOGIN %S %S" user password))
 503    ((nnimap-capability "AUTH=CRAM-MD5")
 504     (erase-buffer)
 505     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
 506           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
 507       (process-send-string
 508        (get-buffer-process (current-buffer))
 509        (concat
 510         (base64-encode-string
 511          (concat user " "
 512                  (rfc2104-hash 'md5 64 16 password
 513                                (base64-decode-string challenge))))
 514         "\r\n"))
 515       (nnimap-wait-for-response sequence)))
 516    ((not (nnimap-capability "LOGINDISABLED"))
 517     (nnimap-command "LOGIN %S %S" user password))
 518    ((nnimap-capability "AUTH=PLAIN")
 519     (nnimap-command
 520      "AUTHENTICATE PLAIN %s"
 521      (base64-encode-string
 522       (format "\000%s\000%s"
 523               (nnimap-quote-specials user)
 524               (nnimap-quote-specials password)))))))
 525
 526 (defun nnimap-quote-specials (string)
 527   (with-temp-buffer
 528     (insert string)
 529     (goto-char (point-min))
 530     (while (re-search-forward "[\\\"]" nil t)
 531       (forward-char -1)
 532       (insert "\\")
 533       (forward-char 1))
 534     (buffer-string)))
 535
 536 (defun nnimap-find-parameter (parameter elems)
 537   (let (result)
 538     (dolist (elem elems)
 539       (cond
 540        ((equal (car elem) parameter)
 541         (setq result (cdr elem)))
 542        ((and (equal (car elem) "OK")
 543              (consp (cadr elem))
 544              (equal (caadr elem) parameter))
 545         (setq result (cdr (cadr elem))))))
 546     result))
 547
 548 (deffoo nnimap-close-server (&optional server)
 549   (when (nnoo-change-server 'nnimap server nil)
 550     (ignore-errors
 551       (delete-process (get-buffer-process (nnimap-buffer))))
 552     (nnoo-close-server 'nnimap server)
 553     t))
 554
 555 (deffoo nnimap-request-close ()
 556   t)
 557
 558 (deffoo nnimap-server-opened (&optional server)
 559   (and (nnoo-current-server-p 'nnimap server)
 560        nntp-server-buffer
 561        (gnus-buffer-live-p nntp-server-buffer)
 562        (nnimap-find-connection nntp-server-buffer)))
 563
 564 (deffoo nnimap-status-message (&optional server)
 565   nnimap-status-string)
 566
 567 (deffoo nnimap-request-article (article &optional group server to-buffer)
 568   (when group
 569     (setq group (nnimap-decode-gnus-group group)))
 570   (with-current-buffer nntp-server-buffer
 571     (let ((result (nnimap-change-group group server))
 572           parts structure)
 573       (when (stringp article)
 574         (setq article (nnimap-find-article-by-message-id group server article)))
 575       (when (and result
 576                  article)
 577         (erase-buffer)
 578         (with-current-buffer (nnimap-buffer)
 579           (erase-buffer)
 580           (when nnimap-fetch-partial-articles
 581             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 582             (goto-char (point-min))
 583             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 584               (setq structure (ignore-errors
 585                                 (let ((start (point)))
 586                                   (forward-sexp 1)
 587                                   (downcase-region start (point))
 588                                   (goto-char start)
 589                                   (read (current-buffer))))
 590                     parts (nnimap-find-wanted-parts structure))))
 591           (when (if parts
 592                     (nnimap-get-partial-article article parts structure)
 593                   (nnimap-get-whole-article article))
 594             (let ((buffer (current-buffer)))
 595               (with-current-buffer (or to-buffer nntp-server-buffer)
 596                 (nnheader-insert-buffer-substring buffer)
 597                 (nnheader-ms-strip-cr)))
 598             (cons group article)))))))
 599
 600 (deffoo nnimap-request-head (article &optional group server to-buffer)
 601   (when group
 602     (setq group (nnimap-decode-gnus-group group)))
 603   (when (nnimap-change-group group server)
 604     (with-current-buffer (nnimap-buffer)
 605       (when (stringp article)
 606         (setq article (nnimap-find-article-by-message-id group server article)))
 607       (if (null article)
 608           nil
 609         (nnimap-get-whole-article
 610          article (format "UID FETCH %%d %s"
 611                          (nnimap-header-parameters)))
 612         (let ((buffer (current-buffer)))
 613           (with-current-buffer (or to-buffer nntp-server-buffer)
 614             (erase-buffer)
 615             (insert-buffer-substring buffer)
 616             (nnheader-ms-strip-cr)
 617             (cons group article)))))))
 618
 619 (defun nnimap-get-whole-article (article &optional command)
 620   (let ((result
 621          (nnimap-command
 622           (or command
 623               (if (nnimap-ver4-p)
 624                   "UID FETCH %d BODY.PEEK[]"
 625                 "UID FETCH %d RFC822.PEEK"))
 626           article)))
 627     ;; Check that we really got an article.
 628     (goto-char (point-min))
 629     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 630       (setq result nil))
 631     (when result
 632       ;; Remove any data that may have arrived before the FETCH data.
 633       (beginning-of-line)
 634       (unless (bobp)
 635         (delete-region (point-min) (point)))
 636       (let ((bytes (nnimap-get-length)))
 637         (delete-region (line-beginning-position)
 638                        (progn (forward-line 1) (point)))
 639         (goto-char (+ (point) bytes))
 640         (delete-region (point) (point-max)))
 641       t)))
 642
 643 (defun nnimap-capability (capability)
 644   (member capability (nnimap-capabilities nnimap-object)))
 645
 646 (defun nnimap-ver4-p ()
 647   (nnimap-capability "IMAP4REV1"))
 648
 649 (defun nnimap-get-partial-article (article parts structure)
 650   (let ((result
 651          (nnimap-command
 652           "UID FETCH %d (%s %s)"
 653           article
 654           (if (nnimap-ver4-p)
 655               "BODY.PEEK[HEADER]"
 656             "RFC822.HEADER")
 657           (if (nnimap-ver4-p)
 658               (mapconcat (lambda (part)
 659                            (format "BODY.PEEK[%s]" part))
 660                          parts " ")
 661             (mapconcat (lambda (part)
 662                          (format "RFC822.PEEK[%s]" part))
 663                        parts " ")))))
 664     (when result
 665       (nnimap-convert-partial-article structure))))
 666
 667 (defun nnimap-convert-partial-article (structure)
 668   ;; First just skip past the headers.
 669   (goto-char (point-min))
 670   (let ((bytes (nnimap-get-length))
 671         id parts)
 672     ;; Delete "FETCH" line.
 673     (delete-region (line-beginning-position)
 674                    (progn (forward-line 1) (point)))
 675     (goto-char (+ (point) bytes))
 676     ;; Collect all the body parts.
 677     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 678       (setq id (match-string 1)
 679             bytes (or (nnimap-get-length) 0))
 680       (beginning-of-line)
 681       (delete-region (point) (progn (forward-line 1) (point)))
 682       (push (list id (buffer-substring (point) (+ (point) bytes)))
 683             parts)
 684       (delete-region (point) (+ (point) bytes)))
 685     ;; Delete trailing junk.
 686     (delete-region (point) (point-max))
 687     ;; Now insert all the parts again where they fit in the structure.
 688     (nnimap-insert-partial-structure structure parts)
 689     t))
 690
 691 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 692   (let (type boundary)
 693     (let ((bstruc structure))
 694       (while (consp (car bstruc))
 695         (pop bstruc))
 696       (setq type (car bstruc))
 697       (setq bstruc (car (cdr bstruc)))
 698       (let ((has-boundary (member "boundary" bstruc)))
 699         (when has-boundary
 700           (setq boundary (cadr has-boundary)))))
 701     (when subp
 702       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 703                       (downcase type) boundary)))
 704     (while (not (stringp (car structure)))
 705       (insert "\n--" boundary "\n")
 706       (if (consp (caar structure))
 707           (nnimap-insert-partial-structure (pop structure) parts t)
 708         (let ((bit (pop structure)))
 709           (insert (format "Content-type: %s/%s"
 710                           (downcase (nth 0 bit))
 711                           (downcase (nth 1 bit))))
 712           (if (member-ignore-case "CHARSET" (nth 2 bit))
 713               (insert (format
 714                        "; charset=%S\n"
 715                        (cadr (member-ignore-case "CHARSET" (nth 2 bit)))))
 716             (insert "\n"))
 717           (insert (format "Content-transfer-encoding: %s\n"
 718                           (nth 5 bit)))
 719           (insert "\n")
 720           (when (assoc (nth 9 bit) parts)
 721             (insert (cadr (assoc (nth 9 bit) parts)))))))
 722     (insert "\n--" boundary "--\n")))
 723
 724 (defun nnimap-find-wanted-parts (structure)
 725   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 726
 727 (defun nnimap-find-wanted-parts-1 (structure prefix)
 728   (let ((num 1)
 729         parts)
 730     (while (consp (car structure))
 731       (let ((sub (pop structure)))
 732         (if (consp (car sub))
 733             (push (nnimap-find-wanted-parts-1
 734                    sub (if (string= prefix "")
 735                            (number-to-string num)
 736                          (format "%s.%s" prefix num)))
 737                   parts)
 738           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 739                 (id (if (string= prefix "")
 740                         (number-to-string num)
 741                       (format "%s.%s" prefix num))))
 742             (setcar (nthcdr 9 sub) id)
 743             (when (if (eq nnimap-fetch-partial-articles t)
 744                       (equal id "1")
 745                     (string-match nnimap-fetch-partial-articles type))
 746               (push id parts))))
 747         (incf num)))
 748     (nreverse parts)))
 749
 750 (defun nnimap-decode-gnus-group (group)
 751   (decode-coding-string group 'utf-8))
 752
 753 (deffoo nnimap-request-group (group &optional server dont-check info)
 754   (setq group (nnimap-decode-gnus-group group))
 755   (let ((result (nnimap-change-group
 756                  ;; Don't SELECT the group if we're going to select it
 757                  ;; later, anyway.
 758                  (if (and (not dont-check)
 759                           (assoc group nnimap-current-infos))
 760                      nil
 761                    group)
 762                  server))
 763         articles active marks high low)
 764     (with-current-buffer nntp-server-buffer
 765       (when result
 766         (if (and dont-check
 767                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 768             (insert (format "211 %d %d %d %S\n"
 769                             (- (cdr active) (car active))
 770                             (car active)
 771                             (cdr active)
 772                             group))
 773           (with-current-buffer (nnimap-buffer)
 774             (erase-buffer)
 775             (let ((group-sequence
 776                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 777                   (flag-sequence
 778                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 779               (setf (nnimap-group nnimap-object) group)
 780               (nnimap-wait-for-response flag-sequence)
 781               (setq marks
 782                     (nnimap-flags-to-marks
 783                      (nnimap-parse-flags
 784                       (list (list group-sequence flag-sequence
 785                                   1 group "SELECT")))))
 786               (when (and info
 787                          marks)
 788                 (nnimap-update-infos marks (list info))
 789                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 790               (goto-char (point-max))
 791               (let ((uidnext (nth 5 (car marks))))
 792                 (setq high (or (if uidnext
 793                                    (1- uidnext)
 794                                  (nth 3 (car marks)))
 795                                0)
 796                       low (or (nth 4 (car marks)) uidnext 1)))))
 797           (erase-buffer)
 798           (insert
 799            (format
 800             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 801         t))))
 802
 803 (deffoo nnimap-request-create-group (group &optional server args)
 804   (setq group (nnimap-decode-gnus-group group))
 805   (when (nnimap-change-group nil server)
 806     (with-current-buffer (nnimap-buffer)
 807       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 808
 809 (deffoo nnimap-request-delete-group (group &optional force server)
 810   (setq group (nnimap-decode-gnus-group group))
 811   (when (nnimap-change-group nil server)
 812     (with-current-buffer (nnimap-buffer)
 813       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 814
 815 (deffoo nnimap-request-rename-group (group new-name &optional server)
 816   (setq group (nnimap-decode-gnus-group group))
 817   (when (nnimap-change-group nil server)
 818     (with-current-buffer (nnimap-buffer)
 819       (nnimap-unselect-group)
 820       (car (nnimap-command "RENAME %S %S"
 821                            (utf7-encode group t) (utf7-encode new-name t))))))
 822
 823 (defun nnimap-unselect-group ()
 824   ;; Make sure we don't have this group open read/write by asking
 825   ;; to examine a mailbox that doesn't exist.  This seems to be
 826   ;; the only way that allows us to reliably go back to unselected
 827   ;; state on Courier.
 828   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 829
 830 (deffoo nnimap-request-expunge-group (group &optional server)
 831   (setq group (nnimap-decode-gnus-group group))
 832   (when (nnimap-change-group group server)
 833     (with-current-buffer (nnimap-buffer)
 834       (car (nnimap-command "EXPUNGE")))))
 835
 836 (defun nnimap-get-flags (spec)
 837   (let ((articles nil)
 838         elems end)
 839     (with-current-buffer (nnimap-buffer)
 840       (erase-buffer)
 841       (nnimap-wait-for-response (nnimap-send-command
 842                                  "UID FETCH %s FLAGS" spec))
 843       (setq end (point))
 844       (subst-char-in-region (point-min) (point-max)
 845                             ?\\ ?% t)
 846       (goto-char (point-min))
 847       (while (search-forward " FETCH " end t)
 848         (setq elems (read (current-buffer)))
 849         (push (cons (cadr (memq 'UID elems))
 850                     (cadr (memq 'FLAGS elems)))
 851               articles)))
 852     (nreverse articles)))
 853
 854 (deffoo nnimap-close-group (group &optional server)
 855   t)
 856
 857 (deffoo nnimap-request-move-article (article group server accept-form
 858                                              &optional last internal-move-group)
 859   (setq group (nnimap-decode-gnus-group group))
 860   (with-temp-buffer
 861     (mm-disable-multibyte)
 862     (when (funcall (if internal-move-group
 863                        'nnimap-request-head
 864                      'nnimap-request-article)
 865                    article group server (current-buffer))
 866       ;; If the move is internal (on the same server), just do it the easy
 867       ;; way.
 868       (let ((message-id (message-field-value "message-id")))
 869         (if internal-move-group
 870             (let ((result
 871                    (with-current-buffer (nnimap-buffer)
 872                      (nnimap-command "UID COPY %d %S"
 873                                      article
 874                                      (utf7-encode internal-move-group t)))))
 875               (when (car result)
 876                 (nnimap-delete-article article)
 877                 (cons internal-move-group
 878                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 879                           (nnimap-find-article-by-message-id
 880                            internal-move-group server message-id
 881                            nnimap-request-articles-find-limit)))))
 882           ;; Move the article to a different method.
 883           (let ((result (eval accept-form)))
 884             (when result
 885               (nnimap-change-group group server)
 886               (nnimap-delete-article article)
 887               result)))))))
 888
 889 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 890   (setq group (nnimap-decode-gnus-group group))
 891   (cond
 892    ((null articles)
 893     nil)
 894    ((not (nnimap-change-group group server))
 895     articles)
 896    ((and force
 897          (eq nnmail-expiry-target 'delete))
 898     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 899       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 900     nil)
 901    (t
 902     (let ((deletable-articles
 903            (if (or force
 904                    (eq nnmail-expiry-wait 'immediate))
 905                articles
 906              (gnus-sorted-intersection
 907               articles
 908               (nnimap-find-expired-articles group)))))
 909       (if (null deletable-articles)
 910           articles
 911         (if (eq nnmail-expiry-target 'delete)
 912             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 913           (setq deletable-articles
 914                 (nnimap-process-expiry-targets
 915                  deletable-articles group server)))
 916         ;; Return the articles we didn't delete.
 917         (gnus-sorted-complement articles deletable-articles))))))
 918
 919 (defun nnimap-process-expiry-targets (articles group server)
 920   (let ((deleted-articles nil))
 921     (cond
 922      ;; shortcut further processing if we're going to delete the articles
 923      ((eq nnmail-expiry-target 'delete)
 924       (setq deleted-articles articles)
 925       t)
 926      ;; or just move them to another folder on the same IMAP server
 927      ((and (not (functionp nnmail-expiry-target))
 928            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
 929                               (gnus-server-to-method
 930                                (format "nnimap:%s" server))))
 931       (and (nnimap-change-group group server)
 932            (with-current-buffer (nnimap-buffer)
 933              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
 934              (nnimap-command
 935               "UID COPY %s %S"
 936               (nnimap-article-ranges (gnus-compress-sequence articles))
 937               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
 938              (setq deleted-articles articles)))
 939       t)
 940      (t
 941       (dolist (article articles)
 942         (let ((target nnmail-expiry-target))
 943           (with-temp-buffer
 944             (mm-disable-multibyte)
 945             (when (nnimap-request-article article group server (current-buffer))
 946               (when (functionp target)
 947                 (setq target (funcall target group)))
 948               (if (and target
 949                        (not (eq target 'delete)))
 950                   (if (or (gnus-request-group target t)
 951                           (gnus-request-create-group target))
 952                       (progn
 953                         (nnmail-expiry-target-group target group)
 954                         (nnheader-message 7 "Expiring article %s:%d to %s"
 955                                           group article target))
 956                     (setq target nil))
 957                 (nnheader-message 7 "Expiring article %s:%d" group article))
 958               (when target
 959                 (push article deleted-articles))))))))
 960     ;; Change back to the current group again.
 961     (nnimap-change-group group server)
 962     (setq deleted-articles (nreverse deleted-articles))
 963     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 964     deleted-articles))
 965
 966 (defun nnimap-find-expired-articles (group)
 967   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 968     (with-current-buffer (nnimap-buffer)
 969       (let ((result
 970              (nnimap-command
 971               "UID SEARCH SENTBEFORE %s"
 972               (format-time-string
 973                (format "%%d-%s-%%Y"
 974                        (upcase
 975                         (car (rassoc (nth 4 (decode-time cutoff))
 976                                      parse-time-months))))
 977                cutoff))))
 978         (and (car result)
 979              (delete 0 (mapcar #'string-to-number
 980                                (cdr (assoc "SEARCH" (cdr result))))))))))
 981
 982
 983 (defun nnimap-find-article-by-message-id (group server message-id
 984                                                 &optional limit)
 985   "Search for message with MESSAGE-ID in GROUP from SERVER.
 986 If LIMIT, first try to limit the search to the N last articles."
 987   (with-current-buffer (nnimap-buffer)
 988     (erase-buffer)
 989     (let* ((change-group-result (nnimap-change-group group server nil t))
 990            (number-of-article
 991             (and (listp change-group-result)
 992                  (catch 'found
 993                    (dolist (result (cdr change-group-result))
 994                      (when (equal "EXISTS" (cadr result))
 995                        (throw 'found (car result)))))))
 996            (sequence
 997             (nnimap-send-command
 998              "UID SEARCH%s HEADER Message-Id %S"
 999              (if (and limit number-of-article)
1000                  ;; The -1 is because IMAP message
1001                  ;; numbers are one-based rather than
1002                  ;; zero-based.
1003                  (format " %s:*" (- (string-to-number number-of-article)
1004                                     limit -1))
1005                "")
1006              message-id)))
1007       (when (nnimap-wait-for-response sequence)
1008         (let ((article (car (last (cdr (assoc "SEARCH"
1009                                               (nnimap-parse-response)))))))
1010           (if article
1011               (string-to-number article)
1012             (when (and limit number-of-article)
1013               (nnimap-find-article-by-message-id group server message-id))))))))
1014
1015 (defun nnimap-delete-article (articles)
1016   (with-current-buffer (nnimap-buffer)
1017     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
1018                     (nnimap-article-ranges articles))
1019     (cond
1020      ((nnimap-capability "UIDPLUS")
1021       (nnimap-command "UID EXPUNGE %s"
1022                       (nnimap-article-ranges articles))
1023       t)
1024      (nnimap-expunge
1025       (nnimap-command "EXPUNGE")
1026       t)
1027      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
1028                                 "server doesn't support UIDPLUS, so we won't "
1029                                 "delete this article now"))))))
1030
1031 (deffoo nnimap-request-scan (&optional group server)
1032   (when group
1033     (setq group (nnimap-decode-gnus-group group)))
1034   (when (and (nnimap-change-group nil server)
1035              nnimap-inbox
1036              nnimap-split-methods)
1037     (nnheader-message 7 "nnimap %s splitting mail..." server)
1038     (if (listp nnimap-inbox)
1039        (dolist (nnimap-inbox nnimap-inbox)
1040          (nnimap-split-incoming-mail))
1041       (nnimap-split-incoming-mail))
1042     (nnheader-message 7 "nnimap %s splitting mail...done" server)))
1043
1044 (defun nnimap-marks-to-flags (marks)
1045   (let (flags flag)
1046     (dolist (mark marks)
1047       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
1048         (push flag flags)))
1049     flags))
1050
1051 (deffoo nnimap-request-update-group-status (group status &optional server)
1052   (setq group (nnimap-decode-gnus-group group))
1053   (when (nnimap-change-group nil server)
1054     (let ((command (assoc
1055                     status
1056                     '((subscribe "SUBSCRIBE")
1057                       (unsubscribe "UNSUBSCRIBE")))))
1058       (when command
1059         (with-current-buffer (nnimap-buffer)
1060           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
1061
1062 (deffoo nnimap-request-set-mark (group actions &optional server)
1063   (setq group (nnimap-decode-gnus-group group))
1064   (when (nnimap-change-group group server)
1065     (let (sequence)
1066       (with-current-buffer (nnimap-buffer)
1067         (erase-buffer)
1068         ;; Just send all the STORE commands without waiting for
1069         ;; response.  If they're successful, they're successful.
1070         (dolist (action actions)
1071           (destructuring-bind (range action marks) action
1072             (let ((flags (nnimap-marks-to-flags marks)))
1073               (when flags
1074                 (setq sequence (nnimap-send-command
1075                                 "UID STORE %s %sFLAGS.SILENT (%s)"
1076                                 (nnimap-article-ranges range)
1077                                 (cond
1078                                  ((eq action 'del) "-")
1079                                  ((eq action 'add) "+")
1080                                  ((eq action 'set) ""))
1081                                 (mapconcat #'identity flags " ")))))))
1082         ;; Wait for the last command to complete to avoid later
1083         ;; synchronization problems with the stream.
1084         (when sequence
1085           (nnimap-wait-for-response sequence))))))
1086
1087 (deffoo nnimap-request-accept-article (group &optional server last)
1088   (setq group (nnimap-decode-gnus-group group))
1089   (when (nnimap-change-group nil server)
1090     (nnmail-check-syntax)
1091     (let ((message-id (message-field-value "message-id"))
1092           sequence message)
1093       (nnimap-add-cr)
1094       (setq message (buffer-substring-no-properties (point-min) (point-max)))
1095       (with-current-buffer (nnimap-buffer)
1096         (when (setq message (or (nnimap-process-quirk "OK Gimap " 'append message)
1097                                 message))
1098           ;; If we have this group open read-only, then unselect it
1099           ;; before appending to it.
1100           (when (equal (nnimap-examined nnimap-object) group)
1101             (nnimap-unselect-group))
1102           (erase-buffer)
1103           (setq sequence (nnimap-send-command
1104                           "APPEND %S {%d}" (utf7-encode group t)
1105                           (length message)))
1106           (unless nnimap-streaming
1107             (nnimap-wait-for-connection "^[+]"))
1108           (process-send-string (get-buffer-process (current-buffer)) message)
1109           (process-send-string (get-buffer-process (current-buffer))
1110                                (if (nnimap-newlinep nnimap-object)
1111                                    "\n"
1112                                  "\r\n"))
1113           (let ((result (nnimap-get-response sequence)))
1114             (if (not (nnimap-ok-p result))
1115                 (progn
1116                   (nnheader-report 'nnimap "%s" result)
1117                   nil)
1118               (cons group
1119                     (or (nnimap-find-uid-response "APPENDUID" (car result))
1120                         (nnimap-find-article-by-message-id
1121                          group server message-id
1122                          nnimap-request-articles-find-limit))))))))))
1123
1124 (defun nnimap-process-quirk (greeting-match type data)
1125   (when (and (nnimap-greeting nnimap-object)
1126              (string-match greeting-match (nnimap-greeting nnimap-object))
1127              (eq type 'append)
1128              (string-match "\000" data))
1129     (let ((choice (gnus-multiple-choice
1130                    "Message contains NUL characters.  Delete, continue, abort? "
1131                    '((?d "Delete NUL characters")
1132                      (?c "Try to APPEND the message as is")
1133                      (?a "Abort")))))
1134       (cond
1135        ((eq choice ?a)
1136         (nnheader-report 'nnimap "Aborted APPEND due to NUL characters"))
1137        ((eq choice ?c)
1138         data)
1139        (t
1140         (with-temp-buffer
1141           (insert data)
1142           (goto-char (point-min))
1143           (while (search-forward "\000" nil t)
1144             (replace-match "" t t))
1145           (buffer-string)))))))
1146
1147 (defun nnimap-ok-p (value)
1148   (and (consp value)
1149        (consp (car value))
1150        (equal (caar value) "OK")))
1151
1152 (defun nnimap-find-uid-response (name list)
1153   (let ((result (car (last (nnimap-find-response-element name list)))))
1154     (and result
1155          (string-to-number result))))
1156
1157 (defun nnimap-find-response-element (name list)
1158   (let (result)
1159     (dolist (elem list)
1160       (when (and (consp elem)
1161                  (equal name (car elem)))
1162         (setq result elem)))
1163     result))
1164
1165 (deffoo nnimap-request-replace-article (article group buffer)
1166   (setq group (nnimap-decode-gnus-group group))
1167   (let (group-art)
1168     (when (and (nnimap-change-group group)
1169                ;; Put the article into the group.
1170                (with-current-buffer buffer
1171                  (setq group-art
1172                        (nnimap-request-accept-article group nil t))))
1173       (nnimap-delete-article (list article))
1174       ;; Return the new article number.
1175       (cdr group-art))))
1176
1177 (defun nnimap-add-cr ()
1178   (goto-char (point-min))
1179   (while (re-search-forward "\r?\n" nil t)
1180     (replace-match "\r\n" t t)))
1181
1182 (defun nnimap-get-groups ()
1183   (erase-buffer)
1184   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1185         groups)
1186     (nnimap-wait-for-response sequence)
1187     (subst-char-in-region (point-min) (point-max)
1188                           ?\\ ?% t)
1189     (goto-char (point-min))
1190     (nnimap-unfold-quoted-lines)
1191     (goto-char (point-min))
1192     (while (search-forward "* LIST " nil t)
1193       (let ((flags (read (current-buffer)))
1194             (separator (read (current-buffer)))
1195             (group (read (current-buffer))))
1196         (unless (member '%NoSelect flags)
1197           (push (utf7-decode (if (stringp group)
1198                                  group
1199                                (format "%s" group)) t)
1200                 groups))))
1201     (nreverse groups)))
1202
1203 (defun nnimap-get-responses (sequences)
1204   (let (responses)
1205     (dolist (sequence sequences)
1206       (goto-char (point-min))
1207       (when (re-search-forward (format "^%d " sequence) nil t)
1208         (push (list sequence (nnimap-parse-response))
1209               responses)))
1210     responses))
1211
1212 (deffoo nnimap-request-list (&optional server)
1213   (when (nnimap-change-group nil server)
1214     (with-current-buffer nntp-server-buffer
1215       (erase-buffer)
1216       (let ((groups
1217              (with-current-buffer (nnimap-buffer)
1218                (nnimap-get-groups)))
1219             sequences responses)
1220         (when groups
1221           (with-current-buffer (nnimap-buffer)
1222             (setf (nnimap-group nnimap-object) nil)
1223             (dolist (group groups)
1224               (setf (nnimap-examined nnimap-object) group)
1225               (push (list (nnimap-send-command "EXAMINE %S"
1226                                                (utf7-encode group t))
1227                           group)
1228                     sequences))
1229             (nnimap-wait-for-response (caar sequences))
1230             (setq responses
1231                   (nnimap-get-responses (mapcar #'car sequences))))
1232           (dolist (response responses)
1233             (let* ((sequence (car response))
1234                    (response (cadr response))
1235                    (group (cadr (assoc sequence sequences)))
1236                    (egroup (encode-coding-string group 'utf-8)))
1237               (when (and group
1238                          (equal (caar response) "OK"))
1239                 (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1240                       highest exists)
1241                   (dolist (elem response)
1242                     (when (equal (cadr elem) "EXISTS")
1243                       (setq exists (string-to-number (car elem)))))
1244                   (when uidnext
1245                     (setq highest (1- (string-to-number (car uidnext)))))
1246                   (cond
1247                    ((null highest)
1248                     (insert (format "%S 0 1 y\n" egroup)))
1249                    ((zerop exists)
1250                     ;; Empty group.
1251                     (insert (format "%S %d %d y\n" egroup
1252                                     highest (1+ highest))))
1253                    (t
1254                     ;; Return the widest possible range.
1255                     (insert (format "%S %d 1 y\n" egroup
1256                                     (or highest exists)))))))))
1257           t)))))
1258
1259 (deffoo nnimap-request-newgroups (date &optional server)
1260   (when (nnimap-change-group nil server)
1261     (with-current-buffer nntp-server-buffer
1262       (erase-buffer)
1263       (dolist (group (with-current-buffer (nnimap-buffer)
1264                        (nnimap-get-groups)))
1265         (unless (assoc group nnimap-current-infos)
1266           ;; Insert dummy numbers here -- they don't matter.
1267           (insert (format "%S 0 1 y\n" (encode-coding-string group 'utf-8)))))
1268       t)))
1269
1270 (deffoo nnimap-retrieve-group-data-early (server infos)
1271   (when (and (nnimap-change-group nil server)
1272              infos)
1273     (with-current-buffer (nnimap-buffer)
1274       (erase-buffer)
1275       (setf (nnimap-group nnimap-object) nil)
1276       (setf (nnimap-initial-resync nnimap-object) 0)
1277       (let ((qresyncp (nnimap-capability "QRESYNC"))
1278             params groups sequences active uidvalidity modseq group
1279             unexist)
1280         ;; Go through the infos and gather the data needed to know
1281         ;; what and how to request the data.
1282         (dolist (info infos)
1283           (setq params (gnus-info-params info)
1284                 group (nnimap-decode-gnus-group
1285                        (gnus-group-real-name (gnus-info-group info)))
1286                 active (cdr (assq 'active params))
1287                 unexist (assq 'unexist (gnus-info-marks info))
1288                 uidvalidity (cdr (assq 'uidvalidity params))
1289                 modseq (cdr (assq 'modseq params)))
1290           (setf (nnimap-examined nnimap-object) group)
1291           (if (and qresyncp
1292                    uidvalidity
1293                    active
1294                    modseq
1295                    unexist)
1296               (push
1297                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1298                                           (utf7-encode group t)
1299                                           (nnimap-quirk "QRESYNC")
1300                                           uidvalidity modseq)
1301                      'qresync
1302                      nil group 'qresync)
1303                sequences)
1304             (let ((command
1305                    (if uidvalidity
1306                        "EXAMINE"
1307                      ;; If we don't have a UIDVALIDITY, then this is
1308                      ;; the first time we've seen the group, so we
1309                      ;; have to do a SELECT (which is slower than an
1310                      ;; examine), but will tell us whether the group
1311                      ;; is read-only or not.
1312                      "SELECT"))
1313                   start)
1314               (if (and active uidvalidity unexist)
1315                   ;; Fetch the last 100 flags.
1316                   (setq start (max 1 (- (cdr active) 100)))
1317                 (incf (nnimap-initial-resync nnimap-object))
1318                 (setq start 1))
1319               (push (list (nnimap-send-command "%s %S" command
1320                                                (utf7-encode group t))
1321                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1322                           start group command)
1323                     sequences))))
1324         sequences))))
1325
1326 (defun nnimap-quirk (command)
1327   (let ((quirk (assoc command nnimap-quirks)))
1328     ;; If this server is of a type that matches a quirk, then return
1329     ;; the "quirked" command instead of the proper one.
1330     (if (or (null quirk)
1331             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1332         command
1333       (nth 2 quirk))))
1334
1335 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1336   (when (and sequences
1337              (nnimap-change-group nil server t)
1338              ;; Check that the process is still alive.
1339              (get-buffer-process (nnimap-buffer))
1340              (memq (process-status (get-buffer-process (nnimap-buffer)))
1341                    '(open run)))
1342     (with-current-buffer (nnimap-buffer)
1343       ;; Wait for the final data to trickle in.
1344       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1345                                           (caar sequences)
1346                                         (cadar sequences))
1347                                       t)
1348         ;; Now we should have most of the data we need, no matter
1349         ;; whether we're QRESYNCING, fetching all the flags from
1350         ;; scratch, or just fetching the last 100 flags per group.
1351         (nnimap-update-infos (nnimap-flags-to-marks
1352                               (nnimap-parse-flags
1353                                (nreverse sequences)))
1354                              infos)
1355         ;; Finally, just return something resembling an active file in
1356         ;; the nntp buffer, so that the agent can save the info, too.
1357         (with-current-buffer nntp-server-buffer
1358           (erase-buffer)
1359           (dolist (info infos)
1360             (let* ((group (gnus-info-group info))
1361                    (active (gnus-active group)))
1362               (when active
1363                 (insert (format "%S %d %d y\n"
1364                                 (decode-coding-string
1365                                  (gnus-group-real-name group) 'utf-8)
1366                                 (cdr active)
1367                                 (car active)))))))))))
1368
1369 (defun nnimap-update-infos (flags infos)
1370   (dolist (info infos)
1371     (let* ((group (nnimap-decode-gnus-group
1372                    (gnus-group-real-name (gnus-info-group info))))
1373            (marks (cdr (assoc group flags))))
1374       (when marks
1375         (nnimap-update-info info marks)))))
1376
1377 (defun nnimap-update-info (info marks)
1378   (destructuring-bind (existing flags high low uidnext start-article
1379                                 permanent-flags uidvalidity
1380                                 vanished highestmodseq) marks
1381     (cond
1382      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1383      ;; completely empty groups.
1384      ((and (not existing)
1385            (not uidnext))
1386       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1387         (when active
1388           (gnus-set-active (gnus-info-group info) active))))
1389      ;; We have a mismatch between the old and new UIDVALIDITY
1390      ;; identifiers, so we have to re-request the group info (the next
1391      ;; time).  This virtually never happens.
1392      ((let ((old-uidvalidity
1393              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1394         (and old-uidvalidity
1395              (not (equal old-uidvalidity uidvalidity))
1396              (or (not start-article)
1397                  (> start-article 1))))
1398       (gnus-group-remove-parameter info 'uidvalidity)
1399       (gnus-group-remove-parameter info 'modseq))
1400      ;; We have the data needed to update.
1401      (t
1402       (let* ((group (gnus-info-group info))
1403              (completep (and start-article
1404                              (= start-article 1)))
1405              (active (or (gnus-active group)
1406                          (cdr (assq 'active (gnus-info-params info))))))
1407         (when uidnext
1408           (setq high (1- uidnext)))
1409         ;; First set the active ranges based on high/low.
1410         (if (or completep
1411                 (not (gnus-active group)))
1412             (gnus-set-active group
1413                              (cond
1414                               (active
1415                                (cons (min (or low (car active))
1416                                           (car active))
1417                                      (max (or high (cdr active))
1418                                           (cdr active))))
1419                               ((and low high)
1420                                (cons low high))
1421                               (uidnext
1422                                ;; No articles in this group.
1423                                (cons uidnext (1- uidnext)))
1424                               (start-article
1425                                (cons start-article (1- start-article)))
1426                               (t
1427                                ;; No articles and no uidnext.
1428                                nil)))
1429           (gnus-set-active group
1430                            (cons (car active)
1431                                  (or high (1- uidnext)))))
1432         ;; See whether this is a read-only group.
1433         (unless (eq permanent-flags 'not-scanned)
1434           (gnus-group-set-parameter
1435            info 'permanent-flags
1436            (and (or (memq '%* permanent-flags)
1437                     (memq '%Seen permanent-flags))
1438                 permanent-flags)))
1439         ;; Update marks and read articles if this isn't a
1440         ;; read-only IMAP group.
1441         (when (setq permanent-flags
1442                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1443           (if (and highestmodseq
1444                    (not start-article))
1445               ;; We've gotten the data by QRESYNCing.
1446               (nnimap-update-qresync-info
1447                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1448             ;; Do normal non-QRESYNC flag updates.
1449             ;; Update the list of read articles.
1450             (let* ((unread
1451                     (gnus-compress-sequence
1452                      (gnus-set-difference
1453                       (gnus-set-difference
1454                        existing
1455                        (cdr (assoc '%Seen flags)))
1456                       (cdr (assoc '%Flagged flags)))))
1457                    (read (gnus-range-difference
1458                           (cons start-article high) unread)))
1459               (when (> start-article 1)
1460                 (setq read
1461                       (gnus-range-nconcat
1462                        (if (> start-article 1)
1463                            (gnus-sorted-range-intersection
1464                             (cons 1 (1- start-article))
1465                             (gnus-info-read info))
1466                          (gnus-info-read info))
1467                        read)))
1468               (when (or (not (listp permanent-flags))
1469                         (memq '%Seen permanent-flags))
1470                 (gnus-info-set-read info read))
1471               ;; Update the marks.
1472               (setq marks (gnus-info-marks info))
1473               (dolist (type (cdr nnimap-mark-alist))
1474                 (when (or (not (listp permanent-flags))
1475                           (memq (car (assoc (caddr type) flags))
1476                                 permanent-flags)
1477                           (memq '%* permanent-flags))
1478                   (let ((old-marks (assoc (car type) marks))
1479                         (new-marks
1480                          (gnus-compress-sequence
1481                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1482                                    (assoc (intern (cadr type) obarray) flags)
1483                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1484                     (setq marks (delq old-marks marks))
1485                     (pop old-marks)
1486                     (when (and old-marks
1487                                (> start-article 1))
1488                       (setq old-marks (gnus-range-difference
1489                                        old-marks
1490                                        (cons start-article high)))
1491                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1492                     (when new-marks
1493                       (push (cons (car type) new-marks) marks)))))
1494               ;; Keep track of non-existing articles.
1495               (let* ((old-unexists (assq 'unexist marks))
1496                      (active (gnus-active group))
1497                      (unexists
1498                       (if completep
1499                           (gnus-range-difference
1500                            active
1501                            (gnus-compress-sequence existing))
1502                         (gnus-add-to-range
1503                          (cdr old-unexists)
1504                          (gnus-list-range-difference
1505                           existing (gnus-active group))))))
1506                 (when (> (car active) 1)
1507                   (setq unexists (gnus-range-add
1508                                   (cons 1 (1- (car active)))
1509                                   unexists)))
1510                 (if old-unexists
1511                     (setcdr old-unexists unexists)
1512                   (push (cons 'unexist unexists) marks)))
1513               (gnus-info-set-marks info marks t))))
1514         ;; Tell Gnus whether there are any \Recent messages in any of
1515         ;; the groups.
1516         (let ((recent (cdr (assoc '%Recent flags))))
1517           (when (and active
1518                      recent
1519                      (> (car (last recent)) (cdr active)))
1520             (push (list (cons (gnus-group-real-name group) 0))
1521                   nnmail-split-history)))
1522         ;; Note the active level for the next run-through.
1523         (gnus-group-set-parameter info 'active (gnus-active group))
1524         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1525         (gnus-group-set-parameter info 'modseq highestmodseq)
1526         (nnimap-store-info info (gnus-active group)))))))
1527
1528 (defun nnimap-update-qresync-info (info existing vanished flags)
1529   ;; Add all the vanished articles to the list of read articles.
1530   (gnus-info-set-read
1531    info
1532    (gnus-add-to-range
1533     (gnus-add-to-range
1534      (gnus-range-add (gnus-info-read info)
1535                      vanished)
1536      (cdr (assq '%Flagged flags)))
1537     (cdr (assq '%Seen flags))))
1538   (let ((marks (gnus-info-marks info)))
1539     (dolist (type (cdr nnimap-mark-alist))
1540       (let ((ticks (assoc (car type) marks))
1541             (new-marks
1542              (cdr (or (assoc (caddr type) flags) ; %Flagged
1543                       (assoc (intern (cadr type) obarray) flags)
1544                       (assoc (cadr type) flags))))) ; "\Flagged"
1545         (setq marks (delq ticks marks))
1546         (pop ticks)
1547         ;; Add the new marks we got.
1548         (setq ticks (gnus-add-to-range ticks new-marks))
1549         ;; Remove the marks from messages that don't have them.
1550         (setq ticks (gnus-remove-from-range
1551                      ticks
1552                      (gnus-compress-sequence
1553                       (gnus-sorted-complement existing new-marks))))
1554         (when ticks
1555           (push (cons (car type) ticks) marks)))
1556       (gnus-info-set-marks info marks t))
1557     ;; Add vanished to the list of unexisting articles.
1558     (when vanished
1559       (let* ((old-unexists (assq 'unexist marks))
1560              (unexists (gnus-range-add (cdr old-unexists) vanished)))
1561         (if old-unexists
1562             (setcdr old-unexists unexists)
1563           (push (cons 'unexist unexists) marks)))
1564       (gnus-info-set-marks info marks t))))
1565
1566 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1567   (if (zerop (length irange))
1568       nil
1569     (let ((result nil))
1570       (dolist (elem (split-string irange ","))
1571         (push
1572          (if (string-match ":" elem)
1573              (let ((numbers (split-string elem ":")))
1574                (cons (string-to-number (car numbers))
1575                      (string-to-number (cadr numbers))))
1576            (string-to-number elem))
1577          result))
1578       (nreverse result))))
1579
1580 (defun nnimap-store-info (info active)
1581   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1582          (entry (assoc group nnimap-current-infos)))
1583     (if entry
1584         (setcdr entry (list info active))
1585       (push (list group info active) nnimap-current-infos))))
1586
1587 (defun nnimap-flags-to-marks (groups)
1588   (let (data group totalp uidnext articles start-article mark permanent-flags
1589              uidvalidity vanished highestmodseq)
1590     (dolist (elem groups)
1591       (setq group (car elem)
1592             uidnext (nth 1 elem)
1593             start-article (nth 2 elem)
1594             permanent-flags (nth 3 elem)
1595             uidvalidity (nth 4 elem)
1596             vanished (nth 5 elem)
1597             highestmodseq (nth 6 elem)
1598             articles (nthcdr 7 elem))
1599       (let ((high (caar articles))
1600             marks low existing)
1601         (dolist (article articles)
1602           (setq low (car article))
1603           (push (car article) existing)
1604           (dolist (flag (cdr article))
1605             (setq mark (assoc flag marks))
1606             (if (not mark)
1607                 (push (list flag (car article)) marks)
1608               (setcdr mark (cons (car article) (cdr mark))))))
1609         (push (list group existing marks high low uidnext start-article
1610                     permanent-flags uidvalidity vanished highestmodseq)
1611               data)))
1612     data))
1613
1614 (defun nnimap-parse-flags (sequences)
1615   (goto-char (point-min))
1616   ;; Change \Delete etc to %Delete, so that the Emacs Lisp reader can
1617   ;; read it.
1618   (subst-char-in-region (point-min) (point-max)
1619                         ?\\ ?% t)
1620   ;; Remove any MODSEQ entries in the buffer, because they may contain
1621   ;; numbers that are too large for 32-bit Emacsen.
1622   (while (re-search-forward " MODSEQ ([0-9]+)" nil t)
1623     (replace-match "" t t))
1624   (goto-char (point-min))
1625   (let (start end articles groups uidnext elems permanent-flags
1626               uidvalidity vanished highestmodseq)
1627     (dolist (elem sequences)
1628       (destructuring-bind (group-sequence flag-sequence totalp group command)
1629           elem
1630         (setq start (point))
1631         (when (and
1632                ;; The EXAMINE was successful.
1633                (search-forward (format "\n%d OK " group-sequence) nil t)
1634                (progn
1635                  (forward-line 1)
1636                  (setq end (point))
1637                  (goto-char start)
1638                  (setq permanent-flags
1639                        (if (equal command "SELECT")
1640                            (and (search-forward "PERMANENTFLAGS "
1641                                                 (or end (point-min)) t)
1642                                 (read (current-buffer)))
1643                          'not-scanned))
1644                  (goto-char start)
1645                  (setq uidnext
1646                        (and (search-forward "UIDNEXT "
1647                                             (or end (point-min)) t)
1648                             (read (current-buffer))))
1649                  (goto-char start)
1650                  (setq uidvalidity
1651                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1652                                                (or end (point-min)) t)
1653                             ;; Store UIDVALIDITY as a string, as it's
1654                             ;; too big for 32-bit Emacsen, usually.
1655                             (match-string 1)))
1656                  (goto-char start)
1657                  (setq vanished
1658                        (and (eq flag-sequence 'qresync)
1659                             (re-search-forward "^\\* VANISHED .*? \\([0-9:,]+\\)"
1660                                                (or end (point-min)) t)
1661                             (match-string 1)))
1662                  (goto-char start)
1663                  (setq highestmodseq
1664                        (and (re-search-forward "HIGHESTMODSEQ \\([0-9]+\\)"
1665                                             (or end (point-min)) t)
1666                             (match-string 1)))
1667                  (goto-char end)
1668                  (forward-line -1))
1669                ;; The UID FETCH FLAGS was successful.
1670                (or (eq flag-sequence 'qresync)
1671                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1672           (if (eq flag-sequence 'qresync)
1673               (progn
1674                 (goto-char start)
1675                 (setq start end))
1676             (setq start (point))
1677             (goto-char end))
1678           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1679             (let ((p (point)))
1680               (setq elems (read (current-buffer)))
1681               (push (cons (cadr (memq 'UID elems))
1682                           (cadr (memq 'FLAGS elems)))
1683                     articles)))
1684           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1685                              vanished highestmodseq)
1686                        articles)
1687                 groups)
1688           (if (eq flag-sequence 'qresync)
1689               (goto-char end)
1690             (setq end (point)))
1691           (setq articles nil))))
1692     groups))
1693
1694 (defun nnimap-find-process-buffer (buffer)
1695   (cadr (assoc buffer nnimap-connection-alist)))
1696
1697 (deffoo nnimap-request-post (&optional server)
1698   (setq nnimap-status-string "Read-only server")
1699   nil)
1700
1701 (defvar gnus-refer-thread-use-nnir) ;; gnus-sum.el
1702 (declare-function gnus-fetch-headers "gnus-sum"
1703                   (articles &optional limit force-new dependencies))
1704
1705 (autoload 'nnir-search-thread "nnir")
1706
1707 (deffoo nnimap-request-thread (header &optional group server)
1708   (when group
1709     (setq group (nnimap-decode-gnus-group group)))
1710   (if gnus-refer-thread-use-nnir
1711       (nnir-search-thread header)
1712     (when (nnimap-change-group group server)
1713       (let* ((cmd (nnimap-make-thread-query header))
1714              (result (with-current-buffer (nnimap-buffer)
1715                        (nnimap-command  "UID SEARCH %s" cmd))))
1716         (when result
1717           (gnus-fetch-headers
1718            (and (car result)
1719                 (delete 0 (mapcar #'string-to-number
1720                                   (cdr (assoc "SEARCH" (cdr result))))))
1721            nil t))))))
1722
1723 (defun nnimap-change-group (group &optional server no-reconnect read-only)
1724   "Change group to GROUP if non-nil.
1725 If SERVER is set, check that server is connected, otherwise retry
1726 to reconnect, unless NO-RECONNECT is set to t.  Return nil if
1727 unsuccessful in connecting.
1728 If GROUP is nil, return t.
1729 If READ-ONLY is set, send EXAMINE rather than SELECT to the server.
1730 Return the server's response to the SELECT or EXAMINE command.
1731 "
1732   (let ((open-result t))
1733     (when (and server
1734                (not (nnimap-server-opened server)))
1735       (setq open-result (nnimap-open-server server nil no-reconnect)))
1736     (cond
1737      ((not open-result)
1738       nil)
1739      ((not group)
1740       t)
1741      (t
1742       (with-current-buffer (nnimap-buffer)
1743         (let ((result (nnimap-command "%s %S"
1744                                       (if read-only
1745                                           "EXAMINE"
1746                                         "SELECT")
1747                                       (utf7-encode group t))))
1748           (when (car result)
1749             (setf (nnimap-group nnimap-object) group
1750                   (nnimap-select-result nnimap-object) result)
1751             result)))))))
1752
1753 (defun nnimap-find-connection (buffer)
1754   "Find the connection delivering to BUFFER."
1755   (let ((entry (assoc buffer nnimap-connection-alist)))
1756     (when entry
1757       (if (and (buffer-name (cadr entry))
1758                (get-buffer-process (cadr entry))
1759                (memq (process-status (get-buffer-process (cadr entry)))
1760                      '(open run)))
1761           (get-buffer-process (cadr entry))
1762         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1763         nil))))
1764
1765 (defvar nnimap-sequence 0)
1766
1767 (defun nnimap-send-command (&rest args)
1768   (setf (nnimap-last-command-time nnimap-object) (current-time))
1769   (process-send-string
1770    (get-buffer-process (current-buffer))
1771    (nnimap-log-command
1772     (format "%d %s%s\n"
1773             (incf nnimap-sequence)
1774             (apply #'format args)
1775             (if (nnimap-newlinep nnimap-object)
1776                 ""
1777               "\r"))))
1778   ;; Some servers apparently can't have many outstanding
1779   ;; commands, so throttle them.
1780   (unless nnimap-streaming
1781     (nnimap-wait-for-response nnimap-sequence))
1782   nnimap-sequence)
1783
1784 (defvar nnimap-record-commands nil
1785   "If non-nil, log commands to the \"*imap log*\" buffer.")
1786
1787 (defun nnimap-log-buffer ()
1788   (let ((name "*imap log*"))
1789     (or (get-buffer name)
1790         (with-current-buffer (get-buffer-create name)
1791           (when (boundp 'window-point-insertion-type)
1792             (make-local-variable 'window-point-insertion-type)
1793             (setq window-point-insertion-type t))
1794           (current-buffer)))))
1795
1796 (defun nnimap-log-command (command)
1797   (when nnimap-record-commands
1798     (with-current-buffer (nnimap-log-buffer)
1799       (goto-char (point-max))
1800       (insert (format-time-string "%H:%M:%S")
1801               " [" nnimap-address "] "
1802               (if nnimap-inhibit-logging
1803                   "(inhibited)\n"
1804                 command))))
1805   command)
1806
1807 (defun nnimap-command (&rest args)
1808   (erase-buffer)
1809   (let* ((sequence (apply #'nnimap-send-command args))
1810          (response (nnimap-get-response sequence)))
1811     (if (equal (caar response) "OK")
1812         (cons t response)
1813       (nnheader-report 'nnimap "%s"
1814                        (mapconcat (lambda (a)
1815                                     (format "%s" a))
1816                                   (car response) " "))
1817       nil)))
1818
1819 (defun nnimap-get-response (sequence)
1820   (nnimap-wait-for-response sequence)
1821   (nnimap-parse-response))
1822
1823 (defun nnimap-wait-for-connection (&optional regexp)
1824   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1825
1826 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1827   (let ((process (get-buffer-process (current-buffer))))
1828     (goto-char (point-min))
1829     (while (and (memq (process-status process)
1830                       '(open run))
1831                 (not (re-search-forward regexp nil t)))
1832       (nnheader-accept-process-output process)
1833       (goto-char (point-min)))
1834     (forward-line -1)
1835     (and (looking-at (or response-regexp regexp))
1836          (match-string 1))))
1837
1838 (defun nnimap-wait-for-response (sequence &optional messagep)
1839   (let ((process (get-buffer-process (current-buffer)))
1840         openp)
1841     (condition-case nil
1842         (progn
1843           (goto-char (point-max))
1844           (while (and (setq openp (memq (process-status process)
1845                                         '(open run)))
1846                       (progn
1847                         ;; Skip past any "*" lines that the server has
1848                         ;; output.
1849                         (while (and (not (bobp))
1850                                     (progn
1851                                       (forward-line -1)
1852                                       (looking-at "\\*"))))
1853                         (not (looking-at (format "%d .*\n" sequence)))))
1854             (when messagep
1855               (nnheader-message-maybe
1856                7 "nnimap read %dk from %s%s" (/ (buffer-size) 1000)
1857                nnimap-address
1858                (if (not (zerop (nnimap-initial-resync nnimap-object)))
1859                    (format " (initial sync of %d group%s; please wait)"
1860                            (nnimap-initial-resync nnimap-object)
1861                            (if (= (nnimap-initial-resync nnimap-object) 1)
1862                                ""
1863                              "s"))
1864                  "")))
1865             (nnheader-accept-process-output process)
1866             (goto-char (point-max)))
1867           (setf (nnimap-initial-resync nnimap-object) 0)
1868           openp)
1869       (quit
1870        (when debug-on-quit
1871          (debug "Quit"))
1872        ;; The user hit C-g while we were waiting: kill the process, in case
1873        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1874        ;; NAT routers).
1875        (delete-process process)
1876        nil))))
1877
1878 (defun nnimap-parse-response ()
1879   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1880         result)
1881     (dolist (line lines)
1882       (push (cdr (nnimap-parse-line line)) result))
1883     ;; Return the OK/error code first, and then all the "continuation
1884     ;; lines" afterwards.
1885     (cons (pop result)
1886           (nreverse result))))
1887
1888 ;; Parse an IMAP response line lightly.  They look like
1889 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1890 ;; the lines into a list of strings and lists of string.
1891 (defun nnimap-parse-line (line)
1892   (let (char result)
1893     (with-temp-buffer
1894       (mm-disable-multibyte)
1895       (insert line)
1896       (goto-char (point-min))
1897       (while (not (eobp))
1898         (if (eql (setq char (following-char)) ? )
1899             (forward-char 1)
1900           (push
1901            (cond
1902             ((eql char ?\[)
1903              (split-string
1904               (buffer-substring
1905                (1+ (point))
1906                (if (search-forward "]" (line-end-position) 'move)
1907                    (1- (point))
1908                  (point)))))
1909             ((eql char ?\()
1910              (split-string
1911               (buffer-substring
1912                (1+ (point))
1913                (if (search-forward ")" (line-end-position) 'move)
1914                    (1- (point))
1915                  (point)))))
1916             ((eql char ?\")
1917              (forward-char 1)
1918              (buffer-substring
1919               (point)
1920               (1- (or (search-forward "\"" (line-end-position) 'move)
1921                       (point)))))
1922             (t
1923              (buffer-substring (point) (if (search-forward " " nil t)
1924                                            (1- (point))
1925                                          (goto-char (point-max))))))
1926            result)))
1927       (nreverse result))))
1928
1929 (defun nnimap-last-response-string ()
1930   (save-excursion
1931     (forward-line 1)
1932     (let ((end (point)))
1933       (forward-line -1)
1934       (when (not (bobp))
1935         (forward-line -1)
1936         (while (and (not (bobp))
1937                     (eql (following-char) ?*))
1938           (forward-line -1))
1939         (unless (eql (following-char) ?*)
1940           (forward-line 1)))
1941       (buffer-substring (point) end))))
1942
1943 (defvar nnimap-incoming-split-list nil)
1944
1945 (defun nnimap-fetch-inbox (articles)
1946   (erase-buffer)
1947   (nnimap-wait-for-response
1948    (nnimap-send-command
1949     "UID FETCH %s %s"
1950     (nnimap-article-ranges articles)
1951     (format "(UID %s%s)"
1952             (format
1953              (if (nnimap-ver4-p)
1954                  "BODY.PEEK"
1955                "RFC822.PEEK"))
1956             (cond
1957              (nnimap-split-download-body-default
1958               "[]")
1959              ((nnimap-ver4-p)
1960               "[HEADER]")
1961              (t
1962               "[1]"))))
1963    t))
1964
1965 (defun nnimap-split-incoming-mail ()
1966   (with-current-buffer (nnimap-buffer)
1967     (let ((nnimap-incoming-split-list nil)
1968           (nnmail-split-methods
1969            (cond
1970             ((eq nnimap-split-methods 'default)
1971              nnmail-split-methods)
1972             (nnimap-split-methods
1973              nnimap-split-methods)
1974             (nnimap-split-fancy
1975              'nnmail-split-fancy)))
1976           (nnmail-split-fancy (or nnimap-split-fancy
1977                                   nnmail-split-fancy))
1978           (nnmail-inhibit-default-split-group t)
1979           (groups (nnimap-get-groups))
1980           new-articles)
1981       (erase-buffer)
1982       (nnimap-command "SELECT %S" nnimap-inbox)
1983       (setf (nnimap-group nnimap-object) nnimap-inbox)
1984       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1985       (when new-articles
1986         (nnimap-fetch-inbox new-articles)
1987         (nnimap-transform-split-mail)
1988         (nnheader-ms-strip-cr)
1989         (nnmail-cache-open)
1990         (nnmail-split-incoming (current-buffer)
1991                                #'nnimap-save-mail-spec
1992                                nil nil
1993                                #'nnimap-dummy-active-number
1994                                #'nnimap-save-mail-spec)
1995         (when nnimap-incoming-split-list
1996           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1997                 sequences junk-articles)
1998             ;; Create any groups that doesn't already exist on the
1999             ;; server first.
2000             (dolist (spec specs)
2001               (when (and (not (member (car spec) groups))
2002                          (not (eq (car spec) 'junk)))
2003                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
2004             ;; Then copy over all the messages.
2005             (erase-buffer)
2006             (dolist (spec specs)
2007               (let ((group (car spec))
2008                     (ranges (cdr spec)))
2009                 (if (eq group 'junk)
2010                     (setq junk-articles ranges)
2011                   (push (list (nnimap-send-command
2012                                "UID COPY %s %S"
2013                                (nnimap-article-ranges ranges)
2014                                (utf7-encode group t))
2015                               ranges)
2016                         sequences))))
2017             ;; Wait for the last COPY response...
2018             (when sequences
2019               (nnimap-wait-for-response (caar sequences))
2020               ;; And then mark the successful copy actions as deleted,
2021               ;; and possibly expunge them.
2022               (nnimap-mark-and-expunge-incoming
2023                (nnimap-parse-copied-articles sequences)))
2024             (nnimap-mark-and-expunge-incoming junk-articles)))))))
2025
2026 (defun nnimap-mark-and-expunge-incoming (range)
2027   (when range
2028     (setq range (nnimap-article-ranges range))
2029     (erase-buffer)
2030     (let ((sequence
2031            (nnimap-send-command
2032             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
2033       (cond
2034        ;; If the server supports it, we now delete the message we have
2035        ;; just copied over.
2036        ((nnimap-capability "UIDPLUS")
2037         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
2038        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
2039        ;; user has configured it.
2040        (nnimap-expunge
2041         (setq sequence (nnimap-send-command "EXPUNGE"))))
2042       (nnimap-wait-for-response sequence))))
2043
2044 (defun nnimap-parse-copied-articles (sequences)
2045   (let (sequence copied range)
2046     (goto-char (point-min))
2047     (while (re-search-forward "^\\([0-9]+\\) OK\\b" nil t)
2048       (setq sequence (string-to-number (match-string 1)))
2049       (when (setq range (cadr (assq sequence sequences)))
2050         (push (gnus-uncompress-range range) copied)))
2051     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
2052
2053 (defun nnimap-new-articles (flags)
2054   (let (new)
2055     (dolist (elem flags)
2056       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
2057                                       (cdr elem))
2058         (push (car elem) new)))
2059     (gnus-compress-sequence (nreverse new))))
2060
2061 (defun nnimap-make-split-specs (list)
2062   (let ((specs nil)
2063         entry)
2064     (dolist (elem list)
2065       (destructuring-bind (article spec) elem
2066         (dolist (group (delete nil (mapcar #'car spec)))
2067           (unless (setq entry (assoc group specs))
2068             (push (setq entry (list group)) specs))
2069           (setcdr entry (cons article (cdr entry))))))
2070     (dolist (entry specs)
2071       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
2072     specs))
2073
2074 (defun nnimap-transform-split-mail ()
2075   (goto-char (point-min))
2076   (let (article bytes)
2077     (block nil
2078       (while (not (eobp))
2079         (while (not (looking-at "\\* [0-9]+ FETCH.+UID \\([0-9]+\\)"))
2080           (delete-region (point) (progn (forward-line 1) (point)))
2081           (when (eobp)
2082             (return)))
2083         (setq article (match-string 1)
2084               bytes (nnimap-get-length))
2085         (delete-region (line-beginning-position) (line-end-position))
2086         ;; Insert MMDF separator, and a way to remember what this
2087         ;; article UID is.
2088         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
2089         (forward-char (1+ bytes))
2090         (setq bytes (nnimap-get-length))
2091         (delete-region (line-beginning-position) (line-end-position))
2092         ;; There's a body; skip past that.
2093         (when bytes
2094           (forward-char (1+ bytes))
2095           (delete-region (line-beginning-position) (line-end-position)))))))
2096
2097 (defun nnimap-dummy-active-number (group &optional server)
2098   1)
2099
2100 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
2101   (let (article)
2102     (goto-char (point-min))
2103     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
2104         (error "Invalid nnimap mail")
2105       (setq article (string-to-number (match-string 1))))
2106     (push (list article
2107                 (if (eq group-art 'junk)
2108                     (list (cons 'junk 1))
2109                   group-art))
2110           nnimap-incoming-split-list)))
2111
2112 (defun nnimap-make-thread-query (header)
2113   (let* ((id  (mail-header-id header))
2114          (refs (split-string
2115                 (or (mail-header-references header)
2116                     "")))
2117          (value
2118           (format
2119            "(OR HEADER REFERENCES %S HEADER Message-Id %S)"
2120            id id)))
2121     (dolist (refid refs value)
2122       (setq value (format
2123                    "(OR (OR HEADER Message-Id %S HEADER REFERENCES %S) %s)"
2124                    refid refid value)))))
2125
2126
2127 (provide 'nnimap)
2128
2129 ;;; nnimap.el ends here