cgit.sxemacs.org Git - gnus/blob - lisp/nnheader.el

   1 ;;; nnheader.el --- header access macros for Gnus and its backends
   2 ;; Copyright (C) 1987,88,89,90,93,94,95,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; These macros may look very much like the ones in GNUS 4.1.  They
  28 ;; are, in a way, but you should note that the indices they use have
  29 ;; been changed from the internal GNUS format to the NOV format.  The
  30 ;; makes it possible to read headers from XOVER much faster.
  31 ;;
  32 ;; The format of a header is now:
  33 ;; [number subject from date id references chars lines xref]
  34 ;;
  35 ;; (That last entry is defined as "misc" in the NOV format, but Gnus
  36 ;; uses it for xrefs.)
  37
  38 ;;; Code:
  39
  40 (require 'mail-utils)
  41
  42 (defvar nnheader-max-head-length 4096
  43   "*Max length of the head of articles.")
  44
  45 (defvar nnheader-head-chop-length 2048
  46   "*Length of each read operation when trying to fetch HEAD headers.")
  47
  48 (defvar nnheader-file-name-translation-alist nil
  49   "*Alist that says how to translate characters in file names.
  50 For instance, if \":\" is illegal as a file character in file names
  51 on your system, you could say something like:
  52
  53 \(setq nnheader-file-name-translation-alist '((?: . ?_)))")
  54
  55 (eval-and-compile
  56  (autoload 'nnmail-message-id "nnmail")
  57  (autoload 'mail-position-on-field "sendmail")
  58  (autoload 'message-remove-header "message")
  59  (autoload 'cancel-function-timers "timers"))
  60
  61 ;;; Header access macros.
  62
  63 (defmacro mail-header-number (header)
  64   "Return article number in HEADER."
  65   `(aref ,header 0))
  66
  67 (defmacro mail-header-set-number (header number)
  68   "Set article number of HEADER to NUMBER."
  69   `(aset ,header 0 ,number))
  70
  71 (defmacro mail-header-subject (header)
  72   "Return subject string in HEADER."
  73   `(aref ,header 1))
  74
  75 (defmacro mail-header-set-subject (header subject)
  76   "Set article subject of HEADER to SUBJECT."
  77   `(aset ,header 1 ,subject))
  78
  79 (defmacro mail-header-from (header)
  80   "Return author string in HEADER."
  81   `(aref ,header 2))
  82
  83 (defmacro mail-header-set-from (header from)
  84   "Set article author of HEADER to FROM."
  85   `(aset ,header 2 ,from))
  86
  87 (defmacro mail-header-date (header)
  88   "Return date in HEADER."
  89   `(aref ,header 3))
  90
  91 (defmacro mail-header-set-date (header date)
  92   "Set article date of HEADER to DATE."
  93   `(aset ,header 3 ,date))
  94
  95 (defalias 'mail-header-message-id 'mail-header-id)
  96 (defmacro mail-header-id (header)
  97   "Return Id in HEADER."
  98   `(aref ,header 4))
  99
 100 (defalias 'mail-header-set-message-id 'mail-header-set-id)
 101 (defmacro mail-header-set-id (header id)
 102   "Set article Id of HEADER to ID."
 103   `(aset ,header 4 ,id))
 104
 105 (defmacro mail-header-references (header)
 106   "Return references in HEADER."
 107   `(aref ,header 5))
 108
 109 (defmacro mail-header-set-references (header ref)
 110   "Set article references of HEADER to REF."
 111   `(aset ,header 5 ,ref))
 112
 113 (defmacro mail-header-chars (header)
 114   "Return number of chars of article in HEADER."
 115   `(aref ,header 6))
 116
 117 (defmacro mail-header-set-chars (header chars)
 118   "Set number of chars in article of HEADER to CHARS."
 119   `(aset ,header 6 ,chars))
 120
 121 (defmacro mail-header-lines (header)
 122   "Return lines in HEADER."
 123   `(aref ,header 7))
 124
 125 (defmacro mail-header-set-lines (header lines)
 126   "Set article lines of HEADER to LINES."
 127   `(aset ,header 7 ,lines))
 128
 129 (defmacro mail-header-xref (header)
 130   "Return xref string in HEADER."
 131   `(aref ,header 8))
 132
 133 (defmacro mail-header-set-xref (header xref)
 134   "Set article xref of HEADER to xref."
 135   `(aset ,header 8 ,xref))
 136
 137 (defun make-mail-header (&optional init)
 138   "Create a new mail header structure initialized with INIT."
 139   (make-vector 9 init))
 140
 141 (defun make-full-mail-header (&optional number subject from date id
 142                                         references chars lines xref)
 143   "Create a new mail header structure initialized with the parameters given."
 144   (vector number subject from date id references chars lines xref))
 145
 146 ;; fake message-ids: generation and detection
 147
 148 (defvar nnheader-fake-message-id 1)
 149
 150 (defsubst nnheader-generate-fake-message-id ()
 151   (concat "fake+none+" (int-to-string (incf nnheader-fake-message-id))))
 152
 153 (defsubst nnheader-fake-message-id-p (id)
 154   (save-match-data                      ; regular message-id's are <.*>
 155     (string-match "\\`fake\\+none\\+[0-9]+\\'" id)))
 156
 157 ;; Parsing headers and NOV lines.
 158
 159 (defsubst nnheader-header-value ()
 160   (buffer-substring (match-end 0) (gnus-point-at-eol)))
 161
 162 (defun nnheader-parse-head (&optional naked)
 163   (let ((case-fold-search t)
 164         (cur (current-buffer))
 165         (buffer-read-only nil)
 166         in-reply-to lines p)
 167     (goto-char (point-min))
 168     (when naked
 169       (insert "\n"))
 170     ;; Search to the beginning of the next header.  Error messages
 171     ;; do not begin with 2 or 3.
 172     (prog1
 173         (when (or naked (re-search-forward "^[23][0-9]+ " nil t))
 174           ;; This implementation of this function, with nine
 175           ;; search-forwards instead of the one re-search-forward and
 176           ;; a case (which basically was the old function) is actually
 177           ;; about twice as fast, even though it looks messier.  You
 178           ;; can't have everything, I guess.  Speed and elegance
 179           ;; doesn't always go hand in hand.
 180           (vector
 181            ;; Number.
 182            (if naked
 183                (progn
 184                  (setq p (point-min))
 185                  0)
 186              (prog1
 187                  (read cur)
 188                (end-of-line)
 189                (setq p (point))
 190                (narrow-to-region (point)
 191                                  (or (and (search-forward "\n.\n" nil t)
 192                                           (- (point) 2))
 193                                      (point)))))
 194            ;; Subject.
 195            (progn
 196              (goto-char p)
 197              (if (search-forward "\nsubject: " nil t)
 198                  (nnheader-header-value) "(none)"))
 199            ;; From.
 200            (progn
 201              (goto-char p)
 202              (if (search-forward "\nfrom: " nil t)
 203                  (nnheader-header-value) "(nobody)"))
 204            ;; Date.
 205            (progn
 206              (goto-char p)
 207              (if (search-forward "\ndate: " nil t)
 208                  (nnheader-header-value) ""))
 209            ;; Message-ID.
 210            (progn
 211              (goto-char p)
 212              (if (search-forward "\nmessage-id: " nil t)
 213                  (nnheader-header-value)
 214                ;; If there was no message-id, we just fake one to make
 215                ;; subsequent routines simpler.
 216                (nnheader-generate-fake-message-id)))
 217            ;; References.
 218            (progn
 219              (goto-char p)
 220              (if (search-forward "\nreferences: " nil t)
 221                  (nnheader-header-value)
 222                ;; Get the references from the in-reply-to header if there
 223                ;; were no references and the in-reply-to header looks
 224                ;; promising.
 225                (if (and (search-forward "\nin-reply-to: " nil t)
 226                         (setq in-reply-to (nnheader-header-value))
 227                         (string-match "<[^>]+>" in-reply-to))
 228                    (substring in-reply-to (match-beginning 0)
 229                               (match-end 0))
 230                  "")))
 231            ;; Chars.
 232            0
 233            ;; Lines.
 234            (progn
 235              (goto-char p)
 236              (if (search-forward "\nlines: " nil t)
 237                  (if (numberp (setq lines (read cur)))
 238                      lines 0)
 239                0))
 240            ;; Xref.
 241            (progn
 242              (goto-char p)
 243              (and (search-forward "\nxref: " nil t)
 244                   (nnheader-header-value)))))
 245       (when naked
 246         (goto-char (point-min))
 247         (delete-char 1)))))
 248
 249 (defmacro nnheader-nov-skip-field ()
 250   '(search-forward "\t" eol 'move))
 251
 252 (defmacro nnheader-nov-field ()
 253   '(buffer-substring (point) (if (nnheader-nov-skip-field) (1- (point)) eol)))
 254
 255 (defmacro nnheader-nov-read-integer ()
 256   '(prog1
 257        (if (= (following-char) ?\t)
 258            0
 259          (let ((num (ignore-errors (read (current-buffer)))))
 260            (if (numberp num) num 0)))
 261      (or (eobp) (forward-char 1))))
 262
 263 ;; (defvar nnheader-none-counter 0)
 264
 265 (defun nnheader-parse-nov ()
 266   (let ((eol (gnus-point-at-eol)))
 267     (vector
 268      (nnheader-nov-read-integer)        ; number
 269      (nnheader-nov-field)               ; subject
 270      (nnheader-nov-field)               ; from
 271      (nnheader-nov-field)               ; date
 272      (or (nnheader-nov-field)
 273          (nnheader-generate-fake-message-id)) ; id
 274      (nnheader-nov-field)               ; refs
 275      (nnheader-nov-read-integer)        ; chars
 276      (nnheader-nov-read-integer)        ; lines
 277      (if (= (following-char) ?\n)
 278          nil
 279        (nnheader-nov-field))            ; misc
 280      )))
 281
 282 (defun nnheader-insert-nov (header)
 283   (princ (mail-header-number header) (current-buffer))
 284   (insert
 285    "\t"
 286    (or (mail-header-subject header) "(none)") "\t"
 287    (or (mail-header-from header) "(nobody)") "\t"
 288    (or (mail-header-date header) "") "\t"
 289    (or (mail-header-id header)
 290        (nnmail-message-id))
 291    "\t"
 292    (or (mail-header-references header) "") "\t")
 293   (princ (or (mail-header-chars header) 0) (current-buffer))
 294   (insert "\t")
 295   (princ (or (mail-header-lines header) 0) (current-buffer))
 296   (insert "\t")
 297   (when (mail-header-xref header)
 298     (insert "Xref: " (mail-header-xref header) "\t"))
 299   (insert "\n"))
 300
 301 (defun nnheader-insert-article-line (article)
 302   (goto-char (point-min))
 303   (insert "220 ")
 304   (princ article (current-buffer))
 305   (insert " Article retrieved.\n")
 306   (search-forward "\n\n" nil 'move)
 307   (delete-region (point) (point-max))
 308   (forward-char -1)
 309   (insert "."))
 310
 311 (defun nnheader-nov-delete-outside-range (beg end)
 312   "Delete all NOV lines that lie outside the BEG to END range."
 313   ;; First we find the first wanted line.
 314   (nnheader-find-nov-line beg)
 315   (delete-region (point-min) (point))
 316   ;; Then we find the last wanted line.
 317   (when (nnheader-find-nov-line end)
 318     (forward-line 1))
 319   (delete-region (point) (point-max)))
 320
 321 (defun nnheader-find-nov-line (article)
 322   "Put point at the NOV line that start with ARTICLE.
 323 If ARTICLE doesn't exist, put point where that line
 324 would have been.  The function will return non-nil if
 325 the line could be found."
 326   ;; This function basically does a binary search.
 327   (let ((max (point-max))
 328         (min (goto-char (point-min)))
 329         (cur (current-buffer))
 330         (prev (point-min))
 331         num found)
 332     (while (not found)
 333       (goto-char (/ (+ max min) 2))
 334       (beginning-of-line)
 335       (if (or (= (point) prev)
 336               (eobp))
 337           (setq found t)
 338         (setq prev (point))
 339         (cond ((> (setq num (read cur)) article)
 340                (setq max (point)))
 341               ((< num article)
 342                (setq min (point)))
 343               (t
 344                (setq found 'yes)))))
 345     ;; We may be at the first line.
 346     (when (and (not num)
 347                (not (eobp)))
 348       (setq num (read cur)))
 349     ;; Now we may have found the article we're looking for, or we
 350     ;; may be somewhere near it.
 351     (when (and (not (eq found 'yes))
 352                (not (eq num article)))
 353       (setq found (point))
 354       (while (and (< (point) max)
 355                   (or (not (numberp num))
 356                       (< num article)))
 357         (forward-line 1)
 358         (setq found (point))
 359         (or (eobp)
 360             (= (setq num (read cur)) article)))
 361       (unless (eq num article)
 362         (goto-char found)))
 363     (beginning-of-line)
 364     (eq num article)))
 365
 366 ;; Various cruft the backends and Gnus need to communicate.
 367
 368 (defvar nntp-server-buffer nil)
 369 (defvar gnus-verbose-backends 7
 370   "*A number that says how talkative the Gnus backends should be.")
 371 (defvar gnus-nov-is-evil nil
 372   "If non-nil, Gnus backends will never output headers in the NOV format.")
 373 (defvar news-reply-yank-from nil)
 374 (defvar news-reply-yank-message-id nil)
 375
 376 (defvar nnheader-callback-function nil)
 377
 378 (defun nnheader-init-server-buffer ()
 379   "Initialize the Gnus-backend communication buffer."
 380   (save-excursion
 381     (unless (gnus-buffer-live-p nntp-server-buffer)
 382       (setq nntp-server-buffer (get-buffer-create " *nntpd*")))
 383     (set-buffer nntp-server-buffer)
 384     (buffer-disable-undo (current-buffer))
 385     (erase-buffer)
 386     (kill-all-local-variables)
 387     (setq case-fold-search t)           ;Should ignore case.
 388     t))
 389
 390 ;;; Various functions the backends use.
 391
 392 (defun nnheader-file-error (file)
 393   "Return a string that says what is wrong with FILE."
 394   (format
 395    (cond
 396     ((not (file-exists-p file))
 397      "%s does not exist")
 398     ((file-directory-p file)
 399      "%s is a directory")
 400     ((not (file-readable-p file))
 401      "%s is not readable"))
 402    file))
 403
 404 (defun nnheader-insert-head (file)
 405   "Insert the head of the article."
 406   (when (file-exists-p file)
 407     (if (eq nnheader-max-head-length t)
 408         ;; Just read the entire file.
 409         (nnheader-insert-file-contents file)
 410       ;; Read 1K blocks until we find a separator.
 411       (let ((beg 0)
 412             format-alist)
 413         (while (and (eq nnheader-head-chop-length
 414                         (nth 1 (nnheader-insert-file-contents
 415                                 file nil beg
 416                                 (incf beg nnheader-head-chop-length))))
 417                     (prog1 (not (search-forward "\n\n" nil t))
 418                       (goto-char (point-max)))
 419                     (or (null nnheader-max-head-length)
 420                         (< beg nnheader-max-head-length))))))
 421     t))
 422
 423 (defun nnheader-article-p ()
 424   "Say whether the current buffer looks like an article."
 425   (goto-char (point-min))
 426   (if (not (search-forward "\n\n" nil t))
 427       nil
 428     (narrow-to-region (point-min) (1- (point)))
 429     (goto-char (point-min))
 430     (while (looking-at "[A-Z][^ \t]+:.*\n\\([ \t].*\n\\)*\\|From .*\n")
 431       (goto-char (match-end 0)))
 432     (prog1
 433         (eobp)
 434       (widen))))
 435
 436 (defun nnheader-insert-references (references message-id)
 437   "Insert a References header based on REFERENCES and MESSAGE-ID."
 438   (if (and (not references) (not message-id))
 439       ()                                ; This is illegal, but not all articles have Message-IDs.
 440     (mail-position-on-field "References")
 441     (let ((begin (save-excursion (beginning-of-line) (point)))
 442           (fill-column 78)
 443           (fill-prefix "\t"))
 444       (when references
 445         (insert references))
 446       (when (and references message-id)
 447         (insert " "))
 448       (when message-id
 449         (insert message-id))
 450       ;; Fold long References lines to conform to RFC1036 (sort of).
 451       ;; The region must end with a newline to fill the region
 452       ;; without inserting extra newline.
 453       (fill-region-as-paragraph begin (1+ (point))))))
 454
 455 (defun nnheader-replace-header (header new-value)
 456   "Remove HEADER and insert the NEW-VALUE."
 457   (save-excursion
 458     (save-restriction
 459       (nnheader-narrow-to-headers)
 460       (prog1
 461           (message-remove-header header)
 462         (goto-char (point-max))
 463         (insert header ": " new-value "\n")))))
 464
 465 (defun nnheader-narrow-to-headers ()
 466   "Narrow to the head of an article."
 467   (widen)
 468   (narrow-to-region
 469    (goto-char (point-min))
 470    (if (search-forward "\n\n" nil t)
 471        (1- (point))
 472      (point-max)))
 473   (goto-char (point-min)))
 474
 475 (defun nnheader-set-temp-buffer (name &optional noerase)
 476   "Set-buffer to an empty (possibly new) buffer called NAME with undo disabled."
 477   (set-buffer (get-buffer-create name))
 478   (buffer-disable-undo (current-buffer))
 479   (unless noerase
 480     (erase-buffer))
 481   (current-buffer))
 482
 483 (defmacro nnheader-temp-write (file &rest forms)
 484   "Create a new buffer, evaluate FORMS there, and write the buffer to FILE.
 485 Return the value of FORMS.
 486 If FILE is nil, just evaluate FORMS and don't save anything.
 487 If FILE is t, return the buffer contents as a string."
 488   (let ((temp-file (make-symbol "temp-file"))
 489         (temp-buffer (make-symbol "temp-buffer"))
 490         (temp-results (make-symbol "temp-results")))
 491     `(save-excursion
 492        (let* ((,temp-file ,file)
 493               (default-major-mode 'fundamental-mode)
 494               (,temp-buffer
 495                (set-buffer
 496                 (get-buffer-create
 497                  (generate-new-buffer-name " *nnheader temp*"))))
 498               ,temp-results)
 499          (unwind-protect
 500              (progn
 501                (setq ,temp-results (progn ,@forms))
 502                (cond
 503                 ;; Don't save anything.
 504                 ((null ,temp-file)
 505                  ,temp-results)
 506                 ;; Return the buffer contents.
 507                 ((eq ,temp-file t)
 508                  (set-buffer ,temp-buffer)
 509                  (buffer-string))
 510                 ;; Save a file.
 511                 (t
 512                  (set-buffer ,temp-buffer)
 513                  ;; Make sure the directory where this file is
 514                  ;; to be saved exists.
 515                  (when (not (file-directory-p
 516                              (file-name-directory ,temp-file)))
 517                    (make-directory (file-name-directory ,temp-file) t))
 518                  ;; Save the file.
 519                  (write-region (point-min) (point-max)
 520                                ,temp-file nil 'nomesg)
 521                  ,temp-results)))
 522            ;; Kill the buffer.
 523            (when (buffer-name ,temp-buffer)
 524              (kill-buffer ,temp-buffer)))))))
 525
 526 (put 'nnheader-temp-write 'lisp-indent-function 1)
 527 (put 'nnheader-temp-write 'edebug-form-spec '(form body))
 528
 529 (defvar jka-compr-compression-info-list)
 530 (defvar nnheader-numerical-files
 531   (if (boundp 'jka-compr-compression-info-list)
 532       (concat "\\([0-9]+\\)\\("
 533               (mapconcat (lambda (i) (aref i 0))
 534                          jka-compr-compression-info-list "\\|")
 535               "\\)?")
 536     "[0-9]+$")
 537   "Regexp that match numerical files.")
 538
 539 (defvar nnheader-numerical-short-files (concat "^" nnheader-numerical-files)
 540   "Regexp that matches numerical file names.")
 541
 542 (defvar nnheader-numerical-full-files (concat "/" nnheader-numerical-files)
 543   "Regexp that matches numerical full file paths.")
 544
 545 (defsubst nnheader-file-to-number (file)
 546   "Take a file name and return the article number."
 547   (if (not (boundp 'jka-compr-compression-info-list))
 548       (string-to-int file)
 549     (string-match nnheader-numerical-short-files file)
 550     (string-to-int (match-string 0 file))))
 551
 552 (defun nnheader-directory-files-safe (&rest args)
 553   ;; It has been reported numerous times that `directory-files'
 554   ;; fails with an alarming frequency on NFS mounted file systems.
 555   ;; This function executes that function twice and returns
 556   ;; the longest result.
 557   (let ((first (apply 'directory-files args))
 558         (second (apply 'directory-files args)))
 559     (if (> (length first) (length second))
 560         first
 561       second)))
 562
 563 (defun nnheader-directory-articles (dir)
 564   "Return a list of all article files in a directory."
 565   (mapcar 'nnheader-file-to-number
 566           (nnheader-directory-files-safe
 567            dir nil nnheader-numerical-short-files t)))
 568
 569 (defun nnheader-article-to-file-alist (dir)
 570   "Return an alist of article/file pairs in DIR."
 571   (mapcar (lambda (file) (cons (nnheader-file-to-number file) file))
 572           (nnheader-directory-files-safe
 573            dir nil nnheader-numerical-short-files t)))
 574
 575 (defun nnheader-fold-continuation-lines ()
 576   "Fold continuation lines in the current buffer."
 577   (nnheader-replace-regexp "\\(\r?\n[ \t]+\\)+" " "))
 578
 579 (defun nnheader-translate-file-chars (file)
 580   (if (null nnheader-file-name-translation-alist)
 581       ;; No translation is necessary.
 582       file
 583     ;; We translate -- but only the file name.  We leave the directory
 584     ;; alone.
 585     (let* ((i 0)
 586            trans leaf path len)
 587       (if (string-match "/[^/]+\\'" file)
 588           ;; This is needed on NT's and stuff.
 589           (setq leaf (substring file (1+ (match-beginning 0)))
 590                 path (substring file 0 (1+ (match-beginning 0))))
 591         ;; Fall back on this.
 592         (setq leaf (file-name-nondirectory file)
 593               path (file-name-directory file)))
 594       (setq len (length leaf))
 595       (while (< i len)
 596         (when (setq trans (cdr (assq (aref leaf i)
 597                                      nnheader-file-name-translation-alist)))
 598           (aset leaf i trans))
 599         (incf i))
 600       (concat path leaf))))
 601
 602 (defun nnheader-report (backend &rest args)
 603   "Report an error from the BACKEND.
 604 The first string in ARGS can be a format string."
 605   (set (intern (format "%s-status-string" backend))
 606        (if (< (length args) 2)
 607            (car args)
 608          (apply 'format args)))
 609   nil)
 610
 611 (defun nnheader-get-report (backend)
 612   "Get the most recent report from BACKEND."
 613   (condition-case ()
 614       (message "%s" (symbol-value (intern (format "%s-status-string"
 615                                                   backend))))
 616     (error (message ""))))
 617
 618 (defun nnheader-insert (format &rest args)
 619   "Clear the communication buffer and insert FORMAT and ARGS into the buffer.
 620 If FORMAT isn't a format string, it and all ARGS will be inserted
 621 without formatting."
 622   (save-excursion
 623     (set-buffer nntp-server-buffer)
 624     (erase-buffer)
 625     (if (string-match "%" format)
 626         (insert (apply 'format format args))
 627       (apply 'insert format args))
 628     t))
 629
 630 (defun nnheader-mail-file-mbox-p (file)
 631   "Say whether FILE looks like an Unix mbox file."
 632   (when (and (file-exists-p file)
 633              (file-readable-p file)
 634              (file-regular-p file))
 635     (save-excursion
 636       (nnheader-set-temp-buffer " *mail-file-mbox-p*")
 637       (nnheader-insert-file-contents file)
 638       (goto-char (point-min))
 639       (prog1
 640           (looking-at message-unix-mail-delimiter)
 641         (kill-buffer (current-buffer))))))
 642
 643 (defun nnheader-replace-chars-in-string (string from to)
 644   "Replace characters in STRING from FROM to TO."
 645   (let ((string (substring string 0))   ;Copy string.
 646         (len (length string))
 647         (idx 0))
 648     ;; Replace all occurrences of FROM with TO.
 649     (while (< idx len)
 650       (when (= (aref string idx) from)
 651         (aset string idx to))
 652       (setq idx (1+ idx)))
 653     string))
 654
 655 (defun nnheader-file-to-group (file &optional top)
 656   "Return a group name based on FILE and TOP."
 657   (nnheader-replace-chars-in-string
 658    (if (not top)
 659        file
 660      (condition-case ()
 661          (substring (expand-file-name file)
 662                     (length
 663                      (expand-file-name
 664                       (file-name-as-directory top))))
 665        (error "")))
 666    ?/ ?.))
 667
 668 (defun nnheader-message (level &rest args)
 669   "Message if the Gnus backends are talkative."
 670   (if (or (not (numberp gnus-verbose-backends))
 671           (<= level gnus-verbose-backends))
 672       (apply 'message args)
 673     (apply 'format args)))
 674
 675 (defun nnheader-be-verbose (level)
 676   "Return whether the backends should be verbose on LEVEL."
 677   (or (not (numberp gnus-verbose-backends))
 678       (<= level gnus-verbose-backends)))
 679
 680 (defun nnheader-group-pathname (group dir &optional file)
 681   "Make pathname for GROUP."
 682   (concat
 683    (let ((dir (file-name-as-directory (expand-file-name dir))))
 684      ;; If this directory exists, we use it directly.
 685      (if (file-directory-p (concat dir group))
 686          (concat dir group "/")
 687        ;; If not, we translate dots into slashes.
 688        (concat dir (nnheader-replace-chars-in-string group ?. ?/) "/")))
 689    (cond ((null file) "")
 690          ((numberp file) (int-to-string file))
 691          (t file))))
 692
 693 (defun nnheader-functionp (form)
 694   "Return non-nil if FORM is funcallable."
 695   (or (and (symbolp form) (fboundp form))
 696       (and (listp form) (eq (car form) 'lambda))))
 697
 698 (defun nnheader-concat (dir &rest files)
 699   "Concat DIR as directory to FILE."
 700   (apply 'concat (file-name-as-directory dir) files))
 701
 702 (defun nnheader-ms-strip-cr ()
 703   "Strip ^M from the end of all lines."
 704   (save-excursion
 705     (goto-char (point-min))
 706     (while (re-search-forward "\r$" nil t)
 707       (delete-backward-char 1))))
 708
 709 (defun nnheader-file-size (file)
 710   "Return the file size of FILE or 0."
 711   (or (nth 7 (file-attributes file)) 0))
 712
 713 (defun nnheader-find-etc-directory (package &optional file)
 714   "Go through the path and find the \".../etc/PACKAGE\" directory.
 715 If FILE, find the \".../etc/PACKAGE\" file instead."
 716   (let ((path load-path)
 717         dir result)
 718     ;; We try to find the dir by looking at the load path,
 719     ;; stripping away the last component and adding "etc/".
 720     (while path
 721       (if (and (car path)
 722                (file-exists-p
 723                 (setq dir (concat
 724                            (file-name-directory
 725                             (directory-file-name (car path)))
 726                            "etc/" package
 727                            (if file "" "/"))))
 728                (or file (file-directory-p dir)))
 729           (setq result dir
 730                 path nil)
 731         (setq path (cdr path))))
 732     result))
 733
 734 (defvar ange-ftp-path-format)
 735 (defvar efs-path-regexp)
 736 (defun nnheader-re-read-dir (path)
 737   "Re-read directory PATH if PATH is on a remote system."
 738   (if (and (fboundp 'efs-re-read-dir) (boundp 'efs-path-regexp))
 739       (when (string-match efs-path-regexp path)
 740         (efs-re-read-dir path))
 741     (when (and (fboundp 'ange-ftp-re-read-dir) (boundp 'ange-ftp-path-format))
 742       (when (string-match (car ange-ftp-path-format) path)
 743         (ange-ftp-re-read-dir path)))))
 744
 745 (defun nnheader-insert-file-contents (filename &optional visit beg end replace)
 746   "Like `insert-file-contents', q.v., but only reads in the file.
 747 A buffer may be modified in several ways after reading into the buffer due
 748 to advanced Emacs features, such as file-name-handlers, format decoding,
 749 find-file-hooks, etc.
 750   This function ensures that none of these modifications will take place."
 751   (let ((format-alist nil)
 752         (auto-mode-alist (nnheader-auto-mode-alist))
 753         (default-major-mode 'fundamental-mode)
 754         (after-insert-file-functions nil))
 755     (insert-file-contents filename visit beg end replace)))
 756
 757 (defun nnheader-find-file-noselect (&rest args)
 758   (let ((format-alist nil)
 759         (auto-mode-alist (nnheader-auto-mode-alist))
 760         (default-major-mode 'fundamental-mode)
 761         (enable-local-variables nil)
 762         (after-insert-file-functions nil))
 763     (apply 'find-file-noselect args)))
 764
 765 (defun nnheader-auto-mode-alist ()
 766   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 767   (let ((alist auto-mode-alist)
 768         out)
 769     (while alist
 770       (when (listp (cdar alist))
 771         (push (car alist) out))
 772       (pop alist))
 773     (nreverse out)))
 774
 775 (defun nnheader-directory-regular-files (dir)
 776   "Return a list of all regular files in DIR."
 777   (let ((files (directory-files dir t))
 778         out)
 779     (while files
 780       (when (file-regular-p (car files))
 781         (push (car files) out))
 782       (pop files))
 783     (nreverse out)))
 784
 785 (defmacro nnheader-skeleton-replace (from &optional to regexp)
 786   `(let ((new (generate-new-buffer " *nnheader replace*"))
 787          (cur (current-buffer))
 788          (start (point-min)))
 789      (set-buffer new)
 790      (buffer-disable-undo (current-buffer))
 791      (set-buffer cur)
 792      (goto-char (point-min))
 793      (while (,(if regexp 're-search-forward 'search-forward)
 794              ,from nil t)
 795        (insert-buffer-substring
 796         cur start (prog1 (match-beginning 0) (set-buffer new)))
 797        (goto-char (point-max))
 798        ,(when to `(insert ,to))
 799        (set-buffer cur)
 800        (setq start (point)))
 801      (insert-buffer-substring
 802       cur start (prog1 (point-max) (set-buffer new)))
 803      (copy-to-buffer cur (point-min) (point-max))
 804      (kill-buffer (current-buffer))
 805      (set-buffer cur)))
 806
 807 (defun nnheader-replace-string (from to)
 808   "Do a fast replacement of FROM to TO from point to point-max."
 809   (nnheader-skeleton-replace from to))
 810
 811 (defun nnheader-replace-regexp (from to)
 812   "Do a fast regexp replacement of FROM to TO from point to point-max."
 813   (nnheader-skeleton-replace from to t))
 814
 815 (defun nnheader-strip-cr ()
 816   "Strip all \r's from the current buffer."
 817   (nnheader-skeleton-replace "\r"))
 818
 819 (fset 'nnheader-run-at-time 'run-at-time)
 820 (fset 'nnheader-cancel-timer 'cancel-timer)
 821 (fset 'nnheader-cancel-function-timers 'cancel-function-timers)
 822
 823 (when (string-match "XEmacs\\|Lucid" emacs-version)
 824   (require 'nnheaderxm))
 825
 826 (run-hooks 'nnheader-load-hook)
 827
 828 (provide 'nnheader)
 829
 830 ;;; nnheader.el ends here