cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; For Emacs < 22.2.
  27 (eval-and-compile
  28   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  29
  30 (require 'mm-util)
  31 (require 'mm-bodies)
  32 (require 'mm-encode)
  33 (require 'mm-decode)
  34 (require 'mml-sec)
  35 (eval-when-compile (require 'cl))
  36
  37 (autoload 'message-make-message-id "message")
  38 (autoload 'gnus-setup-posting-charset "gnus-msg")
  39 (autoload 'gnus-make-local-hook "gnus-util")
  40 (autoload 'message-fetch-field "message")
  41 (autoload 'message-mark-active-p "message")
  42 (autoload 'message-info "message")
  43 (autoload 'fill-flowed-encode "flow-fill")
  44 (autoload 'message-posting-charset "message")
  45 (autoload 'dnd-get-local-file-name "dnd")
  46
  47 (autoload 'message-options-set    "message")
  48 (autoload 'message-narrow-to-head "message")
  49 (autoload 'message-in-body-p      "message")
  50 (autoload 'message-mail-p         "message")
  51
  52 (defvar gnus-article-mime-handles)
  53 (defvar gnus-mouse-2)
  54 (defvar gnus-newsrc-hashtb)
  55 (defvar message-default-charset)
  56 (defvar message-deletable-headers)
  57 (defvar message-options)
  58 (defvar message-posting-charset)
  59 (defvar message-required-mail-headers)
  60 (defvar message-required-news-headers)
  61 (defvar dnd-protocol-alist)
  62 (defvar mml-dnd-protocol-alist)
  63
  64 (defcustom mml-content-type-parameters
  65   '(name access-type expiration size permission format)
  66   "*A list of acceptable parameters in MML tag.
  67 These parameters are generated in Content-Type header if exists."
  68   :version "22.1"
  69   :type '(repeat (symbol :tag "Parameter"))
  70   :group 'message)
  71
  72 (defcustom mml-content-disposition-parameters
  73   '(filename creation-date modification-date read-date)
  74   "*A list of acceptable parameters in MML tag.
  75 These parameters are generated in Content-Disposition header if exists."
  76   :version "22.1"
  77   :type '(repeat (symbol :tag "Parameter"))
  78   :group 'message)
  79
  80 (defcustom mml-content-disposition-alist
  81   '((text (rtf . "attachment") (t . "inline"))
  82     (t . "attachment"))
  83   "Alist of MIME types or regexps matching file names and default dispositions.
  84 Each element should be one of the following three forms:
  85
  86   (REGEXP . DISPOSITION)
  87   (SUPERTYPE (SUBTYPE . DISPOSITION) (SUBTYPE . DISPOSITION)...)
  88   (TYPE . DISPOSITION)
  89
  90 Where REGEXP is a string which matches the file name (if any) of an
  91 attachment, SUPERTYPE, SUBTYPE and TYPE should be symbols which are a
  92 MIME supertype (e.g., text), a MIME subtype (e.g., plain) and a MIME
  93 type (e.g., text/plain) respectively, and DISPOSITION should be either
  94 the string \"attachment\" or the string \"inline\".  The value t for
  95 SUPERTYPE, SUBTYPE or TYPE matches any of those types.  The first
  96 match found will be used."
  97   :version "23.1" ;; No Gnus
  98   :type (let ((dispositions '(radio :format "DISPOSITION: %v"
  99                                     :value "attachment"
 100                                     (const :format "%v " "attachment")
 101                                     (const :format "%v\n" "inline"))))
 102           `(repeat
 103             :offset 0
 104             (choice :format "%[Value Menu%]%v"
 105                     (cons :tag "(REGEXP . DISPOSITION)" :extra-offset 4
 106                           (regexp :tag "REGEXP" :value ".*")
 107                           ,dispositions)
 108                     (cons :tag "(SUPERTYPE (SUBTYPE . DISPOSITION)...)"
 109                           :indent 0
 110                           (symbol :tag "    SUPERTYPE" :value text)
 111                           (repeat :format "%v%i\n" :offset 0 :extra-offset 4
 112                                   (cons :format "%v" :extra-offset 5
 113                                         (symbol :tag "SUBTYPE" :value t)
 114                                         ,dispositions)))
 115                     (cons :tag "(TYPE . DISPOSITION)" :extra-offset 4
 116                           (symbol :tag "TYPE" :value t)
 117                           ,dispositions))))
 118   :group 'message)
 119
 120 (defcustom mml-insert-mime-headers-always nil
 121   "If non-nil, always put Content-Type: text/plain at top of empty parts.
 122 It is necessary to work against a bug in certain clients."
 123   :version "22.1"
 124   :type 'boolean
 125   :group 'message)
 126
 127 (defvar mml-tweak-type-alist nil
 128   "A list of (TYPE . FUNCTION) for tweaking MML parts.
 129 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
 130 is a Lisp function which is called with the MML handle to tweak the
 131 part.  This variable is used only when no TWEAK parameter exists in
 132 the MML handle.")
 133
 134 (defvar mml-tweak-function-alist nil
 135   "A list of (NAME . FUNCTION) for tweaking MML parts.
 136 NAME is a string containing the name of the TWEAK parameter in the MML
 137 handle.  FUNCTION is a Lisp function which is called with the MML
 138 handle to tweak the part.")
 139
 140 (defvar mml-tweak-sexp-alist
 141   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
 142   "A list of (SEXP . FUNCTION) for tweaking MML parts.
 143 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
 144 is called.  FUNCTION is a Lisp function which is called with the MML
 145 handle to tweak the part.")
 146
 147 (defvar mml-externalize-attachments nil
 148   "*If non-nil, local-file attachments are generated as external parts.")
 149
 150 (defvar mml-generate-multipart-alist nil
 151   "*Alist of multipart generation functions.
 152 Each entry has the form (NAME . FUNCTION), where
 153 NAME is a string containing the name of the part (without the
 154 leading \"/multipart/\"),
 155 FUNCTION is a Lisp function which is called to generate the part.
 156
 157 The Lisp function has to supply the appropriate MIME headers and the
 158 contents of this part.")
 159
 160 (defvar mml-syntax-table
 161   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 162     (modify-syntax-entry ?\\ "/" table)
 163     (modify-syntax-entry ?< "(" table)
 164     (modify-syntax-entry ?> ")" table)
 165     (modify-syntax-entry ?@ "w" table)
 166     (modify-syntax-entry ?/ "w" table)
 167     (modify-syntax-entry ?= " " table)
 168     (modify-syntax-entry ?* " " table)
 169     (modify-syntax-entry ?\; " " table)
 170     (modify-syntax-entry ?\' " " table)
 171     table))
 172
 173 (defvar mml-boundary-function 'mml-make-boundary
 174   "A function called to suggest a boundary.
 175 The function may be called several times, and should try to make a new
 176 suggestion each time.  The function is called with one parameter,
 177 which is a number that says how many times the function has been
 178 called for this message.")
 179
 180 (defvar mml-confirmation-set nil
 181   "A list of symbols, each of which disables some warning.
 182 `unknown-encoding': always send messages contain characters with
 183 unknown encoding; `use-ascii': always use ASCII for those characters
 184 with unknown encoding; `multipart': always send messages with more than
 185 one charsets.")
 186
 187 (defvar mml-generate-default-type "text/plain"
 188   "Content type by which the Content-Type header can be omitted.
 189 The Content-Type header will not be put in the MIME part if the type
 190 equals the value and there's no parameter (e.g. charset, format, etc.)
 191 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 192 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 193 part.  This is for the internal use, you should never modify the value.")
 194
 195 (defvar mml-buffer-list nil)
 196
 197 (defun mml-generate-new-buffer (name)
 198   (let ((buf (generate-new-buffer name)))
 199     (push buf mml-buffer-list)
 200     buf))
 201
 202 (defun mml-destroy-buffers ()
 203   (let (kill-buffer-hook)
 204     (mapc 'kill-buffer mml-buffer-list)
 205     (setq mml-buffer-list nil)))
 206
 207 (defun mml-parse ()
 208   "Parse the current buffer as an MML document."
 209   (save-excursion
 210     (goto-char (point-min))
 211     (with-syntax-table mml-syntax-table
 212       (mml-parse-1))))
 213
 214 (defun mml-parse-1 ()
 215   "Parse the current buffer as an MML document."
 216   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 217     (while (and (not (eobp))
 218                 (not (looking-at "<#/multipart")))
 219       (cond
 220        ((looking-at "<#secure")
 221         ;; The secure part is essentially a meta-meta tag, which
 222         ;; expands to either a part tag if there are no other parts in
 223         ;; the document or a multipart tag if there are other parts
 224         ;; included in the message
 225         (let* (secure-mode
 226                (taginfo (mml-read-tag))
 227                (keyfile (cdr (assq 'keyfile taginfo)))
 228                (certfile (cdr (assq 'certfile taginfo)))
 229                (recipients (cdr (assq 'recipients taginfo)))
 230                (sender (cdr (assq 'sender taginfo)))
 231                (location (cdr (assq 'tag-location taginfo)))
 232                (mode (cdr (assq 'mode taginfo)))
 233                (method (cdr (assq 'method taginfo)))
 234                tags)
 235           (save-excursion
 236             (if (re-search-forward
 237                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 238                 (setq secure-mode "multipart")
 239               (setq secure-mode "part")))
 240           (save-excursion
 241             (goto-char location)
 242             (re-search-forward "<#secure[^\n]*>\n"))
 243           (delete-region (match-beginning 0) (match-end 0))
 244           (cond ((string= mode "sign")
 245                  (setq tags (list "sign" method)))
 246                 ((string= mode "encrypt")
 247                  (setq tags (list "encrypt" method)))
 248                 ((string= mode "signencrypt")
 249                  (setq tags (list "sign" method "encrypt" method))))
 250           (eval `(mml-insert-tag ,secure-mode
 251                                  ,@tags
 252                                  ,(if keyfile "keyfile")
 253                                  ,keyfile
 254                                  ,(if certfile "certfile")
 255                                  ,certfile
 256                                  ,(if recipients "recipients")
 257                                  ,recipients
 258                                  ,(if sender "sender")
 259                                  ,sender))
 260           ;; restart the parse
 261           (goto-char location)))
 262        ((looking-at "<#multipart")
 263         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 264        ((looking-at "<#external")
 265         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 266               struct))
 267        (t
 268         (if (or (looking-at "<#part") (looking-at "<#mml"))
 269             (setq tag (mml-read-tag)
 270                   no-markup-p nil
 271                   warn nil)
 272           (setq tag (list 'part '(type . "text/plain"))
 273                 no-markup-p t
 274                 warn t))
 275         (setq raw (cdr (assq 'raw tag))
 276               point (point)
 277               contents (mml-read-part (eq 'mml (car tag)))
 278               charsets (cond
 279                         (raw nil)
 280                         ((assq 'charset tag)
 281                          (list
 282                           (intern (downcase (cdr (assq 'charset tag))))))
 283                         (t
 284                          (mm-find-mime-charset-region point (point)
 285                                                       mm-hack-charsets))))
 286         (when (and (not raw) (memq nil charsets))
 287           (if (or (memq 'unknown-encoding mml-confirmation-set)
 288                   (message-options-get 'unknown-encoding)
 289                   (and (y-or-n-p "\
 290 Message contains characters with unknown encoding.  Really send? ")
 291                        (message-options-set 'unknown-encoding t)))
 292               (if (setq use-ascii
 293                         (or (memq 'use-ascii mml-confirmation-set)
 294                             (message-options-get 'use-ascii)
 295                             (and (y-or-n-p "Use ASCII as charset? ")
 296                                  (message-options-set 'use-ascii t))))
 297                   (setq charsets (delq nil charsets))
 298                 (setq warn nil))
 299             (error "Edit your message to remove those characters")))
 300         (if (or raw
 301                 (eq 'mml (car tag))
 302                 (< (length charsets) 2))
 303             (if (or (not no-markup-p)
 304                     (string-match "[^ \t\r\n]" contents))
 305                 ;; Don't create blank parts.
 306                 (push (nconc tag (list (cons 'contents contents)))
 307                       struct))
 308           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 309                           tag point (point) use-ascii)))
 310             (when (and warn
 311                        (not (memq 'multipart mml-confirmation-set))
 312                        (not (message-options-get 'multipart))
 313                        (not (and (y-or-n-p (format "\
 314 A message part needs to be split into %d charset parts.  Really send? "
 315                                                    (length nstruct)))
 316                                  (message-options-set 'multipart t))))
 317               (error "Edit your message to use only one charset"))
 318             (setq struct (nconc nstruct struct)))))))
 319     (unless (eobp)
 320       (forward-line 1))
 321     (nreverse struct)))
 322
 323 (defun mml-parse-singlepart-with-multiple-charsets
 324   (orig-tag beg end &optional use-ascii)
 325   (save-excursion
 326     (save-restriction
 327       (narrow-to-region beg end)
 328       (goto-char (point-min))
 329       (let ((current (or (mm-mime-charset (mm-charset-after))
 330                          (and use-ascii 'us-ascii)))
 331             charset struct space newline paragraph)
 332         (while (not (eobp))
 333           (setq charset (mm-mime-charset (mm-charset-after)))
 334           (cond
 335            ;; The charset remains the same.
 336            ((eq charset 'us-ascii))
 337            ((or (and use-ascii (not charset))
 338                 (eq charset current))
 339             (setq space nil
 340                   newline nil
 341                   paragraph nil))
 342            ;; The initial charset was ascii.
 343            ((eq current 'us-ascii)
 344             (setq current charset
 345                   space nil
 346                   newline nil
 347                   paragraph nil))
 348            ;; We have a change in charsets.
 349            (t
 350             (push (append
 351                    orig-tag
 352                    (list (cons 'contents
 353                                (buffer-substring-no-properties
 354                                 beg (or paragraph newline space (point))))))
 355                   struct)
 356             (setq beg (or paragraph newline space (point))
 357                   current charset
 358                   space nil
 359                   newline nil
 360                   paragraph nil)))
 361           ;; Compute places where it might be nice to break the part.
 362           (cond
 363            ((memq (following-char) '(?  ?\t))
 364             (setq space (1+ (point))))
 365            ((and (eq (following-char) ?\n)
 366                  (not (bobp))
 367                  (eq (char-after (1- (point))) ?\n))
 368             (setq paragraph (point)))
 369            ((eq (following-char) ?\n)
 370             (setq newline (1+ (point)))))
 371           (forward-char 1))
 372         ;; Do the final part.
 373         (unless (= beg (point))
 374           (push (append orig-tag
 375                         (list (cons 'contents
 376                                     (buffer-substring-no-properties
 377                                      beg (point)))))
 378                 struct))
 379         struct))))
 380
 381 (defun mml-read-tag ()
 382   "Read a tag and return the contents."
 383   (let ((orig-point (point))
 384         contents name elem val)
 385     (forward-char 2)
 386     (setq name (buffer-substring-no-properties
 387                 (point) (progn (forward-sexp 1) (point))))
 388     (skip-chars-forward " \t\n")
 389     (while (not (looking-at ">[ \t]*\n?"))
 390       (setq elem (buffer-substring-no-properties
 391                   (point) (progn (forward-sexp 1) (point))))
 392       (skip-chars-forward "= \t\n")
 393       (setq val (buffer-substring-no-properties
 394                  (point) (progn (forward-sexp 1) (point))))
 395       (when (string-match "^\"\\(.*\\)\"$" val)
 396         (setq val (match-string 1 val)))
 397       (push (cons (intern elem) val) contents)
 398       (skip-chars-forward " \t\n"))
 399     (goto-char (match-end 0))
 400     ;; Don't skip the leading space.
 401     ;;(skip-chars-forward " \t\n")
 402     ;; Put the tag location into the returned contents
 403     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 404     (cons (intern name) (nreverse contents))))
 405
 406 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 407   (let ((str (buffer-substring-no-properties start end))
 408         (bufstart start) tmp)
 409     (while (setq tmp (text-property-any start end 'hard 't))
 410       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 411                            '(hard t) str)
 412       (setq start (1+ tmp)))
 413     str))
 414
 415 (defun mml-read-part (&optional mml)
 416   "Return the buffer up till the next part, multipart or closing part or multipart.
 417 If MML is non-nil, return the buffer up till the correspondent mml tag."
 418   (let ((beg (point)) (count 1))
 419     ;; If the tag ended at the end of the line, we go to the next line.
 420     (when (looking-at "[ \t]*\n")
 421       (forward-line 1))
 422     (if mml
 423         (progn
 424           (while (and (> count 0) (not (eobp)))
 425             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 426                 (setq count (+ count (if (match-beginning 1) -1 1)))
 427               (goto-char (point-max))))
 428           (mml-buffer-substring-no-properties-except-hard-newlines
 429            beg (if (> count 0)
 430                    (point)
 431                  (match-beginning 0))))
 432       (if (re-search-forward
 433            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 434           (prog1
 435               (mml-buffer-substring-no-properties-except-hard-newlines
 436                beg (match-beginning 0))
 437             (if (or (not (match-beginning 1))
 438                     (equal (match-string 2) "multipart"))
 439                 (goto-char (match-beginning 0))
 440               (when (looking-at "[ \t]*\n")
 441                 (forward-line 1))))
 442         (mml-buffer-substring-no-properties-except-hard-newlines
 443          beg (goto-char (point-max)))))))
 444
 445 (defvar mml-boundary nil)
 446 (defvar mml-base-boundary "-=-=")
 447 (defvar mml-multipart-number 0)
 448
 449 (defun mml-generate-mime ()
 450   "Generate a MIME message based on the current MML document."
 451   (let ((cont (mml-parse))
 452         (mml-multipart-number mml-multipart-number))
 453     (if (not cont)
 454         nil
 455       (mm-with-multibyte-buffer
 456         (if (and (consp (car cont))
 457                  (= (length cont) 1))
 458             (mml-generate-mime-1 (car cont))
 459           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 460                                       cont)))
 461         (buffer-string)))))
 462
 463 (defun mml-generate-mime-1 (cont)
 464   (let ((mm-use-ultra-safe-encoding
 465          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 466     (save-restriction
 467       (narrow-to-region (point) (point))
 468       (mml-tweak-part cont)
 469       (cond
 470        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 471         (let* ((raw (cdr (assq 'raw cont)))
 472                (filename (cdr (assq 'filename cont)))
 473                (type (or (cdr (assq 'type cont))
 474                          (if filename
 475                              (or (mm-default-file-encoding filename)
 476                                  "application/octet-stream")
 477                            "text/plain")))
 478                (charset (cdr (assq 'charset cont)))
 479                (coding (mm-charset-to-coding-system charset))
 480                encoding flowed coded)
 481           (cond ((eq coding 'ascii)
 482                  (setq charset nil
 483                        coding nil))
 484                 (charset
 485                  ;; The value of `charset' might be a bogus alias that
 486                  ;; `mm-charset-synonym-alist' provides, like `utf8',
 487                  ;; so we prefer the MIME charset that Emacs knows for
 488                  ;; the coding system `coding'.
 489                  (setq charset (or (mm-coding-system-to-mime-charset coding)
 490                                    (intern (downcase charset))))))
 491           (if (and (not raw)
 492                    (member (car (split-string type "/")) '("text" "message")))
 493               (progn
 494                 (with-temp-buffer
 495                   (cond
 496                    ((cdr (assq 'buffer cont))
 497                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 498                    ((and filename
 499                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 500                     (let ((coding-system-for-read coding))
 501                       (mm-insert-file-contents filename)))
 502                    ((eq 'mml (car cont))
 503                     (insert (cdr (assq 'contents cont))))
 504                    (t
 505                     (save-restriction
 506                       (narrow-to-region (point) (point))
 507                       (insert (cdr (assq 'contents cont)))
 508                       ;; Remove quotes from quoted tags.
 509                       (goto-char (point-min))
 510                       (while (re-search-forward
 511                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\)"
 512                               nil t)
 513                         (delete-region (+ (match-beginning 0) 2)
 514                                        (+ (match-beginning 0) 3))))))
 515                   (cond
 516                    ((eq (car cont) 'mml)
 517                     (let ((mml-boundary (mml-compute-boundary cont))
 518                           ;; It is necessary for the case where this
 519                           ;; function is called recursively since
 520                           ;; `m-g-d-t' will be bound to "message/rfc822"
 521                           ;; when encoding an article to be forwarded.
 522                           (mml-generate-default-type "text/plain"))
 523                       (mml-to-mime))
 524                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 525                       ;; ignore 0x1b, it is part of iso-2022-jp
 526                       (setq encoding (mm-body-7-or-8))))
 527                    ((string= (car (split-string type "/")) "message")
 528                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 529                       ;; ignore 0x1b, it is part of iso-2022-jp
 530                       (setq encoding (mm-body-7-or-8))))
 531                    (t
 532                     ;; Only perform format=flowed filling on text/plain
 533                     ;; parts where there either isn't a format parameter
 534                     ;; in the mml tag or it says "flowed" and there
 535                     ;; actually are hard newlines in the text.
 536                     (let (use-hard-newlines)
 537                       (when (and (string= type "text/plain")
 538                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 539                                  (or (null (assq 'format cont))
 540                                      (string= (cdr (assq 'format cont))
 541                                               "flowed"))
 542                                  (setq use-hard-newlines
 543                                        (text-property-any
 544                                         (point-min) (point-max) 'hard 't)))
 545                         (fill-flowed-encode)
 546                         ;; Indicate that `mml-insert-mime-headers' should
 547                         ;; insert a "; format=flowed" string unless the
 548                         ;; user has already specified it.
 549                         (setq flowed (null (assq 'format cont)))))
 550                     ;; Prefer `utf-8' for text/calendar parts.
 551                     (if (or charset
 552                             (not (string= type "text/calendar")))
 553                         (setq charset (mm-encode-body charset))
 554                       (let ((mm-coding-system-priorities
 555                              (cons 'utf-8 mm-coding-system-priorities)))
 556                         (setq charset (mm-encode-body))))
 557                     (setq encoding (mm-body-encoding
 558                                     charset (cdr (assq 'encoding cont))))))
 559                   (setq coded (buffer-string)))
 560                 (mml-insert-mime-headers cont type charset encoding flowed)
 561                 (insert "\n")
 562                 (insert coded))
 563             (mm-with-unibyte-buffer
 564               (cond
 565                ((cdr (assq 'buffer cont))
 566                 (insert (mm-string-as-unibyte
 567                          (with-current-buffer (cdr (assq 'buffer cont))
 568                            (buffer-string)))))
 569                ((and filename
 570                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 571                 (let ((coding-system-for-read mm-binary-coding-system))
 572                   (mm-insert-file-contents filename nil nil nil nil t))
 573                 (unless charset
 574                   (setq charset (mm-coding-system-to-mime-charset
 575                                  (mm-find-buffer-file-coding-system
 576                                   filename)))))
 577                (t
 578                 (let ((contents (cdr (assq 'contents cont))))
 579                   (if (if (featurep 'xemacs)
 580                           (string-match "[^\000-\377]" contents)
 581                         (mm-multibyte-string-p contents))
 582                       (progn
 583                         (mm-enable-multibyte)
 584                         (insert contents)
 585                         (unless raw
 586                           (setq charset (mm-encode-body charset))))
 587                     (insert contents)))))
 588               (setq encoding (mm-encode-buffer type)
 589                     coded (mm-string-as-multibyte (buffer-string))))
 590             (mml-insert-mime-headers cont type charset encoding nil)
 591             (insert "\n" coded))))
 592        ((eq (car cont) 'external)
 593         (insert "Content-Type: message/external-body")
 594         (let ((parameters (mml-parameter-string
 595                            cont '(expiration size permission)))
 596               (name (cdr (assq 'name cont)))
 597               (url (cdr (assq 'url cont))))
 598           (when name
 599             (setq name (mml-parse-file-name name))
 600             (if (stringp name)
 601                 (mml-insert-parameter
 602                  (mail-header-encode-parameter "name" name)
 603                  "access-type=local-file")
 604               (mml-insert-parameter
 605                (mail-header-encode-parameter
 606                 "name" (file-name-nondirectory (nth 2 name)))
 607                (mail-header-encode-parameter "site" (nth 1 name))
 608                (mail-header-encode-parameter
 609                 "directory" (file-name-directory (nth 2 name))))
 610               (mml-insert-parameter
 611                (concat "access-type="
 612                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 613                            "anon-ftp"
 614                          "ftp")))))
 615           (when url
 616             (mml-insert-parameter
 617              (mail-header-encode-parameter "url" url)
 618              "access-type=url"))
 619           (when parameters
 620             (mml-insert-parameter-string
 621              cont '(expiration size permission)))
 622           (insert "\n\n")
 623           (insert "Content-Type: "
 624                   (or (cdr (assq 'type cont))
 625                       (if name
 626                           (or (mm-default-file-encoding name)
 627                               "application/octet-stream")
 628                         "text/plain"))
 629                   "\n")
 630           (insert "Content-ID: " (message-make-message-id) "\n")
 631           (insert "Content-Transfer-Encoding: "
 632                   (or (cdr (assq 'encoding cont)) "binary"))
 633           (insert "\n\n")
 634           (insert (or (cdr (assq 'contents cont))))
 635           (insert "\n")))
 636        ((eq (car cont) 'multipart)
 637         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 638                (mml-generate-default-type (if (equal type "digest")
 639                                               "message/rfc822"
 640                                             "text/plain"))
 641                (handler (assoc type mml-generate-multipart-alist)))
 642           (if handler
 643               (funcall (cdr handler) cont)
 644             ;; No specific handler.  Use default one.
 645             (let ((mml-boundary (mml-compute-boundary cont)))
 646               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 647                               type mml-boundary)
 648                       (if (cdr (assq 'start cont))
 649                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 650                         "\n"))
 651               (let ((cont cont) part)
 652                 (while (setq part (pop cont))
 653                   ;; Skip `multipart' and attributes.
 654                   (when (and (consp part) (consp (cdr part)))
 655                     (insert "\n--" mml-boundary "\n")
 656                     (mml-generate-mime-1 part)
 657                     (goto-char (point-max)))))
 658               (insert "\n--" mml-boundary "--\n")))))
 659        (t
 660         (error "Invalid element: %S" cont)))
 661       ;; handle sign & encrypt tags in a semi-smart way.
 662       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 663             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 664                                  mml-encrypt-alist))
 665             sender recipients)
 666         (when (or sign-item encrypt-item)
 667           (when (setq sender (cdr (assq 'sender cont)))
 668             (message-options-set 'mml-sender sender)
 669             (message-options-set 'message-sender sender))
 670           (if (setq recipients (cdr (assq 'recipients cont)))
 671               (message-options-set 'message-recipients recipients))
 672           (let ((style (mml-signencrypt-style
 673                         (first (or sign-item encrypt-item)))))
 674             ;; check if: we're both signing & encrypting, both methods
 675             ;; are the same (why would they be different?!), and that
 676             ;; the signencrypt style allows for combined operation.
 677             (if (and sign-item encrypt-item (equal (first sign-item)
 678                                                    (first encrypt-item))
 679                      (equal style 'combined))
 680                 (funcall (nth 1 encrypt-item) cont t)
 681               ;; otherwise, revert to the old behavior.
 682               (when sign-item
 683                 (funcall (nth 1 sign-item) cont))
 684               (when encrypt-item
 685                 (funcall (nth 1 encrypt-item) cont)))))))))
 686
 687 (defun mml-compute-boundary (cont)
 688   "Return a unique boundary that does not exist in CONT."
 689   (let ((mml-boundary (funcall mml-boundary-function
 690                                (incf mml-multipart-number))))
 691     ;; This function tries again and again until it has found
 692     ;; a unique boundary.
 693     (while (not (catch 'not-unique
 694                   (mml-compute-boundary-1 cont))))
 695     mml-boundary))
 696
 697 (defun mml-compute-boundary-1 (cont)
 698   (let (filename)
 699     (cond
 700      ((eq (car cont) 'part)
 701       (with-temp-buffer
 702         (cond
 703          ((cdr (assq 'buffer cont))
 704           (insert-buffer-substring (cdr (assq 'buffer cont))))
 705          ((and (setq filename (cdr (assq 'filename cont)))
 706                (not (equal (cdr (assq 'nofile cont)) "yes")))
 707           (mm-insert-file-contents filename nil nil nil nil t))
 708          (t
 709           (insert (cdr (assq 'contents cont)))))
 710         (goto-char (point-min))
 711         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 712                                  nil t)
 713           (setq mml-boundary (funcall mml-boundary-function
 714                                       (incf mml-multipart-number)))
 715           (throw 'not-unique nil))))
 716      ((eq (car cont) 'multipart)
 717       (mapc 'mml-compute-boundary-1 (cddr cont))))
 718     t))
 719
 720 (defun mml-make-boundary (number)
 721   (concat (make-string (% number 60) ?=)
 722           (if (> number 17)
 723               (format "%x" number)
 724             "")
 725           mml-base-boundary))
 726
 727 (defun mml-content-disposition (type &optional filename)
 728   "Return a default disposition name suitable to TYPE or FILENAME."
 729   (let ((defs mml-content-disposition-alist)
 730         disposition def types)
 731     (while (and (not disposition) defs)
 732       (setq def (pop defs))
 733       (cond ((stringp (car def))
 734              (when (and filename
 735                         (string-match (car def) filename))
 736                (setq disposition (cdr def))))
 737             ((consp (cdr def))
 738              (when (string= (car (setq types (split-string type "/")))
 739                             (car def))
 740                (setq type (cadr types)
 741                      types (cdr def))
 742                (while (and (not disposition) types)
 743                  (setq def (pop types))
 744                  (when (or (eq (car def) t) (string= type (car def)))
 745                    (setq disposition (cdr def))))))
 746             (t
 747              (when (or (eq (car def) t) (string= type (car def)))
 748                (setq disposition (cdr def))))))
 749     (or disposition "attachment")))
 750
 751 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 752   (let (parameters id disposition description)
 753     (setq parameters
 754           (mml-parameter-string
 755            cont mml-content-type-parameters))
 756     (when (or charset
 757               parameters
 758               flowed
 759               (not (equal type mml-generate-default-type))
 760               mml-insert-mime-headers-always)
 761       (when (consp charset)
 762         (error
 763          "Can't encode a part with several charsets"))
 764       (insert "Content-Type: " type)
 765       (when charset
 766         (mml-insert-parameter
 767          (mail-header-encode-parameter "charset" (symbol-name charset))))
 768       (when flowed
 769         (mml-insert-parameter "format=flowed"))
 770       (when parameters
 771         (mml-insert-parameter-string
 772          cont mml-content-type-parameters))
 773       (insert "\n"))
 774     (when (setq id (cdr (assq 'id cont)))
 775       (insert "Content-ID: " id "\n"))
 776     (setq parameters
 777           (mml-parameter-string
 778            cont mml-content-disposition-parameters))
 779     (when (or (setq disposition (cdr (assq 'disposition cont)))
 780               parameters)
 781       (insert "Content-Disposition: "
 782               (or disposition
 783                   (mml-content-disposition type (cdr (assq 'filename cont)))))
 784       (when parameters
 785         (mml-insert-parameter-string
 786          cont mml-content-disposition-parameters))
 787       (insert "\n"))
 788     (unless (eq encoding '7bit)
 789       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 790     (when (setq description (cdr (assq 'description cont)))
 791       (insert "Content-Description: ")
 792       (setq description (prog1
 793                             (point)
 794                           (insert description "\n")))
 795       (mail-encode-encoded-word-region description (point)))))
 796
 797 (defun mml-parameter-string (cont types)
 798   (let ((string "")
 799         value type)
 800     (while (setq type (pop types))
 801       (when (setq value (cdr (assq type cont)))
 802         ;; Strip directory component from the filename parameter.
 803         (when (eq type 'filename)
 804           (setq value (file-name-nondirectory value)))
 805         (setq string (concat string "; "
 806                              (mail-header-encode-parameter
 807                               (symbol-name type) value)))))
 808     (when (not (zerop (length string)))
 809       string)))
 810
 811 (defun mml-insert-parameter-string (cont types)
 812   (let (value type)
 813     (while (setq type (pop types))
 814       (when (setq value (cdr (assq type cont)))
 815         ;; Strip directory component from the filename parameter.
 816         (when (eq type 'filename)
 817           (setq value (file-name-nondirectory value)))
 818         (mml-insert-parameter
 819          (mail-header-encode-parameter
 820           (symbol-name type) value))))))
 821
 822 (defvar ange-ftp-name-format)
 823 (defvar efs-path-regexp)
 824
 825 (defun mml-parse-file-name (path)
 826   (if (if (boundp 'efs-path-regexp)
 827           (string-match efs-path-regexp path)
 828         (if (boundp 'ange-ftp-name-format)
 829             (string-match (car ange-ftp-name-format) path)))
 830       (list (match-string 1 path) (match-string 2 path)
 831             (substring path (1+ (match-end 2))))
 832     path))
 833
 834 (defun mml-insert-buffer (buffer)
 835   "Insert BUFFER at point and quote any MML markup."
 836   (save-restriction
 837     (narrow-to-region (point) (point))
 838     (insert-buffer-substring buffer)
 839     (mml-quote-region (point-min) (point-max))
 840     (goto-char (point-max))))
 841
 842 ;;;
 843 ;;; Transforming MIME to MML
 844 ;;;
 845
 846 ;; message-narrow-to-head autoloads message.
 847 (declare-function message-remove-header "message"
 848                   (header &optional is-regexp first reverse))
 849
 850 (defun mime-to-mml (&optional handles)
 851   "Translate the current buffer (which should be a message) into MML.
 852 If HANDLES is non-nil, use it instead reparsing the buffer."
 853   ;; First decode the head.
 854   (save-restriction
 855     (message-narrow-to-head)
 856     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 857       (mail-decode-encoded-word-region (point-min) (point-max))))
 858   (unless handles
 859     (setq handles (mm-dissect-buffer t)))
 860   (goto-char (point-min))
 861   (search-forward "\n\n" nil t)
 862   (delete-region (point) (point-max))
 863   (if (stringp (car handles))
 864       (mml-insert-mime handles)
 865     (mml-insert-mime handles t))
 866   (mm-destroy-parts handles)
 867   (save-restriction
 868     (message-narrow-to-head)
 869     ;; Remove them, they are confusing.
 870     (message-remove-header "Content-Type")
 871     (message-remove-header "MIME-Version")
 872     (message-remove-header "Content-Disposition")
 873     (message-remove-header "Content-Transfer-Encoding")))
 874
 875 (autoload 'message-encode-message-body "message")
 876 (declare-function message-narrow-to-headers-or-head "message" ())
 877
 878 (defun mml-to-mime ()
 879   "Translate the current buffer from MML to MIME."
 880   ;; `message-encode-message-body' will insert an encoded Content-Description
 881   ;; header in the message header if the body contains a single part
 882   ;; that is specified by a user with a MML tag containing a description
 883   ;; token.  So, we encode the message header first to prevent the encoded
 884   ;; Content-Description header from being encoded again.
 885   (save-restriction
 886     (message-narrow-to-headers-or-head)
 887     ;; Skip past any From_ headers.
 888     (while (looking-at "From ")
 889       (forward-line 1))
 890     (let ((mail-parse-charset message-default-charset))
 891       (mail-encode-encoded-word-buffer)))
 892   (message-encode-message-body))
 893
 894 (defun mml-insert-mime (handle &optional no-markup)
 895   (let (textp buffer mmlp)
 896     ;; Determine type and stuff.
 897     (unless (stringp (car handle))
 898       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 899         (save-excursion
 900           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 901           (if (eq (mail-content-type-get (mm-handle-type handle) 'charset)
 902                   'gnus-decoded)
 903               ;; A part that mm-uu dissected from a non-MIME message
 904               ;; because of `gnus-article-emulate-mime'.
 905               (progn
 906                 (mm-enable-multibyte)
 907                 (insert-buffer-substring (mm-handle-buffer handle)))
 908             (mm-insert-part handle 'no-cache)
 909             (if (setq mmlp (equal (mm-handle-media-type handle)
 910                                   "message/rfc822"))
 911                 (mime-to-mml))))))
 912     (if mmlp
 913         (mml-insert-mml-markup handle nil t t)
 914       (unless (and no-markup
 915                    (equal (mm-handle-media-type handle) "text/plain"))
 916         (mml-insert-mml-markup handle buffer textp)))
 917     (cond
 918      (mmlp
 919       (insert-buffer-substring buffer)
 920       (goto-char (point-max))
 921       (insert "<#/mml>\n"))
 922      ((stringp (car handle))
 923       (mapc 'mml-insert-mime (cdr handle))
 924       (insert "<#/multipart>\n"))
 925      (textp
 926       (let ((charset (mail-content-type-get
 927                       (mm-handle-type handle) 'charset))
 928             (start (point)))
 929         (if (eq charset 'gnus-decoded)
 930             (mm-insert-part handle)
 931           (insert (mm-decode-string (mm-get-part handle) charset)))
 932         (mml-quote-region start (point)))
 933       (goto-char (point-max)))
 934      (t
 935       (insert "<#/part>\n")))))
 936
 937 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 938   "Take a MIME handle and insert an MML tag."
 939   (if (stringp (car handle))
 940       (progn
 941         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 942         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 943           (when start
 944             (insert " start=\"" start "\"")))
 945         (insert ">\n"))
 946     (if mmlp
 947         (insert "<#mml type=" (mm-handle-media-type handle))
 948       (insert "<#part type=" (mm-handle-media-type handle)))
 949     (dolist (elem (append (cdr (mm-handle-type handle))
 950                           (cdr (mm-handle-disposition handle))))
 951       (unless (symbolp (cdr elem))
 952         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 953     (when (mm-handle-id handle)
 954       (insert " id=\"" (mm-handle-id handle) "\""))
 955     (when (mm-handle-disposition handle)
 956       (insert " disposition=" (car (mm-handle-disposition handle))))
 957     (when buffer
 958       (insert " buffer=\"" (buffer-name buffer) "\""))
 959     (when nofile
 960       (insert " nofile=yes"))
 961     (when (mm-handle-description handle)
 962       (insert " description=\"" (mm-handle-description handle) "\""))
 963     (insert ">\n")))
 964
 965 (defun mml-insert-parameter (&rest parameters)
 966   "Insert PARAMETERS in a nice way."
 967   (let (start end)
 968     (dolist (param parameters)
 969       (insert ";")
 970       (setq start (point))
 971       (insert " " param)
 972       (setq end (point))
 973       (goto-char start)
 974       (end-of-line)
 975       (if (> (current-column) 76)
 976           (progn
 977             (goto-char start)
 978             (insert "\n")
 979             (goto-char (1+ end)))
 980         (goto-char end)))))
 981
 982 ;;;
 983 ;;; Mode for inserting and editing MML forms
 984 ;;;
 985
 986 (defvar mml-mode-map
 987   (let ((sign (make-sparse-keymap))
 988         (encrypt (make-sparse-keymap))
 989         (signpart (make-sparse-keymap))
 990         (encryptpart (make-sparse-keymap))
 991         (map (make-sparse-keymap))
 992         (main (make-sparse-keymap)))
 993     (define-key map "\C-s" 'mml-secure-message-sign)
 994     (define-key map "\C-c" 'mml-secure-message-encrypt)
 995     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
 996     (define-key map "\C-p\C-s" 'mml-secure-sign)
 997     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
 998     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
 999     (define-key sign "o" 'mml-secure-message-sign-pgp)
1000     (define-key sign "s" 'mml-secure-message-sign-smime)
1001     (define-key signpart "p" 'mml-secure-sign-pgpmime)
1002     (define-key signpart "o" 'mml-secure-sign-pgp)
1003     (define-key signpart "s" 'mml-secure-sign-smime)
1004     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
1005     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
1006     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
1007     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
1008     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
1009     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
1010     (define-key map "\C-n" 'mml-unsecure-message)
1011     (define-key map "f" 'mml-attach-file)
1012     (define-key map "b" 'mml-attach-buffer)
1013     (define-key map "e" 'mml-attach-external)
1014     (define-key map "q" 'mml-quote-region)
1015     (define-key map "m" 'mml-insert-multipart)
1016     (define-key map "p" 'mml-insert-part)
1017     (define-key map "v" 'mml-validate)
1018     (define-key map "P" 'mml-preview)
1019     (define-key map "s" sign)
1020     (define-key map "S" signpart)
1021     (define-key map "c" encrypt)
1022     (define-key map "C" encryptpart)
1023     ;;(define-key map "n" 'mml-narrow-to-part)
1024     ;; `M-m' conflicts with `back-to-indentation'.
1025     ;; (define-key main "\M-m" map)
1026     (define-key main "\C-c\C-m" map)
1027     main))
1028
1029 (easy-menu-define
1030   mml-menu mml-mode-map ""
1031   `("Attachments"
1032     ["Attach File..." mml-attach-file
1033      ,@(if (featurep 'xemacs) '(t)
1034          '(:help "Attach a file at point"))]
1035     ["Attach Buffer..." mml-attach-buffer
1036      ,@(if (featurep 'xemacs) '(t)
1037          '(:help "Attach a buffer to the outgoing message"))]
1038     ["Attach External..." mml-attach-external
1039      ,@(if (featurep 'xemacs) '(t)
1040          '(:help "Attach reference to an external file"))]
1041     ;; FIXME: Is it possible to do this without using
1042     ;; `gnus-gcc-externalize-attachments'?
1043     ["Externalize Attachments"
1044      (lambda ()
1045        (interactive)
1046        (if (not (and (boundp 'gnus-gcc-externalize-attachments)
1047                      (memq gnus-gcc-externalize-attachments
1048                            '(all t nil))))
1049            ;; Stupid workaround for XEmacs not honoring :visible.
1050            (message "Can't handle this value of `gnus-gcc-externalize-attachments'")
1051          (setq gnus-gcc-externalize-attachments
1052                (not gnus-gcc-externalize-attachments))
1053          (message "gnus-gcc-externalize-attachments is `%s'."
1054                   gnus-gcc-externalize-attachments)))
1055      ;; XEmacs barfs on :visible.
1056      ,@(if (featurep 'xemacs) nil
1057          '(:visible (and (boundp 'gnus-gcc-externalize-attachments)
1058                          (memq gnus-gcc-externalize-attachments
1059                                '(all t nil)))))
1060      :style toggle
1061      :selected gnus-gcc-externalize-attachments
1062      ,@(if (featurep 'xemacs) nil
1063          '(:help "Save attachments as external parts in Gcc copies"))]
1064     "----"
1065     ;;
1066     ("Change Security Method"
1067      ["PGP/MIME"
1068       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
1069       ,@(if (featurep 'xemacs) nil
1070           '(:help "Set Security Method to PGP/MIME"))
1071       :style radio
1072       :selected (equal mml-secure-method "pgpmime") ]
1073      ["S/MIME"
1074       (lambda () (interactive) (setq mml-secure-method "smime"))
1075       ,@(if (featurep 'xemacs) nil
1076           '(:help "Set Security Method to S/MIME"))
1077       :style radio
1078       :selected (equal mml-secure-method "smime") ]
1079      ["Inline PGP"
1080       (lambda () (interactive) (setq mml-secure-method "pgp"))
1081       ,@(if (featurep 'xemacs) nil
1082           '(:help "Set Security Method to inline PGP"))
1083       :style radio
1084       :selected (equal mml-secure-method "pgp") ] )
1085     ;;
1086     ["Sign Message" mml-secure-message-sign t]
1087     ["Encrypt Message" mml-secure-message-encrypt t]
1088     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
1089     ["Encrypt/Sign off" mml-unsecure-message
1090      ,@(if (featurep 'xemacs) '(t)
1091          '(:help "Don't Encrypt/Sign Message"))]
1092     ;; Do we have separate encrypt and encrypt/sign commands for parts?
1093     ["Sign Part" mml-secure-sign t]
1094     ["Encrypt Part" mml-secure-encrypt t]
1095     "----"
1096     ;; Maybe we could remove these, because people who write MML most probably
1097     ;; don't use the menu:
1098     ["Insert Part..." mml-insert-part
1099      :active (message-in-body-p)]
1100     ["Insert Multipart..." mml-insert-multipart
1101      :active (message-in-body-p)]
1102     ;;
1103     ;;["Narrow" mml-narrow-to-part t]
1104     ["Quote MML in region" mml-quote-region
1105      :active (message-mark-active-p)
1106      ,@(if (featurep 'xemacs) nil
1107          '(:help "Quote MML tags in region"))]
1108     ["Validate MML" mml-validate t]
1109     ["Preview" mml-preview t]
1110     "----"
1111     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
1112      ,@(if (featurep 'xemacs) '(t)
1113          '(:help "Display the Emacs MIME manual"))]
1114     ["PGG manual" (lambda () (interactive) (message-info mml2015-use))
1115      ;; XEmacs barfs on :visible.
1116      ,@(if (featurep 'xemacs) nil
1117          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'pgg))))
1118      ,@(if (featurep 'xemacs) '(t)
1119          '(:help "Display the PGG manual"))]
1120     ["EasyPG manual" (lambda () (interactive) (require 'mml2015) (message-info mml2015-use))
1121      ;; XEmacs barfs on :visible.
1122      ,@(if (featurep 'xemacs) nil
1123          '(:visible (and (boundp 'mml2015-use) (equal mml2015-use 'epg))))
1124      ,@(if (featurep 'xemacs) '(t)
1125          '(:help "Display the EasyPG manual"))]))
1126
1127 (defvar mml-mode nil
1128   "Minor mode for editing MML.")
1129
1130 (defun mml-mode (&optional arg)
1131   "Minor mode for editing MML.
1132 MML is the MIME Meta Language, a minor mode for composing MIME articles.
1133 See Info node `(emacs-mime)Composing'.
1134
1135 \\{mml-mode-map}"
1136   (interactive "P")
1137   (when (set (make-local-variable 'mml-mode)
1138              (if (null arg) (not mml-mode)
1139                (> (prefix-numeric-value arg) 0)))
1140     (add-minor-mode 'mml-mode " MML" mml-mode-map)
1141     (easy-menu-add mml-menu mml-mode-map)
1142     (when (boundp 'dnd-protocol-alist)
1143       (set (make-local-variable 'dnd-protocol-alist)
1144            (append mml-dnd-protocol-alist dnd-protocol-alist)))
1145     (run-hooks 'mml-mode-hook)))
1146
1147 ;;;
1148 ;;; Helper functions for reading MIME stuff from the minibuffer and
1149 ;;; inserting stuff to the buffer.
1150 ;;;
1151
1152 (defcustom mml-default-directory mm-default-directory
1153   "The default directory where mml will find files.
1154 If not set, `default-directory' will be used."
1155   :type '(choice directory (const :tag "Default" nil))
1156   :version "23.1" ;; No Gnus
1157   :group 'message)
1158
1159 (defun mml-minibuffer-read-file (prompt)
1160   (let* ((completion-ignored-extensions nil)
1161          (file (read-file-name prompt
1162                                (or mml-default-directory default-directory)
1163                                nil t)))
1164     ;; Prevent some common errors.  This is inspired by similar code in
1165     ;; VM.
1166     (when (file-directory-p file)
1167       (error "%s is a directory, cannot attach" file))
1168     (unless (file-exists-p file)
1169       (error "No such file: %s" file))
1170     (unless (file-readable-p file)
1171       (error "Permission denied: %s" file))
1172     file))
1173
1174 (defun mml-minibuffer-read-type (name &optional default)
1175   (mailcap-parse-mimetypes)
1176   (let* ((default (or default
1177                       (mm-default-file-encoding name)
1178                       ;; Perhaps here we should check what the file
1179                       ;; looks like, and offer text/plain if it looks
1180                       ;; like text/plain.
1181                       "application/octet-stream"))
1182          (string (completing-read
1183                   (format "Content type (default %s): " default)
1184                   (mapcar 'list (mailcap-mime-types)))))
1185     (if (not (equal string ""))
1186         string
1187       default)))
1188
1189 (defun mml-minibuffer-read-description ()
1190   (let ((description (read-string "One line description: ")))
1191     (when (string-match "\\`[ \t]*\\'" description)
1192       (setq description nil))
1193     description))
1194
1195 (defun mml-minibuffer-read-disposition (type &optional default filename)
1196   (unless default
1197     (setq default (mml-content-disposition type filename)))
1198   (let ((disposition (completing-read
1199                       (format "Disposition (default %s): " default)
1200                       '(("attachment") ("inline") (""))
1201                       nil t nil nil default)))
1202     (if (not (equal disposition ""))
1203         disposition
1204       default)))
1205
1206 (defun mml-quote-region (beg end)
1207   "Quote the MML tags in the region."
1208   (interactive "r")
1209   (save-excursion
1210     (save-restriction
1211       ;; Temporarily narrow the region to defend from changes
1212       ;; invalidating END.
1213       (narrow-to-region beg end)
1214       (goto-char (point-min))
1215       ;; Quote parts.
1216       (while (re-search-forward
1217               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
1218         ;; Insert ! after the #.
1219         (goto-char (+ (match-beginning 0) 2))
1220         (insert "!")))))
1221
1222 (defun mml-insert-tag (name &rest plist)
1223   "Insert an MML tag described by NAME and PLIST."
1224   (when (symbolp name)
1225     (setq name (symbol-name name)))
1226   (insert "<#" name)
1227   (while plist
1228     (let ((key (pop plist))
1229           (value (pop plist)))
1230       (when value
1231         ;; Quote VALUE if it contains suspicious characters.
1232         (when (string-match "[\"'\\~/*;() \t\n]" value)
1233           (setq value (with-output-to-string
1234                         (let (print-escape-nonascii)
1235                           (prin1 value)))))
1236         (insert (format " %s=%s" key value)))))
1237   (insert ">\n"))
1238
1239 (defun mml-insert-empty-tag (name &rest plist)
1240   "Insert an empty MML tag described by NAME and PLIST."
1241   (when (symbolp name)
1242     (setq name (symbol-name name)))
1243   (apply #'mml-insert-tag name plist)
1244   (insert "<#/" name ">\n"))
1245
1246 ;;; Attachment functions.
1247
1248 (defcustom mml-dnd-protocol-alist
1249   '(("^file:///" . mml-dnd-attach-file)
1250     ("^file://"  . dnd-open-file)
1251     ("^file:"    . mml-dnd-attach-file))
1252   "The functions to call when a drop in `mml-mode' is made.
1253 See `dnd-protocol-alist' for more information.  When nil, behave
1254 as in other buffers."
1255   :type '(choice (repeat (cons (regexp) (function)))
1256                  (const :tag "Behave as in other buffers" nil))
1257   :version "22.1" ;; Gnus 5.10.9
1258   :group 'message)
1259
1260 (defcustom mml-dnd-attach-options nil
1261   "Which options should be queried when attaching a file via drag and drop.
1262
1263 If it is a list, valid members are `type', `description' and
1264 `disposition'.  `disposition' implies `type'.  If it is nil,
1265 don't ask for options.  If it is t, ask the user whether or not
1266 to specify options."
1267   :type '(choice
1268           (const :tag "None" nil)
1269           (const :tag "Query" t)
1270           (list :value (type description disposition)
1271            (set :inline t
1272                 (const type)
1273                 (const description)
1274                 (const disposition))))
1275   :version "22.1" ;; Gnus 5.10.9
1276   :group 'message)
1277
1278 (defun mml-attach-file (file &optional type description disposition)
1279   "Attach a file to the outgoing MIME message.
1280 The file is not inserted or encoded until you send the message with
1281 `\\[message-send-and-exit]' or `\\[message-send]'.
1282
1283 FILE is the name of the file to attach.  TYPE is its
1284 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1285 is a one-line description of the attachment.  The DISPOSITION
1286 specifies how the attachment is intended to be displayed.  It can
1287 be either \"inline\" (displayed automatically within the message
1288 body) or \"attachment\" (separate from the body)."
1289   (interactive
1290    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1291           (type (mml-minibuffer-read-type file))
1292           (description (mml-minibuffer-read-description))
1293           (disposition (mml-minibuffer-read-disposition type nil file)))
1294      (list file type description disposition)))
1295   (save-excursion
1296     (unless (message-in-body-p) (goto-char (point-max)))
1297     (mml-insert-empty-tag 'part
1298                           'type type
1299                           ;; icicles redefines read-file-name and returns a
1300                           ;; string w/ text properties :-/
1301                           'filename (mm-substring-no-properties file)
1302                           'disposition (or disposition "attachment")
1303                           'description description)))
1304
1305 (defun mml-dnd-attach-file (uri action)
1306   "Attach a drag and drop file.
1307
1308 Ask for type, description or disposition according to
1309 `mml-dnd-attach-options'."
1310   (let ((file (dnd-get-local-file-name uri t)))
1311     (when (and file (file-regular-p file))
1312       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1313             type description disposition)
1314         (setq mml-dnd-attach-options
1315               (when (and (eq mml-dnd-attach-options t)
1316                          (not
1317                           (y-or-n-p
1318                            "Use default type, disposition and description? ")))
1319                 '(type description disposition)))
1320         (when (or (memq 'type mml-dnd-attach-options)
1321                   (memq 'disposition mml-dnd-attach-options))
1322           (setq type (mml-minibuffer-read-type file)))
1323         (when (memq 'description mml-dnd-attach-options)
1324           (setq description (mml-minibuffer-read-description)))
1325         (when (memq 'disposition mml-dnd-attach-options)
1326           (setq disposition (mml-minibuffer-read-disposition type nil file)))
1327         (mml-attach-file file type description disposition)))))
1328
1329 (defun mml-attach-buffer (buffer &optional type description disposition)
1330   "Attach a buffer to the outgoing MIME message.
1331 BUFFER is the name of the buffer to attach.  See
1332 `mml-attach-file' for details of operation."
1333   (interactive
1334    (let* ((buffer (read-buffer "Attach buffer: "))
1335           (type (mml-minibuffer-read-type buffer "text/plain"))
1336           (description (mml-minibuffer-read-description))
1337           (disposition (mml-minibuffer-read-disposition type nil)))
1338      (list buffer type description disposition)))
1339   (save-excursion
1340     (unless (message-in-body-p) (goto-char (point-max)))
1341     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1342                           'disposition disposition
1343                           'description description)))
1344
1345 (defun mml-attach-external (file &optional type description)
1346   "Attach an external file into the buffer.
1347 FILE is an ange-ftp/efs specification of the part location.
1348 TYPE is the MIME type to use."
1349   (interactive
1350    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1351           (type (mml-minibuffer-read-type file))
1352           (description (mml-minibuffer-read-description)))
1353      (list file type description)))
1354   (save-excursion
1355     (unless (message-in-body-p) (goto-char (point-max)))
1356     (mml-insert-empty-tag 'external 'type type 'name file
1357                           'disposition "attachment" 'description description)))
1358
1359 (defun mml-insert-multipart (&optional type)
1360   (interactive (list (completing-read "Multipart type (default mixed): "
1361                                       '(("mixed") ("alternative") ("digest") ("parallel")
1362                                         ("signed") ("encrypted"))
1363                                       nil nil "mixed")))
1364   (or type
1365       (setq type "mixed"))
1366   (mml-insert-empty-tag "multipart" 'type type)
1367   (forward-line -1))
1368
1369 (defun mml-insert-part (&optional type)
1370   (interactive
1371    (list (mml-minibuffer-read-type "")))
1372   (mml-insert-tag 'part 'type type 'disposition "inline")
1373   (forward-line -1))
1374
1375 (declare-function message-subscribed-p "message" ())
1376 (declare-function message-make-mail-followup-to "message"
1377                   (&optional only-show-subscribed))
1378 (declare-function message-position-on-field "message" (header &rest afters))
1379
1380 (defun mml-preview-insert-mail-followup-to ()
1381   "Insert a Mail-Followup-To header before previewing an article.
1382 Should be adopted if code in `message-send-mail' is changed."
1383   (when (and (message-mail-p)
1384              (message-subscribed-p)
1385              (not (mail-fetch-field "mail-followup-to"))
1386              (message-make-mail-followup-to))
1387     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1388     (insert (message-make-mail-followup-to))))
1389
1390 (defvar mml-preview-buffer nil)
1391
1392 (autoload 'gnus-make-hashtable "gnus-util")
1393 (autoload 'widget-button-press "wid-edit" nil t)
1394 (declare-function widget-event-point "wid-edit" (event))
1395 ;; If gnus-buffer-configuration is bound this is loaded.
1396 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
1397 ;; Called after message-mail-p, which autoloads message.
1398 (declare-function message-news-p                "message" ())
1399 (declare-function message-options-set-recipient "message" ())
1400 (declare-function message-generate-headers      "message" (headers))
1401 (declare-function message-sort-headers          "message" ())
1402
1403 (defun mml-preview (&optional raw)
1404   "Display current buffer with Gnus, in a new buffer.
1405 If RAW, display a raw encoded MIME message.
1406
1407 The window layout for the preview buffer is controled by the variables
1408 `special-display-buffer-names', `special-display-regexps', or
1409 `gnus-buffer-configuration' (the first match made will be used),
1410 or the `pop-to-buffer' function."
1411   (interactive "P")
1412   (setq mml-preview-buffer (generate-new-buffer
1413                             (concat (if raw "*Raw MIME preview of "
1414                                       "*MIME preview of ") (buffer-name))))
1415   (save-excursion
1416     (let* ((buf (current-buffer))
1417            (message-options message-options)
1418            (message-this-is-mail (message-mail-p))
1419            (message-this-is-news (message-news-p))
1420            (message-posting-charset (or (gnus-setup-posting-charset
1421                                          (save-restriction
1422                                            (message-narrow-to-headers-or-head)
1423                                            (message-fetch-field "Newsgroups")))
1424                                         message-posting-charset)))
1425       (message-options-set-recipient)
1426       (when (boundp 'gnus-buffers)
1427         (push mml-preview-buffer gnus-buffers))
1428       (save-restriction
1429         (widen)
1430         (set-buffer mml-preview-buffer)
1431         (erase-buffer)
1432         (insert-buffer-substring buf))
1433       (mml-preview-insert-mail-followup-to)
1434       (let ((message-deletable-headers (if (message-news-p)
1435                                            nil
1436                                          message-deletable-headers)))
1437         (message-generate-headers
1438          (copy-sequence (if (message-news-p)
1439                             message-required-news-headers
1440                           message-required-mail-headers))))
1441       (if (re-search-forward
1442            (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1443           (replace-match "\n"))
1444       (let ((mail-header-separator ""));; mail-header-separator is removed.
1445         (message-sort-headers)
1446         (mml-to-mime))
1447       (if raw
1448           (when (fboundp 'set-buffer-multibyte)
1449             (let ((s (buffer-string)))
1450               ;; Insert the content into unibyte buffer.
1451               (erase-buffer)
1452               (mm-disable-multibyte)
1453               (insert s)))
1454         (let ((gnus-newsgroup-charset (car message-posting-charset))
1455               gnus-article-prepare-hook gnus-original-article-buffer)
1456           (run-hooks 'gnus-article-decode-hook)
1457           (let ((gnus-newsgroup-name "dummy")
1458                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1459                                         (gnus-make-hashtable 5))))
1460             (gnus-article-prepare-display))))
1461       ;; Disable article-mode-map.
1462       (use-local-map nil)
1463       (gnus-make-local-hook 'kill-buffer-hook)
1464       (add-hook 'kill-buffer-hook
1465                 (lambda ()
1466                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1467       (setq buffer-read-only t)
1468       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1469       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1470       (local-set-key "\r"
1471                      (lambda ()
1472                        (interactive)
1473                        (widget-button-press (point))))
1474       (local-set-key gnus-mouse-2
1475                      (lambda (event)
1476                        (interactive "@e")
1477                        (widget-button-press (widget-event-point event) event)))
1478       ;; FIXME: Buffer is in article mode, but most tool bar commands won't
1479       ;; work.  Maybe only keep the following icons: search, print, quit
1480       (goto-char (point-min))))
1481   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1482            (boundp 'gnus-buffer-configuration)
1483            (assq 'mml-preview gnus-buffer-configuration))
1484       (let ((gnus-message-buffer (current-buffer)))
1485         (gnus-configure-windows 'mml-preview))
1486     (pop-to-buffer mml-preview-buffer)))
1487
1488 (defun mml-validate ()
1489   "Validate the current MML document."
1490   (interactive)
1491   (mml-parse))
1492
1493 (defun mml-tweak-part (cont)
1494   "Tweak a MML part."
1495   (let ((tweak (cdr (assq 'tweak cont)))
1496         func)
1497     (cond
1498      (tweak
1499       (setq func
1500             (or (cdr (assoc tweak mml-tweak-function-alist))
1501                 (intern tweak))))
1502      (mml-tweak-type-alist
1503       (let ((alist mml-tweak-type-alist)
1504             (type (or (cdr (assq 'type cont)) "text/plain")))
1505         (while alist
1506           (if (string-match (caar alist) type)
1507               (setq func (cdar alist)
1508                     alist nil)
1509             (setq alist (cdr alist)))))))
1510     (if func
1511         (funcall func cont)
1512       cont)
1513     (let ((alist mml-tweak-sexp-alist))
1514       (while alist
1515         (if (eval (caar alist))
1516             (funcall (cdar alist) cont))
1517         (setq alist (cdr alist)))))
1518   cont)
1519
1520 (defun mml-tweak-externalize-attachments (cont)
1521   "Tweak attached files as external parts."
1522   (let (filename-cons)
1523     (when (and (eq (car cont) 'part)
1524                (not (cdr (assq 'buffer cont)))
1525                (and (setq filename-cons (assq 'filename cont))
1526                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1527       (setcar cont 'external)
1528       (setcar filename-cons 'name))))
1529
1530 (provide 'mml)
1531
1532 ;; arch-tag: 583c96cf-1ffe-451b-a5e5-4733ae9ddd12
1533 ;;; mml.el ends here