cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;;; Code:
  24
  25 ;; For Emacs <22.2 and XEmacs.
  26 (eval-and-compile
  27   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  28
  29 (require 'mm-util)
  30 (require 'mm-bodies)
  31 (require 'mm-encode)
  32 (require 'mm-decode)
  33 (require 'mml-sec)
  34 (eval-when-compile (require 'cl))
  35 (eval-when-compile
  36   (when (featurep 'xemacs)
  37     (require 'easy-mmode))) ; for `define-minor-mode'
  38
  39 (autoload 'message-make-message-id "message")
  40 (declare-function gnus-setup-posting-charset "gnus-msg" (group))
  41 (autoload 'gnus-make-local-hook "gnus-util")
  42 (autoload 'gnus-completing-read "gnus-util")
  43 (autoload 'message-fetch-field "message")
  44 (autoload 'message-mark-active-p "message")
  45 (autoload 'message-info "message")
  46 (autoload 'fill-flowed-encode "flow-fill")
  47 (autoload 'message-posting-charset "message")
  48 (autoload 'dnd-get-local-file-name "dnd")
  49
  50 (autoload 'message-options-set    "message")
  51 (autoload 'message-narrow-to-head "message")
  52 (autoload 'message-in-body-p      "message")
  53 (autoload 'message-mail-p         "message")
  54
  55 (defvar gnus-article-mime-handles)
  56 (defvar gnus-mouse-2)
  57 (defvar gnus-newsrc-hashtb)
  58 (defvar message-default-charset)
  59 (defvar message-deletable-headers)
  60 (defvar message-options)
  61 (defvar message-posting-charset)
  62 (defvar message-required-mail-headers)
  63 (defvar message-required-news-headers)
  64 (defvar dnd-protocol-alist)
  65 (defvar mml-dnd-protocol-alist)
  66
  67 (defcustom mml-content-type-parameters
  68   '(name access-type expiration size permission format)
  69   "*A list of acceptable parameters in MML tag.
  70 These parameters are generated in Content-Type header if exists."
  71   :version "22.1"
  72   :type '(repeat (symbol :tag "Parameter"))
  73   :group 'message)
  74
  75 (defcustom mml-content-disposition-parameters
  76   '(filename creation-date modification-date read-date)
  77   "*A list of acceptable parameters in MML tag.
  78 These parameters are generated in Content-Disposition header if exists."
  79   :version "22.1"
  80   :type '(repeat (symbol :tag "Parameter"))
  81   :group 'message)
  82
  83 (defcustom mml-content-disposition-alist
  84   '((text (rtf . "attachment") (t . "inline"))
  85     (t . "attachment"))
  86   "Alist of MIME types or regexps matching file names and default dispositions.
  87 Each element should be one of the following three forms:
  88
  89   (REGEXP . DISPOSITION)
  90   (SUPERTYPE (SUBTYPE . DISPOSITION) (SUBTYPE . DISPOSITION)...)
  91   (TYPE . DISPOSITION)
  92
  93 Where REGEXP is a string which matches the file name (if any) of an
  94 attachment, SUPERTYPE, SUBTYPE and TYPE should be symbols which are a
  95 MIME supertype (e.g., text), a MIME subtype (e.g., plain) and a MIME
  96 type (e.g., text/plain) respectively, and DISPOSITION should be either
  97 the string \"attachment\" or the string \"inline\".  The value t for
  98 SUPERTYPE, SUBTYPE or TYPE matches any of those types.  The first
  99 match found will be used."
 100   :version "23.1" ;; No Gnus
 101   :type (let ((dispositions '(radio :format "DISPOSITION: %v"
 102                                     :value "attachment"
 103                                     (const :format "%v " "attachment")
 104                                     (const :format "%v\n" "inline"))))
 105           `(repeat
 106             :offset 0
 107             (choice :format "%[Value Menu%]%v"
 108                     (cons :tag "(REGEXP . DISPOSITION)" :extra-offset 4
 109                           (regexp :tag "REGEXP" :value ".*")
 110                           ,dispositions)
 111                     (cons :tag "(SUPERTYPE (SUBTYPE . DISPOSITION)...)"
 112                           :indent 0
 113                           (symbol :tag "    SUPERTYPE" :value text)
 114                           (repeat :format "%v%i\n" :offset 0 :extra-offset 4
 115                                   (cons :format "%v" :extra-offset 5
 116                                         (symbol :tag "SUBTYPE" :value t)
 117                                         ,dispositions)))
 118                     (cons :tag "(TYPE . DISPOSITION)" :extra-offset 4
 119                           (symbol :tag "TYPE" :value t)
 120                           ,dispositions))))
 121   :group 'message)
 122
 123 (defcustom mml-insert-mime-headers-always t
 124   "If non-nil, always put Content-Type: text/plain at top of empty parts.
 125 It is necessary to work against a bug in certain clients."
 126   :version "24.1"
 127   :type 'boolean
 128   :group 'message)
 129
 130 (defcustom mml-enable-flowed t
 131   "If non-nil, enable format=flowed usage when encoding a message.
 132 This is only performed when filling on text/plain with hard
 133 newlines in the text."
 134   :version "24.1"
 135   :type 'boolean
 136   :group 'message)
 137
 138 (defvar mml-tweak-type-alist nil
 139   "A list of (TYPE . FUNCTION) for tweaking MML parts.
 140 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
 141 is a Lisp function which is called with the MML handle to tweak the
 142 part.  This variable is used only when no TWEAK parameter exists in
 143 the MML handle.")
 144
 145 (defvar mml-tweak-function-alist nil
 146   "A list of (NAME . FUNCTION) for tweaking MML parts.
 147 NAME is a string containing the name of the TWEAK parameter in the MML
 148 handle.  FUNCTION is a Lisp function which is called with the MML
 149 handle to tweak the part.")
 150
 151 (defvar mml-tweak-sexp-alist
 152   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
 153   "A list of (SEXP . FUNCTION) for tweaking MML parts.
 154 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
 155 is called.  FUNCTION is a Lisp function which is called with the MML
 156 handle to tweak the part.")
 157
 158 (defvar mml-externalize-attachments nil
 159   "*If non-nil, local-file attachments are generated as external parts.")
 160
 161 (defvar mml-generate-multipart-alist nil
 162   "*Alist of multipart generation functions.
 163 Each entry has the form (NAME . FUNCTION), where
 164 NAME is a string containing the name of the part (without the
 165 leading \"/multipart/\"),
 166 FUNCTION is a Lisp function which is called to generate the part.
 167
 168 The Lisp function has to supply the appropriate MIME headers and the
 169 contents of this part.")
 170
 171 (defvar mml-syntax-table
 172   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 173     (modify-syntax-entry ?\\ "/" table)
 174     (modify-syntax-entry ?< "(" table)
 175     (modify-syntax-entry ?> ")" table)
 176     (modify-syntax-entry ?@ "w" table)
 177     (modify-syntax-entry ?/ "w" table)
 178     (modify-syntax-entry ?= " " table)
 179     (modify-syntax-entry ?* " " table)
 180     (modify-syntax-entry ?\; " " table)
 181     (modify-syntax-entry ?\' " " table)
 182     table))
 183
 184 (defvar mml-boundary-function 'mml-make-boundary
 185   "A function called to suggest a boundary.
 186 The function may be called several times, and should try to make a new
 187 suggestion each time.  The function is called with one parameter,
 188 which is a number that says how many times the function has been
 189 called for this message.")
 190
 191 (defvar mml-confirmation-set nil
 192   "A list of symbols, each of which disables some warning.
 193 `unknown-encoding': always send messages contain characters with
 194 unknown encoding; `use-ascii': always use ASCII for those characters
 195 with unknown encoding; `multipart': always send messages with more than
 196 one charsets.")
 197
 198 (defvar mml-generate-default-type "text/plain"
 199   "Content type by which the Content-Type header can be omitted.
 200 The Content-Type header will not be put in the MIME part if the type
 201 equals the value and there's no parameter (e.g. charset, format, etc.)
 202 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 203 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 204 part.  This is for the internal use, you should never modify the value.")
 205
 206 (defvar mml-buffer-list nil)
 207
 208 (defun mml-generate-new-buffer (name)
 209   (let ((buf (generate-new-buffer name)))
 210     (push buf mml-buffer-list)
 211     buf))
 212
 213 (defun mml-destroy-buffers ()
 214   (let (kill-buffer-hook)
 215     (mapc 'kill-buffer mml-buffer-list)
 216     (setq mml-buffer-list nil)))
 217
 218 (defun mml-parse ()
 219   "Parse the current buffer as an MML document."
 220   (save-excursion
 221     (goto-char (point-min))
 222     (with-syntax-table mml-syntax-table
 223       (mml-parse-1))))
 224
 225 (defun mml-parse-1 ()
 226   "Parse the current buffer as an MML document."
 227   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 228     (while (and (not (eobp))
 229                 (not (looking-at "<#/multipart")))
 230       (cond
 231        ((looking-at "<#secure")
 232         ;; The secure part is essentially a meta-meta tag, which
 233         ;; expands to either a part tag if there are no other parts in
 234         ;; the document or a multipart tag if there are other parts
 235         ;; included in the message
 236         (let* (secure-mode
 237                (taginfo (mml-read-tag))
 238                (keyfile (cdr (assq 'keyfile taginfo)))
 239                (certfiles (delq nil (mapcar (lambda (tag)
 240                                               (if (eq (car-safe tag) 'certfile)
 241                                                   (cdr tag)))
 242                                             taginfo)))
 243                (recipients (cdr (assq 'recipients taginfo)))
 244                (sender (cdr (assq 'sender taginfo)))
 245                (location (cdr (assq 'tag-location taginfo)))
 246                (mode (cdr (assq 'mode taginfo)))
 247                (method (cdr (assq 'method taginfo)))
 248                tags)
 249           (save-excursion
 250             (if (re-search-forward
 251                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 252                 (setq secure-mode "multipart")
 253               (setq secure-mode "part")))
 254           (save-excursion
 255             (goto-char location)
 256             (re-search-forward "<#secure[^\n]*>\n"))
 257           (delete-region (match-beginning 0) (match-end 0))
 258           (cond ((string= mode "sign")
 259                  (setq tags (list "sign" method)))
 260                 ((string= mode "encrypt")
 261                  (setq tags (list "encrypt" method)))
 262                 ((string= mode "signencrypt")
 263                  (setq tags (list "sign" method "encrypt" method))))
 264           (eval `(mml-insert-tag ,secure-mode
 265                                  ,@tags
 266                                  ,(if keyfile "keyfile")
 267                                  ,keyfile
 268                                  ,@(apply #'append
 269                                           (mapcar (lambda (certfile)
 270                                                     (list "certfile" certfile))
 271                                                   certfiles))
 272                                  ,(if recipients "recipients")
 273                                  ,recipients
 274                                  ,(if sender "sender")
 275                                  ,sender))
 276           ;; restart the parse
 277           (goto-char location)))
 278        ((looking-at "<#multipart")
 279         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 280        ((looking-at "<#external")
 281         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 282               struct))
 283        (t
 284         (if (or (looking-at "<#part") (looking-at "<#mml"))
 285             (setq tag (mml-read-tag)
 286                   no-markup-p nil
 287                   warn nil)
 288           (setq tag (list 'part '(type . "text/plain"))
 289                 no-markup-p t
 290                 warn t))
 291         (setq raw (cdr (assq 'raw tag))
 292               point (point)
 293               contents (mml-read-part (eq 'mml (car tag)))
 294               charsets (cond
 295                         (raw nil)
 296                         ((assq 'charset tag)
 297                          (list
 298                           (intern (downcase (cdr (assq 'charset tag))))))
 299                         (t
 300                          (mm-find-mime-charset-region point (point)
 301                                                       mm-hack-charsets))))
 302         (when (and (not raw) (memq nil charsets))
 303           (if (or (memq 'unknown-encoding mml-confirmation-set)
 304                   (message-options-get 'unknown-encoding)
 305                   (and (y-or-n-p "\
 306 Message contains characters with unknown encoding.  Really send? ")
 307                        (message-options-set 'unknown-encoding t)))
 308               (if (setq use-ascii
 309                         (or (memq 'use-ascii mml-confirmation-set)
 310                             (message-options-get 'use-ascii)
 311                             (and (y-or-n-p "Use ASCII as charset? ")
 312                                  (message-options-set 'use-ascii t))))
 313                   (setq charsets (delq nil charsets))
 314                 (setq warn nil))
 315             (error "Edit your message to remove those characters")))
 316         (if (or raw
 317                 (eq 'mml (car tag))
 318                 (< (length charsets) 2))
 319             (if (or (not no-markup-p)
 320                     (string-match "[^ \t\r\n]" contents))
 321                 ;; Don't create blank parts.
 322                 (push (nconc tag (list (cons 'contents contents)))
 323                       struct))
 324           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 325                           tag point (point) use-ascii)))
 326             (when (and warn
 327                        (not (memq 'multipart mml-confirmation-set))
 328                        (not (message-options-get 'multipart))
 329                        (not (and (y-or-n-p (format "\
 330 A message part needs to be split into %d charset parts.  Really send? "
 331                                                    (length nstruct)))
 332                                  (message-options-set 'multipart t))))
 333               (error "Edit your message to use only one charset"))
 334             (setq struct (nconc nstruct struct)))))))
 335     (unless (eobp)
 336       (forward-line 1))
 337     (nreverse struct)))
 338
 339 (defun mml-parse-singlepart-with-multiple-charsets
 340   (orig-tag beg end &optional use-ascii)
 341   (save-excursion
 342     (save-restriction
 343       (narrow-to-region beg end)
 344       (goto-char (point-min))
 345       (let ((current (or (mm-mime-charset (mm-charset-after))
 346                          (and use-ascii 'us-ascii)))
 347             charset struct space newline paragraph)
 348         (while (not (eobp))
 349           (setq charset (mm-mime-charset (mm-charset-after)))
 350           (cond
 351            ;; The charset remains the same.
 352            ((eq charset 'us-ascii))
 353            ((or (and use-ascii (not charset))
 354                 (eq charset current))
 355             (setq space nil
 356                   newline nil
 357                   paragraph nil))
 358            ;; The initial charset was ascii.
 359            ((eq current 'us-ascii)
 360             (setq current charset
 361                   space nil
 362                   newline nil
 363                   paragraph nil))
 364            ;; We have a change in charsets.
 365            (t
 366             (push (append
 367                    orig-tag
 368                    (list (cons 'contents
 369                                (buffer-substring-no-properties
 370                                 beg (or paragraph newline space (point))))))
 371                   struct)
 372             (setq beg (or paragraph newline space (point))
 373                   current charset
 374                   space nil
 375                   newline nil
 376                   paragraph nil)))
 377           ;; Compute places where it might be nice to break the part.
 378           (cond
 379            ((memq (following-char) '(?  ?\t))
 380             (setq space (1+ (point))))
 381            ((and (eq (following-char) ?\n)
 382                  (not (bobp))
 383                  (eq (char-after (1- (point))) ?\n))
 384             (setq paragraph (point)))
 385            ((eq (following-char) ?\n)
 386             (setq newline (1+ (point)))))
 387           (forward-char 1))
 388         ;; Do the final part.
 389         (unless (= beg (point))
 390           (push (append orig-tag
 391                         (list (cons 'contents
 392                                     (buffer-substring-no-properties
 393                                      beg (point)))))
 394                 struct))
 395         struct))))
 396
 397 (defun mml-read-tag ()
 398   "Read a tag and return the contents."
 399   (let ((orig-point (point))
 400         contents name elem val)
 401     (forward-char 2)
 402     (setq name (buffer-substring-no-properties
 403                 (point) (progn (forward-sexp 1) (point))))
 404     (skip-chars-forward " \t\n")
 405     (while (not (looking-at ">[ \t]*\n?"))
 406       (setq elem (buffer-substring-no-properties
 407                   (point) (progn (forward-sexp 1) (point))))
 408       (skip-chars-forward "= \t\n")
 409       (setq val (buffer-substring-no-properties
 410                  (point) (progn (forward-sexp 1) (point))))
 411       (when (string-match "\\`\"" val)
 412         (setq val (read val))) ;; inverse of prin1 in mml-insert-tag
 413       (push (cons (intern elem) val) contents)
 414       (skip-chars-forward " \t\n"))
 415     (goto-char (match-end 0))
 416     ;; Don't skip the leading space.
 417     ;;(skip-chars-forward " \t\n")
 418     ;; Put the tag location into the returned contents
 419     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 420     (cons (intern name) (nreverse contents))))
 421
 422 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 423   (let ((str (buffer-substring-no-properties start end))
 424         (bufstart start) tmp)
 425     (while (setq tmp (text-property-any start end 'hard 't))
 426       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 427                            '(hard t) str)
 428       (setq start (1+ tmp)))
 429     str))
 430
 431 (defun mml-read-part (&optional mml)
 432   "Return the buffer up till the next part, multipart or closing part or multipart.
 433 If MML is non-nil, return the buffer up till the correspondent mml tag."
 434   (let ((beg (point)) (count 1))
 435     ;; If the tag ended at the end of the line, we go to the next line.
 436     (when (looking-at "[ \t]*\n")
 437       (forward-line 1))
 438     (if mml
 439         (progn
 440           (while (and (> count 0) (not (eobp)))
 441             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 442                 (setq count (+ count (if (match-beginning 1) -1 1)))
 443               (goto-char (point-max))))
 444           (mml-buffer-substring-no-properties-except-hard-newlines
 445            beg (if (> count 0)
 446                    (point)
 447                  (match-beginning 0))))
 448       (if (re-search-forward
 449            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 450           (prog1
 451               (mml-buffer-substring-no-properties-except-hard-newlines
 452                beg (match-beginning 0))
 453             (if (or (not (match-beginning 1))
 454                     (equal (match-string 2) "multipart"))
 455                 (goto-char (match-beginning 0))
 456               (when (looking-at "[ \t]*\n")
 457                 (forward-line 1))))
 458         (mml-buffer-substring-no-properties-except-hard-newlines
 459          beg (goto-char (point-max)))))))
 460
 461 (defvar mml-boundary nil)
 462 (defvar mml-base-boundary "-=-=")
 463 (defvar mml-multipart-number 0)
 464 (defvar mml-inhibit-compute-boundary nil)
 465
 466 (defun mml-generate-mime (&optional multipart-type)
 467   "Generate a MIME message based on the current MML document.
 468 MULTIPART-TYPE defaults to \"mixed\", but can also
 469 be \"related\" or \"alternate\"."
 470   (let ((cont (mml-parse))
 471         (mml-multipart-number mml-multipart-number)
 472         (options message-options))
 473     (if (not cont)
 474         nil
 475       (prog1
 476           (mm-with-multibyte-buffer
 477             (setq message-options options)
 478             (if (and (consp (car cont))
 479                      (= (length cont) 1))
 480                 (mml-generate-mime-1 (car cont))
 481               (mml-generate-mime-1
 482                (nconc (list 'multipart (cons 'type (or multipart-type "mixed")))
 483                       cont)))
 484             (setq options message-options)
 485             (buffer-string))
 486         (setq message-options options)))))
 487
 488 (defun mml-generate-mime-1 (cont)
 489   (let ((mm-use-ultra-safe-encoding
 490          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 491     (save-restriction
 492       (narrow-to-region (point) (point))
 493       (mml-tweak-part cont)
 494       (cond
 495        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 496         (let* ((raw (cdr (assq 'raw cont)))
 497                (filename (cdr (assq 'filename cont)))
 498                (type (or (cdr (assq 'type cont))
 499                          (if filename
 500                              (or (mm-default-file-encoding filename)
 501                                  "application/octet-stream")
 502                            "text/plain")))
 503                (charset (cdr (assq 'charset cont)))
 504                (coding (mm-charset-to-coding-system charset))
 505                encoding flowed coded)
 506           (cond ((eq coding 'ascii)
 507                  (setq charset nil
 508                        coding nil))
 509                 (charset
 510                  ;; The value of `charset' might be a bogus alias that
 511                  ;; `mm-charset-synonym-alist' provides, like `utf8',
 512                  ;; so we prefer the MIME charset that Emacs knows for
 513                  ;; the coding system `coding'.
 514                  (setq charset (or (mm-coding-system-to-mime-charset coding)
 515                                    (intern (downcase charset))))))
 516           (if (and (not raw)
 517                    (member (car (split-string type "/")) '("text" "message")))
 518               (progn
 519                 (with-temp-buffer
 520                   (cond
 521                    ((cdr (assq 'buffer cont))
 522                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 523                    ((and filename
 524                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 525                     (let ((coding-system-for-read coding))
 526                       (mm-insert-file-contents filename)))
 527                    ((eq 'mml (car cont))
 528                     (insert (cdr (assq 'contents cont))))
 529                    (t
 530                     (save-restriction
 531                       (narrow-to-region (point) (point))
 532                       (insert (cdr (assq 'contents cont)))
 533                       ;; Remove quotes from quoted tags.
 534                       (goto-char (point-min))
 535                       (while (re-search-forward
 536                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\|secure\\)"
 537                               nil t)
 538                         (delete-region (+ (match-beginning 0) 2)
 539                                        (+ (match-beginning 0) 3))))))
 540                   (cond
 541                    ((eq (car cont) 'mml)
 542                     (let ((mml-boundary (mml-compute-boundary cont))
 543                           ;; It is necessary for the case where this
 544                           ;; function is called recursively since
 545                           ;; `m-g-d-t' will be bound to "message/rfc822"
 546                           ;; when encoding an article to be forwarded.
 547                           (mml-generate-default-type "text/plain"))
 548                       (mml-to-mime)
 549                       ;; Update handle so mml-compute-boundary can
 550                       ;; detect collisions with the nested parts.
 551                       (unless mml-inhibit-compute-boundary
 552                         (setcdr (assoc 'contents cont) (buffer-string))))
 553                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 554                       ;; ignore 0x1b, it is part of iso-2022-jp
 555                       (setq encoding (mm-body-7-or-8))))
 556                    ((string= (car (split-string type "/")) "message")
 557                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 558                       ;; ignore 0x1b, it is part of iso-2022-jp
 559                       (setq encoding (mm-body-7-or-8))))
 560                    (t
 561                     ;; Only perform format=flowed filling on text/plain
 562                     ;; parts where there either isn't a format parameter
 563                     ;; in the mml tag or it says "flowed" and there
 564                     ;; actually are hard newlines in the text.
 565                     (let (use-hard-newlines)
 566                       (when (and mml-enable-flowed
 567                                  (string= type "text/plain")
 568                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 569                                  (or (null (assq 'format cont))
 570                                      (string= (cdr (assq 'format cont))
 571                                               "flowed"))
 572                                  (setq use-hard-newlines
 573                                        (text-property-any
 574                                         (point-min) (point-max) 'hard 't)))
 575                         (fill-flowed-encode)
 576                         ;; Indicate that `mml-insert-mime-headers' should
 577                         ;; insert a "; format=flowed" string unless the
 578                         ;; user has already specified it.
 579                         (setq flowed (null (assq 'format cont)))))
 580                     ;; Prefer `utf-8' for text/calendar parts.
 581                     (if (or charset
 582                             (not (string= type "text/calendar")))
 583                         (setq charset (mm-encode-body charset))
 584                       (let ((mm-coding-system-priorities
 585                              (cons 'utf-8 mm-coding-system-priorities)))
 586                         (setq charset (mm-encode-body))))
 587                     (setq encoding (mm-body-encoding
 588                                     charset (cdr (assq 'encoding cont))))))
 589                   (setq coded (buffer-string)))
 590                 (mml-insert-mime-headers cont type charset encoding flowed)
 591                 (insert "\n")
 592                 (insert coded))
 593             (mm-with-unibyte-buffer
 594               (cond
 595                ((cdr (assq 'buffer cont))
 596                 (insert (mm-string-as-unibyte
 597                          (with-current-buffer (cdr (assq 'buffer cont))
 598                            (buffer-string)))))
 599                ((and filename
 600                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 601                 (let ((coding-system-for-read mm-binary-coding-system))
 602                   (mm-insert-file-contents filename nil nil nil nil t))
 603                 (unless charset
 604                   (setq charset (mm-coding-system-to-mime-charset
 605                                  (mm-find-buffer-file-coding-system
 606                                   filename)))))
 607                (t
 608                 (let ((contents (cdr (assq 'contents cont))))
 609                   (if (if (featurep 'xemacs)
 610                           (string-match "[^\000-\377]" contents)
 611                         (mm-multibyte-string-p contents))
 612                       (progn
 613                         (mm-enable-multibyte)
 614                         (insert contents)
 615                         (unless raw
 616                           (setq charset (mm-encode-body charset))))
 617                     (insert contents)))))
 618               (if (setq encoding (cdr (assq 'encoding cont)))
 619                   (setq encoding (intern (downcase encoding))))
 620               (setq encoding (mm-encode-buffer type encoding)
 621                     coded (mm-string-as-multibyte (buffer-string))))
 622             (mml-insert-mime-headers cont type charset encoding nil)
 623             (insert "\n" coded))))
 624        ((eq (car cont) 'external)
 625         (insert "Content-Type: message/external-body")
 626         (let ((parameters (mml-parameter-string
 627                            cont '(expiration size permission)))
 628               (name (cdr (assq 'name cont)))
 629               (url (cdr (assq 'url cont))))
 630           (when name
 631             (setq name (mml-parse-file-name name))
 632             (if (stringp name)
 633                 (mml-insert-parameter
 634                  (mail-header-encode-parameter "name" name)
 635                  "access-type=local-file")
 636               (mml-insert-parameter
 637                (mail-header-encode-parameter
 638                 "name" (file-name-nondirectory (nth 2 name)))
 639                (mail-header-encode-parameter "site" (nth 1 name))
 640                (mail-header-encode-parameter
 641                 "directory" (file-name-directory (nth 2 name))))
 642               (mml-insert-parameter
 643                (concat "access-type="
 644                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 645                            "anon-ftp"
 646                          "ftp")))))
 647           (when url
 648             (mml-insert-parameter
 649              (mail-header-encode-parameter "url" url)
 650              "access-type=url"))
 651           (when parameters
 652             (mml-insert-parameter-string
 653              cont '(expiration size permission)))
 654           (insert "\n\n")
 655           (insert "Content-Type: "
 656                   (or (cdr (assq 'type cont))
 657                       (if name
 658                           (or (mm-default-file-encoding name)
 659                               "application/octet-stream")
 660                         "text/plain"))
 661                   "\n")
 662           (insert "Content-ID: " (message-make-message-id) "\n")
 663           (insert "Content-Transfer-Encoding: "
 664                   (or (cdr (assq 'encoding cont)) "binary"))
 665           (insert "\n\n")
 666           (insert (or (cdr (assq 'contents cont))))
 667           (insert "\n")))
 668        ((eq (car cont) 'multipart)
 669         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 670                (mml-generate-default-type (if (equal type "digest")
 671                                               "message/rfc822"
 672                                             "text/plain"))
 673                (handler (assoc type mml-generate-multipart-alist)))
 674           (if handler
 675               (funcall (cdr handler) cont)
 676             ;; No specific handler.  Use default one.
 677             (let ((mml-boundary (mml-compute-boundary cont)))
 678               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 679                               type mml-boundary)
 680                       (if (cdr (assq 'start cont))
 681                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 682                         "\n"))
 683               (let ((cont cont) part)
 684                 (while (setq part (pop cont))
 685                   ;; Skip `multipart' and attributes.
 686                   (when (and (consp part) (consp (cdr part)))
 687                     (insert "\n--" mml-boundary "\n")
 688                     (mml-generate-mime-1 part)
 689                     (goto-char (point-max)))))
 690               (insert "\n--" mml-boundary "--\n")))))
 691        (t
 692         (error "Invalid element: %S" cont)))
 693       ;; handle sign & encrypt tags in a semi-smart way.
 694       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 695             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 696                                  mml-encrypt-alist))
 697             sender recipients)
 698         (when (or sign-item encrypt-item)
 699           (when (setq sender (cdr (assq 'sender cont)))
 700             (message-options-set 'mml-sender sender)
 701             (message-options-set 'message-sender sender))
 702           (if (setq recipients (cdr (assq 'recipients cont)))
 703               (message-options-set 'message-recipients recipients))
 704           (let ((style (mml-signencrypt-style
 705                         (first (or sign-item encrypt-item)))))
 706             ;; check if: we're both signing & encrypting, both methods
 707             ;; are the same (why would they be different?!), and that
 708             ;; the signencrypt style allows for combined operation.
 709             (if (and sign-item encrypt-item (equal (first sign-item)
 710                                                    (first encrypt-item))
 711                      (equal style 'combined))
 712                 (funcall (nth 1 encrypt-item) cont t)
 713               ;; otherwise, revert to the old behavior.
 714               (when sign-item
 715                 (funcall (nth 1 sign-item) cont))
 716               (when encrypt-item
 717                 (funcall (nth 1 encrypt-item) cont)))))))))
 718
 719 (defun mml-compute-boundary (cont)
 720   "Return a unique boundary that does not exist in CONT."
 721   (let ((mml-boundary (funcall mml-boundary-function
 722                                (incf mml-multipart-number))))
 723     (unless mml-inhibit-compute-boundary
 724       ;; This function tries again and again until it has found
 725       ;; a unique boundary.
 726       (while (not (catch 'not-unique
 727                     (mml-compute-boundary-1 cont)))))
 728     mml-boundary))
 729
 730 (defun mml-compute-boundary-1 (cont)
 731   (cond
 732    ((member (car cont) '(part mml))
 733     (mm-with-multibyte-buffer
 734       (let ((mml-inhibit-compute-boundary t)
 735             (mml-multipart-number 0)
 736             mml-sign-alist mml-encrypt-alist)
 737         (mml-generate-mime-1 cont))
 738       (goto-char (point-min))
 739       (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 740                                nil t)
 741         (setq mml-boundary (funcall mml-boundary-function
 742                                     (incf mml-multipart-number)))
 743         (throw 'not-unique nil))))
 744    ((eq (car cont) 'multipart)
 745     (mapc 'mml-compute-boundary-1 (cddr cont))))
 746   t)
 747
 748 (defun mml-make-boundary (number)
 749   (concat (make-string (% number 60) ?=)
 750           (if (> number 17)
 751               (format "%x" number)
 752             "")
 753           mml-base-boundary))
 754
 755 (defun mml-content-disposition (type &optional filename)
 756   "Return a default disposition name suitable to TYPE or FILENAME."
 757   (let ((defs mml-content-disposition-alist)
 758         disposition def types)
 759     (while (and (not disposition) defs)
 760       (setq def (pop defs))
 761       (cond ((stringp (car def))
 762              (when (and filename
 763                         (string-match (car def) filename))
 764                (setq disposition (cdr def))))
 765             ((consp (cdr def))
 766              (when (string= (car (setq types (split-string type "/")))
 767                             (car def))
 768                (setq type (cadr types)
 769                      types (cdr def))
 770                (while (and (not disposition) types)
 771                  (setq def (pop types))
 772                  (when (or (eq (car def) t) (string= type (car def)))
 773                    (setq disposition (cdr def))))))
 774             (t
 775              (when (or (eq (car def) t) (string= type (car def)))
 776                (setq disposition (cdr def))))))
 777     (or disposition "attachment")))
 778
 779 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 780   (let (parameters id disposition description)
 781     (setq parameters
 782           (mml-parameter-string
 783            cont mml-content-type-parameters))
 784     (when (or charset
 785               parameters
 786               flowed
 787               (not (equal type mml-generate-default-type))
 788               mml-insert-mime-headers-always)
 789       (when (consp charset)
 790         (error
 791          "Can't encode a part with several charsets"))
 792       (insert "Content-Type: " type)
 793       (when charset
 794         (mml-insert-parameter
 795          (mail-header-encode-parameter "charset" (symbol-name charset))))
 796       (when flowed
 797         (mml-insert-parameter "format=flowed"))
 798       (when parameters
 799         (mml-insert-parameter-string
 800          cont mml-content-type-parameters))
 801       (insert "\n"))
 802     (when (setq id (cdr (assq 'id cont)))
 803       (insert "Content-ID: " id "\n"))
 804     (setq parameters
 805           (mml-parameter-string
 806            cont mml-content-disposition-parameters))
 807     (when (or (setq disposition (cdr (assq 'disposition cont)))
 808               parameters)
 809       (insert "Content-Disposition: "
 810               (or disposition
 811                   (mml-content-disposition type (cdr (assq 'filename cont)))))
 812       (when parameters
 813         (mml-insert-parameter-string
 814          cont mml-content-disposition-parameters))
 815       (insert "\n"))
 816     (unless (eq encoding '7bit)
 817       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 818     (when (setq description (cdr (assq 'description cont)))
 819       (insert "Content-Description: ")
 820       (setq description (prog1
 821                             (point)
 822                           (insert description "\n")))
 823       (mail-encode-encoded-word-region description (point)))))
 824
 825 (defun mml-parameter-string (cont types)
 826   (let ((string "")
 827         value type)
 828     (while (setq type (pop types))
 829       (when (setq value (cdr (assq type cont)))
 830         ;; Strip directory component from the filename parameter.
 831         (when (eq type 'filename)
 832           (setq value (file-name-nondirectory value)))
 833         (setq string (concat string "; "
 834                              (mail-header-encode-parameter
 835                               (symbol-name type) value)))))
 836     (when (not (zerop (length string)))
 837       string)))
 838
 839 (defun mml-insert-parameter-string (cont types)
 840   (let (value type)
 841     (while (setq type (pop types))
 842       (when (setq value (cdr (assq type cont)))
 843         ;; Strip directory component from the filename parameter.
 844         (when (eq type 'filename)
 845           (setq value (file-name-nondirectory value)))
 846         (mml-insert-parameter
 847          (mail-header-encode-parameter
 848           (symbol-name type) value))))))
 849
 850 (defvar ange-ftp-name-format)
 851 (defvar efs-path-regexp)
 852
 853 (defun mml-parse-file-name (path)
 854   (if (if (boundp 'efs-path-regexp)
 855           (string-match efs-path-regexp path)
 856         (if (boundp 'ange-ftp-name-format)
 857             (string-match (car ange-ftp-name-format) path)))
 858       (list (match-string 1 path) (match-string 2 path)
 859             (substring path (1+ (match-end 2))))
 860     path))
 861
 862 (defun mml-insert-buffer (buffer)
 863   "Insert BUFFER at point and quote any MML markup."
 864   (save-restriction
 865     (narrow-to-region (point) (point))
 866     (insert-buffer-substring buffer)
 867     (mml-quote-region (point-min) (point-max))
 868     (goto-char (point-max))))
 869
 870 ;;;
 871 ;;; Transforming MIME to MML
 872 ;;;
 873
 874 ;; message-narrow-to-head autoloads message.
 875 (declare-function message-remove-header "message"
 876                   (header &optional is-regexp first reverse))
 877
 878 (defun mime-to-mml (&optional handles)
 879   "Translate the current buffer (which should be a message) into MML.
 880 If HANDLES is non-nil, use it instead reparsing the buffer."
 881   ;; First decode the head.
 882   (save-restriction
 883     (message-narrow-to-head)
 884     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 885       (mail-decode-encoded-word-region (point-min) (point-max))))
 886   (unless handles
 887     (setq handles (mm-dissect-buffer t)))
 888   (goto-char (point-min))
 889   (search-forward "\n\n" nil t)
 890   (delete-region (point) (point-max))
 891   (if (stringp (car handles))
 892       (mml-insert-mime handles)
 893     (mml-insert-mime handles t))
 894   (mm-destroy-parts handles)
 895   (save-restriction
 896     (message-narrow-to-head)
 897     ;; Remove them, they are confusing.
 898     (message-remove-header "Content-Type")
 899     (message-remove-header "MIME-Version")
 900     (message-remove-header "Content-Disposition")
 901     (message-remove-header "Content-Transfer-Encoding")))
 902
 903 (autoload 'message-encode-message-body "message")
 904 (declare-function message-narrow-to-headers-or-head "message" ())
 905
 906 ;;;###autoload
 907 (defun mml-to-mime ()
 908   "Translate the current buffer from MML to MIME."
 909   ;; `message-encode-message-body' will insert an encoded Content-Description
 910   ;; header in the message header if the body contains a single part
 911   ;; that is specified by a user with a MML tag containing a description
 912   ;; token.  So, we encode the message header first to prevent the encoded
 913   ;; Content-Description header from being encoded again.
 914   (save-restriction
 915     (message-narrow-to-headers-or-head)
 916     ;; Skip past any From_ headers.
 917     (while (looking-at "From ")
 918       (forward-line 1))
 919     (let ((mail-parse-charset message-default-charset))
 920       (mail-encode-encoded-word-buffer)))
 921   (message-encode-message-body))
 922
 923 (defun mml-insert-mime (handle &optional no-markup)
 924   (let (textp buffer mmlp)
 925     ;; Determine type and stuff.
 926     (unless (stringp (car handle))
 927       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 928         (with-current-buffer (setq buffer (mml-generate-new-buffer " *mml*"))
 929           (if (eq (mail-content-type-get (mm-handle-type handle) 'charset)
 930                   'gnus-decoded)
 931               ;; A part that mm-uu dissected from a non-MIME message
 932               ;; because of `gnus-article-emulate-mime'.
 933               (progn
 934                 (mm-enable-multibyte)
 935                 (insert-buffer-substring (mm-handle-buffer handle)))
 936             (mm-insert-part handle 'no-cache)
 937             (if (setq mmlp (equal (mm-handle-media-type handle)
 938                                   "message/rfc822"))
 939                 (mime-to-mml))))))
 940     (if mmlp
 941         (mml-insert-mml-markup handle nil t t)
 942       (unless (and no-markup
 943                    (equal (mm-handle-media-type handle) "text/plain"))
 944         (mml-insert-mml-markup handle buffer textp)))
 945     (cond
 946      (mmlp
 947       (insert-buffer-substring buffer)
 948       (goto-char (point-max))
 949       (insert "<#/mml>\n"))
 950      ((stringp (car handle))
 951       (mapc 'mml-insert-mime (cdr handle))
 952       (insert "<#/multipart>\n"))
 953      (textp
 954       (let ((charset (mail-content-type-get
 955                       (mm-handle-type handle) 'charset))
 956             (start (point)))
 957         (if (eq charset 'gnus-decoded)
 958             (mm-insert-part handle)
 959           (insert (mm-decode-string (mm-get-part handle) charset)))
 960         (mml-quote-region start (point)))
 961       (goto-char (point-max)))
 962      (t
 963       (insert "<#/part>\n")))))
 964
 965 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 966   "Take a MIME handle and insert an MML tag."
 967   (if (stringp (car handle))
 968       (progn
 969         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 970         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 971           (when start
 972             (insert " start=\"" start "\"")))
 973         (insert ">\n"))
 974     (if mmlp
 975         (insert "<#mml type=" (mm-handle-media-type handle))
 976       (insert "<#part type=" (mm-handle-media-type handle)))
 977     (dolist (elem (append (cdr (mm-handle-type handle))
 978                           (cdr (mm-handle-disposition handle))))
 979       (unless (symbolp (cdr elem))
 980         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 981     (when (mm-handle-id handle)
 982       (insert " id=\"" (mm-handle-id handle) "\""))
 983     (when (mm-handle-disposition handle)
 984       (insert " disposition=" (car (mm-handle-disposition handle))))
 985     (when buffer
 986       (insert " buffer=\"" (buffer-name buffer) "\""))
 987     (when nofile
 988       (insert " nofile=yes"))
 989     (when (mm-handle-description handle)
 990       (insert " description=\"" (mm-handle-description handle) "\""))
 991     (insert ">\n")))
 992
 993 (defun mml-insert-parameter (&rest parameters)
 994   "Insert PARAMETERS in a nice way."
 995   (let (start end)
 996     (dolist (param parameters)
 997       (insert ";")
 998       (setq start (point))
 999       (insert " " param)
1000       (setq end (point))
1001       (goto-char start)
1002       (end-of-line)
1003       (if (> (current-column) 76)
1004           (progn
1005             (goto-char start)
1006             (insert "\n")
1007             (goto-char (1+ end)))
1008         (goto-char end)))))
1009
1010 ;;;
1011 ;;; Mode for inserting and editing MML forms
1012 ;;;
1013
1014 (defvar mml-mode-map
1015   (let ((sign (make-sparse-keymap))
1016         (encrypt (make-sparse-keymap))
1017         (signpart (make-sparse-keymap))
1018         (encryptpart (make-sparse-keymap))
1019         (map (make-sparse-keymap))
1020         (main (make-sparse-keymap)))
1021     (define-key map "\C-s" 'mml-secure-message-sign)
1022     (define-key map "\C-c" 'mml-secure-message-encrypt)
1023     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
1024     (define-key map "\C-p\C-s" 'mml-secure-sign)
1025     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
1026     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
1027     (define-key sign "o" 'mml-secure-message-sign-pgp)
1028     (define-key sign "s" 'mml-secure-message-sign-smime)
1029     (define-key signpart "p" 'mml-secure-sign-pgpmime)
1030     (define-key signpart "o" 'mml-secure-sign-pgp)
1031     (define-key signpart "s" 'mml-secure-sign-smime)
1032     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
1033     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
1034     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
1035     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
1036     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
1037     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
1038     (define-key map "\C-n" 'mml-unsecure-message)
1039     (define-key map "f" 'mml-attach-file)
1040     (define-key map "b" 'mml-attach-buffer)
1041     (define-key map "e" 'mml-attach-external)
1042     (define-key map "q" 'mml-quote-region)
1043     (define-key map "m" 'mml-insert-multipart)
1044     (define-key map "p" 'mml-insert-part)
1045     (define-key map "v" 'mml-validate)
1046     (define-key map "P" 'mml-preview)
1047     (define-key map "s" sign)
1048     (define-key map "S" signpart)
1049     (define-key map "c" encrypt)
1050     (define-key map "C" encryptpart)
1051     ;;(define-key map "n" 'mml-narrow-to-part)
1052     ;; `M-m' conflicts with `back-to-indentation'.
1053     ;; (define-key main "\M-m" map)
1054     (define-key main "\C-c\C-m" map)
1055     main))
1056
1057 (easy-menu-define
1058   mml-menu mml-mode-map ""
1059   `("Attachments"
1060     ["Attach File..." mml-attach-file
1061      ,@(if (featurep 'xemacs) '(t)
1062          '(:help "Attach a file at point"))]
1063     ["Attach Buffer..." mml-attach-buffer
1064      ,@(if (featurep 'xemacs) '(t)
1065          '(:help "Attach a buffer to the outgoing message"))]
1066     ["Attach External..." mml-attach-external
1067      ,@(if (featurep 'xemacs) '(t)
1068          '(:help "Attach reference to an external file"))]
1069     ;; FIXME: Is it possible to do this without using
1070     ;; `gnus-gcc-externalize-attachments'?
1071     ["Externalize Attachments"
1072      (lambda ()
1073        (interactive)
1074        (if (not (and (boundp 'gnus-gcc-externalize-attachments)
1075                      (memq gnus-gcc-externalize-attachments
1076                            '(all t nil))))
1077            ;; Stupid workaround for XEmacs not honoring :visible.
1078            (message "Can't handle this value of `gnus-gcc-externalize-attachments'")
1079          (setq gnus-gcc-externalize-attachments
1080                (not gnus-gcc-externalize-attachments))
1081          (message "gnus-gcc-externalize-attachments is `%s'."
1082                   gnus-gcc-externalize-attachments)))
1083      ;; XEmacs barfs on :visible.
1084      ,@(if (featurep 'xemacs) nil
1085          '(:visible (and (boundp 'gnus-gcc-externalize-attachments)
1086                          (memq gnus-gcc-externalize-attachments
1087                                '(all t nil)))))
1088      :style toggle
1089      :selected gnus-gcc-externalize-attachments
1090      ,@(if (featurep 'xemacs) nil
1091          '(:help "Save attachments as external parts in Gcc copies"))]
1092     "----"
1093     ;;
1094     ("Change Security Method"
1095      ["PGP/MIME"
1096       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
1097       ,@(if (featurep 'xemacs) nil
1098           '(:help "Set Security Method to PGP/MIME"))
1099       :style radio
1100       :selected (equal mml-secure-method "pgpmime") ]
1101      ["S/MIME"
1102       (lambda () (interactive) (setq mml-secure-method "smime"))
1103       ,@(if (featurep 'xemacs) nil
1104           '(:help "Set Security Method to S/MIME"))
1105       :style radio
1106       :selected (equal mml-secure-method "smime") ]
1107      ["Inline PGP"
1108       (lambda () (interactive) (setq mml-secure-method "pgp"))
1109       ,@(if (featurep 'xemacs) nil
1110           '(:help "Set Security Method to inline PGP"))
1111       :style radio
1112       :selected (equal mml-secure-method "pgp") ] )
1113     ;;
1114     ["Sign Message" mml-secure-message-sign t]
1115     ["Encrypt Message" mml-secure-message-encrypt t]
1116     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
1117     ["Encrypt/Sign off" mml-unsecure-message
1118      ,@(if (featurep 'xemacs) '(t)
1119          '(:help "Don't Encrypt/Sign Message"))]
1120     ;; Do we have separate encrypt and encrypt/sign commands for parts?
1121     ["Sign Part" mml-secure-sign t]
1122     ["Encrypt Part" mml-secure-encrypt t]
1123     "----"
1124     ;; Maybe we could remove these, because people who write MML most probably
1125     ;; don't use the menu:
1126     ["Insert Part..." mml-insert-part
1127      :active (message-in-body-p)]
1128     ["Insert Multipart..." mml-insert-multipart
1129      :active (message-in-body-p)]
1130     ;;
1131     ;;["Narrow" mml-narrow-to-part t]
1132     ["Quote MML in region" mml-quote-region
1133      :active (message-mark-active-p)
1134      ,@(if (featurep 'xemacs) nil
1135          '(:help "Quote MML tags in region"))]
1136     ["Validate MML" mml-validate t]
1137     ["Preview" mml-preview t]
1138     "----"
1139     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
1140      ,@(if (featurep 'xemacs) '(t)
1141          '(:help "Display the Emacs MIME manual"))]
1142     ["PGG manual" (lambda () (interactive) (message-info mml2015-use))
1143      ;; XEmacs barfs on :visible.
1144      ,@(if (featurep 'xemacs) nil
1145          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'pgg))))
1146      ,@(if (featurep 'xemacs) '(t)
1147          '(:help "Display the PGG manual"))]
1148     ["EasyPG manual" (lambda () (interactive) (require 'mml2015) (message-info mml2015-use))
1149      ;; XEmacs barfs on :visible.
1150      ,@(if (featurep 'xemacs) nil
1151          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'epg))))
1152      ,@(if (featurep 'xemacs) '(t)
1153          '(:help "Display the EasyPG manual"))]))
1154
1155 (define-minor-mode mml-mode
1156   "Minor mode for editing MML.
1157 MML is the MIME Meta Language, a minor mode for composing MIME articles.
1158 See Info node `(emacs-mime)Composing'.
1159
1160 \\{mml-mode-map}"
1161   :lighter " MML" :keymap mml-mode-map
1162   (when mml-mode
1163     (easy-menu-add mml-menu mml-mode-map)
1164     (when (boundp 'dnd-protocol-alist)
1165       (set (make-local-variable 'dnd-protocol-alist)
1166            (append mml-dnd-protocol-alist dnd-protocol-alist)))))
1167
1168 ;;;
1169 ;;; Helper functions for reading MIME stuff from the minibuffer and
1170 ;;; inserting stuff to the buffer.
1171 ;;;
1172
1173 (defcustom mml-default-directory mm-default-directory
1174   "The default directory where mml will find files.
1175 If not set, `default-directory' will be used."
1176   :type '(choice directory (const :tag "Default" nil))
1177   :version "23.1" ;; No Gnus
1178   :group 'message)
1179
1180 (defun mml-minibuffer-read-file (prompt)
1181   (let* ((completion-ignored-extensions nil)
1182          (file (read-file-name prompt
1183                                (or mml-default-directory default-directory)
1184                                nil t)))
1185     ;; Prevent some common errors.  This is inspired by similar code in
1186     ;; VM.
1187     (when (file-directory-p file)
1188       (error "%s is a directory, cannot attach" file))
1189     (unless (file-exists-p file)
1190       (error "No such file: %s" file))
1191     (unless (file-readable-p file)
1192       (error "Permission denied: %s" file))
1193     file))
1194
1195 (declare-function mailcap-parse-mimetypes "mailcap" (&optional path force))
1196 (declare-function mailcap-mime-types "mailcap" ())
1197
1198 (defun mml-minibuffer-read-type (name &optional default)
1199   (require 'mailcap)
1200   (mailcap-parse-mimetypes)
1201   (let* ((default (or default
1202                       (mm-default-file-encoding name)
1203                       ;; Perhaps here we should check what the file
1204                       ;; looks like, and offer text/plain if it looks
1205                       ;; like text/plain.
1206                       "application/octet-stream"))
1207          (string (gnus-completing-read
1208                   "Content type"
1209                   (mailcap-mime-types)
1210                   nil nil nil default)))
1211     (if (not (equal string ""))
1212         string
1213       default)))
1214
1215 (defun mml-minibuffer-read-description ()
1216   (let ((description (read-string "One line description: ")))
1217     (when (string-match "\\`[ \t]*\\'" description)
1218       (setq description nil))
1219     description))
1220
1221 (defun mml-minibuffer-read-disposition (type &optional default filename)
1222   (unless default
1223     (setq default (mml-content-disposition type filename)))
1224   (let ((disposition (gnus-completing-read
1225                       "Disposition"
1226                       '("attachment" "inline")
1227                       t nil nil default)))
1228     (if (not (equal disposition ""))
1229         disposition
1230       default)))
1231
1232 (defun mml-quote-region (beg end)
1233   "Quote the MML tags in the region."
1234   (interactive "r")
1235   (save-excursion
1236     (save-restriction
1237       ;; Temporarily narrow the region to defend from changes
1238       ;; invalidating END.
1239       (narrow-to-region beg end)
1240       (goto-char (point-min))
1241       ;; Quote parts.
1242       (while (re-search-forward
1243               "<#!*/?\\(multipart\\|part\\|external\\|mml\\|secure\\)" nil t)
1244         ;; Insert ! after the #.
1245         (goto-char (+ (match-beginning 0) 2))
1246         (insert "!")))))
1247
1248 (defun mml-insert-tag (name &rest plist)
1249   "Insert an MML tag described by NAME and PLIST."
1250   (when (symbolp name)
1251     (setq name (symbol-name name)))
1252   (insert "<#" name)
1253   (while plist
1254     (let ((key (pop plist))
1255           (value (pop plist)))
1256       (when value
1257         ;; Quote VALUE if it contains suspicious characters.
1258         (when (string-match "[\"'\\~/*;() \t\n]" value)
1259           (setq value (with-output-to-string
1260                         (let (print-escape-nonascii)
1261                           (prin1 value)))))
1262         (insert (format " %s=%s" key value)))))
1263   (insert ">\n"))
1264
1265 (defun mml-insert-empty-tag (name &rest plist)
1266   "Insert an empty MML tag described by NAME and PLIST."
1267   (when (symbolp name)
1268     (setq name (symbol-name name)))
1269   (apply #'mml-insert-tag name plist)
1270   (insert "<#/" name ">\n"))
1271
1272 ;;; Attachment functions.
1273
1274 (defcustom mml-dnd-protocol-alist
1275   '(("^file:///" . mml-dnd-attach-file)
1276     ("^file://"  . dnd-open-file)
1277     ("^file:"    . mml-dnd-attach-file))
1278   "The functions to call when a drop in `mml-mode' is made.
1279 See `dnd-protocol-alist' for more information.  When nil, behave
1280 as in other buffers."
1281   :type '(choice (repeat (cons (regexp) (function)))
1282                  (const :tag "Behave as in other buffers" nil))
1283   :version "22.1" ;; Gnus 5.10.9
1284   :group 'message)
1285
1286 (defcustom mml-dnd-attach-options nil
1287   "Which options should be queried when attaching a file via drag and drop.
1288
1289 If it is a list, valid members are `type', `description' and
1290 `disposition'.  `disposition' implies `type'.  If it is nil,
1291 don't ask for options.  If it is t, ask the user whether or not
1292 to specify options."
1293   :type '(choice
1294           (const :tag "None" nil)
1295           (const :tag "Query" t)
1296           (list :value (type description disposition)
1297            (set :inline t
1298                 (const type)
1299                 (const description)
1300                 (const disposition))))
1301   :version "22.1" ;; Gnus 5.10.9
1302   :group 'message)
1303
1304 ;;;###autoload
1305 (defun mml-attach-file (file &optional type description disposition)
1306   "Attach a file to the outgoing MIME message.
1307 The file is not inserted or encoded until you send the message with
1308 `\\[message-send-and-exit]' or `\\[message-send]'.
1309
1310 FILE is the name of the file to attach.  TYPE is its
1311 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1312 is a one-line description of the attachment.  The DISPOSITION
1313 specifies how the attachment is intended to be displayed.  It can
1314 be either \"inline\" (displayed automatically within the message
1315 body) or \"attachment\" (separate from the body)."
1316   (interactive
1317    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1318           (type (mml-minibuffer-read-type file))
1319           (description (mml-minibuffer-read-description))
1320           (disposition (mml-minibuffer-read-disposition type nil file)))
1321      (list file type description disposition)))
1322   ;; Don't move point if this command is invoked inside the message header.
1323   (let ((head (unless (message-in-body-p)
1324                 (prog1
1325                     (point)
1326                   (goto-char (point-max))))))
1327     (mml-insert-empty-tag 'part
1328                           'type type
1329                           ;; icicles redefines read-file-name and returns a
1330                           ;; string w/ text properties :-/
1331                           'filename (mm-substring-no-properties file)
1332                           'disposition (or disposition "attachment")
1333                           'description description)
1334     (when head
1335       (unless (prog1
1336                   (pos-visible-in-window-p)
1337                 (goto-char head))
1338         (message "The file \"%s\" has been attached at the end of the message"
1339                  (file-name-nondirectory file))))))
1340
1341 (defun mml-dnd-attach-file (uri action)
1342   "Attach a drag and drop file.
1343
1344 Ask for type, description or disposition according to
1345 `mml-dnd-attach-options'."
1346   (let ((file (dnd-get-local-file-name uri t)))
1347     (when (and file (file-regular-p file))
1348       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1349             type description disposition)
1350         (setq mml-dnd-attach-options
1351               (when (and (eq mml-dnd-attach-options t)
1352                          (not
1353                           (y-or-n-p
1354                            "Use default type, disposition and description? ")))
1355                 '(type description disposition)))
1356         (when (or (memq 'type mml-dnd-attach-options)
1357                   (memq 'disposition mml-dnd-attach-options))
1358           (setq type (mml-minibuffer-read-type file)))
1359         (when (memq 'description mml-dnd-attach-options)
1360           (setq description (mml-minibuffer-read-description)))
1361         (when (memq 'disposition mml-dnd-attach-options)
1362           (setq disposition (mml-minibuffer-read-disposition type nil file)))
1363         (mml-attach-file file type description disposition)))))
1364
1365 (defun mml-attach-buffer (buffer &optional type description disposition)
1366   "Attach a buffer to the outgoing MIME message.
1367 BUFFER is the name of the buffer to attach.  See
1368 `mml-attach-file' for details of operation."
1369   (interactive
1370    (let* ((buffer (read-buffer "Attach buffer: "))
1371           (type (mml-minibuffer-read-type buffer "text/plain"))
1372           (description (mml-minibuffer-read-description))
1373           (disposition (mml-minibuffer-read-disposition type nil)))
1374      (list buffer type description disposition)))
1375   ;; Don't move point if this command is invoked inside the message header.
1376   (let ((head (unless (message-in-body-p)
1377                 (prog1
1378                     (point)
1379                   (goto-char (point-max))))))
1380     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1381                           'disposition disposition
1382                           'description description)
1383     (when head
1384       (unless (prog1
1385                   (pos-visible-in-window-p)
1386                 (goto-char head))
1387         (message
1388          "The buffer \"%s\" has been attached at the end of the message"
1389          buffer)))))
1390
1391 (defun mml-attach-external (file &optional type description)
1392   "Attach an external file into the buffer.
1393 FILE is an ange-ftp/efs specification of the part location.
1394 TYPE is the MIME type to use."
1395   (interactive
1396    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1397           (type (mml-minibuffer-read-type file))
1398           (description (mml-minibuffer-read-description)))
1399      (list file type description)))
1400   ;; Don't move point if this command is invoked inside the message header.
1401   (let ((head (unless (message-in-body-p)
1402                 (prog1
1403                     (point)
1404                   (goto-char (point-max))))))
1405     (mml-insert-empty-tag 'external 'type type 'name file
1406                           'disposition "attachment" 'description description)
1407     (when head
1408       (unless (prog1
1409                   (pos-visible-in-window-p)
1410                 (goto-char head))
1411         (message "The file \"%s\" has been attached at the end of the message"
1412                  (file-name-nondirectory file))))))
1413
1414 (defun mml-insert-multipart (&optional type)
1415   (interactive (if (message-in-body-p)
1416                    (list (gnus-completing-read "Multipart type"
1417                                                '("mixed" "alternative"
1418                                                  "digest" "parallel"
1419                                                  "signed" "encrypted")
1420                                                nil "mixed"))
1421                  (error "Use this command in the message body")))
1422   (or type
1423       (setq type "mixed"))
1424   (mml-insert-empty-tag "multipart" 'type type)
1425   (forward-line -1))
1426
1427 (defun mml-insert-part (&optional type)
1428   (interactive (if (message-in-body-p)
1429                    (list (mml-minibuffer-read-type ""))
1430                  (error "Use this command in the message body")))
1431   (mml-insert-tag 'part 'type type 'disposition "inline"))
1432
1433 (declare-function message-subscribed-p "message" ())
1434 (declare-function message-make-mail-followup-to "message"
1435                   (&optional only-show-subscribed))
1436 (declare-function message-position-on-field "message" (header &rest afters))
1437
1438 (defun mml-preview-insert-mail-followup-to ()
1439   "Insert a Mail-Followup-To header before previewing an article.
1440 Should be adopted if code in `message-send-mail' is changed."
1441   (when (and (message-mail-p)
1442              (message-subscribed-p)
1443              (not (mail-fetch-field "mail-followup-to"))
1444              (message-make-mail-followup-to))
1445     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1446     (insert (message-make-mail-followup-to))))
1447
1448 (defvar mml-preview-buffer nil)
1449
1450 (autoload 'gnus-make-hashtable "gnus-util")
1451 (autoload 'widget-button-press "wid-edit" nil t)
1452 (declare-function widget-event-point "wid-edit" (event))
1453 ;; If gnus-buffer-configuration is bound this is loaded.
1454 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
1455 ;; Called after message-mail-p, which autoloads message.
1456 (declare-function message-news-p                "message" ())
1457 (declare-function message-options-set-recipient "message" ())
1458 (declare-function message-generate-headers      "message" (headers))
1459 (declare-function message-sort-headers          "message" ())
1460
1461 (defun mml-preview (&optional raw)
1462   "Display current buffer with Gnus, in a new buffer.
1463 If RAW, display a raw encoded MIME message.
1464
1465 The window layout for the preview buffer is controlled by the variables
1466 `special-display-buffer-names', `special-display-regexps', or
1467 `gnus-buffer-configuration' (the first match made will be used),
1468 or the `pop-to-buffer' function."
1469   (interactive "P")
1470   (setq mml-preview-buffer (generate-new-buffer
1471                             (concat (if raw "*Raw MIME preview of "
1472                                       "*MIME preview of ") (buffer-name))))
1473   (require 'gnus-msg)                 ; for gnus-setup-posting-charset
1474   (save-excursion
1475     (let* ((buf (current-buffer))
1476            (article-editing (eq major-mode 'gnus-article-edit-mode))
1477            (message-options message-options)
1478            (message-this-is-mail (message-mail-p))
1479            (message-this-is-news (message-news-p))
1480            (message-posting-charset (or (gnus-setup-posting-charset
1481                                          (save-restriction
1482                                            (message-narrow-to-headers-or-head)
1483                                            (message-fetch-field "Newsgroups")))
1484                                         message-posting-charset)))
1485       (message-options-set-recipient)
1486       (when (boundp 'gnus-buffers)
1487         (push mml-preview-buffer gnus-buffers))
1488       (save-restriction
1489         (widen)
1490         (set-buffer mml-preview-buffer)
1491         (erase-buffer)
1492         (insert-buffer-substring buf))
1493       (mml-preview-insert-mail-followup-to)
1494       (let ((message-deletable-headers (if (message-news-p)
1495                                            nil
1496                                          message-deletable-headers))
1497             (mail-header-separator (if article-editing
1498                                        ""
1499                                      mail-header-separator)))
1500         (message-generate-headers
1501          (copy-sequence (if (message-news-p)
1502                             message-required-news-headers
1503                           message-required-mail-headers)))
1504         (unless article-editing
1505           (if (re-search-forward
1506                (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1507               (replace-match "\n"))
1508           (setq mail-header-separator ""))
1509         (message-sort-headers)
1510         (mml-to-mime))
1511       (if raw
1512           (when (fboundp 'set-buffer-multibyte)
1513             (let ((s (buffer-string)))
1514               ;; Insert the content into unibyte buffer.
1515               (erase-buffer)
1516               (mm-disable-multibyte)
1517               (insert s)))
1518         (let ((gnus-newsgroup-charset (car message-posting-charset))
1519               gnus-article-prepare-hook gnus-original-article-buffer
1520               gnus-displaying-mime)
1521           (run-hooks 'gnus-article-decode-hook)
1522           (let ((gnus-newsgroup-name "dummy")
1523                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1524                                         (gnus-make-hashtable 5))))
1525             (gnus-article-prepare-display))))
1526       ;; Disable article-mode-map.
1527       (use-local-map nil)
1528       (gnus-make-local-hook 'kill-buffer-hook)
1529       (add-hook 'kill-buffer-hook
1530                 (lambda ()
1531                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1532       (setq buffer-read-only t)
1533       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1534       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1535       (local-set-key "\r"
1536                      (lambda ()
1537                        (interactive)
1538                        (widget-button-press (point))))
1539       (local-set-key gnus-mouse-2
1540                      (lambda (event)
1541                        (interactive "@e")
1542                        (widget-button-press (widget-event-point event) event)))
1543       ;; FIXME: Buffer is in article mode, but most tool bar commands won't
1544       ;; work.  Maybe only keep the following icons: search, print, quit
1545       (goto-char (point-min))))
1546   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1547            (boundp 'gnus-buffer-configuration)
1548            (assq 'mml-preview gnus-buffer-configuration))
1549       (let ((gnus-message-buffer (current-buffer)))
1550         (gnus-configure-windows 'mml-preview))
1551     (pop-to-buffer mml-preview-buffer)))
1552
1553 (defun mml-validate ()
1554   "Validate the current MML document."
1555   (interactive)
1556   (mml-parse))
1557
1558 (defun mml-tweak-part (cont)
1559   "Tweak a MML part."
1560   (let ((tweak (cdr (assq 'tweak cont)))
1561         func)
1562     (cond
1563      (tweak
1564       (setq func
1565             (or (cdr (assoc tweak mml-tweak-function-alist))
1566                 (intern tweak))))
1567      (mml-tweak-type-alist
1568       (let ((alist mml-tweak-type-alist)
1569             (type (or (cdr (assq 'type cont)) "text/plain")))
1570         (while alist
1571           (if (string-match (caar alist) type)
1572               (setq func (cdar alist)
1573                     alist nil)
1574             (setq alist (cdr alist)))))))
1575     (if func
1576         (funcall func cont)
1577       cont)
1578     (let ((alist mml-tweak-sexp-alist))
1579       (while alist
1580         (if (eval (caar alist))
1581             (funcall (cdar alist) cont))
1582         (setq alist (cdr alist)))))
1583   cont)
1584
1585 (defun mml-tweak-externalize-attachments (cont)
1586   "Tweak attached files as external parts."
1587   (let (filename-cons)
1588     (when (and (eq (car cont) 'part)
1589                (not (cdr (assq 'buffer cont)))
1590                (and (setq filename-cons (assq 'filename cont))
1591                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1592       (setcar cont 'external)
1593       (setcar filename-cons 'name))))
1594
1595 (provide 'mml)
1596
1597 ;;; mml.el ends here