cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader)
  35   ;; In Emacs 24, `open-protocol-stream' is an autoloaded alias for
  36   ;; `make-network-stream'.
  37   (unless (fboundp 'open-protocol-stream)
  38     (require 'proto-stream)))
  39
  40 (eval-when-compile
  41   (require 'cl))
  42
  43 (require 'nnheader)
  44 (require 'gnus-util)
  45 (require 'gnus)
  46 (require 'nnoo)
  47 (require 'netrc)
  48 (require 'utf7)
  49 (require 'tls)
  50 (require 'parse-time)
  51 (require 'nnmail)
  52
  53 (autoload 'auth-source-forget+ "auth-source")
  54 (autoload 'auth-source-search "auth-source")
  55
  56 (nnoo-declare nnimap)
  57
  58 (defvoo nnimap-address nil
  59   "The address of the IMAP server.")
  60
  61 (defvoo nnimap-user nil
  62   "Username to use for authentication to the IMAP server.")
  63
  64 (defvoo nnimap-server-port nil
  65   "The IMAP port used.
  66 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  67 it will default to `imap'.")
  68
  69 (defvoo nnimap-stream 'undecided
  70   "How nnimap talks to the IMAP server.
  71 The value should be either `undecided', `ssl' or `tls',
  72 `network', `starttls', `plain', or `shell'.
  73
  74 If the value is `undecided', nnimap tries `ssl' first, then falls
  75 back on `network'.")
  76
  77 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  78                                  (if (listp imap-shell-program)
  79                                      (car imap-shell-program)
  80                                    imap-shell-program)
  81                                "ssh %s imapd"))
  82
  83 (defvoo nnimap-inbox nil
  84   "The mail box where incoming mail arrives and should be split out of.
  85 This can be a string or a list of strings
  86 For example, \"INBOX\" or (\"INBOX\" \"SENT\").")
  87
  88 (defvoo nnimap-split-methods nil
  89   "How mail is split.
  90 Uses the same syntax as `nnmail-split-methods'.")
  91
  92 (defvoo nnimap-split-fancy nil
  93   "Uses the same syntax as `nnmail-split-fancy'.")
  94
  95 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  96   "Articles with the flags in the list will not be considered when splitting.")
  97
  98 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  99                         "Emacs 24.1")
 100
 101 (defvoo nnimap-authenticator nil
 102   "How nnimap authenticate itself to the server.
 103 Possible choices are nil (use default methods) or `anonymous'.")
 104
 105 (defvoo nnimap-expunge t
 106   "If non-nil, expunge articles after deleting them.
 107 This is always done if the server supports UID EXPUNGE, but it's
 108 not done by default on servers that doesn't support that command.")
 109
 110 (defvoo nnimap-streaming t
 111   "If non-nil, try to use streaming commands with IMAP servers.
 112 Switching this off will make nnimap slower, but it helps with
 113 some servers.")
 114
 115 (defvoo nnimap-connection-alist nil)
 116
 117 (defvoo nnimap-current-infos nil)
 118
 119 (defvoo nnimap-fetch-partial-articles nil
 120   "If non-nil, Gnus will fetch partial articles.
 121 If t, Gnus will fetch only the first part.  If a string, it
 122 will fetch all parts that have types that match that string.  A
 123 likely value would be \"text/\" to automatically fetch all
 124 textual parts.")
 125
 126 (defgroup nnimap nil
 127   "IMAP for Gnus."
 128   :group 'gnus)
 129
 130 (defcustom nnimap-request-move-articles-find-limit nil
 131   "Limit the number of articles to look for after moving an article."
 132   :type 'integer
 133   :version "24.2"
 134   :group 'nnimap)
 135
 136 (defvar nnimap-process nil)
 137
 138 (defvar nnimap-status-string "")
 139
 140 (defvar nnimap-split-download-body-default nil
 141   "Internal variable with default value for `nnimap-split-download-body'.")
 142
 143 (defvar nnimap-keepalive-timer nil)
 144 (defvar nnimap-process-buffers nil)
 145
 146 (defstruct nnimap
 147   group process commands capabilities select-result newlinep server
 148   last-command-time greeting examined stream-type initial-resync)
 149
 150 (defvar nnimap-object nil)
 151
 152 (defvar nnimap-mark-alist
 153   '((read "\\Seen" %Seen)
 154     (tick "\\Flagged" %Flagged)
 155     (reply "\\Answered" %Answered)
 156     (expire "gnus-expire")
 157     (dormant "gnus-dormant")
 158     (score "gnus-score")
 159     (save "gnus-save")
 160     (download "gnus-download")
 161     (forward "gnus-forward")))
 162
 163 (defvar nnimap-quirks
 164   '(("QRESYNC" "Zimbra" "QRESYNC ")))
 165
 166 (defvar nnimap-inhibit-logging nil)
 167
 168 (defun nnimap-buffer ()
 169   (nnimap-find-process-buffer nntp-server-buffer))
 170
 171 (defun nnimap-header-parameters ()
 172   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 173           (format
 174            (if (nnimap-ver4-p)
 175                "BODY.PEEK[HEADER.FIELDS %s]"
 176              "RFC822.HEADER.LINES %s")
 177            (append '(Subject From Date Message-Id
 178                              References In-Reply-To Xref)
 179                    nnmail-extra-headers))))
 180
 181 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 182   (when group
 183     (setq group (nnimap-decode-gnus-group group)))
 184   (with-current-buffer nntp-server-buffer
 185     (erase-buffer)
 186     (when (nnimap-change-group group server)
 187       (with-current-buffer (nnimap-buffer)
 188         (erase-buffer)
 189         (nnimap-wait-for-response
 190          (nnimap-send-command
 191           "UID FETCH %s %s"
 192           (nnimap-article-ranges (gnus-compress-sequence articles))
 193           (nnimap-header-parameters))
 194          t)
 195         (nnimap-transform-headers)
 196         (nnheader-remove-cr-followed-by-lf))
 197       (insert-buffer-substring
 198        (nnimap-find-process-buffer (current-buffer))))
 199     'headers))
 200
 201 (defun nnimap-transform-headers ()
 202   (goto-char (point-min))
 203   (let (article lines size string)
 204     (block nil
 205       (while (not (eobp))
 206         (while (not (looking-at "\\* [0-9]+ FETCH"))
 207           (delete-region (point) (progn (forward-line 1) (point)))
 208           (when (eobp)
 209             (return)))
 210         (goto-char (match-end 0))
 211         ;; Unfold quoted {number} strings.
 212         (while (re-search-forward
 213                 "[^]][ (]{\\([0-9]+\\)}\r?\n"
 214                 (save-excursion
 215                   ;; Start of the header section.
 216                   (or (re-search-forward "] {[0-9]+}\r?\n" nil t)
 217                       ;; Start of the next FETCH.
 218                       (re-search-forward "\\* [0-9]+ FETCH" nil t)
 219                       (point-max)))
 220                 t)
 221           (setq size (string-to-number (match-string 1)))
 222           (delete-region (+ (match-beginning 0) 2) (point))
 223           (setq string (buffer-substring (point) (+ (point) size)))
 224           (delete-region (point) (+ (point) size))
 225           (insert (format "%S" (mm-subst-char-in-string ?\n ?\s string))))
 226         (beginning-of-line)
 227         (setq article
 228               (and (re-search-forward "UID \\([0-9]+\\)" (line-end-position)
 229                                       t)
 230                    (match-string 1)))
 231         (setq lines nil)
 232         (setq size
 233               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 234                                       (line-end-position)
 235                                       t)
 236                    (match-string 1)))
 237         (beginning-of-line)
 238         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 239           (let ((structure (ignore-errors
 240                              (read (current-buffer)))))
 241             (while (and (consp structure)
 242                         (not (atom (car structure))))
 243               (setq structure (car structure)))
 244             (setq lines (if (and
 245                              (stringp (car structure))
 246                              (equal (upcase (nth 0 structure)) "MESSAGE")
 247                              (equal (upcase (nth 1 structure)) "RFC822"))
 248                             (nth 9 structure)
 249                           (nth 7 structure)))))
 250         (delete-region (line-beginning-position) (line-end-position))
 251         (insert (format "211 %s Article retrieved." article))
 252         (forward-line 1)
 253         (when size
 254           (insert (format "Chars: %s\n" size)))
 255         (when lines
 256           (insert (format "Lines: %s\n" lines)))
 257         (unless (re-search-forward "^\r$" nil t)
 258           (goto-char (point-max)))
 259         (delete-region (line-beginning-position) (line-end-position))
 260         (insert ".")
 261         (forward-line 1)))))
 262
 263 (defun nnimap-unfold-quoted-lines ()
 264   ;; Unfold quoted {number} strings.
 265   (let (size string)
 266     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 267       (setq size (string-to-number (match-string 1)))
 268       (delete-region (1+ (match-beginning 0)) (point))
 269       (setq string (buffer-substring (point) (+ (point) size)))
 270       (delete-region (point) (+ (point) size))
 271       (insert (format "%S" string)))))
 272
 273 (defun nnimap-get-length ()
 274   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 275        (string-to-number (match-string 1))))
 276
 277 (defun nnimap-article-ranges (ranges)
 278   (let (result)
 279     (cond
 280      ((numberp ranges)
 281       (number-to-string ranges))
 282      ((numberp (cdr ranges))
 283       (format "%d:%d" (car ranges) (cdr ranges)))
 284      (t
 285       (dolist (elem ranges)
 286         (push
 287          (if (consp elem)
 288              (format "%d:%d" (car elem) (cdr elem))
 289            (number-to-string elem))
 290          result))
 291       (mapconcat #'identity (nreverse result) ",")))))
 292
 293 (deffoo nnimap-open-server (server &optional defs no-reconnect)
 294   (if (nnimap-server-opened server)
 295       t
 296     (unless (assq 'nnimap-address defs)
 297       (setq defs (append defs (list (list 'nnimap-address server)))))
 298     (nnoo-change-server 'nnimap server defs)
 299     (if no-reconnect
 300         (nnimap-find-connection nntp-server-buffer)
 301       (or (nnimap-find-connection nntp-server-buffer)
 302           (nnimap-open-connection nntp-server-buffer)))))
 303
 304 (defun nnimap-make-process-buffer (buffer)
 305   (with-current-buffer
 306       (generate-new-buffer (format " *nnimap %s %s %s*"
 307                                    nnimap-address nnimap-server-port
 308                                    (gnus-buffer-exists-p buffer)))
 309     (mm-disable-multibyte)
 310     (buffer-disable-undo)
 311     (gnus-add-buffer)
 312     (set (make-local-variable 'after-change-functions) nil)
 313     (set (make-local-variable 'nnimap-object)
 314          (make-nnimap :server (nnoo-current-server 'nnimap)
 315                       :initial-resync 0))
 316     (push (list buffer (current-buffer)) nnimap-connection-alist)
 317     (push (current-buffer) nnimap-process-buffers)
 318     (current-buffer)))
 319
 320 (defun nnimap-credentials (address ports user)
 321   (let* ((auth-source-creation-prompts
 322           '((user  . "IMAP user at %h: ")
 323             (secret . "IMAP password for %u@%h: ")))
 324          (found (nth 0 (auth-source-search :max 1
 325                                            :host address
 326                                            :port ports
 327                                            :user user
 328                                            :require '(:user :secret)
 329                                            :create t))))
 330     (if found
 331         (list (plist-get found :user)
 332               (let ((secret (plist-get found :secret)))
 333                 (if (functionp secret)
 334                     (funcall secret)
 335                   secret))
 336               (plist-get found :save-function))
 337       nil)))
 338
 339 (defun nnimap-keepalive ()
 340   (let ((now (current-time)))
 341     (dolist (buffer nnimap-process-buffers)
 342       (when (buffer-name buffer)
 343         (with-current-buffer buffer
 344           (when (and nnimap-object
 345                      (nnimap-last-command-time nnimap-object)
 346                      (> (gnus-float-time
 347                          (time-subtract
 348                           now
 349                           (nnimap-last-command-time nnimap-object)))
 350                         ;; More than five minutes since the last command.
 351                         (* 5 60)))
 352             (nnimap-send-command "NOOP")))))))
 353
 354 (defun nnimap-open-connection (buffer)
 355   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
 356   ;; `ssl' when nnimap-server-port was nil.  Sort of.
 357   (when (and nnimap-server-port
 358              (eq nnimap-stream 'undecided))
 359     (setq nnimap-stream 'ssl))
 360   (let ((stream
 361          (if (eq nnimap-stream 'undecided)
 362              (loop for type in '(ssl network)
 363                    for stream = (let ((nnimap-stream type))
 364                                   (nnimap-open-connection-1 buffer))
 365                    while (eq stream 'no-connect)
 366                    finally (return stream))
 367            (nnimap-open-connection-1 buffer))))
 368     (if (eq stream 'no-connect)
 369         nil
 370       stream)))
 371
 372 (defun nnimap-map-port (port)
 373   (if (equal port "imaps")
 374       "993"
 375     port))
 376
 377 (defun nnimap-open-connection-1 (buffer)
 378   (unless nnimap-keepalive-timer
 379     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 380                                               'nnimap-keepalive)))
 381   (with-current-buffer (nnimap-make-process-buffer buffer)
 382     (let* ((coding-system-for-read 'binary)
 383            (coding-system-for-write 'binary)
 384            (ports
 385             (cond
 386              ((memq nnimap-stream '(network plain starttls))
 387               (nnheader-message 7 "Opening connection to %s..."
 388                                 nnimap-address)
 389               '("imap" "143"))
 390              ((eq nnimap-stream 'shell)
 391               (nnheader-message 7 "Opening connection to %s via shell..."
 392                                 nnimap-address)
 393               '("imap"))
 394              ((memq nnimap-stream '(ssl tls))
 395               (nnheader-message 7 "Opening connection to %s via tls..."
 396                                 nnimap-address)
 397               '("imaps" "imap" "993" "143"))
 398              (t
 399               (error "Unknown stream type: %s" nnimap-stream))))
 400            login-result credentials)
 401       (when nnimap-server-port
 402         (push nnimap-server-port ports))
 403       (let* ((stream-list
 404               (open-protocol-stream
 405                "*nnimap*" (current-buffer) nnimap-address
 406                (nnimap-map-port (car ports))
 407                :type nnimap-stream
 408                :return-list t
 409                :shell-command nnimap-shell-program
 410                :capability-command "1 CAPABILITY\r\n"
 411                :end-of-command "\r\n"
 412                :success " OK "
 413                :starttls-function
 414                (lambda (capabilities)
 415                  (when (gnus-string-match-p "STARTTLS" capabilities)
 416                    "1 STARTTLS\r\n"))))
 417              (stream (car stream-list))
 418              (props (cdr stream-list))
 419              (greeting (plist-get props :greeting))
 420              (capabilities (plist-get props :capabilities))
 421              (stream-type (plist-get props :type)))
 422         (when (and stream (not (memq (process-status stream) '(open run))))
 423           (setq stream nil))
 424
 425         (when (and (fboundp 'set-network-process-option) ;; Not in XEmacs.
 426                    (fboundp 'process-type) ;; Emacs 22 doesn't provide it.
 427                    (eq (process-type stream) 'network))
 428           ;; Use TCP-keepalive so that connections that pass through a NAT
 429           ;; router don't hang when left idle.
 430           (set-network-process-option stream :keepalive t))
 431
 432         (setf (nnimap-process nnimap-object) stream)
 433         (setf (nnimap-stream-type nnimap-object) stream-type)
 434         (if (not stream)
 435             (progn
 436               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 437                                nnimap-address (car ports) nnimap-stream)
 438               'no-connect)
 439           (gnus-set-process-query-on-exit-flag stream nil)
 440           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
 441               (nnheader-report 'nnimap "%s" greeting)
 442             ;; Store the greeting (for debugging purposes).
 443             (setf (nnimap-greeting nnimap-object) greeting)
 444             (setf (nnimap-capabilities nnimap-object)
 445                   (mapcar #'upcase
 446                           (split-string capabilities)))
 447             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
 448               (if (not (setq credentials
 449                              (if (eq nnimap-authenticator 'anonymous)
 450                                  (list "anonymous"
 451                                        (message-make-address))
 452                                ;; Look for the credentials based on
 453                                ;; the virtual server name and the address
 454                                (nnimap-credentials
 455                                 (gnus-delete-duplicates
 456                                  (list
 457                                   nnimap-address
 458                                   (nnoo-current-server 'nnimap)))
 459                                 ports
 460                                 nnimap-user))))
 461                   (setq nnimap-object nil)
 462                 (let ((nnimap-inhibit-logging t))
 463                   (setq login-result
 464                         (nnimap-login (car credentials) (cadr credentials))))
 465                 (if (car login-result)
 466                     (progn
 467                       ;; Save the credentials if a save function exists
 468                       ;; (such a function will only be passed if a new
 469                       ;; token was created).
 470                       (when (functionp (nth 2 credentials))
 471                         (funcall (nth 2 credentials)))
 472                       ;; See if CAPABILITY is set as part of login
 473                       ;; response.
 474                       (dolist (response (cddr login-result))
 475                         (when (string= "CAPABILITY" (upcase (car response)))
 476                           (setf (nnimap-capabilities nnimap-object)
 477                                 (mapcar #'upcase (cdr response))))))
 478                   ;; If the login failed, then forget the credentials
 479                   ;; that are now possibly cached.
 480                   (dolist (host (list (nnoo-current-server 'nnimap)
 481                                       nnimap-address))
 482                     (dolist (port ports)
 483                       (auth-source-forget+ :host host :port port)))
 484                   (delete-process (nnimap-process nnimap-object))
 485                   (setq nnimap-object nil))))
 486             (when nnimap-object
 487               (when (nnimap-capability "QRESYNC")
 488                 (nnimap-command "ENABLE QRESYNC"))
 489               (nnheader-message 7 "Opening connection to %s...done"
 490                                 nnimap-address)
 491               (nnimap-process nnimap-object))))))))
 492
 493 (autoload 'rfc2104-hash "rfc2104")
 494
 495 (defun nnimap-login (user password)
 496   (cond
 497    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
 498    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
 499    ;; and we're using an encrypted connection.
 500    ((and (not (nnimap-capability "LOGINDISABLED"))
 501          (eq (nnimap-stream-type nnimap-object) 'tls))
 502     (nnimap-command "LOGIN %S %S" user password))
 503    ((nnimap-capability "AUTH=CRAM-MD5")
 504     (erase-buffer)
 505     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
 506           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
 507       (process-send-string
 508        (get-buffer-process (current-buffer))
 509        (concat
 510         (base64-encode-string
 511          (concat user " "
 512                  (rfc2104-hash 'md5 64 16 password
 513                                (base64-decode-string challenge))))
 514         "\r\n"))
 515       (nnimap-wait-for-response sequence)))
 516    ((not (nnimap-capability "LOGINDISABLED"))
 517     (nnimap-command "LOGIN %S %S" user password))
 518    ((nnimap-capability "AUTH=PLAIN")
 519     (nnimap-command
 520      "AUTHENTICATE PLAIN %s"
 521      (base64-encode-string
 522       (format "\000%s\000%s"
 523               (nnimap-quote-specials user)
 524               (nnimap-quote-specials password)))))))
 525
 526 (defun nnimap-quote-specials (string)
 527   (with-temp-buffer
 528     (insert string)
 529     (goto-char (point-min))
 530     (while (re-search-forward "[\\\"]" nil t)
 531       (forward-char -1)
 532       (insert "\\")
 533       (forward-char 1))
 534     (buffer-string)))
 535
 536 (defun nnimap-find-parameter (parameter elems)
 537   (let (result)
 538     (dolist (elem elems)
 539       (cond
 540        ((equal (car elem) parameter)
 541         (setq result (cdr elem)))
 542        ((and (equal (car elem) "OK")
 543              (consp (cadr elem))
 544              (equal (caadr elem) parameter))
 545         (setq result (cdr (cadr elem))))))
 546     result))
 547
 548 (deffoo nnimap-close-server (&optional server)
 549   (when (nnoo-change-server 'nnimap server nil)
 550     (ignore-errors
 551       (delete-process (get-buffer-process (nnimap-buffer))))
 552     (nnoo-close-server 'nnimap server)
 553     t))
 554
 555 (deffoo nnimap-request-close ()
 556   t)
 557
 558 (deffoo nnimap-server-opened (&optional server)
 559   (and (nnoo-current-server-p 'nnimap server)
 560        nntp-server-buffer
 561        (gnus-buffer-live-p nntp-server-buffer)
 562        (nnimap-find-connection nntp-server-buffer)))
 563
 564 (deffoo nnimap-status-message (&optional server)
 565   nnimap-status-string)
 566
 567 (deffoo nnimap-request-article (article &optional group server to-buffer)
 568   (when group
 569     (setq group (nnimap-decode-gnus-group group)))
 570   (with-current-buffer nntp-server-buffer
 571     (let ((result (nnimap-change-group group server))
 572           parts structure)
 573       (when (stringp article)
 574         (setq article (nnimap-find-article-by-message-id group server article)))
 575       (when (and result
 576                  article)
 577         (erase-buffer)
 578         (with-current-buffer (nnimap-buffer)
 579           (erase-buffer)
 580           (when nnimap-fetch-partial-articles
 581             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 582             (goto-char (point-min))
 583             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 584               (setq structure (ignore-errors
 585                                 (let ((start (point)))
 586                                   (forward-sexp 1)
 587                                   (downcase-region start (point))
 588                                   (goto-char start)
 589                                   (read (current-buffer))))
 590                     parts (nnimap-find-wanted-parts structure))))
 591           (when (if parts
 592                     (nnimap-get-partial-article article parts structure)
 593                   (nnimap-get-whole-article article))
 594             (let ((buffer (current-buffer)))
 595               (with-current-buffer (or to-buffer nntp-server-buffer)
 596                 (nnheader-insert-buffer-substring buffer)
 597                 (nnheader-ms-strip-cr)))
 598             (cons group article)))))))
 599
 600 (deffoo nnimap-request-head (article &optional group server to-buffer)
 601   (when group
 602     (setq group (nnimap-decode-gnus-group group)))
 603   (when (nnimap-change-group group server)
 604     (with-current-buffer (nnimap-buffer)
 605       (when (stringp article)
 606         (setq article (nnimap-find-article-by-message-id group server article)))
 607       (if (null article)
 608           nil
 609         (nnimap-get-whole-article
 610          article (format "UID FETCH %%d %s"
 611                          (nnimap-header-parameters)))
 612         (let ((buffer (current-buffer)))
 613           (with-current-buffer (or to-buffer nntp-server-buffer)
 614             (erase-buffer)
 615             (insert-buffer-substring buffer)
 616             (nnheader-ms-strip-cr)
 617             (cons group article)))))))
 618
 619 (defun nnimap-get-whole-article (article &optional command)
 620   (let ((result
 621          (nnimap-command
 622           (or command
 623               (if (nnimap-ver4-p)
 624                   "UID FETCH %d BODY.PEEK[]"
 625                 "UID FETCH %d RFC822.PEEK"))
 626           article)))
 627     ;; Check that we really got an article.
 628     (goto-char (point-min))
 629     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 630       (setq result nil))
 631     (when result
 632       ;; Remove any data that may have arrived before the FETCH data.
 633       (beginning-of-line)
 634       (unless (bobp)
 635         (delete-region (point-min) (point)))
 636       (let ((bytes (nnimap-get-length)))
 637         (delete-region (line-beginning-position)
 638                        (progn (forward-line 1) (point)))
 639         (goto-char (+ (point) bytes))
 640         (delete-region (point) (point-max)))
 641       t)))
 642
 643 (defun nnimap-capability (capability)
 644   (member capability (nnimap-capabilities nnimap-object)))
 645
 646 (defun nnimap-ver4-p ()
 647   (nnimap-capability "IMAP4REV1"))
 648
 649 (defun nnimap-get-partial-article (article parts structure)
 650   (let ((result
 651          (nnimap-command
 652           "UID FETCH %d (%s %s)"
 653           article
 654           (if (nnimap-ver4-p)
 655               "BODY.PEEK[HEADER]"
 656             "RFC822.HEADER")
 657           (if (nnimap-ver4-p)
 658               (mapconcat (lambda (part)
 659                            (format "BODY.PEEK[%s]" part))
 660                          parts " ")
 661             (mapconcat (lambda (part)
 662                          (format "RFC822.PEEK[%s]" part))
 663                        parts " ")))))
 664     (when result
 665       (nnimap-convert-partial-article structure))))
 666
 667 (defun nnimap-convert-partial-article (structure)
 668   ;; First just skip past the headers.
 669   (goto-char (point-min))
 670   (let ((bytes (nnimap-get-length))
 671         id parts)
 672     ;; Delete "FETCH" line.
 673     (delete-region (line-beginning-position)
 674                    (progn (forward-line 1) (point)))
 675     (goto-char (+ (point) bytes))
 676     ;; Collect all the body parts.
 677     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 678       (setq id (match-string 1)
 679             bytes (or (nnimap-get-length) 0))
 680       (beginning-of-line)
 681       (delete-region (point) (progn (forward-line 1) (point)))
 682       (push (list id (buffer-substring (point) (+ (point) bytes)))
 683             parts)
 684       (delete-region (point) (+ (point) bytes)))
 685     ;; Delete trailing junk.
 686     (delete-region (point) (point-max))
 687     ;; Now insert all the parts again where they fit in the structure.
 688     (nnimap-insert-partial-structure structure parts)
 689     t))
 690
 691 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 692   (let (type boundary)
 693     (let ((bstruc structure))
 694       (while (consp (car bstruc))
 695         (pop bstruc))
 696       (setq type (car bstruc))
 697       (setq bstruc (car (cdr bstruc)))
 698       (let ((has-boundary (member "boundary" bstruc)))
 699         (when has-boundary
 700           (setq boundary (cadr has-boundary)))))
 701     (when subp
 702       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 703                       (downcase type) boundary)))
 704     (while (not (stringp (car structure)))
 705       (insert "\n--" boundary "\n")
 706       (if (consp (caar structure))
 707           (nnimap-insert-partial-structure (pop structure) parts t)
 708         (let ((bit (pop structure)))
 709           (insert (format "Content-type: %s/%s"
 710                           (downcase (nth 0 bit))
 711                           (downcase (nth 1 bit))))
 712           (if (member-ignore-case "CHARSET" (nth 2 bit))
 713               (insert (format
 714                        "; charset=%S\n"
 715                        (cadr (member-ignore-case "CHARSET" (nth 2 bit)))))
 716             (insert "\n"))
 717           (insert (format "Content-transfer-encoding: %s\n"
 718                           (nth 5 bit)))
 719           (insert "\n")
 720           (when (assoc (nth 9 bit) parts)
 721             (insert (cadr (assoc (nth 9 bit) parts)))))))
 722     (insert "\n--" boundary "--\n")))
 723
 724 (defun nnimap-find-wanted-parts (structure)
 725   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 726
 727 (defun nnimap-find-wanted-parts-1 (structure prefix)
 728   (let ((num 1)
 729         parts)
 730     (while (consp (car structure))
 731       (let ((sub (pop structure)))
 732         (if (consp (car sub))
 733             (push (nnimap-find-wanted-parts-1
 734                    sub (if (string= prefix "")
 735                            (number-to-string num)
 736                          (format "%s.%s" prefix num)))
 737                   parts)
 738           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 739                 (id (if (string= prefix "")
 740                         (number-to-string num)
 741                       (format "%s.%s" prefix num))))
 742             (setcar (nthcdr 9 sub) id)
 743             (when (if (eq nnimap-fetch-partial-articles t)
 744                       (equal id "1")
 745                     (string-match nnimap-fetch-partial-articles type))
 746               (push id parts))))
 747         (incf num)))
 748     (nreverse parts)))
 749
 750 (defun nnimap-decode-gnus-group (group)
 751   (decode-coding-string group 'utf-8))
 752
 753 (deffoo nnimap-request-group (group &optional server dont-check info)
 754   (setq group (nnimap-decode-gnus-group group))
 755   (let ((result (nnimap-change-group
 756                  ;; Don't SELECT the group if we're going to select it
 757                  ;; later, anyway.
 758                  (if (and (not dont-check)
 759                           (assoc group nnimap-current-infos))
 760                      nil
 761                    group)
 762                  server))
 763         articles active marks high low)
 764     (with-current-buffer nntp-server-buffer
 765       (when result
 766         (if (and dont-check
 767                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 768             (insert (format "211 %d %d %d %S\n"
 769                             (- (cdr active) (car active))
 770                             (car active)
 771                             (cdr active)
 772                             group))
 773           (with-current-buffer (nnimap-buffer)
 774             (erase-buffer)
 775             (let ((group-sequence
 776                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 777                   (flag-sequence
 778                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 779               (setf (nnimap-group nnimap-object) group)
 780               (nnimap-wait-for-response flag-sequence)
 781               (setq marks
 782                     (nnimap-flags-to-marks
 783                      (nnimap-parse-flags
 784                       (list (list group-sequence flag-sequence
 785                                   1 group "SELECT")))))
 786               (when (and info
 787                          marks)
 788                 (nnimap-update-infos marks (list info))
 789                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 790               (goto-char (point-max))
 791               (let ((uidnext (nth 5 (car marks))))
 792                 (setq high (or (if uidnext
 793                                    (1- uidnext)
 794                                  (nth 3 (car marks)))
 795                                0)
 796                       low (or (nth 4 (car marks)) uidnext 1)))))
 797           (erase-buffer)
 798           (insert
 799            (format
 800             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 801         t))))
 802
 803 (deffoo nnimap-request-create-group (group &optional server args)
 804   (setq group (nnimap-decode-gnus-group group))
 805   (when (nnimap-change-group nil server)
 806     (with-current-buffer (nnimap-buffer)
 807       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 808
 809 (deffoo nnimap-request-delete-group (group &optional force server)
 810   (setq group (nnimap-decode-gnus-group group))
 811   (when (nnimap-change-group nil server)
 812     (with-current-buffer (nnimap-buffer)
 813       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 814
 815 (deffoo nnimap-request-rename-group (group new-name &optional server)
 816   (setq group (nnimap-decode-gnus-group group))
 817   (when (nnimap-change-group nil server)
 818     (with-current-buffer (nnimap-buffer)
 819       (nnimap-unselect-group)
 820       (car (nnimap-command "RENAME %S %S"
 821                            (utf7-encode group t) (utf7-encode new-name t))))))
 822
 823 (defun nnimap-unselect-group ()
 824   ;; Make sure we don't have this group open read/write by asking
 825   ;; to examine a mailbox that doesn't exist.  This seems to be
 826   ;; the only way that allows us to reliably go back to unselected
 827   ;; state on Courier.
 828   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 829
 830 (deffoo nnimap-request-expunge-group (group &optional server)
 831   (setq group (nnimap-decode-gnus-group group))
 832   (when (nnimap-change-group group server)
 833     (with-current-buffer (nnimap-buffer)
 834       (car (nnimap-command "EXPUNGE")))))
 835
 836 (defun nnimap-get-flags (spec)
 837   (let ((articles nil)
 838         elems end)
 839     (with-current-buffer (nnimap-buffer)
 840       (erase-buffer)
 841       (nnimap-wait-for-response (nnimap-send-command
 842                                  "UID FETCH %s FLAGS" spec))
 843       (setq end (point))
 844       (subst-char-in-region (point-min) (point-max)
 845                             ?\\ ?% t)
 846       (goto-char (point-min))
 847       (while (search-forward " FETCH " end t)
 848         (setq elems (read (current-buffer)))
 849         (push (cons (cadr (memq 'UID elems))
 850                     (cadr (memq 'FLAGS elems)))
 851               articles)))
 852     (nreverse articles)))
 853
 854 (deffoo nnimap-close-group (group &optional server)
 855   t)
 856
 857 (deffoo nnimap-request-move-article (article group server accept-form
 858                                              &optional last internal-move-group)
 859   (setq group (nnimap-decode-gnus-group group))
 860   (with-temp-buffer
 861     (mm-disable-multibyte)
 862     (when (funcall (if internal-move-group
 863                        'nnimap-request-head
 864                      'nnimap-request-article)
 865                    article group server (current-buffer))
 866       ;; If the move is internal (on the same server), just do it the easy
 867       ;; way.
 868       (let ((message-id (message-field-value "message-id")))
 869         (if internal-move-group
 870             (let ((result
 871                    (with-current-buffer (nnimap-buffer)
 872                      (nnimap-command "UID COPY %d %S"
 873                                      article
 874                                      (utf7-encode internal-move-group t)))))
 875               (when (car result)
 876                 (nnimap-delete-article article)
 877                 (cons internal-move-group
 878                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 879                           (nnimap-find-article-by-message-id
 880                            internal-move-group server message-id
 881                            nnimap-request-move-articles-find-limit)))))
 882           ;; Move the article to a different method.
 883           (let ((result (eval accept-form)))
 884             (when result
 885               (nnimap-change-group group server)
 886               (nnimap-delete-article article)
 887               result)))))))
 888
 889 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 890   (setq group (nnimap-decode-gnus-group group))
 891   (cond
 892    ((null articles)
 893     nil)
 894    ((not (nnimap-change-group group server))
 895     articles)
 896    ((and force
 897          (eq nnmail-expiry-target 'delete))
 898     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 899       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 900     nil)
 901    (t
 902     (let ((deletable-articles
 903            (if (or force
 904                    (eq nnmail-expiry-wait 'immediate))
 905                articles
 906              (gnus-sorted-intersection
 907               articles
 908               (nnimap-find-expired-articles group)))))
 909       (if (null deletable-articles)
 910           articles
 911         (if (eq nnmail-expiry-target 'delete)
 912             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 913           (setq deletable-articles
 914                 (nnimap-process-expiry-targets
 915                  deletable-articles group server)))
 916         ;; Return the articles we didn't delete.
 917         (gnus-sorted-complement articles deletable-articles))))))
 918
 919 (defun nnimap-process-expiry-targets (articles group server)
 920   (let ((deleted-articles nil))
 921     (cond
 922      ;; shortcut further processing if we're going to delete the articles
 923      ((eq nnmail-expiry-target 'delete)
 924       (setq deleted-articles articles)
 925       t)
 926      ;; or just move them to another folder on the same IMAP server
 927      ((and (not (functionp nnmail-expiry-target))
 928            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
 929                               (gnus-server-to-method
 930                                (format "nnimap:%s" server))))
 931       (and (nnimap-change-group group server)
 932            (with-current-buffer (nnimap-buffer)
 933              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
 934              (nnimap-command
 935               "UID COPY %s %S"
 936               (nnimap-article-ranges (gnus-compress-sequence articles))
 937               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
 938              (setq deleted-articles articles)))
 939       t)
 940      (t
 941       (dolist (article articles)
 942         (let ((target nnmail-expiry-target))
 943           (with-temp-buffer
 944             (mm-disable-multibyte)
 945             (when (nnimap-request-article article group server (current-buffer))
 946               (when (functionp target)
 947                 (setq target (funcall target group)))
 948               (if (and target
 949                        (not (eq target 'delete)))
 950                   (if (or (gnus-request-group target t)
 951                           (gnus-request-create-group target))
 952                       (progn
 953                         (nnmail-expiry-target-group target group)
 954                         (nnheader-message 7 "Expiring article %s:%d to %s"
 955                                           group article target))
 956                     (setq target nil))
 957                 (nnheader-message 7 "Expiring article %s:%d" group article))
 958               (when target
 959                 (push article deleted-articles))))))))
 960     ;; Change back to the current group again.
 961     (nnimap-change-group group server)
 962     (setq deleted-articles (nreverse deleted-articles))
 963     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 964     deleted-articles))
 965
 966 (defun nnimap-find-expired-articles (group)
 967   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 968     (with-current-buffer (nnimap-buffer)
 969       (let ((result
 970              (nnimap-command
 971               "UID SEARCH SENTBEFORE %s"
 972               (format-time-string
 973                (format "%%d-%s-%%Y"
 974                        (upcase
 975                         (car (rassoc (nth 4 (decode-time cutoff))
 976                                      parse-time-months))))
 977                cutoff))))
 978         (and (car result)
 979              (delete 0 (mapcar #'string-to-number
 980                                (cdr (assoc "SEARCH" (cdr result))))))))))
 981
 982
 983 (defun nnimap-find-article-by-message-id (group server message-id &optional limit)
 984   "Search for message with MESSAGE-ID in GROUP from SERVER.
 985 If LIMIT, first try to limit the search to the N last articles."
 986   (with-current-buffer (nnimap-buffer)
 987     (erase-buffer)
 988     (let* ((number-of-article
 989            (catch 'found
 990              (dolist (result (cdr (nnimap-change-group group server nil t)))
 991                (when (equal "EXISTS" (cadr result))
 992                  (throw 'found (car result))))))
 993            (sequence
 994             (nnimap-send-command "UID SEARCH%s HEADER Message-Id %S"
 995                                  (if (and limit number-of-article)
 996                                      ;; The -1 is because IMAP message
 997                                      ;; numbers are one-based rather than
 998                                      ;; zero-based.
 999                                      (format " %s:*" (- (string-to-number number-of-article) limit -1))
1000                                    "")
1001                                  message-id)))
1002       (when (nnimap-wait-for-response sequence)
1003         (let ((article (car (last (cdr (assoc "SEARCH" (nnimap-parse-response)))))))
1004           (if article
1005               (string-to-number article)
1006             (when (and limit number-of-article)
1007               (nnimap-find-article-by-message-id group server message-id))))))))
1008
1009 (defun nnimap-delete-article (articles)
1010   (with-current-buffer (nnimap-buffer)
1011     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
1012                     (nnimap-article-ranges articles))
1013     (cond
1014      ((nnimap-capability "UIDPLUS")
1015       (nnimap-command "UID EXPUNGE %s"
1016                       (nnimap-article-ranges articles))
1017       t)
1018      (nnimap-expunge
1019       (nnimap-command "EXPUNGE")
1020       t)
1021      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
1022                                 "server doesn't support UIDPLUS, so we won't "
1023                                 "delete this article now"))))))
1024
1025 (deffoo nnimap-request-scan (&optional group server)
1026   (when group
1027     (setq group (nnimap-decode-gnus-group group)))
1028   (when (and (nnimap-change-group nil server)
1029              nnimap-inbox
1030              nnimap-split-methods)
1031     (nnheader-message 7 "nnimap %s splitting mail..." server)
1032     (if (listp nnimap-inbox)
1033        (dolist (nnimap-inbox nnimap-inbox)
1034          (nnimap-split-incoming-mail))
1035       (nnimap-split-incoming-mail))
1036     (nnheader-message 7 "nnimap %s splitting mail...done" server)))
1037
1038 (defun nnimap-marks-to-flags (marks)
1039   (let (flags flag)
1040     (dolist (mark marks)
1041       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
1042         (push flag flags)))
1043     flags))
1044
1045 (deffoo nnimap-request-update-group-status (group status &optional server)
1046   (setq group (nnimap-decode-gnus-group group))
1047   (when (nnimap-change-group nil server)
1048     (let ((command (assoc
1049                     status
1050                     '((subscribe "SUBSCRIBE")
1051                       (unsubscribe "UNSUBSCRIBE")))))
1052       (when command
1053         (with-current-buffer (nnimap-buffer)
1054           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
1055
1056 (deffoo nnimap-request-set-mark (group actions &optional server)
1057   (setq group (nnimap-decode-gnus-group group))
1058   (when (nnimap-change-group group server)
1059     (let (sequence)
1060       (with-current-buffer (nnimap-buffer)
1061         (erase-buffer)
1062         ;; Just send all the STORE commands without waiting for
1063         ;; response.  If they're successful, they're successful.
1064         (dolist (action actions)
1065           (destructuring-bind (range action marks) action
1066             (let ((flags (nnimap-marks-to-flags marks)))
1067               (when flags
1068                 (setq sequence (nnimap-send-command
1069                                 "UID STORE %s %sFLAGS.SILENT (%s)"
1070                                 (nnimap-article-ranges range)
1071                                 (cond
1072                                  ((eq action 'del) "-")
1073                                  ((eq action 'add) "+")
1074                                  ((eq action 'set) ""))
1075                                 (mapconcat #'identity flags " ")))))))
1076         ;; Wait for the last command to complete to avoid later
1077         ;; synchronization problems with the stream.
1078         (when sequence
1079           (nnimap-wait-for-response sequence))))))
1080
1081 (deffoo nnimap-request-accept-article (group &optional server last)
1082   (setq group (nnimap-decode-gnus-group group))
1083   (when (nnimap-change-group nil server)
1084     (nnmail-check-syntax)
1085     (let ((message-id (message-field-value "message-id"))
1086           sequence message)
1087       (nnimap-add-cr)
1088       (setq message (buffer-substring-no-properties (point-min) (point-max)))
1089       (with-current-buffer (nnimap-buffer)
1090         (when (setq message (or (nnimap-process-quirk "OK Gimap " 'append message)
1091                                 message))
1092           ;; If we have this group open read-only, then unselect it
1093           ;; before appending to it.
1094           (when (equal (nnimap-examined nnimap-object) group)
1095             (nnimap-unselect-group))
1096           (erase-buffer)
1097           (setq sequence (nnimap-send-command
1098                           "APPEND %S {%d}" (utf7-encode group t)
1099                           (length message)))
1100           (unless nnimap-streaming
1101             (nnimap-wait-for-connection "^[+]"))
1102           (process-send-string (get-buffer-process (current-buffer)) message)
1103           (process-send-string (get-buffer-process (current-buffer))
1104                                (if (nnimap-newlinep nnimap-object)
1105                                    "\n"
1106                                  "\r\n"))
1107           (let ((result (nnimap-get-response sequence)))
1108             (if (not (nnimap-ok-p result))
1109                 (progn
1110                   (nnheader-report 'nnimap "%s" result)
1111                   nil)
1112               (cons group
1113                     (or (nnimap-find-uid-response "APPENDUID" (car result))
1114                         (nnimap-find-article-by-message-id
1115                          group server message-id))))))))))
1116
1117 (defun nnimap-process-quirk (greeting-match type data)
1118   (when (and (nnimap-greeting nnimap-object)
1119              (string-match greeting-match (nnimap-greeting nnimap-object))
1120              (eq type 'append)
1121              (string-match "\000" data))
1122     (let ((choice (gnus-multiple-choice
1123                    "Message contains NUL characters.  Delete, continue, abort? "
1124                    '((?d "Delete NUL characters")
1125                      (?c "Try to APPEND the message as is")
1126                      (?a "Abort")))))
1127       (cond
1128        ((eq choice ?a)
1129         (nnheader-report 'nnimap "Aborted APPEND due to NUL characters"))
1130        ((eq choice ?c)
1131         data)
1132        (t
1133         (with-temp-buffer
1134           (insert data)
1135           (goto-char (point-min))
1136           (while (search-forward "\000" nil t)
1137             (replace-match "" t t))
1138           (buffer-string)))))))
1139
1140 (defun nnimap-ok-p (value)
1141   (and (consp value)
1142        (consp (car value))
1143        (equal (caar value) "OK")))
1144
1145 (defun nnimap-find-uid-response (name list)
1146   (let ((result (car (last (nnimap-find-response-element name list)))))
1147     (and result
1148          (string-to-number result))))
1149
1150 (defun nnimap-find-response-element (name list)
1151   (let (result)
1152     (dolist (elem list)
1153       (when (and (consp elem)
1154                  (equal name (car elem)))
1155         (setq result elem)))
1156     result))
1157
1158 (deffoo nnimap-request-replace-article (article group buffer)
1159   (setq group (nnimap-decode-gnus-group group))
1160   (let (group-art)
1161     (when (and (nnimap-change-group group)
1162                ;; Put the article into the group.
1163                (with-current-buffer buffer
1164                  (setq group-art
1165                        (nnimap-request-accept-article group nil t))))
1166       (nnimap-delete-article (list article))
1167       ;; Return the new article number.
1168       (cdr group-art))))
1169
1170 (defun nnimap-add-cr ()
1171   (goto-char (point-min))
1172   (while (re-search-forward "\r?\n" nil t)
1173     (replace-match "\r\n" t t)))
1174
1175 (defun nnimap-get-groups ()
1176   (erase-buffer)
1177   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1178         groups)
1179     (nnimap-wait-for-response sequence)
1180     (subst-char-in-region (point-min) (point-max)
1181                           ?\\ ?% t)
1182     (goto-char (point-min))
1183     (nnimap-unfold-quoted-lines)
1184     (goto-char (point-min))
1185     (while (search-forward "* LIST " nil t)
1186       (let ((flags (read (current-buffer)))
1187             (separator (read (current-buffer)))
1188             (group (read (current-buffer))))
1189         (unless (member '%NoSelect flags)
1190           (push (utf7-decode (if (stringp group)
1191                                  group
1192                                (format "%s" group)) t)
1193                 groups))))
1194     (nreverse groups)))
1195
1196 (deffoo nnimap-request-list (&optional server)
1197   (when (nnimap-change-group nil server)
1198     (with-current-buffer nntp-server-buffer
1199       (erase-buffer)
1200       (dolist (response
1201                (with-current-buffer (nnimap-buffer)
1202                  ;; Build a list of (group result-of-EXAMINE) for each group
1203                  (mapcar
1204                   (lambda (group)
1205                     (list group (cdr (nnimap-change-group group server nil t))))
1206                   (nnimap-get-groups))))
1207         (let ((group (encode-coding-string (car response) 'utf-8))
1208               (response (cadr response)))
1209           (when (equal (caar response) "OK")
1210             (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1211                 highest exists)
1212               (dolist (elem response)
1213                 (when (equal (cadr elem) "EXISTS")
1214                   (setq exists (string-to-number (car elem)))))
1215               (when uidnext
1216                 (setq highest (1- (string-to-number (car uidnext)))))
1217               (cond
1218                ((null highest)
1219                 (insert (format "%S 0 1 y\n" group)))
1220                ((zerop exists)
1221                 ;; Empty group.
1222                 (insert (format "%S %d %d y\n" group
1223                                 highest (1+ highest))))
1224                (t
1225                 ;; Return the widest possible range.
1226                 (insert (format "%S %d 1 y\n" group
1227                                 (or highest exists)))))))))
1228       t)))
1229
1230 (deffoo nnimap-request-newgroups (date &optional server)
1231   (when (nnimap-change-group nil server)
1232     (with-current-buffer nntp-server-buffer
1233       (erase-buffer)
1234       (dolist (group (with-current-buffer (nnimap-buffer)
1235                        (nnimap-get-groups)))
1236         (unless (assoc group nnimap-current-infos)
1237           ;; Insert dummy numbers here -- they don't matter.
1238           (insert (format "%S 0 1 y\n" (encode-coding-string group 'utf-8)))))
1239       t)))
1240
1241 (deffoo nnimap-retrieve-group-data-early (server infos)
1242   (when (and (nnimap-change-group nil server)
1243              infos)
1244     (with-current-buffer (nnimap-buffer)
1245       (erase-buffer)
1246       (setf (nnimap-group nnimap-object) nil)
1247       (setf (nnimap-initial-resync nnimap-object) 0)
1248       (let ((qresyncp (nnimap-capability "QRESYNC"))
1249             params groups sequences active uidvalidity modseq group
1250             unexist)
1251         ;; Go through the infos and gather the data needed to know
1252         ;; what and how to request the data.
1253         (dolist (info infos)
1254           (setq params (gnus-info-params info)
1255                 group (nnimap-decode-gnus-group
1256                        (gnus-group-real-name (gnus-info-group info)))
1257                 active (cdr (assq 'active params))
1258                 unexist (assq 'unexist (gnus-info-marks info))
1259                 uidvalidity (cdr (assq 'uidvalidity params))
1260                 modseq (cdr (assq 'modseq params)))
1261           (setf (nnimap-examined nnimap-object) group)
1262           (if (and qresyncp
1263                    uidvalidity
1264                    active
1265                    modseq
1266                    unexist)
1267               (push
1268                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1269                                           (utf7-encode group t)
1270                                           (nnimap-quirk "QRESYNC")
1271                                           uidvalidity modseq)
1272                      'qresync
1273                      nil group 'qresync)
1274                sequences)
1275             (let ((command
1276                    (if uidvalidity
1277                        "EXAMINE"
1278                      ;; If we don't have a UIDVALIDITY, then this is
1279                      ;; the first time we've seen the group, so we
1280                      ;; have to do a SELECT (which is slower than an
1281                      ;; examine), but will tell us whether the group
1282                      ;; is read-only or not.
1283                      "SELECT"))
1284                   start)
1285               (if (and active uidvalidity unexist)
1286                   ;; Fetch the last 100 flags.
1287                   (setq start (max 1 (- (cdr active) 100)))
1288                 (incf (nnimap-initial-resync nnimap-object))
1289                 (setq start 1))
1290               (push (list (nnimap-send-command "%s %S" command
1291                                                (utf7-encode group t))
1292                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1293                           start group command)
1294                     sequences))))
1295         sequences))))
1296
1297 (defun nnimap-quirk (command)
1298   (let ((quirk (assoc command nnimap-quirks)))
1299     ;; If this server is of a type that matches a quirk, then return
1300     ;; the "quirked" command instead of the proper one.
1301     (if (or (null quirk)
1302             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1303         command
1304       (nth 2 quirk))))
1305
1306 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1307   (when (and sequences
1308              (nnimap-change-group nil server t)
1309              ;; Check that the process is still alive.
1310              (get-buffer-process (nnimap-buffer))
1311              (memq (process-status (get-buffer-process (nnimap-buffer)))
1312                    '(open run)))
1313     (with-current-buffer (nnimap-buffer)
1314       ;; Wait for the final data to trickle in.
1315       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1316                                           (caar sequences)
1317                                         (cadar sequences))
1318                                       t)
1319         ;; Now we should have most of the data we need, no matter
1320         ;; whether we're QRESYNCING, fetching all the flags from
1321         ;; scratch, or just fetching the last 100 flags per group.
1322         (nnimap-update-infos (nnimap-flags-to-marks
1323                               (nnimap-parse-flags
1324                                (nreverse sequences)))
1325                              infos)
1326         ;; Finally, just return something resembling an active file in
1327         ;; the nntp buffer, so that the agent can save the info, too.
1328         (with-current-buffer nntp-server-buffer
1329           (erase-buffer)
1330           (dolist (info infos)
1331             (let* ((group (gnus-info-group info))
1332                    (active (gnus-active group)))
1333               (when active
1334                 (insert (format "%S %d %d y\n"
1335                                 (decode-coding-string
1336                                  (gnus-group-real-name group) 'utf-8)
1337                                 (cdr active)
1338                                 (car active)))))))))))
1339
1340 (defun nnimap-update-infos (flags infos)
1341   (dolist (info infos)
1342     (let* ((group (nnimap-decode-gnus-group
1343                    (gnus-group-real-name (gnus-info-group info))))
1344            (marks (cdr (assoc group flags))))
1345       (when marks
1346         (nnimap-update-info info marks)))))
1347
1348 (defun nnimap-update-info (info marks)
1349   (destructuring-bind (existing flags high low uidnext start-article
1350                                 permanent-flags uidvalidity
1351                                 vanished highestmodseq) marks
1352     (cond
1353      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1354      ;; completely empty groups.
1355      ((and (not existing)
1356            (not uidnext))
1357       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1358         (when active
1359           (gnus-set-active (gnus-info-group info) active))))
1360      ;; We have a mismatch between the old and new UIDVALIDITY
1361      ;; identifiers, so we have to re-request the group info (the next
1362      ;; time).  This virtually never happens.
1363      ((let ((old-uidvalidity
1364              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1365         (and old-uidvalidity
1366              (not (equal old-uidvalidity uidvalidity))
1367              (or (not start-article)
1368                  (> start-article 1))))
1369       (gnus-group-remove-parameter info 'uidvalidity)
1370       (gnus-group-remove-parameter info 'modseq))
1371      ;; We have the data needed to update.
1372      (t
1373       (let* ((group (gnus-info-group info))
1374              (completep (and start-article
1375                              (= start-article 1)))
1376              (active (or (gnus-active group)
1377                          (cdr (assq 'active (gnus-info-params info))))))
1378         (when uidnext
1379           (setq high (1- uidnext)))
1380         ;; First set the active ranges based on high/low.
1381         (if (or completep
1382                 (not (gnus-active group)))
1383             (gnus-set-active group
1384                              (cond
1385                               (active
1386                                (cons (min (or low (car active))
1387                                           (car active))
1388                                      (max (or high (cdr active))
1389                                           (cdr active))))
1390                               ((and low high)
1391                                (cons low high))
1392                               (uidnext
1393                                ;; No articles in this group.
1394                                (cons uidnext (1- uidnext)))
1395                               (start-article
1396                                (cons start-article (1- start-article)))
1397                               (t
1398                                ;; No articles and no uidnext.
1399                                nil)))
1400           (gnus-set-active group
1401                            (cons (car active)
1402                                  (or high (1- uidnext)))))
1403         ;; See whether this is a read-only group.
1404         (unless (eq permanent-flags 'not-scanned)
1405           (gnus-group-set-parameter
1406            info 'permanent-flags
1407            (and (or (memq '%* permanent-flags)
1408                     (memq '%Seen permanent-flags))
1409                 permanent-flags)))
1410         ;; Update marks and read articles if this isn't a
1411         ;; read-only IMAP group.
1412         (when (setq permanent-flags
1413                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1414           (if (and highestmodseq
1415                    (not start-article))
1416               ;; We've gotten the data by QRESYNCing.
1417               (nnimap-update-qresync-info
1418                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1419             ;; Do normal non-QRESYNC flag updates.
1420             ;; Update the list of read articles.
1421             (let* ((unread
1422                     (gnus-compress-sequence
1423                      (gnus-set-difference
1424                       (gnus-set-difference
1425                        existing
1426                        (cdr (assoc '%Seen flags)))
1427                       (cdr (assoc '%Flagged flags)))))
1428                    (read (gnus-range-difference
1429                           (cons start-article high) unread)))
1430               (when (> start-article 1)
1431                 (setq read
1432                       (gnus-range-nconcat
1433                        (if (> start-article 1)
1434                            (gnus-sorted-range-intersection
1435                             (cons 1 (1- start-article))
1436                             (gnus-info-read info))
1437                          (gnus-info-read info))
1438                        read)))
1439               (when (or (not (listp permanent-flags))
1440                         (memq '%Seen permanent-flags))
1441                 (gnus-info-set-read info read))
1442               ;; Update the marks.
1443               (setq marks (gnus-info-marks info))
1444               (dolist (type (cdr nnimap-mark-alist))
1445                 (when (or (not (listp permanent-flags))
1446                           (memq (car (assoc (caddr type) flags))
1447                                 permanent-flags)
1448                           (memq '%* permanent-flags))
1449                   (let ((old-marks (assoc (car type) marks))
1450                         (new-marks
1451                          (gnus-compress-sequence
1452                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1453                                    (assoc (intern (cadr type) obarray) flags)
1454                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1455                     (setq marks (delq old-marks marks))
1456                     (pop old-marks)
1457                     (when (and old-marks
1458                                (> start-article 1))
1459                       (setq old-marks (gnus-range-difference
1460                                        old-marks
1461                                        (cons start-article high)))
1462                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1463                     (when new-marks
1464                       (push (cons (car type) new-marks) marks)))))
1465               ;; Keep track of non-existing articles.
1466               (let* ((old-unexists (assq 'unexist marks))
1467                      (active (gnus-active group))
1468                      (unexists
1469                       (if completep
1470                           (gnus-range-difference
1471                            active
1472                            (gnus-compress-sequence existing))
1473                         (gnus-add-to-range
1474                          (cdr old-unexists)
1475                          (gnus-list-range-difference
1476                           existing (gnus-active group))))))
1477                 (when (> (car active) 1)
1478                   (setq unexists (gnus-range-add
1479                                   (cons 1 (1- (car active)))
1480                                   unexists)))
1481                 (if old-unexists
1482                     (setcdr old-unexists unexists)
1483                   (push (cons 'unexist unexists) marks)))
1484               (gnus-info-set-marks info marks t))))
1485         ;; Tell Gnus whether there are any \Recent messages in any of
1486         ;; the groups.
1487         (let ((recent (cdr (assoc '%Recent flags))))
1488           (when (and active
1489                      recent
1490                      (> (car (last recent)) (cdr active)))
1491             (push (list (cons (gnus-group-real-name group) 0))
1492                   nnmail-split-history)))
1493         ;; Note the active level for the next run-through.
1494         (gnus-group-set-parameter info 'active (gnus-active group))
1495         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1496         (gnus-group-set-parameter info 'modseq highestmodseq)
1497         (nnimap-store-info info (gnus-active group)))))))
1498
1499 (defun nnimap-update-qresync-info (info existing vanished flags)
1500   ;; Add all the vanished articles to the list of read articles.
1501   (gnus-info-set-read
1502    info
1503    (gnus-add-to-range
1504     (gnus-add-to-range
1505      (gnus-range-add (gnus-info-read info)
1506                      vanished)
1507      (cdr (assq '%Flagged flags)))
1508     (cdr (assq '%Seen flags))))
1509   (let ((marks (gnus-info-marks info)))
1510     (dolist (type (cdr nnimap-mark-alist))
1511       (let ((ticks (assoc (car type) marks))
1512             (new-marks
1513              (cdr (or (assoc (caddr type) flags) ; %Flagged
1514                       (assoc (intern (cadr type) obarray) flags)
1515                       (assoc (cadr type) flags))))) ; "\Flagged"
1516         (setq marks (delq ticks marks))
1517         (pop ticks)
1518         ;; Add the new marks we got.
1519         (setq ticks (gnus-add-to-range ticks new-marks))
1520         ;; Remove the marks from messages that don't have them.
1521         (setq ticks (gnus-remove-from-range
1522                      ticks
1523                      (gnus-compress-sequence
1524                       (gnus-sorted-complement existing new-marks))))
1525         (when ticks
1526           (push (cons (car type) ticks) marks)))
1527       (gnus-info-set-marks info marks t))
1528     ;; Add vanished to the list of unexisting articles.
1529     (when vanished
1530       (let* ((old-unexists (assq 'unexist marks))
1531              (unexists (gnus-range-add (cdr old-unexists) vanished)))
1532         (if old-unexists
1533             (setcdr old-unexists unexists)
1534           (push (cons 'unexist unexists) marks)))
1535       (gnus-info-set-marks info marks t))))
1536
1537 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1538   (if (zerop (length irange))
1539       nil
1540     (let ((result nil))
1541       (dolist (elem (split-string irange ","))
1542         (push
1543          (if (string-match ":" elem)
1544              (let ((numbers (split-string elem ":")))
1545                (cons (string-to-number (car numbers))
1546                      (string-to-number (cadr numbers))))
1547            (string-to-number elem))
1548          result))
1549       (nreverse result))))
1550
1551 (defun nnimap-store-info (info active)
1552   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1553          (entry (assoc group nnimap-current-infos)))
1554     (if entry
1555         (setcdr entry (list info active))
1556       (push (list group info active) nnimap-current-infos))))
1557
1558 (defun nnimap-flags-to-marks (groups)
1559   (let (data group totalp uidnext articles start-article mark permanent-flags
1560              uidvalidity vanished highestmodseq)
1561     (dolist (elem groups)
1562       (setq group (car elem)
1563             uidnext (nth 1 elem)
1564             start-article (nth 2 elem)
1565             permanent-flags (nth 3 elem)
1566             uidvalidity (nth 4 elem)
1567             vanished (nth 5 elem)
1568             highestmodseq (nth 6 elem)
1569             articles (nthcdr 7 elem))
1570       (let ((high (caar articles))
1571             marks low existing)
1572         (dolist (article articles)
1573           (setq low (car article))
1574           (push (car article) existing)
1575           (dolist (flag (cdr article))
1576             (setq mark (assoc flag marks))
1577             (if (not mark)
1578                 (push (list flag (car article)) marks)
1579               (setcdr mark (cons (car article) (cdr mark))))))
1580         (push (list group existing marks high low uidnext start-article
1581                     permanent-flags uidvalidity vanished highestmodseq)
1582               data)))
1583     data))
1584
1585 (defun nnimap-parse-flags (sequences)
1586   (goto-char (point-min))
1587   ;; Change \Delete etc to %Delete, so that the Emacs Lisp reader can
1588   ;; read it.
1589   (subst-char-in-region (point-min) (point-max)
1590                         ?\\ ?% t)
1591   ;; Remove any MODSEQ entries in the buffer, because they may contain
1592   ;; numbers that are too large for 32-bit Emacsen.
1593   (while (re-search-forward " MODSEQ ([0-9]+)" nil t)
1594     (replace-match "" t t))
1595   (goto-char (point-min))
1596   (let (start end articles groups uidnext elems permanent-flags
1597               uidvalidity vanished highestmodseq)
1598     (dolist (elem sequences)
1599       (destructuring-bind (group-sequence flag-sequence totalp group command)
1600           elem
1601         (setq start (point))
1602         (when (and
1603                ;; The EXAMINE was successful.
1604                (search-forward (format "\n%d OK " group-sequence) nil t)
1605                (progn
1606                  (forward-line 1)
1607                  (setq end (point))
1608                  (goto-char start)
1609                  (setq permanent-flags
1610                        (if (equal command "SELECT")
1611                            (and (search-forward "PERMANENTFLAGS "
1612                                                 (or end (point-min)) t)
1613                                 (read (current-buffer)))
1614                          'not-scanned))
1615                  (goto-char start)
1616                  (setq uidnext
1617                        (and (search-forward "UIDNEXT "
1618                                             (or end (point-min)) t)
1619                             (read (current-buffer))))
1620                  (goto-char start)
1621                  (setq uidvalidity
1622                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1623                                                (or end (point-min)) t)
1624                             ;; Store UIDVALIDITY as a string, as it's
1625                             ;; too big for 32-bit Emacsen, usually.
1626                             (match-string 1)))
1627                  (goto-char start)
1628                  (setq vanished
1629                        (and (eq flag-sequence 'qresync)
1630                             (re-search-forward "^\\* VANISHED .*? \\([0-9:,]+\\)"
1631                                                (or end (point-min)) t)
1632                             (match-string 1)))
1633                  (goto-char start)
1634                  (setq highestmodseq
1635                        (and (re-search-forward "HIGHESTMODSEQ \\([0-9]+\\)"
1636                                             (or end (point-min)) t)
1637                             (match-string 1)))
1638                  (goto-char end)
1639                  (forward-line -1))
1640                ;; The UID FETCH FLAGS was successful.
1641                (or (eq flag-sequence 'qresync)
1642                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1643           (if (eq flag-sequence 'qresync)
1644               (progn
1645                 (goto-char start)
1646                 (setq start end))
1647             (setq start (point))
1648             (goto-char end))
1649           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1650             (let ((p (point)))
1651               (setq elems (read (current-buffer)))
1652               (push (cons (cadr (memq 'UID elems))
1653                           (cadr (memq 'FLAGS elems)))
1654                     articles)))
1655           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1656                              vanished highestmodseq)
1657                        articles)
1658                 groups)
1659           (if (eq flag-sequence 'qresync)
1660               (goto-char end)
1661             (setq end (point)))
1662           (setq articles nil))))
1663     groups))
1664
1665 (defun nnimap-find-process-buffer (buffer)
1666   (cadr (assoc buffer nnimap-connection-alist)))
1667
1668 (deffoo nnimap-request-post (&optional server)
1669   (setq nnimap-status-string "Read-only server")
1670   nil)
1671
1672 (defvar gnus-refer-thread-use-nnir) ;; gnus-sum.el
1673 (declare-function gnus-fetch-headers "gnus-sum"
1674                   (articles &optional limit force-new dependencies))
1675
1676 (autoload 'nnir-search-thread "nnir")
1677
1678 (deffoo nnimap-request-thread (header &optional group server)
1679   (when group
1680     (setq group (nnimap-decode-gnus-group group)))
1681   (if gnus-refer-thread-use-nnir
1682       (nnir-search-thread header)
1683     (when (nnimap-change-group group server)
1684       (let* ((cmd (nnimap-make-thread-query header))
1685              (result (with-current-buffer (nnimap-buffer)
1686                        (nnimap-command  "UID SEARCH %s" cmd))))
1687         (when result
1688           (gnus-fetch-headers
1689            (and (car result)
1690                 (delete 0 (mapcar #'string-to-number
1691                                   (cdr (assoc "SEARCH" (cdr result))))))
1692            nil t))))))
1693
1694 (defun nnimap-change-group (group &optional server no-reconnect read-only)
1695   "Change group to GROUP.
1696 If SERVER is set, check that server is connected, otherwise retry
1697 to reconnect, unless NO-RECONNECT is set to t.
1698 if READ-ONLY is set, send EXAMINE rather than SELECT to the server."
1699   (let ((open-result t))
1700     (when (and server
1701                (not (nnimap-server-opened server)))
1702       (setq open-result (nnimap-open-server server nil no-reconnect)))
1703     (cond
1704      ((not open-result)
1705       nil)
1706      ((not group)
1707       t)
1708      (t
1709       (with-current-buffer (nnimap-buffer)
1710         (let ((result (nnimap-command "%s %S"
1711                                       (if read-only
1712                                           "EXAMINE"
1713                                         "SELECT")
1714                                       (utf7-encode group t))))
1715           (when (car result)
1716             (setf (nnimap-group nnimap-object) group
1717                   (nnimap-select-result nnimap-object) result)
1718             result)))))))
1719
1720 (defun nnimap-find-connection (buffer)
1721   "Find the connection delivering to BUFFER."
1722   (let ((entry (assoc buffer nnimap-connection-alist)))
1723     (when entry
1724       (if (and (buffer-name (cadr entry))
1725                (get-buffer-process (cadr entry))
1726                (memq (process-status (get-buffer-process (cadr entry)))
1727                      '(open run)))
1728           (get-buffer-process (cadr entry))
1729         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1730         nil))))
1731
1732 (defvar nnimap-sequence 0)
1733
1734 (defun nnimap-send-command (&rest args)
1735   (setf (nnimap-last-command-time nnimap-object) (current-time))
1736   (process-send-string
1737    (get-buffer-process (current-buffer))
1738    (nnimap-log-command
1739     (format "%d %s%s\n"
1740             (incf nnimap-sequence)
1741             (apply #'format args)
1742             (if (nnimap-newlinep nnimap-object)
1743                 ""
1744               "\r"))))
1745   ;; Some servers apparently can't have many outstanding
1746   ;; commands, so throttle them.
1747   (unless nnimap-streaming
1748     (nnimap-wait-for-response nnimap-sequence))
1749   nnimap-sequence)
1750
1751 (defvar nnimap-record-commands nil
1752   "If non-nil, log commands to the \"*imap log*\" buffer.")
1753
1754 (defun nnimap-log-command (command)
1755   (when nnimap-record-commands
1756     (with-current-buffer (get-buffer-create "*imap log*")
1757       (goto-char (point-max))
1758       (insert (format-time-string "%H:%M:%S")
1759               " [" nnimap-address "] "
1760               (if nnimap-inhibit-logging
1761                   "(inhibited)\n"
1762                 command))))
1763   command)
1764
1765 (defun nnimap-command (&rest args)
1766   (erase-buffer)
1767   (let* ((sequence (apply #'nnimap-send-command args))
1768          (response (nnimap-get-response sequence)))
1769     (if (equal (caar response) "OK")
1770         (cons t response)
1771       (nnheader-report 'nnimap "%s"
1772                        (mapconcat (lambda (a)
1773                                     (format "%s" a))
1774                                   (car response) " "))
1775       nil)))
1776
1777 (defun nnimap-get-response (sequence)
1778   (nnimap-wait-for-response sequence)
1779   (nnimap-parse-response))
1780
1781 (defun nnimap-wait-for-connection (&optional regexp)
1782   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1783
1784 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1785   (let ((process (get-buffer-process (current-buffer))))
1786     (goto-char (point-min))
1787     (while (and (memq (process-status process)
1788                       '(open run))
1789                 (not (re-search-forward regexp nil t)))
1790       (nnheader-accept-process-output process)
1791       (goto-char (point-min)))
1792     (forward-line -1)
1793     (and (looking-at (or response-regexp regexp))
1794          (match-string 1))))
1795
1796 (defun nnimap-wait-for-response (sequence &optional messagep)
1797   (let ((process (get-buffer-process (current-buffer)))
1798         openp)
1799     (condition-case nil
1800         (progn
1801           (goto-char (point-max))
1802           (while (and (setq openp (memq (process-status process)
1803                                         '(open run)))
1804                       (progn
1805                         ;; Skip past any "*" lines that the server has
1806                         ;; output.
1807                         (while (and (not (bobp))
1808                                     (progn
1809                                       (forward-line -1)
1810                                       (looking-at "\\*"))))
1811                         (not (looking-at (format "%d .*\n" sequence)))))
1812             (when messagep
1813               (nnheader-message-maybe
1814                7 "nnimap read %dk from %s%s" (/ (buffer-size) 1000)
1815                nnimap-address
1816                (if (not (zerop (nnimap-initial-resync nnimap-object)))
1817                    (format " (initial sync of %d group%s; please wait)"
1818                            (nnimap-initial-resync nnimap-object)
1819                            (if (= (nnimap-initial-resync nnimap-object) 1)
1820                                ""
1821                              "s"))
1822                  "")))
1823             (nnheader-accept-process-output process)
1824             (goto-char (point-max)))
1825           (setf (nnimap-initial-resync nnimap-object) 0)
1826           openp)
1827       (quit
1828        (when debug-on-quit
1829          (debug "Quit"))
1830        ;; The user hit C-g while we were waiting: kill the process, in case
1831        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1832        ;; NAT routers).
1833        (delete-process process)
1834        nil))))
1835
1836 (defun nnimap-parse-response ()
1837   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1838         result)
1839     (dolist (line lines)
1840       (push (cdr (nnimap-parse-line line)) result))
1841     ;; Return the OK/error code first, and then all the "continuation
1842     ;; lines" afterwards.
1843     (cons (pop result)
1844           (nreverse result))))
1845
1846 ;; Parse an IMAP response line lightly.  They look like
1847 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1848 ;; the lines into a list of strings and lists of string.
1849 (defun nnimap-parse-line (line)
1850   (let (char result)
1851     (with-temp-buffer
1852       (mm-disable-multibyte)
1853       (insert line)
1854       (goto-char (point-min))
1855       (while (not (eobp))
1856         (if (eql (setq char (following-char)) ? )
1857             (forward-char 1)
1858           (push
1859            (cond
1860             ((eql char ?\[)
1861              (split-string
1862               (buffer-substring
1863                (1+ (point))
1864                (if (search-forward "]" (line-end-position) 'move)
1865                    (1- (point))
1866                  (point)))))
1867             ((eql char ?\()
1868              (split-string
1869               (buffer-substring
1870                (1+ (point))
1871                (if (search-forward ")" (line-end-position) 'move)
1872                    (1- (point))
1873                  (point)))))
1874             ((eql char ?\")
1875              (forward-char 1)
1876              (buffer-substring
1877               (point)
1878               (1- (or (search-forward "\"" (line-end-position) 'move)
1879                       (point)))))
1880             (t
1881              (buffer-substring (point) (if (search-forward " " nil t)
1882                                            (1- (point))
1883                                          (goto-char (point-max))))))
1884            result)))
1885       (nreverse result))))
1886
1887 (defun nnimap-last-response-string ()
1888   (save-excursion
1889     (forward-line 1)
1890     (let ((end (point)))
1891       (forward-line -1)
1892       (when (not (bobp))
1893         (forward-line -1)
1894         (while (and (not (bobp))
1895                     (eql (following-char) ?*))
1896           (forward-line -1))
1897         (unless (eql (following-char) ?*)
1898           (forward-line 1)))
1899       (buffer-substring (point) end))))
1900
1901 (defun nnimap-get-responses (sequences)
1902   (let (responses)
1903     (dolist (sequence sequences)
1904       (goto-char (point-min))
1905       (when (re-search-forward (format "^%d " sequence) nil t)
1906         (push (list sequence (nnimap-parse-response))
1907               responses)))
1908     responses))
1909
1910 (defvar nnimap-incoming-split-list nil)
1911
1912 (defun nnimap-fetch-inbox (articles)
1913   (erase-buffer)
1914   (nnimap-wait-for-response
1915    (nnimap-send-command
1916     "UID FETCH %s %s"
1917     (nnimap-article-ranges articles)
1918     (format "(UID %s%s)"
1919             (format
1920              (if (nnimap-ver4-p)
1921                  "BODY.PEEK"
1922                "RFC822.PEEK"))
1923             (cond
1924              (nnimap-split-download-body-default
1925               "[]")
1926              ((nnimap-ver4-p)
1927               "[HEADER]")
1928              (t
1929               "[1]"))))
1930    t))
1931
1932 (defun nnimap-split-incoming-mail ()
1933   (with-current-buffer (nnimap-buffer)
1934     (let ((nnimap-incoming-split-list nil)
1935           (nnmail-split-methods
1936            (cond
1937             ((eq nnimap-split-methods 'default)
1938              nnmail-split-methods)
1939             (nnimap-split-methods
1940              nnimap-split-methods)
1941             (nnimap-split-fancy
1942              'nnmail-split-fancy)))
1943           (nnmail-split-fancy (or nnimap-split-fancy
1944                                   nnmail-split-fancy))
1945           (nnmail-inhibit-default-split-group t)
1946           (groups (nnimap-get-groups))
1947           new-articles)
1948       (erase-buffer)
1949       (nnimap-command "SELECT %S" nnimap-inbox)
1950       (setf (nnimap-group nnimap-object) nnimap-inbox)
1951       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1952       (when new-articles
1953         (nnimap-fetch-inbox new-articles)
1954         (nnimap-transform-split-mail)
1955         (nnheader-ms-strip-cr)
1956         (nnmail-cache-open)
1957         (nnmail-split-incoming (current-buffer)
1958                                #'nnimap-save-mail-spec
1959                                nil nil
1960                                #'nnimap-dummy-active-number
1961                                #'nnimap-save-mail-spec)
1962         (when nnimap-incoming-split-list
1963           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1964                 sequences junk-articles)
1965             ;; Create any groups that doesn't already exist on the
1966             ;; server first.
1967             (dolist (spec specs)
1968               (when (and (not (member (car spec) groups))
1969                          (not (eq (car spec) 'junk)))
1970                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1971             ;; Then copy over all the messages.
1972             (erase-buffer)
1973             (dolist (spec specs)
1974               (let ((group (car spec))
1975                     (ranges (cdr spec)))
1976                 (if (eq group 'junk)
1977                     (setq junk-articles ranges)
1978                   (push (list (nnimap-send-command
1979                                "UID COPY %s %S"
1980                                (nnimap-article-ranges ranges)
1981                                (utf7-encode group t))
1982                               ranges)
1983                         sequences))))
1984             ;; Wait for the last COPY response...
1985             (when sequences
1986               (nnimap-wait-for-response (caar sequences))
1987               ;; And then mark the successful copy actions as deleted,
1988               ;; and possibly expunge them.
1989               (nnimap-mark-and-expunge-incoming
1990                (nnimap-parse-copied-articles sequences)))
1991             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1992
1993 (defun nnimap-mark-and-expunge-incoming (range)
1994   (when range
1995     (setq range (nnimap-article-ranges range))
1996     (erase-buffer)
1997     (let ((sequence
1998            (nnimap-send-command
1999             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
2000       (cond
2001        ;; If the server supports it, we now delete the message we have
2002        ;; just copied over.
2003        ((nnimap-capability "UIDPLUS")
2004         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
2005        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
2006        ;; user has configured it.
2007        (nnimap-expunge
2008         (setq sequence (nnimap-send-command "EXPUNGE"))))
2009       (nnimap-wait-for-response sequence))))
2010
2011 (defun nnimap-parse-copied-articles (sequences)
2012   (let (sequence copied range)
2013     (goto-char (point-min))
2014     (while (re-search-forward "^\\([0-9]+\\) OK\\b" nil t)
2015       (setq sequence (string-to-number (match-string 1)))
2016       (when (setq range (cadr (assq sequence sequences)))
2017         (push (gnus-uncompress-range range) copied)))
2018     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
2019
2020 (defun nnimap-new-articles (flags)
2021   (let (new)
2022     (dolist (elem flags)
2023       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
2024                                       (cdr elem))
2025         (push (car elem) new)))
2026     (gnus-compress-sequence (nreverse new))))
2027
2028 (defun nnimap-make-split-specs (list)
2029   (let ((specs nil)
2030         entry)
2031     (dolist (elem list)
2032       (destructuring-bind (article spec) elem
2033         (dolist (group (delete nil (mapcar #'car spec)))
2034           (unless (setq entry (assoc group specs))
2035             (push (setq entry (list group)) specs))
2036           (setcdr entry (cons article (cdr entry))))))
2037     (dolist (entry specs)
2038       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
2039     specs))
2040
2041 (defun nnimap-transform-split-mail ()
2042   (goto-char (point-min))
2043   (let (article bytes)
2044     (block nil
2045       (while (not (eobp))
2046         (while (not (looking-at "\\* [0-9]+ FETCH.+UID \\([0-9]+\\)"))
2047           (delete-region (point) (progn (forward-line 1) (point)))
2048           (when (eobp)
2049             (return)))
2050         (setq article (match-string 1)
2051               bytes (nnimap-get-length))
2052         (delete-region (line-beginning-position) (line-end-position))
2053         ;; Insert MMDF separator, and a way to remember what this
2054         ;; article UID is.
2055         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
2056         (forward-char (1+ bytes))
2057         (setq bytes (nnimap-get-length))
2058         (delete-region (line-beginning-position) (line-end-position))
2059         ;; There's a body; skip past that.
2060         (when bytes
2061           (forward-char (1+ bytes))
2062           (delete-region (line-beginning-position) (line-end-position)))))))
2063
2064 (defun nnimap-dummy-active-number (group &optional server)
2065   1)
2066
2067 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
2068   (let (article)
2069     (goto-char (point-min))
2070     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
2071         (error "Invalid nnimap mail")
2072       (setq article (string-to-number (match-string 1))))
2073     (push (list article
2074                 (if (eq group-art 'junk)
2075                     (list (cons 'junk 1))
2076                   group-art))
2077           nnimap-incoming-split-list)))
2078
2079 (defun nnimap-make-thread-query (header)
2080   (let* ((id  (mail-header-id header))
2081          (refs (split-string
2082                 (or (mail-header-references header)
2083                     "")))
2084          (value
2085           (format
2086            "(OR HEADER REFERENCES %S HEADER Message-Id %S)"
2087            id id)))
2088     (dolist (refid refs value)
2089       (setq value (format
2090                    "(OR (OR HEADER Message-Id %S HEADER REFERENCES %S) %s)"
2091                    refid refid value)))))
2092
2093
2094 (provide 'nnimap)
2095
2096 ;;; nnimap.el ends here