cgit.sxemacs.org Git - gnus/blob - lisp/mm-encode.el

   1 ;;; mm-encode.el --- Functions for encoding MIME things
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29
  30 (defvar mm-content-transfer-encoding-defaults
  31   '(("text/.*" quoted-printable)
  32     ("message/rfc822" quoted-printable)
  33     ("application/emacs-lisp" 8bit)
  34     ("application/x-patch" 8bit)
  35     (".*" base64))
  36   "Alist of regexps that match MIME types and their encodings.")
  37
  38 (defun mm-insert-rfc822-headers (charset encoding)
  39   "Insert text/plain headers with CHARSET and ENCODING."
  40   (insert "MIME-Version: 1.0\n")
  41   (insert "Content-Type: text/plain; charset="
  42           (mail-quote-string (downcase (symbol-name charset))) "\n")
  43   (insert "Content-Transfer-Encoding: "
  44           (downcase (symbol-name encoding)) "\n"))
  45
  46 (defun mm-insert-multipart-headers ()
  47   "Insert multipart/mixed headers."
  48   (let ((boundary "=-=-="))
  49     (insert "MIME-Version: 1.0\n")
  50     (insert (format "Content-Type: multipart/mixed; boundary=\"%s\"\n"
  51                     boundary))
  52     boundary))
  53
  54 (defun mm-default-file-encoding (file)
  55   "Return a default encoding for FILE."
  56   (if (not (string-match "\\.[^.]+$" file))
  57       "application/octet-stream"
  58     (mailcap-extension-to-mime (match-string 0 file))))
  59
  60 (defun mm-encode-content-transfer-encoding (encoding &optional type)
  61   (cond
  62    ((eq encoding 'quoted-printable)
  63     (quoted-printable-encode-region (point-min) (point-max)))
  64    ((eq encoding 'base64)
  65     (when (equal type "text/plain")
  66       (goto-char (point-min))
  67       (while (search-forward "\n" nil t)
  68         (replace-match "\r\n" t t)))
  69     (condition-case error
  70         (base64-encode-region (point-min) (point-max))
  71       (error
  72        (message "Error while decoding: %s" error)
  73        nil)))
  74    ((memq encoding '(7bit 8bit binary))
  75     )
  76    ((null encoding)
  77     )
  78    ;;((eq encoding 'x-uuencode)
  79    ;; (condition-case ()
  80    ;;   (uudecode-encode-region (point-min) (point-max))
  81    ;;   (error nil)))
  82    ((functionp encoding)
  83     (condition-case ()
  84         (funcall encoding (point-min) (point-max))
  85       (error nil)))
  86    (t
  87     (message "Unknown encoding %s; defaulting to 8bit" encoding))))
  88
  89 (defun mm-encode-buffer (type)
  90   "Encode the buffer which contains data of TYPE.
  91 The encoding used is returned."
  92   (let* ((mime-type (if (stringp type) type (car type)))
  93          (encoding
  94           (or (and (listp type)
  95                    (cadr (assq 'encoding type)))
  96               (mm-content-transfer-encoding mime-type))))
  97     (mm-encode-content-transfer-encoding encoding mime-type)
  98     encoding))
  99
 100 (defun mm-insert-headers (type encoding &optional file)
 101   "Insert headers for TYPE."
 102   (insert "Content-Type: " type)
 103   (when file
 104     (insert ";\n\tname=\"" (file-name-nondirectory file) "\""))
 105   (insert "\n")
 106   (insert (format "Content-Transfer-Encoding: %s\n" encoding))
 107   (insert "Content-Disposition: inline")
 108   (when file
 109     (insert ";\n\tfilename=\"" (file-name-nondirectory file) "\""))
 110   (insert "\n")
 111   (insert "\n"))
 112
 113 (defun mm-content-transfer-encoding (type)
 114   "Return a CTE suitable for TYPE."
 115   (let ((rules mm-content-transfer-encoding-defaults))
 116     (catch 'found
 117       (while rules
 118         (when (string-match (caar rules) type)
 119           (throw 'found (cadar rules)))
 120         (pop rules)))))
 121
 122 (provide 'mm-encode)
 123
 124 ;;; mm-encode.el ends here