cgit.sxemacs.org Git - gnus/blob - lisp/mailcap.el

   1 ;;; mailcap.el --- MIME media types configuration
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: William M. Perry <wmperry@aventail.com>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news, mail, multimedia
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Provides configuration of MIME media types from directly from Lisp
  30 ;; and via the usual mailcap mechanism (RFC 1524).  Deals with
  31 ;; mime.types similarly.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36 (require 'mail-parse)
  37 (require 'mm-util)
  38
  39 (defgroup mailcap nil
  40   "Definition of viewers for MIME types."
  41   :version "21.1"
  42   :group 'mime)
  43
  44 (defvar mailcap-parse-args-syntax-table
  45   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  46     (modify-syntax-entry ?' "\"" table)
  47     (modify-syntax-entry ?` "\"" table)
  48     (modify-syntax-entry ?{ "(" table)
  49     (modify-syntax-entry ?} ")" table)
  50     table)
  51   "A syntax table for parsing SGML attributes.")
  52
  53 (eval-and-compile
  54   (when (featurep 'xemacs)
  55     (condition-case nil
  56         (require 'lpr)
  57       (error nil))))
  58
  59 (defvar mailcap-print-command
  60   (mapconcat 'identity
  61              (cons (if (boundp 'lpr-command)
  62                        lpr-command
  63                      "lpr")
  64                    (when (boundp 'lpr-switches)
  65                      (if (stringp lpr-switches)
  66                          (list lpr-switches)
  67                        lpr-switches)))
  68              " ")
  69   "Shell command (including switches) used to print Postscript files.")
  70
  71 ;; Postpone using defcustom for this as it's so big and we essentially
  72 ;; have to have two copies of the data around then.  Perhaps just
  73 ;; customize the Lisp viewers and rely on the normal configuration
  74 ;; files for the rest?  -- fx
  75 (defvar mailcap-mime-data
  76   `(("application"
  77      ("vnd.ms-excel"
  78       (viewer . "gnumeric %s")
  79       (test   . (getenv "DISPLAY"))
  80       (type . "application/vnd.ms-excel"))
  81      ("x-x509-ca-cert"
  82       (viewer . ssl-view-site-cert)
  83       (test . (fboundp 'ssl-view-site-cert))
  84       (type . "application/x-x509-ca-cert"))
  85      ("x-x509-user-cert"
  86       (viewer . ssl-view-user-cert)
  87       (test . (fboundp 'ssl-view-user-cert))
  88       (type . "application/x-x509-user-cert"))
  89      ("octet-stream"
  90       (viewer . mailcap-save-binary-file)
  91       (non-viewer . t)
  92       (type . "application/octet-stream"))
  93      ("dvi"
  94       (viewer . "xdvi -safer %s")
  95       (test   . (eq window-system 'x))
  96       ("needsx11")
  97       (type   . "application/dvi")
  98       ("print" . "dvips -qRP %s"))
  99      ("dvi"
 100       (viewer . "dvitty %s")
 101       (test   . (not (getenv "DISPLAY")))
 102       (type   . "application/dvi")
 103       ("print" . "dvips -qRP %s"))
 104      ("emacs-lisp"
 105       (viewer . mailcap-maybe-eval)
 106       (type   . "application/emacs-lisp"))
 107      ("x-emacs-lisp"
 108       (viewer . mailcap-maybe-eval)
 109       (type   . "application/x-emacs-lisp"))
 110      ("x-tar"
 111       (viewer . mailcap-save-binary-file)
 112       (non-viewer . t)
 113       (type   . "application/x-tar"))
 114      ("x-latex"
 115       (viewer . tex-mode)
 116       (test   . (fboundp 'tex-mode))
 117       (type   . "application/x-latex"))
 118      ("x-tex"
 119       (viewer . tex-mode)
 120       (test   . (fboundp 'tex-mode))
 121       (type   . "application/x-tex"))
 122      ("latex"
 123       (viewer . tex-mode)
 124       (test   . (fboundp 'tex-mode))
 125       (type   . "application/latex"))
 126      ("tex"
 127       (viewer . tex-mode)
 128       (test   . (fboundp 'tex-mode))
 129       (type   . "application/tex"))
 130      ("texinfo"
 131       (viewer . texinfo-mode)
 132       (test   . (fboundp 'texinfo-mode))
 133       (type   . "application/tex"))
 134      ("zip"
 135       (viewer . mailcap-save-binary-file)
 136       (non-viewer . t)
 137       (type   . "application/zip")
 138       ("copiousoutput"))
 139      ("pdf"
 140       (viewer . "gv -safer %s")
 141       (type . "application/pdf")
 142       (test . window-system)
 143       ("print" . ,(concat "pdf2ps %s - | " mailcap-print-command)))
 144      ("pdf"
 145       (viewer . "gpdf %s")
 146       (type . "application/pdf")
 147       ("print" . ,(concat "pdftops %s - | " mailcap-print-command))
 148       (test . (eq window-system 'x)))
 149      ("pdf"
 150       (viewer . "xpdf %s")
 151       (type . "application/pdf")
 152       ("print" . ,(concat "pdftops %s - | " mailcap-print-command))
 153       (test . (eq window-system 'x)))
 154      ("pdf"
 155       (viewer . ,(concat "pdftotext %s -"))
 156       (type   . "application/pdf")
 157       ("print" . ,(concat "pdftops %s - | " mailcap-print-command))
 158       ("copiousoutput"))
 159      ("postscript"
 160       (viewer . "gv -safer %s")
 161       (type . "application/postscript")
 162       (test   . window-system)
 163       ("print" . ,(concat mailcap-print-command " %s"))
 164       ("needsx11"))
 165      ("postscript"
 166       (viewer . "ghostview -dSAFER %s")
 167       (type . "application/postscript")
 168       (test   . (eq window-system 'x))
 169       ("print" . ,(concat mailcap-print-command " %s"))
 170       ("needsx11"))
 171      ("postscript"
 172       (viewer . "ps2ascii %s")
 173       (type . "application/postscript")
 174       (test . (not (getenv "DISPLAY")))
 175       ("print" . ,(concat mailcap-print-command " %s"))
 176       ("copiousoutput"))
 177      ("sieve"
 178       (viewer . sieve-mode)
 179       (test   . (fboundp 'sieve-mode))
 180       (type   . "application/sieve"))
 181      ("pgp-keys"
 182       (viewer . "gpg --import --interactive --verbose")
 183       (type   . "application/pgp-keys")
 184       ("needsterminal")))
 185     ("audio"
 186      ("x-mpeg"
 187       (viewer . "maplay %s")
 188       (type   . "audio/x-mpeg"))
 189      (".*"
 190       (viewer . "showaudio")
 191       (type   . "audio/*")))
 192     ("message"
 193      ("rfc-*822"
 194       (viewer . mm-view-message)
 195       (test   . (and (featurep 'gnus)
 196                      (gnus-alive-p)))
 197       (type   . "message/rfc822"))
 198      ("rfc-*822"
 199       (viewer . vm-mode)
 200       (test   . (fboundp 'vm-mode))
 201       (type   . "message/rfc822"))
 202      ("rfc-*822"
 203       (viewer . w3-mode)
 204       (test   . (fboundp 'w3-mode))
 205       (type   . "message/rfc822"))
 206      ("rfc-*822"
 207       (viewer . view-mode)
 208       (type   . "message/rfc822")))
 209     ("image"
 210      ("x-xwd"
 211       (viewer  . "xwud -in %s")
 212       (type    . "image/x-xwd")
 213       ("compose" . "xwd -frame > %s")
 214       (test    . (eq window-system 'x))
 215       ("needsx11"))
 216      ("x11-dump"
 217       (viewer . "xwud -in %s")
 218       (type . "image/x-xwd")
 219       ("compose" . "xwd -frame > %s")
 220       (test   . (eq window-system 'x))
 221       ("needsx11"))
 222      ("windowdump"
 223       (viewer . "xwud -in %s")
 224       (type . "image/x-xwd")
 225       ("compose" . "xwd -frame > %s")
 226       (test   . (eq window-system 'x))
 227       ("needsx11"))
 228      (".*"
 229       (viewer . "display %s")
 230       (type . "image/*")
 231       (test   . (eq window-system 'x))
 232       ("needsx11"))
 233      (".*"
 234       (viewer . "ee %s")
 235       (type . "image/*")
 236       (test   . (eq window-system 'x))
 237       ("needsx11")))
 238     ("text"
 239      ("plain"
 240       (viewer  . w3-mode)
 241       (test    . (fboundp 'w3-mode))
 242       (type    . "text/plain"))
 243      ("plain"
 244       (viewer  . view-mode)
 245       (test    . (fboundp 'view-mode))
 246       (type    . "text/plain"))
 247      ("plain"
 248       (viewer  . fundamental-mode)
 249       (type    . "text/plain"))
 250      ("enriched"
 251       (viewer . enriched-decode)
 252       (test   . (fboundp 'enriched-decode))
 253       (type   . "text/enriched"))
 254      ("html"
 255       (viewer . mm-w3-prepare-buffer)
 256       (test   . (fboundp 'w3-prepare-buffer))
 257       (type   . "text/html"))
 258      ("dns"
 259       (viewer . dns-mode)
 260       (test   . (fboundp 'dns-mode))
 261       (type   . "text/dns")))
 262     ("video"
 263      ("mpeg"
 264       (viewer . "mpeg_play %s")
 265       (type   . "video/mpeg")
 266       (test   . (eq window-system 'x))
 267       ("needsx11")))
 268     ("x-world"
 269      ("x-vrml"
 270       (viewer  . "webspace -remote %s -URL %u")
 271       (type    . "x-world/x-vrml")
 272       ("description"
 273        "VRML document")))
 274     ("archive"
 275      ("tar"
 276       (viewer . tar-mode)
 277       (type . "archive/tar")
 278       (test . (fboundp 'tar-mode)))))
 279   "The mailcap structure is an assoc list of assoc lists.
 280 1st assoc list is keyed on the major content-type
 281 2nd assoc list is keyed on the minor content-type (which can be a regexp)
 282
 283 Which looks like:
 284 -----------------
 285  ((\"application\"
 286    (\"postscript\" . <info>))
 287   (\"text\"
 288    (\"plain\" . <info>)))
 289
 290 Where <info> is another assoc list of the various information
 291 related to the mailcap RFC 1524.  This is keyed on the lowercase
 292 attribute name (viewer, test, etc).  This looks like:
 293  ((viewer . VIEWERINFO)
 294   (test   . TESTINFO)
 295   (xxxx   . \"STRING\")
 296   FLAG)
 297
 298 Where VIEWERINFO specifies how the content-type is viewed.  Can be
 299 a string, in which case it is run through a shell, with
 300 appropriate parameters, or a symbol, in which case the symbol is
 301 `funcall'ed, with the buffer as an argument.
 302
 303 TESTINFO is a test for the viewer's applicability, or nil.  If nil, it
 304 means the viewer is always valid.  If it is a Lisp function, it is
 305 called with a list of items from any extra fields from the
 306 Content-Type header as argument to return a boolean value for the
 307 validity.  Otherwise, if it is a non-function Lisp symbol or list
 308 whose car is a symbol, it is `eval'led to yield the validity.  If it
 309 is a string or list of strings, it represents a shell command to run
 310 to return a true or false shell value for the validity.")
 311 (put 'mailcap-mime-data 'risky-local-variable t)
 312
 313 (defcustom mailcap-download-directory nil
 314   "*Directory to which `mailcap-save-binary-file' downloads files by default.
 315 nil means your home directory."
 316   :type '(choice (const :tag "Home directory" nil)
 317                  directory)
 318   :group 'mailcap)
 319
 320 (defvar mailcap-poor-system-types
 321   '(ms-dos ms-windows windows-nt win32 w32 mswindows)
 322   "Systems that don't have a Unix-like directory hierarchy.")
 323
 324 ;;;
 325 ;;; Utility functions
 326 ;;;
 327
 328 (defun mailcap-save-binary-file ()
 329   (goto-char (point-min))
 330   (unwind-protect
 331       (let ((file (read-file-name
 332                    "Filename to save as: "
 333                    (or mailcap-download-directory "~/")))
 334             (require-final-newline nil))
 335         (write-region (point-min) (point-max) file))
 336     (kill-buffer (current-buffer))))
 337
 338 (defvar mailcap-maybe-eval-warning
 339   "*** WARNING ***
 340
 341 This MIME part contains untrusted and possibly harmful content.
 342 If you evaluate the Emacs Lisp code contained in it, a lot of nasty
 343 things can happen.  Please examine the code very carefully before you
 344 instruct Emacs to evaluate it.  You can browse the buffer containing
 345 the code using \\[scroll-other-window].
 346
 347 If you are unsure what to do, please answer \"no\"."
 348   "Text of warning message displayed by `mailcap-maybe-eval'.
 349 Make sure that this text consists only of few text lines.  Otherwise,
 350 Gnus might fail to display all of it.")
 351
 352 (defun mailcap-maybe-eval ()
 353   "Maybe evaluate a buffer of Emacs Lisp code."
 354   (let ((lisp-buffer (current-buffer)))
 355     (goto-char (point-min))
 356     (when
 357         (save-window-excursion
 358           (delete-other-windows)
 359           (let ((buffer (get-buffer-create (generate-new-buffer-name
 360                                             "*Warning*"))))
 361             (unwind-protect
 362                 (with-current-buffer buffer
 363                   (insert (substitute-command-keys
 364                            mailcap-maybe-eval-warning))
 365                   (goto-char (point-min))
 366                   (display-buffer buffer)
 367                   (yes-or-no-p "This is potentially dangerous emacs-lisp code, evaluate it? "))
 368               (kill-buffer buffer))))
 369       (eval-buffer (current-buffer)))
 370     (when (buffer-live-p lisp-buffer)
 371       (with-current-buffer lisp-buffer
 372         (emacs-lisp-mode)))))
 373
 374
 375 ;;;
 376 ;;; The mailcap parser
 377 ;;;
 378
 379 (defun mailcap-replace-regexp (regexp to-string)
 380   ;; Quiet replace-regexp.
 381   (goto-char (point-min))
 382   (while (re-search-forward regexp nil t)
 383     (replace-match to-string t nil)))
 384
 385 (defvar mailcap-parsed-p nil)
 386
 387 (defun mailcap-parse-mailcaps (&optional path force)
 388   "Parse out all the mailcaps specified in a path string PATH.
 389 Components of PATH are separated by the `path-separator' character
 390 appropriate for this system.  If FORCE, re-parse even if already
 391 parsed.  If PATH is omitted, use the value of environment variable
 392 MAILCAPS if set; otherwise (on Unix) use the path from RFC 1524, plus
 393 /usr/local/etc/mailcap."
 394   (interactive (list nil t))
 395   (when (or (not mailcap-parsed-p)
 396             force)
 397     (cond
 398      (path nil)
 399      ((getenv "MAILCAPS") (setq path (getenv "MAILCAPS")))
 400      ((memq system-type mailcap-poor-system-types)
 401       (setq path '("~/.mailcap" "~/mail.cap" "~/etc/mail.cap")))
 402      (t (setq path
 403               ;; This is per RFC 1524, specifically
 404               ;; with /usr before /usr/local.
 405               '("~/.mailcap" "/etc/mailcap" "/usr/etc/mailcap"
 406                 "/usr/local/etc/mailcap"))))
 407     (let ((fnames (reverse
 408                    (if (stringp path)
 409                        (delete "" (split-string path path-separator))
 410                      path)))
 411           fname)
 412       (while fnames
 413         (setq fname (car fnames))
 414         (if (and (file-readable-p fname)
 415                  (file-regular-p fname))
 416             (mailcap-parse-mailcap fname))
 417         (setq fnames (cdr fnames))))
 418       (setq mailcap-parsed-p t)))
 419
 420 (defun mailcap-parse-mailcap (fname)
 421   "Parse out the mailcap file specified by FNAME."
 422   (let (major                           ; The major mime type (image/audio/etc)
 423         minor                           ; The minor mime type (gif, basic, etc)
 424         save-pos                        ; Misc saved positions used in parsing
 425         viewer                          ; How to view this mime type
 426         info                            ; Misc info about this mime type
 427         )
 428     (with-temp-buffer
 429       (insert-file-contents fname)
 430       (set-syntax-table mailcap-parse-args-syntax-table)
 431       (mailcap-replace-regexp "#.*" "") ; Remove all comments
 432       (mailcap-replace-regexp "\\\\[ \t]*\n" " ") ; And collapse spaces
 433       (mailcap-replace-regexp "\n+" "\n") ; And blank lines
 434       (goto-char (point-max))
 435       (skip-chars-backward " \t\n")
 436       (delete-region (point) (point-max))
 437       (while (not (bobp))
 438         (skip-chars-backward " \t\n")
 439         (beginning-of-line)
 440         (setq save-pos (point)
 441               info nil)
 442         (skip-chars-forward "^/; \t\n")
 443         (downcase-region save-pos (point))
 444         (setq major (buffer-substring save-pos (point)))
 445         (skip-chars-forward " \t")
 446         (setq minor "")
 447         (when (eq (char-after) ?/)
 448           (forward-char)
 449           (skip-chars-forward " \t")
 450           (setq save-pos (point))
 451           (skip-chars-forward "^; \t\n")
 452           (downcase-region save-pos (point))
 453           (setq minor
 454                 (cond
 455                  ((eq ?* (or (char-after save-pos) 0)) ".*")
 456                  ((= (point) save-pos) ".*")
 457                  (t (regexp-quote (buffer-substring save-pos (point)))))))
 458         (skip-chars-forward " \t")
 459         ;;; Got the major/minor chunks, now for the viewers/etc
 460         ;;; The first item _must_ be a viewer, according to the
 461         ;;; RFC for mailcap files (#1524)
 462         (setq viewer "")
 463         (when (eq (char-after) ?\;)
 464           (forward-char)
 465           (skip-chars-forward " \t")
 466           (setq save-pos (point))
 467           (skip-chars-forward "^;\n")
 468           ;; skip \;
 469           (while (eq (char-before) ?\\)
 470             (backward-delete-char 1)
 471             (forward-char)
 472             (skip-chars-forward "^;\n"))
 473           (if (eq (or (char-after save-pos) 0) ?')
 474               (setq viewer (progn
 475                              (narrow-to-region (1+ save-pos) (point))
 476                              (goto-char (point-min))
 477                              (prog1
 478                                  (read (current-buffer))
 479                                (goto-char (point-max))
 480                                (widen))))
 481             (setq viewer (buffer-substring save-pos (point)))))
 482         (setq save-pos (point))
 483         (end-of-line)
 484         (unless (equal viewer "")
 485           (setq info (nconc (list (cons 'viewer viewer)
 486                                   (cons 'type (concat major "/"
 487                                                       (if (string= minor ".*")
 488                                                           "*" minor))))
 489                             (mailcap-parse-mailcap-extras save-pos (point))))
 490           (mailcap-mailcap-entry-passes-test info)
 491           (mailcap-add-mailcap-entry major minor info))
 492         (beginning-of-line)))))
 493
 494 (defun mailcap-parse-mailcap-extras (st nd)
 495   "Grab all the extra stuff from a mailcap entry."
 496   (let (
 497         name                            ; From name=
 498         value                           ; its value
 499         results                         ; Assoc list of results
 500         name-pos                        ; Start of XXXX= position
 501         val-pos                         ; Start of value position
 502         done                            ; Found end of \'d ;s?
 503         )
 504     (save-restriction
 505       (narrow-to-region st nd)
 506       (goto-char (point-min))
 507       (skip-chars-forward " \n\t;")
 508       (while (not (eobp))
 509         (setq done nil)
 510         (setq name-pos (point))
 511         (skip-chars-forward "^ \n\t=;")
 512         (downcase-region name-pos (point))
 513         (setq name (buffer-substring name-pos (point)))
 514         (skip-chars-forward " \t\n")
 515         (if (not (eq (char-after (point)) ?=)) ; There is no value
 516             (setq value t)
 517           (skip-chars-forward " \t\n=")
 518           (setq val-pos (point))
 519           (if (memq (char-after val-pos) '(?\" ?'))
 520               (progn
 521                 (setq val-pos (1+ val-pos))
 522                 (condition-case nil
 523                     (progn
 524                       (forward-sexp 1)
 525                       (backward-char 1))
 526                   (error (goto-char (point-max)))))
 527             (while (not done)
 528               (skip-chars-forward "^;")
 529               (if (eq (char-after (1- (point))) ?\\ )
 530                   (progn
 531                     (subst-char-in-region (1- (point)) (point) ?\\ ? )
 532                     (skip-chars-forward ";"))
 533                 (setq done t))))
 534           (setq value (buffer-substring val-pos (point))))
 535         (setq results (cons (cons name value) results))
 536         (skip-chars-forward " \";\n\t"))
 537       results)))
 538
 539 (defun mailcap-mailcap-entry-passes-test (info)
 540   "Return non-nil iff mailcap entry INFO passes its test clause.
 541 Also return non-nil if no test clause is present."
 542   (let ((test (assq 'test info))        ; The test clause
 543         status)
 544     (setq status (and test (split-string (cdr test) " ")))
 545     (if (and (or (assoc "needsterm" info)
 546                  (assoc "needsterminal" info)
 547                  (assoc "needsx11" info))
 548              (not (getenv "DISPLAY")))
 549         (setq status nil)
 550       (cond
 551        ((and (equal (nth 0 status) "test")
 552              (equal (nth 1 status) "-n")
 553              (or (equal (nth 2 status) "$DISPLAY")
 554                  (equal (nth 2 status) "\"$DISPLAY\"")))
 555         (setq status (if (getenv "DISPLAY") t nil)))
 556        ((and (equal (nth 0 status) "test")
 557              (equal (nth 1 status) "-z")
 558              (or (equal (nth 2 status) "$DISPLAY")
 559                  (equal (nth 2 status) "\"$DISPLAY\"")))
 560         (setq status (if (getenv "DISPLAY") nil t)))
 561        (test nil)
 562        (t nil)))
 563     (and test (listp test) (setcdr test status))))
 564
 565 ;;;
 566 ;;; The action routines.
 567 ;;;
 568
 569 (defun mailcap-possible-viewers (major minor)
 570   "Return a list of possible viewers from MAJOR for minor type MINOR."
 571   (let ((exact '())
 572         (wildcard '()))
 573     (while major
 574       (cond
 575        ((equal (car (car major)) minor)
 576         (setq exact (cons (cdr (car major)) exact)))
 577        ((and minor (string-match (concat "^" (car (car major)) "$") minor))
 578         (setq wildcard (cons (cdr (car major)) wildcard))))
 579       (setq major (cdr major)))
 580     (nconc exact wildcard)))
 581
 582 (defun mailcap-unescape-mime-test (test type-info)
 583   (let (save-pos save-chr subst)
 584     (cond
 585      ((symbolp test) test)
 586      ((and (listp test) (symbolp (car test))) test)
 587      ((or (stringp test)
 588           (and (listp test) (stringp (car test))
 589                (setq test (mapconcat 'identity test " "))))
 590       (with-temp-buffer
 591         (insert test)
 592         (goto-char (point-min))
 593         (while (not (eobp))
 594           (skip-chars-forward "^%")
 595           (if (/= (- (point)
 596                      (progn (skip-chars-backward "\\\\")
 597                             (point)))
 598                   0)                    ; It is an escaped %
 599               (progn
 600                 (delete-char 1)
 601                 (skip-chars-forward "%."))
 602             (setq save-pos (point))
 603             (skip-chars-forward "%")
 604             (setq save-chr (char-after (point)))
 605             ;; Escapes:
 606             ;; %s: name of a file for the body data
 607             ;; %t: content-type
 608             ;; %{<parameter name}: value of parameter in mailcap entry
 609             ;; %n: number of sub-parts for multipart content-type
 610             ;; %F: a set of content-type/filename pairs for multiparts
 611             (cond
 612              ((null save-chr) nil)
 613              ((= save-chr ?t)
 614               (delete-region save-pos (progn (forward-char 1) (point)))
 615               (insert (or (cdr (assq 'type type-info)) "\"\"")))
 616              ((memq save-chr '(?M ?n ?F))
 617               (delete-region save-pos (progn (forward-char 1) (point)))
 618               (insert "\"\""))
 619              ((= save-chr ?{)
 620               (forward-char 1)
 621               (skip-chars-forward "^}")
 622               (downcase-region (+ 2 save-pos) (point))
 623               (setq subst (buffer-substring (+ 2 save-pos) (point)))
 624               (delete-region save-pos (1+ (point)))
 625               (insert (or (cdr (assoc subst type-info)) "\"\"")))
 626              (t nil))))
 627         (buffer-string)))
 628      (t (error "Bad value to mailcap-unescape-mime-test: %s" test)))))
 629
 630 (defvar mailcap-viewer-test-cache nil)
 631
 632 (defun mailcap-viewer-passes-test (viewer-info type-info)
 633   "Return non-nil iff viewer specified by VIEWER-INFO passes its test clause.
 634 Also return non-nil if it has no test clause.  TYPE-INFO is an argument
 635 to supply to the test."
 636   (let* ((test-info (assq 'test viewer-info))
 637          (test (cdr test-info))
 638          (otest test)
 639          (viewer (cdr (assoc 'viewer viewer-info)))
 640          (default-directory (expand-file-name "~/"))
 641          status parsed-test cache result)
 642     (if (setq cache (assoc test mailcap-viewer-test-cache))
 643         (cadr cache)
 644       (setq
 645        result
 646        (cond
 647         ((not test-info) t)             ; No test clause
 648         ((not test) nil)                ; Already failed test
 649         ((eq test t) t)                 ; Already passed test
 650         ((functionp test)               ; Lisp function as test
 651          (funcall test type-info))
 652         ((and (symbolp test)            ; Lisp variable as test
 653               (boundp test))
 654          (symbol-value test))
 655         ((and (listp test)              ; List to be eval'd
 656               (symbolp (car test)))
 657          (eval test))
 658         (t
 659          (setq test (mailcap-unescape-mime-test test type-info)
 660                test (list shell-file-name nil nil nil
 661                           shell-command-switch test)
 662                status (apply 'call-process test))
 663          (eq 0 status))))
 664       (push (list otest result) mailcap-viewer-test-cache)
 665       result)))
 666
 667 (defun mailcap-add-mailcap-entry (major minor info)
 668   (let ((old-major (assoc major mailcap-mime-data)))
 669     (if (null old-major)                ; New major area
 670         (setq mailcap-mime-data
 671               (cons (cons major (list (cons minor info)))
 672                     mailcap-mime-data))
 673       (let ((cur-minor (assoc minor old-major)))
 674         (cond
 675          ((or (null cur-minor)          ; New minor area, or
 676               (assq 'test info))        ; Has a test, insert at beginning
 677           (setcdr old-major (cons (cons minor info) (cdr old-major))))
 678          ((and (not (assq 'test info))  ; No test info, replace completely
 679                (not (assq 'test cur-minor))
 680                (equal (assq 'viewer info)  ; Keep alternative viewer
 681                       (assq 'viewer cur-minor)))
 682           (setcdr cur-minor info))
 683          (t
 684           (setcdr old-major (cons (cons minor info) (cdr old-major))))))
 685       )))
 686
 687 (defun mailcap-add (type viewer &optional test)
 688   "Add VIEWER as a handler for TYPE.
 689 If TEST is not given, it defaults to t."
 690   (let ((tl (split-string type "/")))
 691     (when (or (not (car tl))
 692               (not (cadr tl)))
 693       (error "%s is not a valid MIME type" type))
 694     (mailcap-add-mailcap-entry
 695      (car tl) (cadr tl)
 696      `((viewer . ,viewer)
 697        (test . ,(if test test t))
 698        (type . ,type)))))
 699
 700 ;;;
 701 ;;; The main whabbo
 702 ;;;
 703
 704 (defun mailcap-viewer-lessp (x y)
 705   "Return t iff viewer X is more desirable than viewer Y."
 706   (let ((x-wild (string-match "[*?]" (or (cdr-safe (assq 'type x)) "")))
 707         (y-wild (string-match "[*?]" (or (cdr-safe (assq 'type y)) "")))
 708         (x-lisp (not (stringp (or (cdr-safe (assq 'viewer x)) ""))))
 709         (y-lisp (not (stringp (or (cdr-safe (assq 'viewer y)) "")))))
 710     (cond
 711      ((and x-wild (not y-wild))
 712       nil)
 713      ((and (not x-wild) y-wild)
 714       t)
 715      ((and (not y-lisp) x-lisp)
 716       t)
 717      (t nil))))
 718
 719 (defun mailcap-mime-info (string &optional request)
 720   "Get the MIME viewer command for STRING, return nil if none found.
 721 Expects a complete content-type header line as its argument.
 722
 723 Second argument REQUEST specifies what information to return.  If it is
 724 nil or the empty string, the viewer (second field of the mailcap
 725 entry) will be returned.  If it is a string, then the mailcap field
 726 corresponding to that string will be returned (print, description,
 727 whatever).  If a number, then all the information for this specific
 728 viewer is returned.  If `all', then all possible viewers for
 729 this type is returned."
 730   (let (
 731         major                           ; Major encoding (text, etc)
 732         minor                           ; Minor encoding (html, etc)
 733         info                            ; Other info
 734         save-pos                        ; Misc. position during parse
 735         major-info                      ; (assoc major mailcap-mime-data)
 736         minor-info                      ; (assoc minor major-info)
 737         test                            ; current test proc.
 738         viewers                         ; Possible viewers
 739         passed                          ; Viewers that passed the test
 740         viewer                          ; The one and only viewer
 741         ctl)
 742     (save-excursion
 743       (setq ctl (mail-header-parse-content-type (or string "text/plain")))
 744       (setq major (split-string (car ctl) "/"))
 745       (setq minor (cadr major)
 746             major (car major))
 747       (when (setq major-info (cdr (assoc major mailcap-mime-data)))
 748         (when (setq viewers (mailcap-possible-viewers major-info minor))
 749           (setq info (mapcar (lambda (a) (cons (symbol-name (car a))
 750                                                (cdr a)))
 751                              (cdr ctl)))
 752           (while viewers
 753             (if (mailcap-viewer-passes-test (car viewers) info)
 754                 (setq passed (cons (car viewers) passed)))
 755             (setq viewers (cdr viewers)))
 756           (setq passed (sort passed 'mailcap-viewer-lessp))
 757           (setq viewer (car passed))))
 758       (when (and (stringp (cdr (assq 'viewer viewer)))
 759                  passed)
 760         (setq viewer (car passed)))
 761       (cond
 762        ((and (null viewer) (not (equal major "default")) request)
 763         (mailcap-mime-info "default" request))
 764        ((or (null request) (equal request ""))
 765         (mailcap-unescape-mime-test (cdr (assq 'viewer viewer)) info))
 766        ((stringp request)
 767         (mailcap-unescape-mime-test
 768          (cdr-safe (assoc request viewer)) info))
 769        ((eq request 'all)
 770         passed)
 771        (t
 772         ;; MUST make a copy *sigh*, else we modify mailcap-mime-data
 773         (setq viewer (copy-sequence viewer))
 774         (let ((view (assq 'viewer viewer))
 775               (test (assq 'test viewer)))
 776           (if view (setcdr view (mailcap-unescape-mime-test (cdr view) info)))
 777           (if test (setcdr test (mailcap-unescape-mime-test (cdr test) info))))
 778         viewer)))))
 779
 780 ;;;
 781 ;;; Experimental MIME-types parsing
 782 ;;;
 783
 784 (defvar mailcap-mime-extensions
 785   '((""        . "text/plain")
 786     (".abs"   . "audio/x-mpeg")
 787     (".aif"   . "audio/aiff")
 788     (".aifc"  . "audio/aiff")
 789     (".aiff"  . "audio/aiff")
 790     (".ano"   . "application/x-annotator")
 791     (".au"    . "audio/ulaw")
 792     (".avi"   . "video/x-msvideo")
 793     (".bcpio" . "application/x-bcpio")
 794     (".bin"   . "application/octet-stream")
 795     (".cdf"   . "application/x-netcdr")
 796     (".cpio"  . "application/x-cpio")
 797     (".csh"   . "application/x-csh")
 798     (".css"   . "text/css")
 799     (".dvi"   . "application/x-dvi")
 800     (".diff"  . "text/x-patch")
 801     (".el"    . "application/emacs-lisp")
 802     (".eps"   . "application/postscript")
 803     (".etx"   . "text/x-setext")
 804     (".exe"   . "application/octet-stream")
 805     (".fax"   . "image/x-fax")
 806     (".gif"   . "image/gif")
 807     (".hdf"   . "application/x-hdf")
 808     (".hqx"   . "application/mac-binhex40")
 809     (".htm"   . "text/html")
 810     (".html"  . "text/html")
 811     (".icon"  . "image/x-icon")
 812     (".ief"   . "image/ief")
 813     (".jpg"   . "image/jpeg")
 814     (".macp"  . "image/x-macpaint")
 815     (".man"   . "application/x-troff-man")
 816     (".me"    . "application/x-troff-me")
 817     (".mif"   . "application/mif")
 818     (".mov"   . "video/quicktime")
 819     (".movie" . "video/x-sgi-movie")
 820     (".mp2"   . "audio/x-mpeg")
 821     (".mp3"   . "audio/x-mpeg")
 822     (".mp2a"  . "audio/x-mpeg2")
 823     (".mpa"   . "audio/x-mpeg")
 824     (".mpa2"  . "audio/x-mpeg2")
 825     (".mpe"   . "video/mpeg")
 826     (".mpeg"  . "video/mpeg")
 827     (".mpega" . "audio/x-mpeg")
 828     (".mpegv" . "video/mpeg")
 829     (".mpg"   . "video/mpeg")
 830     (".mpv"   . "video/mpeg")
 831     (".ms"    . "application/x-troff-ms")
 832     (".nc"    . "application/x-netcdf")
 833     (".nc"    . "application/x-netcdf")
 834     (".oda"   . "application/oda")
 835     (".patch" . "text/x-patch")
 836     (".pbm"   . "image/x-portable-bitmap")
 837     (".pdf"   . "application/pdf")
 838     (".pgm"   . "image/portable-graymap")
 839     (".pict"  . "image/pict")
 840     (".png"   . "image/png")
 841     (".pnm"   . "image/x-portable-anymap")
 842     (".ppm"   . "image/portable-pixmap")
 843     (".ps"    . "application/postscript")
 844     (".qt"    . "video/quicktime")
 845     (".ras"   . "image/x-raster")
 846     (".rgb"   . "image/x-rgb")
 847     (".rtf"   . "application/rtf")
 848     (".rtx"   . "text/richtext")
 849     (".sh"    . "application/x-sh")
 850     (".sit"   . "application/x-stuffit")
 851     (".siv"   . "application/sieve")
 852     (".snd"   . "audio/basic")
 853     (".soa"   . "text/dns")
 854     (".src"   . "application/x-wais-source")
 855     (".tar"   . "archive/tar")
 856     (".tcl"   . "application/x-tcl")
 857     (".tex"   . "application/x-tex")
 858     (".texi"  . "application/texinfo")
 859     (".tga"   . "image/x-targa")
 860     (".tif"   . "image/tiff")
 861     (".tiff"  . "image/tiff")
 862     (".tr"    . "application/x-troff")
 863     (".troff" . "application/x-troff")
 864     (".tsv"   . "text/tab-separated-values")
 865     (".txt"   . "text/plain")
 866     (".vbs"   . "video/mpeg")
 867     (".vox"   . "audio/basic")
 868     (".vrml"  . "x-world/x-vrml")
 869     (".wav"   . "audio/x-wav")
 870     (".xls"   . "application/vnd.ms-excel")
 871     (".wrl"   . "x-world/x-vrml")
 872     (".xbm"   . "image/xbm")
 873     (".xpm"   . "image/xpm")
 874     (".xwd"   . "image/windowdump")
 875     (".zip"   . "application/zip")
 876     (".ai"    . "application/postscript")
 877     (".jpe"   . "image/jpeg")
 878     (".jpeg"  . "image/jpeg"))
 879   "An alist of file extensions and corresponding MIME content-types.
 880 This exists for you to customize the information in Lisp.  It is
 881 merged with values from mailcap files by `mailcap-parse-mimetypes'.")
 882
 883 (defvar mailcap-mimetypes-parsed-p nil)
 884
 885 (defun mailcap-parse-mimetypes (&optional path force)
 886   "Parse out all the mimetypes specified in a Unix-style path string PATH.
 887 Components of PATH are separated by the `path-separator' character
 888 appropriate for this system.  If PATH is omitted, use the value of
 889 environment variable MIMETYPES if set; otherwise use a default path.
 890 If FORCE, re-parse even if already parsed."
 891   (interactive (list nil t))
 892   (when (or (not mailcap-mimetypes-parsed-p)
 893             force)
 894     (cond
 895      (path nil)
 896      ((getenv "MIMETYPES") (setq path (getenv "MIMETYPES")))
 897      ((memq system-type mailcap-poor-system-types)
 898       (setq path '("~/mime.typ" "~/etc/mime.typ")))
 899      (t (setq path
 900               ;; mime.types seems to be the normal name, definitely so
 901               ;; on current GNUish systems.  The search order follows
 902               ;; that for mailcap.
 903               '("~/.mime.types"
 904                 "/etc/mime.types"
 905                 "/usr/etc/mime.types"
 906                 "/usr/local/etc/mime.types"
 907                 "/usr/local/www/conf/mime.types"
 908                 "~/.mime-types"
 909                 "/etc/mime-types"
 910                 "/usr/etc/mime-types"
 911                 "/usr/local/etc/mime-types"
 912                 "/usr/local/www/conf/mime-types"))))
 913     (let ((fnames (reverse (if (stringp path)
 914                                (delete "" (split-string path path-separator))
 915                              path)))
 916           fname)
 917       (while fnames
 918         (setq fname (car fnames))
 919         (if (and (file-readable-p fname))
 920             (mailcap-parse-mimetype-file fname))
 921         (setq fnames (cdr fnames))))
 922     (setq mailcap-mimetypes-parsed-p t)))
 923
 924 (defun mailcap-parse-mimetype-file (fname)
 925   "Parse out a mime-types file FNAME."
 926   (let (type                            ; The MIME type for this line
 927         extns                           ; The extensions for this line
 928         save-pos                        ; Misc. saved buffer positions
 929         )
 930     (with-temp-buffer
 931       (insert-file-contents fname)
 932       (mailcap-replace-regexp "#.*" "")
 933       (mailcap-replace-regexp "\n+" "\n")
 934       (mailcap-replace-regexp "[ \t]+$" "")
 935       (goto-char (point-max))
 936       (skip-chars-backward " \t\n")
 937       (delete-region (point) (point-max))
 938       (goto-char (point-min))
 939       (while (not (eobp))
 940         (skip-chars-forward " \t\n")
 941         (setq save-pos (point))
 942         (skip-chars-forward "^ \t\n")
 943         (downcase-region save-pos (point))
 944         (setq type (buffer-substring save-pos (point)))
 945         (while (not (eolp))
 946           (skip-chars-forward " \t")
 947           (setq save-pos (point))
 948           (skip-chars-forward "^ \t\n")
 949           (setq extns (cons (buffer-substring save-pos (point)) extns)))
 950         (while extns
 951           (setq mailcap-mime-extensions
 952                 (cons
 953                  (cons (if (= (string-to-char (car extns)) ?.)
 954                            (car extns)
 955                          (concat "." (car extns))) type)
 956                  mailcap-mime-extensions)
 957                 extns (cdr extns)))))))
 958
 959 (defun mailcap-extension-to-mime (extn)
 960   "Return the MIME content type of the file extensions EXTN."
 961   (mailcap-parse-mimetypes)
 962   (if (and (stringp extn)
 963            (not (eq (string-to-char extn) ?.)))
 964       (setq extn (concat "." extn)))
 965   (cdr (assoc (downcase extn) mailcap-mime-extensions)))
 966
 967 ;; Unused?
 968 (defalias 'mailcap-command-p 'executable-find)
 969
 970 (defun mailcap-mime-types ()
 971   "Return a list of MIME media types."
 972   (mailcap-parse-mimetypes)
 973   (mm-delete-duplicates
 974    (nconc
 975     (mapcar 'cdr mailcap-mime-extensions)
 976     (apply
 977      'nconc
 978      (mapcar
 979       (lambda (l)
 980         (delq nil
 981               (mapcar
 982                (lambda (m)
 983                  (let ((type (cdr (assq 'type (cdr m)))))
 984                    (if (equal (cadr (split-string type "/"))
 985                               "*")
 986                        nil
 987                      type)))
 988                (cdr l))))
 989       mailcap-mime-data)))))
 990
 991 (provide 'mailcap)
 992
 993 ;;; arch-tag: 1fd4f9c9-c305-4d2e-9747-3a4d45baa0bd
 994 ;;; mailcap.el ends here