cgit.sxemacs.org Git - gnus/blob - lisp/nnheader.el

   1 ;;; nnheader.el --- header access macros for Gnus and its backends
   2
   3 ;; Copyright (C) 1987, 1988, 1989, 1990, 1993, 1994, 1995, 1996,
   4 ;;        1997, 1998, 2000
   5 ;;        Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (require 'mail-utils)
  35 (require 'mm-util)
  36
  37 (defvar nnheader-max-head-length 4096
  38   "*Max length of the head of articles.")
  39
  40 (defvar nnheader-head-chop-length 2048
  41   "*Length of each read operation when trying to fetch HEAD headers.")
  42
  43 (defvar nnheader-file-name-translation-alist nil
  44   "*Alist that says how to translate characters in file names.
  45 For instance, if \":\" is invalid as a file character in file names
  46 on your system, you could say something like:
  47
  48 \(setq nnheader-file-name-translation-alist '((?: . ?_)))")
  49
  50 (eval-and-compile
  51   (autoload 'nnmail-message-id "nnmail")
  52   (autoload 'mail-position-on-field "sendmail")
  53   (autoload 'message-remove-header "message")
  54   (autoload 'gnus-point-at-eol "gnus-util")
  55   (autoload 'gnus-delete-line "gnus-util")
  56   (autoload 'gnus-buffer-live-p "gnus-util"))
  57
  58 ;;; Header access macros.
  59
  60 ;; These macros may look very much like the ones in GNUS 4.1.  They
  61 ;; are, in a way, but you should note that the indices they use have
  62 ;; been changed from the internal GNUS format to the NOV format.  The
  63 ;; makes it possible to read headers from XOVER much faster.
  64 ;;
  65 ;; The format of a header is now:
  66 ;; [number subject from date id references chars lines xref extra]
  67 ;;
  68 ;; (That next-to-last entry is defined as "misc" in the NOV format,
  69 ;; but Gnus uses it for xrefs.)
  70
  71 (defmacro mail-header-number (header)
  72   "Return article number in HEADER."
  73   `(aref ,header 0))
  74
  75 (defmacro mail-header-set-number (header number)
  76   "Set article number of HEADER to NUMBER."
  77   `(aset ,header 0 ,number))
  78
  79 (defmacro mail-header-subject (header)
  80   "Return subject string in HEADER."
  81   `(aref ,header 1))
  82
  83 (defmacro mail-header-set-subject (header subject)
  84   "Set article subject of HEADER to SUBJECT."
  85   `(aset ,header 1 ,subject))
  86
  87 (defmacro mail-header-from (header)
  88   "Return author string in HEADER."
  89   `(aref ,header 2))
  90
  91 (defmacro mail-header-set-from (header from)
  92   "Set article author of HEADER to FROM."
  93   `(aset ,header 2 ,from))
  94
  95 (defmacro mail-header-date (header)
  96   "Return date in HEADER."
  97   `(aref ,header 3))
  98
  99 (defmacro mail-header-set-date (header date)
 100   "Set article date of HEADER to DATE."
 101   `(aset ,header 3 ,date))
 102
 103 (defalias 'mail-header-message-id 'mail-header-id)
 104 (defmacro mail-header-id (header)
 105   "Return Id in HEADER."
 106   `(aref ,header 4))
 107
 108 (defalias 'mail-header-set-message-id 'mail-header-set-id)
 109 (defmacro mail-header-set-id (header id)
 110   "Set article Id of HEADER to ID."
 111   `(aset ,header 4 ,id))
 112
 113 (defmacro mail-header-references (header)
 114   "Return references in HEADER."
 115   `(aref ,header 5))
 116
 117 (defmacro mail-header-set-references (header ref)
 118   "Set article references of HEADER to REF."
 119   `(aset ,header 5 ,ref))
 120
 121 (defmacro mail-header-chars (header)
 122   "Return number of chars of article in HEADER."
 123   `(aref ,header 6))
 124
 125 (defmacro mail-header-set-chars (header chars)
 126   "Set number of chars in article of HEADER to CHARS."
 127   `(aset ,header 6 ,chars))
 128
 129 (defmacro mail-header-lines (header)
 130   "Return lines in HEADER."
 131   `(aref ,header 7))
 132
 133 (defmacro mail-header-set-lines (header lines)
 134   "Set article lines of HEADER to LINES."
 135   `(aset ,header 7 ,lines))
 136
 137 (defmacro mail-header-xref (header)
 138   "Return xref string in HEADER."
 139   `(aref ,header 8))
 140
 141 (defmacro mail-header-set-xref (header xref)
 142   "Set article xref of HEADER to xref."
 143   `(aset ,header 8 ,xref))
 144
 145 (defmacro mail-header-extra (header)
 146   "Return the extra headers in HEADER."
 147   `(aref ,header 9))
 148
 149 (defmacro mail-header-set-extra (header extra)
 150   "Set the extra headers in HEADER to EXTRA."
 151   `(aset ,header 9 ',extra))
 152
 153 (defsubst make-mail-header (&optional init)
 154   "Create a new mail header structure initialized with INIT."
 155   (make-vector 10 init))
 156
 157 (defsubst make-full-mail-header (&optional number subject from date id
 158                                            references chars lines xref
 159                                            extra)
 160   "Create a new mail header structure initialized with the parameters given."
 161   (vector number subject from date id references chars lines xref extra))
 162
 163 ;; fake message-ids: generation and detection
 164
 165 (defvar nnheader-fake-message-id 1)
 166
 167 (defsubst nnheader-generate-fake-message-id ()
 168   (concat "fake+none+" (int-to-string (incf nnheader-fake-message-id))))
 169
 170 (defsubst nnheader-fake-message-id-p (id)
 171   (save-match-data                      ; regular message-id's are <.*>
 172     (string-match "\\`fake\\+none\\+[0-9]+\\'" id)))
 173
 174 ;; Parsing headers and NOV lines.
 175
 176 (defsubst nnheader-header-value ()
 177   (buffer-substring (match-end 0) (gnus-point-at-eol)))
 178
 179 (defun nnheader-parse-head (&optional naked)
 180   (let ((case-fold-search t)
 181         (cur (current-buffer))
 182         (buffer-read-only nil)
 183         in-reply-to lines p ref)
 184     (goto-char (point-min))
 185     (when naked
 186       (insert "\n"))
 187     ;; Search to the beginning of the next header.  Error messages
 188     ;; do not begin with 2 or 3.
 189     (prog1
 190         (when (or naked (re-search-forward "^[23][0-9]+ " nil t))
 191           ;; This implementation of this function, with nine
 192           ;; search-forwards instead of the one re-search-forward and
 193           ;; a case (which basically was the old function) is actually
 194           ;; about twice as fast, even though it looks messier.  You
 195           ;; can't have everything, I guess.  Speed and elegance
 196           ;; don't always go hand in hand.
 197           (vector
 198            ;; Number.
 199            (if naked
 200                (progn
 201                  (setq p (point-min))
 202                  0)
 203              (prog1
 204                  (read cur)
 205                (end-of-line)
 206                (setq p (point))
 207                (narrow-to-region (point)
 208                                  (or (and (search-forward "\n.\n" nil t)
 209                                           (- (point) 2))
 210                                      (point)))))
 211            ;; Subject.
 212            (progn
 213              (goto-char p)
 214              (if (search-forward "\nsubject: " nil t)
 215                  (nnheader-header-value) "(none)"))
 216            ;; From.
 217            (progn
 218              (goto-char p)
 219              (if (search-forward "\nfrom: " nil t)
 220                  (nnheader-header-value) "(nobody)"))
 221            ;; Date.
 222            (progn
 223              (goto-char p)
 224              (if (search-forward "\ndate: " nil t)
 225                  (nnheader-header-value) ""))
 226            ;; Message-ID.
 227            (progn
 228              (goto-char p)
 229              (if (search-forward "\nmessage-id:" nil t)
 230                  (buffer-substring
 231                   (1- (or (search-forward "<" (gnus-point-at-eol) t)
 232                           (point)))
 233                   (or (search-forward ">" (gnus-point-at-eol) t) (point)))
 234                ;; If there was no message-id, we just fake one to make
 235                ;; subsequent routines simpler.
 236                (nnheader-generate-fake-message-id)))
 237            ;; References.
 238            (progn
 239              (goto-char p)
 240              (if (search-forward "\nreferences: " nil t)
 241                  (nnheader-header-value)
 242                ;; Get the references from the in-reply-to header if there
 243                ;; were no references and the in-reply-to header looks
 244                ;; promising.
 245                (if (and (search-forward "\nin-reply-to: " nil t)
 246                         (setq in-reply-to (nnheader-header-value))
 247                         (string-match "<[^\n>]+>" in-reply-to))
 248                    (let (ref2)
 249                      (setq ref (substring in-reply-to (match-beginning 0)
 250                                           (match-end 0)))
 251                      (while (string-match "<[^\n>]+>"
 252                                           in-reply-to (match-end 0))
 253                        (setq ref2 (substring in-reply-to (match-beginning 0)
 254                                              (match-end 0)))
 255                        (when (> (length ref2) (length ref))
 256                          (setq ref ref2)))
 257                      ref)
 258                  nil)))
 259            ;; Chars.
 260            0
 261            ;; Lines.
 262            (progn
 263              (goto-char p)
 264              (if (search-forward "\nlines: " nil t)
 265                  (if (numberp (setq lines (read cur)))
 266                      lines 0)
 267                0))
 268            ;; Xref.
 269            (progn
 270              (goto-char p)
 271              (and (search-forward "\nxref: " nil t)
 272                   (nnheader-header-value)))
 273
 274            ;; Extra.
 275            (when nnmail-extra-headers
 276              (let ((extra nnmail-extra-headers)
 277                    out)
 278                (while extra
 279                  (goto-char p)
 280                  (when (search-forward
 281                         (concat "\n" (symbol-name (car extra)) ": ") nil t)
 282                    (push (cons (car extra) (nnheader-header-value))
 283                          out))
 284                  (pop extra))
 285                out))))
 286       (when naked
 287         (goto-char (point-min))
 288         (delete-char 1)))))
 289
 290 (defmacro nnheader-nov-skip-field ()
 291   '(search-forward "\t" eol 'move))
 292
 293 (defmacro nnheader-nov-field ()
 294   '(buffer-substring (point) (if (nnheader-nov-skip-field) (1- (point)) eol)))
 295
 296 (defmacro nnheader-nov-read-integer ()
 297   '(prog1
 298        (if (eq (char-after) ?\t)
 299            0
 300          (let ((num (condition-case nil
 301                         (read (current-buffer))
 302                       (error nil))))
 303            (if (numberp num) num 0)))
 304      (or (eobp) (forward-char 1))))
 305
 306 (defmacro nnheader-nov-parse-extra ()
 307   '(let (out string)
 308      (while (not (memq (char-after) '(?\n nil)))
 309        (setq string (nnheader-nov-field))
 310        (when (string-match "^\\([^ :]+\\): " string)
 311          (push (cons (intern (match-string 1 string))
 312                      (substring string (match-end 0)))
 313                out)))
 314      out))
 315
 316 (defmacro nnheader-nov-read-message-id ()
 317   '(let ((id (nnheader-nov-field)))
 318      (if (string-match "^<[^>]+>$" id)
 319          id
 320        (nnheader-generate-fake-message-id))))
 321
 322 (defun nnheader-parse-nov ()
 323   (let ((eol (gnus-point-at-eol)))
 324     (vector
 325      (nnheader-nov-read-integer)        ; number
 326      (nnheader-nov-field)               ; subject
 327      (nnheader-nov-field)               ; from
 328      (nnheader-nov-field)               ; date
 329      (nnheader-nov-read-message-id)     ; id
 330      (nnheader-nov-field)               ; refs
 331      (nnheader-nov-read-integer)        ; chars
 332      (nnheader-nov-read-integer)        ; lines
 333      (if (eq (char-after) ?\n)
 334          nil
 335        (nnheader-nov-field))            ; misc
 336      (nnheader-nov-parse-extra))))      ; extra
 337
 338 (defun nnheader-insert-nov (header)
 339   (princ (mail-header-number header) (current-buffer))
 340   (let ((p (point)))
 341     (insert
 342      "\t"
 343      (or (mail-header-subject header) "(none)") "\t"
 344      (or (mail-header-from header) "(nobody)") "\t"
 345      (or (mail-header-date header) "") "\t"
 346      (or (mail-header-id header)
 347          (nnmail-message-id))
 348      "\t"
 349      (or (mail-header-references header) "") "\t")
 350     (princ (or (mail-header-chars header) 0) (current-buffer))
 351     (insert "\t")
 352     (princ (or (mail-header-lines header) 0) (current-buffer))
 353     (insert "\t")
 354     (when (mail-header-xref header)
 355       (insert "Xref: " (mail-header-xref header)))
 356     (when (or (mail-header-xref header)
 357               (mail-header-extra header))
 358       (insert "\t"))
 359     (when (mail-header-extra header)
 360       (let ((extra (mail-header-extra header)))
 361         (while extra
 362           (insert (symbol-name (caar extra))
 363                   ": " (cdar extra) "\t")
 364           (pop extra))))
 365     (insert "\n")
 366     (backward-char 1)
 367     (while (search-backward "\n" p t)
 368       (delete-char 1))
 369     (forward-line 1)))
 370
 371 (defun nnheader-insert-header (header)
 372   (insert
 373    "Subject: " (or (mail-header-subject header) "(none)") "\n"
 374    "From: " (or (mail-header-from header) "(nobody)") "\n"
 375    "Date: " (or (mail-header-date header) "") "\n"
 376    "Message-ID: " (or (mail-header-id header) (nnmail-message-id)) "\n"
 377    "References: " (or (mail-header-references header) "") "\n"
 378    "Lines: ")
 379   (princ (or (mail-header-lines header) 0) (current-buffer))
 380   (insert "\n\n"))
 381
 382 (defun nnheader-insert-article-line (article)
 383   (goto-char (point-min))
 384   (insert "220 ")
 385   (princ article (current-buffer))
 386   (insert " Article retrieved.\n")
 387   (search-forward "\n\n" nil 'move)
 388   (delete-region (point) (point-max))
 389   (forward-char -1)
 390   (insert "."))
 391
 392 (defun nnheader-nov-delete-outside-range (beg end)
 393   "Delete all NOV lines that lie outside the BEG to END range."
 394   ;; First we find the first wanted line.
 395   (nnheader-find-nov-line beg)
 396   (delete-region (point-min) (point))
 397   ;; Then we find the last wanted line.
 398   (when (nnheader-find-nov-line end)
 399     (forward-line 1))
 400   (delete-region (point) (point-max)))
 401
 402 (defun nnheader-find-nov-line (article)
 403   "Put point at the NOV line that start with ARTICLE.
 404 If ARTICLE doesn't exist, put point where that line
 405 would have been.  The function will return non-nil if
 406 the line could be found."
 407   ;; This function basically does a binary search.
 408   (let ((max (point-max))
 409         (min (goto-char (point-min)))
 410         (cur (current-buffer))
 411         (prev (point-min))
 412         num found)
 413     (while (not found)
 414       (goto-char (/ (+ max min) 2))
 415       (beginning-of-line)
 416       (if (or (= (point) prev)
 417               (eobp))
 418           (setq found t)
 419         (setq prev (point))
 420         (while (and (not (numberp (setq num (read cur))))
 421                     (not (eobp)))
 422           (gnus-delete-line))
 423         (cond ((> num article)
 424                (setq max (point)))
 425               ((< num article)
 426                (setq min (point)))
 427               (t
 428                (setq found 'yes)))))
 429     ;; We may be at the first line.
 430     (when (and (not num)
 431                (not (eobp)))
 432       (setq num (read cur)))
 433     ;; Now we may have found the article we're looking for, or we
 434     ;; may be somewhere near it.
 435     (when (and (not (eq found 'yes))
 436                (not (eq num article)))
 437       (setq found (point))
 438       (while (and (< (point) max)
 439                   (or (not (numberp num))
 440                       (< num article)))
 441         (forward-line 1)
 442         (setq found (point))
 443         (or (eobp)
 444             (= (setq num (read cur)) article)))
 445       (unless (eq num article)
 446         (goto-char found)))
 447     (beginning-of-line)
 448     (eq num article)))
 449
 450 ;; Various cruft the backends and Gnus need to communicate.
 451
 452 (defvar nntp-server-buffer nil)
 453 (defvar gnus-verbose-backends 7
 454   "*A number that says how talkative the Gnus backends should be.")
 455 (defvar gnus-nov-is-evil nil
 456   "If non-nil, Gnus backends will never output headers in the NOV format.")
 457 (defvar news-reply-yank-from nil)
 458 (defvar news-reply-yank-message-id nil)
 459
 460 (defvar nnheader-callback-function nil)
 461
 462 (defun nnheader-init-server-buffer ()
 463   "Initialize the Gnus-backend communication buffer."
 464   (save-excursion
 465     (unless (gnus-buffer-live-p nntp-server-buffer)
 466       (setq nntp-server-buffer (get-buffer-create " *nntpd*")))
 467     (mm-enable-multibyte)
 468     (set-buffer nntp-server-buffer)
 469     (erase-buffer)
 470     (kill-all-local-variables)
 471     (setq case-fold-search t)           ;Should ignore case.
 472     t))
 473
 474 ;;; Various functions the backends use.
 475
 476 (defun nnheader-file-error (file)
 477   "Return a string that says what is wrong with FILE."
 478   (format
 479    (cond
 480     ((not (file-exists-p file))
 481      "%s does not exist")
 482     ((file-directory-p file)
 483      "%s is a directory")
 484     ((not (file-readable-p file))
 485      "%s is not readable"))
 486    file))
 487
 488 (defun nnheader-insert-head (file)
 489   "Insert the head of the article."
 490   (when (file-exists-p file)
 491     (if (eq nnheader-max-head-length t)
 492         ;; Just read the entire file.
 493         (nnheader-insert-file-contents file)
 494       ;; Read 1K blocks until we find a separator.
 495       (let ((beg 0)
 496             format-alist)
 497         (while (and (eq nnheader-head-chop-length
 498                         (nth 1 (nnheader-insert-file-contents
 499                                 file nil beg
 500                                 (incf beg nnheader-head-chop-length))))
 501                     (prog1 (not (search-forward "\n\n" nil t))
 502                       (goto-char (point-max)))
 503                     (or (null nnheader-max-head-length)
 504                         (< beg nnheader-max-head-length))))))
 505     t))
 506
 507 (defun nnheader-article-p ()
 508   "Say whether the current buffer looks like an article."
 509   (goto-char (point-min))
 510   (if (not (search-forward "\n\n" nil t))
 511       nil
 512     (narrow-to-region (point-min) (1- (point)))
 513     (goto-char (point-min))
 514     (while (looking-at "[a-zA-Z][^ \t]+:.*\n\\([ \t].*\n\\)*\\|From .*\n")
 515       (goto-char (match-end 0)))
 516     (prog1
 517         (eobp)
 518       (widen))))
 519
 520 (defun nnheader-insert-references (references message-id)
 521   "Insert a References header based on REFERENCES and MESSAGE-ID."
 522   (if (and (not references) (not message-id))
 523       ;; This is invalid, but not all articles have Message-IDs.
 524       ()
 525     (mail-position-on-field "References")
 526     (let ((begin (save-excursion (beginning-of-line) (point)))
 527           (fill-column 78)
 528           (fill-prefix "\t"))
 529       (when references
 530         (insert references))
 531       (when (and references message-id)
 532         (insert " "))
 533       (when message-id
 534         (insert message-id))
 535       ;; Fold long References lines to conform to RFC1036 (sort of).
 536       ;; The region must end with a newline to fill the region
 537       ;; without inserting extra newline.
 538       (fill-region-as-paragraph begin (1+ (point))))))
 539
 540 (defun nnheader-replace-header (header new-value)
 541   "Remove HEADER and insert the NEW-VALUE."
 542   (save-excursion
 543     (save-restriction
 544       (nnheader-narrow-to-headers)
 545       (prog1
 546           (message-remove-header header)
 547         (goto-char (point-max))
 548         (insert header ": " new-value "\n")))))
 549
 550 (defun nnheader-narrow-to-headers ()
 551   "Narrow to the head of an article."
 552   (widen)
 553   (narrow-to-region
 554    (goto-char (point-min))
 555    (if (search-forward "\n\n" nil t)
 556        (1- (point))
 557      (point-max)))
 558   (goto-char (point-min)))
 559
 560 (defun nnheader-set-temp-buffer (name &optional noerase)
 561   "Set-buffer to an empty (possibly new) buffer called NAME with undo disabled."
 562   (set-buffer (get-buffer-create name))
 563   (buffer-disable-undo)
 564   (unless noerase
 565     (erase-buffer))
 566   (current-buffer))
 567
 568 (eval-when-compile (defvar jka-compr-compression-info-list))
 569 (defvar nnheader-numerical-files
 570   (if (boundp 'jka-compr-compression-info-list)
 571       (concat "\\([0-9]+\\)\\("
 572               (mapconcat (lambda (i) (aref i 0))
 573                          jka-compr-compression-info-list "\\|")
 574               "\\)?")
 575     "[0-9]+$")
 576   "Regexp that match numerical files.")
 577
 578 (defvar nnheader-numerical-short-files (concat "^" nnheader-numerical-files)
 579   "Regexp that matches numerical file names.")
 580
 581 (defvar nnheader-numerical-full-files (concat "/" nnheader-numerical-files)
 582   "Regexp that matches numerical full file paths.")
 583
 584 (defsubst nnheader-file-to-number (file)
 585   "Take a file name and return the article number."
 586   (if (string= nnheader-numerical-short-files "^[0-9]+$")
 587       (string-to-int file)
 588     (string-match nnheader-numerical-short-files file)
 589     (string-to-int (match-string 0 file))))
 590
 591 (defun nnheader-directory-files-safe (&rest args)
 592   ;; It has been reported numerous times that `directory-files'
 593   ;; fails with an alarming frequency on NFS mounted file systems.
 594   ;; This function executes that function twice and returns
 595   ;; the longest result.
 596   (let ((first (apply 'directory-files args))
 597         (second (apply 'directory-files args)))
 598     (if (> (length first) (length second))
 599         first
 600       second)))
 601
 602 (defun nnheader-directory-articles (dir)
 603   "Return a list of all article files in a directory."
 604   (mapcar 'nnheader-file-to-number
 605           (nnheader-directory-files-safe
 606            dir nil nnheader-numerical-short-files t)))
 607
 608 (defun nnheader-article-to-file-alist (dir)
 609   "Return an alist of article/file pairs in DIR."
 610   (mapcar (lambda (file) (cons (nnheader-file-to-number file) file))
 611           (nnheader-directory-files-safe
 612            dir nil nnheader-numerical-short-files t)))
 613
 614 (defun nnheader-fold-continuation-lines ()
 615   "Fold continuation lines in the current buffer."
 616   (nnheader-replace-regexp "\\(\r?\n[ \t]+\\)+" " "))
 617
 618 (defun nnheader-translate-file-chars (file &optional full)
 619   "Translate FILE into something that can be a file name.
 620 If FULL, translate everything."
 621   (if (null nnheader-file-name-translation-alist)
 622       ;; No translation is necessary.
 623       file
 624     (let* ((i 0)
 625            trans leaf path len)
 626       (if full
 627           ;; Do complete translation.
 628           (setq leaf (copy-sequence file)
 629                 path ""
 630                 i (if (and (< 1 (length leaf)) (eq ?: (aref leaf 1)))
 631                       2 0))
 632         ;; We translate -- but only the file name.  We leave the directory
 633         ;; alone.
 634         (if (string-match "/[^/]+\\'" file)
 635             ;; This is needed on NT's and stuff.
 636             (setq leaf (substring file (1+ (match-beginning 0)))
 637                   path (substring file 0 (1+ (match-beginning 0))))
 638           ;; Fall back on this.
 639           (setq leaf (file-name-nondirectory file)
 640                 path (file-name-directory file))))
 641       (setq len (length leaf))
 642       (while (< i len)
 643         (when (setq trans (cdr (assq (aref leaf i)
 644                                      nnheader-file-name-translation-alist)))
 645           (aset leaf i trans))
 646         (incf i))
 647       (concat path leaf))))
 648
 649 (defun nnheader-report (backend &rest args)
 650   "Report an error from the BACKEND.
 651 The first string in ARGS can be a format string."
 652   (set (intern (format "%s-status-string" backend))
 653        (if (< (length args) 2)
 654            (car args)
 655          (apply 'format args)))
 656   nil)
 657
 658 (defun nnheader-get-report (backend)
 659   "Get the most recent report from BACKEND."
 660   (condition-case ()
 661       (nnheader-message 5 "%s" (symbol-value (intern (format "%s-status-string"
 662                                                              backend))))
 663     (error (nnheader-message 5 ""))))
 664
 665 (defun nnheader-insert (format &rest args)
 666   "Clear the communication buffer and insert FORMAT and ARGS into the buffer.
 667 If FORMAT isn't a format string, it and all ARGS will be inserted
 668 without formatting."
 669   (save-excursion
 670     (set-buffer nntp-server-buffer)
 671     (erase-buffer)
 672     (if (string-match "%" format)
 673         (insert (apply 'format format args))
 674       (apply 'insert format args))
 675     t))
 676
 677 (defun nnheader-replace-chars-in-string (string from to)
 678   "Replace characters in STRING from FROM to TO."
 679   (let ((string (substring string 0))   ;Copy string.
 680         (len (length string))
 681         (idx 0))
 682     ;; Replace all occurrences of FROM with TO.
 683     (while (< idx len)
 684       (when (= (aref string idx) from)
 685         (aset string idx to))
 686       (setq idx (1+ idx)))
 687     string))
 688
 689 (defun nnheader-replace-duplicate-chars-in-string (string from to)
 690   "Replace characters in STRING from FROM to TO."
 691   (let ((string (substring string 0))   ;Copy string.
 692         (len (length string))
 693         (idx 0) prev i)
 694     ;; Replace all occurrences of FROM with TO.
 695     (while (< idx len)
 696       (setq i (aref string idx))
 697       (when (and (eq prev from) (= i from))
 698         (aset string (1- idx) to)
 699         (aset string idx to))
 700       (setq prev i)
 701       (setq idx (1+ idx)))
 702     string))
 703
 704 (defun nnheader-file-to-group (file &optional top)
 705   "Return a group name based on FILE and TOP."
 706   (nnheader-replace-chars-in-string
 707    (if (not top)
 708        file
 709      (condition-case ()
 710          (substring (expand-file-name file)
 711                     (length
 712                      (expand-file-name
 713                       (file-name-as-directory top))))
 714        (error "")))
 715    ?/ ?.))
 716
 717 (defun nnheader-message (level &rest args)
 718   "Message if the Gnus backends are talkative."
 719   (if (or (not (numberp gnus-verbose-backends))
 720           (<= level gnus-verbose-backends))
 721       (apply 'message args)
 722     (apply 'format args)))
 723
 724 (defun nnheader-be-verbose (level)
 725   "Return whether the backends should be verbose on LEVEL."
 726   (or (not (numberp gnus-verbose-backends))
 727       (<= level gnus-verbose-backends)))
 728
 729 (defvar nnheader-pathname-coding-system 'binary
 730   "*Coding system for pathname.")
 731
 732 (defun nnheader-group-pathname (group dir &optional file)
 733   "Make pathname for GROUP."
 734   (concat
 735    (let ((dir (file-name-as-directory (expand-file-name dir))))
 736      ;; If this directory exists, we use it directly.
 737      (file-name-as-directory
 738       (if (file-directory-p (concat dir group))
 739           (expand-file-name group dir)
 740         ;; If not, we translate dots into slashes.
 741         (expand-file-name (mm-encode-coding-string
 742                            (nnheader-replace-chars-in-string group ?. ?/)
 743                           nnheader-pathname-coding-system)
 744                           dir))))
 745    (cond ((null file) "")
 746          ((numberp file) (int-to-string file))
 747          (t file))))
 748
 749 (defun nnheader-functionp (form)
 750   "Return non-nil if FORM is funcallable."
 751   (or (and (symbolp form) (fboundp form))
 752       (and (listp form) (eq (car form) 'lambda))))
 753
 754 (defun nnheader-concat (dir &rest files)
 755   "Concat DIR as directory to FILE."
 756   (apply 'concat (file-name-as-directory dir) files))
 757
 758 (defun nnheader-ms-strip-cr ()
 759   "Strip ^M from the end of all lines."
 760   (save-excursion
 761     (goto-char (point-min))
 762     (while (re-search-forward "\r$" nil t)
 763       (delete-backward-char 1))))
 764
 765 (defun nnheader-file-size (file)
 766   "Return the file size of FILE or 0."
 767   (or (nth 7 (file-attributes file)) 0))
 768
 769 (defun nnheader-find-etc-directory (package &optional file)
 770   "Go through the path and find the \".../etc/PACKAGE\" directory.
 771 If FILE, find the \".../etc/PACKAGE\" file instead."
 772   (let ((path load-path)
 773         dir result)
 774     ;; We try to find the dir by looking at the load path,
 775     ;; stripping away the last component and adding "etc/".
 776     (while path
 777       (if (and (car path)
 778                (file-exists-p
 779                 (setq dir (concat
 780                            (file-name-directory
 781                             (directory-file-name (car path)))
 782                            "etc/" package
 783                            (if file "" "/"))))
 784                (or file (file-directory-p dir)))
 785           (setq result dir
 786                 path nil)
 787         (setq path (cdr path))))
 788     result))
 789
 790 (defvar ange-ftp-path-format)
 791 (defvar efs-path-regexp)
 792 (defun nnheader-re-read-dir (path)
 793   "Re-read directory PATH if PATH is on a remote system."
 794   (if (and (fboundp 'efs-re-read-dir) (boundp 'efs-path-regexp))
 795       (when (string-match efs-path-regexp path)
 796         (efs-re-read-dir path))
 797     (when (and (fboundp 'ange-ftp-re-read-dir) (boundp 'ange-ftp-path-format))
 798       (when (string-match (car ange-ftp-path-format) path)
 799         (ange-ftp-re-read-dir path)))))
 800
 801 (defvar nnheader-file-coding-system 'raw-text
 802   "Coding system used in file backends of Gnus.")
 803
 804 (defun nnheader-insert-file-contents (filename &optional visit beg end replace)
 805   "Like `insert-file-contents', q.v., but only reads in the file.
 806 A buffer may be modified in several ways after reading into the buffer due
 807 to advanced Emacs features, such as file-name-handlers, format decoding,
 808 find-file-hooks, etc.
 809   This function ensures that none of these modifications will take place."
 810   (let ((coding-system-for-read nnheader-file-coding-system))
 811     (mm-insert-file-contents filename visit beg end replace)))
 812
 813 (defun nnheader-find-file-noselect (&rest args)
 814   (let ((format-alist nil)
 815         (auto-mode-alist (mm-auto-mode-alist))
 816         (default-major-mode 'fundamental-mode)
 817         (enable-local-variables nil)
 818         (after-insert-file-functions nil)
 819         (enable-local-eval nil)
 820         (find-file-hooks nil)
 821         (coding-system-for-read nnheader-file-coding-system))
 822     (apply 'find-file-noselect args)))
 823
 824 (defun nnheader-directory-regular-files (dir)
 825   "Return a list of all regular files in DIR."
 826   (let ((files (directory-files dir t))
 827         out)
 828     (while files
 829       (when (file-regular-p (car files))
 830         (push (car files) out))
 831       (pop files))
 832     (nreverse out)))
 833
 834 (defun nnheader-directory-files (&rest args)
 835   "Same as `directory-files', but prune \".\" and \"..\"."
 836   (let ((files (apply 'directory-files args))
 837         out)
 838     (while files
 839       (unless (member (file-name-nondirectory (car files)) '("." ".."))
 840         (push (car files) out))
 841       (pop files))
 842     (nreverse out)))
 843
 844 (defmacro nnheader-skeleton-replace (from &optional to regexp)
 845   `(let ((new (generate-new-buffer " *nnheader replace*"))
 846          (cur (current-buffer))
 847          (start (point-min)))
 848      (set-buffer cur)
 849      (goto-char (point-min))
 850      (while (,(if regexp 're-search-forward 'search-forward)
 851              ,from nil t)
 852        (insert-buffer-substring
 853         cur start (prog1 (match-beginning 0) (set-buffer new)))
 854        (goto-char (point-max))
 855        ,(when to `(insert ,to))
 856        (set-buffer cur)
 857        (setq start (point)))
 858      (insert-buffer-substring
 859       cur start (prog1 (point-max) (set-buffer new)))
 860      (copy-to-buffer cur (point-min) (point-max))
 861      (kill-buffer (current-buffer))
 862      (set-buffer cur)))
 863
 864 (defun nnheader-replace-string (from to)
 865   "Do a fast replacement of FROM to TO from point to point-max."
 866   (nnheader-skeleton-replace from to))
 867
 868 (defun nnheader-replace-regexp (from to)
 869   "Do a fast regexp replacement of FROM to TO from point to point-max."
 870   (nnheader-skeleton-replace from to t))
 871
 872 (defun nnheader-strip-cr ()
 873   "Strip all \r's from the current buffer."
 874   (nnheader-skeleton-replace "\r"))
 875
 876 (defalias 'nnheader-run-at-time 'run-at-time)
 877 (defalias 'nnheader-cancel-timer 'cancel-timer)
 878 (defalias 'nnheader-cancel-function-timers 'cancel-function-timers)
 879
 880 (when (string-match "XEmacs" emacs-version)
 881   (require 'nnheaderxm))
 882
 883 (run-hooks 'nnheader-load-hook)
 884
 885 (provide 'nnheader)
 886
 887 ;;; nnheader.el ends here