cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   7 ;;         Jim Radford <radford@robby.caltech.edu>
   8 ;; Keywords: mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Todo, major things:
  30 ;;
  31 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  32 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  33 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  34 ;;   o Sieve
  35 ;;   o MIME (partial article fetches)
  36 ;;   o Split to other backends, different split rules for different
  37 ;;     servers/inboxes
  38 ;;
  39 ;; Todo, minor things:
  40 ;;
  41 ;;   o Don't require half of Gnus -- backends should be standalone
  42 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  43 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  44 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  45 ;;   o What do I do with gnus-newsgroup-*?
  46 ;;   o Tell Gnus about new groups (how can we tell?)
  47 ;;   o Respooling (fix Gnus?) (unnecessary?)
  48 ;;   o Add support for the following: (if applicable)
  49 ;;       request-list-newsgroups, request-regenerate
  50 ;;       list-active-group,
  51 ;;       request-associate-buffer, request-restore-buffer,
  52 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  53 ;;   o Support RFC2221 (Login referrals)
  54 ;;   o IMAP2BIS compatibility? (RFC2061)
  55 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  56 ;;     .newsrc.eld)
  57 ;;   o What about Gnus's article editing, can we support it?  NO!
  58 ;;   o Use \Draft to support the draft group??
  59 ;;   o Duplicate suppression
  60 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  61
  62 ;;; Code:
  63
  64 (require 'imap)
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyzes the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "22.1"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "22.1"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "22.1"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "22.1"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 ;; Authorization / Privacy variables
 258
 259 (defvoo nnimap-auth-method nil
 260   "Obsolete.")
 261
 262 (defvoo nnimap-stream nil
 263   "How nnimap will connect to the server.
 264
 265 The default, nil, will try to use the \"best\" method the server can
 266 handle.
 267
 268 Change this if
 269
 270 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 271    with IMAP is suboptimal so you'll have to tell it
 272    specifically.
 273
 274 2) your server is more capable than your environment -- i.e. your
 275    server accept Kerberos login's but you haven't installed the
 276    `imtest' program or your machine isn't configured for Kerberos.
 277
 278 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 279 See also `imap-streams' and `imap-stream-alist'.")
 280
 281 (defvoo nnimap-authenticator nil
 282   "How nnimap authenticate itself to the server.
 283
 284 The default, nil, will try to use the \"best\" method the server can
 285 handle.
 286
 287 There is only one reason for fiddling with this variable, and that is
 288 if your server is more capable than your environment -- i.e. you
 289 connect to a server that accept Kerberos login's but you haven't
 290 installed the `imtest' program or your machine isn't configured for
 291 Kerberos.
 292
 293 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 294 See also `imap-authenticators' and `imap-authenticator-alist'")
 295
 296 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 297   "Directory to keep NOV cache files for nnimap groups.
 298 See also `nnimap-nov-file-name'.")
 299
 300 (defvoo nnimap-nov-file-name "nnimap."
 301   "NOV cache base filename.
 302 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 303 typical complete file name would be
 304 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 305 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 306 `nnmail-use-long-file-names' is nil")
 307
 308 (defvoo nnimap-nov-file-name-suffix ".novcache"
 309   "Suffix for NOV cache base filename.")
 310
 311 (defvoo nnimap-nov-is-evil gnus-agent
 312   "If non-nil, never generate or use a local nov database for this backend.
 313 Using nov databases should speed up header fetching considerably.
 314 However, it will invoke a UID SEARCH UID command on the server, and
 315 some servers implement this command inefficiently by opening each and
 316 every message in the group, thus making it quite slow.
 317 Unlike other backends, you do not need to take special care if you
 318 flip this variable.")
 319
 320 (defvoo nnimap-search-uids-not-since-is-evil nil
 321   "If non-nil, avoid \"UID SEARCH UID ... NOT SINCE\" queries when expiring.
 322 Instead, use \"UID SEARCH SINCE\" to prune the list of expirable
 323 articles within Gnus.  This seems to be faster on Courier in some cases.")
 324
 325 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 326   "Whether to expunge a group when it is closed.
 327 When a IMAP group with articles marked for deletion is closed, this
 328 variable determine if nnimap should actually remove the articles or
 329 not.
 330
 331 If always, nnimap always perform a expunge when closing the group.
 332 If never, nnimap never expunges articles marked for deletion.
 333 If ask, nnimap will ask you if you wish to expunge marked articles.
 334
 335 When setting this variable to `never', you can only expunge articles
 336 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 337
 338 (defvoo nnimap-list-pattern "*"
 339   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 340 See below for available wildcards.
 341
 342 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 343 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 344 semantics of this are server specific, on the University of Washington
 345 server you can specify a directory.
 346
 347 Example:
 348  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 349
 350 There are two wildcards * and %. * matches everything, % matches
 351 everything in the current hierarchy.")
 352
 353 (defvoo nnimap-news-groups nil
 354   "IMAP support a news-like mode, also known as bulletin board mode,
 355 where replies is sent via IMAP instead of SMTP.
 356
 357 This variable should contain a regexp matching groups where you wish
 358 replies to be stored to the mailbox directly.
 359
 360 Example:
 361   '(\"^[^I][^N][^B][^O][^X].*$\")
 362
 363 This will match all groups not beginning with \"INBOX\".
 364
 365 Note that there is nothing technically different between mail-like and
 366 news-like mailboxes.  If you wish to have a group with todo items or
 367 similar which you wouldn't want to set up a mailing list for, you can
 368 use this to make replies go directly to the group.")
 369
 370 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 371   "IMAP search command to use for articles that are to be expired.
 372 The first %s is replaced by a UID set of articles to search on,
 373 and the second %s is replaced by a date criterium.
 374
 375 One useful (and perhaps the only useful) value to change this to would
 376 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 377 instead of the internal date of messages.  See section 6.4.4 of RFC
 378 2060 for more information on valid strings.
 379
 380 However, if `nnimap-search-uids-not-since-is-evil' is true, this
 381 variable has no effect since the search logic is reversed.")
 382
 383 (defvoo nnimap-importantize-dormant t
 384   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 385 Note that within Gnus, dormant articles will still (only) be
 386 marked as ticked.  This is to make \"dormant\" articles stand out,
 387 just like \"ticked\" articles, in other IMAP clients.")
 388
 389 (defvoo nnimap-server-address nil
 390   "Obsolete.  Use `nnimap-address'.")
 391
 392 (defcustom nnimap-authinfo-file "~/.authinfo"
 393   "Authorization information for IMAP servers.  In .netrc format."
 394   :type
 395   '(choice file
 396            (repeat :tag "Entries"
 397                    :menu-tag "Inline"
 398                    (list :format "%v"
 399                          :value ("" ("login" . "") ("password" . ""))
 400                          (string :tag "Host")
 401                          (checklist :inline t
 402                                     (cons :format "%v"
 403                                           (const :format "" "login")
 404                                           (string :format "Login: %v"))
 405                                     (cons :format "%v"
 406                                           (const :format "" "password")
 407                                           (string :format "Password: %v"))))))
 408   :group 'nnimap)
 409
 410 (defcustom nnimap-prune-cache t
 411   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 412   :type 'boolean
 413   :group 'nnimap)
 414
 415 (defvar nnimap-request-list-method 'imap-mailbox-list
 416   "Method to use to request a list of all folders from the server.
 417 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 418 restrict visible folders.")
 419
 420 (defcustom nnimap-id nil
 421   "Plist with client identity to send to server upon login.
 422 Nil means no information is sent, symbol `no' to disable ID query
 423 alltogheter, or plist with identifier-value pairs to send to
 424 server.  RFC 2971 describes the list as follows:
 425
 426    Any string may be sent as a field, but the following are defined to
 427    describe certain values that might be sent.  Implementations are free
 428    to send none, any, or all of these.  Strings are not case-sensitive.
 429    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 430    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 431    than 30 field-value pairs.
 432
 433      name            Name of the program
 434      version         Version number of the program
 435      os              Name of the operating system
 436      os-version      Version of the operating system
 437      vendor          Vendor of the client/server
 438      support-url     URL to contact for support
 439      address         Postal address of contact/vendor
 440      date            Date program was released, specified as a date-time
 441                        in IMAP4rev1
 442      command         Command used to start the program
 443      arguments       Arguments supplied on the command line, if any
 444                        if any
 445      environment     Description of environment, i.e., UNIX environment
 446                        variables or Windows registry settings
 447
 448    Implementations MUST NOT send the same field name more than once.
 449
 450 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 451 \"os\" system-configuration \"vendor\" \"GNU\")."
 452   :group 'nnimap
 453   :type '(choice (const :tag "No information" nil)
 454                  (const :tag "Disable ID query" no)
 455                  (plist :key-type string :value-type string)))
 456
 457 (defcustom nnimap-debug nil
 458   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 459 Note that username, passwords and other privacy sensitive
 460 information (such as e-mail) may be stored in the *nnimap-debug*
 461 buffer.  It is not written to disk, however.  Do not enable this
 462 variable unless you are comfortable with that."
 463   :group 'nnimap
 464   :type 'boolean)
 465
 466 ;; Internal variables:
 467
 468 (defvar nnimap-debug-buffer "*nnimap-debug*")
 469 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 470 (defvar nnimap-current-move-server nil)
 471 (defvar nnimap-current-move-group nil)
 472 (defvar nnimap-current-move-article nil)
 473 (defvar nnimap-length)
 474 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 475 (defvar nnimap-progress-how-often 20)
 476 (defvar nnimap-counter)
 477 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 478 (defvar nnimap-current-server nil) ;; Current server
 479 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 480
 481 \f
 482
 483 (nnoo-define-basics nnimap)
 484
 485 ;; Utility functions:
 486
 487 (defsubst nnimap-get-server-buffer (server)
 488   "Return buffer for SERVER, if nil use current server."
 489   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 490
 491 (defun nnimap-remove-server-from-buffer-alist (server list)
 492   "Remove SERVER from LIST."
 493   (let (l)
 494     (dolist (e list)
 495       (unless (equal server (car-safe e))
 496         (push e l)))
 497     l))
 498
 499 (defun nnimap-possibly-change-server (server)
 500   "Return buffer for SERVER, changing the current server as a side-effect.
 501 If SERVER is nil, uses the current server."
 502   (setq nnimap-current-server (or server nnimap-current-server)
 503         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 504
 505 (defun nnimap-verify-uidvalidity (group server)
 506   "Verify stored uidvalidity match current one in GROUP on SERVER."
 507   (let* ((gnusgroup (gnus-group-prefixed-name
 508                      group (gnus-server-to-method
 509                             (format "nnimap:%s" server))))
 510          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 511          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 512          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 513          (nameuid (nnheader-translate-file-chars
 514                    (concat nnimap-nov-file-name
 515                            (if (equal server "")
 516                                "unnamed"
 517                              server) "." group "." old-uidvalidity
 518                            nnimap-nov-file-name-suffix) t))
 519          (file (if (or nnmail-use-long-file-names
 520                        (file-exists-p (expand-file-name nameuid dir)))
 521                    (expand-file-name nameuid dir)
 522                  (expand-file-name
 523                   (mm-encode-coding-string
 524                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 525                    nnmail-pathname-coding-system)
 526                   dir))))
 527     (if old-uidvalidity
 528         (if (not (equal old-uidvalidity new-uidvalidity))
 529             ;; uidvalidity clash
 530             (gnus-delete-file file)
 531           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 532           t)
 533       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 534       t)))
 535
 536 (defun nnimap-before-find-minmax-bugworkaround ()
 537   "Function called before iterating through mailboxes with
 538 `nnimap-find-minmax-uid'."
 539   (when nnimap-need-unselect-to-notice-new-mail
 540     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 541     ;; currently selected mailbox without a re-select/examine.
 542     (or (null (imap-current-mailbox nnimap-server-buffer))
 543         (imap-mailbox-unselect nnimap-server-buffer))))
 544
 545 (defun nnimap-find-minmax-uid (group &optional examine)
 546   "Find lowest and highest active article number in GROUP.
 547 If EXAMINE is non-nil the group is selected read-only."
 548   (with-current-buffer nnimap-server-buffer
 549     (when (or (string= group (imap-current-mailbox))
 550               (imap-mailbox-select group examine))
 551       (let (minuid maxuid)
 552         (when (> (imap-mailbox-get 'exists) 0)
 553           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 554           (imap-message-map (lambda (uid Uid)
 555                               (setq minuid (if minuid (min minuid uid) uid)
 556                                     maxuid (if maxuid (max maxuid uid) uid)))
 557                             'UID))
 558         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 559
 560 (defun nnimap-possibly-change-group (group &optional server)
 561   "Make GROUP the current group, and SERVER the current server."
 562   (when (nnimap-possibly-change-server server)
 563     (with-current-buffer nnimap-server-buffer
 564       (if (or (null group) (imap-current-mailbox-p group))
 565           imap-current-mailbox
 566         (if (imap-mailbox-select group)
 567             (if (or (nnimap-verify-uidvalidity
 568                      group (or server nnimap-current-server))
 569                     (zerop (imap-mailbox-get 'exists group))
 570                     t ;; for OGnus to see if ignoring uidvalidity
 571                     ;; changes has any bad effects.
 572                     (yes-or-no-p
 573                      (format
 574                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 575                 imap-current-mailbox
 576               (imap-mailbox-unselect)
 577               (error "nnimap: Group %s is not uid-valid" group))
 578           (nnheader-report 'nnimap (imap-error-text)))))))
 579
 580 (defun nnimap-replace-whitespace (string)
 581   "Return STRING with all whitespace replaced with space."
 582   (when string
 583     (while (string-match "[\r\n\t]+" string)
 584       (setq string (replace-match " " t t string)))
 585     string))
 586
 587 ;; Required backend functions
 588
 589 (defun nnimap-retrieve-headers-progress ()
 590   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 591   (and (numberp nnmail-large-newsgroup)
 592        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 593        (> nnimap-length nnmail-large-newsgroup)
 594        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 595                          (nth (/ (% nnimap-counter
 596                                     (* (length nnimap-progress-chars)
 597                                        nnimap-progress-how-often))
 598                                  nnimap-progress-how-often)
 599                               nnimap-progress-chars)))
 600   (with-current-buffer nntp-server-buffer
 601     (let (headers lines chars uid mbx)
 602       (with-current-buffer nnimap-server-buffer
 603         (setq uid imap-current-message
 604               mbx imap-current-mailbox
 605               headers (nnimap-demule
 606                        (if (imap-capability 'IMAP4rev1)
 607                            ;; xxx don't just use car? alist doesn't contain
 608                            ;; anything else now, but it might...
 609                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 610                          (imap-message-get uid 'RFC822.HEADER)))
 611               lines (imap-body-lines (imap-message-body imap-current-message))
 612               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 613       (nnheader-insert-nov
 614        (with-temp-buffer
 615          (buffer-disable-undo)
 616          (insert headers)
 617          (let ((head (nnheader-parse-naked-head uid)))
 618            (mail-header-set-number head uid)
 619            (mail-header-set-chars head chars)
 620            (mail-header-set-lines head lines)
 621            (mail-header-set-xref
 622             head (format "%s %s:%d" (system-name) mbx uid))
 623            head))))))
 624
 625 (defun nnimap-retrieve-which-headers (articles fetch-old)
 626   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 627   (with-current-buffer nnimap-server-buffer
 628     (if (numberp (car-safe articles))
 629         (imap-search
 630          (concat "UID "
 631                  (imap-range-to-message-set
 632                   (gnus-compress-sequence
 633                    (append (gnus-uncompress-sequence
 634                             (and fetch-old
 635                                  (cons (if (numberp fetch-old)
 636                                            (max 1 (- (car articles) fetch-old))
 637                                          1)
 638                                        (1- (car articles)))))
 639                            articles)))))
 640       (mapcar (lambda (msgid)
 641                 (imap-search
 642                  (format "HEADER Message-Id \"%s\"" msgid)))
 643               articles))))
 644
 645 (defun nnimap-group-overview-filename (group server)
 646   "Make file name for GROUP on SERVER."
 647   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 648          (uidvalidity (gnus-group-get-parameter
 649                        (gnus-group-prefixed-name
 650                         group (gnus-server-to-method
 651                                (format "nnimap:%s" server)))
 652                        'uidvalidity))
 653          (name (nnheader-translate-file-chars
 654                 (concat nnimap-nov-file-name
 655                         (if (equal server "")
 656                             "unnamed"
 657                           server) "." group nnimap-nov-file-name-suffix) t))
 658          (nameuid (nnheader-translate-file-chars
 659                    (concat nnimap-nov-file-name
 660                            (if (equal server "")
 661                                "unnamed"
 662                              server) "." group "." uidvalidity
 663                            nnimap-nov-file-name-suffix) t))
 664          (oldfile (if (or nnmail-use-long-file-names
 665                           (file-exists-p (expand-file-name name dir)))
 666                       (expand-file-name name dir)
 667                     (expand-file-name
 668                      (mm-encode-coding-string
 669                       (nnheader-replace-chars-in-string name ?. ?/)
 670                       nnmail-pathname-coding-system)
 671                      dir)))
 672          (newfile (if (or nnmail-use-long-file-names
 673                           (file-exists-p (expand-file-name nameuid dir)))
 674                       (expand-file-name nameuid dir)
 675                     (expand-file-name
 676                      (mm-encode-coding-string
 677                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 678                       nnmail-pathname-coding-system)
 679                      dir))))
 680     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 681       (message "nnimap: Upgrading novcache filename...")
 682       (sit-for 1)
 683       (gnus-make-directory (file-name-directory newfile))
 684       (unless (ignore-errors (rename-file oldfile newfile) t)
 685         (if (ignore-errors (copy-file oldfile newfile) t)
 686             (delete-file oldfile)
 687           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 688     newfile))
 689
 690 (defun nnimap-retrieve-headers-from-file (group server)
 691   (with-current-buffer nntp-server-buffer
 692     (let ((nov (nnimap-group-overview-filename group server)))
 693       (when (file-exists-p nov)
 694         (mm-insert-file-contents nov)
 695         (set-buffer-modified-p nil)
 696         (let ((min (ignore-errors (goto-char (point-min))
 697                                   (read (current-buffer))))
 698               (max (ignore-errors (goto-char (point-max))
 699                                   (forward-line -1)
 700                                   (read (current-buffer)))))
 701           (if (and (numberp min) (numberp max))
 702               (cons min max)
 703             ;; junk, remove it, it's saved later
 704             (erase-buffer)
 705             nil))))))
 706
 707 (defun nnimap-retrieve-headers-from-server (articles group server)
 708   (with-current-buffer nnimap-server-buffer
 709     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 710           (nnimap-length (gnus-range-length articles))
 711           (nnimap-counter 0))
 712       (imap-fetch (imap-range-to-message-set articles)
 713                   (concat "(UID RFC822.SIZE BODY "
 714                           (let ((headers
 715                                  (append '(Subject From Date Message-Id
 716                                                    References In-Reply-To Xref)
 717                                          (copy-sequence
 718                                           nnmail-extra-headers))))
 719                             (if (imap-capability 'IMAP4rev1)
 720                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 721                               (format "RFC822.HEADER.LINES %s)" headers)))))
 722       (with-current-buffer nntp-server-buffer
 723         (sort-numeric-fields 1 (point-min) (point-max)))
 724       (and (numberp nnmail-large-newsgroup)
 725            (> nnimap-length nnmail-large-newsgroup)
 726            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 727
 728 (defun nnimap-dont-use-nov-p (group server)
 729   (or gnus-nov-is-evil nnimap-nov-is-evil
 730       (unless (and (gnus-make-directory
 731                     (file-name-directory
 732                      (nnimap-group-overview-filename group server)))
 733                    (file-writable-p
 734                     (nnimap-group-overview-filename group server)))
 735         (message "nnimap: Nov cache not writable, %s"
 736                  (nnimap-group-overview-filename group server)))))
 737
 738 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 739   (when (nnimap-possibly-change-group group server)
 740     (with-current-buffer nntp-server-buffer
 741       (erase-buffer)
 742       (if (nnimap-dont-use-nov-p group server)
 743           (nnimap-retrieve-headers-from-server
 744            (gnus-compress-sequence articles) group server)
 745         (let (uids cached low high)
 746           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 747                       low (car uids)
 748                       high (car (last uids)))
 749             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 750                 (progn
 751                   ;; fetch articles with uids before cache block
 752                   (when (< low (car cached))
 753                     (goto-char (point-min))
 754                     (nnimap-retrieve-headers-from-server
 755                      (cons low (1- (car cached))) group server))
 756                   ;; fetch articles with uids after cache block
 757                   (when (> high (cdr cached))
 758                     (goto-char (point-max))
 759                     (nnimap-retrieve-headers-from-server
 760                      (cons (1+ (cdr cached)) high) group server))
 761                   (when nnimap-prune-cache
 762                     ;; remove nov's for articles which has expired on server
 763                     (goto-char (point-min))
 764                     (dolist (uid (gnus-set-difference articles uids))
 765                       (when (re-search-forward (format "^%d\t" uid) nil t)
 766                         (gnus-delete-line)))))
 767               ;; nothing cached, fetch whole range from server
 768               (nnimap-retrieve-headers-from-server
 769                (cons low high) group server))
 770             (when (buffer-modified-p)
 771               (nnmail-write-region
 772                (point-min) (point-max)
 773                (nnimap-group-overview-filename group server) nil 'nomesg))
 774             (nnheader-nov-delete-outside-range low high))))
 775       'nov)))
 776
 777 (defun nnimap-open-connection (server)
 778   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 779                       nnimap-authenticator nnimap-server-buffer))
 780       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 781     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 782                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 783       (imap-close nnimap-server-buffer)
 784       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 785     (let* ((list (progn (gnus-message 7 "Parsing authinfo file `%s'."
 786                                       nnimap-authinfo-file)
 787                         (netrc-parse nnimap-authinfo-file)))
 788            (port (if nnimap-server-port
 789                      (int-to-string nnimap-server-port)
 790                    "imap"))
 791            (user (netrc-machine-user-or-password
 792                   "login"
 793                   list
 794                   (list server
 795                         (or nnimap-server-address
 796                             nnimap-address))
 797                   (list port)
 798                   (list "imap" "imaps")))
 799            (passwd (netrc-machine-user-or-password
 800                     "password"
 801                     list
 802                     (list server
 803                           (or nnimap-server-address
 804                               nnimap-address))
 805                     (list port)
 806                     (list "imap" "imaps"))))
 807       (if (imap-authenticate user passwd nnimap-server-buffer)
 808           (prog2
 809               (setq nnimap-server-buffer-alist
 810                     (nnimap-remove-server-from-buffer-alist
 811                      server
 812                      nnimap-server-buffer-alist))
 813               (push (list server nnimap-server-buffer)
 814                     nnimap-server-buffer-alist)
 815             (imap-id nnimap-id nnimap-server-buffer)
 816             (nnimap-possibly-change-server server))
 817         (imap-close nnimap-server-buffer)
 818         (kill-buffer nnimap-server-buffer)
 819         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 820
 821 (deffoo nnimap-open-server (server &optional defs)
 822   (nnheader-init-server-buffer)
 823   (if (nnimap-server-opened server)
 824       t
 825     (unless (assq 'nnimap-server-buffer defs)
 826       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 827     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 828     ;; for people that configured nnimap with a very old version
 829     (unless (assq 'nnimap-address defs)
 830       (if (assq 'nnimap-server-address defs)
 831           (push (list 'nnimap-address
 832                       (cadr (assq 'nnimap-server-address defs))) defs)
 833         (push (list 'nnimap-address server) defs)))
 834     (nnoo-change-server 'nnimap server defs)
 835     (or nnimap-server-buffer
 836         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 837     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 838       (nnoo-change-server 'nnimap server defs))
 839     (or (and nnimap-server-buffer
 840              (imap-opened nnimap-server-buffer)
 841              (if (with-current-buffer nnimap-server-buffer
 842                    (memq imap-state '(auth selected examine)))
 843                  t
 844                (imap-close nnimap-server-buffer)
 845                (nnimap-open-connection server)))
 846         (nnimap-open-connection server))))
 847
 848 (deffoo nnimap-server-opened (&optional server)
 849   "Whether SERVER is opened.
 850 If SERVER is the current virtual server, and the connection to the
 851 physical server is alive, this function return a non-nil value.  If
 852 SERVER is nil, it is treated as the current server."
 853   ;; clean up autologouts??
 854   (and (or server nnimap-current-server)
 855        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 856        (imap-opened (nnimap-get-server-buffer server))))
 857
 858 (deffoo nnimap-close-server (&optional server)
 859   "Close connection to server and free all resources connected to it.
 860 Return nil if the server couldn't be closed for some reason."
 861   (let ((server (or server nnimap-current-server)))
 862     (when (or (nnimap-server-opened server)
 863               (imap-opened (nnimap-get-server-buffer server)))
 864       (imap-close (nnimap-get-server-buffer server))
 865       (kill-buffer (nnimap-get-server-buffer server))
 866       (setq nnimap-server-buffer nil
 867             nnimap-current-server nil
 868             nnimap-server-buffer-alist
 869             (nnimap-remove-server-from-buffer-alist
 870              server
 871              nnimap-server-buffer-alist)))
 872     (nnoo-close-server 'nnimap server)))
 873
 874 (deffoo nnimap-request-close ()
 875   "Close connection to all servers and free all resources that the backend have reserved.
 876 All buffers that have been created by that
 877 backend should be killed.  (Not the nntp-server-buffer, though.) This
 878 function is generally only called when Gnus is shutting down."
 879   (mapc (lambda (server) (nnimap-close-server (car server)))
 880         nnimap-server-buffer-alist)
 881   (setq nnimap-server-buffer-alist nil))
 882
 883 (deffoo nnimap-status-message (&optional server)
 884   "This function returns the last error message from server."
 885   (when (nnimap-possibly-change-server server)
 886     (nnoo-status-message 'nnimap server)))
 887
 888 (defun nnimap-demule (string)
 889   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 890   ;; because it will turn accidental emacs-mule-valid byte sequences
 891   ;; into multibyte chars.  --Stef
 892   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 893   ;; that bad. --Simon
 894   (funcall (if (and (fboundp 'string-as-multibyte)
 895                     (subrp (symbol-function 'string-as-multibyte)))
 896                'string-as-multibyte
 897              'identity)
 898            (or string "")))
 899
 900 (defun nnimap-make-callback (article gnus-callback buffer)
 901   "Return a callback function."
 902   `(lambda ()
 903      (nnimap-callback ,article ,gnus-callback ,buffer)))
 904
 905 (defun nnimap-callback (article gnus-callback buffer)
 906   (when (eq article (imap-current-message))
 907     (remove-hook 'imap-fetch-data-hook
 908                  (nnimap-make-callback article gnus-callback buffer))
 909     (with-current-buffer buffer
 910       (insert
 911        (with-current-buffer nnimap-server-buffer
 912          (nnimap-demule
 913           (if (imap-capability 'IMAP4rev1)
 914               ;; xxx don't just use car? alist doesn't contain
 915               ;; anything else now, but it might...
 916               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 917             (imap-message-get article 'RFC822)))))
 918       (nnheader-ms-strip-cr)
 919       (funcall gnus-callback t))))
 920
 921 (defun nnimap-request-article-part (article part prop &optional
 922                                             group server to-buffer detail)
 923   (when (nnimap-possibly-change-group group server)
 924     (let ((article (if (stringp article)
 925                        (car-safe (imap-search
 926                                   (format "HEADER Message-Id \"%s\"" article)
 927                                   nnimap-server-buffer))
 928                      article)))
 929       (when article
 930         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 931                       article (or group imap-current-mailbox
 932                                   gnus-newsgroup-name))
 933         (if (not nnheader-callback-function)
 934             (with-current-buffer (or to-buffer nntp-server-buffer)
 935               (erase-buffer)
 936               (let ((data (imap-fetch article part prop nil
 937                                       nnimap-server-buffer)))
 938                 (insert (nnimap-demule (if detail
 939                                            (nth 2 (car data))
 940                                          data))))
 941               (nnheader-ms-strip-cr)
 942               (gnus-message
 943                10 "nnimap: Fetching (part of) article %d from %s...done"
 944                article (or group imap-current-mailbox gnus-newsgroup-name))
 945               (if (bobp)
 946                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 947                                    article (or group imap-current-mailbox
 948                                                gnus-newsgroup-name)
 949                                    (imap-error-text nnimap-server-buffer))
 950                 (cons group article)))
 951           (add-hook 'imap-fetch-data-hook
 952                     (nnimap-make-callback article
 953                                           nnheader-callback-function
 954                                           nntp-server-buffer))
 955           (imap-fetch-asynch article part nil nnimap-server-buffer)
 956           (cons group article))))))
 957
 958 (deffoo nnimap-asynchronous-p ()
 959   t)
 960
 961 (deffoo nnimap-request-article (article &optional group server to-buffer)
 962   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 963       (nnimap-request-article-part
 964        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 965     (nnimap-request-article-part
 966      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 967
 968 (deffoo nnimap-request-head (article &optional group server to-buffer)
 969   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 970       (nnimap-request-article-part
 971        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 972     (nnimap-request-article-part
 973      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 974
 975 (deffoo nnimap-request-body (article &optional group server to-buffer)
 976   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 977       (nnimap-request-article-part
 978        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 979     (nnimap-request-article-part
 980      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 981
 982 (deffoo nnimap-request-group (group &optional server fast)
 983   (nnimap-request-update-info-internal
 984    group
 985    (gnus-get-info (gnus-group-prefixed-name
 986                    group (gnus-server-to-method (format "nnimap:%s" server))))
 987    server)
 988   (when (nnimap-possibly-change-group group server)
 989     (nnimap-before-find-minmax-bugworkaround)
 990     (let (info)
 991       (cond (fast group)
 992             ((null (setq info (nnimap-find-minmax-uid group t)))
 993              (nnheader-report 'nnimap "Could not get active info for %s"
 994                               group))
 995             (t
 996              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 997                               (max 1 (or (nth 1 info) 1))
 998                               (or (nth 2 info) 0) group)
 999              (nnheader-report 'nnimap "Group %s selected" group)
1000              t)))))
1001
1002 (defun nnimap-update-unseen (group &optional server)
1003   "Update the unseen count in `nnimap-mailbox-info'."
1004   (gnus-sethash
1005    (gnus-group-prefixed-name group server)
1006    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
1007                                  nnimap-mailbox-info)))
1008      (list (nth 0 old) (nth 1 old)
1009            (imap-mailbox-status group 'unseen nnimap-server-buffer)
1010            (nth 3 old)))
1011    nnimap-mailbox-info))
1012
1013 (defun nnimap-close-group (group &optional server)
1014   (with-current-buffer nnimap-server-buffer
1015     (when (and (imap-opened)
1016                (nnimap-possibly-change-group group server))
1017       (nnimap-update-unseen group server)
1018       (case nnimap-expunge-on-close
1019         (always (progn
1020                   (imap-mailbox-expunge nnimap-close-asynchronous)
1021                   (unless nnimap-dont-close
1022                     (imap-mailbox-close nnimap-close-asynchronous))))
1023         (ask (if (and (imap-search "DELETED")
1024                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1025                                              imap-current-mailbox)))
1026                  (progn
1027                    (imap-mailbox-expunge nnimap-close-asynchronous)
1028                    (unless nnimap-dont-close
1029                      (imap-mailbox-close nnimap-close-asynchronous)))
1030                (imap-mailbox-unselect)))
1031         (t (imap-mailbox-unselect)))
1032       (not imap-current-mailbox))))
1033
1034 (defun nnimap-pattern-to-list-arguments (pattern)
1035   (mapcar (lambda (p)
1036             (cons (car-safe p) (or (cdr-safe p) p)))
1037           (if (and (listp pattern)
1038                    (listp (cdr pattern)))
1039               pattern
1040             (list pattern))))
1041
1042 (deffoo nnimap-request-list (&optional server)
1043   (when (nnimap-possibly-change-server server)
1044     (with-current-buffer nntp-server-buffer
1045       (erase-buffer))
1046     (gnus-message 5 "nnimap: Generating active list%s..."
1047                   (if (> (length server) 0) (concat " for " server) ""))
1048     (nnimap-before-find-minmax-bugworkaround)
1049     (with-current-buffer nnimap-server-buffer
1050       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1051         (dolist (mbx (funcall nnimap-request-list-method
1052                               (cdr pattern) (car pattern)))
1053           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1054               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1055                 (when info
1056                   (with-current-buffer nntp-server-buffer
1057                     (insert (format "\"%s\" %d %d y\n"
1058                                     mbx (or (nth 2 info) 0)
1059                                     (max 1 (or (nth 1 info) 1)))))))))))
1060     (gnus-message 5 "nnimap: Generating active list%s...done"
1061                   (if (> (length server) 0) (concat " for " server) ""))
1062     t))
1063
1064 (deffoo nnimap-request-post (&optional server)
1065   (let ((success t))
1066     (dolist (mbx (message-unquote-tokens
1067                   (message-tokenize-header
1068                    (message-fetch-field "Newsgroups") ", ")) success)
1069       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1070         (or (gnus-active to-newsgroup)
1071             (gnus-activate-group to-newsgroup)
1072             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1073                                        to-newsgroup))
1074                 (or (and (gnus-request-create-group
1075                           to-newsgroup gnus-command-method)
1076                          (gnus-activate-group to-newsgroup nil nil
1077                                               gnus-command-method))
1078                     (error "Couldn't create group %s" to-newsgroup)))
1079             (error "No such group: %s" to-newsgroup))
1080         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1081           (setq success nil))))))
1082
1083 ;; Optional backend functions
1084
1085 (defun nnimap-string-lessp-numerical (s1 s2)
1086   "Return t if first arg string is less than second in numerical order."
1087   (cond ((string= s1 s2)
1088          nil)
1089         ((> (length s1) (length s2))
1090          nil)
1091         ((< (length s1) (length s2))
1092          t)
1093         ((< (string-to-number (substring s1 0 1))
1094             (string-to-number (substring s2 0 1)))
1095          t)
1096         ((> (string-to-number (substring s1 0 1))
1097             (string-to-number (substring s2 0 1)))
1098          nil)
1099         (t
1100          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1101
1102 (deffoo nnimap-retrieve-groups (groups &optional server)
1103   (when (nnimap-possibly-change-server server)
1104     (gnus-message 5 "nnimap: Checking mailboxes...")
1105     (with-current-buffer nntp-server-buffer
1106       (erase-buffer)
1107       (nnimap-before-find-minmax-bugworkaround)
1108       (let (asyncgroups slowgroups)
1109         (if (null nnimap-retrieve-groups-asynchronous)
1110             (setq slowgroups groups)
1111           (dolist (group groups)
1112             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1113             (add-to-list (if (gnus-gethash-safe
1114                               (gnus-group-prefixed-name group server)
1115                               nnimap-mailbox-info)
1116                              'asyncgroups
1117                            'slowgroups)
1118                          (list group (imap-mailbox-status-asynch
1119                                       group '(uidvalidity uidnext unseen)
1120                                       nnimap-server-buffer))))
1121           (dolist (asyncgroup asyncgroups)
1122             (let ((group (nth 0 asyncgroup))
1123                   (tag   (nth 1 asyncgroup))
1124                   new old)
1125               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1126                 (if (or (not (string=
1127                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1128                                                     group server)
1129                                                    nnimap-mailbox-info))
1130                               (imap-mailbox-get 'uidvalidity group
1131                                                 nnimap-server-buffer)))
1132                         (not (string=
1133                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1134                                                     group server)
1135                                                    nnimap-mailbox-info))
1136                               (imap-mailbox-get 'uidnext group
1137                                                 nnimap-server-buffer))))
1138                     (push (list group) slowgroups)
1139                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1140                                                 group server)
1141                                                nnimap-mailbox-info))))))))
1142         (dolist (group slowgroups)
1143           (if nnimap-retrieve-groups-asynchronous
1144               (setq group (car group)))
1145           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1146           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1147           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1148                                                      nnimap-server-buffer))
1149               (let* ((info (nnimap-find-minmax-uid group 'examine))
1150                      (str (format "\"%s\" %d %d y\n" group
1151                                   (or (nth 2 info) 0)
1152                                   (max 1 (or (nth 1 info) 1)))))
1153                 (when (> (or (imap-mailbox-get 'recent group
1154                                                nnimap-server-buffer) 0)
1155                          0)
1156                   (push (list (cons group 0)) nnmail-split-history))
1157                 (insert str)
1158                 (when nnimap-retrieve-groups-asynchronous
1159                   (gnus-sethash
1160                    (gnus-group-prefixed-name group server)
1161                    (list (or (imap-mailbox-get
1162                               'uidvalidity group nnimap-server-buffer)
1163                              (imap-mailbox-status
1164                               group 'uidvalidity nnimap-server-buffer))
1165                          (or (imap-mailbox-get
1166                               'uidnext group nnimap-server-buffer)
1167                              (imap-mailbox-status
1168                               group 'uidnext nnimap-server-buffer))
1169                          (or (imap-mailbox-get
1170                               'unseen group nnimap-server-buffer)
1171                              (imap-mailbox-status
1172                               group 'unseen nnimap-server-buffer))
1173                          str)
1174                    nnimap-mailbox-info)))))))
1175     (gnus-message 5 "nnimap: Checking mailboxes...done")
1176     'active))
1177
1178 (deffoo nnimap-request-update-info-internal (group info &optional server)
1179   (when (nnimap-possibly-change-group group server)
1180     (when info ;; xxx what does this mean? should we create a info?
1181       (with-current-buffer nnimap-server-buffer
1182         (gnus-message 5 "nnimap: Updating info for %s..."
1183                       (gnus-info-group info))
1184
1185         (when (nnimap-mark-permanent-p 'read)
1186           (let (seen unseen)
1187             ;; read info could contain articles marked unread by other
1188             ;; imap clients!  we correct this
1189             (setq unseen (gnus-compress-sequence
1190                           (imap-search "UNSEEN UNDELETED"))
1191                   seen (gnus-range-difference (gnus-info-read info) unseen)
1192                   seen (gnus-range-add seen
1193                                        (gnus-compress-sequence
1194                                         (imap-search "SEEN")))
1195                   seen (if (and (integerp (car seen))
1196                                 (null (cdr seen)))
1197                            (list (cons (car seen) (car seen)))
1198                          seen))
1199             (gnus-info-set-read info seen)))
1200
1201         (mapcar (lambda (pred)
1202                   (when (or (eq (cdr pred) 'recent)
1203                             (and (nnimap-mark-permanent-p (cdr pred))
1204                                  (member (nnimap-mark-to-flag (cdr pred))
1205                                          (imap-mailbox-get 'flags))))
1206                     (gnus-info-set-marks
1207                      info
1208                      (gnus-update-alist-soft
1209                       (cdr pred)
1210                       (gnus-compress-sequence
1211                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1212                       (gnus-info-marks info))
1213                      t)))
1214                 gnus-article-mark-lists)
1215
1216         (when nnimap-importantize-dormant
1217           ;; nnimap mark dormant article as ticked too (for other clients)
1218           ;; so we remove that mark for gnus since we support dormant
1219           (gnus-info-set-marks
1220            info
1221            (gnus-update-alist-soft
1222             'tick
1223             (gnus-remove-from-range
1224              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1225              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1226             (gnus-info-marks info))
1227            t))
1228
1229         (gnus-message 5 "nnimap: Updating info for %s...done"
1230                       (gnus-info-group info))
1231
1232         info))))
1233
1234 (deffoo nnimap-request-type (group &optional article)
1235   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1236       'news
1237     'mail))
1238
1239 (deffoo nnimap-request-set-mark (group actions &optional server)
1240   (when (nnimap-possibly-change-group group server)
1241     (with-current-buffer nnimap-server-buffer
1242       (let (action)
1243         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1244         (while (setq action (pop actions))
1245           (let ((range (nth 0 action))
1246                 (what  (nth 1 action))
1247                 (cmdmarks (nth 2 action))
1248                 marks)
1249             ;; bookmark can't be stored (not list/range
1250             (setq cmdmarks (delq 'bookmark cmdmarks))
1251             ;; killed can't be stored (not list/range
1252             (setq cmdmarks (delq 'killed cmdmarks))
1253             ;; unsent are for nndraft groups only
1254             (setq cmdmarks (delq 'unsent cmdmarks))
1255             ;; cache flags are pointless on the server
1256             (setq cmdmarks (delq 'cache cmdmarks))
1257             ;; seen flags are local to each gnus
1258             (setq cmdmarks (delq 'seen cmdmarks))
1259             ;; recent marks can't be set
1260             (setq cmdmarks (delq 'recent cmdmarks))
1261             (when nnimap-importantize-dormant
1262               ;; flag dormant articles as ticked
1263               (if (memq 'dormant cmdmarks)
1264                   (setq cmdmarks (cons 'tick cmdmarks))))
1265             ;; remove stuff we are forbidden to store
1266             (mapc (lambda (mark)
1267                     (if (imap-message-flag-permanent-p
1268                          (nnimap-mark-to-flag mark))
1269                         (setq marks (cons mark marks))))
1270                   cmdmarks)
1271             (when (and range marks)
1272               (cond ((eq what 'del)
1273                      (imap-message-flags-del
1274                       (imap-range-to-message-set range)
1275                       (nnimap-mark-to-flag marks nil t)))
1276                     ((eq what 'add)
1277                      (imap-message-flags-add
1278                       (imap-range-to-message-set range)
1279                       (nnimap-mark-to-flag marks nil t)))
1280                     ((eq what 'set)
1281                      (imap-message-flags-set
1282                       (imap-range-to-message-set range)
1283                       (nnimap-mark-to-flag marks nil t)))))))
1284         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1285   nil)
1286
1287 (defun nnimap-split-fancy ()
1288   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1289   (let ((nnmail-split-fancy nnimap-split-fancy))
1290     (nnmail-split-fancy)))
1291
1292 (defun nnimap-split-to-groups (rules)
1293   ;; tries to match all rules in nnimap-split-rule against content of
1294   ;; nntp-server-buffer, returns a list of groups that matched.
1295   (with-current-buffer nntp-server-buffer
1296     ;; Fold continuation lines.
1297     (goto-char (point-min))
1298     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1299       (replace-match " " t t))
1300     (if (functionp rules)
1301         (funcall rules)
1302       (let (to-groups regrepp)
1303         (catch 'split-done
1304           (dolist (rule rules to-groups)
1305             (let ((group (car rule))
1306                   (regexp (cadr rule)))
1307               (goto-char (point-min))
1308               (when (and (if (stringp regexp)
1309                              (progn
1310                                (if (not (stringp group))
1311                                    (setq group (eval group))
1312                                  (setq regrepp
1313                                        (string-match "\\\\[0-9&]" group)))
1314                                (re-search-forward regexp nil t))
1315                            (funcall regexp group))
1316                          ;; Don't enter the article into the same group twice.
1317                          (not (assoc group to-groups)))
1318                 (push (if regrepp
1319                           (nnmail-expand-newtext group)
1320                         group)
1321                       to-groups)
1322                 (or nnimap-split-crosspost
1323                     (throw 'split-done to-groups))))))))))
1324
1325 (defun nnimap-assoc-match (key alist)
1326   (let (element)
1327     (while (and alist (not element))
1328       (if (string-match (car (car alist)) key)
1329           (setq element (car alist)))
1330       (setq alist (cdr alist)))
1331     element))
1332
1333 (defun nnimap-split-find-rule (server inbox)
1334   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1335            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1336       ;; extended format
1337       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1338                                             server nnimap-split-rule))))
1339     nnimap-split-rule))
1340
1341 (defun nnimap-split-find-inbox (server)
1342   (if (listp nnimap-split-inbox)
1343       nnimap-split-inbox
1344     (list nnimap-split-inbox)))
1345
1346 (defun nnimap-split-articles (&optional group server)
1347   (when (nnimap-possibly-change-server server)
1348     (with-current-buffer nnimap-server-buffer
1349       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1350         ;; iterate over inboxes
1351         (while (and (setq inbox (pop inboxes))
1352                     (nnimap-possibly-change-group inbox)) ;; SELECT
1353           ;; find split rule for this server / inbox
1354           (when (setq rule (nnimap-split-find-rule server inbox))
1355             ;; iterate over articles
1356             (dolist (article (imap-search nnimap-split-predicate))
1357               (when (if (if (eq nnimap-split-download-body 'default)
1358                             nnimap-split-download-body-default
1359                           nnimap-split-download-body)
1360                         (and (nnimap-request-article article)
1361                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1362                       (nnimap-request-head article))
1363                 ;; copy article to right group(s)
1364                 (setq removeorig nil)
1365                 (dolist (to-group (nnimap-split-to-groups rule))
1366                   (cond ((eq to-group 'junk)
1367                          (message "IMAP split removed %s:%s:%d" server inbox
1368                                   article)
1369                          (setq removeorig t))
1370                         ((imap-message-copy (number-to-string article)
1371                                             to-group nil 'nocopyuid)
1372                          (message "IMAP split moved %s:%s:%d to %s" server
1373                                   inbox article to-group)
1374                          (setq removeorig t)
1375                          (when nnmail-cache-accepted-message-ids
1376                            (with-current-buffer nntp-server-buffer
1377                              (let (msgid)
1378                                (and (setq msgid
1379                                           (nnmail-fetch-field "message-id"))
1380                                     (nnmail-cache-insert msgid
1381                                                          to-group
1382                                                          (nnmail-fetch-field "subject"))))))
1383                          ;; Add the group-art list to the history list.
1384                          (push (list (cons to-group 0)) nnmail-split-history))
1385                         (t
1386                          (message "IMAP split failed to move %s:%s:%d to %s"
1387                                   server inbox article to-group))))
1388                 (if (if (eq nnimap-split-download-body 'default)
1389                         nnimap-split-download-body-default
1390                       nnimap-split-download-body)
1391                     (widen))
1392                 ;; remove article if it was successfully copied somewhere
1393                 (and removeorig
1394                      (imap-message-flags-add (format "%d" article)
1395                                              "\\Seen \\Deleted")))))
1396           (when (imap-mailbox-select inbox) ;; just in case
1397             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1398             (imap-mailbox-expunge)
1399             (imap-mailbox-close)))
1400         (when nnmail-cache-accepted-message-ids
1401           (nnmail-cache-close))
1402         t))))
1403
1404 (deffoo nnimap-request-scan (&optional group server)
1405   (nnimap-split-articles group server))
1406
1407 (deffoo nnimap-request-newgroups (date &optional server)
1408   (when (nnimap-possibly-change-server server)
1409     (with-current-buffer nntp-server-buffer
1410       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1411                     (if (> (length server) 0) " on " "") server)
1412       (erase-buffer)
1413       (nnimap-before-find-minmax-bugworkaround)
1414       (dolist (pattern (nnimap-pattern-to-list-arguments
1415                         nnimap-list-pattern))
1416         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1417                                         nnimap-server-buffer))
1418           (or (catch 'found
1419                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1420                                                    nnimap-server-buffer))
1421                   (if (string= (downcase mailbox) "\\noselect")
1422                       (throw 'found t)))
1423                 nil)
1424               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1425                 (when info
1426                   (insert (format "\"%s\" %d %d y\n"
1427                                   mbx (or (nth 2 info) 0)
1428                                   (max 1 (or (nth 1 info) 1)))))))))
1429       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1430                     (if (> (length server) 0) " on " "") server))
1431     t))
1432
1433 (deffoo nnimap-request-create-group (group &optional server args)
1434   (when (nnimap-possibly-change-server server)
1435     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1436         (imap-mailbox-create group nnimap-server-buffer)
1437         (nnheader-report 'nnimap "%S"
1438                          (imap-error-text nnimap-server-buffer)))))
1439
1440 (defun nnimap-time-substract (time1 time2)
1441   "Return TIME for TIME1 - TIME2."
1442   (let* ((ms (- (car time1) (car time2)))
1443          (ls (- (nth 1 time1) (nth 1 time2))))
1444     (if (< ls 0)
1445         (list (- ms 1) (+ (expt 2 16) ls))
1446       (list ms ls))))
1447
1448 (eval-when-compile (require 'parse-time))
1449 (defun nnimap-date-days-ago (daysago)
1450   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1451   (require 'parse-time)
1452   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1453          (date (format-time-string
1454                 (format "%%d-%s-%%Y"
1455                         (capitalize (car (rassoc (nth 4 (decode-time time))
1456                                                  parse-time-months))))
1457                 time)))
1458     (if (eq ?0 (string-to-char date))
1459         (substring date 1)
1460       date)))
1461
1462 (defun nnimap-request-expire-articles-progress ()
1463   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1464                 imap-current-message))
1465
1466 (defun nnimap-expiry-target (arts group server)
1467   (unless (eq nnmail-expiry-target 'delete)
1468     (with-temp-buffer
1469       (dolist (art arts)
1470         (nnimap-request-article art group server (current-buffer))
1471         ;; hints for optimization in `nnimap-request-accept-article'
1472         (let ((nnimap-current-move-article art)
1473               (nnimap-current-move-group group)
1474               (nnimap-current-move-server server))
1475           (nnmail-expiry-target-group nnmail-expiry-target group))))
1476     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1477     ;; current group to be changed or not, so we make sure here.
1478     (nnimap-possibly-change-group group server)))
1479
1480 ;; Notice that we don't actually delete anything, we just mark them deleted.
1481 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1482   (let ((artseq (gnus-compress-sequence articles)))
1483     (when (and artseq (nnimap-possibly-change-group group server))
1484       (with-current-buffer nnimap-server-buffer
1485         (let ((days (or (and nnmail-expiry-wait-function
1486                              (funcall nnmail-expiry-wait-function group))
1487                         nnmail-expiry-wait)))
1488           (cond ((or force (eq days 'immediate))
1489                  (let ((oldarts (imap-search
1490                                  (concat "UID "
1491                                          (imap-range-to-message-set artseq)))))
1492                    (when oldarts
1493                      (nnimap-expiry-target oldarts group server)
1494                      (when (imap-message-flags-add
1495                             (imap-range-to-message-set
1496                              (gnus-compress-sequence oldarts)) "\\Deleted")
1497                        (setq articles (gnus-set-difference
1498                                        articles oldarts))))))
1499                 ((and nnimap-search-uids-not-since-is-evil (numberp days))
1500                  (let* ((all-new-articles
1501                          (gnus-compress-sequence
1502                           (imap-search (format "SINCE %s"
1503                                                (nnimap-date-days-ago days)))))
1504                         (oldartseq
1505                          (gnus-range-difference artseq all-new-articles))
1506                         (oldarts (gnus-uncompress-range oldartseq)))
1507                    (when oldarts
1508                      (nnimap-expiry-target oldarts group server)
1509                      (when (imap-message-flags-add
1510                             (imap-range-to-message-set oldartseq)
1511                             "\\Deleted")
1512                        (setq articles (gnus-set-difference
1513                                        articles oldarts))))))
1514                 ((numberp days)
1515                  (let ((oldarts (imap-search
1516                                  (format nnimap-expunge-search-string
1517                                          (imap-range-to-message-set artseq)
1518                                          (nnimap-date-days-ago days))))
1519                        (imap-fetch-data-hook
1520                         '(nnimap-request-expire-articles-progress)))
1521                    (when oldarts
1522                      (nnimap-expiry-target oldarts group server)
1523                      (when (imap-message-flags-add
1524                             (imap-range-to-message-set
1525                              (gnus-compress-sequence oldarts)) "\\Deleted")
1526                        (setq articles (gnus-set-difference
1527                                        articles oldarts)))))))))))
1528   ;; return articles not deleted
1529   articles)
1530
1531 (deffoo nnimap-request-move-article (article group server accept-form
1532                                              &optional last move-is-internal)
1533   (when (nnimap-possibly-change-server server)
1534     (save-excursion
1535       (let ((buf (get-buffer-create " *nnimap move*"))
1536             (nnimap-current-move-article article)
1537             (nnimap-current-move-group group)
1538             (nnimap-current-move-server nnimap-current-server)
1539             result)
1540         (gnus-message 10 "nnimap-request-move-article: this is an %s move"
1541                       (if move-is-internal
1542                           "internal"
1543                         "external"))
1544         ;; request the article only when the move is NOT internal
1545         (and (or move-is-internal
1546                  (nnimap-request-article article group server))
1547              (save-excursion
1548                (set-buffer buf)
1549                (buffer-disable-undo (current-buffer))
1550                (insert-buffer-substring nntp-server-buffer)
1551                (setq result (eval accept-form))
1552                (kill-buffer buf)
1553                result)
1554              (nnimap-possibly-change-group group server)
1555              (imap-message-flags-add
1556               (imap-range-to-message-set (list article))
1557               "\\Deleted" 'silent nnimap-server-buffer))
1558         result))))
1559
1560 (deffoo nnimap-request-accept-article (group &optional server last)
1561   (when (nnimap-possibly-change-server server)
1562     (let (uid)
1563       (if (setq uid
1564                 (if (string= nnimap-current-server nnimap-current-move-server)
1565                     ;; moving article within same server, speed it up...
1566                     (and (nnimap-possibly-change-group
1567                           nnimap-current-move-group)
1568                          (imap-message-copy (number-to-string
1569                                              nnimap-current-move-article)
1570                                             group 'dontcreate nil
1571                                             nnimap-server-buffer))
1572                   (with-current-buffer (current-buffer)
1573                     (goto-char (point-min))
1574                     ;; remove any 'From blabla' lines, some IMAP servers
1575                     ;; reject the entire message otherwise.
1576                     (when (looking-at "^From[^:]")
1577                       (delete-region (point) (progn (forward-line) (point))))
1578                     ;; turn into rfc822 format (\r\n eol's)
1579                     (while (search-forward "\n" nil t)
1580                       (replace-match "\r\n"))
1581                     (when nnmail-cache-accepted-message-ids
1582                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1583                                            group
1584                                            (nnmail-fetch-field "subject"))))
1585                   (when (and last nnmail-cache-accepted-message-ids)
1586                     (nnmail-cache-close))
1587                   ;; this 'or' is for Cyrus server bug
1588                   (or (null (imap-current-mailbox nnimap-server-buffer))
1589                       (imap-mailbox-unselect nnimap-server-buffer))
1590                   (imap-message-append group (current-buffer) nil nil
1591                                        nnimap-server-buffer)))
1592           (cons group (nth 1 uid))
1593         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1594
1595 (deffoo nnimap-request-delete-group (group force &optional server)
1596   (when (nnimap-possibly-change-server server)
1597     (with-current-buffer nnimap-server-buffer
1598       (if force
1599           (or (null (imap-mailbox-status group 'uidvalidity))
1600               (imap-mailbox-delete group))
1601         ;; UNSUBSCRIBE?
1602         t))))
1603
1604 (deffoo nnimap-request-rename-group (group new-name &optional server)
1605   (when (nnimap-possibly-change-server server)
1606     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1607
1608 (defun nnimap-expunge (mailbox server)
1609   (when (nnimap-possibly-change-group mailbox server)
1610     (imap-mailbox-expunge nil nnimap-server-buffer)))
1611
1612 (defun nnimap-acl-get (mailbox server)
1613   (when (nnimap-possibly-change-server server)
1614     (and (imap-capability 'ACL nnimap-server-buffer)
1615          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1616
1617 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1618   (when (nnimap-possibly-change-server (cadr method))
1619     (unless (imap-capability 'ACL nnimap-server-buffer)
1620       (error "Your server does not support ACL editing"))
1621     (with-current-buffer nnimap-server-buffer
1622       ;; delete all removed identifiers
1623       (mapc (lambda (old-acl)
1624               (unless (assoc (car old-acl) new-acls)
1625                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1626                     (error "Can't delete ACL for %s" (car old-acl)))))
1627             old-acls)
1628       ;; set all changed acl's
1629       (mapc (lambda (new-acl)
1630               (let ((new-rights (cdr new-acl))
1631                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1632                 (unless (and old-rights new-rights
1633                              (string= old-rights new-rights))
1634                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1635                       (error "Can't set ACL for %s to %s" (car new-acl)
1636                              new-rights)))))
1637             new-acls)
1638       t)))
1639
1640 \f
1641 ;;; Internal functions
1642
1643 ;;
1644 ;; This is confusing.
1645 ;;
1646 ;; mark      => read, tick, draft, reply etc
1647 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1648 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1649 ;;
1650 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1651 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1652 ;;
1653
1654 (defconst nnimap-mark-to-predicate-alist
1655   (mapcar
1656    (lambda (pair)                       ; cdr is the mark
1657      (or (assoc (cdr pair)
1658                 '((read . "SEEN")
1659                   (tick . "FLAGGED")
1660                   (draft . "DRAFT")
1661                   (recent . "RECENT")
1662                   (reply . "ANSWERED")))
1663          (cons (cdr pair)
1664                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1665    (cons '(read . read) gnus-article-mark-lists)))
1666
1667 (defun nnimap-mark-to-predicate (pred)
1668   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1669 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1670 to be used within a IMAP SEARCH query."
1671   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1672
1673 (defconst nnimap-mark-to-flag-alist
1674   (mapcar
1675    (lambda (pair)
1676      (or (assoc (cdr pair)
1677                 '((read . "\\Seen")
1678                   (tick . "\\Flagged")
1679                   (draft . "\\Draft")
1680                   (recent . "\\Recent")
1681                   (reply . "\\Answered")))
1682          (cons (cdr pair)
1683                (format "gnus-%s" (symbol-name (cdr pair))))))
1684    (cons '(read . read) gnus-article-mark-lists)))
1685
1686 (defun nnimap-mark-to-flag-1 (preds)
1687   (if (and (not (null preds)) (listp preds))
1688       (cons (nnimap-mark-to-flag (car preds))
1689             (nnimap-mark-to-flag (cdr preds)))
1690     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1691
1692 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1693   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1694 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1695 be used in a STORE FLAGS command."
1696   (let ((result (nnimap-mark-to-flag-1 preds)))
1697     (setq result (if (and (or make-string always-list)
1698                           (not (listp result)))
1699                      (list result)
1700                    result))
1701     (if make-string
1702         (mapconcat (lambda (flag)
1703                      (if (listp flag)
1704                          (mapconcat 'identity flag " ")
1705                        flag))
1706                    result " ")
1707       result)))
1708
1709 (defun nnimap-mark-permanent-p (mark &optional group)
1710   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1711   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1712
1713 (when nnimap-debug
1714   (require 'trace)
1715   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1716   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1717           '(
1718             nnimap-possibly-change-server
1719             nnimap-verify-uidvalidity
1720             nnimap-find-minmax-uid
1721             nnimap-before-find-minmax-bugworkaround
1722             nnimap-possibly-change-group
1723             ;;nnimap-replace-whitespace
1724             nnimap-retrieve-headers-progress
1725             nnimap-retrieve-which-headers
1726             nnimap-group-overview-filename
1727             nnimap-retrieve-headers-from-file
1728             nnimap-retrieve-headers-from-server
1729             nnimap-retrieve-headers
1730             nnimap-open-connection
1731             nnimap-open-server
1732             nnimap-server-opened
1733             nnimap-close-server
1734             nnimap-request-close
1735             nnimap-status-message
1736             ;;nnimap-demule
1737             nnimap-request-article-part
1738             nnimap-request-article
1739             nnimap-request-head
1740             nnimap-request-body
1741             nnimap-request-group
1742             nnimap-close-group
1743             nnimap-pattern-to-list-arguments
1744             nnimap-request-list
1745             nnimap-request-post
1746             nnimap-retrieve-groups
1747             nnimap-request-update-info-internal
1748             nnimap-request-type
1749             nnimap-request-set-mark
1750             nnimap-split-to-groups
1751             nnimap-split-find-rule
1752             nnimap-split-find-inbox
1753             nnimap-split-articles
1754             nnimap-request-scan
1755             nnimap-request-newgroups
1756             nnimap-request-create-group
1757             nnimap-time-substract
1758             nnimap-date-days-ago
1759             nnimap-request-expire-articles-progress
1760             nnimap-request-expire-articles
1761             nnimap-request-move-article
1762             nnimap-request-accept-article
1763             nnimap-request-delete-group
1764             nnimap-request-rename-group
1765             gnus-group-nnimap-expunge
1766             gnus-group-nnimap-edit-acl
1767             gnus-group-nnimap-edit-acl-done
1768             nnimap-group-mode-hook
1769             nnimap-mark-to-predicate
1770             nnimap-mark-to-flag-1
1771             nnimap-mark-to-flag
1772             nnimap-mark-permanent-p
1773             )))
1774
1775 (provide 'nnimap)
1776
1777 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1778 ;;; nnimap.el ends here