cgit.sxemacs.org Git - gnus/blob - lisp/mml2015.el

   1 ;;; mml2015.el --- MIME Security with Pretty Good Privacy (PGP)
   2 ;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5 ;; Keywords: PGP MIME MML
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; RFC 2015 is updated by RFC 3156, this file should be compatible
  27 ;; with both.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'mm-decode)
  33
  34 (defvar mml2015-use (or
  35                      (progn
  36                        (ignore-errors
  37                          (require 'gpg))
  38                        (and (fboundp 'gpg-sign-detached)
  39                             'gpg))
  40                      (progn (ignore-errors
  41                               (load "mc-toplev"))
  42                             (and (fboundp 'mc-encrypt-generic)
  43                                  (fboundp 'mc-sign-generic)
  44                                  (fboundp 'mc-cleanup-recipient-headers)
  45                                  'mailcrypt)))
  46   "The package used for PGP/MIME.")
  47
  48 ;; Something is not RFC2015.
  49 (defvar mml2015-function-alist
  50   '((mailcrypt mml2015-mailcrypt-sign
  51                mml2015-mailcrypt-encrypt
  52                mml2015-mailcrypt-verify
  53                mml2015-mailcrypt-decrypt
  54                mml2015-mailcrypt-clear-verify
  55                mml2015-mailcrypt-clear-decrypt)
  56     (gpg mml2015-gpg-sign
  57          mml2015-gpg-encrypt
  58          mml2015-gpg-verify
  59          mml2015-gpg-decrypt
  60          mml2015-gpg-clear-verify
  61          mml2015-gpg-clear-decrypt))
  62   "Alist of PGP/MIME functions.")
  63
  64 (defvar mml2015-result-buffer nil)
  65
  66 (defvar mml2015-trust-boundaries-alist
  67   '((trust-undefined . nil)
  68     (trust-none      . nil)
  69     (trust-marginal  . t)
  70     (trust-full      . t)
  71     (trust-ultimate  . t))
  72   "Trust boundaries for a signer's GnuPG key.
  73 This alist contains pairs of the form (trust-symbol . boolean), with
  74 symbols that are contained in `gpg-unabbrev-trust-alist'. The boolean
  75 specifies whether the given trust value is good enough to be trusted
  76 by you.")
  77
  78 ;;; mailcrypt wrapper
  79
  80 (eval-and-compile
  81   (autoload 'mailcrypt-decrypt "mailcrypt")
  82   (autoload 'mailcrypt-verify "mailcrypt")
  83   (autoload 'mc-pgp-always-sign "mailcrypt")
  84   (autoload 'mc-encrypt-generic "mc-toplev")
  85   (autoload 'mc-cleanup-recipient-headers "mc-toplev")
  86   (autoload 'mc-sign-generic "mc-toplev"))
  87
  88 (eval-when-compile
  89   (defvar mc-default-scheme)
  90   (defvar mc-schemes))
  91
  92 (defvar mml2015-decrypt-function 'mailcrypt-decrypt)
  93 (defvar mml2015-verify-function 'mailcrypt-verify)
  94
  95 (defun mml2015-format-error (err)
  96   (if (stringp (cadr err))
  97       (cadr err)
  98     (format "%S" (cdr err))))
  99
 100 (defun mml2015-mailcrypt-decrypt (handle ctl)
 101   (catch 'error
 102     (let (child handles result)
 103       (unless (setq child (mm-find-part-by-type
 104                            (cdr handle)
 105                            "application/octet-stream" nil t))
 106         (mm-set-handle-multipart-parameter
 107          mm-security-handle 'gnus-info "Corrupted")
 108         (throw 'error handle))
 109       (with-temp-buffer
 110         (mm-insert-part child)
 111         (setq result
 112               (condition-case err
 113                   (funcall mml2015-decrypt-function)
 114                 (error
 115                  (mm-set-handle-multipart-parameter
 116                   mm-security-handle 'gnus-details (mml2015-format-error err))
 117                  nil)
 118                 (quit
 119                  (mm-set-handle-multipart-parameter
 120                   mm-security-handle 'gnus-details "Quit.")
 121                  nil)))
 122         (unless (car result)
 123           (mm-set-handle-multipart-parameter
 124            mm-security-handle 'gnus-info "Failed")
 125           (throw 'error handle))
 126         (setq handles (mm-dissect-buffer t)))
 127       (mm-destroy-parts handle)
 128       (mm-set-handle-multipart-parameter
 129        mm-security-handle 'gnus-info
 130        (concat "OK"
 131                (let ((sig (with-current-buffer mml2015-result-buffer
 132                             (mml2015-gpg-extract-signature-details))))
 133                  (concat ", Signer: " sig))))
 134       (if (listp (car handles))
 135           handles
 136         (list handles)))))
 137
 138 (defun mml2015-mailcrypt-clear-decrypt ()
 139   (let (result)
 140     (setq result
 141           (condition-case err
 142               (funcall mml2015-decrypt-function)
 143             (error
 144              (mm-set-handle-multipart-parameter
 145               mm-security-handle 'gnus-details (mml2015-format-error err))
 146              nil)
 147             (quit
 148              (mm-set-handle-multipart-parameter
 149               mm-security-handle 'gnus-details "Quit.")
 150              nil)))
 151     (if (car result)
 152         (mm-set-handle-multipart-parameter
 153          mm-security-handle 'gnus-info "OK")
 154       (mm-set-handle-multipart-parameter
 155        mm-security-handle 'gnus-info "Failed"))))
 156
 157 (defun mml2015-fix-micalg (alg)
 158   (and alg
 159        ;; Mutt/1.2.5i has seen sending micalg=php-sha1
 160        (upcase (if (string-match "^p[gh]p-" alg)
 161                    (substring alg (match-end 0))
 162                  alg))))
 163
 164 (defun mml2015-mailcrypt-verify (handle ctl)
 165   (catch 'error
 166     (let (part)
 167       (unless (setq part (mm-find-raw-part-by-type
 168                           ctl (or (mm-handle-multipart-ctl-parameter
 169                                    ctl 'protocol)
 170                                   "application/pgp-signature")
 171                           t))
 172         (mm-set-handle-multipart-parameter
 173          mm-security-handle 'gnus-info "Corrupted")
 174         (throw 'error handle))
 175       (with-temp-buffer
 176         (insert "-----BEGIN PGP SIGNED MESSAGE-----\n")
 177         (insert (format "Hash: %s\n\n"
 178                         (or (mml2015-fix-micalg
 179                              (mm-handle-multipart-ctl-parameter
 180                               ctl 'micalg))
 181                             "SHA1")))
 182         (save-restriction
 183           (narrow-to-region (point) (point))
 184           (insert part "\n")
 185           (goto-char (point-min))
 186           (while (not (eobp))
 187             (if (looking-at "^-")
 188                 (insert "- "))
 189             (forward-line)))
 190         (unless (setq part (mm-find-part-by-type
 191                             (cdr handle) "application/pgp-signature" nil t))
 192           (mm-set-handle-multipart-parameter
 193            mm-security-handle 'gnus-info "Corrupted")
 194           (throw 'error handle))
 195         (save-restriction
 196           (narrow-to-region (point) (point))
 197           (mm-insert-part part)
 198           (goto-char (point-min))
 199           (if (re-search-forward "^-----BEGIN PGP [^-]+-----\r?$" nil t)
 200               (replace-match "-----BEGIN PGP SIGNATURE-----" t t))
 201           (if (re-search-forward "^-----END PGP [^-]+-----\r?$" nil t)
 202               (replace-match "-----END PGP SIGNATURE-----" t t)))
 203         (let ((mc-gpg-debug-buffer (get-buffer-create " *gnus gpg debug*")))
 204           (unless (condition-case err
 205                       (prog1
 206                           (funcall mml2015-verify-function)
 207                         (if (get-buffer " *mailcrypt stderr temp")
 208                             (mm-set-handle-multipart-parameter
 209                              mm-security-handle 'gnus-details
 210                              (with-current-buffer " *mailcrypt stderr temp"
 211                                (buffer-string))))
 212                         (if (get-buffer " *mailcrypt stdout temp")
 213                             (kill-buffer " *mailcrypt stdout temp"))
 214                         (if (get-buffer " *mailcrypt stderr temp")
 215                             (kill-buffer " *mailcrypt stderr temp"))
 216                         (if (get-buffer " *mailcrypt status temp")
 217                             (kill-buffer " *mailcrypt status temp"))
 218                         (if (get-buffer mc-gpg-debug-buffer)
 219                             (kill-buffer mc-gpg-debug-buffer)))
 220                     (error
 221                      (mm-set-handle-multipart-parameter
 222                       mm-security-handle 'gnus-details (mml2015-format-error err))
 223                      nil)
 224                     (quit
 225                      (mm-set-handle-multipart-parameter
 226                       mm-security-handle 'gnus-details "Quit.")
 227                      nil))
 228             (mm-set-handle-multipart-parameter
 229              mm-security-handle 'gnus-info "Failed")
 230             (throw 'error handle))))
 231       (mm-set-handle-multipart-parameter
 232        mm-security-handle 'gnus-info "OK")
 233       handle)))
 234
 235 (defun mml2015-mailcrypt-clear-verify ()
 236   (let ((mc-gpg-debug-buffer (get-buffer-create " *gnus gpg debug*")))
 237     (if (condition-case err
 238             (prog1
 239                 (funcall mml2015-verify-function)
 240               (if (get-buffer " *mailcrypt stderr temp")
 241                   (mm-set-handle-multipart-parameter
 242                    mm-security-handle 'gnus-details
 243                    (with-current-buffer " *mailcrypt stderr temp"
 244                      (buffer-string))))
 245               (if (get-buffer " *mailcrypt stdout temp")
 246                   (kill-buffer " *mailcrypt stdout temp"))
 247               (if (get-buffer " *mailcrypt stderr temp")
 248                   (kill-buffer " *mailcrypt stderr temp"))
 249               (if (get-buffer " *mailcrypt status temp")
 250                   (kill-buffer " *mailcrypt status temp"))
 251               (if (get-buffer mc-gpg-debug-buffer)
 252                   (kill-buffer mc-gpg-debug-buffer)))
 253           (error
 254            (mm-set-handle-multipart-parameter
 255             mm-security-handle 'gnus-details (mml2015-format-error err))
 256            nil)
 257           (quit
 258            (mm-set-handle-multipart-parameter
 259             mm-security-handle 'gnus-details "Quit.")
 260            nil))
 261         (mm-set-handle-multipart-parameter
 262          mm-security-handle 'gnus-info "OK")
 263       (mm-set-handle-multipart-parameter
 264        mm-security-handle 'gnus-info "Failed"))))
 265
 266 (defun mml2015-mailcrypt-sign (cont)
 267   (mc-sign-generic (message-options-get 'message-sender)
 268                    nil nil nil nil)
 269   (let ((boundary
 270          (funcall mml-boundary-function (incf mml-multipart-number)))
 271         hash point)
 272     (goto-char (point-min))
 273     (unless (re-search-forward "^-----BEGIN PGP SIGNED MESSAGE-----\r?$" nil t)
 274       (error "Cannot find signed begin line"))
 275     (goto-char (match-beginning 0))
 276     (forward-line 1)
 277     (unless (looking-at "Hash:[ \t]*\\([a-zA-Z0-9]+\\)")
 278       (error "Cannot not find PGP hash"))
 279     (setq hash (match-string 1))
 280     (unless (re-search-forward "^$" nil t)
 281       (error "Cannot not find PGP message"))
 282     (forward-line 1)
 283     (delete-region (point-min) (point))
 284     (insert (format "Content-Type: multipart/signed; boundary=\"%s\";\n"
 285                     boundary))
 286     (insert (format "\tmicalg=pgp-%s; protocol=\"application/pgp-signature\"\n"
 287                     (downcase hash)))
 288     (insert (format "\n--%s\n" boundary))
 289     (setq point (point))
 290     (goto-char (point-max))
 291     (unless (re-search-backward "^-----END PGP SIGNATURE-----\r?$" nil t)
 292       (error "Cannot find signature part"))
 293     (replace-match "-----END PGP MESSAGE-----" t t)
 294     (goto-char (match-beginning 0))
 295     (unless (re-search-backward "^-----BEGIN PGP SIGNATURE-----\r?$"
 296                                 nil t)
 297       (error "Cannot find signature part"))
 298     (replace-match "-----BEGIN PGP MESSAGE-----" t t)
 299     (goto-char (match-beginning 0))
 300     (save-restriction
 301       (narrow-to-region point (point))
 302       (goto-char point)
 303       (while (re-search-forward "^- -" nil t)
 304         (replace-match "-" t t))
 305       (goto-char (point-max)))
 306     (insert (format "--%s\n" boundary))
 307     (insert "Content-Type: application/pgp-signature\n\n")
 308     (goto-char (point-max))
 309     (insert (format "--%s--\n" boundary))
 310     (goto-char (point-max))))
 311
 312 (defun mml2015-mailcrypt-encrypt (cont &optional sign)
 313   (let ((mc-pgp-always-sign
 314          (or mc-pgp-always-sign
 315              sign
 316              (eq t (or (message-options-get 'message-sign-encrypt)
 317                        (message-options-set
 318                         'message-sign-encrypt
 319                         (or (y-or-n-p "Sign the message? ")
 320                             'not))))
 321              'never)))
 322     (mm-with-unibyte-current-buffer-mule4
 323       (mc-encrypt-generic
 324        (or (message-options-get 'message-recipients)
 325            (message-options-set 'message-recipients
 326                               (mc-cleanup-recipient-headers
 327                                (read-string "Recipients: "))))
 328        nil nil nil
 329        (message-options-get 'message-sender))))
 330   (goto-char (point-min))
 331   (unless (looking-at "-----BEGIN PGP MESSAGE-----")
 332     (error "Fail to encrypt the message"))
 333   (let ((boundary
 334          (funcall mml-boundary-function (incf mml-multipart-number))))
 335     (insert (format "Content-Type: multipart/encrypted; boundary=\"%s\";\n"
 336                     boundary))
 337     (insert "\tprotocol=\"application/pgp-encrypted\"\n\n")
 338     (insert (format "--%s\n" boundary))
 339     (insert "Content-Type: application/pgp-encrypted\n\n")
 340     (insert "Version: 1\n\n")
 341     (insert (format "--%s\n" boundary))
 342     (insert "Content-Type: application/octet-stream\n\n")
 343     (goto-char (point-max))
 344     (insert (format "--%s--\n" boundary))
 345     (goto-char (point-max))))
 346
 347 ;;; gpg wrapper
 348
 349 (eval-and-compile
 350   (autoload 'gpg-decrypt "gpg")
 351   (autoload 'gpg-verify "gpg")
 352   (autoload 'gpg-verify-cleartext "gpg")
 353   (autoload 'gpg-sign-detached "gpg")
 354   (autoload 'gpg-sign-encrypt "gpg")
 355   (autoload 'gpg-encrypt "gpg")
 356   (autoload 'gpg-passphrase-read "gpg"))
 357
 358 (defun mml2015-gpg-passphrase ()
 359   (or (message-options-get 'gpg-passphrase)
 360       (message-options-set 'gpg-passphrase (gpg-passphrase-read))))
 361
 362 (defun mml2015-gpg-decrypt-1 ()
 363   (let ((cipher (current-buffer)) plain result)
 364     (if (with-temp-buffer
 365           (prog1
 366               (gpg-decrypt cipher (setq plain (current-buffer))
 367                            mml2015-result-buffer nil)
 368             (mm-set-handle-multipart-parameter
 369              mm-security-handle 'gnus-details
 370              (with-current-buffer mml2015-result-buffer
 371                (buffer-string)))
 372             (set-buffer cipher)
 373             (erase-buffer)
 374             (insert-buffer plain)
 375             (goto-char (point-min))
 376             (while (search-forward "\r\n" nil t)
 377               (replace-match "\n" t t))))
 378         '(t)
 379       ;; Some wrong with the return value, check plain text buffer.
 380       (if (> (point-max) (point-min))
 381           '(t)
 382         nil))))
 383
 384 (defun mml2015-gpg-decrypt (handle ctl)
 385   (let ((mml2015-decrypt-function 'mml2015-gpg-decrypt-1))
 386     (mml2015-mailcrypt-decrypt handle ctl)))
 387
 388 (defun mml2015-gpg-clear-decrypt ()
 389   (let (result)
 390     (setq result (mml2015-gpg-decrypt-1))
 391     (if (car result)
 392         (mm-set-handle-multipart-parameter
 393          mm-security-handle 'gnus-info "OK")
 394       (mm-set-handle-multipart-parameter
 395        mm-security-handle 'gnus-info "Failed"))))
 396
 397 (defun mml2015-gpg-pretty-print-fpr (fingerprint)
 398   (let* ((result "")
 399          (fpr-length (string-width fingerprint))
 400          (n-slice 0)
 401          slice)
 402     (setq fingerprint (string-to-list fingerprint))
 403     (while fingerprint
 404       (setq fpr-length (- fpr-length 4))
 405       (setq slice (butlast fingerprint fpr-length))
 406       (setq fingerprint (nthcdr 4 fingerprint))
 407       (setq n-slice (1+ n-slice))
 408       (setq result
 409             (concat
 410              result
 411              (case n-slice
 412                (1  slice)
 413                (otherwise (concat " " slice))))))
 414     result))
 415
 416 (defun mml2015-gpg-extract-signature-details ()
 417   (goto-char (point-min))
 418   (if (boundp 'gpg-unabbrev-trust-alist)
 419       (let* ((expired (re-search-forward
 420                        "^\\[GNUPG:\\] SIGEXPIRED$"
 421                        nil t))
 422              (signer (and (re-search-forward
 423                            "^\\[GNUPG:\\] GOODSIG \\([0-9A-Za-z]*\\) \\(.*\\)$"
 424                            nil t)
 425                           (cons (match-string 1) (match-string 2))))
 426              (fprint (and (re-search-forward
 427                            "^\\[GNUPG:\\] VALIDSIG \\([0-9a-zA-Z]*\\) "
 428                            nil t)
 429                           (match-string 1)))
 430              (trust  (and (re-search-forward
 431                            "^\\[GNUPG:\\] \\(TRUST_.*\\)$"
 432                            nil t)
 433                           (match-string 1)))
 434              (trust-good-enough-p
 435               (cdr (assoc (cdr (assoc trust gpg-unabbrev-trust-alist))
 436                           mml2015-trust-boundaries-alist))))
 437         (cond ((and signer fprint)
 438                (concat (cdr signer)
 439                        (unless trust-good-enough-p
 440                          (concat "\nUntrusted, Fingerprint: "
 441                                  (mml2015-gpg-pretty-print-fpr fprint)))
 442                        (when expired
 443                          (format "\nWARNING: Signature from expired key (%s)"
 444                           (car signer)))))
 445               (t
 446                "From unknown user")))
 447     (if (re-search-forward "^gpg: Good signature from \"\\(.*\\)\"$" nil t)
 448         (match-string 1)
 449       "From unknown user")))
 450
 451 (defun mml2015-gpg-verify (handle ctl)
 452   (catch 'error
 453     (let (part message signature info-is-set-p)
 454       (unless (setq part (mm-find-raw-part-by-type
 455                           ctl (or (mm-handle-multipart-ctl-parameter
 456                                    ctl 'protocol)
 457                                   "application/pgp-signature")
 458                           t))
 459         (mm-set-handle-multipart-parameter
 460          mm-security-handle 'gnus-info "Corrupted")
 461         (throw 'error handle))
 462       (with-temp-buffer
 463         (setq message (current-buffer))
 464         (insert part)
 465         ;; Convert <LF> to <CR><LF> in verify mode.  Sign and
 466         ;; clearsign use --textmode. The conversion is not necessary.
 467         ;; In clearverify, the conversion is not necessary either.
 468         (goto-char (point-min))
 469         (end-of-line)
 470         (while (not (eobp))
 471           (unless (eq (char-before) ?\r)
 472             (insert "\r"))
 473           (forward-line)
 474           (end-of-line))
 475         (with-temp-buffer
 476           (setq signature (current-buffer))
 477           (unless (setq part (mm-find-part-by-type
 478                               (cdr handle) "application/pgp-signature" nil t))
 479             (mm-set-handle-multipart-parameter
 480              mm-security-handle 'gnus-info "Corrupted")
 481             (throw 'error handle))
 482           (mm-insert-part part)
 483           (unless (condition-case err
 484                       (prog1
 485                           (gpg-verify message signature mml2015-result-buffer)
 486                         (mm-set-handle-multipart-parameter
 487                          mm-security-handle 'gnus-details
 488                          (with-current-buffer mml2015-result-buffer
 489                            (buffer-string))))
 490                     (error
 491                      (mm-set-handle-multipart-parameter
 492                       mm-security-handle 'gnus-details (mml2015-format-error err))
 493                      (mm-set-handle-multipart-parameter
 494                       mm-security-handle 'gnus-info "Error.")
 495                      (setq info-is-set-p t)
 496                      nil)
 497                     (quit
 498                      (mm-set-handle-multipart-parameter
 499                       mm-security-handle 'gnus-details "Quit.")
 500                      (mm-set-handle-multipart-parameter
 501                       mm-security-handle 'gnus-info "Quit.")
 502                      (setq info-is-set-p t)
 503                      nil))
 504             (unless info-is-set-p
 505               (mm-set-handle-multipart-parameter
 506                mm-security-handle 'gnus-info "Failed"))
 507             (throw 'error handle)))
 508         (mm-set-handle-multipart-parameter
 509          mm-security-handle 'gnus-info
 510          (with-current-buffer mml2015-result-buffer
 511            (mml2015-gpg-extract-signature-details))))
 512       handle)))
 513
 514 (defun mml2015-gpg-clear-verify ()
 515   (if (condition-case err
 516           (prog1
 517               (gpg-verify-cleartext (current-buffer) mml2015-result-buffer)
 518             (mm-set-handle-multipart-parameter
 519              mm-security-handle 'gnus-details
 520              (with-current-buffer mml2015-result-buffer
 521                (buffer-string))))
 522         (error
 523          (mm-set-handle-multipart-parameter
 524           mm-security-handle 'gnus-details (mml2015-format-error err))
 525          nil)
 526         (quit
 527          (mm-set-handle-multipart-parameter
 528           mm-security-handle 'gnus-details "Quit.")
 529          nil))
 530       (mm-set-handle-multipart-parameter
 531        mm-security-handle 'gnus-info
 532        (with-current-buffer mml2015-result-buffer
 533          (mml2015-gpg-extract-signature-details)))
 534     (mm-set-handle-multipart-parameter
 535      mm-security-handle 'gnus-info "Failed")))
 536
 537 (defun mml2015-gpg-sign (cont)
 538   (let ((boundary
 539          (funcall mml-boundary-function (incf mml-multipart-number)))
 540         (text (current-buffer)) signature)
 541     (goto-char (point-max))
 542     (unless (bolp)
 543       (insert "\n"))
 544     (with-temp-buffer
 545       (unless (gpg-sign-detached text (setq signature (current-buffer))
 546                                  mml2015-result-buffer
 547                                  nil
 548                                  (message-options-get 'message-sender)
 549                                  t t) ; armor & textmode
 550         (unless (> (point-max) (point-min))
 551           (pop-to-buffer mml2015-result-buffer)
 552           (error "Sign error")))
 553       (goto-char (point-min))
 554       (while (re-search-forward "\r+$" nil t)
 555         (replace-match "" t t))
 556       (set-buffer text)
 557       (goto-char (point-min))
 558       (insert (format "Content-Type: multipart/signed; boundary=\"%s\";\n"
 559                       boundary))
 560       ;;; FIXME: what is the micalg?
 561       (insert "\tmicalg=pgp-sha1; protocol=\"application/pgp-signature\"\n")
 562       (insert (format "\n--%s\n" boundary))
 563       (goto-char (point-max))
 564       (insert (format "\n--%s\n" boundary))
 565       (insert "Content-Type: application/pgp-signature\n\n")
 566       (insert-buffer signature)
 567       (goto-char (point-max))
 568       (insert (format "--%s--\n" boundary))
 569       (goto-char (point-max)))))
 570
 571 (defun mml2015-gpg-encrypt (cont &optional sign)
 572   (let ((boundary
 573          (funcall mml-boundary-function (incf mml-multipart-number)))
 574         (text (current-buffer))
 575         cipher)
 576     (mm-with-unibyte-current-buffer-mule4
 577       (with-temp-buffer
 578         ;; set up a function to call the correct gpg encrypt routine
 579         ;; with the right arguments. (FIXME: this should be done
 580         ;; differently.)
 581         (flet ((gpg-encrypt-func
 582                  (sign plaintext ciphertext result recipients &optional
 583                        passphrase sign-with-key armor textmode)
 584                  (if sign
 585                      (gpg-sign-encrypt
 586                       plaintext ciphertext result recipients passphrase
 587                       sign-with-key armor textmode)
 588                    (gpg-encrypt
 589                     plaintext ciphertext result recipients passphrase
 590                     armor textmode))))
 591           (unless (gpg-encrypt-func
 592                     sign ; passed in when using signencrypt
 593                     text (setq cipher (current-buffer))
 594                     mml2015-result-buffer
 595                     (split-string
 596                      (or
 597                       (message-options-get 'message-recipients)
 598                       (message-options-set 'message-recipients
 599                                            (read-string "Recipients: ")))
 600                      "[ \f\t\n\r\v,]+")
 601                     nil
 602                     (message-options-get 'message-sender)
 603                     t t) ; armor & textmode
 604             (unless (> (point-max) (point-min))
 605               (pop-to-buffer mml2015-result-buffer)
 606               (error "Encrypt error"))))
 607         (goto-char (point-min))
 608         (while (re-search-forward "\r+$" nil t)
 609           (replace-match "" t t))
 610         (set-buffer text)
 611         (delete-region (point-min) (point-max))
 612         (insert (format "Content-Type: multipart/encrypted; boundary=\"%s\";\n"
 613                         boundary))
 614         (insert "\tprotocol=\"application/pgp-encrypted\"\n\n")
 615         (insert (format "--%s\n" boundary))
 616         (insert "Content-Type: application/pgp-encrypted\n\n")
 617         (insert "Version: 1\n\n")
 618         (insert (format "--%s\n" boundary))
 619         (insert "Content-Type: application/octet-stream\n\n")
 620         (insert-buffer cipher)
 621         (goto-char (point-max))
 622         (insert (format "--%s--\n" boundary))
 623         (goto-char (point-max))))))
 624
 625 ;;; General wrapper
 626
 627 (defun mml2015-clean-buffer ()
 628   (if (gnus-buffer-live-p mml2015-result-buffer)
 629       (with-current-buffer mml2015-result-buffer
 630         (erase-buffer)
 631         t)
 632     (setq mml2015-result-buffer
 633           (gnus-get-buffer-create "*MML2015 Result*"))
 634     nil))
 635
 636 (defsubst mml2015-clear-decrypt-function ()
 637   (nth 6 (assq mml2015-use mml2015-function-alist)))
 638
 639 (defsubst mml2015-clear-verify-function ()
 640   (nth 5 (assq mml2015-use mml2015-function-alist)))
 641
 642 ;;;###autoload
 643 (defun mml2015-decrypt (handle ctl)
 644   (mml2015-clean-buffer)
 645   (let ((func (nth 4 (assq mml2015-use mml2015-function-alist))))
 646     (if func
 647         (funcall func handle ctl)
 648       handle)))
 649
 650 ;;;###autoload
 651 (defun mml2015-decrypt-test (handle ctl)
 652   mml2015-use)
 653
 654 ;;;###autoload
 655 (defun mml2015-verify (handle ctl)
 656   (mml2015-clean-buffer)
 657   (let ((func (nth 3 (assq mml2015-use mml2015-function-alist))))
 658     (if func
 659         (funcall func handle ctl)
 660       handle)))
 661
 662 ;;;###autoload
 663 (defun mml2015-verify-test (handle ctl)
 664   mml2015-use)
 665
 666 ;;;###autoload
 667 (defun mml2015-encrypt (cont &optional sign)
 668   (mml2015-clean-buffer)
 669   (let ((func (nth 2 (assq mml2015-use mml2015-function-alist))))
 670     (if func
 671         (funcall func cont sign)
 672       (error "Cannot find encrypt function"))))
 673
 674 ;;;###autoload
 675 (defun mml2015-sign (cont)
 676   (mml2015-clean-buffer)
 677   (let ((func (nth 1 (assq mml2015-use mml2015-function-alist))))
 678     (if func
 679         (funcall func cont)
 680       (error "Cannot find sign function"))))
 681
 682 ;;;###autoload
 683 (defun mml2015-self-encrypt ()
 684   (mml2015-encrypt nil))
 685
 686 (provide 'mml2015)
 687
 688 ;;; mml2015.el ends here