cgit.sxemacs.org Git - gnus/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'nnheader)
  29 (require 'nnmail)
  30 (require 'gnus-start)
  31 (require 'nnmh)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nndraft
  36   nnmh)
  37
  38 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  39   "Where nndraft will store its files."
  40   nnmh-directory)
  41
  42 \f
  43
  44 (defvoo nndraft-current-group "" nil nnmh-current-group)
  45 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  46 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  47
  48 (defconst nndraft-version "nndraft 1.0")
  49 (defvoo nndraft-status-string "" nil nnmh-status-string)
  50
  51 \f
  52
  53 ;;; Interface functions.
  54
  55 (nnoo-define-basics nndraft)
  56
  57 (deffoo nndraft-open-server (server &optional defs)
  58   (nnoo-change-server 'nndraft server defs)
  59   (cond
  60    ((not (file-exists-p nndraft-directory))
  61     (nndraft-close-server)
  62     (nnheader-report 'nndraft "No such file or directory: %s"
  63                      nndraft-directory))
  64    ((not (file-directory-p (file-truename nndraft-directory)))
  65     (nndraft-close-server)
  66     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  67    (t
  68     (nnheader-report 'nndraft "Opened server %s using directory %s"
  69                      server nndraft-directory)
  70     t)))
  71
  72 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  73   (nndraft-possibly-change-group group)
  74   (save-excursion
  75     (set-buffer nntp-server-buffer)
  76     (erase-buffer)
  77     (let* ((buf (get-buffer-create " *draft headers*"))
  78            article)
  79       (set-buffer buf)
  80       (buffer-disable-undo (current-buffer))
  81       (erase-buffer)
  82       ;; We don't support fetching by Message-ID.
  83       (if (stringp (car articles))
  84           'headers
  85         (while articles
  86           (set-buffer buf)
  87           (when (nndraft-request-article
  88                  (setq article (pop articles)) group server (current-buffer))
  89             (goto-char (point-min))
  90             (if (search-forward "\n\n" nil t)
  91                 (forward-line -1)
  92               (goto-char (point-max)))
  93             (delete-region (point) (point-max))
  94             (set-buffer nntp-server-buffer)
  95             (goto-char (point-max))
  96             (insert (format "221 %d Article retrieved.\n" article))
  97             (insert-buffer-substring buf)
  98             (insert ".\n")))
  99
 100         (nnheader-fold-continuation-lines)
 101         'headers))))
 102
 103 (deffoo nndraft-request-article (id &optional group server buffer)
 104   (nndraft-possibly-change-group group)
 105   (when (numberp id)
 106     ;; We get the newest file of the auto-saved file and the
 107     ;; "real" file.
 108     (let* ((file (nndraft-article-filename id))
 109            (auto (nndraft-auto-save-file-name file))
 110            (newest (if (file-newer-than-file-p file auto) file auto))
 111            (nntp-server-buffer (or buffer nntp-server-buffer)))
 112       (when (and (file-exists-p newest)
 113                  (nnmail-find-file newest))
 114         (save-excursion
 115           (set-buffer nntp-server-buffer)
 116           (goto-char (point-min))
 117           ;; If there's a mail header separator in this file,
 118           ;; we remove it.
 119           (when (re-search-forward
 120                  (concat "^" mail-header-separator "$") nil t)
 121             (replace-match "" t t)))
 122         t))))
 123
 124 (deffoo nndraft-request-restore-buffer (article &optional group server)
 125   "Request a new buffer that is restored to the state of ARTICLE."
 126   (nndraft-possibly-change-group group)
 127   (when (nndraft-request-article article group server (current-buffer))
 128     (message-remove-header "xref")
 129     (message-remove-header "lines")
 130     (let ((gnus-verbose-backends nil))
 131       (nndraft-request-expire-articles (list article) group server t))
 132     t))
 133
 134 (deffoo nndraft-request-update-info (group info &optional server)
 135   (nndraft-possibly-change-group group)
 136   (gnus-info-set-read
 137    info
 138    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 139                               (nndraft-articles) t))
 140   (let (marks)
 141     (when (setq marks (nth 3 info))
 142       (setcar (nthcdr 3 info)
 143               (if (assq 'unsend marks)
 144                   (list (assq 'unsend marks))
 145                 nil))))
 146   t)
 147
 148 (deffoo nndraft-request-associate-buffer (group)
 149   "Associate the current buffer with some article in the draft group."
 150   (nndraft-open-server "")
 151   (nndraft-request-group group)
 152   (nndraft-possibly-change-group group)
 153   (let ((gnus-verbose-backends nil)
 154         (buf (current-buffer))
 155          article file)
 156     (nnheader-temp-write nil
 157       (insert-buffer buf)
 158       (setq article (nndraft-request-accept-article
 159                      group (nnoo-current-server 'nndraft) t 'noinsert))
 160       (setq file (nndraft-article-filename article)))
 161     (setq buffer-file-name (expand-file-name file))
 162     (setq buffer-auto-save-file-name (make-auto-save-file-name))
 163     (clear-visited-file-modtime)
 164     article))
 165
 166 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 167   (nndraft-possibly-change-group group)
 168   (let* ((nnmh-allow-delete-final t)
 169          (res (nnoo-parent-function 'nndraft
 170                                     'nnmh-request-expire-articles
 171                                     (list articles group server force)))
 172          article)
 173     ;; Delete all the "state" files of articles that have been expired.
 174     (while articles
 175       (unless (memq (setq article (pop articles)) res)
 176         (let ((auto (nndraft-auto-save-file-name
 177                      (nndraft-article-filename article))))
 178           (when (file-exists-p auto)
 179             (funcall nnmail-delete-file-function auto)))))
 180     res))
 181
 182 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 183   (nndraft-possibly-change-group group)
 184   (let ((gnus-verbose-backends nil))
 185     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 186                           (list group server last noinsert))))
 187
 188 (deffoo nndraft-request-create-group (group &optional server args)
 189   (nndraft-possibly-change-group group)
 190   (if (file-exists-p nndraft-current-directory)
 191       (if (file-directory-p nndraft-current-directory)
 192           t
 193         nil)
 194     (condition-case ()
 195         (progn
 196           (gnus-make-directory nndraft-current-directory)
 197           t)
 198       (file-error nil))))
 199
 200 \f
 201 ;;; Low-Level Interface
 202
 203 (defun nndraft-possibly-change-group (group)
 204   (when (and group
 205              (not (equal group nndraft-current-group)))
 206     (nndraft-open-server "")
 207     (setq nndraft-current-group group)
 208     (setq nndraft-current-directory
 209           (nnheader-concat nndraft-directory group))))
 210
 211 (defun nndraft-article-filename (article &rest args)
 212   (apply 'concat
 213          (file-name-as-directory nndraft-current-directory)
 214          (int-to-string article)
 215          args))
 216
 217 (defun nndraft-auto-save-file-name (file)
 218   (save-excursion
 219     (prog1
 220         (progn
 221           (set-buffer (get-buffer-create " *draft tmp*"))
 222           (setq buffer-file-name file)
 223           (make-auto-save-file-name))
 224       (kill-buffer (current-buffer)))))
 225
 226 (defun nndraft-articles ()
 227   "Return the list of messages in the group."
 228   (gnus-make-directory nndraft-current-directory)
 229   (sort
 230    (mapcar 'string-to-int
 231            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 232    '<))
 233
 234 (nnoo-import nndraft
 235   (nnmh
 236    nnmh-retrieve-headers
 237    nnmh-request-group
 238    nnmh-close-group
 239    nnmh-request-list
 240    nnmh-request-newsgroups
 241    nnmh-request-move-article
 242    nnmh-request-replace-article))
 243
 244 (provide 'nndraft)
 245
 246 ;;; nndraft.el ends here