cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40 (require 'utf7)
  41 (require 'tls)
  42 (require 'parse-time)
  43
  44 (autoload 'auth-source-forget-user-or-password "auth-source")
  45 (autoload 'auth-source-user-or-password "auth-source")
  46
  47 (nnoo-declare nnimap)
  48
  49 (defvoo nnimap-address nil
  50   "The address of the IMAP server.")
  51
  52 (defvoo nnimap-server-port nil
  53   "The IMAP port used.
  54 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  55 it will default to `imap'.")
  56
  57 (defvoo nnimap-stream 'ssl
  58   "How nnimap will talk to the IMAP server.
  59 Values are `ssl', `network', `starttls' or `shell'.")
  60
  61 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  62                                  (if (listp imap-shell-program)
  63                                      (car imap-shell-program)
  64                                    imap-shell-program)
  65                                "ssh %s imapd"))
  66
  67 (defvoo nnimap-inbox nil
  68   "The mail box where incoming mail arrives and should be split out of.")
  69
  70 (defvoo nnimap-split-methods nil
  71   "How mail is split.
  72 Uses the same syntax as nnmail-split-methods")
  73
  74 (defvoo nnimap-split-fancy nil
  75   "Uses the same syntax as nnmail-split-fancy.")
  76
  77 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  78                         "Emacs 24.1")
  79
  80 (defvoo nnimap-authenticator nil
  81   "How nnimap authenticate itself to the server.
  82 Possible choices are nil (use default methods) or `anonymous'.")
  83
  84 (defvoo nnimap-expunge t
  85   "If non-nil, expunge articles after deleting them.
  86 This is always done if the server supports UID EXPUNGE, but it's
  87 not done by default on servers that doesn't support that command.")
  88
  89 (defvoo nnimap-streaming t
  90   "If non-nil, try to use streaming commands with IMAP servers.
  91 Switching this off will make nnimap slower, but it helps with
  92 some servers.")
  93
  94 (defvoo nnimap-connection-alist nil)
  95
  96 (defvoo nnimap-current-infos nil)
  97
  98 (defvoo nnimap-fetch-partial-articles nil
  99   "If non-nil, Gnus will fetch partial articles.
 100 If t, nnimap will fetch only the first part.  If a string, it
 101 will fetch all parts that have types that match that string.  A
 102 likely value would be \"text/\" to automatically fetch all
 103 textual parts.")
 104
 105 (defvar nnimap-process nil)
 106
 107 (defvar nnimap-status-string "")
 108
 109 (defvar nnimap-split-download-body-default nil
 110   "Internal variable with default value for `nnimap-split-download-body'.")
 111
 112 (defvar nnimap-keepalive-timer nil)
 113 (defvar nnimap-process-buffers nil)
 114
 115 (defstruct nnimap
 116   group process commands capabilities select-result newlinep server
 117   last-command-time greeting)
 118
 119 (defvar nnimap-object nil)
 120
 121 (defvar nnimap-mark-alist
 122   '((read "\\Seen" %Seen)
 123     (tick "\\Flagged" %Flagged)
 124     (reply "\\Answered" %Answered)
 125     (expire "gnus-expire")
 126     (dormant "gnus-dormant")
 127     (score "gnus-score")
 128     (save "gnus-save")
 129     (download "gnus-download")
 130     (forward "gnus-forward")))
 131
 132 (defun nnimap-buffer ()
 133   (nnimap-find-process-buffer nntp-server-buffer))
 134
 135 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 136   (with-current-buffer nntp-server-buffer
 137     (erase-buffer)
 138     (when (nnimap-possibly-change-group group server)
 139       (with-current-buffer (nnimap-buffer)
 140         (erase-buffer)
 141         (nnimap-wait-for-response
 142          (nnimap-send-command
 143           "UID FETCH %s %s"
 144           (nnimap-article-ranges (gnus-compress-sequence articles))
 145           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 146                   (format
 147                    (if (nnimap-ver4-p)
 148                        "BODY.PEEK[HEADER.FIELDS %s]"
 149                      "RFC822.HEADER.LINES %s")
 150                    (append '(Subject From Date Message-Id
 151                                      References In-Reply-To Xref)
 152                            nnmail-extra-headers))))
 153          t)
 154         (nnimap-transform-headers))
 155       (insert-buffer-substring
 156        (nnimap-find-process-buffer (current-buffer))))
 157     'headers))
 158
 159 (defun nnimap-transform-headers ()
 160   (goto-char (point-min))
 161   (let (article bytes lines size string)
 162     (block nil
 163       (while (not (eobp))
 164         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 165           (delete-region (point) (progn (forward-line 1) (point)))
 166           (when (eobp)
 167             (return)))
 168         (setq article (match-string 1))
 169         ;; Unfold quoted {number} strings.
 170         (while (re-search-forward "[^]] {\\([0-9]+\\)}\r\n"
 171                                   (1+ (line-end-position)) t)
 172           (setq size (string-to-number (match-string 1)))
 173           (delete-region (+ (match-beginning 0) 2) (point))
 174           (setq string (delete-region (point) (+ (point) size)))
 175           (insert (format "%S" string)))
 176         (setq bytes (nnimap-get-length)
 177               lines nil)
 178         (beginning-of-line)
 179         (setq size
 180               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 181                                       (line-end-position)
 182                                       t)
 183                    (match-string 1)))
 184         (beginning-of-line)
 185         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 186           (let ((structure (ignore-errors
 187                              (read (current-buffer)))))
 188             (while (and (consp structure)
 189                         (not (stringp (car structure))))
 190               (setq structure (car structure)))
 191             (setq lines (nth 7 structure))))
 192         (delete-region (line-beginning-position) (line-end-position))
 193         (insert (format "211 %s Article retrieved." article))
 194         (forward-line 1)
 195         (when size
 196           (insert (format "Chars: %s\n" size)))
 197         (when lines
 198           (insert (format "Lines: %s\n" lines)))
 199         (re-search-forward "^\r$")
 200         (delete-region (line-beginning-position) (line-end-position))
 201         (insert ".")
 202         (forward-line 1)))))
 203
 204 (defun nnimap-get-length ()
 205   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 206        (string-to-number (match-string 1))))
 207
 208 (defun nnimap-article-ranges (ranges)
 209   (let (result)
 210     (cond
 211      ((numberp ranges)
 212       (number-to-string ranges))
 213      ((numberp (cdr ranges))
 214       (format "%d:%d" (car ranges) (cdr ranges)))
 215      (t
 216       (dolist (elem ranges)
 217         (push
 218          (if (consp elem)
 219              (format "%d:%d" (car elem) (cdr elem))
 220            (number-to-string elem))
 221          result))
 222       (mapconcat #'identity (nreverse result) ",")))))
 223
 224 (deffoo nnimap-open-server (server &optional defs)
 225   (if (nnimap-server-opened server)
 226       t
 227     (unless (assq 'nnimap-address defs)
 228       (setq defs (append defs (list (list 'nnimap-address server)))))
 229     (nnoo-change-server 'nnimap server defs)
 230     (or (nnimap-find-connection nntp-server-buffer)
 231         (nnimap-open-connection nntp-server-buffer))))
 232
 233 (defun nnimap-make-process-buffer (buffer)
 234   (with-current-buffer
 235       (generate-new-buffer (format "*nnimap %s %s %s*"
 236                                    nnimap-address nnimap-server-port
 237                                    (gnus-buffer-exists-p buffer)))
 238     (mm-disable-multibyte)
 239     (buffer-disable-undo)
 240     (gnus-add-buffer)
 241     (set (make-local-variable 'after-change-functions) nil)
 242     (set (make-local-variable 'nnimap-object)
 243          (make-nnimap :server (nnoo-current-server 'nnimap)))
 244     (push (list buffer (current-buffer)) nnimap-connection-alist)
 245     (push (current-buffer) nnimap-process-buffers)
 246     (current-buffer)))
 247
 248 (defun nnimap-open-shell-stream (name buffer host port)
 249   (let ((process-connection-type nil))
 250     (start-process name buffer shell-file-name
 251                    shell-command-switch
 252                    (format-spec
 253                     nnimap-shell-program
 254                     (format-spec-make
 255                      ?s host
 256                      ?p port)))))
 257
 258 (defun nnimap-credentials (address ports &optional inhibit-create)
 259   (let (port credentials)
 260     ;; Request the credentials from all ports, but only query on the
 261     ;; last port if all the previous ones have failed.
 262     (while (and (null credentials)
 263                 (setq port (pop ports)))
 264       (setq credentials
 265             (auth-source-user-or-password
 266              '("login" "password") address port nil
 267              (if inhibit-create
 268                  nil
 269                (null ports)))))
 270     credentials))
 271
 272 (defun nnimap-keepalive ()
 273   (let ((now (current-time)))
 274     (dolist (buffer nnimap-process-buffers)
 275       (when (buffer-name buffer)
 276         (with-current-buffer buffer
 277           (when (and nnimap-object
 278                      (nnimap-last-command-time nnimap-object)
 279                      (> (time-to-seconds
 280                          (time-subtract
 281                           now
 282                           (nnimap-last-command-time nnimap-object)))
 283                         ;; More than five minutes since the last command.
 284                         (* 5 60)))
 285             (nnimap-send-command "NOOP")))))))
 286
 287 (defun nnimap-open-connection (buffer)
 288   (unless nnimap-keepalive-timer
 289     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 290                                               'nnimap-keepalive)))
 291   (block nil
 292     (with-current-buffer (nnimap-make-process-buffer buffer)
 293       (let* ((coding-system-for-read 'binary)
 294              (coding-system-for-write 'binary)
 295              (port nil)
 296              (ports
 297               (cond
 298                ((eq nnimap-stream 'network)
 299                 (open-network-stream
 300                  "*nnimap*" (current-buffer) nnimap-address
 301                  (setq port
 302                        (or nnimap-server-port
 303                            (if (netrc-find-service-number "imap")
 304                                "imap"
 305                              "143"))))
 306                 '("143" "imap"))
 307                ((eq nnimap-stream 'shell)
 308                 (nnimap-open-shell-stream
 309                  "*nnimap*" (current-buffer) nnimap-address
 310                  (setq port (or nnimap-server-port "imap")))
 311                 '("imap"))
 312                ((eq nnimap-stream 'starttls)
 313                 (let ((tls-program (nnimap-extend-tls-programs)))
 314                   (open-tls-stream
 315                    "*nnimap*" (current-buffer) nnimap-address
 316                    (setq port (or nnimap-server-port "imap"))
 317                    'starttls))
 318                 '("imap"))
 319                ((memq nnimap-stream '(ssl tls))
 320                 (funcall (if (fboundp 'open-gnutls-stream)
 321                              'open-gnutls-stream
 322                            'open-tls-stream)
 323                          "*nnimap*" (current-buffer) nnimap-address
 324                          (setq port
 325                                (or nnimap-server-port
 326                                    (if (netrc-find-service-number "imaps")
 327                                        "imaps"
 328                                      "993"))))
 329                 '("143" "993" "imap" "imaps"))
 330                (t
 331                 (error "Unknown stream type: %s" nnimap-stream))))
 332              connection-result login-result credentials)
 333         (setf (nnimap-process nnimap-object)
 334               (get-buffer-process (current-buffer)))
 335         (if (not (and (nnimap-process nnimap-object)
 336                       (memq (process-status (nnimap-process nnimap-object))
 337                             '(open run))))
 338             (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 339                              nnimap-address port nnimap-stream)
 340           (gnus-set-process-query-on-exit-flag
 341            (nnimap-process nnimap-object) nil)
 342           (if (not (setq connection-result (nnimap-wait-for-connection)))
 343               (nnheader-report 'nnimap
 344                                "%s" (buffer-substring
 345                                      (point) (line-end-position)))
 346             ;; Store the greeting (for debugging purposes).
 347             (setf (nnimap-greeting nnimap-object)
 348                   (buffer-substring (line-beginning-position)
 349                                     (line-end-position)))
 350             ;; Store the capabilities.
 351             (setf (nnimap-capabilities nnimap-object)
 352                   (mapcar
 353                    #'upcase
 354                    (nnimap-find-parameter
 355                     "CAPABILITY" (cdr (nnimap-command "CAPABILITY")))))
 356             (when nnimap-server-port
 357               (push (format "%s" nnimap-server-port) ports))
 358             ;; If this is a STARTTLS-capable server, then sever the
 359             ;; connection and start a STARTTLS connection instead.
 360             (when (and (eq nnimap-stream 'network)
 361                        (member "STARTTLS" (nnimap-capabilities nnimap-object)))
 362               (let ((nnimap-stream 'starttls))
 363                 (let ((tls-process
 364                        (nnimap-open-connection buffer)))
 365                   ;; If the STARTTLS connection was successful, we
 366                   ;; kill our first non-encrypted connection.  If it
 367                   ;; wasn't successful, we just use our unencrypted
 368                   ;; connection.
 369                   (when (memq (process-status tls-process) '(open run))
 370                     (delete-process (nnimap-process nnimap-object))
 371                     (kill-buffer (current-buffer))
 372                     (return tls-process)))))
 373             (unless (equal connection-result "PREAUTH")
 374               (if (not (setq credentials
 375                              (if (eq nnimap-authenticator 'anonymous)
 376                                  (list "anonymous"
 377                                        (message-make-address))
 378                                (or
 379                                 ;; First look for the credentials based
 380                                 ;; on the virtual server name.
 381                                 (nnimap-credentials
 382                                  (nnoo-current-server 'nnimap) ports t)
 383                                 ;; Then look them up based on the
 384                                 ;; physical address.
 385                                 (nnimap-credentials nnimap-address ports)))))
 386                   (setq nnimap-object nil)
 387                 (setq login-result (nnimap-command "LOGIN %S %S"
 388                                                    (car credentials)
 389                                                    (cadr credentials)))
 390                 (unless (car login-result)
 391                   ;; If the login failed, then forget the credentials
 392                   ;; that are now possibly cached.
 393                   (dolist (host (list (nnoo-current-server 'nnimap)
 394                                       nnimap-address))
 395                     (dolist (port ports)
 396                       (dolist (element '("login" "password"))
 397                         (auth-source-forget-user-or-password
 398                          element host port))))
 399                   (delete-process (nnimap-process nnimap-object))
 400                   (setq nnimap-object nil))))
 401             (when nnimap-object
 402               (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 403                 (nnimap-command "ENABLE QRESYNC"))
 404               (nnimap-process nnimap-object))))))))
 405
 406 (defun nnimap-extend-tls-programs ()
 407   (let ((programs tls-program)
 408         result)
 409     (unless (consp programs)
 410       (setq programs (list programs)))
 411     (dolist (program programs)
 412       (when (assoc (car (split-string program)) tls-starttls-switches)
 413         (push (if (not (string-match "%s" program))
 414                   (concat program " " "%s")
 415                 program)
 416               result)))
 417     (nreverse result)))
 418
 419 (defun nnimap-find-parameter (parameter elems)
 420   (let (result)
 421     (dolist (elem elems)
 422       (cond
 423        ((equal (car elem) parameter)
 424         (setq result (cdr elem)))
 425        ((and (equal (car elem) "OK")
 426              (consp (cadr elem))
 427              (equal (caadr elem) parameter))
 428         (setq result (cdr (cadr elem))))))
 429     result))
 430
 431 (deffoo nnimap-close-server (&optional server)
 432   (when (nnoo-change-server 'nnimap server nil)
 433     (ignore-errors
 434       (delete-process (get-buffer-process (nnimap-buffer))))
 435     t))
 436
 437 (deffoo nnimap-request-close ()
 438   t)
 439
 440 (deffoo nnimap-server-opened (&optional server)
 441   (and (nnoo-current-server-p 'nnimap server)
 442        nntp-server-buffer
 443        (gnus-buffer-live-p nntp-server-buffer)
 444        (nnimap-find-connection nntp-server-buffer)))
 445
 446 (deffoo nnimap-status-message (&optional server)
 447   nnimap-status-string)
 448
 449 (deffoo nnimap-request-article (article &optional group server to-buffer)
 450   (with-current-buffer nntp-server-buffer
 451     (let ((result (nnimap-possibly-change-group group server))
 452           parts structure)
 453       (when (stringp article)
 454         (setq article (nnimap-find-article-by-message-id group article)))
 455       (when (and result
 456                  article)
 457         (erase-buffer)
 458         (with-current-buffer (nnimap-buffer)
 459           (erase-buffer)
 460           (when nnimap-fetch-partial-articles
 461             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 462             (goto-char (point-min))
 463             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 464               (setq structure (ignore-errors
 465                                 (let ((start (point)))
 466                                   (forward-sexp 1)
 467                                   (downcase-region start (point))
 468                                   (goto-char (point))
 469                                   (read (current-buffer))))
 470                     parts (nnimap-find-wanted-parts structure))))
 471           (when (if parts
 472                     (nnimap-get-partial-article article parts structure)
 473                   (nnimap-get-whole-article article))
 474             (let ((buffer (current-buffer)))
 475               (with-current-buffer (or to-buffer nntp-server-buffer)
 476                 (erase-buffer)
 477                 (insert-buffer-substring buffer)
 478                 (nnheader-ms-strip-cr)
 479                 (cons group article)))))))))
 480
 481 (defun nnimap-get-whole-article (article)
 482   (let ((result
 483          (nnimap-command
 484           (if (nnimap-ver4-p)
 485               "UID FETCH %d BODY.PEEK[]"
 486             "UID FETCH %d RFC822.PEEK")
 487           article)))
 488     ;; Check that we really got an article.
 489     (goto-char (point-min))
 490     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 491       (setq result nil))
 492     (when result
 493       ;; Remove any data that may have arrived before the FETCH data.
 494       (beginning-of-line)
 495       (unless (bobp)
 496         (delete-region (point-min) (point)))
 497       (let ((bytes (nnimap-get-length)))
 498         (delete-region (line-beginning-position)
 499                        (progn (forward-line 1) (point)))
 500         (goto-char (+ (point) bytes))
 501         (delete-region (point) (point-max)))
 502       t)))
 503
 504 (defun nnimap-ver4-p ()
 505   (member "IMAP4REV1" (nnimap-capabilities nnimap-object)))
 506
 507 (defun nnimap-get-partial-article (article parts structure)
 508   (let ((result
 509          (nnimap-command
 510           "UID FETCH %d (%s %s)"
 511           article
 512           (if (nnimap-ver4-p)
 513               "BODY.PEEK[HEADER]"
 514             "RFC822.HEADER")
 515           (if (nnimap-ver4-p)
 516               (mapconcat (lambda (part)
 517                            (format "BODY.PEEK[%s]" part))
 518                          parts " ")
 519             (mapconcat (lambda (part)
 520                          (format "RFC822.PEEK[%s]" part))
 521                        parts " ")))))
 522     (when result
 523       (nnimap-convert-partial-article structure))))
 524
 525 (defun nnimap-convert-partial-article (structure)
 526   ;; First just skip past the headers.
 527   (goto-char (point-min))
 528   (let ((bytes (nnimap-get-length))
 529         id parts)
 530     ;; Delete "FETCH" line.
 531     (delete-region (line-beginning-position)
 532                    (progn (forward-line 1) (point)))
 533     (goto-char (+ (point) bytes))
 534     ;; Collect all the body parts.
 535     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 536       (setq id (match-string 1)
 537             bytes (nnimap-get-length))
 538       (beginning-of-line)
 539       (delete-region (point) (progn (forward-line 1) (point)))
 540       (push (list id (buffer-substring (point) (+ (point) bytes)))
 541             parts)
 542       (delete-region (point) (+ (point) bytes)))
 543     ;; Delete trailing junk.
 544     (delete-region (point) (point-max))
 545     ;; Now insert all the parts again where they fit in the structure.
 546     (nnimap-insert-partial-structure structure parts)
 547     t))
 548
 549 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 550   (let (type boundary)
 551     (let ((bstruc structure))
 552       (while (consp (car bstruc))
 553         (pop bstruc))
 554       (setq type (car bstruc))
 555       (setq bstruc (car (cdr bstruc)))
 556       (when (and (stringp (car bstruc))
 557                  (string= (downcase (car bstruc)) "boundary"))
 558         (setq boundary (cadr bstruc))))
 559     (when subp
 560       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 561                       (downcase type) boundary)))
 562     (while (not (stringp (car structure)))
 563       (insert "\n--" boundary "\n")
 564       (if (consp (caar structure))
 565           (nnimap-insert-partial-structure (pop structure) parts t)
 566         (let ((bit (pop structure)))
 567           (insert (format  "Content-type: %s/%s"
 568                            (downcase (nth 0 bit))
 569                            (downcase (nth 1 bit))))
 570           (if (member "CHARSET" (nth 2 bit))
 571               (insert (format
 572                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
 573             (insert "\n"))
 574           (insert (format "Content-transfer-encoding: %s\n"
 575                           (nth 5 bit)))
 576           (insert "\n")
 577           (when (assoc (nth 9 bit) parts)
 578             (insert (cadr (assoc (nth 9 bit) parts)))))))
 579     (insert "\n--" boundary "--\n")))
 580
 581 (defun nnimap-find-wanted-parts (structure)
 582   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 583
 584 (defun nnimap-find-wanted-parts-1 (structure prefix)
 585   (let ((num 1)
 586         parts)
 587     (while (consp (car structure))
 588       (let ((sub (pop structure)))
 589         (if (consp (car sub))
 590             (push (nnimap-find-wanted-parts-1
 591                    sub (if (string= prefix "")
 592                            (number-to-string num)
 593                          (format "%s.%s" prefix num)))
 594                   parts)
 595           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 596                 (id (if (string= prefix "")
 597                         (number-to-string num)
 598                       (format "%s.%s" prefix num))))
 599             (setcar (nthcdr 9 sub) id)
 600             (when (if (eq nnimap-fetch-partial-articles t)
 601                       (equal id "1")
 602                     (string-match nnimap-fetch-partial-articles type))
 603               (push id parts))))
 604         (incf num)))
 605     (nreverse parts)))
 606
 607 (deffoo nnimap-request-group (group &optional server dont-check info)
 608   (let ((result (nnimap-possibly-change-group group server))
 609         articles active marks high low)
 610     (with-current-buffer nntp-server-buffer
 611       (when result
 612         (if (and dont-check
 613                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 614             (insert (format "211 %d %d %d %S\n"
 615                             (- (cdr active) (car active))
 616                             (car active)
 617                             (cdr active)
 618                             group))
 619           (with-current-buffer (nnimap-buffer)
 620             (erase-buffer)
 621             (let ((group-sequence
 622                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 623                   (flag-sequence
 624                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 625               (nnimap-wait-for-response flag-sequence)
 626               (setq marks
 627                     (nnimap-flags-to-marks
 628                      (nnimap-parse-flags
 629                       (list (list group-sequence flag-sequence
 630                                   1 group "SELECT")))))
 631               (when (and info
 632                          marks)
 633                 (nnimap-update-infos marks (list info)))
 634               (goto-char (point-max))
 635               (let ((uidnext (nth 5 (car marks))))
 636                 (setq high (or (if uidnext
 637                                    (1- uidnext)
 638                                  (nth 3 (car marks)))
 639                                0)
 640                       low (or (nth 4 (car marks)) uidnext 1)))))
 641           (erase-buffer)
 642           (insert
 643            (format
 644             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 645         t))))
 646
 647 (deffoo nnimap-request-create-group (group &optional server args)
 648   (when (nnimap-possibly-change-group nil server)
 649     (with-current-buffer (nnimap-buffer)
 650       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 651
 652 (deffoo nnimap-request-delete-group (group &optional force server)
 653   (when (nnimap-possibly-change-group nil server)
 654     (with-current-buffer (nnimap-buffer)
 655       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 656
 657 (deffoo nnimap-request-rename-group (group new-name &optional server)
 658   (when (nnimap-possibly-change-group nil server)
 659     (with-current-buffer (nnimap-buffer)
 660       (car (nnimap-command "RENAME %S %S"
 661                            (utf7-encode group t) (utf7-encode new-name t))))))
 662
 663 (deffoo nnimap-request-expunge-group (group &optional server)
 664   (when (nnimap-possibly-change-group group server)
 665     (with-current-buffer (nnimap-buffer)
 666       (car (nnimap-command "EXPUNGE")))))
 667
 668 (defun nnimap-get-flags (spec)
 669   (let ((articles nil)
 670         elems end)
 671     (with-current-buffer (nnimap-buffer)
 672       (erase-buffer)
 673       (nnimap-wait-for-response (nnimap-send-command
 674                                  "UID FETCH %s FLAGS" spec))
 675       (setq end (point))
 676       (subst-char-in-region (point-min) (point-max)
 677                             ?\\ ?% t)
 678       (goto-char (point-min))
 679       (while (search-forward " FETCH " end t)
 680         (setq elems (read (current-buffer)))
 681         (push (cons (cadr (memq 'UID elems))
 682                     (cadr (memq 'FLAGS elems)))
 683               articles)))
 684     (nreverse articles)))
 685
 686 (deffoo nnimap-close-group (group &optional server)
 687   t)
 688
 689 (deffoo nnimap-request-move-article (article group server accept-form
 690                                              &optional last internal-move-group)
 691   (with-temp-buffer
 692     (when (nnimap-request-article article group server (current-buffer))
 693       ;; If the move is internal (on the same server), just do it the easy
 694       ;; way.
 695       (let ((message-id (message-field-value "message-id")))
 696         (if internal-move-group
 697             (let ((result
 698                    (with-current-buffer (nnimap-buffer)
 699                      (nnimap-command "UID COPY %d %S"
 700                                      article
 701                                      (utf7-encode internal-move-group t)))))
 702               (when (car result)
 703                 (nnimap-delete-article article)
 704                 (cons internal-move-group
 705                       (nnimap-find-article-by-message-id
 706                        internal-move-group message-id))))
 707           ;; Move the article to a different method.
 708           (let ((result (eval accept-form)))
 709             (when result
 710               (nnimap-delete-article article)
 711               result)))))))
 712
 713 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 714   (cond
 715    ((null articles)
 716     nil)
 717    ((not (nnimap-possibly-change-group group server))
 718     articles)
 719    ((and force
 720          (eq nnmail-expiry-target 'delete))
 721     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 722       (message "Article marked for deletion, but not expunged."))
 723     nil)
 724    (t
 725     (let ((deletable-articles
 726            (if (or force
 727                    (eq nnmail-expiry-wait 'immediate))
 728                articles
 729              (gnus-sorted-intersection
 730               articles
 731               (nnimap-find-expired-articles group)))))
 732       (if (null deletable-articles)
 733           articles
 734         (if (eq nnmail-expiry-target 'delete)
 735             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 736           (setq deletable-articles
 737                 (nnimap-process-expiry-targets
 738                  deletable-articles group server)))
 739         ;; Return the articles we didn't delete.
 740         (gnus-sorted-complement articles deletable-articles))))))
 741
 742 (defun nnimap-process-expiry-targets (articles group server)
 743   (let ((deleted-articles nil))
 744     (dolist (article articles)
 745       (let ((target nnmail-expiry-target))
 746         (with-temp-buffer
 747           (when (nnimap-request-article article group server (current-buffer))
 748             (message "Expiring article %s:%d" group article)
 749             (when (functionp target)
 750               (setq target (funcall target group)))
 751             (when (and target
 752                        (not (eq target 'delete)))
 753               (if (or (gnus-request-group target t)
 754                       (gnus-request-create-group target))
 755                   (nnmail-expiry-target-group target group)
 756                 (setq target nil)))
 757             (when target
 758               (push article deleted-articles))))))
 759     ;; Change back to the current group again.
 760     (nnimap-possibly-change-group group server)
 761     (setq deleted-articles (nreverse deleted-articles))
 762     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 763     deleted-articles))
 764
 765 (defun nnimap-find-expired-articles (group)
 766   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 767     (with-current-buffer (nnimap-buffer)
 768       (let ((result
 769              (nnimap-command
 770               "UID SEARCH SENTBEFORE %s"
 771               (format-time-string
 772                (format "%%d-%s-%%Y"
 773                        (upcase
 774                         (car (rassoc (nth 4 (decode-time cutoff))
 775                                      parse-time-months))))
 776                cutoff))))
 777         (and (car result)
 778              (delete 0 (mapcar #'string-to-number
 779                                (cdr (assoc "SEARCH" (cdr result))))))))))
 780
 781
 782 (defun nnimap-find-article-by-message-id (group message-id)
 783   (with-current-buffer (nnimap-buffer)
 784     (erase-buffer)
 785     (setf (nnimap-group nnimap-object) nil)
 786     (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 787     (let ((sequence
 788            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 789           article result)
 790       (setq result (nnimap-wait-for-response sequence))
 791       (when (and result
 792                  (car (setq result (nnimap-parse-response))))
 793         ;; Select the last instance of the message in the group.
 794         (and (setq article
 795                    (car (last (assoc "SEARCH" (cdr result)))))
 796              (string-to-number article))))))
 797
 798 (defun nnimap-delete-article (articles)
 799   (with-current-buffer (nnimap-buffer)
 800     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 801                     (nnimap-article-ranges articles))
 802     (cond
 803      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
 804       (nnimap-command "UID EXPUNGE %s"
 805                       (nnimap-article-ranges articles))
 806       t)
 807      (nnimap-expunge
 808       (nnimap-command "EXPUNGE")
 809       t)
 810      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 811                                 "server doesn't support UIDPLUS, so we won't "
 812                                 "delete this article now"))))))
 813
 814 (deffoo nnimap-request-scan (&optional group server)
 815   (when (and (nnimap-possibly-change-group nil server)
 816              nnimap-inbox
 817              nnimap-split-methods)
 818     (message "nnimap %s splitting mail..." server)
 819     (nnimap-split-incoming-mail)))
 820
 821 (defun nnimap-marks-to-flags (marks)
 822   (let (flags flag)
 823     (dolist (mark marks)
 824       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 825         (push flag flags)))
 826     flags))
 827
 828 (deffoo nnimap-request-set-mark (group actions &optional server)
 829   (when (nnimap-possibly-change-group group server)
 830     (let (sequence)
 831       (with-current-buffer (nnimap-buffer)
 832         (erase-buffer)
 833         ;; Just send all the STORE commands without waiting for
 834         ;; response.  If they're successful, they're successful.
 835         (dolist (action actions)
 836           (destructuring-bind (range action marks) action
 837             (let ((flags (nnimap-marks-to-flags marks)))
 838               (when flags
 839                 (setq sequence (nnimap-send-command
 840                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 841                                 (nnimap-article-ranges range)
 842                                 (if (eq action 'del)
 843                                     "-"
 844                                   "+")
 845                                 (mapconcat #'identity flags " ")))))))
 846         ;; Wait for the last command to complete to avoid later
 847         ;; syncronisation problems with the stream.
 848         (when sequence
 849           (nnimap-wait-for-response sequence))))))
 850
 851 (deffoo nnimap-request-accept-article (group &optional server last)
 852   (when (nnimap-possibly-change-group nil server)
 853     (nnmail-check-syntax)
 854     (let ((message-id (message-field-value "message-id"))
 855           sequence message)
 856       (nnimap-add-cr)
 857       (setq message (buffer-string))
 858       (with-current-buffer (nnimap-buffer)
 859         (setq sequence (nnimap-send-command
 860                         "APPEND %S {%d}" (utf7-encode group t)
 861                         (length message)))
 862         (process-send-string (get-buffer-process (current-buffer)) message)
 863         (process-send-string (get-buffer-process (current-buffer))
 864                              (if (nnimap-newlinep nnimap-object)
 865                                  "\n"
 866                                "\r\n"))
 867         (let ((result (nnimap-get-response sequence)))
 868           (if (not (car result))
 869               (progn
 870                 (message "%s" (nnheader-get-report-string 'nnimap))
 871                 nil)
 872             (cons group
 873                   (nnimap-find-article-by-message-id group message-id))))))))
 874
 875 (defun nnimap-add-cr ()
 876   (goto-char (point-min))
 877   (while (re-search-forward "\r?\n" nil t)
 878     (replace-match "\r\n" t t)))
 879
 880 (defun nnimap-get-groups ()
 881   (let ((result (nnimap-command "LIST \"\" \"*\""))
 882         groups)
 883     (when (car result)
 884       (dolist (line (cdr result))
 885         (when (and (equal (car line) "LIST")
 886                    (not (and (caadr line)
 887                              (string-match "noselect" (caadr line)))))
 888           (push (car (last line)) groups)))
 889       (nreverse groups))))
 890
 891 (deffoo nnimap-request-list (&optional server)
 892   (nnimap-possibly-change-group nil server)
 893   (with-current-buffer nntp-server-buffer
 894     (erase-buffer)
 895     (let ((groups
 896            (with-current-buffer (nnimap-buffer)
 897              (nnimap-get-groups)))
 898           sequences responses)
 899       (when groups
 900         (with-current-buffer (nnimap-buffer)
 901           (setf (nnimap-group nnimap-object) nil)
 902           (dolist (group groups)
 903             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 904                         group)
 905                   sequences))
 906           (nnimap-wait-for-response (caar sequences))
 907           (setq responses
 908                 (nnimap-get-responses (mapcar #'car sequences))))
 909         (dolist (response responses)
 910           (let* ((sequence (car response))
 911                  (response (cadr response))
 912                  (group (cadr (assoc sequence sequences))))
 913             (when (and group
 914                        (equal (caar response) "OK"))
 915               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 916                     highest exists)
 917                 (dolist (elem response)
 918                   (when (equal (cadr elem) "EXISTS")
 919                     (setq exists (string-to-number (car elem)))))
 920                 (when uidnext
 921                   (setq highest (1- (string-to-number (car uidnext)))))
 922                 (cond
 923                  ((null highest)
 924                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 925                  ((zerop exists)
 926                   ;; Empty group.
 927                   (insert (format "%S %d %d y\n"
 928                                   (utf7-decode group t) highest (1+ highest))))
 929                  (t
 930                   ;; Return the widest possible range.
 931                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 932                                   (or highest exists)))))))))
 933         t))))
 934
 935 (deffoo nnimap-request-newgroups (date &optional server)
 936   (nnimap-possibly-change-group nil server)
 937   (with-current-buffer nntp-server-buffer
 938     (erase-buffer)
 939     (dolist (group (with-current-buffer (nnimap-buffer)
 940                      (nnimap-get-groups)))
 941       (unless (assoc group nnimap-current-infos)
 942         ;; Insert dummy numbers here -- they don't matter.
 943         (insert (format "%S 0 1 y\n" group))))
 944     t))
 945
 946 (deffoo nnimap-retrieve-group-data-early (server infos)
 947   (when (nnimap-possibly-change-group nil server)
 948     (with-current-buffer (nnimap-buffer)
 949       (erase-buffer)
 950       (setf (nnimap-group nnimap-object) nil)
 951       ;; QRESYNC handling isn't implemented.
 952       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 953             params groups sequences active uidvalidity modseq group)
 954         ;; Go through the infos and gather the data needed to know
 955         ;; what and how to request the data.
 956         (dolist (info infos)
 957           (setq params (gnus-info-params info)
 958                 group (gnus-group-real-name (gnus-info-group info))
 959                 active (cdr (assq 'active params))
 960                 uidvalidity (cdr (assq 'uidvalidity params))
 961                 modseq (cdr (assq 'modseq params)))
 962           (if (and qresyncp
 963                    uidvalidity
 964                    modseq)
 965               (push
 966                (list 'qresync
 967                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 968                                           group uidvalidity modseq)
 969                      nil group 'qresync)
 970                sequences)
 971             (let ((start
 972                    (if (and active uidvalidity)
 973                        ;; Fetch the last 100 flags.
 974                        (max 1 (- (cdr active) 100))
 975                      1))
 976                   (command
 977                    (if uidvalidity
 978                        "EXAMINE"
 979                      ;; If we don't have a UIDVALIDITY, then this is
 980                      ;; the first time we've seen the group, so we
 981                      ;; have to do a SELECT (which is slower than an
 982                      ;; examine), but will tell us whether the group
 983                      ;; is read-only or not.
 984                      "SELECT")))
 985               (push (list (nnimap-send-command "%s %S" command group)
 986                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 987                           start group command)
 988                     sequences)))
 989           ;; Some servers apparently can't have many outstanding
 990           ;; commands, so throttle them.
 991           (when (and (not nnimap-streaming)
 992                      (car sequences))
 993             (nnimap-wait-for-response (caar sequences))))
 994         sequences))))
 995
 996 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 997   (when (and sequences
 998              (nnimap-possibly-change-group nil server))
 999     (with-current-buffer (nnimap-buffer)
1000       ;; Wait for the final data to trickle in.
1001       (when (nnimap-wait-for-response (cadar sequences) t)
1002         ;; Now we should have most of the data we need, no matter
1003         ;; whether we're QRESYNCING, fetching all the flags from
1004         ;; scratch, or just fetching the last 100 flags per group.
1005         (nnimap-update-infos (nnimap-flags-to-marks
1006                               (nnimap-parse-flags
1007                                (nreverse sequences)))
1008                              infos)
1009         ;; Finally, just return something resembling an active file in
1010         ;; the nntp buffer, so that the agent can save the info, too.
1011         (with-current-buffer nntp-server-buffer
1012           (erase-buffer)
1013           (dolist (info infos)
1014             (let* ((group (gnus-info-group info))
1015                    (active (gnus-active group)))
1016               (when active
1017                 (insert (format "%S %d %d y\n"
1018                                 (gnus-group-real-name group)
1019                                 (cdr active)
1020                                 (car active)))))))))))
1021
1022 (defun nnimap-update-infos (flags infos)
1023   (dolist (info infos)
1024     (let* ((group (gnus-group-real-name (gnus-info-group info)))
1025            (marks (cdr (assoc group flags))))
1026       (when marks
1027         (nnimap-update-info info marks)))))
1028
1029 (defun nnimap-update-info (info marks)
1030   (destructuring-bind (existing flags high low uidnext start-article
1031                                 permanent-flags uidvalidity) marks
1032     (cond
1033      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1034      ;; completely empty groups.
1035      ((and (not existing)
1036            (not uidnext))
1037       )
1038      ;; We have a mismatch between the old and new UIDVALIDITY
1039      ;; identifiers, so we have to re-request the group info (the next
1040      ;; time).  This virtually never happens.
1041      ((let ((old-uidvalidity
1042              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1043         (and old-uidvalidity
1044              (not (equal old-uidvalidity uidvalidity))
1045              (> start-article 1)))
1046       (gnus-group-remove-parameter info 'uidvalidity))
1047      ;; We have the data needed to update.
1048      (t
1049       (let ((group (gnus-info-group info))
1050             (completep (and start-article
1051                             (= start-article 1))))
1052         (when uidnext
1053           (setq high (1- uidnext)))
1054         ;; First set the active ranges based on high/low.
1055         (if (or completep
1056                 (not (gnus-active group)))
1057             (gnus-set-active group
1058                              (cond
1059                               ((and low high)
1060                                (cons low high))
1061                               (uidnext
1062                                ;; No articles in this group.
1063                                (cons uidnext (1- uidnext)))
1064                               (start-article
1065                                (cons start-article (1- start-article)))
1066                               (t
1067                                ;; No articles and no uidnext.
1068                                nil)))
1069           (gnus-set-active
1070            group
1071            (cons (car (gnus-active group))
1072                  (or high (1- uidnext)))))
1073         ;; See whether this is a read-only group.
1074         (unless (eq permanent-flags 'not-scanned)
1075           (gnus-group-set-parameter
1076            info 'permanent-flags
1077            (if (memq '%* permanent-flags)
1078                t
1079              nil)))
1080         ;; Then update marks and read articles if this isn't a
1081         ;; read-only IMAP group.
1082         (when (cdr (assq 'permanent-flags (gnus-info-params info)))
1083           ;; Update the list of read articles.
1084           (let* ((unread
1085                   (gnus-compress-sequence
1086                    (gnus-set-difference
1087                     (gnus-set-difference
1088                      existing
1089                      (cdr (assoc '%Seen flags)))
1090                     (cdr (assoc '%Flagged flags)))))
1091                  (read (gnus-range-difference
1092                         (cons start-article high) unread)))
1093             (when (> start-article 1)
1094               (setq read
1095                     (gnus-range-nconcat
1096                      (if (> start-article 1)
1097                          (gnus-sorted-range-intersection
1098                           (cons 1 (1- start-article))
1099                           (gnus-info-read info))
1100                        (gnus-info-read info))
1101                      read)))
1102             (gnus-info-set-read info read)
1103             ;; Update the marks.
1104             (setq marks (gnus-info-marks info))
1105             (dolist (type (cdr nnimap-mark-alist))
1106               (let ((old-marks (assoc (car type) marks))
1107                     (new-marks
1108                      (gnus-compress-sequence
1109                       (cdr (or (assoc (caddr type) flags) ; %Flagged
1110                                (assoc (intern (cadr type) obarray) flags)
1111                                (assoc (cadr type) flags)))))) ; "\Flagged"
1112                 (setq marks (delq old-marks marks))
1113                 (pop old-marks)
1114                 (when (and old-marks
1115                            (> start-article 1))
1116                   (setq old-marks (gnus-range-difference
1117                                    old-marks
1118                                    (cons start-article high)))
1119                   (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1120                 (when new-marks
1121                   (push (cons (car type) new-marks) marks)))
1122               (gnus-info-set-marks info marks t))))
1123         ;; Note the active level for the next run-through.
1124         (gnus-group-set-parameter info 'active (gnus-active group))
1125         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1126         (nnimap-store-info info (gnus-active group)))))))
1127
1128 (defun nnimap-store-info (info active)
1129   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1130          (entry (assoc group nnimap-current-infos)))
1131     (if entry
1132         (setcdr entry (list info active))
1133       (push (list group info active) nnimap-current-infos))))
1134
1135 (defun nnimap-flags-to-marks (groups)
1136   (let (data group totalp uidnext articles start-article mark permanent-flags
1137              uidvalidity)
1138     (dolist (elem groups)
1139       (setq group (car elem)
1140             uidnext (nth 1 elem)
1141             start-article (nth 2 elem)
1142             permanent-flags (nth 3 elem)
1143             uidvalidity (nth 4 elem)
1144             articles (nthcdr 5 elem))
1145       (let ((high (caar articles))
1146             marks low existing)
1147         (dolist (article articles)
1148           (setq low (car article))
1149           (push (car article) existing)
1150           (dolist (flag (cdr article))
1151             (setq mark (assoc flag marks))
1152             (if (not mark)
1153                 (push (list flag (car article)) marks)
1154               (setcdr mark (cons (car article) (cdr mark))))))
1155         (push (list group existing marks high low uidnext start-article
1156                     permanent-flags uidvalidity)
1157               data)))
1158     data))
1159
1160 (defun nnimap-parse-flags (sequences)
1161   (goto-char (point-min))
1162   ;; Change \Delete etc to %Delete, so that the reader can read it.
1163   (subst-char-in-region (point-min) (point-max)
1164                         ?\\ ?% t)
1165   (let (start end articles groups uidnext elems permanent-flags
1166               uidvalidity)
1167     (dolist (elem sequences)
1168       (destructuring-bind (group-sequence flag-sequence totalp group command)
1169           elem
1170         (setq start (point))
1171         ;; The EXAMINE was successful.
1172         (when (and
1173                (search-forward (format "\n%d OK " group-sequence) nil t)
1174                (progn
1175                  (forward-line 1)
1176                  (setq end (point))
1177                  (goto-char start)
1178                  (setq permanent-flags
1179                        (if (equal command "SELECT")
1180                            (and (search-forward "PERMANENTFLAGS "
1181                                                 (or end (point-min)) t)
1182                                 (read (current-buffer)))
1183                          'not-scanned))
1184                  (goto-char start)
1185                  (setq uidnext
1186                        (and (search-forward "UIDNEXT "
1187                                             (or end (point-min)) t)
1188                             (read (current-buffer))))
1189                  (goto-char start)
1190                  (setq uidvalidity
1191                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1192                                             (or end (point-min)) t)
1193                             ;; Store UIDVALIDITY as a string, as it's
1194                             ;; too big for 32-bit Emacsen, usually.
1195                             (match-string 1)))
1196                  (goto-char end)
1197                  (forward-line -1))
1198                ;; The UID FETCH FLAGS was successful.
1199                (search-forward (format "\n%d OK " flag-sequence) nil t))
1200           (setq start (point))
1201           (goto-char end)
1202           (while (search-forward " FETCH " start t)
1203             (setq elems (read (current-buffer)))
1204             (push (cons (cadr (memq 'UID elems))
1205                         (cadr (memq 'FLAGS elems)))
1206                   articles))
1207           (push (nconc (list group uidnext totalp permanent-flags uidvalidity)
1208                        articles)
1209                 groups)
1210           (setq articles nil))))
1211     groups))
1212
1213 (defun nnimap-find-process-buffer (buffer)
1214   (cadr (assoc buffer nnimap-connection-alist)))
1215
1216 (deffoo nnimap-request-post (&optional server)
1217   (setq nnimap-status-string "Read-only server")
1218   nil)
1219
1220 (defun nnimap-possibly-change-group (group server)
1221   (let ((open-result t))
1222     (when (and server
1223                (not (nnimap-server-opened server)))
1224       (setq open-result (nnimap-open-server server)))
1225     (cond
1226      ((not open-result)
1227       nil)
1228      ((not group)
1229       t)
1230      (t
1231       (with-current-buffer (nnimap-buffer)
1232         (if (equal group (nnimap-group nnimap-object))
1233             t
1234           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1235             (when (car result)
1236               (setf (nnimap-group nnimap-object) group
1237                     (nnimap-select-result nnimap-object) result)
1238               result))))))))
1239
1240 (defun nnimap-find-connection (buffer)
1241   "Find the connection delivering to BUFFER."
1242   (let ((entry (assoc buffer nnimap-connection-alist)))
1243     (when entry
1244       (if (and (buffer-name (cadr entry))
1245                (get-buffer-process (cadr entry))
1246                (memq (process-status (get-buffer-process (cadr entry)))
1247                      '(open run)))
1248           (get-buffer-process (cadr entry))
1249         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1250         nil))))
1251
1252 (defvar nnimap-sequence 0)
1253
1254 (defun nnimap-send-command (&rest args)
1255   (process-send-string
1256    (get-buffer-process (current-buffer))
1257    (nnimap-log-command
1258     (format "%d %s%s\n"
1259             (incf nnimap-sequence)
1260             (apply #'format args)
1261             (if (nnimap-newlinep nnimap-object)
1262                 ""
1263               "\r"))))
1264   nnimap-sequence)
1265
1266 (defun nnimap-log-command (command)
1267   (with-current-buffer (get-buffer-create "*imap log*")
1268     (goto-char (point-max))
1269     (insert (format-time-string "%H:%M:%S") " " command))
1270   command)
1271
1272 (defun nnimap-command (&rest args)
1273   (erase-buffer)
1274   (setf (nnimap-last-command-time nnimap-object) (current-time))
1275   (let* ((sequence (apply #'nnimap-send-command args))
1276          (response (nnimap-get-response sequence)))
1277     (if (equal (caar response) "OK")
1278         (cons t response)
1279       (nnheader-report 'nnimap "%s"
1280                        (mapconcat (lambda (a)
1281                                     (format "%s" a))
1282                                   (car response) " "))
1283       nil)))
1284
1285 (defun nnimap-get-response (sequence)
1286   (nnimap-wait-for-response sequence)
1287   (nnimap-parse-response))
1288
1289 (defun nnimap-wait-for-connection ()
1290   (let ((process (get-buffer-process (current-buffer))))
1291     (goto-char (point-min))
1292     (while (and (memq (process-status process)
1293                       '(open run))
1294                 (not (re-search-forward "^[*.] .*\n" nil t)))
1295       (nnheader-accept-process-output process)
1296       (goto-char (point-min)))
1297     (forward-line -1)
1298     (and (looking-at "[*.] \\([A-Z0-9]+\\)")
1299          (match-string 1))))
1300
1301 (defun nnimap-wait-for-response (sequence &optional messagep)
1302   (let ((process (get-buffer-process (current-buffer)))
1303         openp)
1304     (goto-char (point-max))
1305     (while (and (setq openp (memq (process-status process)
1306                                   '(open run)))
1307                 (not (re-search-backward
1308                       (format "^%d .*\n" sequence)
1309                       (if nnimap-streaming
1310                           (max (point-min) (- (point) 500))
1311                         (point-min))
1312                       t)))
1313       (when messagep
1314         (message "nnimap read %dk" (/ (buffer-size) 1000)))
1315       (nnheader-accept-process-output process)
1316       (goto-char (point-max)))
1317     openp))
1318
1319 (defun nnimap-parse-response ()
1320   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1321         result)
1322     (dolist (line lines)
1323       (push (cdr (nnimap-parse-line line)) result))
1324     ;; Return the OK/error code first, and then all the "continuation
1325     ;; lines" afterwards.
1326     (cons (pop result)
1327           (nreverse result))))
1328
1329 ;; Parse an IMAP response line lightly.  They look like
1330 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1331 ;; the lines into a list of strings and lists of string.
1332 (defun nnimap-parse-line (line)
1333   (let (char result)
1334     (with-temp-buffer
1335       (insert line)
1336       (goto-char (point-min))
1337       (while (not (eobp))
1338         (if (eql (setq char (following-char)) ? )
1339             (forward-char 1)
1340           (push
1341            (cond
1342             ((eql char ?\[)
1343              (split-string
1344               (buffer-substring
1345                (1+ (point))
1346                (1- (search-forward "]" (line-end-position) 'move)))))
1347             ((eql char ?\()
1348              (split-string
1349               (buffer-substring
1350                (1+ (point))
1351                (1- (search-forward ")" (line-end-position) 'move)))))
1352             ((eql char ?\")
1353              (forward-char 1)
1354              (buffer-substring
1355               (point)
1356               (1- (or (search-forward "\"" (line-end-position) 'move)
1357                       (point)))))
1358             (t
1359              (buffer-substring (point) (if (search-forward " " nil t)
1360                                            (1- (point))
1361                                          (goto-char (point-max))))))
1362            result)))
1363       (nreverse result))))
1364
1365 (defun nnimap-last-response-string ()
1366   (save-excursion
1367     (forward-line 1)
1368     (let ((end (point)))
1369       (forward-line -1)
1370       (when (not (bobp))
1371         (forward-line -1)
1372         (while (and (not (bobp))
1373                     (eql (following-char) ?*))
1374           (forward-line -1))
1375         (unless (eql (following-char) ?*)
1376           (forward-line 1)))
1377       (buffer-substring (point) end))))
1378
1379 (defun nnimap-get-responses (sequences)
1380   (let (responses)
1381     (dolist (sequence sequences)
1382       (goto-char (point-min))
1383       (when (re-search-forward (format "^%d " sequence) nil t)
1384         (push (list sequence (nnimap-parse-response))
1385               responses)))
1386     responses))
1387
1388 (defvar nnimap-incoming-split-list nil)
1389
1390 (defun nnimap-fetch-inbox (articles)
1391   (erase-buffer)
1392   (nnimap-wait-for-response
1393    (nnimap-send-command
1394     "UID FETCH %s %s"
1395     (nnimap-article-ranges articles)
1396     (format "(UID %s%s)"
1397             (format
1398              (if (nnimap-ver4-p)
1399                  "BODY.PEEK[HEADER] BODY.PEEK"
1400                "RFC822.PEEK"))
1401             (if nnimap-split-download-body-default
1402                 "[]"
1403               "[1]")))
1404    t))
1405
1406 (defun nnimap-split-incoming-mail ()
1407   (with-current-buffer (nnimap-buffer)
1408     (let ((nnimap-incoming-split-list nil)
1409           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1410                                     nnmail-split-methods
1411                                   nnimap-split-methods))
1412           (nnmail-split-fancy (or nnimap-split-fancy
1413                                   nnmail-split-fancy))
1414           (nnmail-inhibit-default-split-group t)
1415           (groups (nnimap-get-groups))
1416           new-articles)
1417       (erase-buffer)
1418       (nnimap-command "SELECT %S" nnimap-inbox)
1419       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1420       (when new-articles
1421         (nnimap-fetch-inbox new-articles)
1422         (nnimap-transform-split-mail)
1423         (nnheader-ms-strip-cr)
1424         (nnmail-cache-open)
1425         (nnmail-split-incoming (current-buffer)
1426                                #'nnimap-save-mail-spec
1427                                nil nil
1428                                #'nnimap-dummy-active-number
1429                                #'nnimap-save-mail-spec)
1430         (when nnimap-incoming-split-list
1431           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1432                 sequences junk-articles)
1433             ;; Create any groups that doesn't already exist on the
1434             ;; server first.
1435             (dolist (spec specs)
1436               (when (and (not (member (car spec) groups))
1437                          (not (eq (car spec) 'junk)))
1438                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1439             ;; Then copy over all the messages.
1440             (erase-buffer)
1441             (dolist (spec specs)
1442               (let ((group (car spec))
1443                     (ranges (cdr spec)))
1444                 (if (eq group 'junk)
1445                     (setq junk-articles ranges)
1446                   (push (list (nnimap-send-command
1447                                "UID COPY %s %S"
1448                                (nnimap-article-ranges ranges)
1449                                (utf7-encode group t))
1450                               ranges)
1451                         sequences))))
1452             ;; Wait for the last COPY response...
1453             (when sequences
1454               (nnimap-wait-for-response (caar sequences))
1455               ;; And then mark the successful copy actions as deleted,
1456               ;; and possibly expunge them.
1457               (nnimap-mark-and-expunge-incoming
1458                (nnimap-parse-copied-articles sequences)))
1459             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1460
1461 (defun nnimap-mark-and-expunge-incoming (range)
1462   (when range
1463     (setq range (nnimap-article-ranges range))
1464     (erase-buffer)
1465     (let ((sequence
1466            (nnimap-send-command
1467             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1468       (cond
1469        ;; If the server supports it, we now delete the message we have
1470        ;; just copied over.
1471        ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1472         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1473        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1474        ;; user has configured it.
1475        (nnimap-expunge
1476         (setq sequence (nnimap-send-command "EXPUNGE"))))
1477       (nnimap-wait-for-response sequence))))
1478
1479 (defun nnimap-parse-copied-articles (sequences)
1480   (let (sequence copied range)
1481     (goto-char (point-min))
1482     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1483       (setq sequence (string-to-number (match-string 1)))
1484       (when (setq range (cadr (assq sequence sequences)))
1485         (push (gnus-uncompress-range range) copied)))
1486     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1487
1488 (defun nnimap-new-articles (flags)
1489   (let (new)
1490     (dolist (elem flags)
1491       (when (or (null (cdr elem))
1492                 (and (not (memq '%Deleted (cdr elem)))
1493                      (not (memq '%Seen (cdr elem)))))
1494         (push (car elem) new)))
1495     (gnus-compress-sequence (nreverse new))))
1496
1497 (defun nnimap-make-split-specs (list)
1498   (let ((specs nil)
1499         entry)
1500     (dolist (elem list)
1501       (destructuring-bind (article spec) elem
1502         (dolist (group (delete nil (mapcar #'car spec)))
1503           (unless (setq entry (assoc group specs))
1504             (push (setq entry (list group)) specs))
1505           (setcdr entry (cons article (cdr entry))))))
1506     (dolist (entry specs)
1507       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1508     specs))
1509
1510 (defun nnimap-transform-split-mail ()
1511   (goto-char (point-min))
1512   (let (article bytes)
1513     (block nil
1514       (while (not (eobp))
1515         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1516           (delete-region (point) (progn (forward-line 1) (point)))
1517           (when (eobp)
1518             (return)))
1519         (setq article (match-string 1)
1520               bytes (nnimap-get-length))
1521         (delete-region (line-beginning-position) (line-end-position))
1522         ;; Insert MMDF separator, and a way to remember what this
1523         ;; article UID is.
1524         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1525         (forward-char (1+ bytes))
1526         (setq bytes (nnimap-get-length))
1527         (delete-region (line-beginning-position) (line-end-position))
1528         (forward-char (1+ bytes))
1529         (delete-region (line-beginning-position) (line-end-position))))))
1530
1531 (defun nnimap-dummy-active-number (group &optional server)
1532   1)
1533
1534 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1535   (let (article)
1536     (goto-char (point-min))
1537     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1538         (error "Invalid nnimap mail")
1539       (setq article (string-to-number (match-string 1))))
1540     (push (list article
1541                 (if (eq group-art 'junk)
1542                     (list (cons 'junk 1))
1543                   group-art))
1544           nnimap-incoming-split-list)))
1545
1546 (provide 'nnimap)
1547
1548 ;;; nnimap.el ends here