cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40
  41 (nnoo-declare nnimap)
  42
  43 (defvoo nnimap-address nil
  44   "The address of the IMAP server.")
  45
  46 (defvoo nnimap-server-port nil
  47   "The IMAP port used.
  48 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  49 it will default to `imap'.")
  50
  51 (defvoo nnimap-stream 'ssl
  52   "How nnimap will talk to the IMAP server.
  53 Values are `ssl' and `network'.")
  54
  55 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  56                                  (if (listp imap-shell-program)
  57                                      (car imap-shell-program)
  58                                    imap-shell-program)
  59                                "ssh %s imapd"))
  60
  61 (defvoo nnimap-inbox nil
  62   "The mail box where incoming mail arrives and should be split out of.")
  63
  64 (defvoo nnimap-expunge-inbox nil
  65   "If non-nil, expunge the inbox after fetching mail.
  66 This is always done if the server supports UID EXPUNGE, but it's
  67 not done by default on servers that doesn't support that command.")
  68
  69 (defvoo nnimap-authenticator nil
  70   "How nnimap authenticate itself to the server.
  71 Possible choices are nil (use default methods) or `anonymous'.")
  72
  73 (defvoo nnimap-fetch-partial-articles nil
  74   "If non-nil, nnimap will fetch partial articles.
  75 If t, nnimap will fetch only the first part.  If a string, it
  76 will fetch all parts that have types that match that string.  A
  77 likely value would be \"text/\" to automatically fetch all
  78 textual parts.")
  79
  80 (defvoo nnimap-connection-alist nil)
  81
  82 (defvoo nnimap-current-infos nil)
  83
  84 (defvar nnimap-process nil)
  85
  86 (defvar nnimap-status-string "")
  87
  88 (defvar nnimap-split-download-body-default nil
  89   "Internal variable with default value for `nnimap-split-download-body'.")
  90
  91 (defstruct nnimap
  92   group process commands capabilities select-result newlinep)
  93
  94 (defvar nnimap-object nil)
  95
  96 (defvar nnimap-mark-alist
  97   '((read "\\Seen")
  98     (tick "\\Flagged")
  99     (reply "\\Answered")
 100     (expire "gnus-expire")
 101     (dormant "gnus-dormant")
 102     (score "gnus-score")
 103     (save "gnus-save")
 104     (download "gnus-download")
 105     (forward "gnus-forward")))
 106
 107 (defvar nnimap-split-methods nil)
 108
 109 (defun nnimap-buffer ()
 110   (nnimap-find-process-buffer nntp-server-buffer))
 111
 112 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 113   (with-current-buffer nntp-server-buffer
 114     (erase-buffer)
 115     (when (nnimap-possibly-change-group group server)
 116       (with-current-buffer (nnimap-buffer)
 117         (nnimap-send-command "SELECT %S" (utf7-encode group t))
 118         (erase-buffer)
 119         (nnimap-wait-for-response
 120          (nnimap-send-command
 121           "UID FETCH %s %s"
 122           (nnimap-article-ranges (gnus-compress-sequence articles))
 123           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 124                   (format
 125                    (if (member "IMAP4REV1"
 126                                (nnimap-capabilities nnimap-object))
 127                        "BODY.PEEK[HEADER.FIELDS %s]"
 128                      "RFC822.HEADER.LINES %s")
 129                    (append '(Subject From Date Message-Id
 130                                      References In-Reply-To Xref)
 131                            nnmail-extra-headers))))
 132          t)
 133         (nnimap-transform-headers))
 134       (insert-buffer-substring
 135        (nnimap-find-process-buffer (current-buffer))))
 136     t))
 137
 138 (defun nnimap-transform-headers ()
 139   (goto-char (point-min))
 140   (let (article bytes lines size)
 141     (block nil
 142       (while (not (eobp))
 143         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 144           (delete-region (point) (progn (forward-line 1) (point)))
 145           (when (eobp)
 146             (return)))
 147         (setq article (match-string 1)
 148               bytes (nnimap-get-length)
 149               lines nil)
 150         (beginning-of-line)
 151         (setq size
 152               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 153                                       (line-end-position)
 154                                       t)
 155                    (match-string 1)))
 156         (beginning-of-line)
 157         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 158           (let ((structure (ignore-errors (read (current-buffer)))))
 159             (while (and (consp structure)
 160                         (not (stringp (car structure))))
 161               (setq structure (car structure)))
 162             (setq lines (nth 7 structure))))
 163         (delete-region (line-beginning-position) (line-end-position))
 164         (insert (format "211 %s Article retrieved." article))
 165         (forward-line 1)
 166         (when size
 167           (insert (format "Chars: %s\n" size)))
 168         (when lines
 169           (insert (format "Lines: %s\n" lines)))
 170         (re-search-forward "^\r$")
 171         (delete-region (line-beginning-position) (line-end-position))
 172         (insert ".")
 173         (forward-line 1)))))
 174
 175 (defun nnimap-get-length ()
 176   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 177        (string-to-number (match-string 1))))
 178
 179 (defun nnimap-article-ranges (ranges)
 180   (let (result)
 181     (cond
 182      ((numberp ranges)
 183       (number-to-string ranges))
 184      ((numberp (cdr ranges))
 185       (format "%d:%d" (car ranges) (cdr ranges)))
 186      (t
 187       (dolist (elem ranges)
 188         (push
 189          (if (consp elem)
 190              (format "%d:%d" (car elem) (cdr elem))
 191            (number-to-string elem))
 192          result))
 193       (mapconcat #'identity (nreverse result) ",")))))
 194
 195 (deffoo nnimap-open-server (server &optional defs)
 196   (if (nnimap-server-opened server)
 197       t
 198     (unless (assq 'nnimap-address defs)
 199       (setq defs (append defs (list (list 'nnimap-address server)))))
 200     (nnoo-change-server 'nnimap server defs)
 201     (or (nnimap-find-connection nntp-server-buffer)
 202         (nnimap-open-connection nntp-server-buffer))))
 203
 204 (defun nnimap-make-process-buffer (buffer)
 205   (with-current-buffer
 206       (generate-new-buffer (format "*nnimap %s %s %s*"
 207                                    nnimap-address nnimap-server-port
 208                                    (gnus-buffer-exists-p buffer)))
 209     (mm-disable-multibyte)
 210     (buffer-disable-undo)
 211     (gnus-add-buffer)
 212     (set (make-local-variable 'after-change-functions) nil)
 213     (set (make-local-variable 'nnimap-object) (make-nnimap))
 214     (push (list buffer (current-buffer)) nnimap-connection-alist)
 215     (current-buffer)))
 216
 217 (defun nnimap-open-shell-stream (name buffer host port)
 218   (let ((process-connection-type nil))
 219     (start-process name buffer shell-file-name
 220                    shell-command-switch
 221                    (format-spec
 222                     nnimap-shell-program
 223                     (format-spec-make
 224                      ?s host
 225                      ?p port)))))
 226
 227 (defun nnimap-credentials (address ports)
 228   (let (port credentials)
 229     ;; Request the credentials from all ports, but only query on the
 230     ;; last port if all the previous ones have failed.
 231     (while (and (null credentials)
 232                 (setq port (pop ports)))
 233       (setq credentials
 234             (auth-source-user-or-password
 235              '("login" "password") address port nil (null ports))))
 236     credentials))
 237
 238 (defun nnimap-open-connection (buffer)
 239   (with-current-buffer (nnimap-make-process-buffer buffer)
 240     (let* ((coding-system-for-read 'binary)
 241            (coding-system-for-write 'binary)
 242            (ports
 243             (cond
 244              ((eq nnimap-stream 'network)
 245               (open-network-stream
 246                "*nnimap*" (current-buffer) nnimap-address
 247                (or nnimap-server-port
 248                    (if (netrc-find-service-number "imap")
 249                        "imap"
 250                      "143")))
 251               '("143" "imap"))
 252              ((eq nnimap-stream 'shell)
 253               (nnimap-open-shell-stream
 254                "*nnimap*" (current-buffer) nnimap-address
 255                (or nnimap-server-port "imap"))
 256               '("imap"))
 257              ((eq nnimap-stream 'ssl)
 258               (open-tls-stream
 259                "*nnimap*" (current-buffer) nnimap-address
 260                (or nnimap-server-port
 261                    (if (netrc-find-service-number "imaps")
 262                        "imaps"
 263                      "993")))
 264               '("143" "993" "imap" "imaps"))))
 265            connection-result login-result credentials)
 266       (setf (nnimap-process nnimap-object)
 267             (get-buffer-process (current-buffer)))
 268       (when (and (nnimap-process nnimap-object)
 269                  (memq (process-status (nnimap-process nnimap-object))
 270                        '(open run)))
 271         (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 272         (when (setq connection-result (nnimap-wait-for-connection))
 273           (unless (equal connection-result "PREAUTH")
 274             (if (not (setq credentials
 275                            (if (eq nnimap-authenticator 'anonymous)
 276                                (list "anonymous"
 277                                      (message-make-address))
 278                              (nnimap-credentials
 279                               nnimap-address
 280                               (if nnimap-server-port
 281                                   (cons (format "%s" nnimap-server-port) ports)
 282                                 ports)))))
 283                 (setq nnimap-object nil)
 284               (setq login-result (nnimap-command "LOGIN %S %S"
 285                                                  (car credentials)
 286                                                  (cadr credentials)))
 287               (unless (car login-result)
 288                 (delete-process (nnimap-process nnimap-object))
 289                 (setq nnimap-object nil))))
 290           (when nnimap-object
 291             (setf (nnimap-capabilities nnimap-object)
 292                   (mapcar
 293                    #'upcase
 294                    (or (nnimap-find-parameter "CAPABILITY" (cdr login-result))
 295                        (nnimap-find-parameter
 296                         "CAPABILITY" (cdr (nnimap-command "CAPABILITY"))))))
 297             (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 298               (nnimap-command "ENABLE QRESYNC"))
 299             t))))))
 300
 301 (defun nnimap-find-parameter (parameter elems)
 302   (let (result)
 303     (dolist (elem elems)
 304       (cond
 305        ((equal (car elem) parameter)
 306         (setq result (cdr elem)))
 307        ((and (equal (car elem) "OK")
 308              (consp (cadr elem))
 309              (equal (caadr elem) parameter))
 310         (setq result (cdr (cadr elem))))))
 311     result))
 312
 313 (deffoo nnimap-close-server (&optional server)
 314   t)
 315
 316 (deffoo nnimap-request-close ()
 317   t)
 318
 319 (deffoo nnimap-server-opened (&optional server)
 320   (and (nnoo-current-server-p 'nnimap server)
 321        nntp-server-buffer
 322        (gnus-buffer-live-p nntp-server-buffer)
 323        (nnimap-find-connection nntp-server-buffer)))
 324
 325 (deffoo nnimap-status-message (&optional server)
 326   nnimap-status-string)
 327
 328 (deffoo nnimap-request-article (article &optional group server to-buffer)
 329   (with-current-buffer nntp-server-buffer
 330     (let ((result (nnimap-possibly-change-group group server))
 331           parts)
 332       (when (stringp article)
 333         (setq article (nnimap-find-article-by-message-id group article)))
 334       (when (and result
 335                  article)
 336         (erase-buffer)
 337         (with-current-buffer (nnimap-buffer)
 338           (erase-buffer)
 339           (when nnimap-fetch-partial-articles
 340             (if (eq nnimap-fetch-partial-articles t)
 341                 (setq parts '(1))
 342               (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 343               (goto-char (point-min))
 344               (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 345                 (let ((structure (ignore-errors (read (current-buffer)))))
 346                   (setq parts (nnimap-find-wanted-parts structure))))))
 347           (setq result
 348                 (nnimap-command
 349                  (if (member "IMAP4REV1" (nnimap-capabilities nnimap-object))
 350                      "UID FETCH %d BODY.PEEK[]"
 351                    "UID FETCH %d RFC822.PEEK")
 352                  article))
 353           ;; Check that we really got an article.
 354           (goto-char (point-min))
 355           (unless (looking-at "\\* [0-9]+ FETCH")
 356             (setq result nil)))
 357         (let ((buffer (nnimap-find-process-buffer (current-buffer))))
 358           (when (car result)
 359             (with-current-buffer (or to-buffer nntp-server-buffer)
 360               (insert-buffer-substring buffer)
 361               (goto-char (point-min))
 362               (let ((bytes (nnimap-get-length)))
 363                 (delete-region (line-beginning-position)
 364                                (progn (forward-line 1) (point)))
 365                 (goto-char (+ (point) bytes))
 366                 (delete-region (point) (point-max))
 367                 (nnheader-ms-strip-cr))
 368               (cons group article))))))))
 369
 370 (defun nnimap-find-wanted-parts (structure)
 371   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 372
 373 (defun nnimap-find-wanted-parts-1 (structure prefix)
 374   (let ((num 1)
 375         parts)
 376     (while (consp (car structure))
 377       (let ((sub (pop structure)))
 378         (if (consp (car sub))
 379             (push (nnimap-find-wanted-parts-1
 380                    sub (if (string= prefix "")
 381                            (number-to-string num)
 382                          (format "%s.%s" prefix num)))
 383                   parts)
 384           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub))))
 385             (when (string-match nnimap-fetch-partial-articles type)
 386               (push (if (string= prefix "")
 387                         (number-to-string num)
 388                       (format "%s.%s" prefix num))
 389                     parts)))
 390           (incf num))))
 391     (nreverse parts)))
 392
 393 (deffoo nnimap-request-group (group &optional server dont-check info)
 394   (let ((result (nnimap-possibly-change-group group server))
 395         articles active marks high low)
 396     (with-current-buffer nntp-server-buffer
 397       (when result
 398         (if (and dont-check
 399                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 400             (insert (format "211 %d %d %d %S\n"
 401                             (- (cdr active) (car active))
 402                             (car active)
 403                             (cdr active)
 404                             group))
 405           (with-current-buffer (nnimap-buffer)
 406             (erase-buffer)
 407             (let ((group-sequence
 408                    (nnimap-send-command "SELECT %S" (utf7-encode group)))
 409                   (flag-sequence
 410                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 411               (nnimap-wait-for-response flag-sequence)
 412               (setq marks
 413                     (nnimap-flags-to-marks
 414                      (nnimap-parse-flags
 415                       (list (list group-sequence flag-sequence 1 group)))))
 416               (when info
 417                 (nnimap-update-infos marks (list info)))
 418               (goto-char (point-max))
 419               (cond
 420                (marks
 421                 (setq high (nth 3 (car marks))
 422                       low (nth 4 (car marks))))
 423                ((re-search-backward "UIDNEXT \\([0-9]+\\)" nil t)
 424                 (setq high (string-to-number (match-string 1))
 425                       low 1)))))
 426           (erase-buffer)
 427           (insert
 428            (format
 429             "211 %d %d %d %S\n"
 430             (1+ (- high low))
 431             low high group))))
 432       t)))
 433
 434 (deffoo nnimap-request-delete-group (group &optional force server)
 435   (when (nnimap-possibly-change-group nil server)
 436     (with-current-buffer (nnimap-buffer)
 437       (car (nnimap-command "DELETE %S" (utf7-encode group))))))
 438
 439 (defun nnimap-get-flags (spec)
 440   (let ((articles nil)
 441         elems)
 442     (with-current-buffer (nnimap-buffer)
 443       (erase-buffer)
 444       (nnimap-wait-for-response (nnimap-send-command
 445                                  "UID FETCH %s FLAGS" spec))
 446       (goto-char (point-min))
 447       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 448         (setq elems (nnimap-parse-line (match-string 1)))
 449         (push (cons (string-to-number (cadr (member "UID" elems)))
 450                     (cadr (member "FLAGS" elems)))
 451               articles)))
 452     (nreverse articles)))
 453
 454 (deffoo nnimap-close-group (group &optional server)
 455   t)
 456
 457 (deffoo nnimap-request-move-article (article group server accept-form
 458                                              &optional last internal-move-group)
 459   (when (nnimap-possibly-change-group group server)
 460     ;; If the move is internal (on the same server), just do it the easy
 461     ;; way.
 462     (let ((message-id (message-field-value "message-id")))
 463       (if internal-move-group
 464           (let ((result
 465                  (with-current-buffer (nnimap-buffer)
 466                    (nnimap-command "UID COPY %d %S"
 467                                    article
 468                                    (utf7-encode internal-move-group t)))))
 469             (when (car result)
 470               (nnimap-delete-article article)
 471               (cons internal-move-group
 472                     (nnimap-find-article-by-message-id
 473                      internal-move-group message-id))))
 474         (with-temp-buffer
 475           (when (nnimap-request-article article group server (current-buffer))
 476             (let ((result (eval accept-form)))
 477               (when result
 478                 (nnimap-delete-article article)
 479                 result))))))))
 480
 481 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 482   (cond
 483    ((not (nnimap-possibly-change-group group server))
 484     articles)
 485    (force
 486     (unless (nnimap-delete-article articles)
 487       (message "Article marked for deletion, but not expunged."))
 488     nil)
 489    (t
 490     articles)))
 491
 492 (defun nnimap-find-article-by-message-id (group message-id)
 493   (when (nnimap-possibly-change-group group nil)
 494     (with-current-buffer (nnimap-buffer)
 495       (let ((result
 496              (nnimap-command "UID SEARCH HEADER Message-Id %S" message-id))
 497             article)
 498         (when (car result)
 499           ;; Select the last instance of the message in the group.
 500           (and (setq article
 501                      (car (last (assoc "SEARCH" (cdr result)))))
 502                (string-to-number article)))))))
 503
 504 (defun nnimap-delete-article (articles)
 505   (with-current-buffer (nnimap-buffer)
 506     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 507                     (nnimap-article-ranges articles))
 508     (when (member "UIDPLUS" (nnimap-capabilities nnimap-object))
 509       (nnimap-send-command "UID EXPUNGE %s"
 510                            (nnimap-article-ranges articles))
 511       t)))
 512
 513 (deffoo nnimap-request-scan (&optional group server)
 514   (when (and (nnimap-possibly-change-group nil server)
 515              (equal group nnimap-inbox)
 516              nnimap-inbox
 517              nnimap-split-methods)
 518     (nnimap-split-incoming-mail)))
 519
 520 (defun nnimap-marks-to-flags (marks)
 521   (let (flags flag)
 522     (dolist (mark marks)
 523       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 524         (push flag flags)))
 525     flags))
 526
 527 (deffoo nnimap-request-set-mark (group actions &optional server)
 528   (when (nnimap-possibly-change-group group server)
 529     (let (sequence)
 530       (with-current-buffer (nnimap-buffer)
 531         ;; Just send all the STORE commands without waiting for
 532         ;; response.  If they're successful, they're successful.
 533         (dolist (action actions)
 534           (destructuring-bind (range action marks) action
 535             (let ((flags (nnimap-marks-to-flags marks)))
 536               (when flags
 537                 (setq sequence (nnimap-send-command
 538                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 539                                 (nnimap-article-ranges range)
 540                                 (if (eq action 'del)
 541                                     "-"
 542                                   "+")
 543                                 (mapconcat #'identity flags " ")))))))
 544         ;; Wait for the last command to complete to avoid later
 545         ;; syncronisation problems with the stream.
 546         (when sequence
 547           (nnimap-wait-for-response sequence))))))
 548
 549 (deffoo nnimap-request-accept-article (group &optional server last)
 550   (when (nnimap-possibly-change-group nil server)
 551     (nnmail-check-syntax)
 552     (let ((message (buffer-string))
 553           (message-id (message-field-value "message-id"))
 554           sequence)
 555       (with-current-buffer (nnimap-buffer)
 556         (setq sequence (nnimap-send-command
 557                         "APPEND %S {%d}" (utf7-encode group t)
 558                         (length message)))
 559         (process-send-string (get-buffer-process (current-buffer)) message)
 560         (process-send-string (get-buffer-process (current-buffer))
 561                              (if (nnimap-newlinep nnimap-object)
 562                                  "\n"
 563                                "\r\n"))
 564         (let ((result (nnimap-get-response sequence)))
 565           (when result
 566             (cons group
 567                   (nnimap-find-article-by-message-id group message-id))))))))
 568
 569 (defun nnimap-add-cr ()
 570   (goto-char (point-min))
 571   (while (re-search-forward "\r?\n" nil t)
 572     (replace-match "\r\n" t t)))
 573
 574 (defun nnimap-get-groups ()
 575   (let ((result (nnimap-command "LIST \"\" \"*\""))
 576         groups)
 577     (when (car result)
 578       (dolist (line (cdr result))
 579         (when (and (equal (car line) "LIST")
 580                    (not (and (caadr line)
 581                              (string-match "noselect" (caadr line)))))
 582           (push (car (last line)) groups)))
 583       (nreverse groups))))
 584
 585 (deffoo nnimap-request-list (&optional server)
 586   (nnimap-possibly-change-group nil server)
 587   (with-current-buffer nntp-server-buffer
 588     (erase-buffer)
 589     (let ((groups
 590            (with-current-buffer (nnimap-buffer)
 591              (nnimap-get-groups)))
 592           sequences responses)
 593       (when groups
 594         (with-current-buffer (nnimap-buffer)
 595           (dolist (group groups)
 596             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 597                         group)
 598                   sequences))
 599           (nnimap-wait-for-response (caar sequences))
 600           (setq responses
 601                 (nnimap-get-responses (mapcar #'car sequences))))
 602         (dolist (response responses)
 603           (let* ((sequence (car response))
 604                  (response (cadr response))
 605                  (group (cadr (assoc sequence sequences))))
 606             (when (and group
 607                        (equal (caar response) "OK"))
 608               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 609                     highest exists)
 610                 (dolist (elem response)
 611                   (when (equal (cadr elem) "EXISTS")
 612                     (setq exists (string-to-number (car elem)))))
 613                 (when uidnext
 614                   (setq highest (1- (string-to-number (car uidnext)))))
 615                 (cond
 616                  ((null highest)
 617                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 618                  ((zerop exists)
 619                   ;; Empty group.
 620                   (insert (format "%S %d %d y\n"
 621                                   (utf7-decode group t) highest (1+ highest))))
 622                  (t
 623                   ;; Return the widest possible range.
 624                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 625                                   (or highest exists)))))))))
 626         t))))
 627
 628 (deffoo nnimap-retrieve-group-data-early (server infos)
 629   (when (nnimap-possibly-change-group nil server)
 630     (with-current-buffer (nnimap-buffer)
 631       ;; QRESYNC handling isn't implemented.
 632       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 633             marks groups sequences)
 634         ;; Go through the infos and gather the data needed to know
 635         ;; what and how to request the data.
 636         (dolist (info infos)
 637           (setq marks (gnus-info-marks info))
 638           (push (list (gnus-group-real-name (gnus-info-group info))
 639                       (cdr (assq 'active marks))
 640                       (cdr (assq 'uid marks)))
 641                 groups))
 642         ;; Then request the data.
 643         (erase-buffer)
 644         (dolist (elem groups)
 645           (if (and qresyncp
 646                    (nth 2 elem))
 647               (push
 648                (list 'qresync
 649                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 650                                           (car elem)
 651                                           (car (nth 2 elem))
 652                                           (cdr (nth 2 elem)))
 653                      nil
 654                      (car elem))
 655                sequences)
 656             (let ((start
 657                    (if (nth 1 elem)
 658                        ;; Fetch the last 100 flags.
 659                        (max 1 (- (cdr (nth 1 elem)) 100))
 660                      1)))
 661               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 662                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 663                           start
 664                           (car elem))
 665                     sequences))))
 666         sequences))))
 667
 668 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 669   (when (and sequences
 670              (nnimap-possibly-change-group nil server))
 671     (with-current-buffer (nnimap-buffer)
 672       ;; Wait for the final data to trickle in.
 673       (nnimap-wait-for-response (cadar sequences))
 674       ;; Now we should have all the data we need, no matter whether
 675       ;; we're QRESYNCING, fetching all the flags from scratch, or
 676       ;; just fetching the last 100 flags per group.
 677       (nnimap-update-infos (nnimap-flags-to-marks
 678                             (nnimap-parse-flags
 679                              (nreverse sequences)))
 680                            infos)
 681       ;; Finally, just return something resembling an active file in
 682       ;; the nntp buffer, so that the agent can save the info, too.
 683       (with-current-buffer nntp-server-buffer
 684         (erase-buffer)
 685         (dolist (info infos)
 686           (let* ((group (gnus-info-group info))
 687                  (active (gnus-active group)))
 688             (when active
 689               (insert (format "%S %d %d y\n"
 690                               (gnus-group-real-name group)
 691                               (cdr active)
 692                               (car active))))))))))
 693
 694 (defun nnimap-update-infos (flags infos)
 695   (dolist (info infos)
 696     (let ((group (gnus-group-real-name (gnus-info-group info))))
 697       (nnimap-update-info info (cdr (assoc group flags))))))
 698
 699 (defun nnimap-update-info (info marks)
 700   (when marks
 701     (destructuring-bind (existing flags high low uidnext start-article) marks
 702       (let ((group (gnus-info-group info))
 703             (completep (and start-article
 704                             (= start-article 1))))
 705         ;; First set the active ranges based on high/low.
 706         (if (or completep
 707                 (not (gnus-active group)))
 708             (gnus-set-active group
 709                              (if high
 710                                  (cons low high)
 711                                ;; No articles in this group.
 712                                (cons (1- uidnext) uidnext)))
 713           (setcdr (gnus-active group) high))
 714         ;; Then update the list of read articles.
 715         (let* ((unread
 716                 (gnus-compress-sequence
 717                  (gnus-set-difference
 718                   (gnus-set-difference
 719                    existing
 720                    (cdr (assoc "\\Seen" flags)))
 721                   (cdr (assoc "\\Flagged" flags)))))
 722                (read (gnus-range-difference
 723                       (cons start-article high) unread)))
 724           (when (> start-article 1)
 725             (setq read
 726                   (gnus-range-nconcat
 727                    (if (> start-article 1)
 728                        (gnus-sorted-range-intersection
 729                         (cons 1 (1- start-article))
 730                         (gnus-info-read info))
 731                      (gnus-info-read info))
 732                    read)))
 733           (gnus-info-set-read info read)
 734           ;; Update the marks.
 735           (setq marks (gnus-info-marks info))
 736           ;; Note the active level for the next run-through.
 737           (let ((active (assq 'active marks)))
 738             (if active
 739                 (setcdr active (gnus-active group))
 740               (push (cons 'active (gnus-active group)) marks)))
 741           (dolist (type (cdr nnimap-mark-alist))
 742             (let ((old-marks (assoc (car type) marks))
 743                   (new-marks (gnus-compress-sequence
 744                               (cdr (assoc (cadr type) flags)))))
 745               (setq marks (delq old-marks marks))
 746               (pop old-marks)
 747               (when (and old-marks
 748                          (> start-article 1))
 749                 (setq old-marks (gnus-range-difference
 750                                  old-marks
 751                                  (cons start-article high)))
 752                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
 753               (when new-marks
 754                 (push (cons (car type) new-marks) marks)))
 755             (gnus-info-set-marks info marks t)
 756             (nnimap-store-info info (gnus-active group))))))))
 757
 758 (defun nnimap-store-info (info active)
 759   (let* ((group (gnus-group-real-name (gnus-info-group info)))
 760          (entry (assoc group nnimap-current-infos)))
 761     (if entry
 762         (setcdr entry (list info active))
 763       (push (list group info active) nnimap-current-infos))))
 764
 765 (defun nnimap-flags-to-marks (groups)
 766   (let (data group totalp uidnext articles start-article mark)
 767     (dolist (elem groups)
 768       (setq group (car elem)
 769             uidnext (cadr elem)
 770             start-article (caddr elem)
 771             articles (cdddr elem))
 772       (let ((high (caar articles))
 773             marks low existing)
 774         (dolist (article articles)
 775           (setq low (car article))
 776           (push (car article) existing)
 777           (dolist (flag (cdr article))
 778             (setq mark (assoc flag marks))
 779             (if (not mark)
 780                 (push (list flag (car article)) marks)
 781               (setcdr mark (cons (car article) (cdr mark)))))
 782           (push (list group existing marks high low uidnext start-article)
 783                 data))))
 784     data))
 785
 786 (defun nnimap-parse-flags (sequences)
 787   (goto-char (point-min))
 788   (let (start end articles groups uidnext elems)
 789     (dolist (elem sequences)
 790       (destructuring-bind (group-sequence flag-sequence totalp group) elem
 791         ;; The EXAMINE was successful.
 792         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
 793                    (progn
 794                      (forward-line 1)
 795                      (setq start (point))
 796                      (if (re-search-backward "UIDNEXT \\([0-9]+\\)"
 797                                                (or end (point-min)) t)
 798                          (setq uidnext (string-to-number (match-string 1)))
 799                        (setq uidnext nil))
 800                      (goto-char start))
 801                    ;; The UID FETCH FLAGS was successful.
 802                    (search-forward (format "\n%d OK " flag-sequence) nil t))
 803           (setq end (point))
 804           (goto-char start)
 805           (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" end t)
 806             (setq elems (nnimap-parse-line (match-string 1)))
 807             (push (cons (string-to-number (cadr (member "UID" elems)))
 808                         (cadr (member "FLAGS" elems)))
 809                   articles))
 810           (push (nconc (list group uidnext totalp) articles) groups)
 811           (setq articles nil))))
 812     groups))
 813
 814 (defun nnimap-find-process-buffer (buffer)
 815   (cadr (assoc buffer nnimap-connection-alist)))
 816
 817 (deffoo nnimap-request-post (&optional server)
 818   (setq nnimap-status-string "Read-only server")
 819   nil)
 820
 821 (defun nnimap-possibly-change-group (group server)
 822   (let ((open-result t))
 823     (when (and server
 824                (not (nnimap-server-opened server)))
 825       (setq open-result (nnimap-open-server server)))
 826     (cond
 827      ((not open-result)
 828       nil)
 829      ((not group)
 830       t)
 831      (t
 832       (with-current-buffer (nnimap-buffer)
 833         (if (equal group (nnimap-group nnimap-object))
 834             t
 835           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
 836             (when (car result)
 837               (setf (nnimap-group nnimap-object) group
 838                     (nnimap-select-result nnimap-object) result)
 839               result))))))))
 840
 841 (defun nnimap-find-connection (buffer)
 842   "Find the connection delivering to BUFFER."
 843   (let ((entry (assoc buffer nnimap-connection-alist)))
 844     (when entry
 845       (if (and (buffer-name (cadr entry))
 846                (get-buffer-process (cadr entry))
 847                (memq (process-status (get-buffer-process (cadr entry)))
 848                      '(open run)))
 849           (get-buffer-process (cadr entry))
 850         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
 851         nil))))
 852
 853 (defvar nnimap-sequence 0)
 854
 855 (defun nnimap-send-command (&rest args)
 856   (process-send-string
 857    (get-buffer-process (current-buffer))
 858    (nnimap-log-command
 859     (format "%d %s%s\n"
 860             (incf nnimap-sequence)
 861             (apply #'format args)
 862             (if (nnimap-newlinep nnimap-object)
 863                 ""
 864               "\r"))))
 865   nnimap-sequence)
 866
 867 (defun nnimap-log-command (command)
 868   (with-current-buffer (get-buffer-create "*imap log*")
 869     (goto-char (point-max))
 870     (insert (format-time-string "%H:%M:%S") " " command))
 871   command)
 872
 873 (defun nnimap-command (&rest args)
 874   (erase-buffer)
 875   (let* ((sequence (apply #'nnimap-send-command args))
 876          (response (nnimap-get-response sequence)))
 877     (if (equal (caar response) "OK")
 878         (cons t response)
 879       (nnheader-report 'nnimap "%s"
 880                        (mapconcat #'identity (car response) " "))
 881       nil)))
 882
 883 (defun nnimap-get-response (sequence)
 884   (nnimap-wait-for-response sequence)
 885   (nnimap-parse-response))
 886
 887 (defun nnimap-wait-for-connection ()
 888   (let ((process (get-buffer-process (current-buffer))))
 889     (goto-char (point-min))
 890     (while (and (memq (process-status process)
 891                       '(open run))
 892                 (not (re-search-forward "^\\* .*\n" nil t)))
 893       (nnheader-accept-process-output process)
 894       (goto-char (point-min)))
 895     (forward-line -1)
 896     (and (looking-at "\\* \\([A-Z0-9]+\\)")
 897          (match-string 1))))
 898
 899 (defun nnimap-wait-for-response (sequence &optional messagep)
 900   (let ((process (get-buffer-process (current-buffer))))
 901     (goto-char (point-max))
 902     (while (and (memq (process-status process)
 903                       '(open run))
 904                 (not (re-search-backward (format "^%d .*\n" sequence)
 905                                          (max (point-min) (- (point) 500))
 906                                          t)))
 907       (when messagep
 908         (message "Read %dKB" (/ (buffer-size) 1000)))
 909       (nnheader-accept-process-output process)
 910       (goto-char (point-max)))))
 911
 912 (defun nnimap-parse-response ()
 913   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
 914         result)
 915     (dolist (line lines)
 916       (push (cdr (nnimap-parse-line line)) result))
 917     ;; Return the OK/error code first, and then all the "continuation
 918     ;; lines" afterwards.
 919     (cons (pop result)
 920           (nreverse result))))
 921
 922 ;; Parse an IMAP response line lightly.  They look like
 923 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
 924 ;; the lines into a list of strings and lists of string.
 925 (defun nnimap-parse-line (line)
 926   (let (char result)
 927     (with-temp-buffer
 928       (insert line)
 929       (goto-char (point-min))
 930       (while (not (eobp))
 931         (if (eql (setq char (following-char)) ? )
 932             (forward-char 1)
 933           (push
 934            (cond
 935             ((eql char ?\[)
 936              (split-string (buffer-substring
 937                             (1+ (point)) (1- (search-forward "]")))))
 938             ((eql char ?\()
 939              (split-string (buffer-substring
 940                             (1+ (point)) (1- (search-forward ")")))))
 941             ((eql char ?\")
 942              (forward-char 1)
 943              (buffer-substring (point) (1- (search-forward "\""))))
 944             (t
 945              (buffer-substring (point) (if (search-forward " " nil t)
 946                                            (1- (point))
 947                                          (goto-char (point-max))))))
 948            result)))
 949       (nreverse result))))
 950
 951 (defun nnimap-last-response-string ()
 952   (save-excursion
 953     (forward-line 1)
 954     (let ((end (point)))
 955       (forward-line -1)
 956       (when (not (bobp))
 957         (forward-line -1)
 958         (while (and (not (bobp))
 959                     (eql (following-char) ?*))
 960           (forward-line -1))
 961         (unless (eql (following-char) ?*)
 962           (forward-line 1)))
 963       (buffer-substring (point) end))))
 964
 965 (defun nnimap-get-responses (sequences)
 966   (let (responses)
 967     (dolist (sequence sequences)
 968       (goto-char (point-min))
 969       (when (re-search-forward (format "^%d " sequence) nil t)
 970         (push (list sequence (nnimap-parse-response))
 971               responses)))
 972     responses))
 973
 974 (defvar nnimap-incoming-split-list nil)
 975
 976 (defun nnimap-fetch-inbox (articles)
 977   (erase-buffer)
 978   (nnimap-wait-for-response
 979    (nnimap-send-command
 980     "UID FETCH %s %s"
 981     (nnimap-article-ranges articles)
 982     (format "(UID %s%s)"
 983             (format
 984              (if (member "IMAP4REV1"
 985                          (nnimap-capabilities nnimap-object))
 986                  "BODY.PEEK[HEADER] BODY.PEEK"
 987                "RFC822.PEEK"))
 988             (if nnimap-split-download-body-default
 989                 "[]"
 990               "[1]")))
 991    t))
 992
 993 (defun nnimap-split-incoming-mail ()
 994   (with-current-buffer (nnimap-buffer)
 995     (let ((nnimap-incoming-split-list nil)
 996           (nnmail-split-methods nnimap-split-methods)
 997           (nnmail-inhibit-default-split-group t)
 998           (groups (nnimap-get-groups))
 999           new-articles)
1000       (erase-buffer)
1001       (nnimap-command "SELECT %S" nnimap-inbox)
1002       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1003       (when new-articles
1004         (nnimap-fetch-inbox new-articles)
1005         (nnimap-transform-split-mail)
1006         (nnheader-ms-strip-cr)
1007         (nnmail-cache-open)
1008         (nnmail-split-incoming (current-buffer)
1009                                #'nnimap-save-mail-spec
1010                                nil nil
1011                                #'nnimap-dummy-active-number)
1012         (when nnimap-incoming-split-list
1013           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1014                 sequences)
1015             ;; Create any groups that doesn't already exist on the
1016             ;; server first.
1017             (dolist (spec specs)
1018               (unless (member (car spec) groups)
1019                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1020             ;; Then copy over all the messages.
1021             (erase-buffer)
1022             (dolist (spec specs)
1023               (let ((group (car spec))
1024                     (ranges (cdr spec)))
1025                 (push (list (nnimap-send-command "UID COPY %s %S"
1026                                                  (nnimap-article-ranges ranges)
1027                                                  (utf7-encode group t))
1028                             ranges)
1029                       sequences)))
1030             ;; Wait for the last COPY response...
1031             (when sequences
1032               (nnimap-wait-for-response (caar sequences))
1033               ;; And then mark the successful copy actions as deleted,
1034               ;; and possibly expunge them.
1035               (nnimap-mark-and-expunge-incoming
1036                (nnimap-parse-copied-articles sequences)))))))))
1037
1038 (defun nnimap-mark-and-expunge-incoming (range)
1039   (when range
1040     (setq range (nnimap-article-ranges range))
1041     (nnimap-send-command
1042      "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)
1043     (cond
1044      ;; If the server supports it, we now delete the message we have
1045      ;; just copied over.
1046      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1047       (nnimap-send-command "UID EXPUNGE %s" range))
1048      ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1049      ;; user has configured it.
1050      (nnimap-expunge-inbox
1051       (nnimap-send-command "EXPUNGE")))))
1052
1053 (defun nnimap-parse-copied-articles (sequences)
1054   (let (sequence copied range)
1055     (goto-char (point-min))
1056     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1057       (setq sequence (string-to-number (match-string 1)))
1058       (when (setq range (cadr (assq sequence sequences)))
1059         (push (gnus-uncompress-range range) copied)))
1060     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1061
1062 (defun nnimap-new-articles (flags)
1063   (let (new)
1064     (dolist (elem flags)
1065       (when (or (null (cdr elem))
1066                 (and (not (member "\\Deleted" (cdr elem)))
1067                      (not (member "\\Seen" (cdr elem)))))
1068         (push (car elem) new)))
1069     (gnus-compress-sequence (nreverse new))))
1070
1071 (defun nnimap-make-split-specs (list)
1072   (let ((specs nil)
1073         entry)
1074     (dolist (elem list)
1075       (destructuring-bind (article spec) elem
1076         (dolist (group (delete nil (mapcar #'car spec)))
1077           (unless (setq entry (assoc group specs))
1078             (push (setq entry (list group)) specs))
1079           (setcdr entry (cons article (cdr entry))))))
1080     (dolist (entry specs)
1081       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1082     specs))
1083
1084 (defun nnimap-transform-split-mail ()
1085   (goto-char (point-min))
1086   (let (article bytes)
1087     (block nil
1088       (while (not (eobp))
1089         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1090           (delete-region (point) (progn (forward-line 1) (point)))
1091           (when (eobp)
1092             (return)))
1093         (setq article (match-string 1)
1094               bytes (nnimap-get-length))
1095         (delete-region (line-beginning-position) (line-end-position))
1096         ;; Insert MMDF separator, and a way to remember what this
1097         ;; article UID is.
1098         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1099         (forward-char (1+ bytes))
1100         (setq bytes (nnimap-get-length))
1101         (delete-region (line-beginning-position) (line-end-position))
1102         (forward-char (1+ bytes))
1103         (delete-region (line-beginning-position) (line-end-position))))))
1104
1105 (defun nnimap-dummy-active-number (group &optional server)
1106   1)
1107
1108 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1109   (let (article)
1110     (goto-char (point-min))
1111     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1112         (error "Invalid nnimap mail")
1113       (setq article (string-to-number (match-string 1))))
1114     (push (list article group-art)
1115           nnimap-incoming-split-list)))
1116
1117 (provide 'nnimap)
1118
1119 ;;; nnimap.el ends here