cgit.sxemacs.org Git - gnus/blob - lisp/mm-encode.el

   1 ;;; mm-encode.el --- Functions for encoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-parse)
  30 (require 'mailcap)
  31 (eval-and-compile
  32   (autoload 'mm-body-7-or-8 "mm-bodies")
  33   (autoload 'mm-long-lines-p "mm-bodies"))
  34
  35 (defcustom mm-content-transfer-encoding-defaults
  36   '(("text/x-patch" 8bit)
  37     ("text/.*" qp-or-base64)
  38     ("message/rfc822" 8bit)
  39     ("application/emacs-lisp" 8bit)
  40     ("application/x-emacs-lisp" 8bit)
  41     ("application/x-patch" 8bit)
  42     (".*" base64))
  43   "Alist of regexps that match MIME types and their encodings.
  44 If the encoding is `qp-or-base64', then either quoted-printable
  45 or base64 will be used, depending on what is more efficient."
  46   :type '(repeat (list (regexp :tag "MIME type")
  47                        (choice :tag "encoding"
  48                                (const 7bit)
  49                                (const 8bit)
  50                                (const qp-or-base64)
  51                                (const quoted-printable)
  52                                (const base64))))
  53   :group 'mime)
  54
  55 (defvar mm-use-ultra-safe-encoding nil
  56   "If non-nil, use encodings aimed at Procrustean bed survival.
  57
  58 This means that textual parts are encoded as quoted-printable if they
  59 contain lines longer than 76 characters or starting with \"From \" in
  60 the body.  Non-7bit encodings (8bit, binary) are generally disallowed.
  61 This is to reduce the probability that a broken MTA or MDA changes the
  62 message.
  63
  64 This variable should never be set directly, but bound before a call to
  65 `mml-generate-mime' or similar functions.")
  66
  67 (defun mm-insert-rfc822-headers (charset encoding)
  68   "Insert text/plain headers with CHARSET and ENCODING."
  69   (insert "MIME-Version: 1.0\n")
  70   (insert "Content-Type: text/plain; charset="
  71           (mail-quote-string (downcase (symbol-name charset))) "\n")
  72   (insert "Content-Transfer-Encoding: "
  73           (downcase (symbol-name encoding)) "\n"))
  74
  75 (defun mm-insert-multipart-headers ()
  76   "Insert multipart/mixed headers."
  77   (let ((boundary "=-=-="))
  78     (insert "MIME-Version: 1.0\n")
  79     (insert "Content-Type: multipart/mixed; boundary=\"" boundary "\"\n")
  80     boundary))
  81
  82 (defun mm-default-file-encoding (file)
  83   "Return a default encoding for FILE."
  84   (if (not (string-match "\\.[^.]+$" file))
  85       "application/octet-stream"
  86     (mailcap-extension-to-mime (match-string 0 file))))
  87
  88 (defun mm-safer-encoding (encoding)
  89   "Return an encoding similar to ENCODING but safer than it."
  90   (cond
  91    ((memq encoding '(7bit 8bit quoted-printable)) 'quoted-printable)
  92    ;; The remaining encodings are binary and base64 (and perhaps some
  93    ;; non-standard ones), which are both turned into base64.
  94    (t 'base64)))
  95
  96 (defun mm-encode-content-transfer-encoding (encoding &optional type)
  97   "Encode the current buffer with ENCODING for MIME type TYPE.
  98 ENCODING can be: nil (do nothing); one of `quoted-printable', `base64';
  99 `7bit', `8bit' or `binary' (all do nothing); a function to do the encoding."
 100   (cond
 101    ((eq encoding 'quoted-printable)
 102     ;; This used to try to make a multibyte buffer unibyte.  That's
 103     ;; completely wrong, since you'd get QP-encoded emacs-mule.  If
 104     ;; this gets run on multibyte text it's an error that needs
 105     ;; fixing, and the encoding function will signal an error.
 106     ;; Likewise base64 below.
 107     (quoted-printable-encode-region (point-min) (point-max) t))
 108    ((eq encoding 'base64)
 109     (when (equal type "text/plain")
 110       (goto-char (point-min))
 111       (while (search-forward "\n" nil t)
 112         (replace-match "\r\n" t t)))
 113     (base64-encode-region (point-min) (point-max)))
 114    ((memq encoding '(7bit 8bit binary))
 115     ;; Do nothing.
 116     )
 117    ((null encoding)
 118     ;; Do nothing.
 119     )
 120    ;; Fixme: Ignoring errors here looks bogus.
 121    ((functionp encoding)
 122     (ignore-errors (funcall encoding (point-min) (point-max))))
 123    (t
 124     (error "Unknown encoding %s" encoding))))
 125
 126 (defun mm-encode-buffer (type)
 127   "Encode the buffer which contains data of MIME type TYPE.
 128 TYPE is a string or a list of the components.
 129 The encoding used is returned."
 130   (let* ((mime-type (if (stringp type) type (car type)))
 131          (encoding
 132           (or (and (listp type)
 133                    (cadr (assq 'encoding type)))
 134               (mm-content-transfer-encoding mime-type)))
 135          (bits (mm-body-7-or-8)))
 136     ;; We force buffers that are 7bit to be unencoded, no matter
 137     ;; what the preferred encoding is.
 138     ;; Only if the buffers don't contain lone lines.
 139     (when (and (eq bits '7bit) (not (mm-long-lines-p 76)))
 140       (setq encoding bits))
 141     (mm-encode-content-transfer-encoding encoding mime-type)
 142     encoding))
 143
 144 (defun mm-insert-headers (type encoding &optional file)
 145   "Insert headers for TYPE."
 146   (insert "Content-Type: " type)
 147   (when file
 148     (insert ";\n\tname=\"" (file-name-nondirectory file) "\""))
 149   (insert "\n")
 150   (insert (format "Content-Transfer-Encoding: %s\n" encoding))
 151   (insert "Content-Disposition: inline")
 152   (when file
 153     (insert ";\n\tfilename=\"" (file-name-nondirectory file) "\""))
 154   (insert "\n")
 155   (insert "\n"))
 156
 157 (defun mm-content-transfer-encoding (type)
 158   "Return a CTE suitable for TYPE to encode the current buffer."
 159   (let ((rules mm-content-transfer-encoding-defaults))
 160     (catch 'found
 161       (while rules
 162         (when (string-match (caar rules) type)
 163           (throw 'found
 164                  (let ((encoding
 165                         (if (eq (cadr (car rules)) 'qp-or-base64)
 166                             (mm-qp-or-base64)
 167                           (cadr (car rules)))))
 168                    (if mm-use-ultra-safe-encoding
 169                        (mm-safer-encoding encoding)
 170                      encoding))))
 171         (pop rules)))))
 172
 173 (defun mm-qp-or-base64 ()
 174   "Return the type with which to encode the buffer.
 175 This is either `base64' or `quoted-printable'."
 176   (if (equal mm-use-ultra-safe-encoding '(sign . "pgp"))
 177       ;; perhaps not always accurate?
 178       'quoted-printable
 179     (save-excursion
 180       (let ((limit (min (point-max) (+ 2000 (point-min))))
 181             (n8bit 0))
 182         (goto-char (point-min))
 183         (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 184         (while (< (point) limit)
 185           (incf n8bit)
 186           (forward-char 1)
 187           (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 188         (if (or (< (* 6 n8bit) (- limit (point-min)))
 189                 ;; Don't base64, say, a short line with a single
 190                 ;; non-ASCII char when splitting parts by charset.
 191                 (= n8bit 1))
 192             'quoted-printable
 193           'base64)))))
 194
 195 (provide 'mm-encode)
 196
 197 ;;; mm-encode.el ends here