cgit.sxemacs.org Git - gnus/blob - lisp/hashcash.el

   1 ;;; hashcash.el --- Add hashcash payments to email
   2
   3 ;; Copyright (C) 2003, 2004, 2005 Free Software Foundation
   4
   5 ;; Written by: Paul Foley <mycroft@actrix.gen.nz> (1997-2002)
   6 ;; Maintainer: Paul Foley <mycroft@actrix.gen.nz>
   7 ;; Keywords: mail, hashcash
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The hashcash binary is at http://www.hashcash.org/.
  29 ;;
  30 ;; Call mail-add-payment to add a hashcash payment to a mail message
  31 ;; in the current buffer.
  32 ;;
  33 ;; Call mail-add-payment-async after writing the addresses but before
  34 ;; writing the mail to start calculating the hashcash payment
  35 ;; asynchronously.
  36 ;;
  37 ;; The easiest way to do this automatically for all outgoing mail
  38 ;; is to set `message-generate-hashcash' to t.  If you want more
  39 ;; control, try the following hooks.
  40 ;;
  41 ;; To automatically add payments to all outgoing mail when sending:
  42 ;;    (add-hook 'message-send-hook 'mail-add-payment)
  43 ;;
  44 ;; To start calculations automatically when addresses are prefilled:
  45 ;;    (add-hook 'message-setup-hook 'mail-add-payment-async)
  46 ;;
  47 ;; To check whether calculations are done before sending:
  48 ;;    (add-hook 'message-send-hook 'hashcash-wait-or-cancel)
  49
  50 ;;; Code:
  51
  52 (defgroup hashcash nil
  53   "Hashcash configuration."
  54   :group 'mail)
  55
  56 (defcustom hashcash-default-payment 20
  57   "*The default number of bits to pay to unknown users.
  58 If this is zero, no payment header will be generated.
  59 See `hashcash-payment-alist'."
  60   :type 'integer
  61   :group 'hashcash)
  62
  63 (defcustom hashcash-payment-alist '()
  64   "*An association list mapping email addresses to payment amounts.
  65 Elements may consist of (ADDR AMOUNT) or (ADDR STRING AMOUNT), where
  66 ADDR is the email address of the intended recipient and AMOUNT is
  67 the value of hashcash payment to be made to that user.  STRING, if
  68 present, is the string to be hashed; if not present ADDR will be used."
  69   :type '(repeat (choice (list :tag "Normal"
  70                                (string :name "Address")
  71                                (integer :name "Amount"))
  72                          (list :tag "Replace hash input"
  73                                (string :name "Address")
  74                                (string :name "Hash input")
  75                                (integer :name "Amount"))))
  76   :group 'hashcash)
  77
  78 (defcustom hashcash-default-accept-payment 20
  79   "*The default minimum number of bits to accept on incoming payments."
  80   :type 'integer
  81   :group 'hashcash)
  82
  83 (defcustom hashcash-accept-resources `((,user-mail-address nil))
  84   "*An association list mapping hashcash resources to payment amounts.
  85 Resources named here are to be accepted in incoming payments.  If the
  86 corresponding AMOUNT is NIL, the value of `hashcash-default-accept-payment'
  87 is used instead."
  88   :group 'hashcash)
  89
  90 (defcustom hashcash-path (executable-find "hashcash")
  91   "*The path to the hashcash binary."
  92   :group 'hashcash)
  93
  94 (defcustom hashcash-extra-generate-parameters nil
  95   "*A list of parameter strings passed to `hashcash-path' when minting.
  96 For example, you may want to set this to '(\"-Z2\") to reduce header length."
  97   :type '(repeat string)
  98   :group 'hashcash)
  99
 100 (defcustom hashcash-double-spend-database "hashcash.db"
 101   "*The path to the double-spending database."
 102   :group 'hashcash)
 103
 104 (defcustom hashcash-in-news nil
 105   "*Specifies whether or not hashcash payments should be made to newsgroups."
 106   :type 'boolean
 107   :group 'hashcash)
 108
 109 (defvar hashcash-process-alist nil
 110   "Alist of asynchronous hashcash processes and buffers.")
 111
 112 (require 'mail-utils)
 113
 114 (eval-and-compile
 115  (if (fboundp 'point-at-bol)
 116      (defalias 'hashcash-point-at-bol 'point-at-bol)
 117    (defalias 'hashcash-point-at-bol 'line-beginning-position))
 118
 119  (if (fboundp 'point-at-eol)
 120      (defalias 'hashcash-point-at-eol 'point-at-eol)
 121    (defalias 'hashcash-point-at-eol 'line-end-position)))
 122
 123 (defun hashcash-strip-quoted-names (addr)
 124   (setq addr (mail-strip-quoted-names addr))
 125   (if (and addr (string-match "\\`\\([^+@]+\\)\\+[^@]*\\(@.+\\)" addr))
 126       (concat (match-string 1 addr) (match-string 2 addr))
 127     addr))
 128
 129 (defun hashcash-token-substring ()
 130   (save-excursion
 131     (let ((token ""))
 132       (loop
 133         (setq token
 134           (concat token (buffer-substring (point) (hashcash-point-at-eol))))
 135         (goto-char (hashcash-point-at-eol))
 136         (forward-char 1)
 137         (unless (looking-at "[ \t]") (return token))
 138         (while (looking-at "[ \t]") (forward-char 1))))))
 139
 140 (defun hashcash-payment-required (addr)
 141   "Return the hashcash payment value required for the given address."
 142   (let ((val (assoc addr hashcash-payment-alist)))
 143     (or (nth 2 val) (nth 1 val) hashcash-default-payment)))
 144
 145 (defun hashcash-payment-to (addr)
 146   "Return the string with which hashcash payments should collide."
 147   (let ((val (assoc addr hashcash-payment-alist)))
 148     (or (nth 1 val) (nth 0 val) addr)))
 149
 150 (defun hashcash-generate-payment (str val)
 151   "Generate a hashcash payment by finding a VAL-bit collison on STR."
 152   (if (and (> val 0)
 153            hashcash-path)
 154       (save-excursion
 155         (set-buffer (get-buffer-create " *hashcash*"))
 156         (erase-buffer)
 157         (apply 'call-process hashcash-path nil t nil
 158                "-m" "-q" "-b" (number-to-string val) str
 159                hashcash-extra-generate-parameters)
 160         (goto-char (point-min))
 161         (hashcash-token-substring))
 162     (error "No `hashcash' binary found")))
 163
 164 (defun hashcash-generate-payment-async (str val callback)
 165   "Generate a hashcash payment by finding a VAL-bit collison on STR.
 166 Return immediately.  Call CALLBACK with process and result when ready."
 167   (if (> val 0)
 168       (let ((process (apply 'start-process "hashcash" nil
 169                             hashcash-path "-m" "-q"
 170                             "-b" (number-to-string val) str
 171                             hashcash-extra-generate-parameters)))
 172         (setq hashcash-process-alist (cons
 173                                       (cons process (current-buffer))
 174                                       hashcash-process-alist))
 175         (set-process-filter process `(lambda (process output)
 176                                        (funcall ,callback process output))))
 177     (funcall callback nil)))
 178
 179 (defun hashcash-check-payment (token str val)
 180   "Check the validity of a hashcash payment."
 181   (if hashcash-path
 182       (zerop (call-process hashcash-path nil nil nil "-c"
 183                            "-d" "-f" hashcash-double-spend-database
 184                            "-b" (number-to-string val)
 185                            "-r" str
 186                            token))
 187     (progn
 188       (message "No hashcash binary found")
 189       (sleep-for 1)
 190       nil)))
 191
 192 (defun hashcash-version (token)
 193   "Find the format version of a hashcash token."
 194   ;; Version 1.2 looks like n:yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 195   ;;   This carries its own version number embedded in the token,
 196   ;;   so no further format number changes should be necessary
 197   ;;   in the X-Payment header.
 198   ;;
 199   ;; Version 1.1 looks like yymmdd:rrrrr:xxxxxxxxxxxxxxxx
 200   ;;   You need to upgrade your hashcash binary.
 201   ;;
 202   ;; Version 1.0 looked like nnnnnrrrrrxxxxxxxxxxxxxxxx
 203   ;;   This is no longer supported.
 204   (cond ((equal (aref token 1) ?:) 1.2)
 205         ((equal (aref token 6) ?:) 1.1)
 206         (t (error "Unknown hashcash format version"))))
 207
 208 (defun hashcash-already-paid-p (recipient)
 209   "Check for hashcash token to RECIPIENT in current buffer."
 210   (save-excursion
 211     (save-restriction
 212       (message-narrow-to-headers-or-head)
 213       (let ((token (message-fetch-field "x-hashcash")))
 214         (and (stringp token)
 215              (string-match (regexp-quote recipient) token))))))
 216
 217 ;;;###autoload
 218 (defun hashcash-insert-payment (arg)
 219   "Insert X-Payment and X-Hashcash headers with a payment for ARG"
 220   (interactive "sPay to: ")
 221   (unless (hashcash-already-paid-p arg)
 222     (let ((pay (hashcash-generate-payment (hashcash-payment-to arg)
 223                                           (hashcash-payment-required arg))))
 224       (when pay
 225         ;;      (insert-before-markers "X-Payment: hashcash "
 226         ;;                           (number-to-string (hashcash-version pay)) " "
 227         ;;                           pay "\n")
 228         (insert-before-markers "X-Hashcash: " pay "\n")))))
 229
 230 ;;;###autoload
 231 (defun hashcash-insert-payment-async (arg)
 232   "Insert X-Payment and X-Hashcash headers with a payment for ARG
 233 Only start calculation.  Results are inserted when ready."
 234   (interactive "sPay to: ")
 235   (unless (hashcash-already-paid-p arg)
 236     (hashcash-generate-payment-async (hashcash-payment-to arg)
 237                                      (hashcash-payment-required arg)
 238                                      `(lambda (process payment)
 239                                         (hashcash-insert-payment-async-2 ,(current-buffer) process payment)))))
 240
 241 (defun hashcash-insert-payment-async-2 (buffer process pay)
 242   (with-current-buffer buffer
 243     (save-excursion
 244       (save-restriction
 245         (setq hashcash-process-alist (delq
 246                                       (assq process hashcash-process-alist)
 247                                       hashcash-process-alist))
 248         (goto-char (point-min))
 249         (search-forward mail-header-separator)
 250         (beginning-of-line)
 251         (when pay
 252 ;;      (insert-before-markers "X-Payment: hashcash "
 253 ;;                           (number-to-string (hashcash-version pay)) " "
 254 ;;                           pay "\n")
 255           (insert-before-markers "X-Hashcash: " pay))))))
 256
 257 (defun hashcash-cancel-async (&optional buffer)
 258   "Delete any hashcash processes associated with BUFFER.
 259 BUFFER defaults to the current buffer."
 260   (interactive)
 261   (unless buffer (setq buffer (current-buffer)))
 262   (let (entry)
 263     (while (setq entry (rassq buffer hashcash-process-alist))
 264       (delete-process (car entry))
 265       (setq hashcash-process-alist
 266             (delq entry hashcash-process-alist)))))
 267
 268 (defun hashcash-wait-async (&optional buffer)
 269   "Wait for asynchronous hashcash processes in BUFFER to finish.
 270 BUFFER defaults to the current buffer."
 271   (interactive)
 272   (unless buffer (setq buffer (current-buffer)))
 273   (let (entry)
 274     (while (setq entry (rassq buffer hashcash-process-alist))
 275       (accept-process-output (car entry)))))
 276
 277 (defun hashcash-processes-running-p (buffer)
 278   "Return non-nil if hashcash processes in BUFFER are still running."
 279   (rassq buffer hashcash-process-alist))
 280
 281 (defun hashcash-wait-or-cancel ()
 282   "Ask user whether to wait for hashcash processes to finish."
 283   (interactive)
 284   (when (hashcash-processes-running-p (current-buffer))
 285     (if (y-or-n-p
 286           "Hashcash process(es) still running; wait for them to finish? ")
 287         (hashcash-wait-async)
 288       (hashcash-cancel-async))))
 289
 290 ;;;###autoload
 291 (defun hashcash-verify-payment (token &optional resource amount)
 292   "Verify a hashcash payment"
 293   (let* ((split (split-string token ":"))
 294          (key (if (< (hashcash-version token) 1.2)
 295                   (nth 1 split)
 296                   (case (string-to-number (nth 0 split))
 297                     (0 (nth 2 split))
 298                     (1 (nth 3 split))))))
 299     (cond ((null resource)
 300            (let ((elt (assoc key hashcash-accept-resources)))
 301              (and elt (hashcash-check-payment token (car elt)
 302                         (or (cadr elt) hashcash-default-accept-payment)))))
 303           ((equal token key)
 304            (hashcash-check-payment token resource
 305                                 (or amount hashcash-default-accept-payment)))
 306           (t nil))))
 307
 308 ;;;###autoload
 309 (defun mail-add-payment (&optional arg async)
 310   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
 311 for each recipient address.  Prefix arg sets default payment temporarily.
 312 Set ASYNC to t to start asynchronous calculation.  (See
 313 `mail-add-payment-async')."
 314   (interactive "P")
 315   (let ((hashcash-default-payment (if arg (prefix-numeric-value arg)
 316                                     hashcash-default-payment))
 317         (addrlist nil))
 318     (save-excursion
 319       (save-restriction
 320         (goto-char (point-min))
 321         (search-forward mail-header-separator)
 322         (beginning-of-line)
 323         (narrow-to-region (point-min) (point))
 324         (let ((to (hashcash-strip-quoted-names (mail-fetch-field "To" nil t)))
 325               (cc (hashcash-strip-quoted-names (mail-fetch-field "Cc" nil t)))
 326               (ng (hashcash-strip-quoted-names (mail-fetch-field "Newsgroups"
 327                                                                  nil t))))
 328           (when to
 329             (setq addrlist (split-string to ",[ \t\n]*")))
 330           (when cc
 331             (setq addrlist (nconc addrlist (split-string cc ",[ \t\n]*"))))
 332           (when (and hashcash-in-news ng)
 333             (setq addrlist (nconc addrlist (split-string ng ",[ \t\n]*")))))
 334         (when addrlist
 335           (mapcar (if async
 336                       #'hashcash-insert-payment-async
 337                     #'hashcash-insert-payment)
 338                   addrlist))))) ; mapc
 339   t)
 340
 341 ;;;###autoload
 342 (defun mail-add-payment-async (&optional arg)
 343   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
 344 for each recipient address.  Prefix arg sets default payment temporarily.
 345 Calculation is asynchronous."
 346   (interactive "P")
 347   (mail-add-payment arg t))
 348
 349 ;;;###autoload
 350 (defun mail-check-payment (&optional arg)
 351   "Look for a valid X-Payment: or X-Hashcash: header.
 352 Prefix arg sets default accept amount temporarily."
 353   (interactive "P")
 354   (let ((hashcash-default-accept-payment (if arg (prefix-numeric-value arg)
 355                                            hashcash-default-accept-payment))
 356         (version (hashcash-version (hashcash-generate-payment "x" 1))))
 357     (save-excursion
 358       (goto-char (point-min))
 359       (search-forward "\n\n")
 360       (beginning-of-line)
 361       (let ((end (point))
 362             (ok nil))
 363         (goto-char (point-min))
 364         (while (and (not ok) (search-forward "X-Payment: hashcash " end t))
 365           (let ((value (split-string (hashcash-token-substring) " ")))
 366             (when (equal (car value) (number-to-string version))
 367               (setq ok (hashcash-verify-payment (cadr value))))))
 368         (goto-char (point-min))
 369         (while (and (not ok) (search-forward "X-Hashcash: " end t))
 370           (setq ok (hashcash-verify-payment (hashcash-token-substring))))
 371         (when ok
 372           (message "Payment valid"))
 373         ok))))
 374
 375 (provide 'hashcash)
 376
 377 ;;; arch-tag: 0e7fe983-a124-4392-9788-0dbcbd2c4d62