cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2005, 2006, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (autoload 'gnus-active "gnus" nil nil 'macro)
  32   (autoload 'gnus-group-entry "gnus" nil nil 'macro)
  33   (autoload 'gnus-info-level "gnus" nil nil 'macro)
  34   (autoload 'gnus-info-marks "gnus" nil nil 'macro)
  35   (autoload 'gnus-info-method "gnus" nil nil 'macro)
  36   (autoload 'gnus-info-score "gnus" nil nil 'macro))
  37
  38 (require 'text-props)
  39 (defvar menu-bar-mode (featurep 'menubar))
  40 (require 'messagexmas)
  41 (require 'wid-edit)
  42 (require 'gnus-util)
  43
  44 (defgroup gnus-xmas nil
  45   "XEmacsoid support for Gnus"
  46   :group 'gnus)
  47
  48 (defcustom gnus-xmas-glyph-directory nil
  49   "Directory where Gnus logos and icons are located.
  50 If this variable is nil, Gnus will try to locate the directory
  51 automatically."
  52   :type '(choice (const :tag "autodetect" nil)
  53                  directory)
  54   :group 'gnus-xmas)
  55
  56 (unless gnus-xmas-glyph-directory
  57   (unless (setq gnus-xmas-glyph-directory
  58                 (message-xmas-find-glyph-directory "gnus"))
  59     (error "Can't find glyph directory. \
  60 Possibly the `etc' directory has not been installed.")))
  61
  62 ;;; Internal variables.
  63
  64 ;; Don't warn about these undefined variables.
  65
  66 ;;defined in gnus.el
  67 (defvar gnus-active-hashtb)
  68 (defvar gnus-article-buffer)
  69 (defvar gnus-auto-center-summary)
  70 (defvar gnus-current-headers)
  71 (defvar gnus-level-killed)
  72 (defvar gnus-level-zombie)
  73 (defvar gnus-newsgroup-bookmarks)
  74 (defvar gnus-newsgroup-dependencies)
  75 (defvar gnus-newsgroup-selected-overlay)
  76 (defvar gnus-newsrc-hashtb)
  77 (defvar gnus-read-mark)
  78 (defvar gnus-refer-article-method)
  79 (defvar gnus-reffed-article-number)
  80 (defvar gnus-unread-mark)
  81 (defvar gnus-version)
  82 (defvar gnus-view-pseudos)
  83 (defvar gnus-view-pseudos-separately)
  84 (defvar gnus-visual)
  85 (defvar gnus-zombie-list)
  86 ;;defined in gnus-msg.el
  87 (defvar gnus-article-copy)
  88 (defvar gnus-check-before-posting)
  89 ;;defined in gnus-vis.el
  90 (defvar gnus-article-button-face)
  91 (defvar gnus-article-mouse-face)
  92 (defvar gnus-summary-selected-face)
  93 (defvar gnus-group-reading-menu)
  94 (defvar gnus-group-group-menu)
  95 (defvar gnus-group-misc-menu)
  96 (defvar gnus-summary-article-menu)
  97 (defvar gnus-summary-thread-menu)
  98 (defvar gnus-summary-misc-menu)
  99 (defvar gnus-summary-post-menu)
 100 (defvar gnus-summary-kill-menu)
 101 (defvar gnus-article-article-menu)
 102 (defvar gnus-article-treatment-menu)
 103 (defvar gnus-mouse-2)
 104 (defvar standard-display-table)
 105 (defvar gnus-tree-minimize-window)
 106 ;;`gnus-agent-mode' in gnus-agent.el will define it.
 107 (defvar gnus-agent-summary-mode)
 108 (defvar gnus-draft-mode)
 109
 110 (defun gnus-xmas-highlight-selected-summary ()
 111   ;; Highlight selected article in summary buffer
 112   (when gnus-summary-selected-face
 113     (when gnus-newsgroup-selected-overlay
 114       (delete-extent gnus-newsgroup-selected-overlay))
 115     (setq gnus-newsgroup-selected-overlay
 116           (make-extent (point-at-bol) (point-at-eol)))
 117     (set-extent-face gnus-newsgroup-selected-overlay
 118                      gnus-summary-selected-face)))
 119
 120 (defcustom gnus-xmas-force-redisplay nil
 121   "*If non-nil, force a redisplay before recentering the summary buffer.
 122 This is ugly, but it works around a bug in `window-displayed-height'."
 123   :type 'boolean
 124   :group 'gnus-xmas)
 125
 126 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 127   (when (featurep 'scrollbar)
 128     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 129
 130 (defun gnus-xmas-summary-recenter ()
 131   "\"Center\" point in the summary window.
 132 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 133 displayed, no centering will be performed."
 134   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 135   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 136   ;; Force redisplay to get properly computed window height.
 137   (when gnus-xmas-force-redisplay
 138     (sit-for 0))
 139   (when gnus-auto-center-summary
 140     (let* ((height (if (fboundp 'window-displayed-height)
 141                        (window-displayed-height)
 142                      (- (window-height) 2)))
 143            (top (cond ((< height 4) 0)
 144                       ((< height 7) 1)
 145                       (t (if (numberp gnus-auto-center-summary)
 146                              gnus-auto-center-summary
 147                            2))))
 148            (bottom (save-excursion (goto-char (point-max))
 149                                    (forward-line (- height))
 150                                    (point)))
 151            (window (get-buffer-window (current-buffer))))
 152       (when (get-buffer-window gnus-article-buffer)
 153         ;; Only do recentering when the article buffer is displayed,
 154         ;; Set the window start to either `bottom', which is the biggest
 155         ;; possible valid number, or the second line from the top,
 156         ;; whichever is the least.
 157         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 158         (set-window-start
 159          window (min bottom (save-excursion (forward-line (- top)) (point)))
 160          t))
 161       ;; Do horizontal recentering while we're at it.
 162       (when (and (get-buffer-window (current-buffer) t)
 163                  (not (eq gnus-auto-center-summary 'vertical)))
 164         (let ((selected (selected-window)))
 165           (select-window (get-buffer-window (current-buffer) t))
 166           (gnus-summary-position-point)
 167           (gnus-horizontal-recenter)
 168           (select-window selected))))))
 169
 170 (defun gnus-xmas-summary-set-display-table ()
 171   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 172   ;; but done in an XEmacsish way.
 173   (let ((table (make-display-table))
 174         (i 32))
 175     ;; Nix out all the control chars...
 176     (while (>= (setq i (1- i)) 0)
 177       (gnus-put-display-table i [??] table))
 178     ;; ... but not newline and cr, of course.  (cr is necessary for the
 179     ;; selective display).
 180     (gnus-put-display-table ?\n nil table)
 181     (gnus-put-display-table ?\r nil table)
 182     ;; We keep TAB as well.
 183     (gnus-put-display-table ?\t nil table)
 184     ;; We nix out any glyphs over 126 below ctl-arrow.
 185     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 186       (while (>= (setq i (1- i)) 127)
 187         (unless (gnus-get-display-table i table)
 188           (gnus-put-display-table i [??] table))))
 189     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 190     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 191
 192 (defun gnus-xmas-add-text-properties (start end props &optional object)
 193   (add-text-properties start end props object)
 194   (put-text-property start end 'start-closed nil object))
 195
 196 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 197   (put-text-property start end prop value object)
 198   (put-text-property start end 'start-closed nil object))
 199
 200 (defun gnus-xmas-extent-start-open (point)
 201   (map-extents (lambda (extent arg)
 202                  (set-extent-property extent 'start-open t))
 203                nil point (min (1+ (point)) (point-max))))
 204
 205 (defun gnus-xmas-article-push-button (event)
 206   "Check text under the mouse pointer for a callback function.
 207 If the text under the mouse pointer has a `gnus-callback' property,
 208 call it with the value of the `gnus-data' text property."
 209   (interactive "e")
 210   (set-buffer (window-buffer (event-window event)))
 211   (let* ((pos (event-closest-point event))
 212          (data (get-text-property pos 'gnus-data))
 213          (fun (get-text-property pos 'gnus-callback)))
 214     (goto-char pos)
 215     (when fun
 216       (funcall fun data))))
 217
 218 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 219   (set-extent-endpoints extent start end buffer))
 220
 221 (defun gnus-xmas-kill-all-overlays ()
 222   "Delete all extents in the current buffer."
 223   (map-extents (lambda (extent ignore)
 224                  (delete-extent extent)
 225                  nil)))
 226
 227 (defun gnus-xmas-overlays-in (beg end)
 228   "Return a list of the extents that overlap the region BEG ... END."
 229   (mapcar-extents #'identity nil nil beg end))
 230
 231 (defun gnus-xmas-window-top-edge (&optional window)
 232   (nth 1 (window-pixel-edges window)))
 233
 234 (defun gnus-xmas-tree-minimize ()
 235   (when (and gnus-tree-minimize-window
 236              (not (one-window-p)))
 237     (let* ((window-min-height 2)
 238            (height (1+ (count-lines (point-min) (point-max))))
 239            (min (max (1- window-min-height) height))
 240            (tot (if (numberp gnus-tree-minimize-window)
 241                     (min gnus-tree-minimize-window min)
 242                   min))
 243            (win (get-buffer-window (current-buffer)))
 244            (wh (and win (1- (window-height win)))))
 245       (when (and win
 246                  (not (eq tot wh)))
 247         (let ((selected (selected-window)))
 248           (select-window win)
 249           (enlarge-window (- tot wh))
 250           (select-window selected))))))
 251
 252 ;; Select the lowest window on the frame.
 253 (defun gnus-xmas-select-lowest-window ()
 254   (let* ((lowest-window (selected-window))
 255          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 256          (last-window (previous-window))
 257          (window-search t))
 258     (while window-search
 259       (let* ((this-window (next-window))
 260              (next-bottom-edge (car (cdr (cdr (cdr
 261                                                (window-pixel-edges
 262                                                 this-window)))))))
 263         (when (< bottom-edge next-bottom-edge)
 264           (setq bottom-edge next-bottom-edge)
 265           (setq lowest-window this-window))
 266
 267         (select-window this-window)
 268         (when (eq last-window this-window)
 269           (select-window lowest-window)
 270           (setq window-search nil))))))
 271
 272 (defmacro gnus-xmas-menu-add (type &rest menus)
 273   `(gnus-xmas-menu-add-1 ',type ',menus))
 274 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 275
 276 (defun gnus-xmas-menu-add-1 (type menus)
 277   (when (and menu-bar-mode
 278              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 279     (while menus
 280       (easy-menu-add (symbol-value (pop menus))))))
 281
 282 (defun gnus-xmas-group-menu-add ()
 283   (gnus-xmas-menu-add group
 284     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 285
 286 (defun gnus-xmas-summary-menu-add ()
 287   (gnus-xmas-menu-add summary
 288     gnus-summary-misc-menu gnus-summary-kill-menu
 289     gnus-summary-article-menu gnus-summary-thread-menu
 290     gnus-summary-post-menu ))
 291
 292 (defun gnus-xmas-article-menu-add ()
 293   (gnus-xmas-menu-add article
 294     gnus-article-article-menu gnus-article-treatment-menu
 295     gnus-article-post-menu gnus-article-commands-menu))
 296
 297 (defun gnus-xmas-score-menu-add ()
 298   (gnus-xmas-menu-add score
 299     gnus-score-menu))
 300
 301 (defun gnus-xmas-pick-menu-add ()
 302   (gnus-xmas-menu-add pick
 303     gnus-pick-menu))
 304
 305 (defun gnus-xmas-topic-menu-add ()
 306   (gnus-xmas-menu-add topic
 307     gnus-topic-menu))
 308
 309 (defun gnus-xmas-binary-menu-add ()
 310   (gnus-xmas-menu-add binary
 311     gnus-binary-menu))
 312
 313 (defun gnus-xmas-agent-summary-menu-add ()
 314   (gnus-xmas-menu-add agent-summary
 315     gnus-agent-summary-menu))
 316
 317 (defun gnus-xmas-agent-group-menu-add ()
 318   (gnus-xmas-menu-add agent-group
 319     gnus-agent-group-menu))
 320
 321 (defun gnus-xmas-agent-server-menu-add ()
 322   (gnus-xmas-menu-add agent-server
 323     gnus-agent-server-menu))
 324
 325 (defun gnus-xmas-tree-menu-add ()
 326   (gnus-xmas-menu-add tree
 327     gnus-tree-menu))
 328
 329 (defun gnus-xmas-draft-menu-add ()
 330   (gnus-xmas-menu-add draft
 331     gnus-draft-menu))
 332
 333 (defun gnus-xmas-server-menu-add ()
 334   (gnus-xmas-menu-add menu
 335     gnus-server-server-menu gnus-server-connections-menu))
 336
 337 (defun gnus-xmas-browse-menu-add ()
 338   (gnus-xmas-menu-add browse
 339     gnus-browse-menu))
 340
 341 (defun gnus-xmas-read-event-char (&optional prompt)
 342   "Get the next event."
 343   (when prompt
 344     (display-message 'no-log (format "%s" prompt)))
 345   (let ((event (next-command-event)))
 346     (sit-for 0)
 347     ;; We junk all non-key events.  Is this naughty?
 348     (while (not (or (key-press-event-p event)
 349                     (button-press-event-p event)))
 350       (dispatch-event event)
 351       (setq event (next-command-event)))
 352     (cons (and (key-press-event-p event)
 353                (event-to-character event))
 354           event)))
 355
 356 (defun gnus-xmas-article-describe-bindings (&optional prefix)
 357   "Show a list of all defined keys, and their definitions.
 358 The optional argument PREFIX, if non-nil, should be a key sequence;
 359 then we display only bindings that start with that prefix."
 360   (interactive)
 361   (gnus-article-check-buffer)
 362   (let ((keymap (copy-keymap gnus-article-mode-map))
 363         (map (copy-keymap gnus-article-send-map))
 364         (sumkeys (where-is-internal 'gnus-article-read-summary-keys))
 365         parent agent draft)
 366     (define-key keymap "S" map)
 367     (set-keymap-default-binding map nil)
 368     (with-current-buffer gnus-article-current-summary
 369       (set-keymap-parent
 370        keymap
 371        (if (setq parent (keymap-parent gnus-article-mode-map))
 372            (prog1
 373                (setq parent (copy-keymap parent))
 374              (set-keymap-parent parent (current-local-map)))
 375          (current-local-map)))
 376       (let ((def (key-binding "S"))
 377             gnus-pick-mode)
 378         (set-keymap-parent map (if (symbolp def)
 379                                    (symbol-value def)
 380                                  def))
 381         (dolist (key sumkeys)
 382           (when (setq def (key-binding key))
 383             (define-key keymap key def))))
 384       (when (boundp 'gnus-agent-summary-mode)
 385         (setq agent gnus-agent-summary-mode))
 386       (when (boundp 'gnus-draft-mode)
 387         (setq draft gnus-draft-mode)))
 388     (with-temp-buffer
 389       (setq major-mode 'gnus-article-mode)
 390       (use-local-map keymap)
 391       (set (make-local-variable 'gnus-agent-summary-mode) agent)
 392       (set (make-local-variable 'gnus-draft-mode) draft)
 393       (describe-bindings prefix))))
 394
 395 (defun gnus-xmas-define ()
 396   (setq gnus-mouse-2 [button2])
 397   (setq gnus-mouse-3 [button3])
 398   (setq gnus-widget-button-keymap widget-button-keymap)
 399
 400   (unless (memq 'underline (face-list))
 401     (and (fboundp 'make-face)
 402          (funcall (intern "make-face") 'underline)))
 403   ;; Must avoid calling set-face-underline-p directly, because it
 404   ;; is a defsubst in emacs19, and will make the .elc files non
 405   ;; portable!
 406   (unless (face-differs-from-default-p 'underline)
 407     (funcall (intern "set-face-underline-p") 'underline t))
 408
 409   (defalias 'gnus-make-overlay
 410     (lambda (beg end &optional buffer front-advance rear-advance)
 411       "Create a new overlay with range BEG to END in BUFFER.
 412 FRONT-ADVANCE and REAR-ADVANCE are ignored."
 413       (make-extent beg end buffer)))
 414
 415   (defalias 'gnus-delete-overlay 'delete-extent)
 416   (defalias 'gnus-overlay-get 'extent-property)
 417   (defalias 'gnus-overlay-put 'set-extent-property)
 418   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 419   (defalias 'gnus-overlay-buffer 'extent-object)
 420   (defalias 'gnus-overlay-start 'extent-start-position)
 421   (defalias 'gnus-overlay-end 'extent-end-position)
 422   (defalias 'gnus-overlays-in 'gnus-xmas-overlays-in)
 423   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 424   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 425   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 426   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 427   (defalias 'gnus-deactivate-mark 'ignore)
 428   (defalias 'gnus-window-edges 'window-pixel-edges)
 429   (defalias 'gnus-assq-delete-all 'gnus-xmas-assq-delete-all)
 430
 431   (unless (boundp 'standard-display-table)
 432     (setq standard-display-table nil))
 433
 434   (defvar gnus-mouse-face-prop 'highlight)
 435
 436   (defun gnus-byte-code (func)
 437     "Return a form that can be `eval'ed based on FUNC."
 438     (let ((fval (indirect-function func)))
 439       (if (compiled-function-p fval)
 440           (list 'funcall fval)
 441         (cons 'progn (cdr (cdr fval))))))
 442
 443   (unless (fboundp 'match-string-no-properties)
 444     (defalias 'match-string-no-properties 'match-string))
 445
 446   (defalias 'gnus-x-color-values
 447         (if (fboundp 'x-color-values)
 448             'x-color-values
 449           (lambda (color)
 450             (color-instance-rgb-components
 451              (make-color-instance color)))))
 452
 453   (unless (fboundp 'char-width)
 454     (defalias 'char-width (lambda (ch) 1))))
 455
 456 (defun gnus-xmas-redefine ()
 457   "Redefine lots of Gnus functions for XEmacs."
 458   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 459   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 460   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 461   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 462   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 463   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 464   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 465   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 466   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 467   (defalias 'gnus-select-lowest-window
 468     'gnus-xmas-select-lowest-window)
 469   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 470   (defalias 'gnus-character-to-event 'character-to-event)
 471   (defalias 'gnus-mode-line-buffer-identification
 472     'gnus-xmas-mode-line-buffer-identification)
 473   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 474   (defalias 'gnus-region-active-p 'region-active-p)
 475   (defalias 'gnus-mark-active-p 'region-exists-p)
 476   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 477   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 478   (defalias 'gnus-mime-security-button-menu
 479     'gnus-xmas-mime-security-button-menu)
 480   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 481   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 482   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 483   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 484   (defalias 'gnus-article-describe-bindings
 485     'gnus-xmas-article-describe-bindings)
 486
 487   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 488   ;; probably should. If that is done, the code below should then be moved
 489   ;; where each variable is defined, in order not to mess with user settings.
 490   ;; -- didier
 491   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 492   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 493   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 494   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 495   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 496   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add))
 497
 498
 499 ;;; XEmacs logo and toolbar.
 500
 501 (defun gnus-xmas-group-startup-message (&optional x y)
 502   "Insert startup message in current buffer."
 503   ;; Insert the message.
 504   (erase-buffer)
 505   (cond
 506    ((and (console-on-window-system-p)
 507          (or (featurep 'xpm)
 508              (featurep 'xbm)))
 509     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 510            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 511            (glyph (make-glyph
 512                    (cond ((featurep 'xpm)
 513                           `[xpm
 514                             :file ,logo-xpm
 515                             :color-symbols
 516                             (("thing" . ,(car gnus-logo-colors))
 517                              ("shadow" . ,(cadr gnus-logo-colors))
 518                              ("oort" . "#eeeeee")
 519                              ("background" . ,(face-background 'default)))])
 520                          ((featurep 'xbm)
 521                           `[xbm :file ,logo-xbm])
 522                          (t [nothing])))))
 523       (insert " ")
 524       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 525       (goto-char (point-min))
 526       (while (not (eobp))
 527         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 528                              ?\ ))
 529         (forward-line 1)))
 530     (goto-char (point-min))
 531     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 532            (wheight (window-height))
 533            (rest (- wheight pheight)))
 534       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 535    (t
 536     (insert
 537      (format "              %s
 538           _    ___ _             _
 539           _ ___ __ ___  __    _ ___
 540           __   _     ___    __  ___
 541               _           ___     _
 542              _  _ __             _
 543              ___   __            _
 544                    __           _
 545                     _      _   _
 546                    _      _    _
 547                       _  _    _
 548                   __  ___
 549                  _   _ _     _
 550                 _   _
 551               _    _
 552              _    _
 553             _
 554           __
 555
 556 "
 557              ""))
 558     ;; And then hack it.
 559     (gnus-indent-rigidly (point-min) (point-max)
 560                          (/ (max (- (window-width) (or x 46)) 0) 2))
 561     (goto-char (point-min))
 562     (forward-line 1)
 563     (let* ((pheight (count-lines (point-min) (point-max)))
 564            (wheight (window-height))
 565            (rest (- wheight pheight)))
 566       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 567     ;; Paint it.
 568     (put-text-property (point-min) (point-max) 'face 'gnus-splash)))
 569   (setq modeline-buffer-identification
 570         (list (concat gnus-version ": *Group*")))
 571   (set-buffer-modified-p t))
 572
 573
 574 ;;; The toolbar.
 575
 576 (defun gnus-xmas-update-toolbars ()
 577   "Update the toolbars' appearance."
 578   (when (and (not noninteractive)
 579              (featurep 'gnus-xmas))
 580     (save-excursion
 581       (dolist (buffer (buffer-list))
 582         (set-buffer buffer)
 583         (cond ((eq major-mode 'gnus-group-mode)
 584                (gnus-xmas-setup-group-toolbar))
 585               ((eq major-mode 'gnus-summary-mode)
 586                (gnus-xmas-setup-summary-toolbar)))))))
 587
 588 (defcustom gnus-use-toolbar (if (featurep 'toolbar) 'default)
 589   "*Position to display the toolbar.  Nil means do not use a toolbar.
 590 If it is non-nil, it should be one of the symbols `default', `top',
 591 `bottom', `right', and `left'.  `default' means to use the default
 592 toolbar, the rest mean to display the toolbar on the place which those
 593 names show."
 594   :type '(choice (const default)
 595                  (const top) (const bottom) (const left) (const right)
 596                  (const :tag "no toolbar" nil))
 597   :set (lambda (symbol value)
 598          (set-default
 599           symbol
 600           (if (or (not value)
 601                   (memq value (list 'default 'top 'bottom 'right 'left)))
 602               value
 603             'default))
 604          (gnus-xmas-update-toolbars))
 605   :group 'gnus-xmas)
 606
 607 (defcustom gnus-toolbar-thickness
 608   (if (featurep 'toolbar)
 609       (cons (specifier-instance default-toolbar-height)
 610             (specifier-instance default-toolbar-width)))
 611   "*Cons of the height and the width specifying the thickness of a toolbar.
 612 The height is used for the toolbar displayed on the top or the bottom,
 613 the width is used for the toolbar displayed on the right or the left."
 614   :type '(cons :tag "height & width"
 615                (integer :tag "height") (integer :tag "width"))
 616   :set (lambda (symbol value)
 617          (set-default
 618           symbol
 619           (if (and (consp value) (natnump (car value)) (natnump (cdr value)))
 620               value
 621             '(37 . 40)))
 622          (gnus-xmas-update-toolbars))
 623   :group 'gnus-xmas)
 624
 625 (defvar gnus-group-toolbar
 626   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 627     [gnus-group-get-new-news-this-group
 628      gnus-group-get-new-news-this-group t "Get new news in this group"]
 629     [gnus-group-catchup-current
 630      gnus-group-catchup-current t "Catchup group"]
 631     [gnus-group-describe-group
 632      gnus-group-describe-group t "Describe group"]
 633     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 634     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 635     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 636     [gnus-summary-mail-save
 637      gnus-group-save-newsrc t "Save .newsrc files"] ; borrowed icon.
 638     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 639   "The group buffer toolbar.")
 640
 641 (defvar gnus-summary-toolbar
 642   '([gnus-summary-prev-unread
 643      gnus-summary-prev-page-or-article t "Page up"]
 644     [gnus-summary-next-unread
 645      gnus-summary-next-page t "Page down"]
 646     [gnus-summary-post-news
 647      gnus-summary-post-news t "Post an article"]
 648     [gnus-summary-followup-with-original
 649      gnus-summary-followup-with-original t
 650      "Post a followup and yank the original"]
 651     [gnus-summary-followup
 652      gnus-summary-followup t "Post a followup"]
 653     [gnus-summary-reply-with-original
 654      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 655     [gnus-summary-reply
 656      gnus-summary-reply t "Mail a reply"]
 657     [gnus-summary-caesar-message
 658      gnus-summary-caesar-message t "Rot 13"]
 659     [gnus-uu-decode-uu
 660      gnus-uu-decode-uu t "Decode uuencoded articles"]
 661     [gnus-summary-save-article-file
 662      gnus-summary-save-article-file t "Save article in file"]
 663     [gnus-summary-save-article
 664      gnus-summary-save-article t "Save article"]
 665     [gnus-uu-post-news
 666      gnus-uu-post-news t "Post a uuencoded article"]
 667     [gnus-summary-cancel-article
 668      gnus-summary-cancel-article t "Cancel article"]
 669     [gnus-summary-catchup
 670      gnus-summary-catchup t "Catchup"]
 671     [gnus-summary-catchup-and-exit
 672      gnus-summary-catchup-and-exit t "Catchup and exit"]
 673     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 674   "The summary buffer toolbar.")
 675
 676 (defvar gnus-summary-mail-toolbar
 677   '(
 678     [gnus-summary-prev-unread
 679      gnus-summary-prev-unread-article t "Prev unread article"]
 680     [gnus-summary-next-unread
 681      gnus-summary-next-unread-article t "Next unread article"]
 682     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 683     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 684     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 685     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 686     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 687     [gnus-summary-caesar-message
 688      gnus-summary-caesar-message t "Rot 13"]
 689     [gnus-uu-decode-uu
 690      gnus-uu-decode-uu t "Decode uuencoded articles"]
 691     [gnus-summary-save-article-file
 692      gnus-summary-save-article-file t "Save article in file"]
 693     [gnus-summary-save-article
 694      gnus-summary-save-article t "Save article"]
 695     [gnus-summary-cancel-article ; usenet : cancellation :: mail : deletion.
 696      gnus-summary-delete-article t "Delete message"]
 697     [gnus-summary-catchup
 698      gnus-summary-catchup t "Catchup"]
 699     [gnus-summary-catchup-and-exit
 700      gnus-summary-catchup-and-exit t "Catchup and exit"]
 701     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 702   "The summary buffer mail toolbar.")
 703
 704 (defun gnus-xmas-setup-toolbar (toolbar)
 705   (when (featurep 'toolbar)
 706     (if (and gnus-use-toolbar
 707              (message-xmas-setup-toolbar toolbar nil "gnus"))
 708         (let ((bar (or (intern-soft (format "%s-toolbar" gnus-use-toolbar))
 709                        'default-toolbar))
 710               (height (car gnus-toolbar-thickness))
 711               (width (cdr gnus-toolbar-thickness))
 712               (cur (current-buffer))
 713               bars)
 714           (set-specifier (symbol-value bar) toolbar cur)
 715           (set-specifier default-toolbar-height height cur)
 716           (set-specifier default-toolbar-width width cur)
 717           (set-specifier top-toolbar-height height cur)
 718           (set-specifier bottom-toolbar-height height cur)
 719           (set-specifier right-toolbar-width width cur)
 720           (set-specifier left-toolbar-width width cur)
 721           (if (eq bar 'default-toolbar)
 722               (progn
 723                 (remove-specifier default-toolbar-visible-p cur)
 724                 (remove-specifier top-toolbar cur)
 725                 (remove-specifier top-toolbar-visible-p cur)
 726                 (remove-specifier bottom-toolbar cur)
 727                 (remove-specifier bottom-toolbar-visible-p cur)
 728                 (remove-specifier right-toolbar cur)
 729                 (remove-specifier right-toolbar-visible-p cur)
 730                 (remove-specifier left-toolbar cur)
 731                 (remove-specifier left-toolbar-visible-p cur))
 732             (set-specifier (symbol-value (intern (format "%s-visible-p" bar)))
 733                            t cur)
 734             (setq bars (delq bar (list 'default-toolbar
 735                                        'bottom-toolbar 'top-toolbar
 736                                        'right-toolbar 'left-toolbar)))
 737             (while bars
 738               (set-specifier (symbol-value (intern (format "%s-visible-p"
 739                                                            (pop bars))))
 740                              nil cur))))
 741       (let ((cur (current-buffer)))
 742         (set-specifier default-toolbar-visible-p nil cur)
 743         (set-specifier top-toolbar-visible-p nil cur)
 744         (set-specifier bottom-toolbar-visible-p nil cur)
 745         (set-specifier right-toolbar-visible-p nil cur)
 746         (set-specifier left-toolbar-visible-p nil cur)))))
 747
 748 (defun gnus-xmas-setup-group-toolbar ()
 749   (gnus-xmas-setup-toolbar gnus-group-toolbar))
 750
 751 (defun gnus-xmas-setup-summary-toolbar ()
 752   (gnus-xmas-setup-toolbar (if (gnus-news-group-p gnus-newsgroup-name)
 753                                gnus-summary-toolbar
 754                              gnus-summary-mail-toolbar)))
 755
 756 (defun gnus-xmas-mail-strip-quoted-names (address)
 757   "Protect mail-strip-quoted-names from nil input.
 758 XEmacs compatibility workaround."
 759   (if (null address)
 760       nil
 761     (mail-strip-quoted-names address)))
 762
 763 (defun gnus-xmas-call-region (command &rest args)
 764   (apply
 765    'call-process-region (point-min) (point-max) command t '(t nil) nil
 766    args))
 767
 768 (defvar gnus-xmas-modeline-left-extent
 769   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 770     ext))
 771
 772 (defvar gnus-xmas-modeline-right-extent
 773   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 774     ext))
 775
 776 (defvar gnus-xmas-modeline-glyph
 777   (progn
 778     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 779                                        gnus-xmas-glyph-directory))
 780            (file-xbm (expand-file-name "gnus-pointer.xbm"
 781                                        gnus-xmas-glyph-directory))
 782            (glyph (make-glyph
 783                    ;; Gag gag gag.
 784                    (cond ((featurep 'xpm)
 785                           ;; Let's try a nifty XPM
 786                           `[xpm :file ,file-xpm])
 787                          ((featurep 'xbm)
 788                           ;; Then a not-so-nifty XBM
 789                           `[xbm :file ,file-xbm])
 790                          ;; Then the simple string
 791                          (t [string :data "Gnus:"])))))
 792       (set-glyph-face glyph 'modeline-buffer-id)
 793       glyph)))
 794
 795 (defun gnus-xmas-mode-line-buffer-identification (line)
 796   (let ((line (car line))
 797         chop)
 798     (cond
 799      ;; This is some weird type of id.
 800      ((not (stringp line))
 801       (list line))
 802      ;; This is non-standard, so we just pass it through.
 803      ((not (string-match "^Gnus:" line))
 804       (list line))
 805      ;; We have a standard line, so we colorize and glyphize it a bit.
 806      (t
 807       (setq chop (match-end 0))
 808       (list
 809        (if gnus-xmas-modeline-glyph
 810            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 811          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 812        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 813
 814 (defun gnus-xmas-annotation-in-region-p (b e)
 815   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 816       (if (= b e)
 817           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 818         (text-property-any b e 'gnus-undeletable t))))
 819
 820 (defun gnus-xmas-mime-button-menu (event prefix)
 821   "Construct a context-sensitive menu of MIME commands."
 822   (interactive "e\nP")
 823   (let ((response (get-popup-menu-response
 824                    `("MIME Part"
 825                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 826                                gnus-mime-button-commands)))))
 827     (set-buffer (event-buffer event))
 828     (goto-char (event-point event))
 829     (funcall (event-function response) (event-object response))))
 830
 831 (defun gnus-xmas-mime-security-button-menu (event prefix)
 832   "Construct a context-sensitive menu of security commands."
 833   (interactive "e\nP")
 834   (let ((response
 835          (get-popup-menu-response
 836           `("Security Part"
 837             ,@(delq nil
 838                     (mapcar (lambda (c)
 839                               (unless (eq (car c) 'undefined)
 840                                 `[,(caddr c) ,(car c) t]))
 841                             gnus-mime-security-button-commands))))))
 842     (set-buffer (event-buffer event))
 843     (goto-char (event-point event))
 844     (funcall (event-function response) (event-object response))))
 845
 846 (defun gnus-xmas-mailing-list-menu-add ()
 847   (gnus-xmas-menu-add mailing-list
 848                       gnus-mailing-list-menu))
 849
 850 (defun gnus-xmas-image-type-available-p (type)
 851   (and (if (fboundp 'display-images-p)
 852            (display-images-p)
 853          window-system)
 854        (featurep (if (eq type 'pbm) 'xbm type))))
 855
 856 (defun gnus-xmas-create-image (file &optional type data-p &rest props)
 857   (let ((type (cond
 858                (type
 859                 (symbol-name type))
 860                ((and (not data-p)
 861                      (string-match "[.]" file))
 862                 (car (last (split-string file "[.]"))))))
 863         (face (plist-get props :face))
 864         glyph)
 865     (when (equal type "pbm")
 866       (with-temp-buffer
 867         (if data-p
 868             (insert file)
 869           (insert-file-contents-literally file))
 870         (shell-command-on-region (point-min) (point-max)
 871                                  "ppmtoxpm 2>/dev/null" t)
 872         (setq file (buffer-string)
 873               type "xpm"
 874               data-p t)))
 875     (setq glyph
 876           (if (equal type "xbm")
 877               (make-glyph (list (cons 'x file)))
 878             (with-temp-buffer
 879               (if data-p
 880                   (insert file)
 881                 (insert-file-contents-literally file))
 882               (make-glyph
 883                (vector
 884                 (if type
 885                     (intern type)
 886                   (mm-image-type-from-buffer))
 887                 :data (buffer-string))))))
 888     (when face
 889       (set-glyph-face glyph face))
 890     glyph))
 891
 892 (defun gnus-xmas-put-image (glyph &optional string category)
 893   "Insert STRING, but display GLYPH.
 894 Warning: Don't insert text immediately after the image."
 895   (let ((begin (point))
 896         extent)
 897     (if (and (bobp) (not string))
 898         (setq string " "))
 899     (if string
 900         (insert string)
 901       (setq begin (1- begin)))
 902     (setq extent (make-extent begin (point)))
 903     (set-extent-property extent 'gnus-image category)
 904     (set-extent-property extent 'duplicable t)
 905     (if string
 906         (set-extent-property extent 'invisible t))
 907     (set-extent-property extent 'end-glyph glyph))
 908   glyph)
 909
 910 (defun gnus-xmas-remove-image (image &optional category)
 911   "Remove the image matching IMAGE and CATEGORY found first."
 912   (map-extents
 913    (lambda (ext unused)
 914      (when (equal (extent-end-glyph ext) image)
 915        (set-extent-property ext 'invisible nil)
 916        (set-extent-property ext 'end-glyph nil)
 917        t))
 918    nil nil nil nil nil 'gnus-image category))
 919
 920 (defun gnus-xmas-assq-delete-all (key alist)
 921   (let ((elem nil))
 922     (while (setq elem (assq key alist))
 923       (setq alist (delq elem alist)))
 924     alist))
 925
 926 (provide 'gnus-xmas)
 927
 928 ;;; gnus-xmas.el ends here