cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defgroup gnus-xmas nil
  33   "XEmacsoid support for Gnus"
  34   :group 'gnus)
  35
  36 (defcustom gnus-xmas-glyph-directory nil
  37   "*Directory where Gnus logos and icons are located.
  38 If this variable is nil, Gnus will try to locate the directory
  39 automatically."
  40   :type '(choice (const :tag "autodetect" nil)
  41                  directory)
  42   :group 'gnus-xmas)
  43
  44 (defvar gnus-xmas-logo-color-alist
  45   '((flame "#cc3300" "#ff2200")
  46     (pine "#c0cc93" "#f8ffb8")
  47     (moss "#a1cc93" "#d2ffb8")
  48     (irish "#04cc90" "#05ff97")
  49     (sky "#049acc" "#05deff")
  50     (tin "#6886cc" "#82b6ff")
  51     (velvet "#7c68cc" "#8c82ff")
  52     (grape "#b264cc" "#cf7df")
  53     (labia "#cc64c2" "#fd7dff")
  54     (berry "#cc6485" "#ff7db5")
  55     (neutral "#b4b4b4" "#878787")
  56     (september "#bf9900" "#ffcc00"))
  57   "Color alist used for the Gnus logo.")
  58
  59 (defcustom gnus-xmas-logo-color-style 'moss
  60   "Color styles used for the Gnus logo."
  61   :type '(choice (const flame) (const pine) (const moss)
  62                  (const irish) (const sky) (const tin)
  63                  (const velvet) (const grape) (const labia)
  64                  (const berry) (const neutral) (const september))
  65   :group 'gnus-xmas)
  66
  67 (defvar gnus-xmas-logo-colors
  68   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  69   "Colors used for the Gnus logo.")
  70
  71 (defcustom gnus-article-x-face-command
  72   (if (or (featurep 'xface)
  73           (featurep 'xpm))
  74       'gnus-xmas-article-display-xface
  75     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  76   "String or function to be executed to display an X-Face header.
  77 If it is a string, the command will be executed in a sub-shell
  78 asynchronously.  The compressed face will be piped to this command."
  79   :type '(choice string function))
  80
  81 ;;; Internal variables.
  82
  83 ;; Don't warn about these undefined variables.
  84
  85 (defvar gnus-group-mode-hook)
  86 (defvar gnus-summary-mode-hook)
  87 (defvar gnus-article-mode-hook)
  88
  89 ;;defined in gnus.el
  90 (defvar gnus-active-hashtb)
  91 (defvar gnus-article-buffer)
  92 (defvar gnus-auto-center-summary)
  93 (defvar gnus-buffer-list)
  94 (defvar gnus-current-headers)
  95 (defvar gnus-level-killed)
  96 (defvar gnus-level-zombie)
  97 (defvar gnus-newsgroup-bookmarks)
  98 (defvar gnus-newsgroup-dependencies)
  99 (defvar gnus-newsgroup-selected-overlay)
 100 (defvar gnus-newsrc-hashtb)
 101 (defvar gnus-read-mark)
 102 (defvar gnus-refer-article-method)
 103 (defvar gnus-reffed-article-number)
 104 (defvar gnus-unread-mark)
 105 (defvar gnus-version)
 106 (defvar gnus-view-pseudos)
 107 (defvar gnus-view-pseudos-separately)
 108 (defvar gnus-visual)
 109 (defvar gnus-zombie-list)
 110 ;;defined in gnus-msg.el
 111 (defvar gnus-article-copy)
 112 (defvar gnus-check-before-posting)
 113 ;;defined in gnus-vis.el
 114 (defvar gnus-article-button-face)
 115 (defvar gnus-article-mouse-face)
 116 (defvar gnus-summary-selected-face)
 117 (defvar gnus-group-reading-menu)
 118 (defvar gnus-group-group-menu)
 119 (defvar gnus-group-misc-menu)
 120 (defvar gnus-summary-article-menu)
 121 (defvar gnus-summary-thread-menu)
 122 (defvar gnus-summary-misc-menu)
 123 (defvar gnus-summary-post-menu)
 124 (defvar gnus-summary-kill-menu)
 125 (defvar gnus-article-article-menu)
 126 (defvar gnus-article-treatment-menu)
 127 (defvar gnus-mouse-2)
 128 (defvar standard-display-table)
 129 (defvar gnus-tree-minimize-window)
 130
 131 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 132   "You should NEVER use this function.  It is ideologically blasphemous.
 133 It is provided only to ease porting of broken FSF Emacs programs."
 134   (if (stringp buffer)
 135       nil
 136     (map-extents (lambda (extent ignored)
 137                    (remove-text-properties
 138                     start end
 139                     (list (extent-property extent 'text-prop) nil)
 140                     buffer)
 141                    nil)
 142                  buffer start end nil nil 'text-prop)
 143     (gnus-add-text-properties start end props buffer)))
 144
 145 (defun gnus-xmas-highlight-selected-summary ()
 146   ;; Highlight selected article in summary buffer
 147   (when gnus-summary-selected-face
 148     (when gnus-newsgroup-selected-overlay
 149       (delete-extent gnus-newsgroup-selected-overlay))
 150     (setq gnus-newsgroup-selected-overlay
 151           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 152     (set-extent-face gnus-newsgroup-selected-overlay
 153                      gnus-summary-selected-face)))
 154
 155 (defcustom gnus-xmas-force-redisplay nil
 156   "If non-nil, force a redisplay before recentering the summary buffer.
 157 This is ugly, but it works around a bug in `window-displayed-height'."
 158   :type 'boolean
 159   :group 'gnus-xmas)
 160
 161 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 162   (when (featurep 'scrollbar)
 163     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 164
 165 (defun gnus-xmas-summary-recenter ()
 166   "\"Center\" point in the summary window.
 167 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 168 displayed, no centering will be performed."
 169   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 170   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 171   ;; Force redisplay to get properly computed window height.
 172   (when gnus-xmas-force-redisplay
 173     (sit-for 0))
 174   (when gnus-auto-center-summary
 175     (let* ((height (if (fboundp 'window-displayed-height)
 176                        (window-displayed-height)
 177                      (- (window-height) 2)))
 178            (top (cond ((< height 4) 0)
 179                       ((< height 7) 1)
 180                       (t 2)))
 181            (bottom (save-excursion (goto-char (point-max))
 182                                    (forward-line (- height))
 183                                    (point)))
 184            (window (get-buffer-window (current-buffer))))
 185       (when (get-buffer-window gnus-article-buffer)
 186         ;; Only do recentering when the article buffer is displayed,
 187         ;; Set the window start to either `bottom', which is the biggest
 188         ;; possible valid number, or the second line from the top,
 189         ;; whichever is the least.
 190         (set-window-start
 191          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 192       ;; Do horizontal recentering while we're at it.
 193       (when (and (get-buffer-window (current-buffer) t)
 194                  (not (eq gnus-auto-center-summary 'vertical)))
 195         (let ((selected (selected-window)))
 196           (select-window (get-buffer-window (current-buffer) t))
 197           (gnus-summary-position-point)
 198           (gnus-horizontal-recenter)
 199           (select-window selected))))))
 200
 201 (defun gnus-xmas-summary-set-display-table ()
 202   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 203   ;; but done in an XEmacsish way.
 204   (let ((table (make-display-table))
 205         (i 32))
 206     ;; Nix out all the control chars...
 207     (while (>= (setq i (1- i)) 0)
 208       (aset table i [??]))
 209     ;; ... but not newline and cr, of course.  (cr is necessary for the
 210     ;; selective display).
 211     (aset table ?\n nil)
 212     (aset table ?\r nil)
 213     ;; We keep TAB as well.
 214     (aset table ?\t nil)
 215     ;; We nix out any glyphs over 126 below ctl-arrow.
 216     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 217       (while (>= (setq i (1- i)) 127)
 218         (unless (aref table i)
 219           (aset table i [??]))))
 220     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 221     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 222
 223 (defun gnus-xmas-add-text-properties (start end props &optional object)
 224   (add-text-properties start end props object)
 225   (put-text-property start end 'start-closed nil object))
 226
 227 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 228   (put-text-property start end prop value object)
 229   (put-text-property start end 'start-closed nil object))
 230
 231 (defun gnus-xmas-extent-start-open (point)
 232   (map-extents (lambda (extent arg)
 233                  (set-extent-property extent 'start-open t))
 234                nil point (min (1+ (point)) (point-max))))
 235
 236 (defun gnus-xmas-article-push-button (event)
 237   "Check text under the mouse pointer for a callback function.
 238 If the text under the mouse pointer has a `gnus-callback' property,
 239 call it with the value of the `gnus-data' text property."
 240   (interactive "e")
 241   (set-buffer (window-buffer (event-window event)))
 242   (let* ((pos (event-closest-point event))
 243          (data (get-text-property pos 'gnus-data))
 244          (fun (get-text-property pos 'gnus-callback)))
 245     (when fun
 246       (funcall fun data))))
 247
 248 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 249   (set-extent-endpoints extent start end buffer))
 250
 251 (defun gnus-xmas-kill-all-overlays ()
 252   "Delete all extents in the current buffer."
 253   (map-extents (lambda (extent ignore)
 254                  (delete-extent extent)
 255                  nil)))
 256
 257 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 258 (defun gnus-xmas-article-add-button (from to fun &optional data)
 259   "Create a button between FROM and TO with callback FUN and data DATA."
 260   (when gnus-article-button-face
 261     (gnus-overlay-put (gnus-make-overlay from to)
 262                       'face gnus-article-button-face))
 263   (gnus-add-text-properties
 264    from to
 265    (nconc
 266     (and gnus-article-mouse-face
 267          (list 'mouse-face gnus-article-mouse-face))
 268     (list 'gnus-callback fun)
 269     (and data (list 'gnus-data data))
 270     (list 'highlight t))))
 271
 272 (defun gnus-xmas-window-top-edge (&optional window)
 273   (nth 1 (window-pixel-edges window)))
 274
 275 (defun gnus-xmas-tree-minimize ()
 276   (when (and gnus-tree-minimize-window
 277              (not (one-window-p)))
 278     (let* ((window-min-height 2)
 279            (height (1+ (count-lines (point-min) (point-max))))
 280            (min (max (1- window-min-height) height))
 281            (tot (if (numberp gnus-tree-minimize-window)
 282                     (min gnus-tree-minimize-window min)
 283                   min))
 284            (win (get-buffer-window (current-buffer)))
 285            (wh (and win (1- (window-height win)))))
 286       (when (and win
 287                  (not (eq tot wh)))
 288         (let ((selected (selected-window)))
 289           (select-window win)
 290           (enlarge-window (- tot wh))
 291           (select-window selected))))))
 292
 293 ;; Select the lowest window on the frame.
 294 (defun gnus-xmas-appt-select-lowest-window ()
 295   (let* ((lowest-window (selected-window))
 296          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 297          (last-window (previous-window))
 298          (window-search t))
 299     (while window-search
 300       (let* ((this-window (next-window))
 301              (next-bottom-edge (car (cdr (cdr (cdr
 302                                                (window-pixel-edges
 303                                                 this-window)))))))
 304         (when (< bottom-edge next-bottom-edge)
 305           (setq bottom-edge next-bottom-edge)
 306           (setq lowest-window this-window))
 307
 308         (select-window this-window)
 309         (when (eq last-window this-window)
 310           (select-window lowest-window)
 311           (setq window-search nil))))))
 312
 313 (defmacro gnus-xmas-menu-add (type &rest menus)
 314   `(gnus-xmas-menu-add-1 ',type ',menus))
 315 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 316
 317 (defun gnus-xmas-menu-add-1 (type menus)
 318   (when (and menu-bar-mode
 319              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 320     (while menus
 321       (easy-menu-add (symbol-value (pop menus))))))
 322
 323 (defun gnus-xmas-group-menu-add ()
 324   (gnus-xmas-menu-add group
 325     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 326
 327 (defun gnus-xmas-summary-menu-add ()
 328   (gnus-xmas-menu-add summary
 329     gnus-summary-misc-menu gnus-summary-kill-menu
 330     gnus-summary-article-menu gnus-summary-thread-menu
 331     gnus-summary-post-menu ))
 332
 333 (defun gnus-xmas-article-menu-add ()
 334   (gnus-xmas-menu-add article
 335     gnus-article-article-menu gnus-article-treatment-menu))
 336
 337 (defun gnus-xmas-score-menu-add ()
 338   (gnus-xmas-menu-add score
 339     gnus-score-menu))
 340
 341 (defun gnus-xmas-pick-menu-add ()
 342   (gnus-xmas-menu-add pick
 343     gnus-pick-menu))
 344
 345 (defun gnus-xmas-topic-menu-add ()
 346   (gnus-xmas-menu-add topic
 347     gnus-topic-menu))
 348
 349 (defun gnus-xmas-binary-menu-add ()
 350   (gnus-xmas-menu-add binary
 351     gnus-binary-menu))
 352
 353 (defun gnus-xmas-agent-summary-menu-add ()
 354   (gnus-xmas-menu-add agent-summary
 355     gnus-agent-summary-menu))
 356
 357 (defun gnus-xmas-agent-group-menu-add ()
 358   (gnus-xmas-menu-add agent-group
 359     gnus-agent-group-menu))
 360
 361 (defun gnus-xmas-agent-server-menu-add ()
 362   (gnus-xmas-menu-add agent-server
 363     gnus-agent-server-menu))
 364
 365 (defun gnus-xmas-tree-menu-add ()
 366   (gnus-xmas-menu-add tree
 367     gnus-tree-menu))
 368
 369 (defun gnus-xmas-server-menu-add ()
 370   (gnus-xmas-menu-add menu
 371     gnus-server-server-menu gnus-server-connections-menu))
 372
 373 (defun gnus-xmas-browse-menu-add ()
 374   (gnus-xmas-menu-add browse
 375     gnus-browse-menu))
 376
 377 (defun gnus-xmas-grouplens-menu-add ()
 378   (gnus-xmas-menu-add grouplens
 379     gnus-grouplens-menu))
 380
 381 (defun gnus-xmas-read-event-char ()
 382   "Get the next event."
 383   (let ((event (next-command-event)))
 384     (sit-for 0)
 385     ;; We junk all non-key events.  Is this naughty?
 386     (while (not (or (key-press-event-p event)
 387                     (button-press-event-p event)))
 388       (dispatch-event event)
 389       (setq event (next-command-event)))
 390     (cons (and (key-press-event-p event)
 391                (event-to-character event))
 392           event)))
 393
 394 (defun gnus-xmas-seconds-since-epoch (date)
 395   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 396   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 397                         (timezone-parse-date date)))
 398          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 399                         (timezone-parse-time
 400                          (aref (timezone-parse-date date) 3))))
 401          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 402                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 403          (tday (- (timezone-absolute-from-gregorian
 404                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 405                   (timezone-absolute-from-gregorian
 406                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 407     (+ (nth 2 ttime)
 408        (* (nth 1 ttime) 60)
 409        (* (float (nth 0 ttime)) 60 60)
 410        (* (float tday) 60 60 24))))
 411
 412 (defun gnus-xmas-define ()
 413   (setq gnus-mouse-2 [button2])
 414
 415   (unless (memq 'underline (face-list))
 416     (and (fboundp 'make-face)
 417          (funcall (intern "make-face") 'underline)))
 418   ;; Must avoid calling set-face-underline-p directly, because it
 419   ;; is a defsubst in emacs19, and will make the .elc files non
 420   ;; portable!
 421   (unless (face-differs-from-default-p 'underline)
 422     (funcall (intern "set-face-underline-p") 'underline t))
 423
 424   (cond
 425    ((fboundp 'char-or-char-int-p)
 426     ;; Handle both types of marks for XEmacs-20.x.
 427     (fset 'gnus-characterp 'char-or-char-int-p))
 428    ;; V19 of XEmacs, probably.
 429    (t
 430     (fset 'gnus-characterp 'characterp)))
 431
 432   (fset 'gnus-make-overlay 'make-extent)
 433   (fset 'gnus-delete-overlay 'delete-extent)
 434   (fset 'gnus-overlay-put 'set-extent-property)
 435   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 436   (fset 'gnus-overlay-end 'extent-end-position)
 437   (fset 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 438   (fset 'gnus-extent-detached-p 'extent-detached-p)
 439   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 440   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 441   (fset 'gnus-deactivate-mark 'ignore)
 442   (fset 'gnus-window-edges 'window-pixel-edges)
 443
 444   (if (and (<= emacs-major-version 19)
 445            (< emacs-minor-version 14))
 446       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 447
 448   (when (fboundp 'turn-off-scroll-in-place)
 449     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 450
 451   (unless (boundp 'standard-display-table)
 452     (setq standard-display-table nil))
 453
 454   (defvar gnus-mouse-face-prop 'highlight)
 455
 456   (unless (fboundp 'encode-time)
 457     (defun encode-time (sec minute hour day month year &optional zone)
 458       (let ((seconds
 459              (gnus-xmas-seconds-since-epoch
 460               (timezone-make-arpa-date
 461                year month day (timezone-make-time-string hour minute sec)
 462                zone))))
 463         (list (floor (/ seconds (expt 2 16)))
 464               (round (mod seconds (expt 2 16)))))))
 465
 466   (defun gnus-byte-code (func)
 467     "Return a form that can be `eval'ed based on FUNC."
 468     (let ((fval (indirect-function func)))
 469       (if (compiled-function-p fval)
 470           (list 'funcall fval)
 471         (cons 'progn (cdr (cdr fval))))))
 472
 473   (fset 'gnus-x-color-values
 474         (if (fboundp 'x-color-values)
 475             'x-color-values
 476           (lambda (color)
 477             (color-instance-rgb-components
 478              (make-color-instance color))))))
 479
 480 (defun gnus-xmas-redefine ()
 481   "Redefine lots of Gnus functions for XEmacs."
 482   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 483   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 484   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 485   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 486   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 487   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 488   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 489   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 490   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 491   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 492   (fset 'gnus-appt-select-lowest-window
 493         'gnus-xmas-appt-select-lowest-window)
 494   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 495   (fset 'gnus-character-to-event 'character-to-event)
 496   (fset 'gnus-mode-line-buffer-identification
 497         'gnus-xmas-mode-line-buffer-identification)
 498   (fset 'gnus-key-press-event-p 'key-press-event-p)
 499   (fset 'gnus-region-active-p 'region-active-p)
 500
 501   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 502   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 503   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 504   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 505
 506   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 507   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 508   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 509   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 510   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 511   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 512   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 513
 514   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 515   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 516
 517   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add)
 518   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add)
 519   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add)
 520
 521   (add-hook 'gnus-summary-mode-hook
 522             'gnus-xmas-switch-horizontal-scrollbar-off)
 523   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off))
 524
 525
 526 ;;; XEmacs logo and toolbar.
 527
 528 (defun gnus-xmas-group-startup-message (&optional x y)
 529   "Insert startup message in current buffer."
 530   ;; Insert the message.
 531   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 532   (erase-buffer)
 533   (cond
 534    ((and (console-on-window-system-p)
 535          (or (featurep 'xpm)
 536              (featurep 'xbm)))
 537     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 538            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 539            (glyph (make-glyph
 540                    (cond ((featurep 'xpm)
 541                           `[xpm
 542                             :file ,logo-xpm
 543                             :color-symbols
 544                             (("thing" . ,(car gnus-xmas-logo-colors))
 545                              ("shadow" . ,(cadr gnus-xmas-logo-colors))
 546                              ("background" . ,(face-background 'default)))])
 547                          ((featurep 'xbm)
 548                           `[xbm :file ,logo-xbm])
 549                          (t [nothing])))))
 550       (insert " ")
 551       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 552       (goto-char (point-min))
 553       (while (not (eobp))
 554         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 555                              ?\ ))
 556         (forward-line 1)))
 557     (goto-char (point-min))
 558     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 559            (wheight (window-height))
 560            (rest (- wheight pheight)))
 561       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 562    (t
 563     (insert
 564      (format "              %s
 565           _    ___ _             _
 566           _ ___ __ ___  __    _ ___
 567           __   _     ___    __  ___
 568               _           ___     _
 569              _  _ __             _
 570              ___   __            _
 571                    __           _
 572                     _      _   _
 573                    _      _    _
 574                       _  _    _
 575                   __  ___
 576                  _   _ _     _
 577                 _   _
 578               _    _
 579              _    _
 580             _
 581           __
 582
 583 "
 584              ""))
 585     ;; And then hack it.
 586     (gnus-indent-rigidly (point-min) (point-max)
 587                          (/ (max (- (window-width) (or x 46)) 0) 2))
 588     (goto-char (point-min))
 589     (forward-line 1)
 590     (let* ((pheight (count-lines (point-min) (point-max)))
 591            (wheight (window-height))
 592            (rest (- wheight pheight)))
 593       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 594     ;; Paint it.
 595     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 596   (setq modeline-buffer-identification
 597         (list (concat gnus-version ": *Group*")))
 598   (set-buffer-modified-p t))
 599
 600
 601 ;;; The toolbar.
 602
 603 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 604                                 'default-toolbar
 605                               nil)
 606   "*If nil, do not use a toolbar.
 607 If it is non-nil, it must be a toolbar.  The five legal values are
 608 `default-toolbar', `top-toolbar', `bottom-toolbar',
 609 `right-toolbar', and `left-toolbar'."
 610   :type '(choice (const default-toolbar)
 611                  (const top-toolbar) (const bottom-toolbar)
 612                  (const left-toolbar) (const right-toolbar)
 613                  (const :tag "no toolbar" nil))
 614   :group 'gnus-xmas)
 615
 616 (defvar gnus-group-toolbar
 617   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 618     [gnus-group-get-new-news-this-group
 619      gnus-group-get-new-news-this-group t "Get new news in this group"]
 620     [gnus-group-catchup-current
 621      gnus-group-catchup-current t "Catchup group"]
 622     [gnus-group-describe-group
 623      gnus-group-describe-group t "Describe group"]
 624     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 625     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 626     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 627     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 628     )
 629   "The group buffer toolbar.")
 630
 631 (defvar gnus-summary-toolbar
 632   '([gnus-summary-prev-unread
 633      gnus-summary-prev-page-or-article t "Page up"]
 634     [gnus-summary-next-unread
 635      gnus-summary-next-page t "Page down"]
 636     [gnus-summary-post-news
 637      gnus-summary-post-news t "Post an article"]
 638     [gnus-summary-followup-with-original
 639      gnus-summary-followup-with-original t
 640      "Post a followup and yank the original"]
 641     [gnus-summary-followup
 642      gnus-summary-followup t "Post a followup"]
 643     [gnus-summary-reply-with-original
 644      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 645     [gnus-summary-reply
 646      gnus-summary-reply t "Mail a reply"]
 647     [gnus-summary-caesar-message
 648      gnus-summary-caesar-message t "Rot 13"]
 649     [gnus-uu-decode-uu
 650      gnus-uu-decode-uu t "Decode uuencoded articles"]
 651     [gnus-summary-save-article-file
 652      gnus-summary-save-article-file t "Save article in file"]
 653     [gnus-summary-save-article
 654      gnus-summary-save-article t "Save article"]
 655     [gnus-uu-post-news
 656      gnus-uu-post-news t "Post a uuencoded article"]
 657     [gnus-summary-cancel-article
 658      gnus-summary-cancel-article t "Cancel article"]
 659     [gnus-summary-catchup
 660      gnus-summary-catchup t "Catchup"]
 661     [gnus-summary-catchup-and-exit
 662      gnus-summary-catchup-and-exit t "Catchup and exit"]
 663     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 664     )
 665   "The summary buffer toolbar.")
 666
 667 (defvar gnus-summary-mail-toolbar
 668   '(
 669     [gnus-summary-prev-unread
 670      gnus-summary-prev-unread-article t "Prev unread article"]
 671     [gnus-summary-next-unread
 672      gnus-summary-next-unread-article t "Next unread article"]
 673     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 674 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 675     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 676     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 677     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 678 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 679     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 680 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 681 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 682     [gnus-summary-caesar-message
 683      gnus-summary-caesar-message t "Rot 13"]
 684     [gnus-uu-decode-uu
 685      gnus-uu-decode-uu t "Decode uuencoded articles"]
 686     [gnus-summary-save-article-file
 687      gnus-summary-save-article-file t "Save article in file"]
 688     [gnus-summary-save-article
 689      gnus-summary-save-article t "Save article"]
 690     [gnus-summary-catchup
 691      gnus-summary-catchup t "Catchup"]
 692     [gnus-summary-catchup-and-exit
 693      gnus-summary-catchup-and-exit t "Catchup and exit"]
 694     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 695     )
 696   "The summary buffer mail toolbar.")
 697
 698 (defun gnus-xmas-setup-group-toolbar ()
 699   (and gnus-use-toolbar
 700        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 701        (set-specifier (symbol-value gnus-use-toolbar)
 702                       (cons (current-buffer) gnus-group-toolbar))))
 703
 704 (defun gnus-xmas-setup-summary-toolbar ()
 705   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 706                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 707     (and gnus-use-toolbar
 708          (message-xmas-setup-toolbar bar nil "gnus")
 709          (set-specifier (symbol-value gnus-use-toolbar)
 710                         (cons (current-buffer) bar)))))
 711
 712 (defun gnus-xmas-mail-strip-quoted-names (address)
 713   "Protect mail-strip-quoted-names from NIL input.
 714 XEmacs compatibility workaround."
 715   (if (null address)
 716       nil
 717     (mail-strip-quoted-names address)))
 718
 719 (defun gnus-xmas-call-region (command &rest args)
 720   (apply
 721    'call-process-region (point-min) (point-max) command t '(t nil) nil
 722    args))
 723
 724 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 725   "Face to show X face"
 726   :group 'gnus-xmas)
 727
 728 (defun gnus-xmas-article-display-xface (beg end)
 729   "Display any XFace headers in the current article."
 730   (save-excursion
 731     (let ((xface-glyph
 732            (cond ((featurep 'xface)
 733                   (make-glyph (vector 'xface :data
 734                                       (concat "X-Face: "
 735                                               (buffer-substring beg end)))))
 736                  ((featurep 'xpm)
 737                   (let ((cur (current-buffer)))
 738                     (save-excursion
 739                       (gnus-set-work-buffer)
 740                       (insert (format "%s" (buffer-substring beg end cur)))
 741                       (gnus-xmas-call-region "uncompface")
 742                       (goto-char (point-min))
 743                       (insert "/* Width=48, Height=48 */\n")
 744                       (gnus-xmas-call-region "icontopbm")
 745                       (gnus-xmas-call-region "ppmtoxpm")
 746                       (make-glyph
 747                        (vector 'xpm :data (buffer-string))))))
 748                  (t
 749                   (make-glyph [nothing])))))
 750       (set-glyph-face xface-glyph 'gnus-x-face)
 751       (goto-char (point-min))
 752       (re-search-forward "^From:" nil t)
 753       (set-extent-begin-glyph
 754        (make-extent (point) (1+ (point))) xface-glyph))))
 755
 756 ;;(defvar gnus-xmas-pointer-glyph
 757 ;;  (progn
 758 ;;    (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory
 759 ;;                                     "gnus"))
 760 ;;    (let ((file-xpm (expand-file-name "gnus-pointer.xpm"
 761 ;;                                    gnus-xmas-glyph-directory))
 762 ;;        (file-xbm (expand-file-name "gnus-pointer.xbm"
 763 ;;                                    gnus-xmas-glyph-directory)))
 764 ;;      (make-pointer-glyph
 765 ;;       (list (vector 'xpm ':file file-xpm)
 766 ;;           (vector 'xbm ':file file-xbm))))))
 767
 768 (defvar gnus-xmas-modeline-left-extent
 769   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 770 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 771     ext))
 772
 773 (defvar gnus-xmas-modeline-right-extent
 774   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 775 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 776     ext))
 777
 778 (defvar gnus-xmas-modeline-glyph
 779   (progn
 780     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 781     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 782                                        gnus-xmas-glyph-directory))
 783            (file-xbm (expand-file-name "gnus-pointer.xbm"
 784                                        gnus-xmas-glyph-directory))
 785            (glyph (make-glyph
 786                    ;; Gag gag gag.
 787                    (cond ((featurep 'xpm)
 788                           ;; Let's try a nifty XPM
 789                           `[xpm :file ,file-xpm])
 790                          ((featurep 'xbm)
 791                           ;; Then a not-so-nifty XBM
 792                           [xbm :file ,file-xbm])
 793                          ;; Then the simple string
 794                          (t [string :data "Gnus:"])))))
 795       (set-glyph-face glyph 'modeline-buffer-id)
 796       glyph)))
 797
 798 (defun gnus-xmas-mode-line-buffer-identification (line)
 799   (let ((line (car line))
 800         chop)
 801     (cond
 802      ;; This is some weird type of id.
 803      ((not (stringp line))
 804       (list line))
 805      ;; This is non-standard, so we just pass it through.
 806      ((not (string-match "^Gnus:" line))
 807       (list line))
 808      ;; We have a standard line, so we colorize and glyphize it a bit.
 809      (t
 810       (setq chop (match-end 0))
 811       (list
 812        (if gnus-xmas-modeline-glyph
 813            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 814          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 815        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 816
 817 (defun gnus-xmas-splash ()
 818   (when (eq (device-type) 'x)
 819     (gnus-splash)))
 820
 821 (provide 'gnus-xmas)
 822
 823 ;;; gnus-xmas.el ends here