cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; For Emacs < 22.2.
  28 (eval-and-compile
  29   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'mail-prsvr)
  33
  34 (eval-and-compile
  35   (if (featurep 'xemacs)
  36       (unless (ignore-errors
  37                 (require 'timer-funcs))
  38         (require 'timer))
  39     (require 'timer)))
  40
  41 (defvar mm-mime-mule-charset-alist )
  42
  43 ;; Emulate functions that are not available in every (X)Emacs version.
  44 ;; The name of a function is prefixed with mm-, like `mm-char-int' for
  45 ;; `char-int' that is a native XEmacs function, not available in Emacs.
  46 ;; Gnus programs all should use mm- functions, not the original ones.
  47 (eval-and-compile
  48   (mapc
  49    (lambda (elem)
  50      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  51        (if (fboundp (car elem))
  52            (defalias nfunc (car elem))
  53          (defalias nfunc (cdr elem)))))
  54    `(;; `coding-system-list' is not available in XEmacs 21.4 built
  55      ;; without the `file-coding' feature.
  56      (coding-system-list . ignore)
  57      ;; `char-int' is an XEmacs function, not available in Emacs.
  58      (char-int . identity)
  59      ;; `coding-system-equal' is an Emacs function, not available in XEmacs.
  60      (coding-system-equal . equal)
  61      ;; `annotationp' is an XEmacs function, not available in Emacs.
  62      (annotationp . ignore)
  63      ;; `set-buffer-file-coding-system' is not available in XEmacs 21.4
  64      ;; built without the `file-coding' feature.
  65      (set-buffer-file-coding-system . ignore)
  66      ;; `read-charset' is an Emacs function, not available in XEmacs.
  67      (read-charset
  68       . ,(lambda (prompt)
  69            "Return a charset."
  70            (intern
  71             (completing-read
  72              prompt
  73              (mapcar (lambda (e) (list (symbol-name (car e))))
  74                      mm-mime-mule-charset-alist)
  75              nil t))))
  76      ;; `subst-char-in-string' is not available in XEmacs 21.4.
  77      (subst-char-in-string
  78       . ,(lambda (from to string &optional inplace)
  79            ;; stolen (and renamed) from nnheader.el
  80            "Replace characters in STRING from FROM to TO.
  81           Unless optional argument INPLACE is non-nil, return a new string."
  82            (let ((string (if inplace string (copy-sequence string)))
  83                  (len (length string))
  84                  (idx 0))
  85              ;; Replace all occurrences of FROM with TO.
  86              (while (< idx len)
  87                (when (= (aref string idx) from)
  88                  (aset string idx to))
  89                (setq idx (1+ idx)))
  90              string)))
  91      ;; `replace-in-string' is an XEmacs function, not available in Emacs.
  92      (replace-in-string
  93       . ,(lambda (string regexp rep &optional literal)
  94            "See `replace-regexp-in-string', only the order of args differs."
  95            (replace-regexp-in-string regexp rep string nil literal)))
  96      ;; `string-as-unibyte' is an Emacs function, not available in XEmacs.
  97      (string-as-unibyte . identity)
  98      ;; `string-make-unibyte' is an Emacs function, not available in XEmacs.
  99      (string-make-unibyte . identity)
 100      ;; string-as-multibyte often doesn't really do what you think it does.
 101      ;; Example:
 102      ;;    (aref (string-as-multibyte "\201") 0) -> 129 (aka ?\201)
 103      ;;    (aref (string-as-multibyte "\300") 0) -> 192 (aka ?\300)
 104      ;;    (aref (string-as-multibyte "\300\201") 0) -> 192 (aka ?\300)
 105      ;;    (aref (string-as-multibyte "\300\201") 1) -> 129 (aka ?\201)
 106      ;; but
 107      ;;    (aref (string-as-multibyte "\201\300") 0) -> 2240
 108      ;;    (aref (string-as-multibyte "\201\300") 1) -> <error>
 109      ;; Better use string-to-multibyte or encode-coding-string.
 110      ;; If you really need string-as-multibyte somewhere it's usually
 111      ;; because you're using the internal emacs-mule representation (maybe
 112      ;; because you're using string-as-unibyte somewhere), which is
 113      ;; generally a problem in itself.
 114      ;; Here is an approximate equivalence table to help think about it:
 115      ;; (string-as-multibyte s)   ~= (decode-coding-string s 'emacs-mule)
 116      ;; (string-to-multibyte s)   ~= (decode-coding-string s 'binary)
 117      ;; (string-make-multibyte s) ~= (decode-coding-string s locale-coding-system)
 118      ;; `string-as-multibyte' is an Emacs function, not available in XEmacs.
 119      (string-as-multibyte . identity)
 120      ;; `multibyte-string-p' is an Emacs function, not available in XEmacs.
 121      (multibyte-string-p . ignore)
 122      ;; `insert-byte' is available only in Emacs 23.1 or greater.
 123      (insert-byte . insert-char)
 124      ;; `multibyte-char-to-unibyte' is an Emacs function, not available
 125      ;; in XEmacs.
 126      (multibyte-char-to-unibyte . identity)
 127      ;; `set-buffer-multibyte' is an Emacs function, not available in XEmacs.
 128      (set-buffer-multibyte . ignore)
 129      ;; `special-display-p' is an Emacs function, not available in XEmacs.
 130      (special-display-p
 131       . ,(lambda (buffer-name)
 132            "Returns non-nil if a buffer named BUFFER-NAME gets a special frame."
 133            (and special-display-function
 134                 (or (and (member buffer-name special-display-buffer-names) t)
 135                     (cdr (assoc buffer-name special-display-buffer-names))
 136                     (catch 'return
 137                       (dolist (elem special-display-regexps)
 138                         (and (stringp elem)
 139                              (string-match elem buffer-name)
 140                              (throw 'return t))
 141                         (and (consp elem)
 142                              (stringp (car elem))
 143                              (string-match (car elem) buffer-name)
 144                              (throw 'return (cdr elem)))))))))
 145      ;; `substring-no-properties' is available only in Emacs 22.1 or greater.
 146      (substring-no-properties
 147       . ,(lambda (string &optional from to)
 148            "Return a substring of STRING, without text properties.
 149 It starts at index FROM and ending before TO.
 150 TO may be nil or omitted; then the substring runs to the end of STRING.
 151 If FROM is nil or omitted, the substring starts at the beginning of STRING.
 152 If FROM or TO is negative, it counts from the end.
 153
 154 With one argument, just copy STRING without its properties."
 155            (setq string (substring string (or from 0) to))
 156            (set-text-properties 0 (length string) nil string)
 157            string))
 158      ;; `line-number-at-pos' is available only in Emacs 22.1 or greater
 159      ;; and XEmacs 21.5.
 160      (line-number-at-pos
 161       . ,(lambda (&optional pos)
 162            "Return (narrowed) buffer line number at position POS.
 163 If POS is nil, use current buffer location.
 164 Counting starts at (point-min), so the value refers
 165 to the contents of the accessible portion of the buffer."
 166            (let ((opoint (or pos (point))) start)
 167              (save-excursion
 168                (goto-char (point-min))
 169                (setq start (point))
 170                (goto-char opoint)
 171                (forward-line 0)
 172                (1+ (count-lines start (point))))))))))
 173
 174 ;; `decode-coding-string', `encode-coding-string', `decode-coding-region'
 175 ;; and `encode-coding-region' are available in Emacs and XEmacs built with
 176 ;; the `file-coding' feature, but the XEmacs versions treat nil, that is
 177 ;; given as the `coding-system' argument, as the `binary' coding system.
 178 (eval-and-compile
 179   (if (featurep 'xemacs)
 180       (if (featurep 'file-coding)
 181           (progn
 182             (defun mm-decode-coding-string (str coding-system)
 183               (if coding-system
 184                   (decode-coding-string str coding-system)
 185                 str))
 186             (defun mm-encode-coding-string (str coding-system)
 187               (if coding-system
 188                   (encode-coding-string str coding-system)
 189                 str))
 190             (defun mm-decode-coding-region (start end coding-system)
 191               (if coding-system
 192                   (decode-coding-region start end coding-system)))
 193             (defun mm-encode-coding-region (start end coding-system)
 194               (if coding-system
 195                   (encode-coding-region start end coding-system))))
 196         (defun mm-decode-coding-string (str coding-system) str)
 197         (defun mm-encode-coding-string (str coding-system) str)
 198         (defalias 'mm-decode-coding-region 'ignore)
 199         (defalias 'mm-encode-coding-region 'ignore))
 200     (defalias 'mm-decode-coding-string 'decode-coding-string)
 201     (defalias 'mm-encode-coding-string 'encode-coding-string)
 202     (defalias 'mm-decode-coding-region 'decode-coding-region)
 203     (defalias 'mm-encode-coding-region 'encode-coding-region)))
 204
 205 ;; `string-to-multibyte' is available only in Emacs 22.1 or greater.
 206 (defalias 'mm-string-to-multibyte
 207   (cond
 208    ((featurep 'xemacs)
 209     'identity)
 210    ((fboundp 'string-to-multibyte)
 211     'string-to-multibyte)
 212    (t
 213     (lambda (string)
 214       "Return a multibyte string with the same individual chars as STRING."
 215       (mapconcat
 216        (lambda (ch) (mm-string-as-multibyte (char-to-string ch)))
 217        string "")))))
 218
 219 ;; `char-or-char-int-p' is an XEmacs function, not available in Emacs.
 220 (eval-and-compile
 221   (defalias 'mm-char-or-char-int-p
 222     (cond
 223      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
 224      ((fboundp 'char-valid-p) 'char-valid-p)
 225      (t 'identity))))
 226
 227 ;; `ucs-to-char' is a function that Mule-UCS provides.
 228 (if (featurep 'xemacs)
 229     (cond ((and (fboundp 'unicode-to-char) ;; XEmacs 21.5.
 230                 (subrp (symbol-function 'unicode-to-char)))
 231            (if (featurep 'mule)
 232                (defalias 'mm-ucs-to-char 'unicode-to-char)
 233              (defun mm-ucs-to-char (codepoint)
 234                "Convert Unicode codepoint to character."
 235                (or (unicode-to-char codepoint) ?#))))
 236           ((featurep 'mule)
 237            (defun mm-ucs-to-char (codepoint)
 238              "Convert Unicode codepoint to character."
 239              (if (fboundp 'ucs-to-char) ;; Mule-UCS is loaded.
 240                  (progn
 241                    (defalias 'mm-ucs-to-char
 242                      (lambda (codepoint)
 243                        "Convert Unicode codepoint to character."
 244                        (condition-case nil
 245                            (or (ucs-to-char codepoint) ?#)
 246                          (error ?#))))
 247                    (mm-ucs-to-char codepoint))
 248                (condition-case nil
 249                    (or (int-to-char codepoint) ?#)
 250                  (error ?#)))))
 251           (t
 252            (defun mm-ucs-to-char (codepoint)
 253              "Convert Unicode codepoint to character."
 254              (condition-case nil
 255                  (or (int-to-char codepoint) ?#)
 256                (error ?#)))))
 257   (if (let ((char (make-char 'japanese-jisx0208 36 34)))
 258         (eq char (decode-char 'ucs char)))
 259       ;; Emacs 23.
 260       (defalias 'mm-ucs-to-char 'identity)
 261     (defun mm-ucs-to-char (codepoint)
 262       "Convert Unicode codepoint to character."
 263       (or (decode-char 'ucs codepoint) ?#))))
 264
 265 ;; Fixme:  This seems always to be used to read a MIME charset, so it
 266 ;; should be re-named and fixed (in Emacs) to offer completion only on
 267 ;; proper charset names (base coding systems which have a
 268 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 269 ;; test with
 270 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 271 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 272 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 273 (eval-and-compile
 274   (defalias 'mm-read-coding-system
 275     (cond
 276      ((fboundp 'read-coding-system)
 277       (if (and (featurep 'xemacs)
 278                (<= (string-to-number emacs-version) 21.1))
 279           (lambda (prompt &optional default-coding-system)
 280             (read-coding-system prompt))
 281         'read-coding-system))
 282      (t (lambda (prompt &optional default-coding-system)
 283           "Prompt the user for a coding system."
 284           (completing-read
 285            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 286                           mm-mime-mule-charset-alist)))))))
 287
 288 (defvar mm-coding-system-list nil)
 289 (defun mm-get-coding-system-list ()
 290   "Get the coding system list."
 291   (or mm-coding-system-list
 292       (setq mm-coding-system-list (mm-coding-system-list))))
 293
 294 (defun mm-coding-system-p (cs)
 295   "Return non-nil if CS is a symbol naming a coding system.
 296 In XEmacs, also return non-nil if CS is a coding system object.
 297 If CS is available, return CS itself in Emacs, and return a coding
 298 system object in XEmacs."
 299   (if (fboundp 'find-coding-system)
 300       (and cs (find-coding-system cs))
 301     (if (fboundp 'coding-system-p)
 302         (when (coding-system-p cs)
 303           cs)
 304       ;; no-MULE XEmacs:
 305       (car (memq cs (mm-get-coding-system-list))))))
 306
 307 (defun mm-codepage-setup (number &optional alias)
 308   "Create a coding system cpNUMBER.
 309 The coding system is created using `codepage-setup'.  If ALIAS is
 310 non-nil, an alias is created and added to
 311 `mm-charset-synonym-alist'.  If ALIAS is a string, it's used as
 312 the alias.  Else windows-NUMBER is used."
 313   (interactive
 314    (let ((completion-ignore-case t)
 315          (candidates (if (fboundp 'cp-supported-codepages)
 316                          (cp-supported-codepages)
 317                        ;; Removed in Emacs 23 (unicode), so signal an error:
 318                        (error "`codepage-setup' not present in this Emacs version."))))
 319      (list (completing-read "Setup DOS Codepage: (default 437) " candidates
 320                             nil t nil nil "437"))))
 321   (when alias
 322     (setq alias (if (stringp alias)
 323                     (intern alias)
 324                   (intern (format "windows-%s" number)))))
 325   (let* ((cp (intern (format "cp%s" number))))
 326     (unless (mm-coding-system-p cp)
 327       (if (fboundp 'codepage-setup)     ; silence compiler
 328           (codepage-setup number)
 329         (error "`codepage-setup' not present in this Emacs version.")))
 330     (when (and alias
 331                ;; Don't add alias if setup of cp failed.
 332                (mm-coding-system-p cp))
 333       (add-to-list 'mm-charset-synonym-alist (cons alias cp)))))
 334
 335 (defvar mm-charset-synonym-alist
 336   `(
 337     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 338     ,@(unless (mm-coding-system-p 'x-ctext)
 339         '((x-ctext . ctext)))
 340     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_ in 8
 341     ;; positions!
 342     ,@(unless (mm-coding-system-p 'iso-8859-15)
 343         '((iso-8859-15 . iso-8859-1)))
 344     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 345     ,@(unless (mm-coding-system-p 'big5-hkscs)
 346         '((big5-hkscs . big5)))
 347     ;; A Microsoft misunderstanding.
 348     ,@(when (and (not (mm-coding-system-p 'unicode))
 349                  (mm-coding-system-p 'utf-16-le))
 350         '((unicode . utf-16-le)))
 351     ;; A Microsoft misunderstanding.
 352     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 353         (if (mm-coding-system-p 'cp949)
 354             '((ks_c_5601-1987 . cp949))
 355           '((ks_c_5601-1987 . euc-kr))))
 356     ;; Windows-31J is Windows Codepage 932.
 357     ,@(when (and (not (mm-coding-system-p 'windows-31j))
 358                  (mm-coding-system-p 'cp932))
 359         '((windows-31j . cp932)))
 360     ;; Charset name: GBK, Charset aliases: CP936, MS936, windows-936
 361     ;; http://www.iana.org/assignments/charset-reg/GBK
 362     ;; Emacs 22.1 has cp936, but not gbk, so we alias it:
 363     ,@(when (and (not (mm-coding-system-p 'gbk))
 364                  (mm-coding-system-p 'cp936))
 365         '((gbk . cp936)))
 366     ;; UTF8 is a bogus name for UTF-8
 367     ,@(when (and (not (mm-coding-system-p 'utf8))
 368                  (mm-coding-system-p 'utf-8))
 369         '((utf8 . utf-8)))
 370     ;; ISO8859-1 is a bogus name for ISO-8859-1
 371     ,@(when (and (not (mm-coding-system-p 'iso8859-1))
 372                  (mm-coding-system-p 'iso-8859-1))
 373         '((iso8859-1 . iso-8859-1)))
 374     ;; ISO_8859-1 is a bogus name for ISO-8859-1
 375     ,@(when (and (not (mm-coding-system-p 'iso_8859-1))
 376                  (mm-coding-system-p 'iso-8859-1))
 377         '((iso_8859-1 . iso-8859-1)))
 378     )
 379   "A mapping from unknown or invalid charset names to the real charset names.
 380
 381 See `mm-codepage-iso-8859-list' and `mm-codepage-ibm-list'.")
 382
 383 (defcustom mm-codepage-iso-8859-list
 384   (list 1250 ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 385         ;; Outlook users in Czech republic.  Use this to allow reading of
 386         ;; their e-mails.  cp1250 should be defined by M-x codepage-setup
 387         ;; (Emacs 21).
 388         '(1252 . 1) ;; Windows-1252 is a superset of iso-8859-1 (West
 389                     ;; Europe).  See also `gnus-article-dumbquotes-map'.
 390         '(1254 . 9) ;; Windows-1254 is a superset of iso-8859-9 (Turkish).
 391         '(1255 . 8));; Windows-1255 is a superset of iso-8859-8 (Hebrew).
 392   "A list of Windows codepage numbers and iso-8859 charset numbers.
 393
 394 If an element is a number corresponding to a supported windows
 395 codepage, appropriate entries to `mm-charset-synonym-alist' are
 396 added by `mm-setup-codepage-iso-8859'.  An element may also be a
 397 cons cell where the car is a codepage number and the cdr is the
 398 corresponding number of an iso-8859 charset."
 399   :type '(list (set :inline t
 400                     (const 1250 :tag "Central and East European")
 401                     (const (1252 . 1) :tag "West European")
 402                     (const (1254 . 9) :tag "Turkish")
 403                     (const (1255 . 8) :tag "Hebrew"))
 404                (repeat :inline t
 405                        :tag "Other options"
 406                        (choice
 407                         (integer :tag "Windows codepage number")
 408                         (cons (integer :tag "Windows codepage number")
 409                               (integer :tag "iso-8859 charset  number")))))
 410   :version "22.1" ;; Gnus 5.10.9
 411   :group 'mime)
 412
 413 (defcustom mm-codepage-ibm-list
 414   (list 437 ;; (US etc.)
 415         860 ;; (Portugal)
 416         861 ;; (Iceland)
 417         862 ;; (Israel)
 418         863 ;; (Canadian French)
 419         865 ;; (Nordic)
 420         852 ;;
 421         850 ;; (Latin 1)
 422         855 ;; (Cyrillic)
 423         866 ;; (Cyrillic - Russian)
 424         857 ;; (Turkish)
 425         864 ;; (Arabic)
 426         869 ;; (Greek)
 427         874);; (Thai)
 428   ;; In Emacs 23 (unicode), cp... and ibm... are aliases.
 429   ;; Cf. http://thread.gmane.org/v9lkng5nwy.fsf@marauder.physik.uni-ulm.de
 430   "List of IBM codepage numbers.
 431
 432 The codepage mappings slighly differ between IBM and other vendors.
 433 See \"ftp://ftp.unicode.org/Public/MAPPINGS/VENDORS/IBM/README.TXT\".
 434
 435 If an element is a number corresponding to a supported windows
 436 codepage, appropriate entries to `mm-charset-synonym-alist' are
 437 added by `mm-setup-codepage-ibm'."
 438   :type '(list (set :inline t
 439                     (const 437 :tag "US etc.")
 440                     (const 860 :tag "Portugal")
 441                     (const 861 :tag "Iceland")
 442                     (const 862 :tag "Israel")
 443                     (const 863 :tag "Canadian French")
 444                     (const 865 :tag "Nordic")
 445                     (const 852)
 446                     (const 850 :tag "Latin 1")
 447                     (const 855 :tag "Cyrillic")
 448                     (const 866 :tag "Cyrillic - Russian")
 449                     (const 857 :tag "Turkish")
 450                     (const 864 :tag "Arabic")
 451                     (const 869 :tag "Greek")
 452                     (const 874 :tag "Thai"))
 453                (repeat :inline t
 454                        :tag "Other options"
 455                        (integer :tag "Codepage number")))
 456   :version "22.1" ;; Gnus 5.10.9
 457   :group 'mime)
 458
 459 (defun mm-setup-codepage-iso-8859 (&optional list)
 460   "Add appropriate entries to `mm-charset-synonym-alist'.
 461 Unless LIST is given, `mm-codepage-iso-8859-list' is used."
 462   (unless list
 463     (setq list mm-codepage-iso-8859-list))
 464   (dolist (i list)
 465     (let (cp windows iso)
 466       (if (consp i)
 467           (setq cp (intern (format "cp%d" (car i)))
 468                 windows (intern (format "windows-%d" (car i)))
 469                 iso (intern (format "iso-8859-%d" (cdr i))))
 470         (setq cp (intern (format "cp%d" i))
 471               windows (intern (format "windows-%d" i))))
 472       (unless (mm-coding-system-p windows)
 473         (if (mm-coding-system-p cp)
 474             (add-to-list 'mm-charset-synonym-alist (cons windows cp))
 475           (add-to-list 'mm-charset-synonym-alist (cons windows iso)))))))
 476
 477 (defun mm-setup-codepage-ibm (&optional list)
 478   "Add appropriate entries to `mm-charset-synonym-alist'.
 479 Unless LIST is given, `mm-codepage-ibm-list' is used."
 480   (unless list
 481     (setq list mm-codepage-ibm-list))
 482   (dolist (number list)
 483     (let ((ibm (intern (format "ibm%d" number)))
 484           (cp  (intern (format "cp%d" number))))
 485       (when (and (not (mm-coding-system-p ibm))
 486                  (mm-coding-system-p cp))
 487         (add-to-list 'mm-charset-synonym-alist (cons ibm cp))))))
 488
 489 ;; Initialize:
 490 (mm-setup-codepage-iso-8859)
 491 (mm-setup-codepage-ibm)
 492
 493 ;; Note: this has to be defined before `mm-charset-to-coding-system'.
 494 (defcustom mm-charset-eval-alist
 495   (if (featurep 'xemacs)
 496       nil ;; I don't know what would be useful for XEmacs.
 497     '(;; Emacs 21 offers 1250 1251 1253 1257.  Emacs 22 provides autoloads for
 498       ;; 1250-1258 (i.e. `mm-codepage-setup' does nothing).
 499       (windows-1250 . (mm-codepage-setup 1250 t))
 500       (windows-1251 . (mm-codepage-setup 1251 t))
 501       (windows-1253 . (mm-codepage-setup 1253 t))
 502       (windows-1257 . (mm-codepage-setup 1257 t))))
 503   "An alist of (CHARSET . FORM) pairs.
 504 If an article is encoded in an unknown CHARSET, FORM is
 505 evaluated.  This allows to load additional libraries providing
 506 charsets on demand.  If supported by your Emacs version, you
 507 could use `autoload-coding-system' here."
 508   :version "22.1" ;; Gnus 5.10.9
 509   :type '(list (set :inline t
 510                     (const (windows-1250 . (mm-codepage-setup 1250 t)))
 511                     (const (windows-1251 . (mm-codepage-setup 1251 t)))
 512                     (const (windows-1253 . (mm-codepage-setup 1253 t)))
 513                     (const (windows-1257 . (mm-codepage-setup 1257 t)))
 514                     (const (cp850 . (mm-codepage-setup 850 nil))))
 515                (repeat :inline t
 516                        :tag "Other options"
 517                        (cons (symbol :tag "charset")
 518                              (symbol :tag "form"))))
 519   :group 'mime)
 520 (put 'mm-charset-eval-alist 'risky-local-variable t)
 521
 522 (defvar mm-charset-override-alist)
 523
 524 ;; Note: this function has to be defined before `mm-charset-override-alist'
 525 ;; since it will use this function in order to determine its default value
 526 ;; when loading mm-util.elc.
 527 (defun mm-charset-to-coding-system (charset &optional lbt
 528                                             allow-override silent)
 529   "Return coding-system corresponding to CHARSET.
 530 CHARSET is a symbol naming a MIME charset.
 531 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 532 used as the line break code type of the coding system.
 533
 534 If ALLOW-OVERRIDE is given, use `mm-charset-override-alist' to
 535 map undesired charset names to their replacement.  This should
 536 only be used for decoding, not for encoding.
 537
 538 A non-nil value of SILENT means don't issue a warning even if CHARSET
 539 is not available."
 540   ;; OVERRIDE is used (only) in `mm-decode-body' and `mm-decode-string'.
 541   (when (stringp charset)
 542     (setq charset (intern (downcase charset))))
 543   (when lbt
 544     (setq charset (intern (format "%s-%s" charset lbt))))
 545   (cond
 546    ((null charset)
 547     charset)
 548    ;; Running in a non-MULE environment.
 549    ((or (null (mm-get-coding-system-list))
 550         (not (fboundp 'coding-system-get)))
 551     charset)
 552    ;; Check override list quite early.  Should only used for decoding, not for
 553    ;; encoding!
 554    ((and allow-override
 555          (let ((cs (cdr (assq charset mm-charset-override-alist))))
 556            (and cs (mm-coding-system-p cs) cs))))
 557    ;; ascii
 558    ((eq charset 'us-ascii)
 559     'ascii)
 560    ;; Check to see whether we can handle this charset.  (This depends
 561    ;; on there being some coding system matching each `mime-charset'
 562    ;; property defined, as there should be.)
 563    ((and (mm-coding-system-p charset)
 564 ;;; Doing this would potentially weed out incorrect charsets.
 565 ;;;      charset
 566 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 567          )
 568     charset)
 569    ;; Eval expressions from `mm-charset-eval-alist'
 570    ((let* ((el (assq charset mm-charset-eval-alist))
 571            (cs (car el))
 572            (form (cdr el)))
 573       (and cs
 574            form
 575            (prog2
 576                ;; Avoid errors...
 577                (condition-case nil (eval form) (error nil))
 578                ;; (message "Failed to eval `%s'" form))
 579                (mm-coding-system-p cs)
 580              (message "Added charset `%s' via `mm-charset-eval-alist'" cs))
 581            cs)))
 582    ;; Translate invalid charsets.
 583    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 584       (and cs
 585            (mm-coding-system-p cs)
 586            ;; (message
 587            ;;  "Using synonym `%s' from `mm-charset-synonym-alist' for `%s'"
 588            ;;  cs charset)
 589            cs)))
 590    ;; Last resort: search the coding system list for entries which
 591    ;; have the right mime-charset in case the canonical name isn't
 592    ;; defined (though it should be).
 593    ((let (cs)
 594       ;; mm-get-coding-system-list returns a list of cs without lbt.
 595       ;; Do we need -lbt?
 596       (dolist (c (mm-get-coding-system-list))
 597         (if (and (null cs)
 598                  (eq charset (or (coding-system-get c :mime-charset)
 599                                  (coding-system-get c 'mime-charset))))
 600             (setq cs c)))
 601       (unless (or silent cs)
 602         ;; Warn the user about unknown charset:
 603         (if (fboundp 'gnus-message)
 604             (gnus-message 7 "Unknown charset: %s" charset)
 605           (message "Unknown charset: %s" charset)))
 606       cs))))
 607
 608 ;; Note: `mm-charset-to-coding-system' has to be defined before this.
 609 (defcustom mm-charset-override-alist
 610   ;; Note: pairs that cannot be used in the Emacs version currently running
 611   ;; will be removed.
 612   '((gb2312 . gbk)
 613     (iso-8859-1 . windows-1252)
 614     (iso-8859-8 . windows-1255)
 615     (iso-8859-9 . windows-1254))
 616   "A mapping from undesired charset names to their replacement.
 617
 618 You may add pairs like (iso-8859-1 . windows-1252) here,
 619 i.e. treat iso-8859-1 as windows-1252.  windows-1252 is a
 620 superset of iso-8859-1."
 621   :type
 622   '(list
 623     :convert-widget
 624     (lambda (widget)
 625       (let ((defaults
 626               (delq nil
 627                     (mapcar (lambda (pair)
 628                               (if (mm-charset-to-coding-system (cdr pair)
 629                                                                nil nil t)
 630                                   pair))
 631                             '((gb2312 . gbk)
 632                               (iso-8859-1 . windows-1252)
 633                               (iso-8859-8 . windows-1255)
 634                               (iso-8859-9 . windows-1254)
 635                               (undecided  . windows-1252)))))
 636             (val (copy-sequence (default-value 'mm-charset-override-alist)))
 637             pair rest)
 638         (while val
 639           (push (if (and (prog1
 640                              (setq pair (assq (caar val) defaults))
 641                            (setq defaults (delq pair defaults)))
 642                          (equal (car val) pair))
 643                     `(const ,pair)
 644                   `(cons :format "%v"
 645                          (const :format "(%v" ,(caar val))
 646                          (symbol :size 3 :format " . %v)\n" ,(cdar val))))
 647                 rest)
 648           (setq val (cdr val)))
 649         (while defaults
 650           (push `(const ,(pop defaults)) rest))
 651         (widget-convert
 652          'list
 653          `(set :inline t :format "%v" ,@(nreverse rest))
 654          `(repeat :inline t :tag "Other options"
 655                   (cons :format "%v"
 656                         (symbol :size 3 :format "(%v")
 657                         (symbol :size 3 :format " . %v)\n")))))))
 658   ;; Remove pairs that cannot be used in the Emacs version currently
 659   ;; running.  Note that this section will be evaluated when loading
 660   ;; mm-util.elc.
 661   :set (lambda (symbol value)
 662          (custom-set-default
 663           symbol (delq nil
 664                        (mapcar (lambda (pair)
 665                                  (if (mm-charset-to-coding-system (cdr pair)
 666                                                                   nil nil t)
 667                                      pair))
 668                                value))))
 669   :version "22.1" ;; Gnus 5.10.9
 670   :group 'mime)
 671
 672 (defvar mm-binary-coding-system
 673   (cond
 674    ((mm-coding-system-p 'binary) 'binary)
 675    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 676    (t nil))
 677   "100% binary coding system.")
 678
 679 (defvar mm-text-coding-system
 680   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 681           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 682         (and (mm-coding-system-p 'raw-text) 'raw-text))
 683       mm-binary-coding-system)
 684   "Text-safe coding system (For removing ^M).")
 685
 686 (defvar mm-text-coding-system-for-write nil
 687   "Text coding system for write.")
 688
 689 (defvar mm-auto-save-coding-system
 690   (cond
 691    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 692     (if (memq system-type '(windows-nt ms-dos ms-windows))
 693         (if (mm-coding-system-p 'utf-8-emacs-dos)
 694             'utf-8-emacs-dos mm-binary-coding-system)
 695       'utf-8-emacs))
 696    ((mm-coding-system-p 'emacs-mule)
 697     (if (memq system-type '(windows-nt ms-dos ms-windows))
 698         (if (mm-coding-system-p 'emacs-mule-dos)
 699             'emacs-mule-dos mm-binary-coding-system)
 700       'emacs-mule))
 701    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 702    (t mm-binary-coding-system))
 703   "Coding system of auto save file.")
 704
 705 (defvar mm-universal-coding-system mm-auto-save-coding-system
 706   "The universal coding system.")
 707
 708 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 709 ;; should only matter with XEmacs, though.
 710 (defvar mm-mime-mule-charset-alist
 711   `((us-ascii ascii)
 712     (iso-8859-1 latin-iso8859-1)
 713     (iso-8859-2 latin-iso8859-2)
 714     (iso-8859-3 latin-iso8859-3)
 715     (iso-8859-4 latin-iso8859-4)
 716     (iso-8859-5 cyrillic-iso8859-5)
 717     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 718     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 719     ;; charset is koi8-r, not iso-8859-5.
 720     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 721     (iso-8859-6 arabic-iso8859-6)
 722     (iso-8859-7 greek-iso8859-7)
 723     (iso-8859-8 hebrew-iso8859-8)
 724     (iso-8859-9 latin-iso8859-9)
 725     (iso-8859-14 latin-iso8859-14)
 726     (iso-8859-15 latin-iso8859-15)
 727     (viscii vietnamese-viscii-lower)
 728     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 729     (euc-kr korean-ksc5601)
 730     (gb2312 chinese-gb2312)
 731     (gbk chinese-gbk)
 732     (gb18030 gb18030-2-byte
 733              gb18030-4-byte-bmp gb18030-4-byte-smp
 734              gb18030-4-byte-ext-1 gb18030-4-byte-ext-2)
 735     (big5 chinese-big5-1 chinese-big5-2)
 736     (tibetan tibetan)
 737     (thai-tis620 thai-tis620)
 738     (windows-1251 cyrillic-iso8859-5)
 739     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 740     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 741                    latin-jisx0201 japanese-jisx0208-1978
 742                    chinese-gb2312 japanese-jisx0208
 743                    korean-ksc5601 japanese-jisx0212)
 744     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 745                     latin-jisx0201 japanese-jisx0208-1978
 746                     chinese-gb2312 japanese-jisx0208
 747                     korean-ksc5601 japanese-jisx0212
 748                     chinese-cns11643-1 chinese-cns11643-2)
 749     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 750                     cyrillic-iso8859-5 greek-iso8859-7
 751                     latin-jisx0201 japanese-jisx0208-1978
 752                     chinese-gb2312 japanese-jisx0208
 753                     korean-ksc5601 japanese-jisx0212
 754                     chinese-cns11643-1 chinese-cns11643-2
 755                     chinese-cns11643-3 chinese-cns11643-4
 756                     chinese-cns11643-5 chinese-cns11643-6
 757                     chinese-cns11643-7)
 758     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 759                    japanese-jisx0213-1 japanese-jisx0213-2)
 760     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 761     ,(cond ((fboundp 'unicode-precedence-list)
 762             (cons 'utf-8 (delq 'ascii (mapcar 'charset-name
 763                                               (unicode-precedence-list)))))
 764            ((or (not (fboundp 'charsetp)) ;; non-Mule case
 765                 (charsetp 'unicode-a)
 766                 (not (mm-coding-system-p 'mule-utf-8)))
 767             '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e))
 768            (t ;; If we have utf-8 we're in Mule 5+.
 769             (append '(utf-8)
 770                     (delete 'ascii
 771                             (coding-system-get 'mule-utf-8 'safe-charsets))))))
 772   "Alist of MIME-charset/MULE-charsets.")
 773
 774 (defun mm-enrich-utf-8-by-mule-ucs ()
 775   "Make the `utf-8' MIME charset usable by the Mule-UCS package.
 776 This function will run when the `un-define' module is loaded under
 777 XEmacs, and fill the `utf-8' entry in `mm-mime-mule-charset-alist'
 778 with Mule charsets.  It is completely useless for Emacs."
 779   (when (boundp 'unicode-basic-translation-charset-order-list)
 780     (condition-case nil
 781         (let ((val (delq
 782                     'ascii
 783                     (copy-sequence
 784                      (symbol-value
 785                       'unicode-basic-translation-charset-order-list))))
 786               (elem (assq 'utf-8 mm-mime-mule-charset-alist)))
 787           (if elem
 788               (setcdr elem val)
 789             (setq mm-mime-mule-charset-alist
 790                   (nconc mm-mime-mule-charset-alist
 791                          (list (cons 'utf-8 val))))))
 792       (error))))
 793
 794 ;; Correct by construction, but should be unnecessary for Emacs:
 795 (if (featurep 'xemacs)
 796     (eval-after-load "un-define" '(mm-enrich-utf-8-by-mule-ucs))
 797   (when (and (fboundp 'coding-system-list)
 798              (fboundp 'sort-coding-systems))
 799     (let ((css (sort-coding-systems (coding-system-list 'base-only)))
 800           cs mime mule alist)
 801       (while css
 802         (setq cs (pop css)
 803               mime (or (coding-system-get cs :mime-charset); Emacs 23 (unicode)
 804                        (coding-system-get cs 'mime-charset)))
 805         (when (and mime
 806                    (not (eq t (setq mule
 807                                     (coding-system-get cs 'safe-charsets))))
 808                    (not (assq mime alist)))
 809           (push (cons mime (delq 'ascii mule)) alist)))
 810       (setq mm-mime-mule-charset-alist (nreverse alist)))))
 811
 812 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 813   "A list of special charsets.
 814 Valid elements include:
 815 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 816 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 817 )
 818
 819 (defvar mm-iso-8859-15-compatible
 820   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 821     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 822   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 823
 824 (defvar mm-iso-8859-x-to-15-table
 825   (and (fboundp 'coding-system-p)
 826        (mm-coding-system-p 'iso-8859-15)
 827        (mapcar
 828         (lambda (cs)
 829           (if (mm-coding-system-p (car cs))
 830               (let ((c (string-to-char
 831                         (decode-coding-string "\341" (car cs)))))
 832                 (cons (char-charset c)
 833                       (cons
 834                        (- (string-to-char
 835                            (decode-coding-string "\341" 'iso-8859-15)) c)
 836                        (string-to-list (decode-coding-string (car (cdr cs))
 837                                                              (car cs))))))
 838             '(gnus-charset 0)))
 839         mm-iso-8859-15-compatible))
 840   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 841
 842 (defcustom mm-coding-system-priorities
 843   (if (boundp 'current-language-environment)
 844       (let ((lang (symbol-value 'current-language-environment)))
 845         (cond (;; In XEmacs 21.5 it may be the one like "Japanese (UTF-8)".
 846                (string-match "\\`Japanese" lang)
 847                ;; Japanese users prefer iso-2022-jp to euc-japan or
 848                ;; shift_jis, however iso-8859-1 should be used when
 849                ;; there are only ASCII text and Latin-1 characters.
 850                '(iso-8859-1 iso-2022-jp iso-2022-jp-2 shift_jis utf-8)))))
 851   "Preferred coding systems for encoding outgoing messages.
 852
 853 More than one suitable coding system may be found for some text.
 854 By default, the coding system with the highest priority is used
 855 to encode outgoing messages (see `sort-coding-systems').  If this
 856 variable is set, it overrides the default priority."
 857   :version "21.2"
 858   :type '(repeat (symbol :tag "Coding system"))
 859   :group 'mime)
 860
 861 ;; ??
 862 (defvar mm-use-find-coding-systems-region
 863   (fboundp 'find-coding-systems-region)
 864   "Use `find-coding-systems-region' to find proper coding systems.
 865
 866 Setting it to nil is useful on Emacsen supporting Unicode if sending
 867 mail with multiple parts is preferred to sending a Unicode one.")
 868
 869 ;;; Internal variables:
 870
 871 ;;; Functions:
 872
 873 (defun mm-mule-charset-to-mime-charset (charset)
 874   "Return the MIME charset corresponding to the given Mule CHARSET."
 875   (if (and (fboundp 'find-coding-systems-for-charsets)
 876            (fboundp 'sort-coding-systems))
 877       (let ((css (sort (sort-coding-systems
 878                         (find-coding-systems-for-charsets (list charset)))
 879                        'mm-sort-coding-systems-predicate))
 880             cs mime)
 881         (while (and (not mime)
 882                     css)
 883           (when (setq cs (pop css))
 884             (setq mime (or (coding-system-get cs :mime-charset)
 885                            (coding-system-get cs 'mime-charset)))))
 886         mime)
 887     (let ((alist (mapcar (lambda (cs)
 888                            (assq cs mm-mime-mule-charset-alist))
 889                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 890                                'mm-sort-coding-systems-predicate)))
 891           out)
 892       (while alist
 893         (when (memq charset (cdar alist))
 894           (setq out (caar alist)
 895                 alist nil))
 896         (pop alist))
 897       out)))
 898
 899 (eval-and-compile
 900   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 901                              (boundp 'default-enable-multibyte-characters)
 902                              default-enable-multibyte-characters
 903                              (fboundp 'set-buffer-multibyte))
 904     "True in Emacs with Mule.")
 905
 906   (if mm-emacs-mule
 907       (defun mm-enable-multibyte ()
 908         "Set the multibyte flag of the current buffer.
 909 Only do this if the default value of `enable-multibyte-characters' is
 910 non-nil.  This is a no-op in XEmacs."
 911         (set-buffer-multibyte 'to))
 912     (defalias 'mm-enable-multibyte 'ignore))
 913
 914   (if mm-emacs-mule
 915       (defun mm-disable-multibyte ()
 916         "Unset the multibyte flag of in the current buffer.
 917 This is a no-op in XEmacs."
 918         (set-buffer-multibyte nil))
 919     (defalias 'mm-disable-multibyte 'ignore)))
 920
 921 (defun mm-preferred-coding-system (charset)
 922   ;; A typo in some Emacs versions.
 923   (or (get-charset-property charset 'preferred-coding-system)
 924       (get-charset-property charset 'prefered-coding-system)))
 925
 926 ;; Mule charsets shouldn't be used.
 927 (defsubst mm-guess-charset ()
 928   "Guess Mule charset from the language environment."
 929   (or
 930    mail-parse-mule-charset ;; cached mule-charset
 931    (progn
 932      (setq mail-parse-mule-charset
 933            (and (boundp 'current-language-environment)
 934                 (car (last
 935                       (assq 'charset
 936                             (assoc current-language-environment
 937                                    language-info-alist))))))
 938      (if (or (not mail-parse-mule-charset)
 939              (eq mail-parse-mule-charset 'ascii))
 940          (setq mail-parse-mule-charset
 941                (or (car (last (assq mail-parse-charset
 942                                     mm-mime-mule-charset-alist)))
 943                    ;; default
 944                    'latin-iso8859-1)))
 945      mail-parse-mule-charset)))
 946
 947 (defun mm-charset-after (&optional pos)
 948   "Return charset of a character in current buffer at position POS.
 949 If POS is nil, it defauls to the current point.
 950 If POS is out of range, the value is nil.
 951 If the charset is `composition', return the actual one."
 952   (let ((char (char-after pos)) charset)
 953     (if (< (mm-char-int char) 128)
 954         (setq charset 'ascii)
 955       ;; charset-after is fake in some Emacsen.
 956       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 957       (if (eq charset 'composition)     ; Mule 4
 958           (let ((p (or pos (point))))
 959             (cadr (find-charset-region p (1+ p))))
 960         (if (and charset (not (memq charset '(ascii eight-bit-control
 961                                                     eight-bit-graphic))))
 962             charset
 963           (mm-guess-charset))))))
 964
 965 (defun mm-mime-charset (charset)
 966   "Return the MIME charset corresponding to the given Mule CHARSET."
 967   (if (eq charset 'unknown)
 968       (error "The message contains non-printable characters, please use attachment"))
 969   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 970       ;; This exists in Emacs 20.
 971       (or
 972        (and (mm-preferred-coding-system charset)
 973             (or (coding-system-get
 974                  (mm-preferred-coding-system charset) :mime-charset)
 975                 (coding-system-get
 976                  (mm-preferred-coding-system charset) 'mime-charset)))
 977        (and (eq charset 'ascii)
 978             'us-ascii)
 979        (mm-preferred-coding-system charset)
 980        (mm-mule-charset-to-mime-charset charset))
 981     ;; This is for XEmacs.
 982     (mm-mule-charset-to-mime-charset charset)))
 983
 984 (if (fboundp 'delete-dups)
 985     (defalias 'mm-delete-duplicates 'delete-dups)
 986   (defun mm-delete-duplicates (list)
 987     "Destructively remove `equal' duplicates from LIST.
 988 Store the result in LIST and return it.  LIST must be a proper list.
 989 Of several `equal' occurrences of an element in LIST, the first
 990 one is kept.
 991
 992 This is a compatibility function for Emacsen without `delete-dups'."
 993     ;; Code from `subr.el' in Emacs 22:
 994     (let ((tail list))
 995       (while tail
 996         (setcdr tail (delete (car tail) (cdr tail)))
 997         (setq tail (cdr tail))))
 998     list))
 999
1000 ;; Fixme:  This is used in places when it should be testing the
1001 ;; default multibyteness.  See mm-default-multibyte-p.
1002 (eval-and-compile
1003   (if (and (not (featurep 'xemacs))
1004            (boundp 'enable-multibyte-characters))
1005       (defun mm-multibyte-p ()
1006         "Non-nil if multibyte is enabled in the current buffer."
1007         enable-multibyte-characters)
1008     (defun mm-multibyte-p () (featurep 'mule))))
1009
1010 (defun mm-default-multibyte-p ()
1011   "Return non-nil if the session is multibyte.
1012 This affects whether coding conversion should be attempted generally."
1013   (if (featurep 'mule)
1014       (if (boundp 'default-enable-multibyte-characters)
1015           default-enable-multibyte-characters
1016         t)))
1017
1018 (defun mm-iso-8859-x-to-15-region (&optional b e)
1019   (if (fboundp 'char-charset)
1020       (let (charset item c inconvertible)
1021         (save-restriction
1022           (if e (narrow-to-region b e))
1023           (goto-char (point-min))
1024           (skip-chars-forward "\0-\177")
1025           (while (not (eobp))
1026             (cond
1027              ((not (setq item (assq (char-charset (setq c (char-after)))
1028                                     mm-iso-8859-x-to-15-table)))
1029               (forward-char))
1030              ((memq c (cdr (cdr item)))
1031               (setq inconvertible t)
1032               (forward-char))
1033              (t
1034               (insert-before-markers (prog1 (+ c (car (cdr item)))
1035                                        (delete-char 1)))))
1036             (skip-chars-forward "\0-\177")))
1037         (not inconvertible))))
1038
1039 (defun mm-sort-coding-systems-predicate (a b)
1040   (let ((priorities
1041          (mapcar (lambda (cs)
1042                    ;; Note: invalid entries are dropped silently
1043                    (and (setq cs (mm-coding-system-p cs))
1044                         (coding-system-base cs)))
1045                  mm-coding-system-priorities)))
1046     (and (setq a (mm-coding-system-p a))
1047          (if (setq b (mm-coding-system-p b))
1048              (> (length (memq (coding-system-base a) priorities))
1049                 (length (memq (coding-system-base b) priorities)))
1050            t))))
1051
1052 (eval-when-compile
1053   (autoload 'latin-unity-massage-name "latin-unity")
1054   (autoload 'latin-unity-maybe-remap "latin-unity")
1055   (autoload 'latin-unity-representations-feasible-region "latin-unity")
1056   (autoload 'latin-unity-representations-present-region "latin-unity"))
1057
1058 (defvar latin-unity-coding-systems)
1059 (defvar latin-unity-ucs-list)
1060
1061 (defun mm-xemacs-find-mime-charset-1 (begin end)
1062   "Determine which MIME charset to use to send region as message.
1063 This uses the XEmacs-specific latin-unity package to better handle the
1064 case where identical characters from diverse ISO-8859-? character sets
1065 can be encoded using a single one of the corresponding coding systems.
1066
1067 It treats `mm-coding-system-priorities' as the list of preferred
1068 coding systems; a useful example setting for this list in Western
1069 Europe would be '(iso-8859-1 iso-8859-15 utf-8), which would default
1070 to the very standard Latin 1 coding system, and only move to coding
1071 systems that are less supported as is necessary to encode the
1072 characters that exist in the buffer.
1073
1074 Latin Unity doesn't know about those non-ASCII Roman characters that
1075 are available in various East Asian character sets.  As such, its
1076 behavior if you have a JIS 0212 LATIN SMALL LETTER A WITH ACUTE in a
1077 buffer and it can otherwise be encoded as Latin 1, won't be ideal.
1078 But this is very much a corner case, so don't worry about it."
1079   (let ((systems mm-coding-system-priorities) csets psets curset)
1080
1081     ;; Load the Latin Unity library, if available.
1082     (when (and (not (featurep 'latin-unity)) (locate-library "latin-unity"))
1083       (require 'latin-unity))
1084
1085     ;; Now, can we use it?
1086     (if (featurep 'latin-unity)
1087         (progn
1088           (setq csets (latin-unity-representations-feasible-region begin end)
1089                 psets (latin-unity-representations-present-region begin end))
1090
1091           (catch 'done
1092
1093             ;; Pass back the first coding system in the preferred list
1094             ;; that can encode the whole region.
1095             (dolist (curset systems)
1096               (setq curset (latin-unity-massage-name 'buffer-default curset))
1097
1098               ;; If the coding system is a universal coding system, then
1099               ;; it can certainly encode all the characters in the region.
1100               (if (memq curset latin-unity-ucs-list)
1101                   (throw 'done (list curset)))
1102
1103               ;; If a coding system isn't universal, and isn't in
1104               ;; the list that latin unity knows about, we can't
1105               ;; decide whether to use it here. Leave that until later
1106               ;; in `mm-find-mime-charset-region' function, whence we
1107               ;; have been called.
1108               (unless (memq curset latin-unity-coding-systems)
1109                 (throw 'done nil))
1110
1111               ;; Right, we know about this coding system, and it may
1112               ;; conceivably be able to encode all the characters in
1113               ;; the region.
1114               (if (latin-unity-maybe-remap begin end curset csets psets t)
1115                   (throw 'done (list curset))))
1116
1117             ;; Can't encode using anything from the
1118             ;; `mm-coding-system-priorities' list.
1119             ;; Leave `mm-find-mime-charset' to do most of the work.
1120             nil))
1121
1122       ;; Right, latin unity isn't available; let `mm-find-charset-region'
1123       ;; take its default action, which equally applies to GNU Emacs.
1124       nil)))
1125
1126 (defmacro mm-xemacs-find-mime-charset (begin end)
1127   (when (featurep 'xemacs)
1128     `(and (featurep 'mule) (mm-xemacs-find-mime-charset-1 ,begin ,end))))
1129
1130 (declare-function mm-delete-duplicates "mm-util" (list))
1131
1132 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
1133   "Return the MIME charsets needed to encode the region between B and E.
1134 nil means ASCII, a single-element list represents an appropriate MIME
1135 charset, and a longer list means no appropriate charset."
1136   (let (charsets)
1137     ;; The return possibilities of this function are a mess...
1138     (or (and (mm-multibyte-p)
1139              mm-use-find-coding-systems-region
1140              ;; Find the mime-charset of the most preferred coding
1141              ;; system that has one.
1142              (let ((systems (find-coding-systems-region b e)))
1143                (when mm-coding-system-priorities
1144                  (setq systems
1145                        (sort systems 'mm-sort-coding-systems-predicate)))
1146                (setq systems (delq 'compound-text systems))
1147                (unless (equal systems '(undecided))
1148                  (while systems
1149                    (let* ((head (pop systems))
1150                           (cs (or (coding-system-get head :mime-charset)
1151                                   (coding-system-get head 'mime-charset))))
1152                      ;; The mime-charset (`x-ctext') of
1153                      ;; `compound-text' is not in the IANA list.  We
1154                      ;; shouldn't normally use anything here with a
1155                      ;; mime-charset having an `x-' prefix.
1156                      ;; Fixme:  Allow this to be overridden, since
1157                      ;; there is existing use of x-ctext.
1158                      ;; Also people apparently need the coding system
1159                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
1160                      ;; mime-charset, though it's not valid).
1161                      (if (and cs
1162                               (not (string-match "^[Xx]-" (symbol-name cs)))
1163                               ;; UTF-16 of any variety is invalid for
1164                               ;; text parts and, unfortunately, has
1165                               ;; mime-charset defined both in Mule-UCS
1166                               ;; and versions of Emacs.  (The name
1167                               ;; might be `mule-utf-16...'  or
1168                               ;; `utf-16...'.)
1169                               (not (string-match "utf-16" (symbol-name cs))))
1170                          (setq systems nil
1171                                charsets (list cs))))))
1172                charsets))
1173         ;; If we're XEmacs, and some coding system is appropriate,
1174         ;; mm-xemacs-find-mime-charset will return an appropriate list.
1175         ;; Otherwise, we'll get nil, and the next setq will get invoked.
1176         (setq charsets (mm-xemacs-find-mime-charset b e))
1177
1178         ;; Fixme: won't work for unibyte Emacs 23:
1179
1180         ;; We're not multibyte, or a single coding system won't cover it.
1181         (setq charsets
1182               (mm-delete-duplicates
1183                (mapcar 'mm-mime-charset
1184                        (delq 'ascii
1185                              (mm-find-charset-region b e))))))
1186     (if (and (> (length charsets) 1)
1187              (memq 'iso-8859-15 charsets)
1188              (memq 'iso-8859-15 hack-charsets)
1189              (save-excursion (mm-iso-8859-x-to-15-region b e)))
1190         (dolist (x mm-iso-8859-15-compatible)
1191           (setq charsets (delq (car x) charsets))))
1192     (if (and (memq 'iso-2022-jp-2 charsets)
1193              (memq 'iso-2022-jp-2 hack-charsets))
1194         (setq charsets (delq 'iso-2022-jp charsets)))
1195     ;; Attempt to reduce the number of charsets if utf-8 is available.
1196     (if (and (featurep 'xemacs)
1197              (> (length charsets) 1)
1198              (mm-coding-system-p 'utf-8))
1199         (let ((mm-coding-system-priorities
1200                (cons 'utf-8 mm-coding-system-priorities)))
1201           (setq charsets
1202                 (mm-delete-duplicates
1203                  (mapcar 'mm-mime-charset
1204                          (delq 'ascii
1205                                (mm-find-charset-region b e)))))))
1206     charsets))
1207
1208 (defmacro mm-with-unibyte-buffer (&rest forms)
1209   "Create a temporary buffer, and evaluate FORMS there like `progn'.
1210 Use unibyte mode for this."
1211   `(with-temp-buffer
1212      (mm-disable-multibyte)
1213      ,@forms))
1214 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
1215 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
1216
1217 (defmacro mm-with-multibyte-buffer (&rest forms)
1218   "Create a temporary buffer, and evaluate FORMS there like `progn'.
1219 Use multibyte mode for this."
1220   `(with-temp-buffer
1221      (mm-enable-multibyte)
1222      ,@forms))
1223 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
1224 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
1225
1226 (defmacro mm-with-unibyte-current-buffer (&rest forms)
1227   "Evaluate FORMS with current buffer temporarily made unibyte.
1228 Also bind `default-enable-multibyte-characters' to nil.
1229 Equivalent to `progn' in XEmacs
1230
1231 NOTE: Use this macro with caution in multibyte buffers (it is not
1232 worth using this macro in unibyte buffers of course).  Use of
1233 `(set-buffer-multibyte t)', which is run finally, is generally
1234 harmful since it is likely to modify existing data in the buffer.
1235 For instance, it converts \"\\300\\255\" into \"\\255\" in
1236 Emacs 23 (unicode)."
1237   (let ((multibyte (make-symbol "multibyte"))
1238         (buffer (make-symbol "buffer")))
1239     `(if mm-emacs-mule
1240          (let ((,multibyte enable-multibyte-characters)
1241                (,buffer (current-buffer)))
1242            (unwind-protect
1243                (let (default-enable-multibyte-characters)
1244                  (set-buffer-multibyte nil)
1245                  ,@forms)
1246              (set-buffer ,buffer)
1247              (set-buffer-multibyte ,multibyte)))
1248        (let (default-enable-multibyte-characters)
1249          ,@forms))))
1250 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
1251 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
1252
1253 (defun mm-find-charset-region (b e)
1254   "Return a list of Emacs charsets in the region B to E."
1255   (cond
1256    ((and (mm-multibyte-p)
1257          (fboundp 'find-charset-region))
1258     ;; Remove composition since the base charsets have been included.
1259     ;; Remove eight-bit-*, treat them as ascii.
1260     (let ((css (find-charset-region b e)))
1261       (dolist (cs
1262                '(composition eight-bit-control eight-bit-graphic control-1)
1263                css)
1264         (setq css (delq cs css)))))
1265    (t
1266     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
1267     (save-excursion
1268       (save-restriction
1269         (narrow-to-region b e)
1270         (goto-char (point-min))
1271         (skip-chars-forward "\0-\177")
1272         (if (eobp)
1273             '(ascii)
1274           (let (charset)
1275             (setq charset
1276                   (and (boundp 'current-language-environment)
1277                        (car (last (assq 'charset
1278                                         (assoc current-language-environment
1279                                                language-info-alist))))))
1280             (if (eq charset 'ascii) (setq charset nil))
1281             (or charset
1282                 (setq charset
1283                       (car (last (assq mail-parse-charset
1284                                        mm-mime-mule-charset-alist)))))
1285             (list 'ascii (or charset 'latin-iso8859-1)))))))))
1286
1287 (defun mm-auto-mode-alist ()
1288   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
1289   (let ((alist auto-mode-alist)
1290         out)
1291     (while alist
1292       (when (listp (cdar alist))
1293         (push (car alist) out))
1294       (pop alist))
1295     (nreverse out)))
1296
1297 (defvar mm-inhibit-file-name-handlers
1298   '(jka-compr-handler image-file-handler epa-file-handler)
1299   "A list of handlers doing (un)compression (etc) thingies.")
1300
1301 (defun mm-insert-file-contents (filename &optional visit beg end replace
1302                                          inhibit)
1303   "Like `insert-file-contents', but only reads in the file.
1304 A buffer may be modified in several ways after reading into the buffer due
1305 to advanced Emacs features, such as file-name-handlers, format decoding,
1306 `find-file-hooks', etc.
1307 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
1308   This function ensures that none of these modifications will take place."
1309   (let* ((format-alist nil)
1310          (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
1311          (default-major-mode 'fundamental-mode)
1312          (enable-local-variables nil)
1313          (after-insert-file-functions nil)
1314          (enable-local-eval nil)
1315          (inhibit-file-name-operation (if inhibit
1316                                           'insert-file-contents
1317                                         inhibit-file-name-operation))
1318          (inhibit-file-name-handlers
1319           (if inhibit
1320               (append mm-inhibit-file-name-handlers
1321                       inhibit-file-name-handlers)
1322             inhibit-file-name-handlers))
1323          (ffh (if (boundp 'find-file-hook)
1324                   'find-file-hook
1325                 'find-file-hooks))
1326          (val (symbol-value ffh)))
1327     (set ffh nil)
1328     (unwind-protect
1329         (insert-file-contents filename visit beg end replace)
1330       (set ffh val))))
1331
1332 (defun mm-append-to-file (start end filename &optional codesys inhibit)
1333   "Append the contents of the region to the end of file FILENAME.
1334 When called from a function, expects three arguments,
1335 START, END and FILENAME.  START and END are buffer positions
1336 saying what text to write.
1337 Optional fourth argument specifies the coding system to use when
1338 encoding the file.
1339 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
1340   (let ((coding-system-for-write
1341          (or codesys mm-text-coding-system-for-write
1342              mm-text-coding-system))
1343         (inhibit-file-name-operation (if inhibit
1344                                          'append-to-file
1345                                        inhibit-file-name-operation))
1346         (inhibit-file-name-handlers
1347          (if inhibit
1348              (append mm-inhibit-file-name-handlers
1349                      inhibit-file-name-handlers)
1350            inhibit-file-name-handlers)))
1351     (write-region start end filename t 'no-message)
1352     (message "Appended to %s" filename)))
1353
1354 (defun mm-write-region (start end filename &optional append visit lockname
1355                               coding-system inhibit)
1356
1357   "Like `write-region'.
1358 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
1359   (let ((coding-system-for-write
1360          (or coding-system mm-text-coding-system-for-write
1361              mm-text-coding-system))
1362         (inhibit-file-name-operation (if inhibit
1363                                          'write-region
1364                                        inhibit-file-name-operation))
1365         (inhibit-file-name-handlers
1366          (if inhibit
1367              (append mm-inhibit-file-name-handlers
1368                      inhibit-file-name-handlers)
1369            inhibit-file-name-handlers)))
1370     (write-region start end filename append visit lockname)))
1371
1372 (autoload 'gmm-write-region "gmm-utils")
1373
1374 ;; It is not a MIME function, but some MIME functions use it.
1375 (if (and (fboundp 'make-temp-file)
1376          (ignore-errors
1377            (let ((def (symbol-function 'make-temp-file)))
1378              (and (byte-code-function-p def)
1379                   (setq def (if (fboundp 'compiled-function-arglist)
1380                                 ;; XEmacs
1381                                 (eval (list 'compiled-function-arglist def))
1382                               (aref def 0)))
1383                   (>= (length def) 4)
1384                   (eq (nth 3 def) 'suffix)))))
1385     (defalias 'mm-make-temp-file 'make-temp-file)
1386   ;; Stolen (and modified for XEmacs) from Emacs 22.
1387   (defun mm-make-temp-file (prefix &optional dir-flag suffix)
1388     "Create a temporary file.
1389 The returned file name (created by appending some random characters at the end
1390 of PREFIX, and expanding against `temporary-file-directory' if necessary),
1391 is guaranteed to point to a newly created empty file.
1392 You can then use `write-region' to write new data into the file.
1393
1394 If DIR-FLAG is non-nil, create a new empty directory instead of a file.
1395
1396 If SUFFIX is non-nil, add that at the end of the file name."
1397     (let ((umask (default-file-modes))
1398           file)
1399       (unwind-protect
1400           (progn
1401             ;; Create temp files with strict access rights.  It's easy to
1402             ;; loosen them later, whereas it's impossible to close the
1403             ;; time-window of loose permissions otherwise.
1404             (set-default-file-modes 448)
1405             (while (condition-case err
1406                        (progn
1407                          (setq file
1408                                (make-temp-name
1409                                 (expand-file-name
1410                                  prefix
1411                                  (if (fboundp 'temp-directory)
1412                                      ;; XEmacs
1413                                      (temp-directory)
1414                                    temporary-file-directory))))
1415                          (if suffix
1416                              (setq file (concat file suffix)))
1417                          (if dir-flag
1418                              (make-directory file)
1419                            ;; NOTE: This is unsafe if Emacs 20
1420                            ;; users and XEmacs users don't use
1421                            ;; a secure temp directory.
1422                            (gmm-write-region "" nil file nil 'silent
1423                                              nil 'excl))
1424                          nil)
1425                      (file-already-exists t)
1426                      ;; The XEmacs version of `make-directory' issues
1427                      ;; `file-error'.
1428                      (file-error (or (and (featurep 'xemacs)
1429                                           (file-exists-p file))
1430                                      (signal (car err) (cdr err)))))
1431               ;; the file was somehow created by someone else between
1432               ;; `make-temp-name' and `write-region', let's try again.
1433               nil)
1434             file)
1435         ;; Reset the umask.
1436         (set-default-file-modes umask)))))
1437
1438 (defun mm-image-load-path (&optional package)
1439   (let (dir result)
1440     (dolist (path load-path (nreverse result))
1441       (when (and path
1442                  (file-directory-p
1443                   (setq dir (concat (file-name-directory
1444                                      (directory-file-name path))
1445                                     "etc/images/" (or package "gnus/")))))
1446         (push dir result))
1447       (push path result))))
1448
1449 ;; Fixme: This doesn't look useful where it's used.
1450 (if (fboundp 'detect-coding-region)
1451     (defun mm-detect-coding-region (start end)
1452       "Like `detect-coding-region' except returning the best one."
1453       (let ((coding-systems
1454              (detect-coding-region start end)))
1455         (or (car-safe coding-systems)
1456             coding-systems)))
1457   (defun mm-detect-coding-region (start end)
1458     (let ((point (point)))
1459       (goto-char start)
1460       (skip-chars-forward "\0-\177" end)
1461       (prog1
1462           (if (eq (point) end) 'ascii (mm-guess-charset))
1463         (goto-char point)))))
1464
1465 (declare-function mm-detect-coding-region "mm-util" (start end))
1466
1467 (if (fboundp 'coding-system-get)
1468     (defun mm-detect-mime-charset-region (start end)
1469       "Detect MIME charset of the text in the region between START and END."
1470       (let ((cs (mm-detect-coding-region start end)))
1471         (or (coding-system-get cs :mime-charset)
1472             (coding-system-get cs 'mime-charset))))
1473   (defun mm-detect-mime-charset-region (start end)
1474     "Detect MIME charset of the text in the region between START and END."
1475     (let ((cs (mm-detect-coding-region start end)))
1476       cs)))
1477
1478 (eval-when-compile
1479   (unless (fboundp 'coding-system-to-mime-charset)
1480     (defalias 'coding-system-to-mime-charset 'ignore)))
1481
1482 (defun mm-coding-system-to-mime-charset (coding-system)
1483   "Return the MIME charset corresponding to CODING-SYSTEM.
1484 To make this function work with XEmacs, the APEL package is required."
1485   (when coding-system
1486     (or (and (fboundp 'coding-system-get)
1487              (or (coding-system-get coding-system :mime-charset)
1488                  (coding-system-get coding-system 'mime-charset)))
1489         (and (featurep 'xemacs)
1490              (or (and (fboundp 'coding-system-to-mime-charset)
1491                       (not (eq (symbol-function 'coding-system-to-mime-charset)
1492                                'ignore)))
1493                  (and (condition-case nil
1494                           (require 'mcharset)
1495                         (error nil))
1496                       (fboundp 'coding-system-to-mime-charset)))
1497              (coding-system-to-mime-charset coding-system)))))
1498
1499 (eval-when-compile
1500   (require 'jka-compr))
1501
1502 (defun mm-decompress-buffer (filename &optional inplace force)
1503   "Decompress buffer's contents, depending on jka-compr.
1504 Only when FORCE is t or `auto-compression-mode' is enabled and FILENAME
1505 agrees with `jka-compr-compression-info-list', decompression is done.
1506 Signal an error if FORCE is neither nil nor t and compressed data are
1507 not decompressed because `auto-compression-mode' is disabled.
1508 If INPLACE is nil, return decompressed data or nil without modifying
1509 the buffer.  Otherwise, replace the buffer's contents with the
1510 decompressed data.  The buffer's multibyteness must be turned off."
1511   (when (and filename
1512              (if force
1513                  (prog1 t (require 'jka-compr))
1514                (and (fboundp 'jka-compr-installed-p)
1515                     (jka-compr-installed-p))))
1516     (let ((info (jka-compr-get-compression-info filename)))
1517       (when info
1518         (unless (or (memq force (list nil t))
1519                     (jka-compr-installed-p))
1520           (error ""))
1521         (let ((prog (jka-compr-info-uncompress-program info))
1522               (args (jka-compr-info-uncompress-args info))
1523               (msg (format "%s %s..."
1524                            (jka-compr-info-uncompress-message info)
1525                            filename))
1526               (err-file (jka-compr-make-temp-name))
1527               (cur (current-buffer))
1528               (coding-system-for-read mm-binary-coding-system)
1529               (coding-system-for-write mm-binary-coding-system)
1530               retval err-msg)
1531           (message "%s" msg)
1532           (mm-with-unibyte-buffer
1533             (insert-buffer-substring cur)
1534             (condition-case err
1535                 (progn
1536                   (unless (memq (apply 'call-process-region
1537                                        (point-min) (point-max)
1538                                        prog t (list t err-file) nil args)
1539                                 jka-compr-acceptable-retval-list)
1540                     (erase-buffer)
1541                     (insert (mapconcat
1542                              'identity
1543                              (delete "" (split-string
1544                                          (prog2
1545                                              (insert-file-contents err-file)
1546                                              (buffer-string)
1547                                            (erase-buffer))))
1548                              " ")
1549                             "\n")
1550                     (setq err-msg
1551                           (format "Error while executing \"%s %s < %s\""
1552                                   prog (mapconcat 'identity args " ")
1553                                   filename)))
1554                   (setq retval (buffer-string)))
1555               (error
1556                (setq err-msg (error-message-string err)))))
1557           (when (file-exists-p err-file)
1558             (ignore-errors (jka-compr-delete-temp-file err-file)))
1559           (when inplace
1560             (unless err-msg
1561               (delete-region (point-min) (point-max))
1562               (insert retval))
1563             (setq retval nil))
1564           (message "%s" (or err-msg (concat msg "done")))
1565           retval)))))
1566
1567 (eval-when-compile
1568   (unless (fboundp 'coding-system-name)
1569     (defalias 'coding-system-name 'ignore))
1570   (unless (fboundp 'find-file-coding-system-for-read-from-filename)
1571     (defalias 'find-file-coding-system-for-read-from-filename 'ignore))
1572   (unless (fboundp 'find-operation-coding-system)
1573     (defalias 'find-operation-coding-system 'ignore)))
1574
1575 (defun mm-find-buffer-file-coding-system (&optional filename)
1576   "Find coding system used to decode the contents of the current buffer.
1577 This function looks for the coding system magic cookie or examines the
1578 coding system specified by `file-coding-system-alist' being associated
1579 with FILENAME which defaults to `buffer-file-name'.  Data compressed by
1580 gzip, bzip2, etc. are allowed."
1581   (unless filename
1582     (setq filename buffer-file-name))
1583   (save-excursion
1584     (let ((decomp (unless ;; No worth to examine charset of tar files.
1585                       (and filename
1586                            (string-match
1587                             "\\.\\(?:tar\\.[^.]+\\|tbz\\|tgz\\)\\'"
1588                             filename))
1589                     (mm-decompress-buffer filename nil t))))
1590       (when decomp
1591         (set-buffer (let (default-enable-multibyte-characters)
1592                       (generate-new-buffer " *temp*")))
1593         (insert decomp)
1594         (setq filename (file-name-sans-extension filename)))
1595       (goto-char (point-min))
1596       (prog1
1597           (cond
1598            ((boundp 'set-auto-coding-function) ;; Emacs
1599             (if filename
1600                 (or (funcall (symbol-value 'set-auto-coding-function)
1601                              filename (- (point-max) (point-min)))
1602                     (car (find-operation-coding-system 'insert-file-contents
1603                                                        filename)))
1604               (let (auto-coding-alist)
1605                 (condition-case nil
1606                     (funcall (symbol-value 'set-auto-coding-function)
1607                              nil (- (point-max) (point-min)))
1608                   (error nil)))))
1609            ((and (featurep 'xemacs) (featurep 'file-coding)) ;; XEmacs
1610             (let ((case-fold-search t)
1611                   (end (point-at-eol))
1612                   codesys start)
1613               (or
1614                (and (re-search-forward "-\\*-+[\t ]*" end t)
1615                     (progn
1616                       (setq start (match-end 0))
1617                       (re-search-forward "[\t ]*-+\\*-" end t))
1618                     (progn
1619                       (setq end (match-beginning 0))
1620                       (goto-char start)
1621                       (or (looking-at "coding:[\t ]*\\([^\t ;]+\\)")
1622                           (re-search-forward
1623                            "[\t ;]+coding:[\t ]*\\([^\t ;]+\\)"
1624                            end t)))
1625                     (find-coding-system (setq codesys
1626                                               (intern (match-string 1))))
1627                     codesys)
1628                (and (re-search-forward "^[\t ]*;+[\t ]*Local[\t ]+Variables:"
1629                                        nil t)
1630                     (progn
1631                       (setq start (match-end 0))
1632                       (re-search-forward "^[\t ]*;+[\t ]*End:" nil t))
1633                     (progn
1634                       (setq end (match-beginning 0))
1635                       (goto-char start)
1636                       (re-search-forward
1637                        "^[\t ]*;+[\t ]*coding:[\t ]*\\([^\t\n\r ]+\\)"
1638                        end t))
1639                     (find-coding-system (setq codesys
1640                                               (intern (match-string 1))))
1641                     codesys)
1642                (and (progn
1643                       (goto-char (point-min))
1644                       (setq case-fold-search nil)
1645                       (re-search-forward "^;;;coding system: "
1646                                          ;;(+ (point-min) 3000) t))
1647                                          nil t))
1648                     (looking-at "[^\t\n\r ]+")
1649                     (find-coding-system
1650                      (setq codesys (intern (match-string 0))))
1651                     codesys)
1652                (and filename
1653                     (setq codesys
1654                           (find-file-coding-system-for-read-from-filename
1655                            filename))
1656                     (coding-system-name (coding-system-base codesys)))))))
1657         (when decomp
1658           (kill-buffer (current-buffer)))))))
1659
1660 (provide 'mm-util)
1661
1662 ;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
1663 ;;; mm-util.el ends here