* lisp/mml.el (mml-insert-mime-headers): Allow `recipient-filename'.
[gnus] / lisp / mml.el
1 ;;; mml.el --- A package for parsing and validating MML documents
2
3 ;; Copyright (C) 1998-2014 Free Software Foundation, Inc.
4
5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
6 ;; This file is part of GNU Emacs.
7
8 ;; GNU Emacs is free software: you can redistribute it and/or modify
9 ;; it under the terms of the GNU General Public License as published by
10 ;; the Free Software Foundation, either version 3 of the License, or
11 ;; (at your option) any later version.
12
13 ;; GNU Emacs is distributed in the hope that it will be useful,
14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ;; GNU General Public License for more details.
17
18 ;; You should have received a copy of the GNU General Public License
19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
20
21 ;;; Commentary:
22
23 ;;; Code:
24
25 (require 'mm-util)
26 (require 'mm-bodies)
27 (require 'mm-encode)
28 (require 'mm-decode)
29 (require 'mml-sec)
30 (eval-when-compile (require 'cl))
31 (eval-when-compile
32   (when (featurep 'xemacs)
33     (require 'easy-mmode))) ; for `define-minor-mode'
34
35 (autoload 'message-make-message-id "message")
36 (declare-function gnus-setup-posting-charset "gnus-msg" (group))
37 (autoload 'gnus-make-local-hook "gnus-util")
38 (autoload 'gnus-completing-read "gnus-util")
39 (autoload 'message-fetch-field "message")
40 (autoload 'message-mark-active-p "message")
41 (autoload 'message-info "message")
42 (autoload 'fill-flowed-encode "flow-fill")
43 (autoload 'message-posting-charset "message")
44 (autoload 'dnd-get-local-file-name "dnd")
45
46 (autoload 'message-options-set    "message")
47 (autoload 'message-narrow-to-head "message")
48 (autoload 'message-in-body-p      "message")
49 (autoload 'message-mail-p         "message")
50
51 (defvar gnus-article-mime-handles)
52 (defvar gnus-mouse-2)
53 (defvar gnus-newsrc-hashtb)
54 (defvar message-default-charset)
55 (defvar message-deletable-headers)
56 (defvar message-options)
57 (defvar message-posting-charset)
58 (defvar message-required-mail-headers)
59 (defvar message-required-news-headers)
60 (defvar dnd-protocol-alist)
61 (defvar mml-dnd-protocol-alist)
62
63 (defcustom mml-content-type-parameters
64   '(name access-type expiration size permission format)
65   "*A list of acceptable parameters in MML tag.
66 These parameters are generated in Content-Type header if exists."
67   :version "22.1"
68   :type '(repeat (symbol :tag "Parameter"))
69   :group 'message)
70
71 (defcustom mml-content-disposition-parameters
72   '(filename creation-date modification-date read-date)
73   "*A list of acceptable parameters in MML tag.
74 These parameters are generated in Content-Disposition header if exists."
75   :version "22.1"
76   :type '(repeat (symbol :tag "Parameter"))
77   :group 'message)
78
79 (defcustom mml-content-disposition-alist
80   '((text (rtf . "attachment") (t . "inline"))
81     (t . "attachment"))
82   "Alist of MIME types or regexps matching file names and default dispositions.
83 Each element should be one of the following three forms:
84
85   (REGEXP . DISPOSITION)
86   (SUPERTYPE (SUBTYPE . DISPOSITION) (SUBTYPE . DISPOSITION)...)
87   (TYPE . DISPOSITION)
88
89 Where REGEXP is a string which matches the file name (if any) of an
90 attachment, SUPERTYPE, SUBTYPE and TYPE should be symbols which are a
91 MIME supertype (e.g., text), a MIME subtype (e.g., plain) and a MIME
92 type (e.g., text/plain) respectively, and DISPOSITION should be either
93 the string \"attachment\" or the string \"inline\".  The value t for
94 SUPERTYPE, SUBTYPE or TYPE matches any of those types.  The first
95 match found will be used."
96   :version "23.1" ;; No Gnus
97   :type (let ((dispositions '(radio :format "DISPOSITION: %v"
98                                     :value "attachment"
99                                     (const :format "%v " "attachment")
100                                     (const :format "%v\n" "inline"))))
101           `(repeat
102             :offset 0
103             (choice :format "%[Value Menu%]%v"
104                     (cons :tag "(REGEXP . DISPOSITION)" :extra-offset 4
105                           (regexp :tag "REGEXP" :value ".*")
106                           ,dispositions)
107                     (cons :tag "(SUPERTYPE (SUBTYPE . DISPOSITION)...)"
108                           :indent 0
109                           (symbol :tag "    SUPERTYPE" :value text)
110                           (repeat :format "%v%i\n" :offset 0 :extra-offset 4
111                                   (cons :format "%v" :extra-offset 5
112                                         (symbol :tag "SUBTYPE" :value t)
113                                         ,dispositions)))
114                     (cons :tag "(TYPE . DISPOSITION)" :extra-offset 4
115                           (symbol :tag "TYPE" :value t)
116                           ,dispositions))))
117   :group 'message)
118
119 (defcustom mml-insert-mime-headers-always t
120   "If non-nil, always put Content-Type: text/plain at top of empty parts.
121 It is necessary to work against a bug in certain clients."
122   :version "24.1"
123   :type 'boolean
124   :group 'message)
125
126 (defcustom mml-enable-flowed t
127   "If non-nil, enable format=flowed usage when encoding a message.
128 This is only performed when filling on text/plain with hard
129 newlines in the text."
130   :version "24.1"
131   :type 'boolean
132   :group 'message)
133
134 (defvar mml-tweak-type-alist nil
135   "A list of (TYPE . FUNCTION) for tweaking MML parts.
136 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
137 is a Lisp function which is called with the MML handle to tweak the
138 part.  This variable is used only when no TWEAK parameter exists in
139 the MML handle.")
140
141 (defvar mml-tweak-function-alist nil
142   "A list of (NAME . FUNCTION) for tweaking MML parts.
143 NAME is a string containing the name of the TWEAK parameter in the MML
144 handle.  FUNCTION is a Lisp function which is called with the MML
145 handle to tweak the part.")
146
147 (defvar mml-tweak-sexp-alist
148   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
149   "A list of (SEXP . FUNCTION) for tweaking MML parts.
150 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
151 is called.  FUNCTION is a Lisp function which is called with the MML
152 handle to tweak the part.")
153
154 (defvar mml-externalize-attachments nil
155   "*If non-nil, local-file attachments are generated as external parts.")
156
157 (defvar mml-generate-multipart-alist nil
158   "*Alist of multipart generation functions.
159 Each entry has the form (NAME . FUNCTION), where
160 NAME is a string containing the name of the part (without the
161 leading \"/multipart/\"),
162 FUNCTION is a Lisp function which is called to generate the part.
163
164 The Lisp function has to supply the appropriate MIME headers and the
165 contents of this part.")
166
167 (defvar mml-syntax-table
168   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
169     (modify-syntax-entry ?\\ "/" table)
170     (modify-syntax-entry ?< "(" table)
171     (modify-syntax-entry ?> ")" table)
172     (modify-syntax-entry ?@ "w" table)
173     (modify-syntax-entry ?/ "w" table)
174     (modify-syntax-entry ?= " " table)
175     (modify-syntax-entry ?* " " table)
176     (modify-syntax-entry ?\; " " table)
177     (modify-syntax-entry ?\' " " table)
178     table))
179
180 (defvar mml-boundary-function 'mml-make-boundary
181   "A function called to suggest a boundary.
182 The function may be called several times, and should try to make a new
183 suggestion each time.  The function is called with one parameter,
184 which is a number that says how many times the function has been
185 called for this message.")
186
187 (defvar mml-confirmation-set nil
188   "A list of symbols, each of which disables some warning.
189 `unknown-encoding': always send messages contain characters with
190 unknown encoding; `use-ascii': always use ASCII for those characters
191 with unknown encoding; `multipart': always send messages with more than
192 one charsets.")
193
194 (defvar mml-generate-default-type "text/plain"
195   "Content type by which the Content-Type header can be omitted.
196 The Content-Type header will not be put in the MIME part if the type
197 equals the value and there's no parameter (e.g. charset, format, etc.)
198 and `mml-insert-mime-headers-always' is nil.  The value will be bound
199 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
200 part.  This is for the internal use, you should never modify the value.")
201
202 (defvar mml-buffer-list nil)
203
204 (defun mml-generate-new-buffer (name)
205   (let ((buf (generate-new-buffer name)))
206     (push buf mml-buffer-list)
207     buf))
208
209 (defun mml-destroy-buffers ()
210   (let (kill-buffer-hook)
211     (mapc 'kill-buffer mml-buffer-list)
212     (setq mml-buffer-list nil)))
213
214 (defun mml-parse ()
215   "Parse the current buffer as an MML document."
216   (save-excursion
217     (goto-char (point-min))
218     (with-syntax-table mml-syntax-table
219       (mml-parse-1))))
220
221 (defun mml-parse-1 ()
222   "Parse the current buffer as an MML document."
223   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
224     (while (and (not (eobp))
225                 (not (looking-at "<#/multipart")))
226       (cond
227        ((looking-at "<#secure")
228         ;; The secure part is essentially a meta-meta tag, which
229         ;; expands to either a part tag if there are no other parts in
230         ;; the document or a multipart tag if there are other parts
231         ;; included in the message
232         (let* (secure-mode
233                (taginfo (mml-read-tag))
234                (keyfile (cdr (assq 'keyfile taginfo)))
235                (certfiles (delq nil (mapcar (lambda (tag)
236                                               (if (eq (car-safe tag) 'certfile)
237                                                   (cdr tag)))
238                                             taginfo)))
239                (recipients (cdr (assq 'recipients taginfo)))
240                (sender (cdr (assq 'sender taginfo)))
241                (location (cdr (assq 'tag-location taginfo)))
242                (mode (cdr (assq 'mode taginfo)))
243                (method (cdr (assq 'method taginfo)))
244                tags)
245           (save-excursion
246             (if (re-search-forward
247                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
248                 (setq secure-mode "multipart")
249               (setq secure-mode "part")))
250           (save-excursion
251             (goto-char location)
252             (re-search-forward "<#secure[^\n]*>\n"))
253           (delete-region (match-beginning 0) (match-end 0))
254           (cond ((string= mode "sign")
255                  (setq tags (list "sign" method)))
256                 ((string= mode "encrypt")
257                  (setq tags (list "encrypt" method)))
258                 ((string= mode "signencrypt")
259                  (setq tags (list "sign" method "encrypt" method))))
260           (eval `(mml-insert-tag ,secure-mode
261                                  ,@tags
262                                  ,(if keyfile "keyfile")
263                                  ,keyfile
264                                  ,@(apply #'append
265                                           (mapcar (lambda (certfile)
266                                                     (list "certfile" certfile))
267                                                   certfiles))
268                                  ,(if recipients "recipients")
269                                  ,recipients
270                                  ,(if sender "sender")
271                                  ,sender))
272           ;; restart the parse
273           (goto-char location)))
274        ((looking-at "<#multipart")
275         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
276        ((looking-at "<#external")
277         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
278               struct))
279        (t
280         (if (or (looking-at "<#part") (looking-at "<#mml"))
281             (setq tag (mml-read-tag)
282                   no-markup-p nil
283                   warn nil)
284           (setq tag (list 'part '(type . "text/plain"))
285                 no-markup-p t
286                 warn t))
287         (setq raw (cdr (assq 'raw tag))
288               point (point)
289               contents (mml-read-part (eq 'mml (car tag)))
290               charsets (cond
291                         (raw nil)
292                         ((assq 'charset tag)
293                          (list
294                           (intern (downcase (cdr (assq 'charset tag))))))
295                         (t
296                          (mm-find-mime-charset-region point (point)
297                                                       mm-hack-charsets))))
298         (when (and (not raw) (memq nil charsets))
299           (if (or (memq 'unknown-encoding mml-confirmation-set)
300                   (message-options-get 'unknown-encoding)
301                   (and (y-or-n-p "\
302 Message contains characters with unknown encoding.  Really send? ")
303                        (message-options-set 'unknown-encoding t)))
304               (if (setq use-ascii
305                         (or (memq 'use-ascii mml-confirmation-set)
306                             (message-options-get 'use-ascii)
307                             (and (y-or-n-p "Use ASCII as charset? ")
308                                  (message-options-set 'use-ascii t))))
309                   (setq charsets (delq nil charsets))
310                 (setq warn nil))
311             (error "Edit your message to remove those characters")))
312         (if (or raw
313                 (eq 'mml (car tag))
314                 (< (length charsets) 2))
315             (if (or (not no-markup-p)
316                     (string-match "[^ \t\r\n]" contents))
317                 ;; Don't create blank parts.
318                 (push (nconc tag (list (cons 'contents contents)))
319                       struct))
320           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
321                           tag point (point) use-ascii)))
322             (when (and warn
323                        (not (memq 'multipart mml-confirmation-set))
324                        (not (message-options-get 'multipart))
325                        (not (and (y-or-n-p (format "\
326 A message part needs to be split into %d charset parts.  Really send? "
327                                                    (length nstruct)))
328                                  (message-options-set 'multipart t))))
329               (error "Edit your message to use only one charset"))
330             (setq struct (nconc nstruct struct)))))))
331     (unless (eobp)
332       (forward-line 1))
333     (nreverse struct)))
334
335 (defun mml-parse-singlepart-with-multiple-charsets
336   (orig-tag beg end &optional use-ascii)
337   (save-excursion
338     (save-restriction
339       (narrow-to-region beg end)
340       (goto-char (point-min))
341       (let ((current (or (mm-mime-charset (mm-charset-after))
342                          (and use-ascii 'us-ascii)))
343             charset struct space newline paragraph)
344         (while (not (eobp))
345           (setq charset (mm-mime-charset (mm-charset-after)))
346           (cond
347            ;; The charset remains the same.
348            ((eq charset 'us-ascii))
349            ((or (and use-ascii (not charset))
350                 (eq charset current))
351             (setq space nil
352                   newline nil
353                   paragraph nil))
354            ;; The initial charset was ascii.
355            ((eq current 'us-ascii)
356             (setq current charset
357                   space nil
358                   newline nil
359                   paragraph nil))
360            ;; We have a change in charsets.
361            (t
362             (push (append
363                    orig-tag
364                    (list (cons 'contents
365                                (buffer-substring-no-properties
366                                 beg (or paragraph newline space (point))))))
367                   struct)
368             (setq beg (or paragraph newline space (point))
369                   current charset
370                   space nil
371                   newline nil
372                   paragraph nil)))
373           ;; Compute places where it might be nice to break the part.
374           (cond
375            ((memq (following-char) '(?  ?\t))
376             (setq space (1+ (point))))
377            ((and (eq (following-char) ?\n)
378                  (not (bobp))
379                  (eq (char-after (1- (point))) ?\n))
380             (setq paragraph (point)))
381            ((eq (following-char) ?\n)
382             (setq newline (1+ (point)))))
383           (forward-char 1))
384         ;; Do the final part.
385         (unless (= beg (point))
386           (push (append orig-tag
387                         (list (cons 'contents
388                                     (buffer-substring-no-properties
389                                      beg (point)))))
390                 struct))
391         struct))))
392
393 (defun mml-read-tag ()
394   "Read a tag and return the contents."
395   (let ((orig-point (point))
396         contents name elem val)
397     (forward-char 2)
398     (setq name (buffer-substring-no-properties
399                 (point) (progn (forward-sexp 1) (point))))
400     (skip-chars-forward " \t\n")
401     (while (not (looking-at ">[ \t]*\n?"))
402       (setq elem (buffer-substring-no-properties
403                   (point) (progn (forward-sexp 1) (point))))
404       (skip-chars-forward "= \t\n")
405       (setq val (buffer-substring-no-properties
406                  (point) (progn (forward-sexp 1) (point))))
407       (when (string-match "\\`\"" val)
408         (setq val (read val))) ;; inverse of prin1 in mml-insert-tag
409       (push (cons (intern elem) val) contents)
410       (skip-chars-forward " \t\n"))
411     (goto-char (match-end 0))
412     ;; Don't skip the leading space.
413     ;;(skip-chars-forward " \t\n")
414     ;; Put the tag location into the returned contents
415     (setq contents (append (list (cons 'tag-location orig-point)) contents))
416     (cons (intern name) (nreverse contents))))
417
418 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
419   (let ((str (buffer-substring-no-properties start end))
420         (bufstart start) tmp)
421     (while (setq tmp (text-property-any start end 'hard 't))
422       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
423                            '(hard t) str)
424       (setq start (1+ tmp)))
425     str))
426
427 (defun mml-read-part (&optional mml)
428   "Return the buffer up till the next part, multipart or closing part or multipart.
429 If MML is non-nil, return the buffer up till the correspondent mml tag."
430   (let ((beg (point)) (count 1))
431     ;; If the tag ended at the end of the line, we go to the next line.
432     (when (looking-at "[ \t]*\n")
433       (forward-line 1))
434     (if mml
435         (progn
436           (while (and (> count 0) (not (eobp)))
437             (if (re-search-forward "<#\\(/\\)?mml." nil t)
438                 (setq count (+ count (if (match-beginning 1) -1 1)))
439               (goto-char (point-max))))
440           (mml-buffer-substring-no-properties-except-hard-newlines
441            beg (if (> count 0)
442                    (point)
443                  (match-beginning 0))))
444       (if (re-search-forward
445            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
446           (prog1
447               (mml-buffer-substring-no-properties-except-hard-newlines
448                beg (match-beginning 0))
449             (if (or (not (match-beginning 1))
450                     (equal (match-string 2) "multipart"))
451                 (goto-char (match-beginning 0))
452               (when (looking-at "[ \t]*\n")
453                 (forward-line 1))))
454         (mml-buffer-substring-no-properties-except-hard-newlines
455          beg (goto-char (point-max)))))))
456
457 (defvar mml-boundary nil)
458 (defvar mml-base-boundary "-=-=")
459 (defvar mml-multipart-number 0)
460 (defvar mml-inhibit-compute-boundary nil)
461
462 (defun mml-generate-mime (&optional multipart-type)
463   "Generate a MIME message based on the current MML document.
464 MULTIPART-TYPE defaults to \"mixed\", but can also
465 be \"related\" or \"alternate\"."
466   (let ((cont (mml-parse))
467         (mml-multipart-number mml-multipart-number)
468         (options message-options))
469     (if (not cont)
470         nil
471       (prog1
472           (mm-with-multibyte-buffer
473             (setq message-options options)
474             (if (and (consp (car cont))
475                      (= (length cont) 1))
476                 (mml-generate-mime-1 (car cont))
477               (mml-generate-mime-1
478                (nconc (list 'multipart (cons 'type (or multipart-type "mixed")))
479                       cont)))
480             (setq options message-options)
481             (buffer-string))
482         (setq message-options options)))))
483
484 (defun mml-generate-mime-1 (cont)
485   (let ((mm-use-ultra-safe-encoding
486          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
487     (save-restriction
488       (narrow-to-region (point) (point))
489       (mml-tweak-part cont)
490       (cond
491        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
492         (let* ((raw (cdr (assq 'raw cont)))
493                (filename (cdr (assq 'filename cont)))
494                (type (or (cdr (assq 'type cont))
495                          (if filename
496                              (or (mm-default-file-encoding filename)
497                                  "application/octet-stream")
498                            "text/plain")))
499                (charset (cdr (assq 'charset cont)))
500                (coding (mm-charset-to-coding-system charset))
501                encoding flowed coded)
502           (cond ((eq coding 'ascii)
503                  (setq charset nil
504                        coding nil))
505                 (charset
506                  ;; The value of `charset' might be a bogus alias that
507                  ;; `mm-charset-synonym-alist' provides, like `utf8',
508                  ;; so we prefer the MIME charset that Emacs knows for
509                  ;; the coding system `coding'.
510                  (setq charset (or (mm-coding-system-to-mime-charset coding)
511                                    (intern (downcase charset))))))
512           (if (and (not raw)
513                    (member (car (split-string type "/")) '("text" "message")))
514               (progn
515                 (with-temp-buffer
516                   (cond
517                    ((cdr (assq 'buffer cont))
518                     (insert-buffer-substring (cdr (assq 'buffer cont))))
519                    ((and filename
520                          (not (equal (cdr (assq 'nofile cont)) "yes")))
521                     (let ((coding-system-for-read coding))
522                       (mm-insert-file-contents filename)))
523                    ((eq 'mml (car cont))
524                     (insert (cdr (assq 'contents cont))))
525                    (t
526                     (save-restriction
527                       (narrow-to-region (point) (point))
528                       (insert (cdr (assq 'contents cont)))
529                       ;; Remove quotes from quoted tags.
530                       (goto-char (point-min))
531                       (while (re-search-forward
532                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\|secure\\)"
533                               nil t)
534                         (delete-region (+ (match-beginning 0) 2)
535                                        (+ (match-beginning 0) 3))))))
536                   (cond
537                    ((eq (car cont) 'mml)
538                     (let ((mml-boundary (mml-compute-boundary cont))
539                           ;; It is necessary for the case where this
540                           ;; function is called recursively since
541                           ;; `m-g-d-t' will be bound to "message/rfc822"
542                           ;; when encoding an article to be forwarded.
543                           (mml-generate-default-type "text/plain"))
544                       (mml-to-mime)
545                       ;; Update handle so mml-compute-boundary can
546                       ;; detect collisions with the nested parts.
547                       (unless mml-inhibit-compute-boundary
548                         (setcdr (assoc 'contents cont) (buffer-string))))
549                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
550                       ;; ignore 0x1b, it is part of iso-2022-jp
551                       (setq encoding (mm-body-7-or-8))))
552                    ((string= (car (split-string type "/")) "message")
553                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
554                       ;; ignore 0x1b, it is part of iso-2022-jp
555                       (setq encoding (mm-body-7-or-8))))
556                    (t
557                     ;; Only perform format=flowed filling on text/plain
558                     ;; parts where there either isn't a format parameter
559                     ;; in the mml tag or it says "flowed" and there
560                     ;; actually are hard newlines in the text.
561                     (let (use-hard-newlines)
562                       (when (and mml-enable-flowed
563                                  (string= type "text/plain")
564                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
565                                  (or (null (assq 'format cont))
566                                      (string= (cdr (assq 'format cont))
567                                               "flowed"))
568                                  (setq use-hard-newlines
569                                        (text-property-any
570                                         (point-min) (point-max) 'hard 't)))
571                         (fill-flowed-encode)
572                         ;; Indicate that `mml-insert-mime-headers' should
573                         ;; insert a "; format=flowed" string unless the
574                         ;; user has already specified it.
575                         (setq flowed (null (assq 'format cont)))))
576                     ;; Prefer `utf-8' for text/calendar parts.
577                     (if (or charset
578                             (not (string= type "text/calendar")))
579                         (setq charset (mm-encode-body charset))
580                       (let ((mm-coding-system-priorities
581                              (cons 'utf-8 mm-coding-system-priorities)))
582                         (setq charset (mm-encode-body))))
583                     (setq encoding (mm-body-encoding
584                                     charset (cdr (assq 'encoding cont))))))
585                   (setq coded (buffer-string)))
586                 (mml-insert-mime-headers cont type charset encoding flowed)
587                 (insert "\n")
588                 (insert coded))
589             (mm-with-unibyte-buffer
590               (cond
591                ((cdr (assq 'buffer cont))
592                 (insert (mm-string-as-unibyte
593                          (with-current-buffer (cdr (assq 'buffer cont))
594                            (buffer-string)))))
595                ((and filename
596                      (not (equal (cdr (assq 'nofile cont)) "yes")))
597                 (let ((coding-system-for-read mm-binary-coding-system))
598                   (mm-insert-file-contents filename nil nil nil nil t))
599                 (unless charset
600                   (setq charset (mm-coding-system-to-mime-charset
601                                  (mm-find-buffer-file-coding-system
602                                   filename)))))
603                (t
604                 (let ((contents (cdr (assq 'contents cont))))
605                   (if (if (featurep 'xemacs)
606                           (string-match "[^\000-\377]" contents)
607                         (mm-multibyte-string-p contents))
608                       (progn
609                         (mm-enable-multibyte)
610                         (insert contents)
611                         (unless raw
612                           (setq charset (mm-encode-body charset))))
613                     (insert contents)))))
614               (if (setq encoding (cdr (assq 'encoding cont)))
615                   (setq encoding (intern (downcase encoding))))
616               (setq encoding (mm-encode-buffer type encoding)
617                     coded (mm-string-as-multibyte (buffer-string))))
618             (mml-insert-mime-headers cont type charset encoding nil)
619             (insert "\n" coded))))
620        ((eq (car cont) 'external)
621         (insert "Content-Type: message/external-body")
622         (let ((parameters (mml-parameter-string
623                            cont '(expiration size permission)))
624               (name (cdr (assq 'name cont)))
625               (url (cdr (assq 'url cont))))
626           (when name
627             (setq name (mml-parse-file-name name))
628             (if (stringp name)
629                 (mml-insert-parameter
630                  (mail-header-encode-parameter "name" name)
631                  "access-type=local-file")
632               (mml-insert-parameter
633                (mail-header-encode-parameter
634                 "name" (file-name-nondirectory (nth 2 name)))
635                (mail-header-encode-parameter "site" (nth 1 name))
636                (mail-header-encode-parameter
637                 "directory" (file-name-directory (nth 2 name))))
638               (mml-insert-parameter
639                (concat "access-type="
640                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
641                            "anon-ftp"
642                          "ftp")))))
643           (when url
644             (mml-insert-parameter
645              (mail-header-encode-parameter "url" url)
646              "access-type=url"))
647           (when parameters
648             (mml-insert-parameter-string
649              cont '(expiration size permission)))
650           (insert "\n\n")
651           (insert "Content-Type: "
652                   (or (cdr (assq 'type cont))
653                       (if name
654                           (or (mm-default-file-encoding name)
655                               "application/octet-stream")
656                         "text/plain"))
657                   "\n")
658           (insert "Content-ID: " (message-make-message-id) "\n")
659           (insert "Content-Transfer-Encoding: "
660                   (or (cdr (assq 'encoding cont)) "binary"))
661           (insert "\n\n")
662           (insert (or (cdr (assq 'contents cont))))
663           (insert "\n")))
664        ((eq (car cont) 'multipart)
665         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
666                (mml-generate-default-type (if (equal type "digest")
667                                               "message/rfc822"
668                                             "text/plain"))
669                (handler (assoc type mml-generate-multipart-alist)))
670           (if handler
671               (funcall (cdr handler) cont)
672             ;; No specific handler.  Use default one.
673             (let ((mml-boundary (mml-compute-boundary cont)))
674               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
675                               type mml-boundary)
676                       (if (cdr (assq 'start cont))
677                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
678                         "\n"))
679               (let ((cont cont) part)
680                 (while (setq part (pop cont))
681                   ;; Skip `multipart' and attributes.
682                   (when (and (consp part) (consp (cdr part)))
683                     (insert "\n--" mml-boundary "\n")
684                     (mml-generate-mime-1 part)
685                     (goto-char (point-max)))))
686               (insert "\n--" mml-boundary "--\n")))))
687        (t
688         (error "Invalid element: %S" cont)))
689       ;; handle sign & encrypt tags in a semi-smart way.
690       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
691             (encrypt-item (assoc (cdr (assq 'encrypt cont))
692                                  mml-encrypt-alist))
693             sender recipients)
694         (when (or sign-item encrypt-item)
695           (when (setq sender (cdr (assq 'sender cont)))
696             (message-options-set 'mml-sender sender)
697             (message-options-set 'message-sender sender))
698           (if (setq recipients (cdr (assq 'recipients cont)))
699               (message-options-set 'message-recipients recipients))
700           (let ((style (mml-signencrypt-style
701                         (first (or sign-item encrypt-item)))))
702             ;; check if: we're both signing & encrypting, both methods
703             ;; are the same (why would they be different?!), and that
704             ;; the signencrypt style allows for combined operation.
705             (if (and sign-item encrypt-item (equal (first sign-item)
706                                                    (first encrypt-item))
707                      (equal style 'combined))
708                 (funcall (nth 1 encrypt-item) cont t)
709               ;; otherwise, revert to the old behavior.
710               (when sign-item
711                 (funcall (nth 1 sign-item) cont))
712               (when encrypt-item
713                 (funcall (nth 1 encrypt-item) cont)))))))))
714
715 (defun mml-compute-boundary (cont)
716   "Return a unique boundary that does not exist in CONT."
717   (let ((mml-boundary (funcall mml-boundary-function
718                                (incf mml-multipart-number))))
719     (unless mml-inhibit-compute-boundary
720       ;; This function tries again and again until it has found
721       ;; a unique boundary.
722       (while (not (catch 'not-unique
723                     (mml-compute-boundary-1 cont)))))
724     mml-boundary))
725
726 (defun mml-compute-boundary-1 (cont)
727   (cond
728    ((member (car cont) '(part mml))
729     (mm-with-multibyte-buffer
730       (let ((mml-inhibit-compute-boundary t)
731             (mml-multipart-number 0)
732             mml-sign-alist mml-encrypt-alist)
733         (mml-generate-mime-1 cont))
734       (goto-char (point-min))
735       (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
736                                nil t)
737         (setq mml-boundary (funcall mml-boundary-function
738                                     (incf mml-multipart-number)))
739         (throw 'not-unique nil))))
740    ((eq (car cont) 'multipart)
741     (mapc 'mml-compute-boundary-1 (cddr cont))))
742   t)
743
744 (defun mml-make-boundary (number)
745   (concat (make-string (% number 60) ?=)
746           (if (> number 17)
747               (format "%x" number)
748             "")
749           mml-base-boundary))
750
751 (defun mml-content-disposition (type &optional filename)
752   "Return a default disposition name suitable to TYPE or FILENAME."
753   (let ((defs mml-content-disposition-alist)
754         disposition def types)
755     (while (and (not disposition) defs)
756       (setq def (pop defs))
757       (cond ((stringp (car def))
758              (when (and filename
759                         (string-match (car def) filename))
760                (setq disposition (cdr def))))
761             ((consp (cdr def))
762              (when (string= (car (setq types (split-string type "/")))
763                             (car def))
764                (setq type (cadr types)
765                      types (cdr def))
766                (while (and (not disposition) types)
767                  (setq def (pop types))
768                  (when (or (eq (car def) t) (string= type (car def)))
769                    (setq disposition (cdr def))))))
770             (t
771              (when (or (eq (car def) t) (string= type (car def)))
772                (setq disposition (cdr def))))))
773     (or disposition "attachment")))
774
775 (defun mml-insert-mime-headers (cont type charset encoding flowed)
776   (let (parameters id disposition description)
777     (setq parameters
778           (mml-parameter-string
779            cont mml-content-type-parameters))
780     (when (or charset
781               parameters
782               flowed
783               (not (equal type mml-generate-default-type))
784               mml-insert-mime-headers-always)
785       (when (consp charset)
786         (error
787          "Can't encode a part with several charsets"))
788       (insert "Content-Type: " type)
789       (when charset
790         (mml-insert-parameter
791          (mail-header-encode-parameter "charset" (symbol-name charset))))
792       (when flowed
793         (mml-insert-parameter "format=flowed"))
794       (when parameters
795         (mml-insert-parameter-string
796          cont mml-content-type-parameters))
797       (insert "\n"))
798     (when (setq id (cdr (assq 'id cont)))
799       (insert "Content-ID: " id "\n"))
800     (setq parameters
801           (mml-parameter-string
802            cont mml-content-disposition-parameters))
803     (when (or (setq disposition (cdr (assq 'disposition cont)))
804               parameters)
805       (insert "Content-Disposition: "
806               (or disposition
807                   (mml-content-disposition
808                    type
809                    (or (cdr (assq 'recipient-filename cont))
810                        (cdr (assq 'filename cont))))))
811       (when parameters
812         (mml-insert-parameter-string
813          cont mml-content-disposition-parameters))
814       (insert "\n"))
815     (unless (eq encoding '7bit)
816       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
817     (when (setq description (cdr (assq 'description cont)))
818       (insert "Content-Description: ")
819       (setq description (prog1
820                             (point)
821                           (insert description "\n")))
822       (mail-encode-encoded-word-region description (point)))))
823
824 (defun mml-parameter-string (cont types)
825   (let ((string "")
826         value type)
827     (while (setq type (pop types))
828       (when (setq value (cdr (assq type cont)))
829         ;; Strip directory component from the filename parameter.
830         (when (eq type 'filename)
831           (setq value (file-name-nondirectory value)))
832         (setq string (concat string "; "
833                              (mail-header-encode-parameter
834                               (symbol-name type) value)))))
835     (when (not (zerop (length string)))
836       string)))
837
838 (defun mml-insert-parameter-string (cont types)
839   (let (value type)
840     (while (setq type (pop types))
841       (when (setq value (cdr (assq type cont)))
842         ;; Strip directory component from the filename parameter.
843         (when (eq type 'filename)
844           (setq value (file-name-nondirectory value)))
845         (mml-insert-parameter
846          (mail-header-encode-parameter
847           (symbol-name type) value))))))
848
849 (defvar ange-ftp-name-format)
850 (defvar efs-path-regexp)
851
852 (defun mml-parse-file-name (path)
853   (if (if (boundp 'efs-path-regexp)
854           (string-match efs-path-regexp path)
855         (if (boundp 'ange-ftp-name-format)
856             (string-match (car ange-ftp-name-format) path)))
857       (list (match-string 1 path) (match-string 2 path)
858             (substring path (1+ (match-end 2))))
859     path))
860
861 (defun mml-insert-buffer (buffer)
862   "Insert BUFFER at point and quote any MML markup."
863   (save-restriction
864     (narrow-to-region (point) (point))
865     (insert-buffer-substring buffer)
866     (mml-quote-region (point-min) (point-max))
867     (goto-char (point-max))))
868
869 ;;;
870 ;;; Transforming MIME to MML
871 ;;;
872
873 ;; message-narrow-to-head autoloads message.
874 (declare-function message-remove-header "message"
875                   (header &optional is-regexp first reverse))
876
877 (defun mime-to-mml (&optional handles)
878   "Translate the current buffer (which should be a message) into MML.
879 If HANDLES is non-nil, use it instead reparsing the buffer."
880   ;; First decode the head.
881   (save-restriction
882     (message-narrow-to-head)
883     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
884       (mail-decode-encoded-word-region (point-min) (point-max))))
885   (unless handles
886     (setq handles (mm-dissect-buffer t)))
887   (goto-char (point-min))
888   (search-forward "\n\n" nil t)
889   (delete-region (point) (point-max))
890   (if (stringp (car handles))
891       (mml-insert-mime handles)
892     (mml-insert-mime handles t))
893   (mm-destroy-parts handles)
894   (save-restriction
895     (message-narrow-to-head)
896     ;; Remove them, they are confusing.
897     (message-remove-header "Content-Type")
898     (message-remove-header "MIME-Version")
899     (message-remove-header "Content-Disposition")
900     (message-remove-header "Content-Transfer-Encoding")))
901
902 (autoload 'message-encode-message-body "message")
903 (declare-function message-narrow-to-headers-or-head "message" ())
904
905 ;;;###autoload
906 (defun mml-to-mime ()
907   "Translate the current buffer from MML to MIME."
908   ;; `message-encode-message-body' will insert an encoded Content-Description
909   ;; header in the message header if the body contains a single part
910   ;; that is specified by a user with a MML tag containing a description
911   ;; token.  So, we encode the message header first to prevent the encoded
912   ;; Content-Description header from being encoded again.
913   (save-restriction
914     (message-narrow-to-headers-or-head)
915     ;; Skip past any From_ headers.
916     (while (looking-at "From ")
917       (forward-line 1))
918     (let ((mail-parse-charset message-default-charset))
919       (mail-encode-encoded-word-buffer)))
920   (message-encode-message-body))
921
922 (defun mml-insert-mime (handle &optional no-markup)
923   (let (textp buffer mmlp)
924     ;; Determine type and stuff.
925     (unless (stringp (car handle))
926       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
927         (with-current-buffer (setq buffer (mml-generate-new-buffer " *mml*"))
928           (if (eq (mail-content-type-get (mm-handle-type handle) 'charset)
929                   'gnus-decoded)
930               ;; A part that mm-uu dissected from a non-MIME message
931               ;; because of `gnus-article-emulate-mime'.
932               (progn
933                 (mm-enable-multibyte)
934                 (insert-buffer-substring (mm-handle-buffer handle)))
935             (mm-insert-part handle 'no-cache)
936             (if (setq mmlp (equal (mm-handle-media-type handle)
937                                   "message/rfc822"))
938                 (mime-to-mml))))))
939     (if mmlp
940         (mml-insert-mml-markup handle nil t t)
941       (unless (and no-markup
942                    (equal (mm-handle-media-type handle) "text/plain"))
943         (mml-insert-mml-markup handle buffer textp)))
944     (cond
945      (mmlp
946       (insert-buffer-substring buffer)
947       (goto-char (point-max))
948       (insert "<#/mml>\n"))
949      ((stringp (car handle))
950       (mapc 'mml-insert-mime (cdr handle))
951       (insert "<#/multipart>\n"))
952      (textp
953       (let ((charset (mail-content-type-get
954                       (mm-handle-type handle) 'charset))
955             (start (point)))
956         (if (eq charset 'gnus-decoded)
957             (mm-insert-part handle)
958           (insert (mm-decode-string (mm-get-part handle) charset)))
959         (mml-quote-region start (point)))
960       (goto-char (point-max)))
961      (t
962       (insert "<#/part>\n")))))
963
964 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
965   "Take a MIME handle and insert an MML tag."
966   (if (stringp (car handle))
967       (progn
968         (insert "<#multipart type=" (mm-handle-media-subtype handle))
969         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
970           (when start
971             (insert " start=\"" start "\"")))
972         (insert ">\n"))
973     (if mmlp
974         (insert "<#mml type=" (mm-handle-media-type handle))
975       (insert "<#part type=" (mm-handle-media-type handle)))
976     (dolist (elem (append (cdr (mm-handle-type handle))
977                           (cdr (mm-handle-disposition handle))))
978       (unless (symbolp (cdr elem))
979         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
980     (when (mm-handle-id handle)
981       (insert " id=\"" (mm-handle-id handle) "\""))
982     (when (mm-handle-disposition handle)
983       (insert " disposition=" (car (mm-handle-disposition handle))))
984     (when buffer
985       (insert " buffer=\"" (buffer-name buffer) "\""))
986     (when nofile
987       (insert " nofile=yes"))
988     (when (mm-handle-description handle)
989       (insert " description=\"" (mm-handle-description handle) "\""))
990     (insert ">\n")))
991
992 (defun mml-insert-parameter (&rest parameters)
993   "Insert PARAMETERS in a nice way."
994   (let (start end)
995     (dolist (param parameters)
996       (insert ";")
997       (setq start (point))
998       (insert " " param)
999       (setq end (point))
1000       (goto-char start)
1001       (end-of-line)
1002       (if (> (current-column) 76)
1003           (progn
1004             (goto-char start)
1005             (insert "\n")
1006             (goto-char (1+ end)))
1007         (goto-char end)))))
1008
1009 ;;;
1010 ;;; Mode for inserting and editing MML forms
1011 ;;;
1012
1013 (defvar mml-mode-map
1014   (let ((sign (make-sparse-keymap))
1015         (encrypt (make-sparse-keymap))
1016         (signpart (make-sparse-keymap))
1017         (encryptpart (make-sparse-keymap))
1018         (map (make-sparse-keymap))
1019         (main (make-sparse-keymap)))
1020     (define-key map "\C-s" 'mml-secure-message-sign)
1021     (define-key map "\C-c" 'mml-secure-message-encrypt)
1022     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
1023     (define-key map "\C-p\C-s" 'mml-secure-sign)
1024     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
1025     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
1026     (define-key sign "o" 'mml-secure-message-sign-pgp)
1027     (define-key sign "s" 'mml-secure-message-sign-smime)
1028     (define-key signpart "p" 'mml-secure-sign-pgpmime)
1029     (define-key signpart "o" 'mml-secure-sign-pgp)
1030     (define-key signpart "s" 'mml-secure-sign-smime)
1031     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
1032     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
1033     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
1034     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
1035     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
1036     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
1037     (define-key map "\C-n" 'mml-unsecure-message)
1038     (define-key map "f" 'mml-attach-file)
1039     (define-key map "b" 'mml-attach-buffer)
1040     (define-key map "e" 'mml-attach-external)
1041     (define-key map "q" 'mml-quote-region)
1042     (define-key map "m" 'mml-insert-multipart)
1043     (define-key map "p" 'mml-insert-part)
1044     (define-key map "v" 'mml-validate)
1045     (define-key map "P" 'mml-preview)
1046     (define-key map "s" sign)
1047     (define-key map "S" signpart)
1048     (define-key map "c" encrypt)
1049     (define-key map "C" encryptpart)
1050     ;;(define-key map "n" 'mml-narrow-to-part)
1051     ;; `M-m' conflicts with `back-to-indentation'.
1052     ;; (define-key main "\M-m" map)
1053     (define-key main "\C-c\C-m" map)
1054     main))
1055
1056 (easy-menu-define
1057   mml-menu mml-mode-map ""
1058   `("Attachments"
1059     ["Attach File..." mml-attach-file
1060      ,@(if (featurep 'xemacs) '(t)
1061          '(:help "Attach a file at point"))]
1062     ["Attach Buffer..." mml-attach-buffer
1063      ,@(if (featurep 'xemacs) '(t)
1064          '(:help "Attach a buffer to the outgoing message"))]
1065     ["Attach External..." mml-attach-external
1066      ,@(if (featurep 'xemacs) '(t)
1067          '(:help "Attach reference to an external file"))]
1068     ;; FIXME: Is it possible to do this without using
1069     ;; `gnus-gcc-externalize-attachments'?
1070     ["Externalize Attachments"
1071      (lambda ()
1072        (interactive)
1073        (if (not (and (boundp 'gnus-gcc-externalize-attachments)
1074                      (memq gnus-gcc-externalize-attachments
1075                            '(all t nil))))
1076            ;; Stupid workaround for XEmacs not honoring :visible.
1077            (message "Can't handle this value of `gnus-gcc-externalize-attachments'")
1078          (setq gnus-gcc-externalize-attachments
1079                (not gnus-gcc-externalize-attachments))
1080          (message "gnus-gcc-externalize-attachments is `%s'."
1081                   gnus-gcc-externalize-attachments)))
1082      ;; XEmacs barfs on :visible.
1083      ,@(if (featurep 'xemacs) nil
1084          '(:visible (and (boundp 'gnus-gcc-externalize-attachments)
1085                          (memq gnus-gcc-externalize-attachments
1086                                '(all t nil)))))
1087      :style toggle
1088      :selected gnus-gcc-externalize-attachments
1089      ,@(if (featurep 'xemacs) nil
1090          '(:help "Save attachments as external parts in Gcc copies"))]
1091     "----"
1092     ;;
1093     ("Change Security Method"
1094      ["PGP/MIME"
1095       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
1096       ,@(if (featurep 'xemacs) nil
1097           '(:help "Set Security Method to PGP/MIME"))
1098       :style radio
1099       :selected (equal mml-secure-method "pgpmime") ]
1100      ["S/MIME"
1101       (lambda () (interactive) (setq mml-secure-method "smime"))
1102       ,@(if (featurep 'xemacs) nil
1103           '(:help "Set Security Method to S/MIME"))
1104       :style radio
1105       :selected (equal mml-secure-method "smime") ]
1106      ["Inline PGP"
1107       (lambda () (interactive) (setq mml-secure-method "pgp"))
1108       ,@(if (featurep 'xemacs) nil
1109           '(:help "Set Security Method to inline PGP"))
1110       :style radio
1111       :selected (equal mml-secure-method "pgp") ] )
1112     ;;
1113     ["Sign Message" mml-secure-message-sign t]
1114     ["Encrypt Message" mml-secure-message-encrypt t]
1115     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
1116     ["Encrypt/Sign off" mml-unsecure-message
1117      ,@(if (featurep 'xemacs) '(t)
1118          '(:help "Don't Encrypt/Sign Message"))]
1119     ;; Do we have separate encrypt and encrypt/sign commands for parts?
1120     ["Sign Part" mml-secure-sign t]
1121     ["Encrypt Part" mml-secure-encrypt t]
1122     "----"
1123     ;; Maybe we could remove these, because people who write MML most probably
1124     ;; don't use the menu:
1125     ["Insert Part..." mml-insert-part
1126      :active (message-in-body-p)]
1127     ["Insert Multipart..." mml-insert-multipart
1128      :active (message-in-body-p)]
1129     ;;
1130     ;;["Narrow" mml-narrow-to-part t]
1131     ["Quote MML in region" mml-quote-region
1132      :active (message-mark-active-p)
1133      ,@(if (featurep 'xemacs) nil
1134          '(:help "Quote MML tags in region"))]
1135     ["Validate MML" mml-validate t]
1136     ["Preview" mml-preview t]
1137     "----"
1138     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
1139      ,@(if (featurep 'xemacs) '(t)
1140          '(:help "Display the Emacs MIME manual"))]
1141     ["PGG manual" (lambda () (interactive) (message-info mml2015-use))
1142      ;; XEmacs barfs on :visible.
1143      ,@(if (featurep 'xemacs) nil
1144          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'pgg))))
1145      ,@(if (featurep 'xemacs) '(t)
1146          '(:help "Display the PGG manual"))]
1147     ["EasyPG manual" (lambda () (interactive) (require 'mml2015) (message-info mml2015-use))
1148      ;; XEmacs barfs on :visible.
1149      ,@(if (featurep 'xemacs) nil
1150          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'epg))))
1151      ,@(if (featurep 'xemacs) '(t)
1152          '(:help "Display the EasyPG manual"))]))
1153
1154 (define-minor-mode mml-mode
1155   "Minor mode for editing MML.
1156 MML is the MIME Meta Language, a minor mode for composing MIME articles.
1157 See Info node `(emacs-mime)Composing'.
1158
1159 \\{mml-mode-map}"
1160   :lighter " MML" :keymap mml-mode-map
1161   (when mml-mode
1162     (easy-menu-add mml-menu mml-mode-map)
1163     (when (boundp 'dnd-protocol-alist)
1164       (set (make-local-variable 'dnd-protocol-alist)
1165            (append mml-dnd-protocol-alist dnd-protocol-alist)))))
1166
1167 ;;;
1168 ;;; Helper functions for reading MIME stuff from the minibuffer and
1169 ;;; inserting stuff to the buffer.
1170 ;;;
1171
1172 (defcustom mml-default-directory mm-default-directory
1173   "The default directory where mml will find files.
1174 If not set, `default-directory' will be used."
1175   :type '(choice directory (const :tag "Default" nil))
1176   :version "23.1" ;; No Gnus
1177   :group 'message)
1178
1179 (defun mml-minibuffer-read-file (prompt)
1180   (let* ((completion-ignored-extensions nil)
1181          (file (read-file-name prompt
1182                                (or mml-default-directory default-directory)
1183                                nil t)))
1184     ;; Prevent some common errors.  This is inspired by similar code in
1185     ;; VM.
1186     (when (file-directory-p file)
1187       (error "%s is a directory, cannot attach" file))
1188     (unless (file-exists-p file)
1189       (error "No such file: %s" file))
1190     (unless (file-readable-p file)
1191       (error "Permission denied: %s" file))
1192     file))
1193
1194 (declare-function mailcap-parse-mimetypes "mailcap" (&optional path force))
1195 (declare-function mailcap-mime-types "mailcap" ())
1196
1197 (defun mml-minibuffer-read-type (name &optional default)
1198   (require 'mailcap)
1199   (mailcap-parse-mimetypes)
1200   (let* ((default (or default
1201                       (mm-default-file-encoding name)
1202                       ;; Perhaps here we should check what the file
1203                       ;; looks like, and offer text/plain if it looks
1204                       ;; like text/plain.
1205                       "application/octet-stream"))
1206          (string (gnus-completing-read
1207                   "Content type"
1208                   (mailcap-mime-types)
1209                   nil nil nil default)))
1210     (if (not (equal string ""))
1211         string
1212       default)))
1213
1214 (defun mml-minibuffer-read-description (&optional default)
1215   (let ((description (read-string "One line description: " default)))
1216     (when (string-match "\\`[ \t]*\\'" description)
1217       (setq description nil))
1218     description))
1219
1220 (defun mml-minibuffer-read-disposition (type &optional default filename)
1221   (unless default
1222     (setq default (mml-content-disposition type filename)))
1223   (let ((disposition (gnus-completing-read
1224                       "Disposition"
1225                       '("attachment" "inline")
1226                       t nil nil default)))
1227     (if (not (equal disposition ""))
1228         disposition
1229       default)))
1230
1231 (defun mml-quote-region (beg end)
1232   "Quote the MML tags in the region."
1233   (interactive "r")
1234   (save-excursion
1235     (save-restriction
1236       ;; Temporarily narrow the region to defend from changes
1237       ;; invalidating END.
1238       (narrow-to-region beg end)
1239       (goto-char (point-min))
1240       ;; Quote parts.
1241       (while (re-search-forward
1242               "<#!*/?\\(multipart\\|part\\|external\\|mml\\|secure\\)" nil t)
1243         ;; Insert ! after the #.
1244         (goto-char (+ (match-beginning 0) 2))
1245         (insert "!")))))
1246
1247 (defun mml-insert-tag (name &rest plist)
1248   "Insert an MML tag described by NAME and PLIST."
1249   (when (symbolp name)
1250     (setq name (symbol-name name)))
1251   (insert "<#" name)
1252   (while plist
1253     (let ((key (pop plist))
1254           (value (pop plist)))
1255       (when value
1256         ;; Quote VALUE if it contains suspicious characters.
1257         (when (string-match "[\"'\\~/*;() \t\n]" value)
1258           (setq value (with-output-to-string
1259                         (let (print-escape-nonascii)
1260                           (prin1 value)))))
1261         (insert (format " %s=%s" key value)))))
1262   (insert ">\n"))
1263
1264 (defun mml-insert-empty-tag (name &rest plist)
1265   "Insert an empty MML tag described by NAME and PLIST."
1266   (when (symbolp name)
1267     (setq name (symbol-name name)))
1268   (apply #'mml-insert-tag name plist)
1269   (insert "<#/" name ">\n"))
1270
1271 ;;; Attachment functions.
1272
1273 (defcustom mml-dnd-protocol-alist
1274   '(("^file:///" . mml-dnd-attach-file)
1275     ("^file://"  . dnd-open-file)
1276     ("^file:"    . mml-dnd-attach-file))
1277   "The functions to call when a drop in `mml-mode' is made.
1278 See `dnd-protocol-alist' for more information.  When nil, behave
1279 as in other buffers."
1280   :type '(choice (repeat (cons (regexp) (function)))
1281                  (const :tag "Behave as in other buffers" nil))
1282   :version "22.1" ;; Gnus 5.10.9
1283   :group 'message)
1284
1285 (defcustom mml-dnd-attach-options nil
1286   "Which options should be queried when attaching a file via drag and drop.
1287
1288 If it is a list, valid members are `type', `description' and
1289 `disposition'.  `disposition' implies `type'.  If it is nil,
1290 don't ask for options.  If it is t, ask the user whether or not
1291 to specify options."
1292   :type '(choice
1293           (const :tag "None" nil)
1294           (const :tag "Query" t)
1295           (list :value (type description disposition)
1296            (set :inline t
1297                 (const type)
1298                 (const description)
1299                 (const disposition))))
1300   :version "22.1" ;; Gnus 5.10.9
1301   :group 'message)
1302
1303 ;;;###autoload
1304 (defun mml-attach-file (file &optional type description disposition)
1305   "Attach a file to the outgoing MIME message.
1306 The file is not inserted or encoded until you send the message with
1307 `\\[message-send-and-exit]' or `\\[message-send]' in Message mode,
1308 or `\\[mail-send-and-exit]' or `\\[mail-send]' in Mail mode.
1309
1310 FILE is the name of the file to attach.  TYPE is its
1311 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1312 is a one-line description of the attachment.  The DISPOSITION
1313 specifies how the attachment is intended to be displayed.  It can
1314 be either \"inline\" (displayed automatically within the message
1315 body) or \"attachment\" (separate from the body)."
1316   (interactive
1317    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1318           (type (mml-minibuffer-read-type file))
1319           (description (mml-minibuffer-read-description))
1320           (disposition (mml-minibuffer-read-disposition type nil file)))
1321      (list file type description disposition)))
1322   ;; If in the message header, attach at the end and leave point unchanged.
1323   (let ((head (unless (message-in-body-p) (point))))
1324     (if head (goto-char (point-max)))
1325     (mml-insert-empty-tag 'part
1326                           'type type
1327                           ;; icicles redefines read-file-name and returns a
1328                           ;; string w/ text properties :-/
1329                           'filename (mm-substring-no-properties file)
1330                           'disposition (or disposition "attachment")
1331                           'description description)
1332     ;; When using Mail mode, make sure it does the mime encoding
1333     ;; when you send the message.
1334     (or (eq mail-user-agent 'message-user-agent)
1335         (setq mail-encode-mml t))
1336     (when head
1337       (unless (pos-visible-in-window-p)
1338         (message "The file \"%s\" has been attached at the end of the message"
1339                  (file-name-nondirectory file)))
1340       (goto-char head))))
1341
1342 (defun mml-dnd-attach-file (uri action)
1343   "Attach a drag and drop file.
1344
1345 Ask for type, description or disposition according to
1346 `mml-dnd-attach-options'."
1347   (let ((file (dnd-get-local-file-name uri t)))
1348     (when (and file (file-regular-p file))
1349       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1350             type description disposition)
1351         (setq mml-dnd-attach-options
1352               (when (and (eq mml-dnd-attach-options t)
1353                          (not
1354                           (y-or-n-p
1355                            "Use default type, disposition and description? ")))
1356                 '(type description disposition)))
1357         (when (or (memq 'type mml-dnd-attach-options)
1358                   (memq 'disposition mml-dnd-attach-options))
1359           (setq type (mml-minibuffer-read-type file)))
1360         (when (memq 'description mml-dnd-attach-options)
1361           (setq description (mml-minibuffer-read-description)))
1362         (when (memq 'disposition mml-dnd-attach-options)
1363           (setq disposition (mml-minibuffer-read-disposition type nil file)))
1364         (mml-attach-file file type description disposition)))))
1365
1366 (defun mml-attach-buffer (buffer &optional type description disposition)
1367   "Attach a buffer to the outgoing MIME message.
1368 BUFFER is the name of the buffer to attach.  See
1369 `mml-attach-file' for details of operation."
1370   (interactive
1371    (let* ((buffer (read-buffer "Attach buffer: "))
1372           (type (mml-minibuffer-read-type buffer "text/plain"))
1373           (description (mml-minibuffer-read-description))
1374           (disposition (mml-minibuffer-read-disposition type nil)))
1375      (list buffer type description disposition)))
1376   ;; If in the message header, attach at the end and leave point unchanged.
1377   (let ((head (unless (message-in-body-p) (point))))
1378     (if head (goto-char (point-max)))
1379     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1380                           'disposition disposition
1381                           'description description)
1382     ;; When using Mail mode, make sure it does the mime encoding
1383     ;; when you send the message.
1384     (or (eq mail-user-agent 'message-user-agent)
1385         (setq mail-encode-mml t))
1386     (when head
1387       (unless (pos-visible-in-window-p)
1388         (message
1389          "The buffer \"%s\" has been attached at the end of the message"
1390          buffer))
1391       (goto-char head))))
1392
1393 (defun mml-attach-external (file &optional type description)
1394   "Attach an external file into the buffer.
1395 FILE is an ange-ftp/efs specification of the part location.
1396 TYPE is the MIME type to use."
1397   (interactive
1398    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1399           (type (mml-minibuffer-read-type file))
1400           (description (mml-minibuffer-read-description)))
1401      (list file type description)))
1402   ;; If in the message header, attach at the end and leave point unchanged.
1403   (let ((head (unless (message-in-body-p) (point))))
1404     (if head (goto-char (point-max)))
1405     (mml-insert-empty-tag 'external 'type type 'name file
1406                           'disposition "attachment" 'description description)
1407     ;; When using Mail mode, make sure it does the mime encoding
1408     ;; when you send the message.
1409     (or (eq mail-user-agent 'message-user-agent)
1410         (setq mail-encode-mml t))
1411     (when head
1412       (unless (pos-visible-in-window-p)
1413         (message "The file \"%s\" has been attached at the end of the message"
1414                  (file-name-nondirectory file)))
1415       (goto-char head))))
1416
1417 (defun mml-insert-multipart (&optional type)
1418   (interactive (if (message-in-body-p)
1419                    (list (gnus-completing-read "Multipart type"
1420                                                '("mixed" "alternative"
1421                                                  "digest" "parallel"
1422                                                  "signed" "encrypted")
1423                                                nil "mixed"))
1424                  (error "Use this command in the message body")))
1425   (or type
1426       (setq type "mixed"))
1427   (mml-insert-empty-tag "multipart" 'type type)
1428   ;; When using Mail mode, make sure it does the mime encoding
1429   ;; when you send the message.
1430   (or (eq mail-user-agent 'message-user-agent)
1431       (setq mail-encode-mml t))
1432   (forward-line -1))
1433
1434 (defun mml-insert-part (&optional type)
1435   (interactive (if (message-in-body-p)
1436                    (list (mml-minibuffer-read-type ""))
1437                  (error "Use this command in the message body")))
1438   ;; When using Mail mode, make sure it does the mime encoding
1439   ;; when you send the message.
1440   (or (eq mail-user-agent 'message-user-agent)
1441       (setq mail-encode-mml t))
1442   (mml-insert-tag 'part 'type type 'disposition "inline")
1443   (save-excursion
1444     (mml-insert-tag '/part)))
1445
1446 (declare-function message-subscribed-p "message" ())
1447 (declare-function message-make-mail-followup-to "message"
1448                   (&optional only-show-subscribed))
1449 (declare-function message-position-on-field "message" (header &rest afters))
1450
1451 (defun mml-preview-insert-mail-followup-to ()
1452   "Insert a Mail-Followup-To header before previewing an article.
1453 Should be adopted if code in `message-send-mail' is changed."
1454   (when (and (message-mail-p)
1455              (message-subscribed-p)
1456              (not (mail-fetch-field "mail-followup-to"))
1457              (message-make-mail-followup-to))
1458     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1459     (insert (message-make-mail-followup-to))))
1460
1461 (defvar mml-preview-buffer nil)
1462
1463 (autoload 'gnus-make-hashtable "gnus-util")
1464 (autoload 'widget-button-press "wid-edit" nil t)
1465 (declare-function widget-event-point "wid-edit" (event))
1466 ;; If gnus-buffer-configuration is bound this is loaded.
1467 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
1468 ;; Called after message-mail-p, which autoloads message.
1469 (declare-function message-news-p                "message" ())
1470 (declare-function message-options-set-recipient "message" ())
1471 (declare-function message-generate-headers      "message" (headers))
1472 (declare-function message-sort-headers          "message" ())
1473
1474 (defun mml-preview (&optional raw)
1475   "Display current buffer with Gnus, in a new buffer.
1476 If RAW, display a raw encoded MIME message.
1477
1478 The window layout for the preview buffer is controlled by the variables
1479 `special-display-buffer-names', `special-display-regexps', or
1480 `gnus-buffer-configuration' (the first match made will be used),
1481 or the `pop-to-buffer' function."
1482   (interactive "P")
1483   (setq mml-preview-buffer (generate-new-buffer
1484                             (concat (if raw "*Raw MIME preview of "
1485                                       "*MIME preview of ") (buffer-name))))
1486   (require 'gnus-msg)                 ; for gnus-setup-posting-charset
1487   (save-excursion
1488     (let* ((buf (current-buffer))
1489            (article-editing (eq major-mode 'gnus-article-edit-mode))
1490            (message-options message-options)
1491            (message-this-is-mail (message-mail-p))
1492            (message-this-is-news (message-news-p))
1493            (message-posting-charset (or (gnus-setup-posting-charset
1494                                          (save-restriction
1495                                            (message-narrow-to-headers-or-head)
1496                                            (message-fetch-field "Newsgroups")))
1497                                         message-posting-charset)))
1498       (message-options-set-recipient)
1499       (when (boundp 'gnus-buffers)
1500         (push mml-preview-buffer gnus-buffers))
1501       (save-restriction
1502         (widen)
1503         (set-buffer mml-preview-buffer)
1504         (erase-buffer)
1505         (insert-buffer-substring buf))
1506       (mml-preview-insert-mail-followup-to)
1507       (let ((message-deletable-headers (if (message-news-p)
1508                                            nil
1509                                          message-deletable-headers))
1510             (mail-header-separator (if article-editing
1511                                        ""
1512                                      mail-header-separator)))
1513         (message-generate-headers
1514          (copy-sequence (if (message-news-p)
1515                             message-required-news-headers
1516                           message-required-mail-headers)))
1517         (unless article-editing
1518           (if (re-search-forward
1519                (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1520               (replace-match "\n"))
1521           (setq mail-header-separator ""))
1522         (message-sort-headers)
1523         (mml-to-mime))
1524       (if raw
1525           (when (fboundp 'set-buffer-multibyte)
1526             (let ((s (buffer-string)))
1527               ;; Insert the content into unibyte buffer.
1528               (erase-buffer)
1529               (mm-disable-multibyte)
1530               (insert s)))
1531         (let ((gnus-newsgroup-charset (car message-posting-charset))
1532               gnus-article-prepare-hook gnus-original-article-buffer
1533               gnus-displaying-mime)
1534           (run-hooks 'gnus-article-decode-hook)
1535           (let ((gnus-newsgroup-name "dummy")
1536                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1537                                         (gnus-make-hashtable 5))))
1538             (gnus-article-prepare-display))))
1539       ;; Disable article-mode-map.
1540       (use-local-map nil)
1541       (gnus-make-local-hook 'kill-buffer-hook)
1542       (add-hook 'kill-buffer-hook
1543                 (lambda ()
1544                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1545       (setq buffer-read-only t)
1546       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1547       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1548       (local-set-key "\r"
1549                      (lambda ()
1550                        (interactive)
1551                        (widget-button-press (point))))
1552       (local-set-key gnus-mouse-2
1553                      (lambda (event)
1554                        (interactive "@e")
1555                        (widget-button-press (widget-event-point event) event)))
1556       ;; FIXME: Buffer is in article mode, but most tool bar commands won't
1557       ;; work.  Maybe only keep the following icons: search, print, quit
1558       (goto-char (point-min))))
1559   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1560            (boundp 'gnus-buffer-configuration)
1561            (assq 'mml-preview gnus-buffer-configuration))
1562       (let ((gnus-message-buffer (current-buffer)))
1563         (gnus-configure-windows 'mml-preview))
1564     (pop-to-buffer mml-preview-buffer)))
1565
1566 (defun mml-validate ()
1567   "Validate the current MML document."
1568   (interactive)
1569   (mml-parse))
1570
1571 (defun mml-tweak-part (cont)
1572   "Tweak a MML part."
1573   (let ((tweak (cdr (assq 'tweak cont)))
1574         func)
1575     (cond
1576      (tweak
1577       (setq func
1578             (or (cdr (assoc tweak mml-tweak-function-alist))
1579                 (intern tweak))))
1580      (mml-tweak-type-alist
1581       (let ((alist mml-tweak-type-alist)
1582             (type (or (cdr (assq 'type cont)) "text/plain")))
1583         (while alist
1584           (if (string-match (caar alist) type)
1585               (setq func (cdar alist)
1586                     alist nil)
1587             (setq alist (cdr alist)))))))
1588     (if func
1589         (funcall func cont)
1590       cont)
1591     (let ((alist mml-tweak-sexp-alist))
1592       (while alist
1593         (if (eval (caar alist))
1594             (funcall (cdar alist) cont))
1595         (setq alist (cdr alist)))))
1596   cont)
1597
1598 (defun mml-tweak-externalize-attachments (cont)
1599   "Tweak attached files as external parts."
1600   (let (filename-cons)
1601     (when (and (eq (car cont) 'part)
1602                (not (cdr (assq 'buffer cont)))
1603                (and (setq filename-cons (assq 'filename cont))
1604                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1605       (setcar cont 'external)
1606       (setcar filename-cons 'name))))
1607
1608 (provide 'mml)
1609
1610 ;;; mml.el ends here