cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40 (require 'parse-time)
  41
  42 (nnoo-declare nnimap)
  43
  44 (defvoo nnimap-address nil
  45   "The address of the IMAP server.")
  46
  47 (defvoo nnimap-server-port nil
  48   "The IMAP port used.
  49 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  50 it will default to `imap'.")
  51
  52 (defvoo nnimap-stream 'ssl
  53   "How nnimap will talk to the IMAP server.
  54 Values are `ssl' and `network'.")
  55
  56 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  57                                  (if (listp imap-shell-program)
  58                                      (car imap-shell-program)
  59                                    imap-shell-program)
  60                                "ssh %s imapd"))
  61
  62 (defvoo nnimap-inbox nil
  63   "The mail box where incoming mail arrives and should be split out of.")
  64
  65 (defvoo nnimap-authenticator nil
  66   "How nnimap authenticate itself to the server.
  67 Possible choices are nil (use default methods) or `anonymous'.")
  68
  69 (defvoo nnimap-fetch-partial-articles nil
  70   "If non-nil, nnimap will fetch partial articles.
  71 If t, nnimap will fetch only the first part.  If a string, it
  72 will fetch all parts that have types that match that string.  A
  73 likely value would be \"text/\" to automatically fetch all
  74 textual parts.")
  75
  76 (defvoo nnimap-expunge t
  77   "If non-nil, expunge articles after deleting them.
  78 This is always done if the server supports UID EXPUNGE, but it's
  79 not done by default on servers that doesn't support that command.")
  80
  81
  82 (defvoo nnimap-connection-alist nil)
  83
  84 (defvoo nnimap-current-infos nil)
  85
  86 (defvar nnimap-process nil)
  87
  88 (defvar nnimap-status-string "")
  89
  90 (defvar nnimap-split-download-body-default nil
  91   "Internal variable with default value for `nnimap-split-download-body'.")
  92
  93 (defstruct nnimap
  94   group process commands capabilities select-result newlinep)
  95
  96 (defvar nnimap-object nil)
  97
  98 (defvar nnimap-mark-alist
  99   '((read "\\Seen")
 100     (tick "\\Flagged")
 101     (reply "\\Answered")
 102     (expire "gnus-expire")
 103     (dormant "gnus-dormant")
 104     (score "gnus-score")
 105     (save "gnus-save")
 106     (download "gnus-download")
 107     (forward "gnus-forward")))
 108
 109 (defvar nnimap-split-methods nil)
 110
 111 (defun nnimap-buffer ()
 112   (nnimap-find-process-buffer nntp-server-buffer))
 113
 114 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 115   (with-current-buffer nntp-server-buffer
 116     (erase-buffer)
 117     (when (nnimap-possibly-change-group group server)
 118       (with-current-buffer (nnimap-buffer)
 119         (nnimap-send-command "SELECT %S" (utf7-encode group t))
 120         (erase-buffer)
 121         (nnimap-wait-for-response
 122          (nnimap-send-command
 123           "UID FETCH %s %s"
 124           (nnimap-article-ranges (gnus-compress-sequence articles))
 125           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 126                   (format
 127                    (if (member "IMAP4REV1"
 128                                (nnimap-capabilities nnimap-object))
 129                        "BODY.PEEK[HEADER.FIELDS %s]"
 130                      "RFC822.HEADER.LINES %s")
 131                    (append '(Subject From Date Message-Id
 132                                      References In-Reply-To Xref)
 133                            nnmail-extra-headers))))
 134          t)
 135         (nnimap-transform-headers))
 136       (insert-buffer-substring
 137        (nnimap-find-process-buffer (current-buffer))))
 138     t))
 139
 140 (defun nnimap-transform-headers ()
 141   (goto-char (point-min))
 142   (let (article bytes lines size)
 143     (block nil
 144       (while (not (eobp))
 145         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 146           (delete-region (point) (progn (forward-line 1) (point)))
 147           (when (eobp)
 148             (return)))
 149         (setq article (match-string 1)
 150               bytes (nnimap-get-length)
 151               lines nil)
 152         (beginning-of-line)
 153         (setq size
 154               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 155                                       (line-end-position)
 156                                       t)
 157                    (match-string 1)))
 158         (beginning-of-line)
 159         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 160           (let ((structure (ignore-errors (read (current-buffer)))))
 161             (while (and (consp structure)
 162                         (not (stringp (car structure))))
 163               (setq structure (car structure)))
 164             (setq lines (nth 7 structure))))
 165         (delete-region (line-beginning-position) (line-end-position))
 166         (insert (format "211 %s Article retrieved." article))
 167         (forward-line 1)
 168         (when size
 169           (insert (format "Chars: %s\n" size)))
 170         (when lines
 171           (insert (format "Lines: %s\n" lines)))
 172         (re-search-forward "^\r$")
 173         (delete-region (line-beginning-position) (line-end-position))
 174         (insert ".")
 175         (forward-line 1)))))
 176
 177 (defun nnimap-get-length ()
 178   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 179        (string-to-number (match-string 1))))
 180
 181 (defun nnimap-article-ranges (ranges)
 182   (let (result)
 183     (cond
 184      ((numberp ranges)
 185       (number-to-string ranges))
 186      ((numberp (cdr ranges))
 187       (format "%d:%d" (car ranges) (cdr ranges)))
 188      (t
 189       (dolist (elem ranges)
 190         (push
 191          (if (consp elem)
 192              (format "%d:%d" (car elem) (cdr elem))
 193            (number-to-string elem))
 194          result))
 195       (mapconcat #'identity (nreverse result) ",")))))
 196
 197 (deffoo nnimap-open-server (server &optional defs)
 198   (if (nnimap-server-opened server)
 199       t
 200     (unless (assq 'nnimap-address defs)
 201       (setq defs (append defs (list (list 'nnimap-address server)))))
 202     (nnoo-change-server 'nnimap server defs)
 203     (or (nnimap-find-connection nntp-server-buffer)
 204         (nnimap-open-connection nntp-server-buffer))))
 205
 206 (defun nnimap-make-process-buffer (buffer)
 207   (with-current-buffer
 208       (generate-new-buffer (format "*nnimap %s %s %s*"
 209                                    nnimap-address nnimap-server-port
 210                                    (gnus-buffer-exists-p buffer)))
 211     (mm-disable-multibyte)
 212     (buffer-disable-undo)
 213     (gnus-add-buffer)
 214     (set (make-local-variable 'after-change-functions) nil)
 215     (set (make-local-variable 'nnimap-object) (make-nnimap))
 216     (push (list buffer (current-buffer)) nnimap-connection-alist)
 217     (current-buffer)))
 218
 219 (defun nnimap-open-shell-stream (name buffer host port)
 220   (let ((process-connection-type nil))
 221     (start-process name buffer shell-file-name
 222                    shell-command-switch
 223                    (format-spec
 224                     nnimap-shell-program
 225                     (format-spec-make
 226                      ?s host
 227                      ?p port)))))
 228
 229 (defun nnimap-credentials (address ports)
 230   (let (port credentials)
 231     ;; Request the credentials from all ports, but only query on the
 232     ;; last port if all the previous ones have failed.
 233     (while (and (null credentials)
 234                 (setq port (pop ports)))
 235       (setq credentials
 236             (auth-source-user-or-password
 237              '("login" "password") address port nil (null ports))))
 238     credentials))
 239
 240 (defun nnimap-open-connection (buffer)
 241   (with-current-buffer (nnimap-make-process-buffer buffer)
 242     (let* ((coding-system-for-read 'binary)
 243            (coding-system-for-write 'binary)
 244            (ports
 245             (cond
 246              ((eq nnimap-stream 'network)
 247               (open-network-stream
 248                "*nnimap*" (current-buffer) nnimap-address
 249                (or nnimap-server-port
 250                    (if (netrc-find-service-number "imap")
 251                        "imap"
 252                      "143")))
 253               '("143" "imap"))
 254              ((eq nnimap-stream 'shell)
 255               (nnimap-open-shell-stream
 256                "*nnimap*" (current-buffer) nnimap-address
 257                (or nnimap-server-port "imap"))
 258               '("imap"))
 259              ((eq nnimap-stream 'ssl)
 260               (open-tls-stream
 261                "*nnimap*" (current-buffer) nnimap-address
 262                (or nnimap-server-port
 263                    (if (netrc-find-service-number "imaps")
 264                        "imaps"
 265                      "993")))
 266               '("143" "993" "imap" "imaps"))))
 267            connection-result login-result credentials)
 268       (setf (nnimap-process nnimap-object)
 269             (get-buffer-process (current-buffer)))
 270       (when (and (nnimap-process nnimap-object)
 271                  (memq (process-status (nnimap-process nnimap-object))
 272                        '(open run)))
 273         (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 274         (when (setq connection-result (nnimap-wait-for-connection))
 275           (unless (equal connection-result "PREAUTH")
 276             (if (not (setq credentials
 277                            (if (eq nnimap-authenticator 'anonymous)
 278                                (list "anonymous"
 279                                      (message-make-address))
 280                              (nnimap-credentials
 281                               nnimap-address
 282                               (if nnimap-server-port
 283                                   (cons (format "%s" nnimap-server-port) ports)
 284                                 ports)))))
 285                 (setq nnimap-object nil)
 286               (setq login-result (nnimap-command "LOGIN %S %S"
 287                                                  (car credentials)
 288                                                  (cadr credentials)))
 289               (unless (car login-result)
 290                 (delete-process (nnimap-process nnimap-object))
 291                 (setq nnimap-object nil))))
 292           (when nnimap-object
 293             (setf (nnimap-capabilities nnimap-object)
 294                   (mapcar
 295                    #'upcase
 296                    (or (nnimap-find-parameter "CAPABILITY" (cdr login-result))
 297                        (nnimap-find-parameter
 298                         "CAPABILITY" (cdr (nnimap-command "CAPABILITY"))))))
 299             (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 300               (nnimap-command "ENABLE QRESYNC"))
 301             t))))))
 302
 303 (defun nnimap-find-parameter (parameter elems)
 304   (let (result)
 305     (dolist (elem elems)
 306       (cond
 307        ((equal (car elem) parameter)
 308         (setq result (cdr elem)))
 309        ((and (equal (car elem) "OK")
 310              (consp (cadr elem))
 311              (equal (caadr elem) parameter))
 312         (setq result (cdr (cadr elem))))))
 313     result))
 314
 315 (deffoo nnimap-close-server (&optional server)
 316   t)
 317
 318 (deffoo nnimap-request-close ()
 319   t)
 320
 321 (deffoo nnimap-server-opened (&optional server)
 322   (and (nnoo-current-server-p 'nnimap server)
 323        nntp-server-buffer
 324        (gnus-buffer-live-p nntp-server-buffer)
 325        (nnimap-find-connection nntp-server-buffer)))
 326
 327 (deffoo nnimap-status-message (&optional server)
 328   nnimap-status-string)
 329
 330 (deffoo nnimap-request-article (article &optional group server to-buffer)
 331   (with-current-buffer nntp-server-buffer
 332     (let ((result (nnimap-possibly-change-group group server))
 333           parts)
 334       (when (stringp article)
 335         (setq article (nnimap-find-article-by-message-id group article)))
 336       (when (and result
 337                  article)
 338         (erase-buffer)
 339         (with-current-buffer (nnimap-buffer)
 340           (erase-buffer)
 341           (when nnimap-fetch-partial-articles
 342             (if (eq nnimap-fetch-partial-articles t)
 343                 (setq parts '(1))
 344               (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 345               (goto-char (point-min))
 346               (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 347                 (let ((structure (ignore-errors (read (current-buffer)))))
 348                   (setq parts (nnimap-find-wanted-parts structure))))))
 349           (setq result
 350                 (nnimap-command
 351                  (if (member "IMAP4REV1" (nnimap-capabilities nnimap-object))
 352                      "UID FETCH %d BODY.PEEK[]"
 353                    "UID FETCH %d RFC822.PEEK")
 354                  article))
 355           ;; Check that we really got an article.
 356           (goto-char (point-min))
 357           (unless (looking-at "\\* [0-9]+ FETCH")
 358             (setq result nil)))
 359         (let ((buffer (nnimap-find-process-buffer (current-buffer))))
 360           (when (car result)
 361             (with-current-buffer (or to-buffer nntp-server-buffer)
 362               (insert-buffer-substring buffer)
 363               (goto-char (point-min))
 364               (let ((bytes (nnimap-get-length)))
 365                 (delete-region (line-beginning-position)
 366                                (progn (forward-line 1) (point)))
 367                 (goto-char (+ (point) bytes))
 368                 (delete-region (point) (point-max))
 369                 (nnheader-ms-strip-cr))
 370               (cons group article))))))))
 371
 372 (defun nnimap-find-wanted-parts (structure)
 373   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 374
 375 (defun nnimap-find-wanted-parts-1 (structure prefix)
 376   (let ((num 1)
 377         parts)
 378     (while (consp (car structure))
 379       (let ((sub (pop structure)))
 380         (if (consp (car sub))
 381             (push (nnimap-find-wanted-parts-1
 382                    sub (if (string= prefix "")
 383                            (number-to-string num)
 384                          (format "%s.%s" prefix num)))
 385                   parts)
 386           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub))))
 387             (when (string-match nnimap-fetch-partial-articles type)
 388               (push (if (string= prefix "")
 389                         (number-to-string num)
 390                       (format "%s.%s" prefix num))
 391                     parts)))
 392           (incf num))))
 393     (nreverse parts)))
 394
 395 (deffoo nnimap-request-group (group &optional server dont-check info)
 396   (let ((result (nnimap-possibly-change-group group server))
 397         articles active marks high low)
 398     (with-current-buffer nntp-server-buffer
 399       (when result
 400         (if (and dont-check
 401                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 402             (insert (format "211 %d %d %d %S\n"
 403                             (- (cdr active) (car active))
 404                             (car active)
 405                             (cdr active)
 406                             group))
 407           (with-current-buffer (nnimap-buffer)
 408             (erase-buffer)
 409             (let ((group-sequence
 410                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 411                   (flag-sequence
 412                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 413               (nnimap-wait-for-response flag-sequence)
 414               (setq marks
 415                     (nnimap-flags-to-marks
 416                      (nnimap-parse-flags
 417                       (list (list group-sequence flag-sequence 1 group)))))
 418               (when info
 419                 (nnimap-update-infos marks (list info)))
 420               (goto-char (point-max))
 421               (cond
 422                (marks
 423                 (setq high (nth 3 (car marks))
 424                       low (nth 4 (car marks))))
 425                ((re-search-backward "UIDNEXT \\([0-9]+\\)" nil t)
 426                 (setq high (1- (string-to-number (match-string 1)))
 427                       low 1)))))
 428           (erase-buffer)
 429           (insert
 430            (format
 431             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 432         t))))
 433
 434 (deffoo nnimap-request-create-group (group &optional server args)
 435   (when (nnimap-possibly-change-group nil server)
 436     (with-current-buffer (nnimap-buffer)
 437       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 438
 439 (deffoo nnimap-request-delete-group (group &optional force server)
 440   (when (nnimap-possibly-change-group nil server)
 441     (with-current-buffer (nnimap-buffer)
 442       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 443
 444 (deffoo nnimap-request-expunge-group (group &optional server)
 445   (when (nnimap-possibly-change-group group server)
 446     (with-current-buffer (nnimap-buffer)
 447       (car (nnimap-command "EXPUNGE")))))
 448
 449 (defun nnimap-get-flags (spec)
 450   (let ((articles nil)
 451         elems)
 452     (with-current-buffer (nnimap-buffer)
 453       (erase-buffer)
 454       (nnimap-wait-for-response (nnimap-send-command
 455                                  "UID FETCH %s FLAGS" spec))
 456       (goto-char (point-min))
 457       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 458         (setq elems (nnimap-parse-line (match-string 1)))
 459         (push (cons (string-to-number (cadr (member "UID" elems)))
 460                     (cadr (member "FLAGS" elems)))
 461               articles)))
 462     (nreverse articles)))
 463
 464 (deffoo nnimap-close-group (group &optional server)
 465   t)
 466
 467 (deffoo nnimap-request-move-article (article group server accept-form
 468                                              &optional last internal-move-group)
 469   (with-temp-buffer
 470     (when (nnimap-request-article article group server (current-buffer))
 471       ;; If the move is internal (on the same server), just do it the easy
 472       ;; way.
 473       (let ((message-id (message-field-value "message-id")))
 474         (if internal-move-group
 475             (let ((result
 476                    (with-current-buffer (nnimap-buffer)
 477                      (nnimap-command "UID COPY %d %S"
 478                                      article
 479                                      (utf7-encode internal-move-group t)))))
 480               (when (car result)
 481                 (nnimap-delete-article article)
 482                 (cons internal-move-group
 483                       (nnimap-find-article-by-message-id
 484                        internal-move-group message-id))))
 485           ;; Move the article to a different method.
 486           (let ((result (eval accept-form)))
 487             (when result
 488               (nnimap-delete-article article)
 489               result)))))))
 490
 491 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 492   (cond
 493    ((null articles)
 494     nil)
 495    ((not (nnimap-possibly-change-group group server))
 496     articles)
 497    ((and force
 498          (eq nnmail-expiry-target 'delete))
 499     (unless (nnimap-delete-article articles)
 500       (message "Article marked for deletion, but not expunged."))
 501     nil)
 502    (t
 503     (let ((deletable-articles
 504            (if force
 505                articles
 506              (gnus-sorted-intersection
 507               articles
 508               (nnimap-find-expired-articles group)))))
 509       (if (null deletable-articles)
 510           articles
 511         (if (eq nnmail-expiry-target 'delete)
 512             (nnimap-delete-article deletable-articles)
 513           (setq deletable-articles
 514                 (nnimap-process-expiry-targets
 515                  deletable-articles group server)))
 516         ;; Return the articles we didn't delete.
 517         (gnus-sorted-complement articles deletable-articles))))))
 518
 519 (defun nnimap-process-expiry-targets (articles group server)
 520   (let ((deleted-articles nil))
 521     (dolist (article articles)
 522       (let ((target nnmail-expiry-target))
 523         (with-temp-buffer
 524           (when (nnimap-request-article article group server (current-buffer))
 525             (message "Expiring article %s:%d" group article)
 526             (when (functionp target)
 527               (setq target (funcall target group)))
 528             (when (and target
 529                        (not (eq target 'delete)))
 530               (if (or (gnus-request-group target t)
 531                       (gnus-request-create-group target))
 532                   (nnmail-expiry-target-group target group)
 533                 (setq target nil)))
 534             (when target
 535               (push article deleted-articles))))))
 536     ;; Change back to the current group again.
 537     (nnimap-possibly-change-group group server)
 538     (setq deleted-articles (nreverse deleted-articles))
 539     (nnimap-delete-article deleted-articles)
 540     deleted-articles))
 541
 542 (defun nnimap-find-expired-articles (group)
 543   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 544     (with-current-buffer (nnimap-buffer)
 545       (let ((result
 546              (nnimap-command
 547               "UID SEARCH SENTBEFORE %s"
 548               (format-time-string
 549                (format "%%d-%s-%%Y"
 550                        (upcase
 551                         (car (rassoc (nth 4 (decode-time cutoff))
 552                                      parse-time-months))))
 553                cutoff))))
 554         (and (car result)
 555              (delete 0 (mapcar #'string-to-number
 556                                (cdr (assoc "SEARCH" (cdr result))))))))))
 557
 558
 559 (defun nnimap-find-article-by-message-id (group message-id)
 560   (when (nnimap-possibly-change-group group nil)
 561     (with-current-buffer (nnimap-buffer)
 562       (let ((result
 563              (nnimap-command "UID SEARCH HEADER Message-Id %S" message-id))
 564             article)
 565         (when (car result)
 566           ;; Select the last instance of the message in the group.
 567           (and (setq article
 568                      (car (last (assoc "SEARCH" (cdr result)))))
 569                (string-to-number article)))))))
 570
 571 (defun nnimap-delete-article (articles)
 572   (with-current-buffer (nnimap-buffer)
 573     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 574                     (nnimap-article-ranges articles))
 575     (cond
 576      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
 577       (nnimap-command "UID EXPUNGE %s"
 578                       (nnimap-article-ranges articles))
 579       t)
 580      (nnimap-expunge
 581       (nnimap-command "EXPUNGE")
 582       t)
 583      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 584                                 "server doesn't support UIDPLUS, so we won't "
 585                                 "delete this article now"))))))
 586
 587 (deffoo nnimap-request-scan (&optional group server)
 588   (when (and (nnimap-possibly-change-group nil server)
 589              (equal group nnimap-inbox)
 590              nnimap-inbox
 591              nnimap-split-methods)
 592     (nnimap-split-incoming-mail)))
 593
 594 (defun nnimap-marks-to-flags (marks)
 595   (let (flags flag)
 596     (dolist (mark marks)
 597       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 598         (push flag flags)))
 599     flags))
 600
 601 (deffoo nnimap-request-set-mark (group actions &optional server)
 602   (when (nnimap-possibly-change-group group server)
 603     (let (sequence)
 604       (with-current-buffer (nnimap-buffer)
 605         ;; Just send all the STORE commands without waiting for
 606         ;; response.  If they're successful, they're successful.
 607         (dolist (action actions)
 608           (destructuring-bind (range action marks) action
 609             (let ((flags (nnimap-marks-to-flags marks)))
 610               (when flags
 611                 (setq sequence (nnimap-send-command
 612                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 613                                 (nnimap-article-ranges range)
 614                                 (if (eq action 'del)
 615                                     "-"
 616                                   "+")
 617                                 (mapconcat #'identity flags " ")))))))
 618         ;; Wait for the last command to complete to avoid later
 619         ;; syncronisation problems with the stream.
 620         (when sequence
 621           (nnimap-wait-for-response sequence))))))
 622
 623 (deffoo nnimap-request-accept-article (group &optional server last)
 624   (when (nnimap-possibly-change-group nil server)
 625     (nnmail-check-syntax)
 626     (let ((message (buffer-string))
 627           (message-id (message-field-value "message-id"))
 628           sequence)
 629       (with-current-buffer (nnimap-buffer)
 630         (setq sequence (nnimap-send-command
 631                         "APPEND %S {%d}" (utf7-encode group t)
 632                         (length message)))
 633         (process-send-string (get-buffer-process (current-buffer)) message)
 634         (process-send-string (get-buffer-process (current-buffer))
 635                              (if (nnimap-newlinep nnimap-object)
 636                                  "\n"
 637                                "\r\n"))
 638         (let ((result (nnimap-get-response sequence)))
 639           (when result
 640             (cons group
 641                   (nnimap-find-article-by-message-id group message-id))))))))
 642
 643 (defun nnimap-add-cr ()
 644   (goto-char (point-min))
 645   (while (re-search-forward "\r?\n" nil t)
 646     (replace-match "\r\n" t t)))
 647
 648 (defun nnimap-get-groups ()
 649   (let ((result (nnimap-command "LIST \"\" \"*\""))
 650         groups)
 651     (when (car result)
 652       (dolist (line (cdr result))
 653         (when (and (equal (car line) "LIST")
 654                    (not (and (caadr line)
 655                              (string-match "noselect" (caadr line)))))
 656           (push (car (last line)) groups)))
 657       (nreverse groups))))
 658
 659 (deffoo nnimap-request-list (&optional server)
 660   (nnimap-possibly-change-group nil server)
 661   (with-current-buffer nntp-server-buffer
 662     (erase-buffer)
 663     (let ((groups
 664            (with-current-buffer (nnimap-buffer)
 665              (nnimap-get-groups)))
 666           sequences responses)
 667       (when groups
 668         (with-current-buffer (nnimap-buffer)
 669           (dolist (group groups)
 670             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 671                         group)
 672                   sequences))
 673           (nnimap-wait-for-response (caar sequences))
 674           (setq responses
 675                 (nnimap-get-responses (mapcar #'car sequences))))
 676         (dolist (response responses)
 677           (let* ((sequence (car response))
 678                  (response (cadr response))
 679                  (group (cadr (assoc sequence sequences))))
 680             (when (and group
 681                        (equal (caar response) "OK"))
 682               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 683                     highest exists)
 684                 (dolist (elem response)
 685                   (when (equal (cadr elem) "EXISTS")
 686                     (setq exists (string-to-number (car elem)))))
 687                 (when uidnext
 688                   (setq highest (1- (string-to-number (car uidnext)))))
 689                 (cond
 690                  ((null highest)
 691                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 692                  ((zerop exists)
 693                   ;; Empty group.
 694                   (insert (format "%S %d %d y\n"
 695                                   (utf7-decode group t) highest (1+ highest))))
 696                  (t
 697                   ;; Return the widest possible range.
 698                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 699                                   (or highest exists)))))))))
 700         t))))
 701
 702 (deffoo nnimap-retrieve-group-data-early (server infos)
 703   (when (nnimap-possibly-change-group nil server)
 704     (with-current-buffer (nnimap-buffer)
 705       ;; QRESYNC handling isn't implemented.
 706       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 707             marks groups sequences)
 708         ;; Go through the infos and gather the data needed to know
 709         ;; what and how to request the data.
 710         (dolist (info infos)
 711           (setq marks (gnus-info-marks info))
 712           (push (list (gnus-group-real-name (gnus-info-group info))
 713                       (cdr (assq 'active marks))
 714                       (cdr (assq 'uid marks)))
 715                 groups))
 716         ;; Then request the data.
 717         (erase-buffer)
 718         (dolist (elem groups)
 719           (if (and qresyncp
 720                    (nth 2 elem))
 721               (push
 722                (list 'qresync
 723                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 724                                           (car elem)
 725                                           (car (nth 2 elem))
 726                                           (cdr (nth 2 elem)))
 727                      nil
 728                      (car elem))
 729                sequences)
 730             (let ((start
 731                    (if (nth 1 elem)
 732                        ;; Fetch the last 100 flags.
 733                        (max 1 (- (cdr (nth 1 elem)) 100))
 734                      1)))
 735               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 736                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 737                           start
 738                           (car elem))
 739                     sequences))))
 740         sequences))))
 741
 742 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 743   (when (and sequences
 744              (nnimap-possibly-change-group nil server))
 745     (with-current-buffer (nnimap-buffer)
 746       ;; Wait for the final data to trickle in.
 747       (nnimap-wait-for-response (cadar sequences))
 748       ;; Now we should have all the data we need, no matter whether
 749       ;; we're QRESYNCING, fetching all the flags from scratch, or
 750       ;; just fetching the last 100 flags per group.
 751       (nnimap-update-infos (nnimap-flags-to-marks
 752                             (nnimap-parse-flags
 753                              (nreverse sequences)))
 754                            infos)
 755       ;; Finally, just return something resembling an active file in
 756       ;; the nntp buffer, so that the agent can save the info, too.
 757       (with-current-buffer nntp-server-buffer
 758         (erase-buffer)
 759         (dolist (info infos)
 760           (let* ((group (gnus-info-group info))
 761                  (active (gnus-active group)))
 762             (when active
 763               (insert (format "%S %d %d y\n"
 764                               (gnus-group-real-name group)
 765                               (cdr active)
 766                               (car active))))))))))
 767
 768 (defun nnimap-update-infos (flags infos)
 769   (dolist (info infos)
 770     (let ((group (gnus-group-real-name (gnus-info-group info))))
 771       (nnimap-update-info info (cdr (assoc group flags))))))
 772
 773 (defun nnimap-update-info (info marks)
 774   (when marks
 775     (destructuring-bind (existing flags high low uidnext start-article) marks
 776       (let ((group (gnus-info-group info))
 777             (completep (and start-article
 778                             (= start-article 1))))
 779         ;; First set the active ranges based on high/low.
 780         (if (or completep
 781                 (not (gnus-active group)))
 782             (gnus-set-active group
 783                              (if high
 784                                  (cons low high)
 785                                ;; No articles in this group.
 786                                (cons (1- uidnext) uidnext)))
 787           (setcdr (gnus-active group) high))
 788         ;; Then update the list of read articles.
 789         (let* ((unread
 790                 (gnus-compress-sequence
 791                  (gnus-set-difference
 792                   (gnus-set-difference
 793                    existing
 794                    (cdr (assoc "\\Seen" flags)))
 795                   (cdr (assoc "\\Flagged" flags)))))
 796                (read (gnus-range-difference
 797                       (cons start-article high) unread)))
 798           (when (> start-article 1)
 799             (setq read
 800                   (gnus-range-nconcat
 801                    (if (> start-article 1)
 802                        (gnus-sorted-range-intersection
 803                         (cons 1 (1- start-article))
 804                         (gnus-info-read info))
 805                      (gnus-info-read info))
 806                    read)))
 807           (gnus-info-set-read info read)
 808           ;; Update the marks.
 809           (setq marks (gnus-info-marks info))
 810           ;; Note the active level for the next run-through.
 811           (let ((active (assq 'active marks)))
 812             (if active
 813                 (setcdr active (gnus-active group))
 814               (push (cons 'active (gnus-active group)) marks)))
 815           (dolist (type (cdr nnimap-mark-alist))
 816             (let ((old-marks (assoc (car type) marks))
 817                   (new-marks (gnus-compress-sequence
 818                               (cdr (assoc (cadr type) flags)))))
 819               (setq marks (delq old-marks marks))
 820               (pop old-marks)
 821               (when (and old-marks
 822                          (> start-article 1))
 823                 (setq old-marks (gnus-range-difference
 824                                  old-marks
 825                                  (cons start-article high)))
 826                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
 827               (when new-marks
 828                 (push (cons (car type) new-marks) marks)))
 829             (gnus-info-set-marks info marks t)
 830             (nnimap-store-info info (gnus-active group))))))))
 831
 832 (defun nnimap-store-info (info active)
 833   (let* ((group (gnus-group-real-name (gnus-info-group info)))
 834          (entry (assoc group nnimap-current-infos)))
 835     (if entry
 836         (setcdr entry (list info active))
 837       (push (list group info active) nnimap-current-infos))))
 838
 839 (defun nnimap-flags-to-marks (groups)
 840   (let (data group totalp uidnext articles start-article mark)
 841     (dolist (elem groups)
 842       (setq group (car elem)
 843             uidnext (cadr elem)
 844             start-article (caddr elem)
 845             articles (cdddr elem))
 846       (let ((high (caar articles))
 847             marks low existing)
 848         (dolist (article articles)
 849           (setq low (car article))
 850           (push (car article) existing)
 851           (dolist (flag (cdr article))
 852             (setq mark (assoc flag marks))
 853             (if (not mark)
 854                 (push (list flag (car article)) marks)
 855               (setcdr mark (cons (car article) (cdr mark)))))
 856           (push (list group existing marks high low uidnext start-article)
 857                 data))))
 858     data))
 859
 860 (defun nnimap-parse-flags (sequences)
 861   (goto-char (point-min))
 862   (let (start end articles groups uidnext elems)
 863     (dolist (elem sequences)
 864       (destructuring-bind (group-sequence flag-sequence totalp group) elem
 865         ;; The EXAMINE was successful.
 866         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
 867                    (progn
 868                      (forward-line 1)
 869                      (setq start (point))
 870                      (if (re-search-backward "UIDNEXT \\([0-9]+\\)"
 871                                                (or end (point-min)) t)
 872                          (setq uidnext (string-to-number (match-string 1)))
 873                        (setq uidnext nil))
 874                      (goto-char start))
 875                    ;; The UID FETCH FLAGS was successful.
 876                    (search-forward (format "\n%d OK " flag-sequence) nil t))
 877           (setq end (point))
 878           (goto-char start)
 879           (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" end t)
 880             (setq elems (nnimap-parse-line (match-string 1)))
 881             (push (cons (string-to-number (cadr (member "UID" elems)))
 882                         (cadr (member "FLAGS" elems)))
 883                   articles))
 884           (push (nconc (list group uidnext totalp) articles) groups)
 885           (setq articles nil))))
 886     groups))
 887
 888 (defun nnimap-find-process-buffer (buffer)
 889   (cadr (assoc buffer nnimap-connection-alist)))
 890
 891 (deffoo nnimap-request-post (&optional server)
 892   (setq nnimap-status-string "Read-only server")
 893   nil)
 894
 895 (defun nnimap-possibly-change-group (group server)
 896   (let ((open-result t))
 897     (when (and server
 898                (not (nnimap-server-opened server)))
 899       (setq open-result (nnimap-open-server server)))
 900     (cond
 901      ((not open-result)
 902       nil)
 903      ((not group)
 904       t)
 905      (t
 906       (with-current-buffer (nnimap-buffer)
 907         (if (equal group (nnimap-group nnimap-object))
 908             t
 909           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
 910             (when (car result)
 911               (setf (nnimap-group nnimap-object) group
 912                     (nnimap-select-result nnimap-object) result)
 913               result))))))))
 914
 915 (defun nnimap-find-connection (buffer)
 916   "Find the connection delivering to BUFFER."
 917   (let ((entry (assoc buffer nnimap-connection-alist)))
 918     (when entry
 919       (if (and (buffer-name (cadr entry))
 920                (get-buffer-process (cadr entry))
 921                (memq (process-status (get-buffer-process (cadr entry)))
 922                      '(open run)))
 923           (get-buffer-process (cadr entry))
 924         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
 925         nil))))
 926
 927 (defvar nnimap-sequence 0)
 928
 929 (defun nnimap-send-command (&rest args)
 930   (process-send-string
 931    (get-buffer-process (current-buffer))
 932    (nnimap-log-command
 933     (format "%d %s%s\n"
 934             (incf nnimap-sequence)
 935             (apply #'format args)
 936             (if (nnimap-newlinep nnimap-object)
 937                 ""
 938               "\r"))))
 939   nnimap-sequence)
 940
 941 (defun nnimap-log-command (command)
 942   (with-current-buffer (get-buffer-create "*imap log*")
 943     (goto-char (point-max))
 944     (insert (format-time-string "%H:%M:%S") " " command))
 945   command)
 946
 947 (defun nnimap-command (&rest args)
 948   (erase-buffer)
 949   (let* ((sequence (apply #'nnimap-send-command args))
 950          (response (nnimap-get-response sequence)))
 951     (if (equal (caar response) "OK")
 952         (cons t response)
 953       (nnheader-report 'nnimap "%s"
 954                        (mapconcat (lambda (a)
 955                                     (format "%s" a))
 956                                   (car response) " "))
 957       nil)))
 958
 959 (defun nnimap-get-response (sequence)
 960   (nnimap-wait-for-response sequence)
 961   (nnimap-parse-response))
 962
 963 (defun nnimap-wait-for-connection ()
 964   (let ((process (get-buffer-process (current-buffer))))
 965     (goto-char (point-min))
 966     (while (and (memq (process-status process)
 967                       '(open run))
 968                 (not (re-search-forward "^\\* .*\n" nil t)))
 969       (nnheader-accept-process-output process)
 970       (goto-char (point-min)))
 971     (forward-line -1)
 972     (and (looking-at "\\* \\([A-Z0-9]+\\)")
 973          (match-string 1))))
 974
 975 (defun nnimap-wait-for-response (sequence &optional messagep)
 976   (let ((process (get-buffer-process (current-buffer))))
 977     (goto-char (point-max))
 978     (while (and (memq (process-status process)
 979                       '(open run))
 980                 (not (re-search-backward (format "^%d .*\n" sequence)
 981                                          (max (point-min) (- (point) 500))
 982                                          t)))
 983       (when messagep
 984         (message "Read %dKB" (/ (buffer-size) 1000)))
 985       (nnheader-accept-process-output process)
 986       (goto-char (point-max)))))
 987
 988 (defun nnimap-parse-response ()
 989   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
 990         result)
 991     (dolist (line lines)
 992       (push (cdr (nnimap-parse-line line)) result))
 993     ;; Return the OK/error code first, and then all the "continuation
 994     ;; lines" afterwards.
 995     (cons (pop result)
 996           (nreverse result))))
 997
 998 ;; Parse an IMAP response line lightly.  They look like
 999 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1000 ;; the lines into a list of strings and lists of string.
1001 (defun nnimap-parse-line (line)
1002   (let (char result)
1003     (with-temp-buffer
1004       (insert line)
1005       (goto-char (point-min))
1006       (while (not (eobp))
1007         (if (eql (setq char (following-char)) ? )
1008             (forward-char 1)
1009           (push
1010            (cond
1011             ((eql char ?\[)
1012              (split-string (buffer-substring
1013                             (1+ (point)) (1- (search-forward "]")))))
1014             ((eql char ?\()
1015              (split-string (buffer-substring
1016                             (1+ (point)) (1- (search-forward ")")))))
1017             ((eql char ?\")
1018              (forward-char 1)
1019              (buffer-substring (point) (1- (search-forward "\""))))
1020             (t
1021              (buffer-substring (point) (if (search-forward " " nil t)
1022                                            (1- (point))
1023                                          (goto-char (point-max))))))
1024            result)))
1025       (nreverse result))))
1026
1027 (defun nnimap-last-response-string ()
1028   (save-excursion
1029     (forward-line 1)
1030     (let ((end (point)))
1031       (forward-line -1)
1032       (when (not (bobp))
1033         (forward-line -1)
1034         (while (and (not (bobp))
1035                     (eql (following-char) ?*))
1036           (forward-line -1))
1037         (unless (eql (following-char) ?*)
1038           (forward-line 1)))
1039       (buffer-substring (point) end))))
1040
1041 (defun nnimap-get-responses (sequences)
1042   (let (responses)
1043     (dolist (sequence sequences)
1044       (goto-char (point-min))
1045       (when (re-search-forward (format "^%d " sequence) nil t)
1046         (push (list sequence (nnimap-parse-response))
1047               responses)))
1048     responses))
1049
1050 (defvar nnimap-incoming-split-list nil)
1051
1052 (defun nnimap-fetch-inbox (articles)
1053   (erase-buffer)
1054   (nnimap-wait-for-response
1055    (nnimap-send-command
1056     "UID FETCH %s %s"
1057     (nnimap-article-ranges articles)
1058     (format "(UID %s%s)"
1059             (format
1060              (if (member "IMAP4REV1"
1061                          (nnimap-capabilities nnimap-object))
1062                  "BODY.PEEK[HEADER] BODY.PEEK"
1063                "RFC822.PEEK"))
1064             (if nnimap-split-download-body-default
1065                 "[]"
1066               "[1]")))
1067    t))
1068
1069 (defun nnimap-split-incoming-mail ()
1070   (with-current-buffer (nnimap-buffer)
1071     (let ((nnimap-incoming-split-list nil)
1072           (nnmail-split-methods nnimap-split-methods)
1073           (nnmail-inhibit-default-split-group t)
1074           (groups (nnimap-get-groups))
1075           new-articles)
1076       (erase-buffer)
1077       (nnimap-command "SELECT %S" nnimap-inbox)
1078       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1079       (when new-articles
1080         (nnimap-fetch-inbox new-articles)
1081         (nnimap-transform-split-mail)
1082         (nnheader-ms-strip-cr)
1083         (nnmail-cache-open)
1084         (nnmail-split-incoming (current-buffer)
1085                                #'nnimap-save-mail-spec
1086                                nil nil
1087                                #'nnimap-dummy-active-number)
1088         (when nnimap-incoming-split-list
1089           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1090                 sequences)
1091             ;; Create any groups that doesn't already exist on the
1092             ;; server first.
1093             (dolist (spec specs)
1094               (unless (member (car spec) groups)
1095                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1096             ;; Then copy over all the messages.
1097             (erase-buffer)
1098             (dolist (spec specs)
1099               (let ((group (car spec))
1100                     (ranges (cdr spec)))
1101                 (push (list (nnimap-send-command "UID COPY %s %S"
1102                                                  (nnimap-article-ranges ranges)
1103                                                  (utf7-encode group t))
1104                             ranges)
1105                       sequences)))
1106             ;; Wait for the last COPY response...
1107             (when sequences
1108               (nnimap-wait-for-response (caar sequences))
1109               ;; And then mark the successful copy actions as deleted,
1110               ;; and possibly expunge them.
1111               (nnimap-mark-and-expunge-incoming
1112                (nnimap-parse-copied-articles sequences)))))))))
1113
1114 (defun nnimap-mark-and-expunge-incoming (range)
1115   (when range
1116     (setq range (nnimap-article-ranges range))
1117     (let ((sequence
1118            (nnimap-send-command
1119             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1120       (cond
1121        ;; If the server supports it, we now delete the message we have
1122        ;; just copied over.
1123        ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1124         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1125        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1126        ;; user has configured it.
1127        (nnimap-expunge
1128         (setq sequence (nnimap-send-command "EXPUNGE"))))
1129       (nnimap-wait-for-response sequence))))
1130
1131 (defun nnimap-parse-copied-articles (sequences)
1132   (let (sequence copied range)
1133     (goto-char (point-min))
1134     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1135       (setq sequence (string-to-number (match-string 1)))
1136       (when (setq range (cadr (assq sequence sequences)))
1137         (push (gnus-uncompress-range range) copied)))
1138     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1139
1140 (defun nnimap-new-articles (flags)
1141   (let (new)
1142     (dolist (elem flags)
1143       (when (or (null (cdr elem))
1144                 (and (not (member "\\Deleted" (cdr elem)))
1145                      (not (member "\\Seen" (cdr elem)))))
1146         (push (car elem) new)))
1147     (gnus-compress-sequence (nreverse new))))
1148
1149 (defun nnimap-make-split-specs (list)
1150   (let ((specs nil)
1151         entry)
1152     (dolist (elem list)
1153       (destructuring-bind (article spec) elem
1154         (dolist (group (delete nil (mapcar #'car spec)))
1155           (unless (setq entry (assoc group specs))
1156             (push (setq entry (list group)) specs))
1157           (setcdr entry (cons article (cdr entry))))))
1158     (dolist (entry specs)
1159       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1160     specs))
1161
1162 (defun nnimap-transform-split-mail ()
1163   (goto-char (point-min))
1164   (let (article bytes)
1165     (block nil
1166       (while (not (eobp))
1167         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1168           (delete-region (point) (progn (forward-line 1) (point)))
1169           (when (eobp)
1170             (return)))
1171         (setq article (match-string 1)
1172               bytes (nnimap-get-length))
1173         (delete-region (line-beginning-position) (line-end-position))
1174         ;; Insert MMDF separator, and a way to remember what this
1175         ;; article UID is.
1176         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1177         (forward-char (1+ bytes))
1178         (setq bytes (nnimap-get-length))
1179         (delete-region (line-beginning-position) (line-end-position))
1180         (forward-char (1+ bytes))
1181         (delete-region (line-beginning-position) (line-end-position))))))
1182
1183 (defun nnimap-dummy-active-number (group &optional server)
1184   1)
1185
1186 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1187   (let (article)
1188     (goto-char (point-min))
1189     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1190         (error "Invalid nnimap mail")
1191       (setq article (string-to-number (match-string 1))))
1192     (push (list article group-art)
1193           nnimap-incoming-split-list)))
1194
1195 (provide 'nnimap)
1196
1197 ;;; nnimap.el ends here