cgit.sxemacs.org Git - gnus/blob - lisp/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-and-compile
  28   (or (fboundp  'base64-decode-region)
  29       (require 'base64))
  30   (autoload 'binhex-decode-region "binhex"))
  31
  32 (require 'mm-util)
  33 (require 'rfc2047)
  34 (require 'qp)
  35 (require 'uudecode)
  36
  37 ;; 8bit treatment gets any char except: 0x32 - 0x7f, CR, LF, TAB, BEL,
  38 ;; BS, vertical TAB, form feed, and ^_
  39 (defvar mm-8bit-char-regexp "[^\x20-\x7f\r\n\t\x7\x8\xb\xc\x1f]")
  40
  41 (defun mm-encode-body ()
  42   "Encode a body.
  43 Should be called narrowed to the body that is to be encoded.
  44 If there is more than one non-ASCII MULE charset, then list of found
  45 MULE charsets are returned.
  46 If successful, the MIME charset is returned.
  47 If no encoding was done, nil is returned."
  48   (if (not (featurep 'mule))
  49       ;; In the non-Mule case, we search for non-ASCII chars and
  50       ;; return the value of `mm-default-charset' if any are found.
  51       (save-excursion
  52         (goto-char (point-min))
  53         (if (re-search-forward "[^\x0-\x7f]" nil t)
  54             mm-default-charset
  55           ;; The logic in `mml-generate-mime-1' confirms that it's OK
  56           ;; to return nil here.
  57           nil))
  58     (save-excursion
  59       (goto-char (point-min))
  60       (let ((charsets
  61              (delq 'ascii (mm-find-charset-region (point-min) (point-max))))
  62             charset)
  63         (cond
  64          ;; No encoding.
  65          ((null charsets)
  66           nil)
  67          ;; Too many charsets.
  68          ((> (length charsets) 1)
  69           charsets)
  70          ;; We encode.
  71          (t
  72           (let ((mime-charset
  73                  (mm-mime-charset (car charsets) (point-min) (point-max)))
  74                 start)
  75             (when (or t
  76                       ;; We always decode.
  77                       (not (mm-coding-system-equal
  78                             mime-charset buffer-file-coding-system)))
  79               (while (not (eobp))
  80                 (if (eq (char-charset (char-after)) 'ascii)
  81                     (when start
  82                       (save-restriction
  83                         (narrow-to-region start (point))
  84                         (mm-encode-coding-region start (point) mime-charset)
  85                         (goto-char (point-max)))
  86                       (setq start nil))
  87                   (unless start
  88                     (setq start (point))))
  89                 (forward-char 1))
  90               (when start
  91                 (mm-encode-coding-region start (point) mime-charset)
  92                 (setq start nil)))
  93             mime-charset)))))))
  94
  95 (defun mm-body-encoding ()
  96   "Return the encoding of the current buffer."
  97   (cond
  98    ((not (featurep 'mule))
  99     (if (save-excursion
 100           (goto-char (point-min))
 101           (re-search-forward mm-8bit-char-regexp nil t))
 102         '8bit
 103       '7bit))
 104    (t
 105     ;; Mule version
 106     (if (and (null (delq 'ascii (find-charset-region (point-min) (point-max))))
 107              ;;!!!The following is necessary because the function
 108              ;;!!!above seems to return the wrong result under
 109              ;;!!!Emacs 20.3.  Sometimes.
 110              (save-excursion
 111                (goto-char (point-min))
 112                (skip-chars-forward "\0-\177")
 113                (eobp)))
 114         '7bit
 115       '8bit))))
 116
 117 ;;;
 118 ;;; Functions for decoding
 119 ;;;
 120
 121 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 122   (prog1
 123       (condition-case ()
 124           (cond
 125            ((eq encoding 'quoted-printable)
 126             (quoted-printable-decode-region (point-min) (point-max)))
 127            ((eq encoding 'base64)
 128             (base64-decode-region (point-min) (point-max)))
 129            ((memq encoding '(7bit 8bit binary))
 130             )
 131            ((null encoding)
 132             )
 133            ((eq encoding 'x-uuencode)
 134             (funcall mm-uu-decode-function (point-min) (point-max)))
 135            ((eq encoding 'x-binhex)
 136             (funcall mm-uu-binhex-decode-function (point-min) (point-max)))
 137            ((functionp encoding)
 138             (funcall encoding (point-min) (point-max)))
 139            (t
 140             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 141         (error nil))
 142     (when (and
 143            (memq encoding '(base64 x-uuencode x-binhex))
 144            (equal type "text/plain"))
 145       (goto-char (point-min))
 146       (while (search-forward "\r\n" nil t)
 147         (replace-match "\n" t t)))))
 148
 149 (defun mm-decode-body (charset &optional encoding type)
 150   "Decode the current article that has been encoded with ENCODING.
 151 The characters in CHARSET should then be decoded."
 152   (setq charset (or charset rfc2047-default-charset))
 153   (save-excursion
 154     (when encoding
 155       (mm-decode-content-transfer-encoding encoding type))
 156     (when (featurep 'mule)
 157       (let (mule-charset)
 158         (when (and charset
 159                    (setq mule-charset (mm-charset-to-coding-system charset))
 160                    ;; buffer-file-coding-system
 161                                         ;Article buffer is nil coding system
 162                                         ;in XEmacs
 163                    enable-multibyte-characters
 164                    (or (not (eq mule-charset 'ascii))
 165                        (setq mule-charset rfc2047-default-charset)))
 166           (mm-decode-coding-region (point-min) (point-max) mule-charset))))))
 167
 168 (defun mm-decode-string (string charset)
 169   "Decode STRING with CHARSET."
 170   (setq charset (or charset rfc2047-default-charset))
 171   (or
 172    (when (featurep 'mule)
 173      (let (mule-charset)
 174        (when (and charset
 175                   (setq mule-charset (mm-charset-to-coding-system charset))
 176                   enable-multibyte-characters
 177                   (or (not (eq mule-charset 'ascii))
 178                       (setq mule-charset rfc2047-default-charset)))
 179          (mm-decode-coding-string string mule-charset))))
 180    string))
 181
 182 (provide 'mm-bodies)
 183
 184 ;; mm-bodies.el ends here