cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; For Emacs < 22.2.
  28 (eval-and-compile
  29   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'mail-prsvr)
  33
  34 (eval-and-compile
  35   (if (featurep 'xemacs)
  36       (unless (ignore-errors
  37                 (require 'timer-funcs))
  38         (require 'timer))
  39     (require 'timer)))
  40
  41 (defvar mm-mime-mule-charset-alist )
  42
  43 (eval-and-compile
  44   (mapc
  45    (lambda (elem)
  46      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  47        (if (fboundp (car elem))
  48            (defalias nfunc (car elem))
  49          (defalias nfunc (cdr elem)))))
  50    '((coding-system-list . ignore)
  51      (char-int . identity)
  52      (coding-system-equal . equal)
  53      (annotationp . ignore)
  54      (set-buffer-file-coding-system . ignore)
  55      (read-charset
  56       . (lambda (prompt)
  57           "Return a charset."
  58           (intern
  59            (completing-read
  60             prompt
  61             (mapcar (lambda (e) (list (symbol-name (car e))))
  62                     mm-mime-mule-charset-alist)
  63             nil t))))
  64      (subst-char-in-string
  65       . (lambda (from to string &optional inplace)
  66           ;; stolen (and renamed) from nnheader.el
  67           "Replace characters in STRING from FROM to TO.
  68           Unless optional argument INPLACE is non-nil, return a new string."
  69           (let ((string (if inplace string (copy-sequence string)))
  70                 (len (length string))
  71                 (idx 0))
  72             ;; Replace all occurrences of FROM with TO.
  73             (while (< idx len)
  74               (when (= (aref string idx) from)
  75                 (aset string idx to))
  76               (setq idx (1+ idx)))
  77             string)))
  78      (replace-in-string
  79       . (lambda (string regexp rep &optional literal)
  80           "See `replace-regexp-in-string', only the order of args differs."
  81           (replace-regexp-in-string regexp rep string nil literal)))
  82      (string-as-unibyte . identity)
  83      (string-make-unibyte . identity)
  84      ;; string-as-multibyte often doesn't really do what you think it does.
  85      ;; Example:
  86      ;;    (aref (string-as-multibyte "\201") 0) -> 129 (aka ?\201)
  87      ;;    (aref (string-as-multibyte "\300") 0) -> 192 (aka ?\300)
  88      ;;    (aref (string-as-multibyte "\300\201") 0) -> 192 (aka ?\300)
  89      ;;    (aref (string-as-multibyte "\300\201") 1) -> 129 (aka ?\201)
  90      ;; but
  91      ;;    (aref (string-as-multibyte "\201\300") 0) -> 2240
  92      ;;    (aref (string-as-multibyte "\201\300") 1) -> <error>
  93      ;; Better use string-to-multibyte or encode-coding-string.
  94      ;; If you really need string-as-multibyte somewhere it's usually
  95      ;; because you're using the internal emacs-mule representation (maybe
  96      ;; because you're using string-as-unibyte somewhere), which is
  97      ;; generally a problem in itself.
  98      ;; Here is an approximate equivalence table to help think about it:
  99      ;; (string-as-multibyte s)   ~= (decode-coding-string s 'emacs-mule)
 100      ;; (string-to-multibyte s)   ~= (decode-coding-string s 'binary)
 101      ;; (string-make-multibyte s) ~= (decode-coding-string s locale-coding-system)
 102      (string-as-multibyte . identity)
 103      (multibyte-string-p . ignore)
 104      (insert-byte . insert-char)
 105      (multibyte-char-to-unibyte . identity)
 106      (set-buffer-multibyte . ignore)
 107      (special-display-p
 108       . (lambda (buffer-name)
 109           "Returns non-nil if a buffer named BUFFER-NAME gets a special frame."
 110           (and special-display-function
 111                (or (and (member buffer-name special-display-buffer-names) t)
 112                    (cdr (assoc buffer-name special-display-buffer-names))
 113                    (catch 'return
 114                      (dolist (elem special-display-regexps)
 115                        (and (stringp elem)
 116                             (string-match elem buffer-name)
 117                             (throw 'return t))
 118                        (and (consp elem)
 119                             (stringp (car elem))
 120                             (string-match (car elem) buffer-name)
 121                             (throw 'return (cdr elem))))))))))))
 122
 123 (eval-and-compile
 124   (if (featurep 'xemacs)
 125       (if (featurep 'file-coding)
 126           ;; Don't modify string if CODING-SYSTEM is nil.
 127           (progn
 128             (defun mm-decode-coding-string (str coding-system)
 129               (if coding-system
 130                   (decode-coding-string str coding-system)
 131                 str))
 132             (defun mm-encode-coding-string (str coding-system)
 133               (if coding-system
 134                   (encode-coding-string str coding-system)
 135                 str))
 136             (defun mm-decode-coding-region (start end coding-system)
 137               (if coding-system
 138                   (decode-coding-region start end coding-system)))
 139             (defun mm-encode-coding-region (start end coding-system)
 140               (if coding-system
 141                   (encode-coding-region start end coding-system))))
 142         (defun mm-decode-coding-string (str coding-system) str)
 143         (defun mm-encode-coding-string (str coding-system) str)
 144         (defalias 'mm-decode-coding-region 'ignore)
 145         (defalias 'mm-encode-coding-region 'ignore))
 146     (defalias 'mm-decode-coding-string 'decode-coding-string)
 147     (defalias 'mm-encode-coding-string 'encode-coding-string)
 148     (defalias 'mm-decode-coding-region 'decode-coding-region)
 149     (defalias 'mm-encode-coding-region 'encode-coding-region)))
 150
 151 (defalias 'mm-string-to-multibyte
 152   (cond
 153    ((featurep 'xemacs)
 154     'identity)
 155    ((fboundp 'string-to-multibyte)
 156     'string-to-multibyte)
 157    (t
 158     (lambda (string)
 159       "Return a multibyte string with the same individual chars as string."
 160       (mapconcat
 161        (lambda (ch) (mm-string-as-multibyte (char-to-string ch)))
 162        string "")))))
 163
 164 (eval-and-compile
 165   (defalias 'mm-char-or-char-int-p
 166     (cond
 167      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
 168      ((fboundp 'char-valid-p) 'char-valid-p)
 169      (t 'identity))))
 170
 171 ;; Fixme:  This seems always to be used to read a MIME charset, so it
 172 ;; should be re-named and fixed (in Emacs) to offer completion only on
 173 ;; proper charset names (base coding systems which have a
 174 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 175 ;; test with
 176 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 177 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 178 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 179 (eval-and-compile
 180   (defalias 'mm-read-coding-system
 181     (cond
 182      ((fboundp 'read-coding-system)
 183       (if (and (featurep 'xemacs)
 184                (<= (string-to-number emacs-version) 21.1))
 185           (lambda (prompt &optional default-coding-system)
 186             (read-coding-system prompt))
 187         'read-coding-system))
 188      (t (lambda (prompt &optional default-coding-system)
 189           "Prompt the user for a coding system."
 190           (completing-read
 191            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 192                           mm-mime-mule-charset-alist)))))))
 193
 194 (defvar mm-coding-system-list nil)
 195 (defun mm-get-coding-system-list ()
 196   "Get the coding system list."
 197   (or mm-coding-system-list
 198       (setq mm-coding-system-list (mm-coding-system-list))))
 199
 200 (defun mm-coding-system-p (cs)
 201   "Return non-nil if CS is a symbol naming a coding system.
 202 In XEmacs, also return non-nil if CS is a coding system object.
 203 If CS is available, return CS itself in Emacs, and return a coding
 204 system object in XEmacs."
 205   (if (fboundp 'find-coding-system)
 206       (and cs (find-coding-system cs))
 207     (if (fboundp 'coding-system-p)
 208         (when (coding-system-p cs)
 209           cs)
 210       ;; no-MULE XEmacs:
 211       (car (memq cs (mm-get-coding-system-list))))))
 212
 213 (defun mm-codepage-setup (number &optional alias)
 214   "Create a coding system cpNUMBER.
 215 The coding system is created using `codepage-setup'.  If ALIAS is
 216 non-nil, an alias is created and added to
 217 `mm-charset-synonym-alist'.  If ALIAS is a string, it's used as
 218 the alias.  Else windows-NUMBER is used."
 219   (interactive
 220    (let ((completion-ignore-case t)
 221          (candidates (if (fboundp 'cp-supported-codepages)
 222                          (cp-supported-codepages)
 223                        ;; Removed in Emacs 23 (unicode), so signal an error:
 224                        (error "`codepage-setup' not present in this Emacs version."))))
 225      (list (completing-read "Setup DOS Codepage: (default 437) " candidates
 226                             nil t nil nil "437"))))
 227   (when alias
 228     (setq alias (if (stringp alias)
 229                     (intern alias)
 230                   (intern (format "windows-%s" number)))))
 231   (let* ((cp (intern (format "cp%s" number))))
 232     (unless (mm-coding-system-p cp)
 233       (if (fboundp 'codepage-setup)     ; silence compiler
 234           (codepage-setup number)
 235         (error "`codepage-setup' not present in this Emacs version.")))
 236     (when (and alias
 237                ;; Don't add alias if setup of cp failed.
 238                (mm-coding-system-p cp))
 239       (add-to-list 'mm-charset-synonym-alist (cons alias cp)))))
 240
 241 (defvar mm-charset-synonym-alist
 242   `(
 243     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 244     ,@(unless (mm-coding-system-p 'x-ctext)
 245         '((x-ctext . ctext)))
 246     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_ in 8
 247     ;; positions!
 248     ,@(unless (mm-coding-system-p 'iso-8859-15)
 249         '((iso-8859-15 . iso-8859-1)))
 250     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 251     ,@(unless (mm-coding-system-p 'big5-hkscs)
 252         '((big5-hkscs . big5)))
 253     ;; A Microsoft misunderstanding.
 254     ,@(when (and (not (mm-coding-system-p 'unicode))
 255                  (mm-coding-system-p 'utf-16-le))
 256         '((unicode . utf-16-le)))
 257     ;; A Microsoft misunderstanding.
 258     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 259         (if (mm-coding-system-p 'cp949)
 260             '((ks_c_5601-1987 . cp949))
 261           '((ks_c_5601-1987 . euc-kr))))
 262     ;; Windows-31J is Windows Codepage 932.
 263     ,@(when (and (not (mm-coding-system-p 'windows-31j))
 264                  (mm-coding-system-p 'cp932))
 265         '((windows-31j . cp932)))
 266     ;; Charset name: GBK, Charset aliases: CP936, MS936, windows-936
 267     ;; http://www.iana.org/assignments/charset-reg/GBK
 268     ;; Emacs 22.1 has cp936, but not gbk, so we alias it:
 269     ,@(when (and (not (mm-coding-system-p 'gbk))
 270                  (mm-coding-system-p 'cp936))
 271         '((gbk . cp936)))
 272     ;; ISO8859-1 is a bogus name for ISO-8859-1
 273     ,@(when (and (not (mm-coding-system-p 'iso8859-1))
 274                  (mm-coding-system-p 'iso-8859-1))
 275         '((iso8859-1 . iso-8859-1)))
 276     )
 277   "A mapping from unknown or invalid charset names to the real charset names.
 278
 279 See `mm-codepage-iso-8859-list' and `mm-codepage-ibm-list'.")
 280
 281 (defcustom mm-codepage-iso-8859-list
 282   (list 1250 ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 283         ;; Outlook users in Czech republic.  Use this to allow reading of
 284         ;; their e-mails.  cp1250 should be defined by M-x codepage-setup
 285         ;; (Emacs 21).
 286         '(1252 . 1) ;; Windows-1252 is a superset of iso-8859-1 (West
 287                     ;; Europe).  See also `gnus-article-dumbquotes-map'.
 288         '(1254 . 9) ;; Windows-1254 is a superset of iso-8859-9 (Turkish).
 289         '(1255 . 8));; Windows-1255 is a superset of iso-8859-8 (Hebrew).
 290   "A list of Windows codepage numbers and iso-8859 charset numbers.
 291
 292 If an element is a number corresponding to a supported windows
 293 codepage, appropriate entries to `mm-charset-synonym-alist' are
 294 added by `mm-setup-codepage-iso-8859'.  An element may also be a
 295 cons cell where the car is a codepage number and the cdr is the
 296 corresponding number of an iso-8859 charset."
 297   :type '(list (set :inline t
 298                     (const 1250 :tag "Central and East European")
 299                     (const (1252 . 1) :tag "West European")
 300                     (const (1254 . 9) :tag "Turkish")
 301                     (const (1255 . 8) :tag "Hebrew"))
 302                (repeat :inline t
 303                        :tag "Other options"
 304                        (choice
 305                         (integer :tag "Windows codepage number")
 306                         (cons (integer :tag "Windows codepage number")
 307                               (integer :tag "iso-8859 charset  number")))))
 308   :version "22.1" ;; Gnus 5.10.9
 309   :group 'mime)
 310
 311 (defcustom mm-codepage-ibm-list
 312   (list 437 ;; (US etc.)
 313         860 ;; (Portugal)
 314         861 ;; (Iceland)
 315         862 ;; (Israel)
 316         863 ;; (Canadian French)
 317         865 ;; (Nordic)
 318         852 ;;
 319         850 ;; (Latin 1)
 320         855 ;; (Cyrillic)
 321         866 ;; (Cyrillic - Russian)
 322         857 ;; (Turkish)
 323         864 ;; (Arabic)
 324         869 ;; (Greek)
 325         874);; (Thai)
 326   ;; In Emacs 23 (unicode), cp... and ibm... are aliases.
 327   ;; Cf. http://thread.gmane.org/v9lkng5nwy.fsf@marauder.physik.uni-ulm.de
 328   "List of IBM codepage numbers.
 329
 330 The codepage mappings slighly differ between IBM and other vendors.
 331 See \"ftp://ftp.unicode.org/Public/MAPPINGS/VENDORS/IBM/README.TXT\".
 332
 333 If an element is a number corresponding to a supported windows
 334 codepage, appropriate entries to `mm-charset-synonym-alist' are
 335 added by `mm-setup-codepage-ibm'."
 336   :type '(list (set :inline t
 337                     (const 437 :tag "US etc.")
 338                     (const 860 :tag "Portugal")
 339                     (const 861 :tag "Iceland")
 340                     (const 862 :tag "Israel")
 341                     (const 863 :tag "Canadian French")
 342                     (const 865 :tag "Nordic")
 343                     (const 852)
 344                     (const 850 :tag "Latin 1")
 345                     (const 855 :tag "Cyrillic")
 346                     (const 866 :tag "Cyrillic - Russian")
 347                     (const 857 :tag "Turkish")
 348                     (const 864 :tag "Arabic")
 349                     (const 869 :tag "Greek")
 350                     (const 874 :tag "Thai"))
 351                (repeat :inline t
 352                        :tag "Other options"
 353                        (integer :tag "Codepage number")))
 354   :version "22.1" ;; Gnus 5.10.9
 355   :group 'mime)
 356
 357 (defun mm-setup-codepage-iso-8859 (&optional list)
 358   "Add appropriate entries to `mm-charset-synonym-alist'.
 359 Unless LIST is given, `mm-codepage-iso-8859-list' is used."
 360   (unless list
 361     (setq list mm-codepage-iso-8859-list))
 362   (dolist (i list)
 363     (let (cp windows iso)
 364       (if (consp i)
 365           (setq cp (intern (format "cp%d" (car i)))
 366                 windows (intern (format "windows-%d" (car i)))
 367                 iso (intern (format "iso-8859-%d" (cdr i))))
 368         (setq cp (intern (format "cp%d" i))
 369               windows (intern (format "windows-%d" i))))
 370       (unless (mm-coding-system-p windows)
 371         (if (mm-coding-system-p cp)
 372             (add-to-list 'mm-charset-synonym-alist (cons windows cp))
 373           (add-to-list 'mm-charset-synonym-alist (cons windows iso)))))))
 374
 375 (defun mm-setup-codepage-ibm (&optional list)
 376   "Add appropriate entries to `mm-charset-synonym-alist'.
 377 Unless LIST is given, `mm-codepage-ibm-list' is used."
 378   (unless list
 379     (setq list mm-codepage-ibm-list))
 380   (dolist (number list)
 381     (let ((ibm (intern (format "ibm%d" number)))
 382           (cp  (intern (format "cp%d" number))))
 383       (when (and (not (mm-coding-system-p ibm))
 384                  (mm-coding-system-p cp))
 385         (add-to-list 'mm-charset-synonym-alist (cons ibm cp))))))
 386
 387 ;; Initialize:
 388 (mm-setup-codepage-iso-8859)
 389 (mm-setup-codepage-ibm)
 390
 391 ;; Note: this has to be defined before `mm-charset-to-coding-system'.
 392 (defcustom mm-charset-eval-alist
 393   (if (featurep 'xemacs)
 394       nil ;; I don't know what would be useful for XEmacs.
 395     '(;; Emacs 21 offers 1250 1251 1253 1257.  Emacs 22 provides autoloads for
 396       ;; 1250-1258 (i.e. `mm-codepage-setup' does nothing).
 397       (windows-1250 . (mm-codepage-setup 1250 t))
 398       (windows-1251 . (mm-codepage-setup 1251 t))
 399       (windows-1253 . (mm-codepage-setup 1253 t))
 400       (windows-1257 . (mm-codepage-setup 1257 t))))
 401   "An alist of (CHARSET . FORM) pairs.
 402 If an article is encoded in an unknown CHARSET, FORM is
 403 evaluated.  This allows to load additional libraries providing
 404 charsets on demand.  If supported by your Emacs version, you
 405 could use `autoload-coding-system' here."
 406   :version "22.1" ;; Gnus 5.10.9
 407   :type '(list (set :inline t
 408                     (const (windows-1250 . (mm-codepage-setup 1250 t)))
 409                     (const (windows-1251 . (mm-codepage-setup 1251 t)))
 410                     (const (windows-1253 . (mm-codepage-setup 1253 t)))
 411                     (const (windows-1257 . (mm-codepage-setup 1257 t)))
 412                     (const (cp850 . (mm-codepage-setup 850 nil))))
 413                (repeat :inline t
 414                        :tag "Other options"
 415                        (cons (symbol :tag "charset")
 416                              (symbol :tag "form"))))
 417   :group 'mime)
 418 (put 'mm-charset-eval-alist 'risky-local-variable t)
 419
 420 ;; Note: this function has to be defined before `mm-charset-override-alist'
 421 ;; since it will use this function in order to determine its default value
 422 ;; when loading mm-util.elc.
 423 (defun mm-charset-to-coding-system (charset &optional lbt
 424                                             allow-override silent)
 425   "Return coding-system corresponding to CHARSET.
 426 CHARSET is a symbol naming a MIME charset.
 427 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 428 used as the line break code type of the coding system.
 429
 430 If ALLOW-OVERRIDE is given, use `mm-charset-override-alist' to
 431 map undesired charset names to their replacement.  This should
 432 only be used for decoding, not for encoding.
 433
 434 A non-nil value of SILENT means don't issue a warning even if CHARSET
 435 is not available."
 436   ;; OVERRIDE is used (only) in `mm-decode-body' and `mm-decode-string'.
 437   (when (stringp charset)
 438     (setq charset (intern (downcase charset))))
 439   (when lbt
 440     (setq charset (intern (format "%s-%s" charset lbt))))
 441   (cond
 442    ((null charset)
 443     charset)
 444    ;; Running in a non-MULE environment.
 445    ((or (null (mm-get-coding-system-list))
 446         (not (fboundp 'coding-system-get)))
 447     charset)
 448    ;; Check override list quite early.  Should only used for decoding, not for
 449    ;; encoding!
 450    ((and allow-override
 451          (let ((cs (cdr (assq charset mm-charset-override-alist))))
 452            (and cs (mm-coding-system-p cs) cs))))
 453    ;; ascii
 454    ((eq charset 'us-ascii)
 455     'ascii)
 456    ;; Check to see whether we can handle this charset.  (This depends
 457    ;; on there being some coding system matching each `mime-charset'
 458    ;; property defined, as there should be.)
 459    ((and (mm-coding-system-p charset)
 460 ;;; Doing this would potentially weed out incorrect charsets.
 461 ;;;      charset
 462 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 463          )
 464     charset)
 465    ;; Eval expressions from `mm-charset-eval-alist'
 466    ((let* ((el (assq charset mm-charset-eval-alist))
 467            (cs (car el))
 468            (form (cdr el)))
 469       (and cs
 470            form
 471            (prog2
 472                ;; Avoid errors...
 473                (condition-case nil (eval form) (error nil))
 474                ;; (message "Failed to eval `%s'" form))
 475                (mm-coding-system-p cs)
 476              (message "Added charset `%s' via `mm-charset-eval-alist'" cs))
 477            cs)))
 478    ;; Translate invalid charsets.
 479    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 480       (and cs
 481            (mm-coding-system-p cs)
 482            ;; (message
 483            ;;  "Using synonym `%s' from `mm-charset-synonym-alist' for `%s'"
 484            ;;  cs charset)
 485            cs)))
 486    ;; Last resort: search the coding system list for entries which
 487    ;; have the right mime-charset in case the canonical name isn't
 488    ;; defined (though it should be).
 489    ((let (cs)
 490       ;; mm-get-coding-system-list returns a list of cs without lbt.
 491       ;; Do we need -lbt?
 492       (dolist (c (mm-get-coding-system-list))
 493         (if (and (null cs)
 494                  (eq charset (or (coding-system-get c :mime-charset)
 495                                  (coding-system-get c 'mime-charset))))
 496             (setq cs c)))
 497       (unless (or silent cs)
 498         ;; Warn the user about unknown charset:
 499         (if (fboundp 'gnus-message)
 500             (gnus-message 7 "Unknown charset: %s" charset)
 501           (message "Unknown charset: %s" charset)))
 502       cs))))
 503
 504 ;; Note: `mm-charset-to-coding-system' has to be defined before this.
 505 (defcustom mm-charset-override-alist
 506   ;; Note: pairs that cannot be used in the Emacs version currently running
 507   ;; will be removed.
 508   '((gb2312 . gbk)
 509     (iso-8859-1 . windows-1252)
 510     (iso-8859-8 . windows-1255)
 511     (iso-8859-9 . windows-1254))
 512   "A mapping from undesired charset names to their replacement.
 513
 514 You may add pairs like (iso-8859-1 . windows-1252) here,
 515 i.e. treat iso-8859-1 as windows-1252.  windows-1252 is a
 516 superset of iso-8859-1."
 517   :type
 518   '(list
 519     :convert-widget
 520     (lambda (widget)
 521       (let ((defaults
 522               (delq nil
 523                     (mapcar (lambda (pair)
 524                               (if (mm-charset-to-coding-system (cdr pair)
 525                                                                nil nil t)
 526                                   pair))
 527                             '((gb2312 . gbk)
 528                               (iso-8859-1 . windows-1252)
 529                               (iso-8859-8 . windows-1255)
 530                               (iso-8859-9 . windows-1254)
 531                               (undecided  . windows-1252)))))
 532             (val (copy-sequence (default-value 'mm-charset-override-alist)))
 533             pair rest)
 534         (while val
 535           (push (if (and (prog1
 536                              (setq pair (assq (caar val) defaults))
 537                            (setq defaults (delq pair defaults)))
 538                          (equal (car val) pair))
 539                     `(const ,pair)
 540                   `(cons :format "%v"
 541                          (const :format "(%v" ,(caar val))
 542                          (symbol :size 3 :format " . %v)\n" ,(cdar val))))
 543                 rest)
 544           (setq val (cdr val)))
 545         (while defaults
 546           (push `(const ,(pop defaults)) rest))
 547         (widget-convert
 548          'list
 549          `(set :inline t :format "%v" ,@(nreverse rest))
 550          `(repeat :inline t :tag "Other options"
 551                   (cons :format "%v"
 552                         (symbol :size 3 :format "(%v")
 553                         (symbol :size 3 :format " . %v)\n")))))))
 554   ;; Remove pairs that cannot be used in the Emacs version currently
 555   ;; running.  Note that this section will be evaluated when loading
 556   ;; mm-util.elc.
 557   :set (lambda (symbol value)
 558          (custom-set-default
 559           symbol (delq nil
 560                        (mapcar (lambda (pair)
 561                                  (if (mm-charset-to-coding-system (cdr pair)
 562                                                                   nil nil t)
 563                                      pair))
 564                                value))))
 565   :version "22.1" ;; Gnus 5.10.9
 566   :group 'mime)
 567
 568 (defvar mm-binary-coding-system
 569   (cond
 570    ((mm-coding-system-p 'binary) 'binary)
 571    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 572    (t nil))
 573   "100% binary coding system.")
 574
 575 (defvar mm-text-coding-system
 576   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 577           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 578         (and (mm-coding-system-p 'raw-text) 'raw-text))
 579       mm-binary-coding-system)
 580   "Text-safe coding system (For removing ^M).")
 581
 582 (defvar mm-text-coding-system-for-write nil
 583   "Text coding system for write.")
 584
 585 (defvar mm-auto-save-coding-system
 586   (cond
 587    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 588     (if (memq system-type '(windows-nt ms-dos ms-windows))
 589         (if (mm-coding-system-p 'utf-8-emacs-dos)
 590             'utf-8-emacs-dos mm-binary-coding-system)
 591       'utf-8-emacs))
 592    ((mm-coding-system-p 'emacs-mule)
 593     (if (memq system-type '(windows-nt ms-dos ms-windows))
 594         (if (mm-coding-system-p 'emacs-mule-dos)
 595             'emacs-mule-dos mm-binary-coding-system)
 596       'emacs-mule))
 597    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 598    (t mm-binary-coding-system))
 599   "Coding system of auto save file.")
 600
 601 (defvar mm-universal-coding-system mm-auto-save-coding-system
 602   "The universal coding system.")
 603
 604 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 605 ;; should only matter with XEmacs, though.
 606 (defvar mm-mime-mule-charset-alist
 607   `((us-ascii ascii)
 608     (iso-8859-1 latin-iso8859-1)
 609     (iso-8859-2 latin-iso8859-2)
 610     (iso-8859-3 latin-iso8859-3)
 611     (iso-8859-4 latin-iso8859-4)
 612     (iso-8859-5 cyrillic-iso8859-5)
 613     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 614     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 615     ;; charset is koi8-r, not iso-8859-5.
 616     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 617     (iso-8859-6 arabic-iso8859-6)
 618     (iso-8859-7 greek-iso8859-7)
 619     (iso-8859-8 hebrew-iso8859-8)
 620     (iso-8859-9 latin-iso8859-9)
 621     (iso-8859-14 latin-iso8859-14)
 622     (iso-8859-15 latin-iso8859-15)
 623     (viscii vietnamese-viscii-lower)
 624     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 625     (euc-kr korean-ksc5601)
 626     (gb2312 chinese-gb2312)
 627     (gbk chinese-gbk)
 628     (gb18030 gb18030-2-byte
 629              gb18030-4-byte-bmp gb18030-4-byte-smp
 630              gb18030-4-byte-ext-1 gb18030-4-byte-ext-2)
 631     (big5 chinese-big5-1 chinese-big5-2)
 632     (tibetan tibetan)
 633     (thai-tis620 thai-tis620)
 634     (windows-1251 cyrillic-iso8859-5)
 635     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 636     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 637                    latin-jisx0201 japanese-jisx0208-1978
 638                    chinese-gb2312 japanese-jisx0208
 639                    korean-ksc5601 japanese-jisx0212)
 640     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 641                     latin-jisx0201 japanese-jisx0208-1978
 642                     chinese-gb2312 japanese-jisx0208
 643                     korean-ksc5601 japanese-jisx0212
 644                     chinese-cns11643-1 chinese-cns11643-2)
 645     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 646                     cyrillic-iso8859-5 greek-iso8859-7
 647                     latin-jisx0201 japanese-jisx0208-1978
 648                     chinese-gb2312 japanese-jisx0208
 649                     korean-ksc5601 japanese-jisx0212
 650                     chinese-cns11643-1 chinese-cns11643-2
 651                     chinese-cns11643-3 chinese-cns11643-4
 652                     chinese-cns11643-5 chinese-cns11643-6
 653                     chinese-cns11643-7)
 654     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 655                    japanese-jisx0213-1 japanese-jisx0213-2)
 656     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 657     ,(cond ((fboundp 'unicode-precedence-list)
 658             (cons 'utf-8 (delq 'ascii (mapcar 'charset-name
 659                                               (unicode-precedence-list)))))
 660            ((or (not (fboundp 'charsetp)) ;; non-Mule case
 661                 (charsetp 'unicode-a)
 662                 (not (mm-coding-system-p 'mule-utf-8)))
 663             '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e))
 664            (t ;; If we have utf-8 we're in Mule 5+.
 665             (append '(utf-8)
 666                     (delete 'ascii
 667                             (coding-system-get 'mule-utf-8 'safe-charsets))))))
 668   "Alist of MIME-charset/MULE-charsets.")
 669
 670 (defun mm-enrich-utf-8-by-mule-ucs ()
 671   "Make the `utf-8' MIME charset usable by the Mule-UCS package.
 672 This function will run when the `un-define' module is loaded under
 673 XEmacs, and fill the `utf-8' entry in `mm-mime-mule-charset-alist'
 674 with Mule charsets.  It is completely useless for Emacs."
 675   (when (boundp 'unicode-basic-translation-charset-order-list)
 676     (condition-case nil
 677         (let ((val (delq
 678                     'ascii
 679                     (copy-sequence
 680                      (symbol-value
 681                       'unicode-basic-translation-charset-order-list))))
 682               (elem (assq 'utf-8 mm-mime-mule-charset-alist)))
 683           (if elem
 684               (setcdr elem val)
 685             (setq mm-mime-mule-charset-alist
 686                   (nconc mm-mime-mule-charset-alist
 687                          (list (cons 'utf-8 val))))))
 688       (error))))
 689
 690 ;; Correct by construction, but should be unnecessary for Emacs:
 691 (if (featurep 'xemacs)
 692     (eval-after-load "un-define" '(mm-enrich-utf-8-by-mule-ucs))
 693   (when (and (fboundp 'coding-system-list)
 694              (fboundp 'sort-coding-systems))
 695     (let ((css (sort-coding-systems (coding-system-list 'base-only)))
 696           cs mime mule alist)
 697       (while css
 698         (setq cs (pop css)
 699               mime (or (coding-system-get cs :mime-charset); Emacs 23 (unicode)
 700                        (coding-system-get cs 'mime-charset)))
 701         (when (and mime
 702                    (not (eq t (setq mule
 703                                     (coding-system-get cs 'safe-charsets))))
 704                    (not (assq mime alist)))
 705           (push (cons mime (delq 'ascii mule)) alist)))
 706       (setq mm-mime-mule-charset-alist (nreverse alist)))))
 707
 708 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 709   "A list of special charsets.
 710 Valid elements include:
 711 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 712 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 713 )
 714
 715 (defvar mm-iso-8859-15-compatible
 716   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 717     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 718   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 719
 720 (defvar mm-iso-8859-x-to-15-table
 721   (and (fboundp 'coding-system-p)
 722        (mm-coding-system-p 'iso-8859-15)
 723        (mapcar
 724         (lambda (cs)
 725           (if (mm-coding-system-p (car cs))
 726               (let ((c (string-to-char
 727                         (decode-coding-string "\341" (car cs)))))
 728                 (cons (char-charset c)
 729                       (cons
 730                        (- (string-to-char
 731                            (decode-coding-string "\341" 'iso-8859-15)) c)
 732                        (string-to-list (decode-coding-string (car (cdr cs))
 733                                                              (car cs))))))
 734             '(gnus-charset 0)))
 735         mm-iso-8859-15-compatible))
 736   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 737
 738 (defcustom mm-coding-system-priorities
 739   (if (boundp 'current-language-environment)
 740       (let ((lang (symbol-value 'current-language-environment)))
 741         (cond ((string= lang "Japanese")
 742                ;; Japanese users prefer iso-2022-jp to euc-japan or
 743                ;; shift_jis, however iso-8859-1 should be used when
 744                ;; there are only ASCII text and Latin-1 characters.
 745                '(iso-8859-1 iso-2022-jp iso-2022-jp-2 shift_jis utf-8)))))
 746   "Preferred coding systems for encoding outgoing messages.
 747
 748 More than one suitable coding system may be found for some text.
 749 By default, the coding system with the highest priority is used
 750 to encode outgoing messages (see `sort-coding-systems').  If this
 751 variable is set, it overrides the default priority."
 752   :version "21.2"
 753   :type '(repeat (symbol :tag "Coding system"))
 754   :group 'mime)
 755
 756 ;; ??
 757 (defvar mm-use-find-coding-systems-region
 758   (fboundp 'find-coding-systems-region)
 759   "Use `find-coding-systems-region' to find proper coding systems.
 760
 761 Setting it to nil is useful on Emacsen supporting Unicode if sending
 762 mail with multiple parts is preferred to sending a Unicode one.")
 763
 764 ;;; Internal variables:
 765
 766 ;;; Functions:
 767
 768 (defun mm-mule-charset-to-mime-charset (charset)
 769   "Return the MIME charset corresponding to the given Mule CHARSET."
 770   (if (and (fboundp 'find-coding-systems-for-charsets)
 771            (fboundp 'sort-coding-systems))
 772       (let ((css (sort (sort-coding-systems
 773                         (find-coding-systems-for-charsets (list charset)))
 774                        'mm-sort-coding-systems-predicate))
 775             cs mime)
 776         (while (and (not mime)
 777                     css)
 778           (when (setq cs (pop css))
 779             (setq mime (or (coding-system-get cs :mime-charset)
 780                            (coding-system-get cs 'mime-charset)))))
 781         mime)
 782     (let ((alist (mapcar (lambda (cs)
 783                            (assq cs mm-mime-mule-charset-alist))
 784                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 785                                'mm-sort-coding-systems-predicate)))
 786           out)
 787       (while alist
 788         (when (memq charset (cdar alist))
 789           (setq out (caar alist)
 790                 alist nil))
 791         (pop alist))
 792       out)))
 793
 794 (eval-and-compile
 795   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 796                              (boundp 'default-enable-multibyte-characters)
 797                              default-enable-multibyte-characters
 798                              (fboundp 'set-buffer-multibyte))
 799     "True in Emacs with Mule.")
 800
 801   (if mm-emacs-mule
 802       (defun mm-enable-multibyte ()
 803         "Set the multibyte flag of the current buffer.
 804 Only do this if the default value of `enable-multibyte-characters' is
 805 non-nil.  This is a no-op in XEmacs."
 806         (set-buffer-multibyte 'to))
 807     (defalias 'mm-enable-multibyte 'ignore))
 808
 809   (if mm-emacs-mule
 810       (defun mm-disable-multibyte ()
 811         "Unset the multibyte flag of in the current buffer.
 812 This is a no-op in XEmacs."
 813         (set-buffer-multibyte nil))
 814     (defalias 'mm-disable-multibyte 'ignore)))
 815
 816 (defun mm-preferred-coding-system (charset)
 817   ;; A typo in some Emacs versions.
 818   (or (get-charset-property charset 'preferred-coding-system)
 819       (get-charset-property charset 'prefered-coding-system)))
 820
 821 ;; Mule charsets shouldn't be used.
 822 (defsubst mm-guess-charset ()
 823   "Guess Mule charset from the language environment."
 824   (or
 825    mail-parse-mule-charset ;; cached mule-charset
 826    (progn
 827      (setq mail-parse-mule-charset
 828            (and (boundp 'current-language-environment)
 829                 (car (last
 830                       (assq 'charset
 831                             (assoc current-language-environment
 832                                    language-info-alist))))))
 833      (if (or (not mail-parse-mule-charset)
 834              (eq mail-parse-mule-charset 'ascii))
 835          (setq mail-parse-mule-charset
 836                (or (car (last (assq mail-parse-charset
 837                                     mm-mime-mule-charset-alist)))
 838                    ;; default
 839                    'latin-iso8859-1)))
 840      mail-parse-mule-charset)))
 841
 842 (defun mm-charset-after (&optional pos)
 843   "Return charset of a character in current buffer at position POS.
 844 If POS is nil, it defauls to the current point.
 845 If POS is out of range, the value is nil.
 846 If the charset is `composition', return the actual one."
 847   (let ((char (char-after pos)) charset)
 848     (if (< (mm-char-int char) 128)
 849         (setq charset 'ascii)
 850       ;; charset-after is fake in some Emacsen.
 851       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 852       (if (eq charset 'composition)     ; Mule 4
 853           (let ((p (or pos (point))))
 854             (cadr (find-charset-region p (1+ p))))
 855         (if (and charset (not (memq charset '(ascii eight-bit-control
 856                                                     eight-bit-graphic))))
 857             charset
 858           (mm-guess-charset))))))
 859
 860 (defun mm-mime-charset (charset)
 861   "Return the MIME charset corresponding to the given Mule CHARSET."
 862   (if (eq charset 'unknown)
 863       (error "The message contains non-printable characters, please use attachment"))
 864   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 865       ;; This exists in Emacs 20.
 866       (or
 867        (and (mm-preferred-coding-system charset)
 868             (or (coding-system-get
 869                  (mm-preferred-coding-system charset) :mime-charset)
 870                 (coding-system-get
 871                  (mm-preferred-coding-system charset) 'mime-charset)))
 872        (and (eq charset 'ascii)
 873             'us-ascii)
 874        (mm-preferred-coding-system charset)
 875        (mm-mule-charset-to-mime-charset charset))
 876     ;; This is for XEmacs.
 877     (mm-mule-charset-to-mime-charset charset)))
 878
 879 (if (fboundp 'delete-dups)
 880     (defalias 'mm-delete-duplicates 'delete-dups)
 881   (defun mm-delete-duplicates (list)
 882     "Destructively remove `equal' duplicates from LIST.
 883 Store the result in LIST and return it.  LIST must be a proper list.
 884 Of several `equal' occurrences of an element in LIST, the first
 885 one is kept.
 886
 887 This is a compatibility function for Emacsen without `delete-dups'."
 888     ;; Code from `subr.el' in Emacs 22:
 889     (let ((tail list))
 890       (while tail
 891         (setcdr tail (delete (car tail) (cdr tail)))
 892         (setq tail (cdr tail))))
 893     list))
 894
 895 ;; Fixme:  This is used in places when it should be testing the
 896 ;; default multibyteness.  See mm-default-multibyte-p.
 897 (eval-and-compile
 898   (if (and (not (featurep 'xemacs))
 899            (boundp 'enable-multibyte-characters))
 900       (defun mm-multibyte-p ()
 901         "Non-nil if multibyte is enabled in the current buffer."
 902         enable-multibyte-characters)
 903     (defun mm-multibyte-p () (featurep 'mule))))
 904
 905 (defun mm-default-multibyte-p ()
 906   "Return non-nil if the session is multibyte.
 907 This affects whether coding conversion should be attempted generally."
 908   (if (featurep 'mule)
 909       (if (boundp 'default-enable-multibyte-characters)
 910           default-enable-multibyte-characters
 911         t)))
 912
 913 (defun mm-iso-8859-x-to-15-region (&optional b e)
 914   (if (fboundp 'char-charset)
 915       (let (charset item c inconvertible)
 916         (save-restriction
 917           (if e (narrow-to-region b e))
 918           (goto-char (point-min))
 919           (skip-chars-forward "\0-\177")
 920           (while (not (eobp))
 921             (cond
 922              ((not (setq item (assq (char-charset (setq c (char-after)))
 923                                     mm-iso-8859-x-to-15-table)))
 924               (forward-char))
 925              ((memq c (cdr (cdr item)))
 926               (setq inconvertible t)
 927               (forward-char))
 928              (t
 929               (insert-before-markers (prog1 (+ c (car (cdr item)))
 930                                        (delete-char 1)))))
 931             (skip-chars-forward "\0-\177")))
 932         (not inconvertible))))
 933
 934 (defun mm-sort-coding-systems-predicate (a b)
 935   (let ((priorities
 936          (mapcar (lambda (cs)
 937                    ;; Note: invalid entries are dropped silently
 938                    (and (setq cs (mm-coding-system-p cs))
 939                         (coding-system-base cs)))
 940                  mm-coding-system-priorities)))
 941     (and (setq a (mm-coding-system-p a))
 942          (if (setq b (mm-coding-system-p b))
 943              (> (length (memq (coding-system-base a) priorities))
 944                 (length (memq (coding-system-base b) priorities)))
 945            t))))
 946
 947 (eval-when-compile
 948   (autoload 'latin-unity-massage-name "latin-unity")
 949   (autoload 'latin-unity-maybe-remap "latin-unity")
 950   (autoload 'latin-unity-representations-feasible-region "latin-unity")
 951   (autoload 'latin-unity-representations-present-region "latin-unity"))
 952
 953 (defvar latin-unity-coding-systems)
 954 (defvar latin-unity-ucs-list)
 955
 956 (defun mm-xemacs-find-mime-charset-1 (begin end)
 957   "Determine which MIME charset to use to send region as message.
 958 This uses the XEmacs-specific latin-unity package to better handle the
 959 case where identical characters from diverse ISO-8859-? character sets
 960 can be encoded using a single one of the corresponding coding systems.
 961
 962 It treats `mm-coding-system-priorities' as the list of preferred
 963 coding systems; a useful example setting for this list in Western
 964 Europe would be '(iso-8859-1 iso-8859-15 utf-8), which would default
 965 to the very standard Latin 1 coding system, and only move to coding
 966 systems that are less supported as is necessary to encode the
 967 characters that exist in the buffer.
 968
 969 Latin Unity doesn't know about those non-ASCII Roman characters that
 970 are available in various East Asian character sets.  As such, its
 971 behavior if you have a JIS 0212 LATIN SMALL LETTER A WITH ACUTE in a
 972 buffer and it can otherwise be encoded as Latin 1, won't be ideal.
 973 But this is very much a corner case, so don't worry about it."
 974   (let ((systems mm-coding-system-priorities) csets psets curset)
 975
 976     ;; Load the Latin Unity library, if available.
 977     (when (and (not (featurep 'latin-unity)) (locate-library "latin-unity"))
 978       (require 'latin-unity))
 979
 980     ;; Now, can we use it?
 981     (if (featurep 'latin-unity)
 982         (progn
 983           (setq csets (latin-unity-representations-feasible-region begin end)
 984                 psets (latin-unity-representations-present-region begin end))
 985
 986           (catch 'done
 987
 988             ;; Pass back the first coding system in the preferred list
 989             ;; that can encode the whole region.
 990             (dolist (curset systems)
 991               (setq curset (latin-unity-massage-name 'buffer-default curset))
 992
 993               ;; If the coding system is a universal coding system, then
 994               ;; it can certainly encode all the characters in the region.
 995               (if (memq curset latin-unity-ucs-list)
 996                   (throw 'done (list curset)))
 997
 998               ;; If a coding system isn't universal, and isn't in
 999               ;; the list that latin unity knows about, we can't
1000               ;; decide whether to use it here. Leave that until later
1001               ;; in `mm-find-mime-charset-region' function, whence we
1002               ;; have been called.
1003               (unless (memq curset latin-unity-coding-systems)
1004                 (throw 'done nil))
1005
1006               ;; Right, we know about this coding system, and it may
1007               ;; conceivably be able to encode all the characters in
1008               ;; the region.
1009               (if (latin-unity-maybe-remap begin end curset csets psets t)
1010                   (throw 'done (list curset))))
1011
1012             ;; Can't encode using anything from the
1013             ;; `mm-coding-system-priorities' list.
1014             ;; Leave `mm-find-mime-charset' to do most of the work.
1015             nil))
1016
1017       ;; Right, latin unity isn't available; let `mm-find-charset-region'
1018       ;; take its default action, which equally applies to GNU Emacs.
1019       nil)))
1020
1021 (defmacro mm-xemacs-find-mime-charset (begin end)
1022   (when (featurep 'xemacs)
1023     `(and (featurep 'mule) (mm-xemacs-find-mime-charset-1 ,begin ,end))))
1024
1025 (declare-function mm-delete-duplicates "mm-util" (list))
1026
1027 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
1028   "Return the MIME charsets needed to encode the region between B and E.
1029 nil means ASCII, a single-element list represents an appropriate MIME
1030 charset, and a longer list means no appropriate charset."
1031   (let (charsets)
1032     ;; The return possibilities of this function are a mess...
1033     (or (and (mm-multibyte-p)
1034              mm-use-find-coding-systems-region
1035              ;; Find the mime-charset of the most preferred coding
1036              ;; system that has one.
1037              (let ((systems (find-coding-systems-region b e)))
1038                (when mm-coding-system-priorities
1039                  (setq systems
1040                        (sort systems 'mm-sort-coding-systems-predicate)))
1041                (setq systems (delq 'compound-text systems))
1042                (unless (equal systems '(undecided))
1043                  (while systems
1044                    (let* ((head (pop systems))
1045                           (cs (or (coding-system-get head :mime-charset)
1046                                   (coding-system-get head 'mime-charset))))
1047                      ;; The mime-charset (`x-ctext') of
1048                      ;; `compound-text' is not in the IANA list.  We
1049                      ;; shouldn't normally use anything here with a
1050                      ;; mime-charset having an `x-' prefix.
1051                      ;; Fixme:  Allow this to be overridden, since
1052                      ;; there is existing use of x-ctext.
1053                      ;; Also people apparently need the coding system
1054                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
1055                      ;; mime-charset, though it's not valid).
1056                      (if (and cs
1057                               (not (string-match "^[Xx]-" (symbol-name cs)))
1058                               ;; UTF-16 of any variety is invalid for
1059                               ;; text parts and, unfortunately, has
1060                               ;; mime-charset defined both in Mule-UCS
1061                               ;; and versions of Emacs.  (The name
1062                               ;; might be `mule-utf-16...'  or
1063                               ;; `utf-16...'.)
1064                               (not (string-match "utf-16" (symbol-name cs))))
1065                          (setq systems nil
1066                                charsets (list cs))))))
1067                charsets))
1068         ;; If we're XEmacs, and some coding system is appropriate,
1069         ;; mm-xemacs-find-mime-charset will return an appropriate list.
1070         ;; Otherwise, we'll get nil, and the next setq will get invoked.
1071         (setq charsets (mm-xemacs-find-mime-charset b e))
1072
1073         ;; Fixme: won't work for unibyte Emacs 23:
1074
1075         ;; We're not multibyte, or a single coding system won't cover it.
1076         (setq charsets
1077               (mm-delete-duplicates
1078                (mapcar 'mm-mime-charset
1079                        (delq 'ascii
1080                              (mm-find-charset-region b e))))))
1081     (if (and (> (length charsets) 1)
1082              (memq 'iso-8859-15 charsets)
1083              (memq 'iso-8859-15 hack-charsets)
1084              (save-excursion (mm-iso-8859-x-to-15-region b e)))
1085         (dolist (x mm-iso-8859-15-compatible)
1086           (setq charsets (delq (car x) charsets))))
1087     (if (and (memq 'iso-2022-jp-2 charsets)
1088              (memq 'iso-2022-jp-2 hack-charsets))
1089         (setq charsets (delq 'iso-2022-jp charsets)))
1090     ;; Attempt to reduce the number of charsets if utf-8 is available.
1091     (if (and (featurep 'xemacs)
1092              (> (length charsets) 1)
1093              (mm-coding-system-p 'utf-8))
1094         (let ((mm-coding-system-priorities
1095                (cons 'utf-8 mm-coding-system-priorities)))
1096           (setq charsets
1097                 (mm-delete-duplicates
1098                  (mapcar 'mm-mime-charset
1099                          (delq 'ascii
1100                                (mm-find-charset-region b e)))))))
1101     charsets))
1102
1103 (defmacro mm-with-unibyte-buffer (&rest forms)
1104   "Create a temporary buffer, and evaluate FORMS there like `progn'.
1105 Use unibyte mode for this."
1106   `(with-temp-buffer
1107      (mm-disable-multibyte)
1108      ,@forms))
1109 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
1110 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
1111
1112 (defmacro mm-with-multibyte-buffer (&rest forms)
1113   "Create a temporary buffer, and evaluate FORMS there like `progn'.
1114 Use multibyte mode for this."
1115   `(with-temp-buffer
1116      (mm-enable-multibyte)
1117      ,@forms))
1118 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
1119 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
1120
1121 (defmacro mm-with-unibyte-current-buffer (&rest forms)
1122   "Evaluate FORMS with current buffer temporarily made unibyte.
1123 Also bind `default-enable-multibyte-characters' to nil.
1124 Equivalent to `progn' in XEmacs
1125
1126 NOTE: Use this macro with caution in multibyte buffers (it is not
1127 worth using this macro in unibyte buffers of course).  Use of
1128 `(set-buffer-multibyte t)', which is run finally, is generally
1129 harmful since it is likely to modify existing data in the buffer.
1130 For instance, it converts \"\\300\\255\" into \"\\255\" in
1131 Emacs 23 (unicode)."
1132   (let ((multibyte (make-symbol "multibyte"))
1133         (buffer (make-symbol "buffer")))
1134     `(if mm-emacs-mule
1135          (let ((,multibyte enable-multibyte-characters)
1136                (,buffer (current-buffer)))
1137            (unwind-protect
1138                (let (default-enable-multibyte-characters)
1139                  (set-buffer-multibyte nil)
1140                  ,@forms)
1141              (set-buffer ,buffer)
1142              (set-buffer-multibyte ,multibyte)))
1143        (let (default-enable-multibyte-characters)
1144          ,@forms))))
1145 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
1146 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
1147
1148 (defun mm-find-charset-region (b e)
1149   "Return a list of Emacs charsets in the region B to E."
1150   (cond
1151    ((and (mm-multibyte-p)
1152          (fboundp 'find-charset-region))
1153     ;; Remove composition since the base charsets have been included.
1154     ;; Remove eight-bit-*, treat them as ascii.
1155     (let ((css (find-charset-region b e)))
1156       (dolist (cs
1157                '(composition eight-bit-control eight-bit-graphic control-1)
1158                css)
1159         (setq css (delq cs css)))))
1160    (t
1161     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
1162     (save-excursion
1163       (save-restriction
1164         (narrow-to-region b e)
1165         (goto-char (point-min))
1166         (skip-chars-forward "\0-\177")
1167         (if (eobp)
1168             '(ascii)
1169           (let (charset)
1170             (setq charset
1171                   (and (boundp 'current-language-environment)
1172                        (car (last (assq 'charset
1173                                         (assoc current-language-environment
1174                                                language-info-alist))))))
1175             (if (eq charset 'ascii) (setq charset nil))
1176             (or charset
1177                 (setq charset
1178                       (car (last (assq mail-parse-charset
1179                                        mm-mime-mule-charset-alist)))))
1180             (list 'ascii (or charset 'latin-iso8859-1)))))))))
1181
1182 (defun mm-auto-mode-alist ()
1183   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
1184   (let ((alist auto-mode-alist)
1185         out)
1186     (while alist
1187       (when (listp (cdar alist))
1188         (push (car alist) out))
1189       (pop alist))
1190     (nreverse out)))
1191
1192 (defvar mm-inhibit-file-name-handlers
1193   '(jka-compr-handler image-file-handler epa-file-handler)
1194   "A list of handlers doing (un)compression (etc) thingies.")
1195
1196 (defun mm-insert-file-contents (filename &optional visit beg end replace
1197                                          inhibit)
1198   "Like `insert-file-contents', but only reads in the file.
1199 A buffer may be modified in several ways after reading into the buffer due
1200 to advanced Emacs features, such as file-name-handlers, format decoding,
1201 `find-file-hooks', etc.
1202 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
1203   This function ensures that none of these modifications will take place."
1204   (let* ((format-alist nil)
1205          (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
1206          (default-major-mode 'fundamental-mode)
1207          (enable-local-variables nil)
1208          (after-insert-file-functions nil)
1209          (enable-local-eval nil)
1210          (inhibit-file-name-operation (if inhibit
1211                                           'insert-file-contents
1212                                         inhibit-file-name-operation))
1213          (inhibit-file-name-handlers
1214           (if inhibit
1215               (append mm-inhibit-file-name-handlers
1216                       inhibit-file-name-handlers)
1217             inhibit-file-name-handlers))
1218          (ffh (if (boundp 'find-file-hook)
1219                   'find-file-hook
1220                 'find-file-hooks))
1221          (val (symbol-value ffh)))
1222     (set ffh nil)
1223     (unwind-protect
1224         (insert-file-contents filename visit beg end replace)
1225       (set ffh val))))
1226
1227 (defun mm-append-to-file (start end filename &optional codesys inhibit)
1228   "Append the contents of the region to the end of file FILENAME.
1229 When called from a function, expects three arguments,
1230 START, END and FILENAME.  START and END are buffer positions
1231 saying what text to write.
1232 Optional fourth argument specifies the coding system to use when
1233 encoding the file.
1234 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
1235   (let ((coding-system-for-write
1236          (or codesys mm-text-coding-system-for-write
1237              mm-text-coding-system))
1238         (inhibit-file-name-operation (if inhibit
1239                                          'append-to-file
1240                                        inhibit-file-name-operation))
1241         (inhibit-file-name-handlers
1242          (if inhibit
1243              (append mm-inhibit-file-name-handlers
1244                      inhibit-file-name-handlers)
1245            inhibit-file-name-handlers)))
1246     (write-region start end filename t 'no-message)
1247     (message "Appended to %s" filename)))
1248
1249 (defun mm-write-region (start end filename &optional append visit lockname
1250                               coding-system inhibit)
1251
1252   "Like `write-region'.
1253 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
1254   (let ((coding-system-for-write
1255          (or coding-system mm-text-coding-system-for-write
1256              mm-text-coding-system))
1257         (inhibit-file-name-operation (if inhibit
1258                                          'write-region
1259                                        inhibit-file-name-operation))
1260         (inhibit-file-name-handlers
1261          (if inhibit
1262              (append mm-inhibit-file-name-handlers
1263                      inhibit-file-name-handlers)
1264            inhibit-file-name-handlers)))
1265     (write-region start end filename append visit lockname)))
1266
1267 (autoload 'gmm-write-region "gmm-utils")
1268
1269 ;; It is not a MIME function, but some MIME functions use it.
1270 (if (and (fboundp 'make-temp-file)
1271          (ignore-errors
1272            (let ((def (symbol-function 'make-temp-file)))
1273              (and (byte-code-function-p def)
1274                   (setq def (if (fboundp 'compiled-function-arglist)
1275                                 ;; XEmacs
1276                                 (eval (list 'compiled-function-arglist def))
1277                               (aref def 0)))
1278                   (>= (length def) 4)
1279                   (eq (nth 3 def) 'suffix)))))
1280     (defalias 'mm-make-temp-file 'make-temp-file)
1281   ;; Stolen (and modified for XEmacs) from Emacs 22.
1282   (defun mm-make-temp-file (prefix &optional dir-flag suffix)
1283     "Create a temporary file.
1284 The returned file name (created by appending some random characters at the end
1285 of PREFIX, and expanding against `temporary-file-directory' if necessary),
1286 is guaranteed to point to a newly created empty file.
1287 You can then use `write-region' to write new data into the file.
1288
1289 If DIR-FLAG is non-nil, create a new empty directory instead of a file.
1290
1291 If SUFFIX is non-nil, add that at the end of the file name."
1292     (let ((umask (default-file-modes))
1293           file)
1294       (unwind-protect
1295           (progn
1296             ;; Create temp files with strict access rights.  It's easy to
1297             ;; loosen them later, whereas it's impossible to close the
1298             ;; time-window of loose permissions otherwise.
1299             (set-default-file-modes 448)
1300             (while (condition-case err
1301                        (progn
1302                          (setq file
1303                                (make-temp-name
1304                                 (expand-file-name
1305                                  prefix
1306                                  (if (fboundp 'temp-directory)
1307                                      ;; XEmacs
1308                                      (temp-directory)
1309                                    temporary-file-directory))))
1310                          (if suffix
1311                              (setq file (concat file suffix)))
1312                          (if dir-flag
1313                              (make-directory file)
1314                            ;; NOTE: This is unsafe if Emacs 20
1315                            ;; users and XEmacs users don't use
1316                            ;; a secure temp directory.
1317                            (gmm-write-region "" nil file nil 'silent
1318                                              nil 'excl))
1319                          nil)
1320                      (file-already-exists t)
1321                      ;; The XEmacs version of `make-directory' issues
1322                      ;; `file-error'.
1323                      (file-error (or (and (featurep 'xemacs)
1324                                           (file-exists-p file))
1325                                      (signal (car err) (cdr err)))))
1326               ;; the file was somehow created by someone else between
1327               ;; `make-temp-name' and `write-region', let's try again.
1328               nil)
1329             file)
1330         ;; Reset the umask.
1331         (set-default-file-modes umask)))))
1332
1333 (defun mm-image-load-path (&optional package)
1334   (let (dir result)
1335     (dolist (path load-path (nreverse result))
1336       (when (and path
1337                  (file-directory-p
1338                   (setq dir (concat (file-name-directory
1339                                      (directory-file-name path))
1340                                     "etc/images/" (or package "gnus/")))))
1341         (push dir result))
1342       (push path result))))
1343
1344 ;; Fixme: This doesn't look useful where it's used.
1345 (if (fboundp 'detect-coding-region)
1346     (defun mm-detect-coding-region (start end)
1347       "Like `detect-coding-region' except returning the best one."
1348       (let ((coding-systems
1349              (detect-coding-region start end)))
1350         (or (car-safe coding-systems)
1351             coding-systems)))
1352   (defun mm-detect-coding-region (start end)
1353     (let ((point (point)))
1354       (goto-char start)
1355       (skip-chars-forward "\0-\177" end)
1356       (prog1
1357           (if (eq (point) end) 'ascii (mm-guess-charset))
1358         (goto-char point)))))
1359
1360 (declare-function mm-detect-coding-region "mm-util" (start end))
1361
1362 (if (fboundp 'coding-system-get)
1363     (defun mm-detect-mime-charset-region (start end)
1364       "Detect MIME charset of the text in the region between START and END."
1365       (let ((cs (mm-detect-coding-region start end)))
1366         (or (coding-system-get cs :mime-charset)
1367             (coding-system-get cs 'mime-charset))))
1368   (defun mm-detect-mime-charset-region (start end)
1369     "Detect MIME charset of the text in the region between START and END."
1370     (let ((cs (mm-detect-coding-region start end)))
1371       cs)))
1372
1373 (eval-when-compile
1374   (unless (fboundp 'coding-system-to-mime-charset)
1375     (defalias 'coding-system-to-mime-charset 'ignore)))
1376
1377 (defun mm-coding-system-to-mime-charset (coding-system)
1378   "Return the MIME charset corresponding to CODING-SYSTEM.
1379 To make this function work with XEmacs, the APEL package is required."
1380   (when coding-system
1381     (or (and (fboundp 'coding-system-get)
1382              (or (coding-system-get coding-system :mime-charset)
1383                  (coding-system-get coding-system 'mime-charset)))
1384         (and (featurep 'xemacs)
1385              (or (and (fboundp 'coding-system-to-mime-charset)
1386                       (not (eq (symbol-function 'coding-system-to-mime-charset)
1387                                'ignore)))
1388                  (and (condition-case nil
1389                           (require 'mcharset)
1390                         (error nil))
1391                       (fboundp 'coding-system-to-mime-charset)))
1392              (coding-system-to-mime-charset coding-system)))))
1393
1394 (eval-when-compile
1395   (require 'jka-compr))
1396
1397 (defun mm-decompress-buffer (filename &optional inplace force)
1398   "Decompress buffer's contents, depending on jka-compr.
1399 Only when FORCE is t or `auto-compression-mode' is enabled and FILENAME
1400 agrees with `jka-compr-compression-info-list', decompression is done.
1401 Signal an error if FORCE is neither nil nor t and compressed data are
1402 not decompressed because `auto-compression-mode' is disabled.
1403 If INPLACE is nil, return decompressed data or nil without modifying
1404 the buffer.  Otherwise, replace the buffer's contents with the
1405 decompressed data.  The buffer's multibyteness must be turned off."
1406   (when (and filename
1407              (if force
1408                  (prog1 t (require 'jka-compr))
1409                (and (fboundp 'jka-compr-installed-p)
1410                     (jka-compr-installed-p))))
1411     (let ((info (jka-compr-get-compression-info filename)))
1412       (when info
1413         (unless (or (memq force (list nil t))
1414                     (jka-compr-installed-p))
1415           (error ""))
1416         (let ((prog (jka-compr-info-uncompress-program info))
1417               (args (jka-compr-info-uncompress-args info))
1418               (msg (format "%s %s..."
1419                            (jka-compr-info-uncompress-message info)
1420                            filename))
1421               (err-file (jka-compr-make-temp-name))
1422               (cur (current-buffer))
1423               (coding-system-for-read mm-binary-coding-system)
1424               (coding-system-for-write mm-binary-coding-system)
1425               retval err-msg)
1426           (message "%s" msg)
1427           (mm-with-unibyte-buffer
1428             (insert-buffer-substring cur)
1429             (condition-case err
1430                 (progn
1431                   (unless (memq (apply 'call-process-region
1432                                        (point-min) (point-max)
1433                                        prog t (list t err-file) nil args)
1434                                 jka-compr-acceptable-retval-list)
1435                     (erase-buffer)
1436                     (insert (mapconcat
1437                              'identity
1438                              (delete "" (split-string
1439                                          (prog2
1440                                              (insert-file-contents err-file)
1441                                              (buffer-string)
1442                                            (erase-buffer))))
1443                              " ")
1444                             "\n")
1445                     (setq err-msg
1446                           (format "Error while executing \"%s %s < %s\""
1447                                   prog (mapconcat 'identity args " ")
1448                                   filename)))
1449                   (setq retval (buffer-string)))
1450               (error
1451                (setq err-msg (error-message-string err)))))
1452           (when (file-exists-p err-file)
1453             (ignore-errors (jka-compr-delete-temp-file err-file)))
1454           (when inplace
1455             (unless err-msg
1456               (delete-region (point-min) (point-max))
1457               (insert retval))
1458             (setq retval nil))
1459           (message "%s" (or err-msg (concat msg "done")))
1460           retval)))))
1461
1462 (eval-when-compile
1463   (unless (fboundp 'coding-system-name)
1464     (defalias 'coding-system-name 'ignore))
1465   (unless (fboundp 'find-file-coding-system-for-read-from-filename)
1466     (defalias 'find-file-coding-system-for-read-from-filename 'ignore))
1467   (unless (fboundp 'find-operation-coding-system)
1468     (defalias 'find-operation-coding-system 'ignore)))
1469
1470 (defun mm-find-buffer-file-coding-system (&optional filename)
1471   "Find coding system used to decode the contents of the current buffer.
1472 This function looks for the coding system magic cookie or examines the
1473 coding system specified by `file-coding-system-alist' being associated
1474 with FILENAME which defaults to `buffer-file-name'.  Data compressed by
1475 gzip, bzip2, etc. are allowed."
1476   (unless filename
1477     (setq filename buffer-file-name))
1478   (save-excursion
1479     (let ((decomp (unless ;; No worth to examine charset of tar files.
1480                       (and filename
1481                            (string-match
1482                             "\\.\\(?:tar\\.[^.]+\\|tbz\\|tgz\\)\\'"
1483                             filename))
1484                     (mm-decompress-buffer filename nil t))))
1485       (when decomp
1486         (set-buffer (let (default-enable-multibyte-characters)
1487                       (generate-new-buffer " *temp*")))
1488         (insert decomp)
1489         (setq filename (file-name-sans-extension filename)))
1490       (goto-char (point-min))
1491       (prog1
1492           (cond
1493            ((boundp 'set-auto-coding-function) ;; Emacs
1494             (if filename
1495                 (or (funcall (symbol-value 'set-auto-coding-function)
1496                              filename (- (point-max) (point-min)))
1497                     (car (find-operation-coding-system 'insert-file-contents
1498                                                        filename)))
1499               (let (auto-coding-alist)
1500                 (condition-case nil
1501                     (funcall (symbol-value 'set-auto-coding-function)
1502                              nil (- (point-max) (point-min)))
1503                   (error nil)))))
1504            ((and (featurep 'xemacs) (featurep 'file-coding)) ;; XEmacs
1505             (let ((case-fold-search t)
1506                   (end (point-at-eol))
1507                   codesys start)
1508               (or
1509                (and (re-search-forward "-\\*-+[\t ]*" end t)
1510                     (progn
1511                       (setq start (match-end 0))
1512                       (re-search-forward "[\t ]*-+\\*-" end t))
1513                     (progn
1514                       (setq end (match-beginning 0))
1515                       (goto-char start)
1516                       (or (looking-at "coding:[\t ]*\\([^\t ;]+\\)")
1517                           (re-search-forward
1518                            "[\t ;]+coding:[\t ]*\\([^\t ;]+\\)"
1519                            end t)))
1520                     (find-coding-system (setq codesys
1521                                               (intern (match-string 1))))
1522                     codesys)
1523                (and (re-search-forward "^[\t ]*;+[\t ]*Local[\t ]+Variables:"
1524                                        nil t)
1525                     (progn
1526                       (setq start (match-end 0))
1527                       (re-search-forward "^[\t ]*;+[\t ]*End:" nil t))
1528                     (progn
1529                       (setq end (match-beginning 0))
1530                       (goto-char start)
1531                       (re-search-forward
1532                        "^[\t ]*;+[\t ]*coding:[\t ]*\\([^\t\n\r ]+\\)"
1533                        end t))
1534                     (find-coding-system (setq codesys
1535                                               (intern (match-string 1))))
1536                     codesys)
1537                (and (progn
1538                       (goto-char (point-min))
1539                       (setq case-fold-search nil)
1540                       (re-search-forward "^;;;coding system: "
1541                                          ;;(+ (point-min) 3000) t))
1542                                          nil t))
1543                     (looking-at "[^\t\n\r ]+")
1544                     (find-coding-system
1545                      (setq codesys (intern (match-string 0))))
1546                     codesys)
1547                (and filename
1548                     (setq codesys
1549                           (find-file-coding-system-for-read-from-filename
1550                            filename))
1551                     (coding-system-name (coding-system-base codesys)))))))
1552         (when decomp
1553           (kill-buffer (current-buffer)))))))
1554
1555 (provide 'mm-util)
1556
1557 ;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
1558 ;;; mm-util.el ends here